         TITLE 'IGF24MPD'                                               00200019
IGF24MPD  CSECT                                                         00400019
*********************************************************************** 00409019
*                                                                     * 00418019
*                       INTRODUCTORY COMMENTS                         * 00427019
*                                                                     * 00436019
*STATUS -- RELEASE 19                                                 * 00445019
*                                                                     * 00454019
*FUNCTION -- THIS MODULE IS THE FIRST LOAD OF THE VARY PATH COMMAND   * 00461019
*   PROCESSOR FOR MULTIPROCESSING SYSTEMS. IT VERIFIES THE COMMAND    * 00468019
*   FORMAT AND SETS UP A PARAMETER LIST FOR THE PRIVATE MACRO,        * 00475019
*   IOSGEN.                                                           * 00482019
*   IOSGEN VERIFIES THE PATHS AND ACCESSES THE CHANNEL ERROR BLOCKS,  * 00490019
*   AND PREFIX STORAGE AREAS FOR BOTH CPU'S. IT SETS THE PATH BITS    * 00499019
*   IN THE UCBWGT FIELD (UCB+12) FOR A VALID COMMAND, AND SETS UP     * 00508019
*   A RETURN CODE FOR THE ACTION TAKEN. (I.E., RETURN CODE=0 FOR PATH * 00517019
*   VARIED SUCCESSFUL, RETURN CODE=12 FOR NON-EXISTENT PATH).         * 00526019
*   THE MODULE PASSES A CODE, ACCORDING TO THE ACTION TAKEN, TO ITS   * 00535019
*   SECOND LOAD, IGF34MPD.                                            * 00544019
*                                                                     * 00553019
*ENTRY POINTS --                                                      * 00562019
*        IGF24MPD -- FIRST INSTRUCTION                                * 00571019
*                                                                     * 00580019
*INPUT -- AT ENTRY, REGISTER 2 CONTAINS THE ADDRESS OF THE SVRB       * 00589019
*   EXTENDED SAVE AREA                                                * 00598019
*                                                                     * 00607019
*OUTPUT -- REGISTER 2 REMAINS UNCHANGED. REGISTER 1  CONTAINS THE     * 00613019
*   INDEX CODE FOR THE SECOND LOAD.                                     00619019
*                                                                     * 00625019
*EXTERNAL REFERENCES -- THE CHANNEL ERROR BLOCKS ARE CHECKED FOR APR  * 00634019
*   INTERACTION. THE ADDRESS OF THE FIRST CHANNEL ERROR BLOCK IS AT A * 00643019
*   DISPLACEMENT OF 24 FROM THE IOS FREELIST. CVT + 124 POINTS TO THE * 00652019
*   IOS FREELIST                                                      * 00661019
*                                                                     * 00670019
*EXITS,NORMAL --                                                      * 00679019
*        XCTL TO IGC3403D                                             * 00688019
*EXITS ERROR --                                                       * 00697019
*        NONE                                                         * 00706019
*                                                                     * 00715019
*TABLES/WORK AREAS -- EXTENDED SAVE AREA OF SVRB, CHANNEL ERROR BLOCKS* 00724019
*                                                                     * 00733019
*ATTRIBUTES -- REFESHABLE                                             * 00742019
*                                                                     * 00751019
*NOTES -- THIS MODULE USES A PRIVATE MACRO, IOSGEN. THERE IS NO       * 00760019
*   CHARACTER CODE DEPENDENCE.                                        * 00769019
*                                                                     * 00778019
*********************************************************************** 00787019
***   GENERAL REGISTER EQUATES   ***                                    00800019
**                                                                      01200019
R0       EQU   0              NON-ADDRESSING REG FOR IOSGEN             01400019
R1       EQU   1             MSG INDEX PASSED TO SECOND LOAD            01600019
R2       EQU   2             ADDRESS OF XSA                             02000019
R3       EQU   3             ADDRESS OF CVT                             02400019
R4       EQU   4             WORK REGISTER                              02800019
R5       EQU   5             ADDRESS OF FIRST OPERAND IN COMMAND        03200019
R6       EQU   6             WORK REGISTER                              03600019
R7       EQU   7             WORK REGISTER                              04000019
R8       EQU   8             REGISTER SAVED FOR STAE IMPLEMENTATION     04400019
R9       EQU   9             WORK REGISTER                              04800019
R10      EQU   10            WORK REGISTER                              05200019
R11      EQU   11            WORK REGISTER                              05600019
BASE     EQU   12            ROUTINE BASE ADDRESS                       06000019
R13      EQU   13            WORK REGISTER FOR IOSGEN                   06400019
R14      EQU   14            DO NOT CHANGE--- USED FOR EXIT FROM MSG   X06500019
                                       MODULES IGC0503D AND IGG2103D    06600019
R15      EQU   15            WORK REGISTER                              06800019
***   EQUATES FOR MCS CHECK   ***                                       07200019
*                                                                       07600019
MCS      EQU   X'02'          MCS IN SYSTEM                             08000019
INPSTR   EQU   X'80'          INPUT STREAM COMMAND                      08400019
INTERNL  EQU   X'00'          INTERNAL COMMAND                          08800019
IOAUTH2  EQU   X'40'          I/O AUTHORITY CODE                        09200019
***   EQUATES FOR CUA VALIDITION   ***                                  09600019
*                                                                       10000019
NUMERIC  EQU   X'F0'         NUMERIC MASK FOR CUA DIGITS                10400019
A        EQU   X'C1'          NON-NUMERIC BOUNDS                        10800019
F        EQU   X'C6'                             FOR VALID CUA DIGITS   11200019
C        EQU   C'C'          LOW BOUND FOR SUBSELECTOR CHANNEL ADDR     11400019
COMMA    EQU   C','           COMMA DELIMITER IN COMMAND                11600019
BLANK    EQU   C' '           BLANK                                     12000019
CPUA     EQU   C'A'          CPUID A                                    12400019
CPUB     EQU   C'B'          CPUID B                                    12800019
***   OTHER EQUATES   ***                                               13200019
ZERO     EQU   0             DISPLACEMENT VALUE                         14000019
ONE      EQU   1             DISPLACEMENT VALUE                         14400019
TWO      EQU   2             DISPLACEMENT VALUE                         14800019
THREE    EQU   3             DISPLACEMENT VALUE                         15200019
FOUR     EQU   4             DISPLACEMENT VALUE                         15600019
FIVE     EQU   5             DISPLACEMENT VALUE                         16000019
SIX      EQU   6              DISPLACEMENT VALUE                        16400019
SEVEN    EQU   7              DISPLACEMENT VALUE                        16800019
EIGHT    EQU   8             DISPLACEMENT VALUE                         17200019
NINE     EQU   9             VALUE DISPLACEMENT                         17600019
TEN      EQU   10            DISPLACEMENT VALUE                         17700019
ELEVEN   EQU   11             DISPLACEMENT VALUE                        17800019
TWELVE   EQU   12            VALUE DISPLACEMENT                         18000019
THIRTN   EQU   13            VALUE DISPLACEMENT                         18400019
FOURTN   EQU   14            DISPLACEMENT VALUE                         18800019
TWENTY   EQU   20        DISPLACEMENT VALUE                             19200019
TWENTONE EQU   21            DISPLACEMENT VALUE                         19600019
TWENTY8  EQU   28            MESSAGE INDEX OF BRANCH TABLE IN IGC3403D  20000019
THIRTY2  EQU   32            MESSAGE INDEX OF BRANCH TABLE IN IGC3403D  20400019
THIRTY6  EQU   36            MESSAGE INDEX OF BRANCH TABLE IN IGC3403D  20800019
*                                                                       21200019
         BALR  BASE,ZERO           ESTABLISH -                          21600019
         USING *,BASE                     ADDRESSABILITY                22000019
         USING XSADS,R2      SET UP XSA BASE                            22400019
         USING SETCVT,R3      SET ADDRESSABILITY FOR CVT                22600019
         L     R3,CVTPTR     GET ADDRESS  OF CVT                        22800019
         LA    R10,VPATH07   GET ADDRESS OF SECOND LOAD SET UP          23200019
********************************************************************    23600019
*                         MCS AUTHORITY CHECK                      *    24000019
*    THIS ROUTINE WILL CAUSE THE COMMAND TO BE REJECTED UNLESS     *    24400019
*    IT COMES THROUGH A CONSOLE AUTHORIZED FOR I/O COMMAND,        *    24800019
*    OR THE INPUT STREAM                                           *    25200019
********************************************************************    25600019
         L     R4,CVTCUCB    GET ADDRESS OF UCM BASE                    26000019
         USING UCMDS,R4      SET ADDRESSABILITY FOR UCM BASE            26400019
         TM    UCMMODE,MCS    IS MCS IN SYSTEM                          26800019
         BNO   VPATH00        NO                                        27200019
         TM    XAU,INPSTR     IS COMMAND FROM INPUT STREAM              27600019
         BO    VPATH00        YES, ALLOW                                28000019
         CLI   XAU,INTERNL    IS COMMAND INTERNAL                       28400019
         BE    VPATH00A      YES,GO SET UP ERROR MESSAGE                28800019
         SR    R9,R9          CLEAR REGISTER                            29200019
         IC    R9,XAU         GET UCM ENTRY INDICATOR AND               29600019
         BCTR  R9,ZERO       SUBTRACT ONE                               30000019
         L     R7,UCMVEZ      GET SIZE OF UCM ENTRIES                   30400019
         MR    R6,R9          FIND UCM ENTRY DISPLACEMENT AND           30800019
         A     R7,UCMVEA      ADD TO FIRST ENTRY ADDRESS                31200019
         DROP  R4                                                       31600019
         USING UCMDS,R7      SET ADDRESSABILITY FOR UCM ENTRY           32000019
         TM    UCMAUTH,IOAUTH2 IS CONSOLE AUTHORIZED                    32400019
         BO    VPATH00       YES,GO DISABLE                             32800019
VPATH00A LA    R1,THIRTY6   SET MESSAGE INDEX FOR BRANCH TABLE          33200019
         BR    R10           GO SET UP FOR XCTL TO NEXT LOAD            33600019
VPATH00  EQU   *                                                        34000019
*******************************************************************     34800019
*     IEE3203D HAS ALREADY SCANNED FOR THE FIRST TWO DELIMITORS    *    34900019
*     AND KEYWORD - ,PATH, - BEFORE PASSING CONTROL TO IGF24MPD.   *    35000019
*     THE COMMAND IS CHECKED FOR PROPER FORMAT, AND IF THERE IS   *     35200019
*     A SYNTAX ERROR, A MESSAGE IS SET UP                         *     35600019
*******************************************************************     36000019
         L     R5,XAL        POINT TO FIRST OPERAND OF COMMAND          36400019
         LA    R13,VPATH05B  GET ADDRESS FOR PATH NON-EXIST MSG SET UP  36800019
         L     R7,XAR         POINT TO                                  37200019
         LA    R7,ZERO(R7)    COMMAND BUFFER                            37600019
         AH    R7,ZERO(R7)    COMPUTE END OF BUFFER                     38000019
         CLI   TWELVE(R5),CPUA  IS CPUID A                              40000019
         BE    VPATH01       YES, GO CHECK LAST COMMA                   40400019
         CLI   TWELVE(R5),CPUB  IS CPUID B                              40800019
         BCR   SEVEN,R13     NO, GO TO MSG SET UP                       41200019
VPATH01  CLI   THIRTN(R5),COMMA  IS LAST COMMA PRESENT                  41600019
         BE    VPATH01A      YES, GO CHECK OFF/ON OPERAND               42000019
VPATH03A LA    R1,TWENTY8   SET UP INDEX FOR DELIMITER ERROR MSG        42500019
         BR    R10           GO SET UP FOR XCTL                         42900019
VPATH01A CLC   FOURTN(SIX,R5),ONLINE I0 VARY FOR ONLINE                 43300019
         BNE   VPATH02       NO, GO CHECK OFFLINE                       43600019
         LA    R6,ON          GET ONLINE INDICATOR                      44000019
         LA    R11,TWENTY(R5)  POINT TO BUFFER END                      44400019
         B     VPATH03        GO CHECK END OF BUFFER                    44800019
VPATH02  CLC   FOURTN(SEVEN,R5),OFFLINE IS VARY FOR OFFLINE             45200019
         BE    VPATH02A      YES, GO CHECK END OF MESSAGE               45600019
VPATH02B LA    R1,THIRTY2   SET UP INDEX FOR KEYWORD MISSPELLED MSG     46000019
         BR    R10           GO SET UP FOR XCTL TO NEXT LOAD            46400019
VPATH02A SR    R6,R6          GET OFFLINE INDICATOR                     46800019
         LA    R11,TWENTONE(R5) POINT TO END OF BUFFER                  47200019
VPATH03  CLI   ZERO(R11),BLANK DOES BLANK DELIMIT LAST OPERAND          47600019
         BE    VPATH04       YES, GO FILL PARAMETER LIST                48000019
         CLR   R7,R11         IS BUFFER END THE DELIMITER               48400019
         BNE   VPATH02B      NO, GO SET UP FOR MSG                      48800019
*******************************************************************     50000019
*     THE IOSGEN PARAMETER LIST IS SET UP IN THE XSA AS FOLLOWS-  *     50400019
*      1. THE PATH TO BE VARIED IS VALIDATED,CONVERTED TO HEX,    *     50800019
*         AND FILLED IN                                           *     51200019
*      2. THE ONLINE/OFFLINE INDICATOR IS FILLED IN               *     51600019
*      4. THE PRIMARY PATH(EBCDIC) IS FILLED IN                   *     52000019
*     THE ADDRESS OF THE PARAMETER LIST IS LOADED INTO REGISTER 15*     52400019
*     AND THEN IOSGEN MACRO IS ISSUED                             *     52800019
*******************************************************************     53200019
VPATH04  LA    R9,XAWORK      POINT TO WORK AREA FOR CUA CONVERSION     53600019
         MVC   XAWORK(THREE),NINE(R5)  MOVE PATH TO WORK AREA           54000019
         LA    R4,THREE       SET UP CONTROL REG                        54400019
VPATH05  TM   ZERO(R9),NUMERIC    IS IT NUMERIC                         54800019
         BO    VPATH06            YES   INSPECT NEXT BYTE               55200019
         CLI   ZERO(R9),A     IS IT AN A OR GREATER                     55600019
         BCR   FOUR,R13      NO, GO TO MSG SET UP                       56000019
         CLI   ZERO(R9),F     IS IT F OR LESS                           56400019
VPATH05A BNH   VPATH05C      YES, GO CONVERT DIGIT TO HEX               56800019
VPATH05B LA    R1,TWELVE    SET MESSAGE INDEX FOR BRANCH TABLE          57200019
         BR    R10           GO SET UP FOR XCTL TO NEXT LOAD            57600019
VPATH05C IC    R11,ZERO(R9)        CONVERT-                             58000019
         LA    R11,NINE(R11)          ALPHABETIC-                       58400019
         STC   R11,ZERO(R9)               TO HEX                        58800019
VPATH06  LA    R9,ONE(R9)     UP POINTER TO NEXT DIGIT IN WORK AREA     59200019
         BCT   R4,VPATH05    IF CUA NOT CHECKED, GO TEST NEXT CHAR      59600019
         PACK  XAVARYP(THREE),XAWORK(FOUR) CONVERT PATH TO HEX          59610019
         CLC   TWO(ONE,R5),ELEVEN(R5)  DO UNIT ADDRS MATCH              59630019
         BCR   SEVEN,R13     NO, GO TO MSG SET UP                       59660019
         CLC   ONE(ONE,R5),TEN(R5) DO CONTROL UNIT ADDRS MATCH          59700019
         BE    VPATH06A  YES, GO FINISH PARAMETER LIST                  59750019
         CLC   ZERO(ONE,R5),NINE(R5) DO CHANNEL ADDR2 MATCH             59790019
         BCR   SEVEN,R13     NO, GO TO MSG SET UP                       59850019
*   THE VARY PATH SUBSELECTOR CHANNEL ADDR IS CHECKED BY IOSGEN         59910019
         CLI   ONE(R5),C     IS PRIMARY PATH                            59980019
         BCR   FOUR,R13      SUBSELECTOR                                60050019
         CLI   ONE(R5),F     CHANNEL ADDR                               60120019
         BCR   TWO,R13       VALID                                      60200019
VPATH06A MVC   XAPRIMEP(THREE),ZERO(R5) PUT PRIMARY PATH IN PARAMETER  X60280019
                                                                LIST    60480019
         STC   R6,XAONOFF     SET ONLINE/OFFLINE INDICATOR              60800019
         STC   R6,XAS        SAVE ONLINE-OFFLINE INDICATOR FOR SECOND  X60900019
                                                              LOAD      61000019
         MVC   XACPUID(ONE),TWELVE(R5)  MOVE IN CPU ID                  61200019
         MVI   NOTUSED,NUMERIC PUT 'F0' BEFORE PRIMARY PATH             61500019
         LR    R15,R2        POINT TO PARAMETER LIST FOR IOSGEN         61700019
         SSM   DISABLE        DISABLE SYSTEM MASK                       61900019
         IOSGEN VARY,(R15,R3,R0),(R1,R4,R5,R6,R7,R9,R10,R11,R13),1,    X62000019
               AUTH=IGF24MPD                                            62100019
*********************************************************************   62200019
*    REGISTER 1  CONTAINS THE INDEX USED IN THE NEXT LOAD,          *   62300019
*    IGF34MPD, TO SET UP A MESSAGE INDICATING THE ACTION TAKEN      *   62400019
*    FOR THE VARY PATH COMMAND. CONTROL IS THEN TRANSFERRED TO      *   62500019
*    IGF34MPD.                                                      *   62600019
*********************************************************************   62700019
VPATH07  MVC   XAD(TWELVE),NEXTLOAD  MOVE IN ZERO DCB POINTER AND NEXT *63200019
                                                 XCTL LOAD NAME         63700019
         LA    R15,XAX       GET ADDRESS OF XCTL NAME                   64400019
         ST    R15,XAP       PUT XCTL ADDR IN XAP                       64800019
         XCTL  SF=(E,(R2))    ISSUE XCTL                                65400019
***   CONSTANTS   ***                                                   66000019
ONLINE   DC    CL6'ONLINE'    ONLINE KEYWORD                            67200019
OFFLINE  DC    CL7'OFFLINE'   OFFLINE KEYWORD                           67600019
NEXTLOAD DC    4X'00'         ZERO DCB POINTER FOR XCTL                 67800019
         DC    C'IGC3403D'    NAME OF SECOND LOAD                       68000019
DISABLE  DC    X'00'          DISABLED SYSTEM MASK FOR IOSGEN           68200019
XSADS    DSECT                                                          68400019
         IEEXSA                                                         68800019
         ORG   XSA        RESET ORIGIN TO ZERO                          69200019
* PARAMETER LIST FOR IOSGEN MACRO                                       69600019
XAVARYP  DS    CL2            HEX ADDRESS OF PATH TO BE VARIED(ZZZ)     70000019
XAONOFF  DS    CL1            ONLINE/OFFLINE INDICATOR                  70400019
OFF      EQU   X'00'         OFFLINE INDICATOR                          70800019
ON       EQU   X'04'         ONLINE INDICATOR                           71200019
XACPUID  DS    CL1           CPU ID-A OR B                              71600019
NOTUSED  DS    CL1            NOT USED                                  72000019
XAPRIMEP DS    CL3            EBCDIC ADDRESS OF PRIMARY PATH(XXX)       72400019
*  END OF PARM LIST                                                     72800019
XAWORK   DS    CL4            WORK AREA                                 73800019
SETCVT   DSECT                                                          74800019
         CVT                                                            75200019
UCMDS    DSECT                                                          75600019
**  DISPLACEMENTS FOR UCM BASE                                          76000019
         DS    17F            GET DISPLACEMENT TO UCMMODE               76400000
UCMMODE  DS    F             MODE FOR CONSOLES--MCS                     76800019
UCMVEA   DS    F             FIRST UCM ENTRY                            77200019
UCMVEZ   DS    F             ENTRY SIZE FOR UCM                         77600019
**  DISPLACEMENTS FOR UCM ENTRY                                         78000019
         ORG   UCMDS          RESET ORIGIN TO ZERO                      78400019
         DS    10F            GET DISPLACEMENT TO UCMAUTTH              78800019
UCMAUTH  DS    CL1           COMMAND CODE AUTHORIZATION                 79200019
   END                                                                  79600019
