IGF2503D CSECT                                                          00100021
         TITLE 'IGF2503D'                                               00200021
*********************************************************************** 00300021
*                                                                     * 00400021
*                       INTRODUCTORY COMMENTS                         * 00500021
*                                                                     * 00600021
*STATUS -- RELEASE 21.6                                               * 00700021
*                                                                     * 00800021
*FUNCTION -- THE MODULE'S PRIMARY FUNCTION IS TO PROCESS THE SWAP     * 00900021
*   COMMAND (OPERATOR-INITIATED DDR).  FOR A SWAP ON/OFF COMMAND, THE * 01000021
*   'DDRON' FLAG IN THE I/O RMS COMMUNICATIONS AREA IS SET TO REIN-   * 01100021
*   STATE/CANCEL FURTHER PROCESSING OF SYSTEM-INITIATED DDR'S. FOR    * 01200021
*   A SWAP DEVICES COMMAND, THE MODULE VERIFIES THE COMMAND, AND      * 01300021
*   INITIALIZES THE I/O RMS COMMUNICATIONS AREA. IT POSTS THE DDRECB  * 01400021
*   TO ACTIVATE THE RMSTCB FOR FURTHER PROCESSING OF THE SWAP IN      * 01500021
*   IGC0108E.                                                         * 01600021
*                                                                     * 01900021
*ENTRY POINTS --                                                      * 02000021
*        IGF2503D -- FIRST INSTRUCTION                                * 02100021
*                                                                     * 02200021
*INPUT -- FOR COMMAND PROCESSING, ENTRY IS FROM IGC0503D.             * 02300021
*   IF ENTRY IS FROM IGC0503D, REGISTER 2  CONTAINS THE  ADDRESS      * 02500021
*   OF THE SVRB EXTENDED SAVE AREA.                                   * 02600021
*                                                                     * 03200021
*OUTPUT -- IF ENTRY WAS FROM IGC0503D, REGISTER 2 REMAINS UNCHANGED.  * 03300021
*                                                                     * 03800021
*EXTERNAL REFERENCES -- ADDRESSES AND FLAG FIELDS FOUND IN THE I/O    * 03900021
*   RMS COMMUNICATIONS AREA. THE ADDRESS OF THE I/O RMS COMMUNICA-    * 04000021
*   TIONS AREA IS FOUND IN THE FIRST WORD OF THE SYS1.LOGREC DCB      * 04100021
*   WHICH IS ACCESSED FROM THE CVT.                                   * 04200021
*                                                                     * 04300021
*EXITS,NORMAL --                                                      * 04400021
*        SVC 3                                                        * 04500021
*        XCTL TO IGC0503D                                             * 04600021
*        XCTL TO IGG2103D                                             * 04700021
*                                                                     * 04800021
*EXITS,ERROR --                                                       * 04900021
*        NONE                                                         * 05000021
*                                                                     * 05100021
*TABLES/WORK AREAS -- I/O RMS COMMUNCATIONS AREA AND THE SVRB         * 05200021
*   EXTENDED SAVE AREA.                                               * 05300021
*                                                                     * 05400021
*ATTRIBUTES -- REFRESHABLE                                            * 05500021
*                                                                     * 05600021
*NOTES -- THIS MODULE USES A PRIVATE MACRO, IORMSCOM, TO MAP          * 05700021
*   THE I/O RMS COMMUNICATIONS AREA. THERE IS NO CHARACTER CODE       * 05800021
*   DEPENDENCE.                                                       * 05900021
*                                                                     * 06000021
* UPDATE ACTIVITY                                                       06010021
*                                                                       06020021
*        APAR 67879  IGF2503D IS NOT REENTRANT                    67879 06030021
*                                                                       06040021
*        APAR 68587  UNALLOCATED DEVICE SWAP PERMITTED            68587 06050021
*                                                                       06060021
*                                                                     * 06100021
*********************************************************************** 06200021
PARMR0   EQU   0             PARAMETER REGISTER                         06300021
R1       EQU   1             WORK REG                                   06400021
XSAB     EQU   2             XSA BASE                                   06500021
R2       EQU   XSAB          REG FOR TAPE REPOSITION'S XSA BASE         06600021
CVTB     EQU   3             CVT BASE                                   06700021
R4       EQU   4             WORK REG                                   06800021
R5       EQU   5             BAL REG                                    06900021
R6       EQU   6              WORK REG                                  07000021
R7       EQU   7             WORK REG                                   07100021
R8       EQU   8             REG FOR STAE IMPLEMENTATION                07200021
R9       EQU   9             WORK REG                                   07300021
TOUCB    EQU   9             ADDRESS OF TO CUA                          07400021
FMUCB    EQU   10            ADDRESS OF 'FROM' CUA                      07500021
COMR     EQU   11            IORMS COMMUNICATIONS BASE                  07600021
BASE     EQU   12            ROUTINE BASE                               07700021
R13      EQU   13            CUA PTR                                    07800021
R14      EQU   14             DO NOT CHANGE -- USED AS EXIT ADDRESS BY *07900021
                                     MASTER SCHEDULER MODULES           08000021
R15      EQU   15            WORK REG                                   08100021
**  E Q U A T E S    F O R   S Y N T A X    C H E C K  **               08200021
COMMA    EQU   C','          COMMA DELIMITER                            08300021
BLANK    EQU   C' '          BLANK DELIMITER                            08400021
NUMBER   EQU   C'0'          VALID NUMERIC DIGIT                        08500021
SIX      EQU   C'6'          VALID CHANNEL LIMIT                        08600021
F        EQU   C'F'          VALID NON-                                 08700021
A        EQU   C'A'                    NUMERIC RANGE                    08800021
**                                                                      08900021
**  E Q U A T E S   FOR   U C B  **                                     09000021
SRTEJBNR EQU   0                       INTERNAL JOB NUMBER DISP         09050021
PASSEDDS EQU   X'03'                   PASSED D.S. ON VOL FLAGS         09060021
SRTESTAT EQU   3              STATUS BYTE A DISPLACEMENT                09100021
PERMRES  EQU   X'04'                   VOL. IS PERM RESIDENT FLSG       09150021
ALLOC    EQU   X'08'          DEVICE IS ALLOCATED                       09200021
SYSRESDV EQU   X'02'          DEVICE IS SYSRES                          09300021
UCBFLG1  EQU   6              UCB FLAG 1 DISPLACEMENT                   09400021
NOTREADY EQU   X'40'          DEVICE IS NOT READY                       09500021
UCBTYPE  EQU   16             MODEL CODE FLAGS                          09600021
OPTFEAT  EQU   17             OPTIONAL FEATURES DISPLACEMENT            09700021
SEVENTR  EQU   X'80'          SEVEN TRACK COMPATIBILITY (2400)          09800021
SHARE    EQU   X'20'         DEVICE IS SHARED                           09900000
SVC34    EQU   34                       SVC 34                    37148 10000021
DUALDENS EQU   X'20'          DUAL-DENSITY (2400)                       10100021
PECODE   EQU   X'04'          PHASE-ENCODE CODED                        10200021
DEVTYPE  EQU   18            DEVICE TYPE INFO                           10300021
DATACELL EQU   X'05'                    DATA CELL INDICATOR       40763 10400021
BINALLOC EQU   X'08'                    ALLOCATION INDICATOR      40763 10500021
TAPE     EQU   X'80'          DEVICE IS TAPE                            10600021
DASD     EQU   X'20'          DEVICE IS DASD                            10700021
RDRPUNCH EQU   X'06'              SUPPORTED READERS AND PUNCHES   21088 10800021
PIKE     EQU   X'0C'              SUPPORTED 3525 PUNCH            21088 10900021
UNITTYPE EQU   19             UNIT TYPE DISPLACEMENT                    11000021
UNITREC  EQU   X'08'                    DEVICE IS UNIT RECORD           11100021
TP2400   EQU   X'01'          TAPE IS 2400 SERIES                       11200021
TP3400   EQU   X'03'                    TAPE IS 3400 SERIES             11300021
A2314    EQU   X'08'          DEVICE IS 2314                            11400021
A2321    EQU   X'05'          DEVICE IS 2321                            11500021
A2311    EQU   X'01'          DEVICE IS 2311                            11600021
A3330    EQU   X'09'                    DEVICE IS 3330                  11700021
PRINTER1 EQU   X'08'         SUPPORTED                                  11800021
PRINTER2 EQU   X'0A'                    PRINTERS                        11900021
NOPATHS  EQU   X'01'                    NO PATHS TO DEVICE BIT    46458 11950000
UCBNALOC EQU   X'04'               NOT ALLOCATABLE FLAG                 11960021
ONLINE   EQU   X'80'               DEVICE ONLINE                        11970021
MNTMSG   EQU   X'80'               MOUNT PENDING INDICATOR        58404 11980021
**                                                                      12000021
** O T H E R    E Q U A T E S  **                                       12100021
MCS      EQU   X'02'          MCS IN SYSTEM                             12200021
INPSTR   EQU   X'80'          INPUT STREAM COMMAND                      12300021
INTERNL  EQU   X'00'          INTERNAL COMMAND                          12400021
IOAUTH2  EQU   X'40'          I/O AUTHORITY CODE                        12500021
DDRINSYS EQU   X'20'          DDR IS IN SYSTEM                          12600021
FF       EQU   X'FF'         COMPOSITE DDR FLAG MASK                    12700021
EXITSVC  EQU   3              SVC 3 FOR EXIT                            12800021
MSG07    EQU   7             MESSAGE NUMBER                             12900021
MSG11    EQU   11            MESSAGE NUMBER                             13000021
MSG13    EQU   13            MESSAGE NUMBER                             13100021
MSG26    EQU   26            MESSAGE NUMBER                             13200021
MSG36    EQU   36            LOWEST MSG INDEX FOR IGG2103D              13300021
MSG41    EQU   41            MESSAGE NUMBER                             13400021
MSG50    EQU   50            MESSAGE NUMBER                             13500021
MSG51    EQU   51            MESSAGE NUMBER                             13600021
MSG52    EQU   52            MESSAGE NUMBER                             13700021
N0       EQU   0             DISPLACEMENT VALUE                         13800021
N1       EQU   1             DISPLACEMENT VALUE                         13900021
N2       EQU   2             DISPLACEMENT VALUE                         14000021
N3       EQU   3             DISPLACEMENT VALUE                         14100021
N4       EQU   4             DISPLACEMENT VALUE                         14200021
N5       EQU   5             DISPLACEMENT VALUE                         14300021
N6       EQU   6             DISPLACEMENT VALUE                         14400021
N7       EQU   7             DISPLACEMENT VALUE                         14500021
N8       EQU   8             DISPLACEMENT VALUE                         14600021
N10      EQU   10                  DISPLACEMENT VALUE                   14650021
N13      EQU   13            DISPLACEMENT VALUE                         14700021
N16      EQU   16            DISPLACEMENT VALUE                         14800021
N17      EQU   17            DISPLACEMENT VALUE                         14900021
N18      EQU   18            DISPLACEMENT VALUE                         15000021
N19      EQU   19            DISPLACEMENT VALUE                         15100021
N20      EQU   20             DISPLACEMENT VALUE                        15200021
N24      EQU   24                                                       15300021
N28      EQU   28                       DISPLACEMENT VALUE              15400021
N35      EQU   35                  DISPLACEMENT FOR MOUNT PENDING 58404 15450021
N59      EQU   59                       DISPLACEMENT VALUE              15500021
         BALR  BASE,N0         ESTABLISH ROUTINE                        15600021
         USING *,BASE             ADDRESSABILITY                        15700021
         USING XSADS,XSAB    SET UP XSA BASE                            15800021
         USING SETCVT,CVTB    SET BASE FOR CVT                          15900021
         USING  IORMS,COMR   SET IORMS COMM AREA BASE                   16000021
         L     CVTB,CVTPTR   GET ADDRESS OF CVT                         16100021
         L     COMR,CVTDCB   POINT TO DCB FOR SYS1LOG REC               16200021
         L     COMR,N0(COMR)   POINT TO IORMS COMMUNICATIONS REGION     16250021
         TM    CVTOPTA,DDRINSYS        IS DDR IN SYST.            50262 16300021
         BZ    ERRM5                   NO,ISSUE'UNSUPPORTED' MSG  50262 16350021
********************************************************************    18000021
*                         MCS AUTHORITY CHECK                      *    18100021
*    THIS ROUTINE WILL CAUSE THE COMMAND TO BE REJECTED UNLESS     *    18200021
*    IT COMES THROUGH A CONSOLE AUTHORIZED FOR I/O COMMAND         *    18300021
********************************************************************    18400021
SWAP00   L     R4,CVTCUCB    GET ADDRESS OF UCM BASE                    18500021
         USING UCMDS,R4      SET ADDRESSABILITY FOR UCM                 18600021
         TM    UCMMODE,MCS    IS MCS IN SYSTEM                          18700021
         BNO   SWAP01         NO                                        18800021
         TM    XAU,INPSTR     IS COMMAND FROM INPUT STREAM              18900021
         BO    ERRM8          YES, REJECT COMMAND                       19000021
         CLI   XAU,INTERNL    IS COMMAND INTERNAL                       19100021
         BE    ERRM8         YES, REJECT COMMAND                        19200021
         SR    R9,R9          CLEAR REGISTER                            19300021
         IC    R9,XAU         GET UCM ENTRY INDICATOR AND               19400021
         BCTR  R9,N0         SUBTRACT ONE                               19500021
         L     R7,UCMVEZ      GET SIZE OF UCM ENTRIES                   19600021
         MR    R6,R9          FIND UCM ENTRY DISPLACEMENT AND           19700021
         A     R7,UCMVEA      ADD TO FIRST ENTRY ADDRESS                19800021
         MVC   CNSLID(N1),XAU    SAVE CONSOLE ID IN COMM REGION         19900021
         DROP  R4                                                       20000021
         USING UCMDS,R7      SET ADDRESSABILITY FOR UCM ENTRY           20100021
         TM    UCMAUTH,IOAUTH2  IS CONSOLE AUTHORIZED                   20200021
         BNO   ERRM8          NO, REJECT COMMAND                        20300021
*********************************************************************** 20400021
*      CHECK TO SEE IF COMMAND IS IN PROPER FORMAT                    * 20500021
*********************************************************************** 20600021
SWAP01   EQU   *                                                        20700021
         L     R13,XAL        POINT TO 1ST OPERAND CHAR IN PARM LIST    20900021
         LA    R13,N0(R13)    ZERO HIGH BYTE                            21000021
         LTR   R13,R13        IS PARM PTR ZERO                          21100021
         BZ    ERRM1          YES, ISSUE 'PARM MISSING' MSG             21200021
          LR     R8,R13                 SAVE BUFFER ADDR IN R8    67879 21250021
         L     R7,XAR         POINT TO BUFFER CONTAINING COMMAND        21300021
         LA    R7,N0(R7)       ZERO HIGH ORDER BYTE                     21400021
         LH    R6,N0(R7)      GET BUFFER LENGTH                         21500021
         AR    R7,R6          COMPUTE BUFFER END ADDR                   21600021
         ST    R7,XAP                         AND SAVE IT               21700021
         CLC   N0(N2,R13),ON  IS COMMAND'SWAP ON'                       21800021
         BNE   SWAP03         NO                                        21900021
         LA    R4,N2(R13)     POINT TO END OF COMMAND                   22000021
         BAL   R5,SWAP06      TEST DELIMITER                            22100021
         OI    DDRFLGSA,DDRON  SET SWAP ON BIT                          22200021
*****************************************************************       22260021
*               CLEAR COMMAND BUFFER AND EXIT                   *       22270021
*****************************************************************       22280021
CLEARBUF  LR     R13,R8              GET CMND. BUFF. ADDR. IN R13 67879 22292021
         XC    N0(N7,R13),N0(R13)  AND CLEAR OUT THE BUFFER             22294021
         SVC   EXITSVC             EXIT                                 22300021
SWAP03   CLC   N0(N3,R13),OFF IS COMMAND 'SWAP OFF'                     22400021
         BNE   SWAP04        NO,GO CHECK COMMA                          22500021
         LA    R4,N3(R13)     POINT TO END OF COMMAND                   22600021
         BAL   R5,SWAP06      TEST DELIMITER                            22700021
         NI    DDRFLGSA,FF-DDRON  SET DDR ON SWITCH OFF                 22800021
         B     CLEARBUF            CLEAR BUFFER AND EXIT                22900021
SWAP04   CLI   N3(R13),COMMA  DOES COMMA DELIMIT FIRST OPERAND          23000021
         BE    SWAP05        YES                                        23100021
         CLI   N3(R13),BLANK    IS DELIMITER BLANK                      23200021
         BNE   ERRM3         NO,ISSUE 'DELIMIT ERROR' MSG               23300021
SWAP05   LA    R4,N7(R13)    POINT TO END OF COMMAND                    23400021
         LA    R5,SWAP07      GET RETURN ADDRESS                        23500021
SWAP06   CLI   N0(R4),BLANK   DOES BLANK DELIMIT LAST OPERAND           23600021
         BCR   N8,R5         YES                                        23700021
         C     R4,XAP         IS THIS BUFFER END                        23800021
         BNE   ERRM3         NO,ISSUE 'DELIMIT ERROR' MSG               23900021
         BR    R5             CONTINUE TESTING                          24000021
*******************************************************************     24300021
*    TEST IF 'FROM' CUA IS VALID AND SUPPORTED BY DDR             *     24400021
*******************************************************************     24500021
SWAP07   BAL   R5,SWAP50      TEST 'FROM' CUA                           24600021
         LR    FMUCB,R9      SAVE 'FROM' UCB ADDR                       24700021
          TM     SRTESTAT(FMUCB),ALLOC IS DEVICE ALLOCATED?       68587 24750021
          BZ     ERRM6        NO, DEV UNALLOCATED MESSAGE         68587 24760021
         CLI   N19(FMUCB),A2321    IS DEVICE A DATA CELL ?              24770021
         BNE   CHKNALOC            NO,CONTINUE TESTING                  24780021
         LA    R9,N59(FMUCB)       GET PTR TO BIN ZERO                  24790021
         LA    R7,N10              INIT COUNT FOR BIN SEARCH            24790421
CHKBIN   TM    N0(R9),BINALLOC     IS BIN ALLOCATED ?                   24792021
         BO    CHKNALOC            YES, CHK IF UNALLOCATABLE            24794021
         LA    R9,N16(R9)          NO,POINT TO NEXT BIN                 24796021
         BCT   R7,CHKBIN           GO LOOK AT NEXT BIN                  24798021
         B     ERRM6               NO BINS ALLOCATED, ISSUE MSG         24798421
CHKNALOC TM    N1(FMUCB),UCBNALOC  IS DEVICE UNALLOCATABLE ?            24798821
         BO    ERRM4               YES,ISSUE DEVICE TYPE INVALID MSG    24799221
         TM    SRTESTAT(FMUCB),ONLINE  IS DEVICE ONLINE ?               24799621
         BNO   ERRM4               NO,ISSUE DEV TYPE INVALID MSG        24799721
         SR    R6,R6          INITIALIZE FOR DASD/UNIT RECORD DDR INDEX 24800021
         CLI   DEVTYPE(FMUCB),TAPE      IS FROM DEVICE TAPE             24900021
         BNE   SWAP08        NO, GO CHECK DASD                          25000021
         TM    N35(FMUCB),MNTMSG   IS A MOUNT OUTSTANDING         58404 25050021
         BO    ERRM4               YES, INVALID FOR SWAP          58404 25060021
         LA    R6,N4          RESET FOR TAPE DDR INDEX                  25100021
         CLI   UNITTYPE(FMUCB),TP2400  IS IT A 2400 SERIES TAPE         25200021
         BE    SWAP12                   YES-CHK IF FROM IS ALLOC  21048 25300021
         CLI   UNITTYPE(FMUCB),TP3400   IS IT A 3400 TAPE         21048 25400021
         BNE   ERRM4          NO, SEND UNSUPPORTED DEVICE MESSAGE       25500021
         B     SWAP12        GO CHECK IF FROM IS ALLOCATED              25600021
*                                                                       25650000
***      DASD DEVICES SUPPORTED ARE 2311, 2314, 2321, 3330.             25660000
****     2311 IS DEFINED AS X'01' IN UCB. ALL OTHERS ARE                25670000
***      DEFINED AS X'05' OR HIGHER AS OF RELEASE 21.                   25680000
*                                                                       25690000
SWAP08   CLI   DEVTYPE(FMUCB),DASD      IS FROM DEVICE DASD             25700021
         BNE   SWAP10        NO, GO CHECK UNIT RECORD                   25800021
         TM    N35(FMUCB),MNTMSG   IS A MOUNT OUTSTANDING         58404 25850021
         BO    ERRM4               YES, INVALID FOR SWAP          58404 25860021
*                                                                       25870021
         CLI   UNITTYPE(FMUCB),A2311    IS IT A 2311                    25900021
         BE    SWAP09        YES, GO CHECK IF SYSRES                    26000021
         CLI   UNITTYPE(FMUCB),A2321    IS IT A 2321                    26100021
         BE    SWAP09                   YES, GO CHECK FOR SYSRES   2524 26110000
         CLI   UNITTYPE(FMUCB),A2314    IS IT A 2314               2524 26120000
         BL    ERRM4                    NO, GO ISSUE UNSUPPORTED MSG    26150000
SWAP09   TM    SRTESTAT(FMUCB),SYSRESDV  IS FROM DEVICE SYSRES          26800021
         BZ    SWAP12        NO, GO CHECK IF FROM ALLOCATED             26900021
         TM    DDRFLGSA,SYSRESOP  IS SYSRES OPTION PRESENT              27000021
         BZ    ERRM5A         NO, ISSUE  DDRSYSR NOT SUPPORTED MSG      27100021
         B     SWAP13        GO CHECK TO DEVICE                         27200021
SWAP10   CLI   DEVTYPE(FMUCB),UNITREC   IS FROM DEVICE UNIT RECORD      27300021
         BNE   ERRM4      NO, GO TO ISSUE UNSUPPORTED DEVICE MESSAGE    27400021
*  THE FOLLOWING READERS/PUNCHES ARE SUPPORTED - 1442,2501,2520,2540,   27500021
*                                                3505,3525        21088 27600021
         CLI   UNITTYPE(FMUCB),RDRPUNCH IS DEVICE SUPPORTED RDR-PUNCH   27700021
         BNH   SWAP11        YES,CHECK READY CONDITION                  27800021
         CLI   UNITTYPE(FMUCB),PIKE  IS DEVICE  3525 PUNCH        21088 27900021
         BE    SWAP11             YES, CHECK READY CONDITION      21088 28000021
         CLI   UNITTYPE(FMUCB),PRINTER1 IS DEVICE SUPPORTED PRINTER     28100021
         BE    SWAP11        YES,CHECK READY CONDITION                  28200021
         CLI   UNITTYPE(FMUCB),PRINTER2 IS DEVICE SUPPORTED PRINTER     28300021
         BH    ERRM4                    NO, SET UP ERROR MSG            28450000
SWAP11   TM    UCBFLG1(FMUCB),NOTREADY  IS DEVICE SET NOT READY         28500021
         BZ    ERRM4         NO, GO SET UP ERROR MSG                    28600021
SWAP12   EQU   *                                                        28650021
         TM    SRTESTAT(FMUCB),PERMRES IS VOL PERM RESIDENT       41729 28660021
         BO    ERRM4                   YES,ISSUE'INVALID' MSG     41729 28670021
*******************************************************************     30000021
*    TEST IF 'TO' CUA IS VALID AND OF THE SAME DEVICE TYPE AS     *     30100021
*    THE 'FROM' CUA                                               *     30200021
*  DEVICE TYPE FIELDS FOR DASD AND UNIT RECORD DEVICES MUST BE    *     30300021
*  EXACTLY THE SAME.                                              *     30400021
*  FOR TAPE, ONLY THE FOLLOWING COMBINATIONS ARE VALID-           *     30500021
*  1. FROM 7-TRACK , TO 7-TRACK                                   *     30600021
*  2. FROM 9-TRACK 800 BPI, TO 9-TRACK 800 BPI                    *     30700021
*  3. FROM 9-TRACK 1600 BPI, TO 9-TRACK 1600 BPI                  *     30800021
*  4. FROM 9-TRACK DUAL DENSITY, TO 9-TRACK DUAL DENSITY          *     30900021
*  5. FROM 9-TRACK DUAL DENSITY, TO 9-TRACK 800 BPI               *     31000021
*  6. FROM 9-TRACK DUAL DENSITY, TO 9-TRACK 1600 BPI              *     31100021
*******************************************************************     31200021
SWAP13    LA   R13,N4(R13)     POINT TO 'TO' CUA                        31300021
SWAP14   BAL   R5,SWAP50      TEST 'TO' CUA                             31400021
         CLR   FMUCB,TOUCB   IS SWAP TO ITSELF                          31500021
         BE    SWAP22        YES, HAS SYS INIT DDR STARTED              31600021
         TM    CVTDCB,CVT4MPS           IS THIS MP                46458 31650000
         BZ    SWAP15                 NO, CHECK IF FROM IS TAPE   46458 31660021
         LR    R7,TOUCB                 SAVE 'TO' UCB POINTER     46458 31670000
         BCTR  R7,0                     SUBTRACT 1 FROM ADDR      46458 31680000
         TM    N0(R7),NOPATHS           ARE THERE PATHS TO DEVICE 46458 31690000
         BO    ERRM4                    NO, ISSUE INVALID MSG     46458 31692000
SWAP15   CLI   DEVTYPE(FMUCB),TAPE  IS 'FROM' TAPE ?                    31692421
         BE    SWAP22              YES, CHECH IF DDR ALREADY ACTIVE     31692821
         CLI   DEVTYPE(FMUCB),DASD  IS 'FROM' DASD ?                    31693221
         BNE   SWAP16              NO,CHK IF DEVICE TYPES THE SAME      31693621
         TM    N35(TOUCB),MNTMSG   IS A MOUNT OUTSTANDING         58404 31696621
         BO    ERRM4               YES, INVALID 'TO' DEVICE       58404 31698621
         TM    OPTFEAT(FMUCB),SHARE IS FROM DEVICE SHARED               31700021
         BO    ERRM4               YES,ISSUE INVALID DEV TYPE MSG       31703021
         TM    OPTFEAT(TOUCB),SHARE IS 'TO' DEVICE SHARED ?             31706021
         BO    ERRM4               YES,ISSUE INVALID DEV TYPE MSG       31709021
         TM    SRTESTAT(TOUCB),SYSRESDV  IS 'TO' SYSRES ?               31719021
         BO    ERRM4               YES,ISSUE INVALID DEV TYPE MSG       31721021
         TM    SRTESTAT(TOUCB),PERMRES   IS VOL.PERM.RESIDENT     41729 31754721
         BO    ERRM4                   YES,ISSUE'INVALID' MSG     41729 31769821
SWAP16   CLC   DEVTYPE(N2,FMUCB),DEVTYPE(TOUCB) ARE DEVICE TYPES SAME   31784921
         BNE   ERRM4               NO,ISSUE INVALID DEV TYPE MSG        31800021
*****************************************************************       31850021
*  THE FOLLOWING CHKS TO INSURE THAT OPTIONAL FEATURES ARE THE SAME     31860021
*****************************************************************       31870021
         CLI   DEVTYPE(FMUCB),DASD      IS THIS SWAP FOR DASD     21048 31900021
         BE    CHKOPTA                  YES , CHECK   OPTIONS     21048 32000021
* FOR DASD BYTE 17 IS COMPARED                                          34800021
*  FOR UNITRECORD-- BYTES 16 AND 17 ARE COMPARED FOR READ-PUNCH COMPARE 35000021
         CLC   UCBTYPE(N1,FMUCB),UCBTYPE(TOUCB) ARE BYTES 16 SAME       35100021
         BNE   ERRM4         NO, GO SEND ERROR MSG                      35200021
CHKOPTA  CLC   OPTFEAT(N1,FMUCB),OPTFEAT(TOUCB)  ARE BYTES 17 SAME      35300021
         BNE   ERRM4       NO, SEND ERROR MESSAGE                       35400021
*******************************************************************     35500021
*    PREPARATION FOR EXIT-               FOR NORMAL PRO-          *     35600021
*    CESSING OF THE SWAP COMMAND, BOTH UCB ADDRESS ARE STORED IN  *     36000021
*    THE IORMS COMMUNICATIONS REGION, OPERATOR-INITIATED SWAP     *     36100021
*    FLAG SET ON,DDRECB POSTED, AND THE COMMAND PROCESSOR EXITS   *     36200021
*******************************************************************     36300021
SWAP22   TM    DDRFLGSA,DDRBUSY HAS SYSTEM-INIT DDR STARTED             36900021
         BO    ERRM7         YES,GO SET UP MSG                          37000021
         OI    DDRFLGSA,DDRBUSY+OPINIT  SET DDR BUSY AND OPERATOR-     *37100021
                                      INITIATED DDR FLAGS               37200021
         STH   FMUCB,DDRFMUCB  PUT FROM DEVICE UCB AND                  37300021
         STH   TOUCB,DDRTOUCB  TO DEVICE UCB IN IORMS COMM AREA         37400021
         STC   R6,DDRFLGSB    SET INDEX FOR SVC 85 INDEX                37500021
         POST   DDRECB       POST DDRECB FOR IORMSTCB                   37600021
         B     CLEARBUF        EXIT                                     37700021
*********************************************************************** 37800021
*   SUBROUTINE WHICH VALIDATES THE CUA'S AND SCANS THE UCBLIST TO     * 37900021
*    FIND IF THE UCB IS IN THE SYSTEM                                 * 38000021
*********************************************************************** 38100021
SWAP50   LR    R1,R13         SAVE CUA PTR                              38200021
         LA    R4,N3         SET UP BCT REG                             38300021
SWAP51   TM    N0(R1),NUMBER   IS ADDR NUMERIC                          38400021
         BO    SWAP53        YES, GET NEXT CHARACTER                    38500021
         CLI   N0(R1),F      IS ADDR VALID                              38600021
         BH    ERRM2          NO, ISSUE  INVALID CUA MESSAGE            38700021
         CLI   N0(R1),A      IS ADDR VALID                              38800021
         BL    ERRM2          NO, ISSUE  INVALID CUA MESSAGE            38900021
SWAP53   LA    R1,N1(R1)     POINT TO NEXT DIGIT IN CUA                 39000021
         BCT   R4,SWAP51     IF CUATEST FINISHED, GO TO SCAN            39100021
         L     R4,CVTILK2     POINT TO UCB LIST                         39200021
SWAP54   LH    R9,N0(R4)     GET UCB ADDR                               39300021
         LTR   R9,R9          TEST UCB ADDR                             39400021
         BZ    SWAP55         IF ZERO, GO BUMP POINTER                  39500021
         BM    ERRM2          IF NEGATIVE,END OF UCBS AND ISSUE UNIT   X39600021
                                          REFERENCE INVALID MSG         39700021
         CLC   N0(N3,R13),N13(R9)  DO CUAS MATCH                        39800021
         BCR   N8,R5          YES, RETURN MAINLINE                      39900021
SWAP55   LA    R4,N2(R4)      POINT TO NEXT                             40000021
         B     SWAP54                      UCB IN UCB LIST              40100021
* SET RETURN CODE AND RTN TO CALLER                                     40200021
********************************************************************    40300021
*   THE FOLLOWING INSTRUCTIONS PASS A DESIGNATED INDEX CODE TO     *    40400021
*   THE MESSAGE-SETUP SUBROUTINE, SETUPMSG , IN REGISTER EIGHT.    *    40500021
****  ERROR  MESSAGES  ****                                             40600021
**                                                                      40700021
ERRM1    BAL   R5,SWAP71      PARM MISSING                              40800021
         DC    AL1(MSG11)                   MESSAGE                     40900021
**                                                                      41000021
ERRM2    BAL   R5,SWAP70     UNIT REFERENC INVALID                      41300021
         DC    AL1(MSG13)                         MESSAGE               41400021
**                                                                      41500021
ERRM3    BAL   R5,SWAP71      DELIMIT ERROR                             41600021
         DC    AL1(MSG07)                   MESSAGE                     41700021
**                                                                      41800021
ERRM4    BAL   R5,SWAP70     DEVICE TYPE INVALID                        42100021
         DC    AL1(MSG50)                        MESSAGE                42200021
**                                                                      42300021
ERRM5    MVC   XAV(N8),DDRNAME  DDR NOT SUPPORTED                       42400021
         B     ERRM5B        SET MSG CODE                               42500021
ERRM5A   MVC   XAV(N8),SYSRESN  SYSRES NOT SUPPORTED                    42600021
ERRM5B   BAL   R5,SWAP71      GO TO FINISH                              42700021
         DC    AL1(MSG26)                MESSAGE                        42800021
**                                                                      42900021
ERRM6    BAL   R5,SWAP70      DEVICE UNALLOCATED                        43000021
         DC    AL1(MSG51)                        MESSAGE                43100021
**                                                                      43200021
ERRM7    MVC   XAV(N8),DDRNAME  DDRCURRENTLY ACTIVE                     43300021
         BAL   R5,SWAP71      GO TO FINISH                              43400021
         DC    AL1(MSG52)                  MESSAGE                      43500021
**                                                                      43600021
ERRM8     BAL  R5,SWAP71      INVALID                                   43700021
         DC    AL1(MSG41)             AUTHORITY CODE                    43800021
**                                                                      43900021
**                                                                      44000021
*********************************************************************** 44100021
*   SUBROUTINE WHICH USES THE EXTENDED SAVE AREA TO-                  * 44200021
*     1. FILL IN THE VARIABLE MESSAGE (XAV)  AND MESSAGE CODE         * 44300021
*        NUMBER (XAE)                                                 * 44400021
*     2. ISSUE AN XCTL TO THE PROPER MESSAGE MODULE                   * 44500021
*********************************************************************** 44700021
SWAP70   MVC   XAV(N3),N0(R13)   MOVE CUA TO FILL AREA                  44800021
         MVC   XAV+N3(N5),BLANKOUT   BLANKOUT REST OF AREA              44900021
SWAP71   MVC   XAE(N1),N0(R5) INSERT MSG CODE NUMBER                    45000021
         CLI   N0(R5),MSG26   IS MESSAGE FOR IGC0503D                   45100021
         BNH   SWAP73        YES                                        45200021
         MVC   XAX(N8),MSG2103D     MODULE NAME FOR IGG2103D            45300021
SWAP72   SR    R15,R15             SET DCB POINTER                      45400021
         ST    R15,XAD                        TO ZERO                   45500021
         LA    R15,XAX        PUT PTR TO NAME                           45600021
         ST    R15,XAP                        IN LIST                   45700021
         LR    R15,XSAB      POINT TO WORK AREA FOR XCTL                45800021
SWAP72A  XCTL  SF=(E,(15)) XCTL TO EITHER MSG MODULE OR TAPE REPOSITION 46400021
SWAP73   MVC   XAX(N8),MSG0503D     MODULE NAME                         46500021
         B     SWAP72                          FOR IGC0503D             46600021
*******************************************************************     46700021
*        C O N S T A N T S                                            * 46800021
*********************************************************************** 46900021
ON       DC    C'ON'         ON OPERAND FOR SWAP COMMAND                47000021
OFF      DC    C'OFF'        OFF OPERAND FOR SWAP COMMAND               47100021
DDRNAME  DC    C'DDR     '   DDR NAME FOR MSGS                          47200021
SYSRESN  DC    C'DDRSYSRS'   NAME FOR DDR SYSRES                        47300021
BLANKOUT DC    C'        '   BLANKS FOR MSGS                            47400021
MSG2103D DC    C'IGG2103D'   NAMES OF BOTH                              47500021
MSG0503D DC    C'IGC0503D'                       MESSAGE MODULES        47600021
XSADS    DSECT                                                          47800021
         IEEXSA                                                         47900021
         IORMSCOM                                                       48000021
SETCVT    DSECT                                                         48100021
         CVT                                                            48200021
**  DISPLACEMENTS FOR UCM BASE                                          48300021
UCMDS    DSECT                                                          48400021
         DS    17F                                                      48500000
UCMMODE  DS    F             MODE FOR CONSOLES--MCS                     48600021
UCMVEA   DS    F             FIRST UCM ENTRY                            48700021
UCMVEZ   DS    F             ENTRY SIZE FOR UCM                         48800021
**  DISPLACEMENTS FOR UCM ENTRY                                         48900021
         ORG   UCMDS                                                    49000021
         DS    10F                                                      49100021
UCMAUTH  DS    CL1                 COMMAND CODE AUTHORIZATION           49150021
         END                                                            90399400
