         TITLE  'IGF34MPD'                                              00300019
IGF34MPD CSECT                                                          00600019
*********************************************************************** 00610019
*                                                                     * 00620019
*                       INTRODUCTORY COMMENTS                         * 00630019
*                                                                     * 00640019
*STATUS -- RELEASE 19                                                 * 00650019
*                                                                     * 00660019
*FUNCTION -- THIS MODULE IS THE SECOND LOAD OF THE VARY PATH COMMAND  * 00670019
*   PROCESSOR FOR MULTIPROCESSING SYSTEMS. THE FIRST LOAD, IGF24MPD,  * 00680019
*   PROCESSES THE COMMAND AND PASSES AN INDEX CODE TO THIS MODULE.    * 00690019
*   IGF34MPD SETS UP A MESSAGE FOR THE ACTION TAKEN ON THE VARY PATH  * 00700019
*   COMMAND, AND TRANSFERS CONTROL TO THE MESSAGE MODULES (EITHER     * 00710019
*   IGC0503D OR IGG2103D).                                            * 00720019
*                                                                     * 00730019
*ENTRY POINTS --                                                      * 00740019
*        IGF34MPD -- FIRST INSTRUCTION                                * 00750019
*                                                                     * 00760019
*INPUT -- AT ENTRY, REGISTER 1 CONTAINS THE INDEX CODE FOR THE       *  00770019
*   MESSAGE TO BE ISSUED, REGISTER 2 THE ADDRESS OF THE SUVB EXTENDED * 00780019
*   SAVE AREA, AND REGISTER 5 THE ADDRESS OF THE COMMAND OPERANDS     * 00790019
*                                                                     * 00800019
*OUTPUT -- REGISTERS SPECIFIED AT INPUT REMAIN UNCHANGED              * 00810019
*EXTERNAL REFERENCES -- NONE                                          * 00820019
*                                                                     * 00830019
*EXITS,NORMAL --                                                      * 00840019
*        XCTL TO IGC0503D                                             * 00850019
*        XCTL TO IGG2103D                                             * 00860019
*                                                                     * 00870019
*EXITS,ERROR --                                                       * 00880019
*        NONE                                                         * 00890019
*                                                                     * 00900019
*TABLES/WORK AREAS -- EXTENDED SAVE AREA OF SVRB                      * 00910019
*                                                                     * 00920019
*ATTRIBUTES -- REFRESHABLE                                            * 00930019
*                                                                     * 00940019
*NOTES -- THIS MODULE HAS NO CHARACTER CODE DEPENDENCE.               * 00950019
*                                                                     * 00960019
*********************************************************************** 00970019
***   GENERAL REGISTER EQUATES   ***                                    01200019
**                                                                      01800019
R1       EQU   1             INDEX CODE REG FOR VARY PATH MSG TO SET UP 02400019
R2       EQU   2             ADDRESS OF XSA                             03000019
R5       EQU   5             ADDRESS OF FIRST OPERAND IN COMMAND        04800019
R6       EQU   6             WORK REGISTER                              05400019
R8       EQU   8             REGISTER SAVED FOR STAE IMPLEMENTATION     06600019
BASE     EQU   12            ROUTINE BASE ADDRESS                       09000019
R15      EQU   15            WORK REGISTER                              09600019
***   OTHER EQUATES   ***                                               10200019
MSG02    EQU   02            MESSAGE NUMBER                             11400019
MSG03    EQU   03            MESSAGE NUMBER                             12000019
MSG13    EQU   13            MESSAGE NUMBER                             12600019
MSG07    EQU   7             MESSAGE NUMBER                             13200019
MSG09    EQU   9              MESSAGE NUMBER                            13800019
MSG41    EQU   41             MESSAGE NUMBER                            14400019
MSG46    EQU   46            MESSAGE NUMBER                             15000019
MSG47    EQU   47            MESSAGE NUMBER                             15600019
MSG48    EQU   48            MESSAGE NUMBER                             16200019
MSG49    EQU   49            MESSAGE NUMBER                             16800019
ZERO     EQU   0             DISPLACEMENT VALUE                         17400019
ONE      EQU   1             DISPLACEMENT VALUE                         18000019
THREE    EQU   3             DISPLACEMENT VALUE                         19200019
FOUR     EQU   4             DISPLACEMENT VALUE                         19800019
EIGHT    EQU   8             DISPLACEMENT VALUE                         22200019
NINE     EQU   9             VALUE DISPLACEMENT                         22800019
BLANK  EQU  C' '                                                        26400019
         BALR  BASE,ZERO     SET UP BASE                                27000019
         USING *,BASE        ADDRESSABILITY                             27600019
         USING XSADS,R2      BASE FOR XSA                               28200019
         L     R5,XAL         POINT TO FIRST OPERAND OF COMMAND         28800019
*     THE FOLLOWING BRANCH TABLE INDICATES THE ACTION TAKEN BY    *     29400019
*     THE IOSGEN MACRO                                            *     30000019
*******************************************************************     30600019
         B     *+FOUR(R1)         USE CODE FOR ENTRY TO BRANCH TABLE    31200019
         B     VPATH07             ZERO. OPERATION SUCCESSFUL           31800019
         B     VPMSG07             FOUR. CANNOT VARY TELEPROC. OFFLINE  32400019
         B     VPMSG06             EIGHT. CANNOT VARY LAST PATH OFFLINE 33000019
         B     VPMSG08        TWELVE.XXX PATH NONEXISTENT               33600019
         B     VPMSG09        SIXTEEN. ZZZ UCB NOT FOUND                34200019
         B     VPMSG10       TWENTY. CAN NOT VARY,RESERVED SHARED DASD  34800019
         B     VPMSG06A      TWENTYFOUR. ONLY ONE PATH                  35400019
         B     VPMSG01       TWENTYEIGHT. DELIMITER ERROR               36000019
         B     VPMSG02     THIRTYTWO. KEYWORD MISSPELLED                36600019
         B     VPMSG03     THIRTYSIX . INVALID AUTHORITY CODE           37200019
VPATH07  CLI   XAS,ON       IS IT VARY ONLINE                           37800019
         BE    VPMSG04       YES, SET UP ONLINE MSG                     38400019
         B     VPMSG05       NO, GO SET UP OFFLINE MSG                  39000019
********************************************************************    39600019
*   THE FOLLOWING INSTRUCTIONS PASS A DESIGNATED INDEX CODE TO     *    40200019
*   THE MESSAGE-SETUP SUBROUTINE, SETUPMSG , IN REGISTER EIGHT.    *    40800019
********************************************************************    41400019
**                                                                      42000019
VPMSG01  BAL   R15,VPATH21    DELIMITOR ERROR MSG                       42600019
         DC    AL1(MSG07)    MESSAGE INDEX CODE                         43200019
**                                                                      43800019
VPMSG02  BAL   R15,VPATH21    KEYWORD MISSPELLED MSG                    44400019
         DC    AL1(MSG09)     INDEX CODE                                45000019
**                                                                      45600019
VPMSG03  BAL   R15,VPATH21    INVALID                                   46200019
         DC    AL1(MSG41)             AUTHORITY CODE                    46800019
**                                                                      47400019
VPMSG04  BAL   R15,VPATH20   PATH NOW                                   48000019
         DC    AL1(MSG02)             ONLINE MSG                        48600019
**                                                                      49200019
VPMSG05  BAL   R15,VPATH20   PATH NOW                                   49800019
         DC    AL1(MSG03)             OFFLINE MSG                       50400019
**                                                                      51000019
VPMSG06A MVC   NINE(THREE,R5),ZERO(R5)     SET UP MSG                   51600019
VPMSG06  BAL   R15,VPATH20   LAST PATH NOT                              52200019
         DC    AL1(MSG46)                  VARIED MSG                   52800019
**                                                                      53400019
VPMSG07  BAL   R15,VPATH20   TP PATH NOT                                54000019
         DC    AL1(MSG47)               VARIED MSG                      54600019
**                                                                      55200019
VPMSG08  BAL   R15,VPATH20    PATH XXX DOES NOT EXIST                   55800019
         DC    AL1(MSG48)                     MESSAGE                   56400019
**                                                                      57000019
VPMSG09  MVC   XAV(THREE),ZERO(R5) UNIT                                 57600019
         MVI   XAV+FOUR,BLANK           REFERENCE                       58200019
         BAL   R15,VPATH21                        INVALID               58800019
         DC    AL1(MSG13)                                      MSG      59400019
**                                                                      60000019
VPMSG10  BAL   R15,VPATH20   RESERVED SHARED                            60600019
         DC    AL1(MSG49)                     DASD MSG                  61200019
**                                                                      61800019
**                                                                      62400019
*******************************************************************     63000019
*     THE FOLLOWING ROUTINE SETS UP THE XSA FOR MESSAGE MODULES    *    63600019
*     IGC0503D AND IGG2103D. THE VARIABLE MESSAGE TEXT(XAV),MES-   *    64200019
*     SAGE INDEX CODE(XAE), AND XCTL NAME ARE FILLED, AND AN XCTL  *    64800019
*     IS ISSUED TO THE PROPER MESSAGE MODULE.                      *    65400019
*******************************************************************     66000019
VPATH20  MVC   XAV(FOUR),PATH   PUT PATH                                66600019
         MVC   XAV+FOUR(FOUR),NINE(R5)  ADDRESS AND CPU ID IN MSG       67200019
VPATH21  MVC   XAE(ONE),ZERO(R15) INSERT MSG CODE INDEX NUMBER          67800019
         CLI   ZERO(R15),MSG13 IS MSG FOR IGC0503D                      68400019
         BNH   VPATH23       YES, GO GET MODULE NAME                    69000019
         MVC   XAX(EIGHT),XCTLNAME SET UP FOR XCTL                      69600019
VPATH22  SR    R6,R6          SET DCB PTR                               70200019
         ST    R6,XAD                    TO ZERO                        70800019
         LA    R6,XAX              PUT PTR TO-                          71400019
         ST    R6,XAP                  NAME IN LIST                     72000019
         XCTL  SF=(E,(R2))    XCTL TO MSG MODULE                        72900019
VPATH23  MVC   XAX(EIGHT),XCTLNAM2  FILL IN MESSAGE MODULE NAME         73800019
         B     VPATH22        CONTINUE WITH MSG SETUP                   74400019
***   CONSTANTS   ***                                                   75000019
     DS  0F                                                             75600019
XCTLNAME DC    C'IGG2103D'   NAME OF MESSAGE MODULE                     76200019
XCTLNAM2 DC    C'IGC0503D'   NAME OF MESSAGE MODULE                     76800019
PATH     DC    C'PATH'       'PATH' FOR MSG SET UPS                     77400019
XSADS    DSECT                                                          78000019
         IEEXSA                                                         78600019
         ORG   XSA            RESET ORIGIN TO ZERO                      79200019
* PARAMETER LIST FOR IOSGEN MACRO                                       79800019
XAVARYP  DS    CL2            HEX ADDRESS OF PATH TO BE VARIED(ZZZ)     80400019
XAONOFF  DS    CL1            ONLINE/OFFLINE INDICATOR                  81000019
OFF      EQU   X'08'         OFFLINE INDICATOR                          81600019
ON       EQU   X'04'         ONLINE INDICATOR                           82200019
XACPUID  DS    CL1           CPU ID-A OR B                              82800019
NOTUSED  DS    CL1            NOT USED                                  83400019
XAPRIMEP DS    CL3            EBCDIC ADDRESS OF PRIMARY PATH(XXX)       84000019
*  END OF PARM LIST                                                     84600019
XAWORK   DS    CL4            WORK AREA                                 85600019
SETCVT   DSECT                                                          87600019
         CVT                                                            88200019
   END                                                                  88800019
