         TITLE 'IGF55301 RECOVERY COMMAND - MODE'                       00050020
IGF55301 CSECT                                                          00100020
*********************************************************************** 00150020
*                                                                     * 00200020
*TITLE   IGF55301   RECOVERY COMMAND - MODE                           * 00250020
*                                                                     * 00300020
*STATUS  LEVEL=01     02/17/71                                        * 00310020
*                                                                     * 00320020
*FUNCTION  ACCEPTS THE PARAMETERS OF THE MODE COMMAND AND             * 00350020
*   PROCEEDS AS FOLLOWS, IF STATUS IS SPECIFIED, OUTPUT PRESENT       * 00400020
*   MACHINE STATUS TO OPERATOR CONSOLE.  IF RECORD IS SPECIFIED,      * 00450020
*   MODIFY CONTROL REGISTER 14 TO ALLOW RECOVERY REPORTS.  IF QUIET   * 00500020
*   IS SPECIFIED, MODIFY CONTROL REGISTER 14 TO KEEP RECOVERY         * 00550020
*   REPORTS PENDING. IF ENABLE IS SPECIFIED, MODIFY MCW TO ALLOW      * 00600020
*   THE BUFFER TO BECOME ENABLE.                                      * 00650020
*                                                                     * 00700020
*ENTRY POINT   IGF55301  FROM MODE COMMAND ROUTER, IEE2603D           * 00750020
*                                                                     * 00800020
*ATTRIBUTES   REENTRANT,TRANSIENT,READ ONLY AND SELF-RELOCATABLE      * 00850020
*                                                                     * 00900020
*APPLICABILITY   MODEL 553 ONLY                                       * 00950020
*                                                                     * 01000020
*EXTERNAL REFERENCES  MASTER SCHEDULER RESIDENT AREA, USING THE       * 01050020
*   MACRO IEEBASE1, EXTENDED SAVE AREA(XSA), USING THE MACRO IEEXSA,  * 01100020
*   COMMUNICATIONS VECTOR TABLE, USING THE MACRO CVT.                 * 01150020
*                                                                     * 01200020
*MACROS  XCTL, IEEBASE1, IEEXSA, WTO, CVT, GETMAIN, AND FREEMAIN      * 01250020
*                                                                     * 01300020
*INPUT  REGISTER 2 POINTS TO XSA WHICH MUST HAVE IN XAR, POINTER      * 01350020
*   TO COMMAND BUFFER, IN XAL, POINTER TO PARAMETER LIST.             * 01400020
*                                                                     * 01450020
*OUTPUT WHEN STATUS WAS SPECIFIED, THE MACHINE STATUS IS DISPLAYED    * 01500020
*   TO THE OPERATOR VIA WTO.                                          * 01550020
*        WHEN AN ERROR IN THE COMMAND INPUT IS DETECTED, AN EXIT      * 01600020
*   TO IEE050D, THE MESSAGE ASSEMBLER, IS MADE WITH REGISTER 2        * 01650020
*   POINTING TO THE EXTENDED SAVE AREA WHICH CONTAINS IN XAE, THE     * 01700020
*   MESSAGE CODE (SEE ERROR MESSAGES BELOW) AND IN XAV, THE VERB IN   * 01750020
*   EBCDIC, LEFT ADJUSTED WITH BLANKS.                                * 01800020
*                                                                     * 01850020
*EXITS  NORMAL SVC 3                                                  * 01900020
*        ERROR XCTL TO MESSAGE ASSEMBLY MODULE (IEE0503D)             * 01950020
*                                                                     * 02000020
*ERROR MESSAGES THE FOLLOWING CONDITIONS GENERATE THE INDICATED MSGS  * 02050020
*        1. FAILURE TO FIND BLANK OR END OF BUFFER AFTER PARAMETER    * 02100020
*           'IEE008I MODE TERM LENGTH ERROR'                 (CODE=8) * 02150020
*        2. NO RECORD, QUIET, ENABLE, OR STATUS PARAMETER             * 02200020
*           'IEE010I MODE KEYWORD MISSING'                   (CODE=10)* 02250020
*                                                                     * 02300020
*OPERATION                                                            * 02350020
*                                                                     * 02400020
*TABLES/WORKAREAS   THE XSA IS MAPPED AS FOLLOWS                      * 02450020
*                                                                     * 02500020
*        ***************************************************          * 02550020
*        *XAP                      *XAD                    *          * 02600020
*        *SAVE AREA FOR PTR TO     *                       *          * 02650020
*        * END OF COMMAND BUFFER.  *                       *          * 02700020
*        ***************************************************          * 02750020
*        *XAX                      *XAX+4                  *          * 02800020
*        *SAVE AREA FOR UCB OF     *SAVE AREA FOR UCB OF   *          * 02850020
*        * INPUT WORK QUEUE.       * PROCEDURE LIBRARY.    *          * 02900020
*        ***************************************************          * 02950020
*        *XAE  *XAE+1 *            *XAL                    *          * 03000020
*        *ERROR *PAR ID*           *SAVE AREA FOR CURRENT  *          * 03050020
*        *CODE *MASK  *            * PARAMETER POINTER.    *          * 03100020
*        ***************************************************          * 03150020
*        *XAV                      *XAV+4                  *          * 03200020
*        *                         * DATE IN PACKED        *          * 03250020
*        *                         *     DECIMAL           *          * 03300020
*        ***************************************************          * 03350020
*        *XAS                      *XAS+4                  *          * 03400020
*        *                         * TIME IN PACKED        *          * 03450020
*        *                         *     DECIMAL.          *          * 03500020
*        ***************************************************          * 03550020
*                                                                     * 03600020
*    NOTES  MAINTENANCE AREA OF 50 BYTES IS LOCATED AT LABEL MAINT      03610020
*********************************************************************** 03650020
          EJECT                                                         03700020
*********************************************************************** 03750020
********                                                       ******** 03800020
********                   E Q U A T E S                       ******** 03850020
********                                                       ******** 03900020
*********************************************************************** 03950020
R0       EQU   0                   GENERAL REGISTER 0                   04000020
R1       EQU   1                   GENERAL REGISTER 1                   04050020
XSABASE  EQU   2                   BASE REGISTER FOR XSA                04100020
R3       EQU   3                   GENERAL REGISTER 3                   04150020
MSBBASE  EQU   4                   BASE FOR MACHINE STATUS BLOCK (MSB)  04200020
R5       EQU   5                                                        04250020
WORK     EQU   5                   GENERAL WORK REGISTER                04300020
COUNT    EQU   5                   CONTAINS DEC. BINARY COUNT VALUES    04350020
R6       EQU   6                   GENERAL REGISTER 6                   04400020
R7       EQU   7                   GENERAL REGISTER 7                   04450020
MSERBASE EQU   8                   BASE REGISTER FOR MS RES. DATA AREA  04500020
CVTBASE  EQU   9                   BASE REGISTER FOR CVT                04550020
SAVEPTR  EQU   10                                                       04600020
BUFPTR   EQU   11                                                       04650020
MODBASE  EQU   12                  MODULE BASE REGISTER                 04700020
R14      EQU   14                  CONTROL REGISTER 14                  04750020
R15      EQU   15                  GENERAL REGISTER 15                  04800020
N0       EQU   0                   DECIMAL VALUE  0                     04850020
N1       EQU   1                   DECIMAL VALUE  1                     04900020
N2       EQU   2                   DECIMAL VALUE  2                     04950020
N3       EQU   3                   DECIMAL VALUE  3                     05000020
N5       EQU   5                   DECIMAL VALUE  5                     05050020
N6       EQU   6                   DECIMAL VALUE  6                     05100020
N7       EQU   7                   DECIMAL VALUE  7                     05150020
N8       EQU   8                   DECIMAL VALUE  8                     05200020
N80      EQU   80                  DECIMAL VALUE 80                     05250020
N128     EQU   128                 *                                    05300020
N255     EQU   255                 DECIMAL VALUE 255                    05350020
XF0      EQU   X'F0'               HEXADECIMAL VALUE F0                 05400020
X0F      EQU   X'0F'               HEXADECIMAL VALUE 0F                 05450020
XDF      EQU   X'DF'               HEXADECIMAL VALUE DF                 05500020
XBF      EQU   X'BF'               HEXADECIMAL VALUE BF                 05550020
X00      EQU   X'00'               HEXADECIMAL VALUE 00                 05600020
XFF      EQU   X'FF'               HEXADECIMAL VALUE FF                 05650020
F0       EQU   C'0'                CHARACTER VALUE 0                    05700020
BLANK    EQU   C' '                CHARACTER BLANK FOR DELIMITER TEST   05750020
ENABSOFT EQU   X'08'               RECOVERY REP. MASK IN CR 14          05800020
MASKSOFT EQU   XFF-ENABSOFT        FOR CLEARING REC. REP. MASK          05850020
RECRD    EQU   X'80'               CURRENT MODE INDICATOR               05900020
BUFDSAB  EQU   X'40'               BUFFER DISABLED FLAG                 05950020
STATLEN  EQU   6                   LENGTH OF CHARS 'STATUS'             06000020
ERR08    EQU   8                   ERROR TYPE CODE FOR MSG MODULE       06050020
ERR10    EQU   10                  ERROR TYPE CODE FOR MSG MODULE       06100020
         EJECT                                                          06150020
         BALR  MODBASE,N0          ESTABLISH                            06200020
         USING START,MODBASE       ADDRESSABILITY                       06250020
         USING XSADSECT,XSABASE    BASE FOR XSA                         06300020
         USING CVT,CVTBASE         BASE FOR CVT                         06350020
         USING BASE,MSERBASE       BASE FOR MS RESIDENT DATA AREA       06400020
START    EQU   *                                                        06450020
         L     CVTBASE,CVTPTR      GET PTR TO CVT                       06500020
         L     MSERBASE,CVTMSER    GET PTR TO MS RESIDENT DATA AREA     06550020
         L     MSBBASE,CVTRMS      GET PTR TO MACHINE STATUS BLOCK      06600020
         USING MSB,MSBBASE         ESTABLISH ADDRESSABILITY             06650020
         L     BUFPTR,XAL          GET PTR TO PARAMETER                 06700020
         LA    BUFPTR,N0(BUFPTR)   CLEAR HI-ORDER BYTE                  06750020
         LTR   BUFPTR,BUFPTR       IS PTR ZERO                          06800020
         BZ    MODERR10            YES, PARAMETER IS MISSING            06850020
         L     R7,XAR              LOAD PTR TO BUFFER                   06900020
         LA    R7,N0(R7)           CONTAINING COMMAND                   06950020
         LH    R6,N0(R7)           LOAD BUFFER LENGTH                   07000020
         N     R6,CLEARFS          CLEAR POSSIBLE GARBAGE               07050020
         AR    R7,R6               COMPUTE END OF BUFFER                07100020
         ST    R7,XAP              SAVE IN XSA                          07150020
         NI    XAE+N1,X00          CLEAR ID MASK AREA                   07200020
         EJECT                                                          07250020
*        EXAMINE  PARAMETER                                             07300020
         USING MODEPARM,BUFPTR                                          07350020
EXAMIN   EQU   *                                                        07400020
         CLC   COMMAND(STATLEN),STATUS TEST FOR STATUS                  07450020
         BNE   EXAMIN2             NOT STATUS - TEST OTHERS             07500020
         CLI   COMMAND+STATLEN,BLANK TEST FOR BLANK                     07550020
         BNE   MODERR08            ERROR - DELIMITER IS MISSING         07600020
         GETMAIN R,LV=N80,SP=N255  GET BUFFER SPACE                     07650020
         LR    SAVEPTR,R1          SAVE PTR TO GOTTEN AREA              07700020
         USING GMAREA,SAVEPTR      ESTABLISH ADDRESSABILITY             07750020
         L     COUNT,MSBTHRLD      GET DEFAULT THR VALUE                07800020
         BAL   R3,CONVERT          CONVERT                              07850020
         STH   COUNT,THRESH        STORE THRESHOLD VALUE                07900020
         L     COUNT,MSBCOUNT      GET COUNT OF SOFT ERRORS             07950020
         BAL   R3,CONVERT          CONVERT                              08000020
         MVC   GMAREA(WTOLEN),WTO  MOVE WTO INFO TO WORK AREA           08050020
         LA    R3,RECORD           INIT. PTR TO RECORD TEST             08100020
         TM    MSBMODE,RECRD       DOES CURRENT MODE = RECORD           08150020
         BO    SKIPUPDT            YES, DO NOT UPDATE PTR               08200020
         LA    R3,QUIET            INIT. PTR TO QUIET TEXT              08250020
SKIPUPDT EQU   *                                                        08300020
         MVC   GMSTATFL(N6),N0(R3) SET CURRENT MODE IN MSG              08350020
         MVC   GMTHRFLD(N2),THRESH SET DEFAULT THR IN MSG               08400020
         STC   COUNT,GMCNTFLD+N1   STORE 2ND BYTE OF CNT                08450020
         SRL   COUNT,N8            POSITION 1ST BYTE                    08500020
         STC   COUNT,GMCNTFLD      STORE 1ST BYTE OF CNT                08550020
         TM    MSBMODE,BUFDSAB     IS BUFFER CURRENTLY DISABLED         08600020
         BZ    SKIPOVLY            NO - ALLOW BUFFER ENABLED MSG        08650020
         MVC   GMBFSTAT(N3),DIS    MAKE MSG READ BUFFER DISABLED        08700020
SKIPOVLY EQU   *                                                        08750020
          SR   R0,R0          CLEAR REGISTER 0                          08760020
          IC   R0,XAU              GET CONSOLE ID                       08800020
         WTO   ,MF=(E,(SAVEPTR))   ISSUE MESSAGE TO CONSOLE             08850020
         LR    R1,SAVEPTR          GET PTR TO GOTTEN AREA               08900020
         FREEMAIN R,LV=N80,A=(R1),SP=N255 FREE BUFFER SPACE             08950020
EXIT     EQU   *                                                        09000020
         SVC   N3                  EXIT                                 09050020
CONVERT  EQU   *                                                        09100020
         CVD   COUNT,GMAREA        CONVERT ERROR CNT TO DEC.            09150020
         UNPK  GMAREA+N2(N2),GMAREA+N6(N2) PREPARE FOR                  09200020
         OI    GMAREA+N3,F0                                             09250020
         L     COUNT,GMAREA        SAVE FOR MSG BUILD                   09300020
         BR    R3                  RETURN TO STATUS PARAMETER           09350020
         EJECT                                                          09400020
EXAMIN2  EQU   *                                                        09450020
         CLC   COMMAND(N6),RECORD  IS RECORD SPECIFIED                  09500020
         BNE   EXAMIN3             NO, GO TEST FOR QUIET                09550020
         CLI   COMMAND+N6,BLANK    TEST FOR BLANK                       09600020
         BNE   MODERR08            ERROR - DELIMITER IS MISSING         09650020
         DC    X'B6EE',S(MSBCR14)  STORE CONTROL REGISTER               09700020
         OI    MSBCR14,ENABSOFT    ENABLE RECOVERY REPORTS              10100020
         OI    MSBMODE,RECRD       SET RECORD MODE FLAG IN MSB          10150020
         SR    WORK,WORK           RESET THE CURRENT SOFT               10200020
         ST    WORK,MSBCOUNT       ERROR COUNT IN THE MSB               10250020
STORCTL  EQU   *                                                        10300020
         DC    X'B7EE',S(MSBCR14)  LOAD CONTROL REGISTER 14             10350020
         B     EXIT                GO TO EXIT MODULE                    10400020
EXAMIN3  EQU   *                                                        10450020
         CLC   COMMAND(N5),QUIET   IS QUIET SPECIFIED                   10500020
         BNE   EXAMIN4            NO, GO TEST FOR ENABLE                10550020
         CLI   COMMAND+N5,BLANK    TEST FOR BLANK                       10600020
         BNE   MODERR08            ERROR - DELIMITER IS MISSING         10650020
         DC    X'B6EE',S(MSBCR14)  STORE CONTROL REGISTER 14            10700020
         NI    MSBCR14,MASKSOFT    DISABLE RECOVERY REPORTS             11100020
         NI    MSBMODE,XFF-RECRD   CLEAR RECORD MODE FLAG IN MSB        11150020
         B     STORCTL             GO TO STORE CR 14 AND EXIT           11200020
*                                                                       11250020
         EJECT                                                          11300020
EXAMIN4  EQU   *                                                        11350020
         CLC   COMMAND(N6),ENABLE IS ENABLE SPECIFIED                   11400020
         BNE   MODERR10           ERROR - NO VALID PARAMETER            11450020
         CLI   COMMAND+N6,BLANK   TEST FOR BLANK                        11500020
         BNE   MODERR08           ERROR - DELIMITER IS MISSING          11550020
         TM    MSBMODE,BUFDSAB    IS BUFFER CURRENTLY DISABLED          11600020
         BZ    FIXUP2             NO - GO CLEAR BUFFER COUNT            11650020
         GETMAIN R,LV=N8,SP=N255  GET MCW SPACE                         11700020
         LR    SAVEPTR,R1         SAVE PTR TO GOTTEN AREA               11750020
         USING MCWORD,SAVEPTR     ESTABLISH ADDRESSABILITY              11800020
         MVC   MCWORD(N8),MSBMCW    MOVE MCW FROM MSB                   11850020
         LA    R5,N128            THE NUMBER OF PARTITIONS              11900020
         LA    R6,RECRD           TURN OFF THE DELETE BIT               11950020
         MVI   BLOCKS,X0F         SET BLOCK SELECT IN MCW               12000020
LOOP     STC   R6,PARTIT          STORE PARTITION NUMBER IN MCW         12050020
         LA    R6,N1(R6)          UPDATE PARTITION NUMBER               12100020
         DC    X'8300',S(MCWORD)                 RE-ASSIGN PARTITION    12150020
         BCT   R5,LOOP            GO ISSUE NEXT CPU B DIAG.             12200020
         NI    MSBMODE,XBF         CLEAR DISABLE BIT FOR BUFFER         12250020
         NI    MSBMCW+N3,XDF          CLEAR BYPASS BIT IN MCW           12300020
         NI    BLOCKS,XF0          CLEAR BLOCK SELECT IN MCW            12350020
         NI    PARTIT,X00          CLEAR PARTITION NUMBER IN MCW        12400020
         NI    MCWORD+N3,XDF        CLEAR BYPASS BIT - ENABLE BUFFER    12450020
         DC    X'8300',S(MCWORD)   ENABLE BUFFER                        12500020
         LR    R1,SAVEPTR           PICKUP POINTER TO AREA              12550020
         FREEMAIN R,LV=N8,A=(R1),SP=N255                                12600020
FIXUP2   EQU   *                                                        12650020
         SR    R5,R5              CLEAR REGISTER 5                      12700020
         STH   R5,MSBBUFER        ZERO OUT BUFFER COUNT                 12750020
         B     EXIT               GO TO EXIT                            12800020
         EJECT                                                          12850020
*********************************************************************** 12900020
*                                                                     * 12950020
*   THIS SECTION SETS UP INFO. FOR THE MESSAGE ASSEMBLY MODULE AND    * 13000020
* XCTLS TO IT.                                                        * 13050020
MODERR08 EQU   *                                                        13100020
         MVI   XAE,ERR08           SETUP ERROR CODE                     13150020
         B     MODERR              GO TO COMMON ROUTINE                 13200020
MODERR10 EQU   *                                                        13250020
         MVI   XAE,ERR10           SETUP ERROR CODE                     13300020
MODERR   EQU   *                                                        13350020
         MVC   XAV(N8),MODECHAR    MOVE VERB TO XSA                     13400020
         MVC   XAX(N8),XCTLNAME    MOVE MODULE NAME FOR XCTL            13450020
         SR    R15,R15             DCB PTR                              13500020
         ST    R15,XAD                     TO ZERO                      13550020
         LA    R15,XAX             PTR TO NAME                          13600020
         ST    R15,XAP                         IN LIST                  13650020
         XCTL  SF=(E,(XSABASE))    PASS CONTROL TO ASSEMBLY MODULE      13700020
         EJECT                                                          13750020
         DS    0F                                                       13800020
CLEARFS  DC    X'0000FFFF'         USED TO ZERO HI HALF OF REG          13850020
WTO      WTO   'IGF053I MODE STATUS-XXXXXX COUNT-NN THRESHOLD-NN BUFFER*13900020
                 ENABLED',DESC=(5),MCSFLAG=(REG0),MF=L                  13950020
WTOEND   EQU   *                   END OF WTO DATA                      14000020
WTOLEN   EQU   WTOEND-WTO          LENGTH OF WTO DATA                   14050020
STATUS   DC    C'STATUS'           CHARS FOR PARAMETER COMPARE          14100020
RECORD   DC    C'RECORD'           CHARS FOR MSG, AND PARAM COMPARE     14150020
QUIET    DC    C'QUIET '           CHARS FOR MSG, AND PARAM COMPARE     14200020
ENABLE   DC    C'ENABLE'           CHARS FOR MSG, AND PARAM COMPARE     14250020
DIS      DC    C'DIS'              LETTERS FOR OVERLAYING BUFR STATUS   14300020
THRESH   DS    H                   IBM DEFAULT THRESHOLD                14350020
MODECHAR DC    C'MODE     '        COMMAND VERB PADDED TO 8 CHARACTERS  14400020
XCTLNAME DC    C'IGC0503D'         NAME OF MS MSG ASSEMBLY MODU.E       14450020
MAINT    DC    XL50'0'        MAINTENANCE SPACE                         14460020
         EJECT                                                          14500020
         DS    0D                  FORCE DBLWD ALIGNMENT                14550020
XSADSECT DSECT                                                          14600020
         IEEXSA                                                         14650020
         EJECT                                                          14700020
CVT      DSECT                                                          14750020
         CVT                                                            14800020
         EJECT                                                          14850020
         IEEBASEA                                                       14900020
         EJECT                                                          14950020
MSBDSECT DSECT                                                          15000020
         RMSMSB MOD=53                                                  15050020
GMAREA   DSECT                                                          15100020
GMTEXT   EQU   GMAREA+4                                                 15150020
GMSTATFL EQU   GMTEXT+20                                                15200020
GMCNTFLD EQU   GMTEXT+33                                                15250020
GMTHRFLD EQU   GMTEXT+46                                                15300020
GMBFSTAT EQU   GMTEXT+56                                                15350020
MODEPARM DSECT                     FOR REFERENCING MODE PARAMETERS      15400020
COMMAND  EQU   *                   POSITION OF 1ST PARAMETER            15450020
MCWORD   DSECT                                                          15500020
BLOCKS   EQU   MCWORD+1                                                 15550020
PARTIT   EQU   MCWORD+2                                                 15600020
         END                                                            15650020
