         LCLA  &LEV,&REL                                                00020021
&LEV     SETA      52                                                   00040021
&REL     SETA  21                                                       00060021
&REL&LEV TITLE 'IGFASR01 LEVEL &LEV RMS-MCH ERROR RECORDER'             00120021
*********************************************************************** 00180015
*                                                                     * 00270015
* MODULE  IGFASR01 - ERROR RECORDER                                   * 00360015
*                                                                     * 00450015
* FUNCTION/OPERATION                                                  * 00540015
*       THE ERROR RECORDER MODULE RECORDS A CPU ERROR ENVIRONMENT     * 00630015
*   RECORD ON THE SYS1.LOGREC DATA SET FOR EVERY MCH RECOVERY ATTEMPT,* 00720021
*   SUCCESSFUL OR UNSUCCESSFUL.  ALSO, IF THE CHANNEL CHECK HANDLER   * 00810015
*   OPTION IS NOT IN THE SYSTEM AND A CHANNEL FAILURE  OCCURS, IT     * 00900015
*   WILL COMPLETE AND RECORD A CHANNEL INBOARD RECORD ON SYS1.LOGREC. * 00930019
*   IF THE CHANNEL CHECK HANDLER IS IN THE SYSTEM AND A CHANNEL       * 00960019
*   FAILURE OCCURS, THIS MODULE WILL RECORD THE INBOARD WHICH CCH HAS * 00990019
*   CREATED. THIS MODULE WILL RECEIVE THE CCH CREATED RECORD VIA REG  * 01020019
*   13 AND THIS RECORD WILL BE RECORDED ON SYS1.LOGREC                * 01050019
*                                                                     * 01080015
*       THE RECORDS WILL CONTAIN DATA OF THE SAME CONTENT AND FORMAT  * 01170015
*   AS THAT NOW RECORDED BY SER0/1. (SEE FORMATS ON FOLLOWING PAGES.) * 01260015
*   IN ADDITION, THE CPU RECORD WILL CONTAIN MCH DETERMINED DATA.     * 01350021
*   THIS DATA INCLUDES THE RESULTS OF THE FOLLOWING MCH FUNCTIONS -   * 01440021
*                                                                     * 01530015
*      . ENVIRONMENT CHECKER                                          * 01620015
*      . ROS CHECKER                                                  * 01710015
*      . MEMORY CHECKER                                               * 01800015
*      . PROGRAM DAMAGE ASSESSMENT AND REPAIR (MFT/MVT)               * 01890015
*      . INSTRUCTION RETRY                                            * 01980015
*                                                                     * 02070015
*   THIS MODULE IS DIVIDED INTO THREE SECTIONS-                       * 02160015
*                                                                     * 02250015
*  SECTION 1-                                                         * 02340015
*       WHEN ERROR RECORDER GAINS CONTROL, IT READS THE HEADER RECORD * 02430015
*   FROM SYS1.LOGREC (R1) AND DETERMINES AVAILABLE RECORDING SPACE.   * 02520015
*   IF THE EXTENT IS FULL, A MESSAGE TO RUN EREP IS PRINTED.          * 02610015
*                                                                     * 02700015
*  SECTION 2-                                                         * 02790015
*       WHEN THE HEADER RECORD INFORMATION INDICATES THAT A RECORD    * 02880015
*   CAN BE WRITTEN, ERROR RECORDER COMPLETES THE RECORD AND WRITES IT.* 02970015
*   THE HEADER RECORD IS UPDATED AND REWRITTEN.                       * 03060015
*       THE RETYPE FIELD IS SET BY MCH NUCLEUS TO I OR C, TO INDICATE * 03080021
*       RESPECTIVELY, THAT EITHER AN INBOARD OR A CPU RECORD ENTRY    * 03100019
*       IS TO BE RECORDED.                                            * 03120019
*       FOR CPU RECORDS, THE FOLLOWING DATA IS ALREADY STORED WITHIN  * 03150015
*   THE RE BUILD AREA (SEE ASRMAC DSECT) -                            * 03240015
*                                                                     * 03330015
*  (1) RESULTS OF MCH MODULE EXECUTION                                * 03420021
*                                                                     * 03510015
*      . REENVCHK                                                     * 03600015
*      . REROSCHK                                                     * 03690015
*      . REMEST                                                       * 03780015
*      . REPDAR (PARTIAL)                                             * 03870015
*      . RERETRY                                                      * 03960015
*      . REMCOPSW                                                     * 04050015
*      . REGPARGP                                                     * 04140015
*      . REGPARFP                                                     * 04230015
*                                                                     * 04320015
*  (2) SAVED BY THE MCH NUCLEUS                                       * 04410021
*                                                                     * 04500015
*      . REGSGPR                                                      * 04590015
*      . REGSFPR                                                      * 04680015
*      . RECPULOG                                                     * 04770015
*                                                                     * 04860015
*      IF CCH IS NOT IN THE SYSTEM, THE FOLLOWING FIELDS              * 04900019
*       FOR INBOARD RECORDS, REIOLOG, RECUA, AND RECSW ARE            * 04950015
*       ALREADY STORED BY MCH NUCLEUS.                                * 05040021
*       THE REMAINING FIELDS IN EITHER TYPE RECORD ARE DETERMINED     * 05400015
*       AND/OR LOADED BY ERROR RECORDER, THUS COMPLETING THE RECORD   * 05490015
*                                                                     * 05580015
*  SECTION 3-                                                         * 05670015
*       A STAND-ALONE (INDEPENDENT OF OS/360) I/O ROUTINE IS USED FOR * 05760015
*   ALL I/O OPERATIONS.                                               * 05850015
*                                                                     * 05940015
*********************************************************************** 06030015
         EJECT                                                          06120015
*                         HEADER  RECORD  AREA                        * 06210015
*                   WHICH RESIDES AS THE FIRST RECORD ON SYS1.LOGREC  * 06290021
*     ***************************************************************** 06370021
*     *              *                                  *     HIGH    * 06450021
* +0  *  F F 0 0     *             LOW EXTENT           *    EXTENT   * 06530021
*     *              *               (CCHH)             *     (CC)    * 06610021
*     ***************************************************************** 06690021
*     * HIGH EXTENT  *       *       RECORD ENTRY AREA ADDRESS        * 06770021
* +8  *   (CONT.)    * SPARE *               (BBCCHHR)                * 06850021
*     *    (HH)      *       *                                        * 06930021
*     ***************************************************************** 07010021
*     *  REC. ENTRY  *  REMAINING     *  TOTAL BYTES    *  ADDRESS OF * 07090021
* +16 * AREA ADDR.   *   BYTES ON     *      ON         * LAST RECORD * 07170021
*     *   (CONT.)    *     TRACK      *    TRACK        * WRITTEN     * 07250021
*     ***************************************************************** 07330021
*     *           ADDRESS OF LAST RECORD         *   TRACKS    * EARLY* 07410021
* +24 *              WRITTEN  (CONT.)            *     PER     * WARN.* 07490021
*     *                                          *  CYLINDER   *  CNT.* 07570021
*     ***************************************************************** 07650021
*     * EARLY * DEV- *     EARLY WARNING                * EARLY*  CK  * 07730021
* +32 * WARN. *  ICE *                MESSAGE TRACK     * WARN.* BYTE * 07810021
*     * CNT.  * CODE *                                  * SWT. * (FF) * 07890021
*     ***************************************************************** 07970021
         EJECT                                                          08190015
*                          MCH CPU RECORD ENTRY AREA                  * 08220021
*                                                     ***************** 08250021
*                                                     *               * 08280021
*                                                 +0  *     KEY       * 08310021
*                                                     *               * 08340021
*     ***************************************************************** 08370015
*     *         RECORD        *  SYS. *  CPU  *  R.E. *    EREP       * 08460021
* +2  *          ENTRY        *  I.D. * MODEL *  TYPE * INDICATORS    * 08550021
*     *          LABEL        *       *  NO.  *       *   (NOTE)      * 08640021
*     ***************************************************************** 08730015
*     *                               *                               * 08820015
* +10 *             DATE              *             TIME              * 08910021
*     *                               *                               * 09000015
*     ***************************************************************** 09090015
*     *                                                               * 09180015
* +18 *                      PROGRAM  IDENTITY                        * 09270021
*     *                                                               * 09360015
*     ***************************************************************** 09450015
*     *                                                               * 09540015
* +26 *                  MACHINE  CHECK  OLD  PSW                     * 09630021
*     *                                                               * 09720015
*     ***************************************************************** 09810015
*     *                                                               * 09900015
* +34 *                                                               * 09990021
*     *                       CHANNEL/UNIT ADDRESSES OF               * 10080015
*     *                       ACTIVE I/O UNITS AT                     * 10170015
*     *                       THE TIME OF FAILURE                     * 10260015
*     *                           (16 BYTES)                          * 10350021
*     *                                                               * 10440015
*     ***************************************************************** 10530021
*     *                                                               * 10620021
* +50 *                  CHANNEL  TYPE  ASSIGNMENT                    * 10710021
*     *                                                               * 10800021
* --- ***************************************************************** 10890015
*     *                                                               * 10980021
* +58 *                     ENVIRONMENT CHECK DATA                    * 11070021
*     *                                                               * 11160015
*     ****************************************************************  11250015
*     *                                                               * 11340015
* +66 *                     CPU (ROS) CHECK DATA (24 BYTES)           * 11430021
*     *                                                               * 11520015
*     ****************************************************************  11610015
*     *                                                               * 11700015
* +90 *                     MEMORY CHECK DATA (112 BYTES)             * 11790021
*     *                                                               * 11880015
*     ****************************************************************  11970015
*     *                                                               * 12060015
* +202*                     PROGRAM DAMAGE ASSESSMENT AND             * 12150021
*     *                        REPAIR DATA                            * 12240015
*     *                                                               * 12330015
*     ****************************************************************  12420015
*     *                                                               * 12510015
* +226*                     INSTRUCTION RETRY DATA                    * 12610021
*     *                          (24 BYTES)                           * 12710021
*     ***************************************************************** 12960015
*     *                                                               * 13050021
* +250*                     GENERAL  REGISTER  CONTENTS               * 13140021
*     *                            (64 BYTES)                         * 13230021
*     ***************************************************************** 13320015
*     *                                                               * 13410021
* +314*               FLOATING  POINT  REGISTER  CONTENTS             * 13500021
*     *                           (32 BYTES)                          * 13590021
*     ***************************************************************** 13680015
*     *                                                               * 13770021
* +346*               GENERAL  PURPOSE  REGISTER  PARITY  FLAGS       * 13860021
*     *                                                               * 13950015
*     ***************************************************************** 14040015
*     *       FLOATING  POINT         *                 CPU           * 14130021
* +354*         REGISTER              *               HARDWARE        * 14220021
*     *       PARITY  FLAGS           *                LOGOUT         * 14310015
*     *********************************                               * 14400015
*     *                                                               * 14490021
* +364*                     MODEL 65 (176 BYTES)                      * 14580021
*     *                                                               * 14670021
*     ***************************************************************** 14760015
*      TOTAL LENGTH OF RECORD IS 534 BYTES. THE LOGOUT AREA IS MOVED  * 14860021
*         UP 4 BYTES FOR EREP BY THIS MODULE BEFORE IT IS WRITTEN TO  * 14960021
*         SYS1.LOGREC                                                 * 15060021
*  NOTES                                                                15350021
*       EREP INDICATORS                                                 15360021
*               BYTE 0                                                  15370021
*                 BIT 0 = UNUSED                                        15372021
*                 BIT 1 = INCOMPLETE RECORD                             15380021
*                 BIT 2 = ILLEGAL CUA                                   15382021
*                 BITS 3,4,5,6,7 = UNUSED                               15382121
*               BYTE 1                                                  15382421
*                 BITS 0,1,2 = UNUSED                                   15382821
*                 BIT 3 = EXPANDED CHANNEL SUPPORT                      15384021
*                 BITS 4,5,6,7 = UNUSED                                 15386021
       EJECT                                                            15390015
*                     INBOARD  RECORD  ENTRY  AREA                    * 15480015
*        THIS RECORD FORMAT IS USED ONLY IF CCH WAS NOT SYSGENED      * 15490021
*                                                     ***************** 15500021
*                                                     *               * 15510021
*                                                  +0 *     K E Y     * 15520021
*                                                     *               * 15530021
*     ***************************************************************** 15570015
*     *         RECORD        *  SYS. *  CPU  *  R.E. *               * 15660015
* +2  *          ENTRY        *  I.D. * MODEL * TYPE *    SPARES      * 15750021
*     *          LABEL        *       *  NO.  *       *               * 15840015
*     ***************************************************************** 15930015
*     *                               *                               * 16020015
* +10 *             DATE              *             TIME              * 16110021
*     *                               *                               * 16200015
*     ***************************************************************** 16290015
*     *                                                               * 16380015
* +18 *                       PROGRAM IDENTITY                        * 16470021
*     *                                                               * 16560015
*     ***************************************************************** 16650015
*     *                                                               * 16740015
* +26 *             FIRST  CCW OF FAILING  CHAIN                      * 16830021
*     *                                                               * 16920015
*     ***************************************************************** 17010015
*     *                                                               * 17100015
* +34 *                       FAILING  CCW                            * 17190021
*     *                                                               * 17280015
*     ***************************************************************** 17370015
*     *                                                               * 17460015
* +42 *              CHANNEL  STATUS  WORD                            * 17550021
*     *                                                               * 17640015
*     ***************************************************************** 17730015
*     *                                                               * 17820015
*     *                                                               * 17910021
*     *                       CHANNEL/UNIT ADDRESSES OF               * 18000015
*     *                       ACTIVE I/O UNITS AT                     * 18090015
*     *                       THE TIME OF FAILURE                     * 18180015
*     *                            (16 BYTES)                         * 18270021
*     *                                                               * 18360015
*     ***************************************************************** 18430021
*     *                                                               * 18500021
* +66 *                  CHANNEL  TYPE  ASSIGNMENT                    * 18570021
*     *                                                               * 18640021
*     ***************************************************************** 18730019
*     *                                                               * 18740019
* +74 *                           SPARE                               * 18750021
*     *                                                               * 18760019
*     ***************************************************************** 18810015
*     *               *               *                 I/O           * 18900015
* +82 *     CUA       *    SPARE      *              HARDWARE         * 18990021
*     *               *               *                LOGOUT         * 19080015
*     *********************************                                 19130021
*     *********************************                               * 19170015
*     *                                                               * 19260015
* +90 *                     MODEL 65 (24 BYTES)                       * 19350021
*     *                                                               * 19440021
*     ***************************************************************** 19530015
*      TOTAL LENGTH OF INBOARD RECORD IS 110 BYTES. THIS FORMAT IS    $ 19540021
*        USED ONLY IF CCH IS NOT IN THE SYSTEM.                       * 19550021
*        THE SPARE(74) AREA IS ZERO AND  IS USED BY EREP,IF 65MP      * 19560021
*                                                                       19570021
*        IF CCH IS IN THE SYSTEM AND IF CCH ENTERS MCH FOR A            19580021
*        CATASTROPHIC ERROR, A REGULAR INBOARD IS WRITTEN AND A         19590021
*        REGULAR INBOARD EXAMPLE CAN BE FOUND IN CCH PUBLICATIONS.      19600021
         EJECT                                                          19620015
IGFASR01 CSECT                                                          19710015
         USING TASRAREA,TASRREG        BASE FOR ASRMAC DSECT            19800015
         USING TCVTNAM,TCVTREG         BASE FOR CVT                     19890015
***      DSECTS                                                         19980015
*                                                                       20070015
TCVTNAM  DSECT                                                          20160015
         CVT                                                            20250015
         EJECT                                                          20340015
TASRAREA DSECT                                                          20430015
         ASRMAC                                                         20520015
         IEAQFX  65,MCH,1,GENCODE=NO                                 MP 20560017
         EJECT                                                          20610015
*                                                                       20700015
*** REGISTER USAGE                                                      20790015
*                                                                       20880015
T0       EQU   0                                                        20970015
TWORK1   EQU   1    WORK REG                                            21060015
TWORK2   EQU   2    WORK REG                                            21150015
TWORK3   EQU   3    WORK REG                                            21240015
TWORK4   EQU   4    WORK REG                                            21330015
TWORK5   EQU   5    WORK REG                                            21420015
TWORK6   EQU   6    WORK REG                                            21510015
TWORK7   EQU   7    WORK REG                                            21600015
TWORK8   EQU   8    WORK REG                                            21690015
TLINK    EQU   9    LINKAGE REGISTER                                    21780015
TCBREG   EQU   11   ADDR OF TCB                                         21960015
TASRREG  EQU   12  DSECT REG FOR ASR COM AREA AND RE                    22050015
TCVTREG  EQU   13   CVT REG FOR DSECT                                   22140015
TNUCREG  EQU   14   ASRNUC BASE REG (NOT TOUCHED)                       22230015
TBASEREG EQU   15   MODULE BASEREG  (SET BY ASRNUC)                     22320015
R1       EQU   1                                                        22410015
R13      EQU   13    LINK REG BACK TO NUCLEUS                           22500015
         SPACE 5                                                        22590015
***** OFFSETS AND FLAGS                                                 22680015
TSHPC    EQU   0   SIX HOUR PSEUDO CLOCK                                22770015
TT4PC    EQU   4   24  HOUR PSEUDO CLOCK                                22860015
TLTPC    EQU   8   LOCAL TIME PSEUDO CLOCK                              22950015
         SPACE                                                          23040015
TUCBACT  EQU   6    UCB BUSY BIT                                        23130015
TUCBCUA  EQU   4    UCB CHANNEL/UNIT ADDRESS                            23220015
TACTTCB  EQU   4    CURRENT TCB                                         23310015
XRBPSW   EQU   17         PSW WAIT BIT OFFSET FOR WAIT TCB              23400015
WAITBIT  EQU   X'02'     WAIT BIT                                       23490015
TOPRBP   EQU   0    TOB RB                                              23580015
TRBSTAB  EQU   10   RB STATUS AND ATTRIBUTE FIELD                       23670015
TCBTIO   EQU   12   TIOT ADDR                                           23760015
TSIRB    EQU   X'80'          SIRB TYPE                                 23850015
TPRB     EQU   X'C0' PRB CODE                                           23940015
TRBTCB   EQU   X'80' RBLNK POINTS TO TCB FLAG (IN RB)                   24030015
TRBLNK   EQU   X'1C' QUEING FLD                                         24120015
TMVT     EQU   X'10' MVT IDENTIFIER SET AT NIP IN 1ST BYTE OF CVTDCB    24210015
MULTPROC EQU   X'10'                    MULTIPROCESSING  MASK        MP 24240017
CHANSTAT EQU   X'78'                    CHANNEL STATUS MASK          MP 24270017
TCDNAME  EQU   8    RB CONTENTS DIRECTORY ENTRY NAME FOR MVT            24300015
TRBCDE   EQU   12   RB CONTENTS DIRECTORY ENTRY FOR MVT                 24390015
         SPACE                                                          24480015
STARTADR EQU   16                                                       24570015
TIOBPTR  EQU   4                                                        24660015
TDCBF0   EQU   44   DCB DEB ADDR                                        24750015
TDEBF4   EQU   36   DEB BBCCHHR                                         24840015
TUCBF12  EQU   20                                                       25020015
         SPACE 3                                                        25110015
*** SYSRES DEVICE TYPE AND ADDRESS                                      25200015
TSYSCUA  EQU   COMSYSRS       ADDRESS                                   25290015
TSYSRSTP EQU   COMSYSRS+2     TYPE                                      25380015
*                             EQUATES                                   25386019
REGGPR13 EQU   REGSGPR+52    CCH PARM REG                          CCH  25392019
CVTSNCVD EQU   CVTSNCTR+2               FOR CCH IN SYSTEM CHECK     CCH 25404019
D1       EQU   1                                                    CCH 25410019
D2       EQU   2                                                    CCH 25416019
D3       EQU   3                                                    CCH 25422019
D5       EQU   5                                                   CCH  25428019
D6       EQU   6                                                    CCH 25434019
D7       EQU   7                                                    CCH 25440019
D8       EQU   8                                                        25443020
D10      EQU   10                                                   CCH 25446019
D48      EQU   48                                                   CCH 25452019
D176     EQU  176           LOGOUT LENGTH                     IE  53354 25454021
XFF      EQU   X'FF'                                               8420 25461019
         EJECT                                                          25470015
         USING IGFASR01,TBASEREG       BASE FOR MODULE                  25560015
IGFASR01 CSECT                                                          25650015
         STM   TCVTREG,TNUCREG,TREGSAVE                                 25740015
         B     TSTART                                                   25830015
         ORG   IGFASR01+8                                               25920015
TTRTABLE DC    C'0A'             ID OF CLEAR CHANNEL MODULE             26010015
         DC    X'00000000'       TTRL                                   26100015
NEWPDAR  EQU   *                                                   2K   26120018
         DC    C'2K'                        NEW PDAR MODULE        2K   26140018
         DC    4X'0'                         ADDR                  2K   26160018
TABEND   DC    X'0000'                                                  26190015
         SPACE 5                                                        26280015
*********************************************************************** 26370015
*                                                                     * 26460015
* SECTION 1 -  READING AND CHECKING HEADER RECORD                       26550015
*                                                                       26640015
*     THIS SECTION READS THE HEADER RECORD FROM THE SYS1.LOGREC DATA  * 26730015
*     SET.  THE TRACK AND CYLINDER IS UPDATED IF NECESSARY, AND IF    * 26820015
*     THE EXTENT IS FULL, EREP IS REQUESTED VIA A CONSOLE MESSAGE. THE* 26910015
*     HEADER RECORD IS THEN UPDATED TO REFLECT INFO FOR THE NEXT      * 27000015
*     RECORD ENTRY TO BE WRITTEN. ALL REQUIRED I/O OPERATIONS ARE     * 27090015
*     PERFORMED BY THE I/O ROUTINE IN SECTION 3.                      * 27180015
*                                                                     * 27270015
*********************************************************************** 27360015
         SPACE 3                                                        27450015
         SPACE 2                                                        27540015
TSTART   EQU   *                                                        27630015
         MVI   COMLEV01,LEVEL       MODULE LEVEL                 MP     27640021
LEVEL  EQU   X'&LEV'             MODULE LEVEL                   21021   27650021
BIT8     EQU    X'EF'                                              MP   27660017
REVD     EQU   REENVCHK+7                                          MP   27670017
         L     TCVTREG,COMCVT      GET CVT ADDR FOR ADDRESSABILITY      27720015
         L     TCBREG,CVTTCBP      LOAD ADDR OF TCB PTR                 27750018
         L     TCBREG,TACTTCB(TCBREG)  GET ADDR OF ACTIVE TCB           27780018
*                                                                       27810015
**** ROUTINE TO RESOLVE DATA ADDRESSES FOR CCWS - NO ADCONS CAN BE USED 27900015
*                                                 IWTH THE ASR LOADER.  27990015
*                                                                       28080015
         LA    TWORK3,TSEEKADR+1        STORE ADDRESS OF                28170015
         ST    TWORK3,WORKAREA            SEEK ADDRESS IN               28260015
         MVC   TIORCA+1(3),WORKAREA+1     SEEK CCW.                     28350015
         SPACE                                                          28440015
         LA    TWORK3,TBUFR0            STORE ADDRESS OF                28530015
         ST    TWORK3,WORKAREA          R0 BUFFER IN                    28620015
         MVC   R0BUF(3),WORKAREA+1      READ R0 CCW.                    28710015
         SPACE                                                          28800015
         LA    TWORK3,TSENSD            STORE ADDRESS OF                28890015
         ST    TWORK3,WORKAREA            SENSE DATA AREA IN            28980015
         MVC   TIORCF+1(3),WORKAREA+1        SENSE CCW.                 29070015
         SPACE                                                          29160015
         LA    TWORK3,TSRCHAD+2         STORE ADDRESS OF                29250015
         ST    TWORK3,WORKAREA            SEARCH ADDRESS IN             29340015
         MVC   THDRCCW+1(3),WORKAREA+1    SEARCH CCWS.                  29430015
         MVC   THDRCCW1+1(3),WORKAREA+1                                 29520015
         MVC   TWRTCCW+1(3),WORKAREA+1                                  29610015
         MVC   TEOFCCW+1(3),WORKAREA+1                                  29700015
         SPACE                                                          29790015
         LA    TWORK3,THDRREC           STORE HEADER RECORD             29880015
         ST    TWORK3,WORKAREA            ADDRESS IN HDR READ           29970015
         MVC   RDHDR(3),WORKAREA+1        AND WRITE CCWS.               30060015
         MVC   WRTHDR(3),WORKAREA+1                                     30150015
         SPACE                                                          30240015
         LA    TWORK3,CTFLDID           STORE RE ADDRESS                30330015
         ST    TWORK3,WORKAREA            IN WRITE RE CCW.              30420015
         MVC   TWRTCCW1+1(3),WORKAREA+1                                 30510015
         SPACE                                                          30600015
         LA    TWORK3,TEOFREC           STORE EOF RECORD ADDRESS        30690015
         ST    TWORK3,WORKAREA            IN WRITE EOF CCW.             30780015
         MVC   EOFRECAD(3),WORKAREA+1                                   30870015
         SPACE 3                                                        30960015
       SPACE 2                                                          31050015
*                                                                       31140015
*****       READ HEADER RECORD FROM SYS1.LOGREC.                        31230015
*                                                                       31320015
         SPACE 2                                                        31410015
         OI    RECTLIND,X'40'      SET INCOMPLETE RECORD INDICATOR      31500015
*  GET ADDRESS OF SYS1.LOGREC FROM DEB                                  31590015
         L     TWORK2,CVTDCB       ADDRESS OF SYS1.LOGREC DCB AND       31680015
         L     TWORK6,TDCBF0(TWORK2)  ADDR OF DEB                       31770015
         MVC   TSRCHAD(6),TDEBF4(TWORK6)    MOVE BBCCHH  FROM DEB       31860015
         MVI   TSRCHAD+6,1         SET SEARCH ID FIELD TO ONE           31950015
         MVC   TDSADRSV(8),TSRCHAD SAVE SYS1.LOGREC ADDRESS             32040015
*  COMPLETE CCWS FOR READ                                               32130015
         LA    TWORK3,THDRCCW      READ HEADER CCW LIST ADDRESS         32220015
         ST    TWORK3,TICADDR      STORE TIC ADDR AND                   32310015
         MVC   TSEEKADR+1(7),TSRCHAD     SEEK ADDR                      32400015
         MVC   HDRDTIC(3),TICADDR+1     MOVE TO HDR READ TIC CCW        32490015
*  READ HEADER                                                          32580015
         BAL   TLINK,TIORTN        TO I/O ROUTINE FOR READ ADR          32670015
         CLI   TSFTYBYT,X'FF'      IS SAFTY BYTE IN HEADER CORRECT      32760015
         BC    7,TERMNATE          BR -NO, INCORRETC - I/O OVERRUN      32850015
         SPACE 5                                                        32940015
*                                                                       33030015
*****    TEST HDR INFO TO DETERMINE IF TRK OR CYL SWITCH IS NECESSRY,OR 33120015
*        IF SYS1.LOGREC IS ALMOST FULL REQUIRING AN EREP RUN.           33210015
       SPACE 2                                                          33300015
* GET SYSRES DEVICE TYPE  (TO DETERMINE ACTUAL DEVICE TRACK CAPACITY)   33390015
         SR    TWORK4,TWORK4            CLEAR REG                       33480015
         IC    TWORK4,TSYSRSTP          GET SYSRES DEVICE TYPE          33570015
         SLL   TWORK4,1                 DOUBLE FOR AN INDEX             33660015
* CHECK IF RECORD WILL FIT ON THIS TRACK                                33750015
         LH    TWORK5,TCONIO-2(TWORK4)  LOAD INBOARD DECREMENT CONSTANT 33840015
         CLI   RETYPE,C'I'              IS THIS AN INBOARD RECORDING    33930015
         BC    8,TSTBYREM               BR YES                          34020015
         LH    TWORK5,TCONRE-2(TWORK4)  LOAD CPU DECREMENT CONSTANT     34110015
TSTBYREM LH    TWORK3,TBYTSREM   GET NO OF BYTES REMAINING ON TRACK     34200015
         SLR   TWORK3,TWORK5            SUBT CONSTANT FROM REMAING BYTS 34290015
         BC    1,TCHKLAST               BR- RE WILL FIT ON THIS TRACK - 34380015
*                                      SO CHECK IF THIS IS LAST TRACK   34470015
         SPACE 2                                                        34560015
* CHECK IF END OF CYLINDER                                              34650015
TESTCYL  LH    TWORK3,TLASTTTR+4        GET LAST USED HEAD POSITION-HH  34740015
         LA    TWORK3,1(TWORK3)         ADD ONE TO HEAD POSITION        34830015
         L     TWORK1,TLASTTT6     GET TRKS PER CYL               21021 34890021
         LA    TWORK1,X0(TWORK1)   CLEAR TOP BYTE                 21021 34950021
         SRL   TWORK1,D8           CLEAR LOW BYTE 2 MOVE RIGHT 1  21021 35010021
         CLR   TWORK1,TWORK3            COMPARE TRKS/CYL TO HEAD POSITN 35100015
         BC    12,TCYLEND               BR EQ/LOW - END OF CYLINDER     35190015
         SPACE 2                                                        35280015
         SPACE 2                                                        35370015
* IF NECESSARY, UPDATE HEAD POSITION TO SWITCH TRACKS                   35460015
TRKUPDT  STH   TWORK3,TLASTTTR+4        STORE NEXT HEAD POSITION IN HDR 35550015
         MVI   TLASTTTR+6,0             SET RECORD ENTRY ID TO ZERO     35640015
         MVC   TBYTSREM(2),TRKCAP       RESET BYTES REMAINING ON TRACK  35730015
         BC    15,TSTBYREM              BR - TRY AGAIN                  35820015
         SPACE 2                                                        35910015
* IF NECESSARY, UPDATE CYLINDER POSITION                                36000015
TCYLEND  SR    TWORK3,TWORK3            CLEAR REGISTER FOR ZERO HEAD    36090015
         LH    TWORK1,TLASTTTR+2        GET LAST USED CYLINDER POSITION 36180015
         LA    TWORK1,1(TWORK1)         UPDATE CYLINDER POSITION -CC    36270015
         STH   TWORK1,TLASTTTR+2        STORE NEXT CYLINDER POS IN HDR  36360015
         BC    15,TRKUPDT               BR - UPDATE HDR                 36450015
         SPACE 2                                                        36540015
* CHECK RECORDING SPACE IN EXTENT FOR POSSIBLE EREP SCHEDULING          36630015
TCHKLAST STH   TWORK3,TBYTSREM          STORE NEW REMAINE BYTCNT IN HDR 36720015
         L     TWORK7,COMPRNT           NEXT AVAIL BYTE IN WTO BUF21021 36750021
         TM    SWITCHES,X80             HAS 90% MSG BEEN ISSUED   21021 36780021
         BO    TESTFULL                 YES- GO TO LOGREC FULL    21961 36810021
         CLC   EWMT(X4),TLASTTT2        EARLY WARN(90%)-NEW CCHH  21021 36840021
         BL    FUL90SET         SET NEAR FULL MESSAGE             21021 36850021
**                        USED ONLY IF WARN TRACK IS BYPASSED     21021 36860021
         BH    TESTFULL                SKIP NEAR FULL MESSAGE     21021 36870021
         CLC   EWMC(D2),TBYTSREM       EARLY WARN CNT=REMAIN BYTE 21021 36900021
         BL    TSETWRT                 NO- SKIP NEARFULL/FULL     21021 36930021
****                                     MESSAGES                 21021 36960021
FUL90SET EQU   *                                                  21021 36990021
**    SYS1.LOGREC IS NEAR FULL-90%                                21021 37020021
         MVC   X0(X3,TWORK7),FUL90MSG   MOVE CODE TO BUFFER       21021 37050021
         LA    TWORK7,X3(TWORK7)        UPDATE ADDR               21021 37080021
         ST    TWORK7,COMPRNT               AND PTR               21021 37110021
         OI    SWITCHES,X80            SET 90% BIT IN LOGREC HDR  21021 37140021
         CLC   EWMT(X4),TLASTTT2        EARLY WARN(90%)-NEW CCHH  21021 37150021
         BL    TESTFULL         GO TO TEST FULL COND              21021 37160021
         B     TSETWRT                 GO WRITE RECORD            21021 37170021
TESTFULL EQU   *                                                  21021 37200021
         CLC   TUPLIMIT(X4),TLASTTT2    COMPARE NEWCCHH/HIGH CCHH 21021 37230021
         BH    TSETWRT                 NO- WRITE RECORD           21021 37260021
**    SYS1.LOGREC IS FULL                                               37290021
         MVC   X0(X3,TWORK7),TFULLMSG  MOVE CODE TO BUFFER         MCS  37470018
         LA    TWORK7,X3(TWORK7)     UPD                           MCS  37540018
         ST    TWORK7,COMPRNT      UPDATE PTR                       MCS 37610018
         B     END                                                      37710015
         SPACE 5                                                        37800015
*                                                                     * 37890015
****     COMPLETE  UPDATING  OF  HEADER                                 37980015
*                                                                       38070015
TSETWRT  BC    8,*+8  BR EQ - EOF HEAD SWITCHING NOT REQUIRED -LAST TRK 38160015
         OI    TFLAGS,THDSWTCH SET EOF HEAD SWITCH REQUIRED SWITCH      38250015
         MVC   TSEEKADR+1(7),TLASTTTR   MOVE SEEK ADDR                  38340015
         MVC   TSRCHAD(7),TSEEKADR+1    MOVE SEARCH                     38430015
         SR    TWORK5,TWORK5            CLEAR REG                       38520015
         IC    TWORK5,TLASTTTR+6        LOAD ID OF LAST REC WRITTEN     38610015
         LA    TWORK5,1(TWORK5)         ADD ONE TO ID FIELD             38700015
         STC   TWORK5,TLASTTTR+6        UPDATE LAST ID WRITTEN IN HDR   38790015
*                                                                       38880015
         OI    TFLAGS,THDROK            SET HEADER COMPLETE SWITCH      38970015
         EJECT                                                          39060015
*********************************************************************** 39150015
* SECTION 2 -  COMPLETION AND WRITING OF RECORD ENTRY                 * 39240015
*                                                                     * 39330015
*     THIS SECTION COMPLETES THE CPU RECORD FOR RMS, COMPLETES THE    * 39380019
*     INBOARD RECORD IF CHANNEL CHECK HANDLER(CCH) IS NOT IN THE      * 39430019
*     SYSTEM, OR WRITES THE CCH CREATED INBOARD RECORD IF CCH IS IN   * 39480019
*     THE SYSTEM.                                             THE     * 39530019
*     FOLLOWING FIELDS ARE LOADED -                                   * 39600015
*                                                                     * 39690015
*                  RELABEL  - ASR (RECORD ENTRY LABEL)                * 39780015
*                  REFORMT  - 0   (FORMAT TYPE)                       * 39870015
*                  REMODNUM - NN  (CPU MODEL NUMBER)                  * 39960015
*                  RETYPE   - C/I (TYPE OF RECORD - CPU OR INBOARD)   * 40050015
*                  REDATE   - DATE                                    * 40140015
*                  RETIME   - TIME                                    * 40230015
*                  REPROGID - PROGRAM ID                              * 40320015
*           REAIOU/REACTIO  - ACTIVE I/O UNITS                        * 40410015
*         RECHASSG/RECHASG  - CHANNEL CONFIG                          * 40500015
*                                                                     * 40590015
*     FOR A CPU RECORD -                                              * 40680015
*                  REPDAR   - JOB AND STEP NAMES                      * 40770015
*     FOR AN INBOARD RECORD,IF CCH IS NOT IN THE SYSTEM -             * 40860019
*                  RECCW1   - FIRST CCW OF FAILING CHAIN              * 40950015
*                  RECCW2   - FAILING CCW                             * 41040015
*               IS ALSO DETERMINED.                                   * 41130015
*                                                                     * 41220015
*     THE RECORD IS THEN WRITTEN VIA THE I/O ROUTINE (SECTION 3).     * 41310015
*                                                                     * 41400015
*********************************************************************** 41490015
         SPACE 3                                                        41580015
*                                                                       41670015
* MOVE KEY LENGTH, DATA LENGTH, RE KEY                                  41760015
         MVI   CTFLDKEY,X'02'                                           41850015
         SPACE                                                          41940015
         LH    TWORK5,CPU65        GET CPU REC LNGTH FOR M65 ***TEMP    42450015
         CLI   RETYPE,C'C'         IS THIS A CPU RECOTD                 42570015
         BE    RELENGTH            BR  YES                              42660015
         TM    CVTSNCVD,TSIRB           IS CCH IN THE SYSTEM        CCH 42700019
         BO    CCHINSYS                 YES  RECORD IN COMPLETED    CCH 42740019
         LH    TWORK5,IO65         GET IO REC LNGTH FOR M65 ****TEMP    42780015
RELENGTH STH   TWORK5,CTFLDDL      PUT RECORD LENGTH IN COUNT FIELD     42840015
         SPACE                                                          42930015
         MVC   REKEY(2),TREKEY                                          43020015
         SPACE 2                                                        43110015
****   MOVE LABEL AND FORMAT INTO RECORD ENTRY                          43200015
*                                                                       43290015
         MVC   RELABEL(4),TIDENTFY      ASR LABEL IS MCH                43380015
         MVI   REMODNUM,X'65'          ********TEMPORARY                43500015
         SPACE                                                          43560015
*                                                                       43650015
****  MOVE DATE FROM CVT INTO RECORD ENTRY                              43740015
*                                                                       43830015
         L     TWORK1,CVTDATE      GET DATE FROM CVT                    43920015
         ST    TWORK1,REDATE       STORE DATE IN RECORD ENTRY           44010015
*                                                                       44100015
         SPACE                                                          44190015
*                                                                       44280015
****  COMPUTE LOCAL TIME OF DAY FOR RECORD ENTRY                        44370015
*                                                                       44460015
         SR    TWORK1,TWORK1  CLEAR REG                                 44550015
         AL    TWORK1,CVTTPC  LOAD PTR TO PSEUDO-CLOCKS (NONE IF CC 0 ) 44640015
         BC    10,PROGID                SKIP TIME TIME OF DAY       CCH 44740019
         L     TWORK2,TSHPC(TWORK1) LOAD 6  HOUR PSEUDO CLOCK           44910015
         AL    TWORK2,TT4PC(TWORK1) ADD 24 HOUR  PSEUDO CLOCK           45000015
         SR    TWORK3,TWORK3     ZERO INDEX                        MP   45020017
         TM    COMMSF,X10        IS THIS A MP SYSTEM              62201 45070021
         BZ    NOTMP           NO - GET REGULAR TIMER             62201 45080021
         L    TWORK3,PREFTMRA  YES - GET PSA WITH ACTIVE TIMER    62201 45090021
NOTMP    EQU   *                                                  62201 45100021
         L     TWORK3,80(TWORK3)    LOAD HARDWARE TIMER            MP   45120017
         SRA   TWORK3,1     (HALVE) CONVERT TO 26 US INCREMENTS         45180020
         SLR   TWORK2,TWORK3        SUBTRACT TIMER                      45270015
         CL    TWORK2,TD24HRS          IS VALUE OVER 24 HOURS           45280019
         BL    NOT24                   NO, SKIP CORRECTION              45290019
         AL    TWORK2,TDADJ         YES,ADD  CORRECTION FACTER          45300019
NOT24    EQU   *                                                        45310019
         AL    TWORK2,TLTPC(TWORK1) ADD LOCAL TIME PSEUDO CLOCK         45360015
         BC    3,TADJUST            BRANCH ON OVERFLOW                  45450015
         CL    TWORK2,TD24HRS       CHECK FOR OVER 24 HOURS             45540015
         BC    4,TADJUST+4          BRANCH IF NOT OVER 24 HOURS         45630015
TADJUST  AL    TWORK2,TDADJ         ADD 7+ HOURS CORRECTION FACTOR      45720015
         ST    TWORK2,RETIME        STORE TIME IN RECORD ENTRY          45810015
         SPACE 2                                                        45900015
         SPACE 2                                                        45990015
*                                                                       46080015
****  MOVE PROGRAM ID FROM RB (MFT) OR CONTENTS DIRECTORY ENTRY (MVT)   46170015
*                                                                       46260015
PROGID   EQU   *                                                    CCH 46300019
         L     TCBREG,CVTTCBP      LOAD ADDR OF TCB POINTERS            46350015
         L     TCBREG,TACTTCB(TCBREG)   GET ADDR OF ACTIVE TCB -CURRENT 46440015
         SR    TWORK2,TWORK2                                            46530015
         CLR   TWORK2,TCBREG       TEST TCBREG FOR ZERO ADDRESS         46620015
         BC    8,CHKTYPE      BR ZERO - NO PROG IDENTITY                46710015
         L     TWORK1,TOPRBP(TCBREG) LOAD ADDR OF TOP RB                46800015
         TM    CVTDCB,TMVT         CHK MVT, NO-WAIT TCBS IN MFT    MP   46840017
         BZ    TRBSRCH       SKIP NEXT TEST                        MP   46880017
         TM    XRBPSW(TWORK1),WAITBIT    IS THIS A WAIT TCB IN MVT SYS. 46920015
         BO    CHKTYPE        BR YES - NO RB                            46980015
TRBSRCH  TM    TRBSTAB(TWORK1),TPRB     TEST RB FOR PRB TYPE            47070015
         BC    7,TNOTPRB                BR, NOT A PRB                   47160015
         LR    TWORK2,TWORK1       SAVE PRB ADDRESS                     47250015
TNOTPRB  TM    TRBSTAB+1(TWORK1),TRBTCB      DOES LINK FLD POINT TO TCB 47340015
         BC    1,TRBEND                        BR YES - END OF RB LIST  47430015
         L     TWORK1,TRBLNK(TWORK1) LOAD NEXT RB ADDRESS               47520015
         B     TRBSRCH               CHECK NEXT RB FOR PRB TYPE         47610015
*                                                                       47700015
TRBEND   LTR   TWORK2,TWORK2       WAS PRB ADDRESS SAVED                47790015
         BC    8,CHKTYPE      BR - NO PRB - NO PROGRAM ID               47880015
         TM    CVTDCB,TMVT         IS SYSTEM MVT OR MFT            MP   47970017
         BO    TRBMVT              MVT-ID IN CDE                   MP   48060017
         LM    TWORK3,TWORK4,0(TWORK2) GET ID FROM RB FOR MFT           48150015
         STM   TWORK3,TWORK4,REPROGID   STORE ID IN RE                  48240015
         B     CHKTYPE                                                  48330015
TRBMVT   L     TWORK2,TRBCDE(TWORK2)    GET PTR TO CNTNTS DRECTRY ENTRY 48420015
         LM    TWORK3,TWORK4,TCDNAME(TWORK2)   GET ID FROM CDE          48510015
         STM   TWORK3,TWORK4,REPROGID          STORE ID IN RE           48600015
         SPACE 2                                                        48690015
*                                                                       48780015
CHKTYPE  CLI   RETYPE,C'I'         IS THIS FOR INBOARD RECORDING        48870015
         BE    TINBOARD                 YES-COMPLETE INBOARD      21021 48930021
NOTINBD  TM    COMMSF,MULTPROC          IS MULTI-SYSTEM FEATURE PRES.MP 49006017
         BNO   NOTPRES                  BRANCH  AROUND  MULT-PRO CODEMP 49010017
         OC    REVD(N1),COMMSF  OR IN 5 BITS FOR EREP 656          2K   49014018
         B     SKIPNEXT                 SKIP NEXT INSTRUCTION        MP 49018017
NOTPRES  NI    REVD,BIT8                TURN OFF 21TH BIT          MP   49022017
SKIPNEXT EQU   *                                                   MP   49026017
         CLI   COMPSA+115,X'01'    DID MCI OCCUR IN CCH                 49070015
         BNE   TJOBSTP             BR NO                                49080015
         MVC   REPDAR(8),CCHNAME   INDICATE CCH IN JOB NAME             49090015
         B     CPUCMPLT                                                 49100015
         SPACE                                                          49110015
*                                                                       49140015
****  MOVE JOB AND STEP NAMES TO RECORD ENTRY                           49230015
*                                                                       49320015
TJOBSTP  L     TWORK1,TCBTIO(TCBREG)    GET TIOT ADDR                   49410015
         LTR   TWORK1,TWORK1            TEST FOR ZERO ADDRESS           49500015
         BC    8,CPUCMPLT               BR- TIOT NOT IN                 49590015
         LM    TWORK2,TWORK5,0(TWORK1)  GET JOB AND STEP NAMES          49680015
         STM   TWORK2,TWORK5,REPDAR     STORE IN RECORD ENTRY           49770015
CPUCMPLT LA    TWORK4,REAIOU  ADDR IN CPU RE FOR ACTIVE I/O UNITS       49860015
         SPACE 2                                                        49950015
*    MOVE LOGOUT TO WORD BOUNDARY FOR EREP                              50040015
         MVC   TEMPSPRE(176),RECPULOG                                   50130015
         OI   SWITCH,X40       INDICATE LOGOUT IN THE         IE  53354 50180021
*             COMMON AREA WAS ADJUSTED BY 4 BYTES             IE  53354 50190021
*                                                                       50220015
         B     TACTIO2                                                  50310015
*                                                                       50400015
         EJECT                                                          50420021
*   THE FOLLOWING THREE SECTIONS ARE USED ONLY IF AN INBOARD RECORD IS  50440021
*         NEEDED TO BE COMPLETE.                                        50460021
**** LOCATE UCB AND LAST REQUEST ELEMENT                                50490015
*                                                                       50580015
*                                                                       50670015
TINBOARD LH    TWORK2,RECUA        GET CUA                              50760015
         LTR   TWORK2,TWORK2            CHECK FOR ZERO CUA              50790019
         BZ    CUAEXIT                  ILLEGAL CUA                     50820019
         L     TWORK1,CVTILK2      ADDR OF TWO-BYTE UCB ADDRESS LIST    50850015
         LA    TWORK3,X'7FF'       CHANNEL/UNIT ADDRESS MASK            50940015
TFINDUCB LH    TWORK4,0(TWORK1)    LOAD UCB ADDRESS                     51030015
         LA    TWORK1,2(TWORK1)    UPDATE UCB POINTER ADDRESS           51120015
         LTR   TWORK4,TWORK4       TEST FOR LAST UCB ADDRESS            51210015
         BZ    TFINDUCB          TO RETURN TO NEXT UCB IF ZEROS    8420 51240019
*                                 ARE FOUND IN THE UCB ADDRESS LIST8420 51270019
         BP    COMPRCUA          A POSITIVE ADD IS FOUND           8420 51300019
CUAEXIT  EQU   *                                                        51340019
         OI    RECTLIND,X'20'      SET ILLEGAL CUA                      51390015
         BC    15,FAILCCW          BR- CUA NOT FOUND IN UCBS            51480015
COMPRCUA EQU   *                                                   8420 51510019
         TM    D2(TWORK4),XFF      TEST IF A REAL UCB              8420 51540019
         BNO   CUAEXIT            NOT VALID  UCB                   8420 51570019
         LH    TWORK5,TUCBCUA(TWORK4)   LOAD CUA FROM UCB          8420 51600019
         NR    TWORK5,TWORK3       CLEAR FLAGS IN UCB CUA FIELD         51660015
         CLR   TWORK5,TWORK2       COMPARE BOTH CUA'S                   51750015
         BC    7,TFINDUCB          BR - NOT CORRECT UCB                 51840015
         SPACE 2                                                        51930015
*                                                                       52020015
****  LOCATE FIRST CCW OF FAILING CHAIN                                 52110015
*                                                                       52200015
         SPACE                                                          52290015
         TM    TUCBACT(TWORK4),X'20'    TEST RQE AVAILABLE              52380015
         BC    8,TACTIO                 BB- NONE AVAILABLE              52470015
         LH    TWORK4,TUCBF12(TWORK4)   LOCATE KQE POINTER              52560015
         L     TWORK4,TIOBPTR(TWORK4)   GET IOB PTR FROM RQE            52650015
         L     TWORK4,STARTADR(TWORK4)  GET FIRST CCW PTR               52740015
         MVC   RECCW1(8),0(TWORK4)      MOVE FIRST CCW INTO RE AREA     52830015
         SPACE                                                          52920015
*                                                                       53010015
****  DETERMINE FAILING CCW AND MOVE INTO RE                            53100015
*                                                                       53190015
FAILCCW  L     TWORK1,RECSW             GET COMMAND ADDR FROM CSW       53280015
         LTR   TWORK1,TWORK1            CHECK ZERO ADDR                 53310019
         BZ    TACTIO                   ZERO- BR NEXT ROUTINE           53340019
         LA    TWORK2,8                 GET DECREMENT CONSTANT          53370015
         SR    TWORK1,TWORK2            DECREMENT  COMMAND ADDR         53460015
         LA    TWORK1,0(TWORK1)         CLEAR HIGH ORDER BYTE           53550015
         CL    TWORK1,CVTMZ00           COMPARE FOR LEGAL ADDRESS       53640015
         BC    11,TACTIO                                                53730015
         TM    RECSW+3,X'07'            INSURE DOUBLE WORD BOUNDARY     53820015
         BC    5,TACTIO                                                 53910015
         MVC   RECCW2(8),0(TWORK1)      MOVE FAILING CCW TO RE AREA     54000015
*                                                                       54090015
*                                                                       54180015
****  MOVE ACTIVE I/O UNIT ADDRESSES TO RECORD ENTRY                    54270015
*                                                                       54360015
TACTIO   LA    TWORK4,REACTIO      ADDR IN I/O RE FOR ACTIVE UNITS      54450015
TACTIO2  EQU   *                                                        54510020
         LA    TWORK3,D8     MAX I/O UNIT ADDRESSES SAVED         39987 54570020
         L     TWORK2,CVTILK2      ADDR OF TWO-BYTE UCB ADDRESS LIST    54630015
*                                                                       54720015
TUCBTEST LH    TWORK1,0(TWORK2)    GET UCB POINTER                      54810015
         LA    TWORK2,2(TWORK2)    UPDATE UCB POINTER ADDRESS           54900015
         LTR   TWORK1,TWORK1       TEST FOR END OF UCB POINTER TABLE    54990015
         BC    4,TCHASGN           BR--END, STORE CHANNEL ASSIGNMENTS   55080015
         BC    8,TUCBTEST          BR IF DUMMY ZERO ADDRESS             55170015
         TM    TUCBACT(TWORK1),X'80' TEST UCB FOR UNIT ACTIVE           55260015
         BC    8,TUCBTEST            BR--NOT ACTIVE, TRY NEXT UCB       55350015
         LH    TWORK1,TUCBCUA(TWORK1) GET CHANNEL/UNIT ADDRESS          55440015
         STH   TWORK1,0(TWORK4)    STORE CUA IN RE AREA                 55530015
         LA    TWORK4,2(TWORK4)    UPDATE RE AREA ADDR                  55620015
         BCT   TWORK3,TUCBTEST     BR, CHK NEXT UCB                     55710015
         SPACE 2                                                        55800015
*                                                                       55890015
****  MOVE SYSTEM CHANNEL CONFIGURATION TO RECORD ENTRY                 55980015
*                                                                       56070015
TCHASGN  L     TWORK4,COMCHASG     ADDR OF CONFIG FROM COMMUN AREA      56160015
         LM    TWORK3,TWORK4,X0(TWORK4)  GET CONFIG                5987 56250020
         CLI   RETYPE,C'C'         IS THIS CPU RECORD                   56340015
         BE    CPURECD       MISS FIRST STORE                      MP   56430017
         STM   TWORK3,TWORK4,RECHASG     SAVE CONFIG IN INBOARD   39987 56490021
         B     TRECMPLT      MISS NEXT STORE                       MP   56550017
CCHINSYS EQU   *                   INBOARD RECORD WITH CCH PRESENT  CCH 56552019
         MVC   TWRTCCW1+D1(D3),REGGPR13+D1  SET UP WCKD CCW        CCH  56555019
         L     TWORK5,REGGPR13          ADDR OF INBOARD RECORD      CCH 56558019
         MVC   0(D5,TWORK5),TLASTTT2   INSERT CCHHR FROM HEADER TO CCH  56560019
**                                       COUNT FIELD IN RECORD     CCH  56562019
         LH    TWORK3,D6(TWORK5)        GET ACTUAL DATA LENGTH      CCH 56566019
         LA    TWORK3,D8(TWORK3)        ADD COUNT AND(KEY=ZERO)   21021 56568021
         STH   TWORK3,TCOUNT            COMPLETE LENGTH             CCH 56570019
***  THE CPU ID FROM CCH INBOARD WILL BE SAME AS MSG(M65MP) OR          56570121
**         CPU ID WILL ALWAYS BE ONE IN A SINGLE PROCESSOR.             56570221
         TM    D84(TWORK5),X08           DID CPU 2 FAIL       IE  47195 56570421
         BO    CPUIDF2            YES                         IE  47195 56570821
         MVI   COMMSG1+X09,XF1    NO-PLACE ID IN MSG          IE  62666 56571221
CCHINSY1 EQU   *                                              IE  47195 56571621
         B     RECMPLT1                 GO WRITE OUT CCH'S RECORD   CCH 56572019
CPUIDF2  EQU   *                                              IE  47195 56574021
         MVI   COMMSG1+X09,XF2    PLACE ID (2) IN MSG         IE  62666 56576021
         B     CCHINSY1           CONTINUE INBOARD PROCESSING IE  47195 56578021
CPURECD  EQU   *                                                   MP   56580017
         STM   TWORK3,TWORK4,RECHASSG      SAVE CONFIG IN CPU ENTR39987 56610021
         MVC   REMCOPSW(8),COMPSA+D48   SAVE OLD MCI PSW                56650019
TRECMPLT EQU   *                                                        56670019
         MVC   TCOUNT(D2),CTFLDDL      GET LENGTH FROM COUNT FIELD      56690019
         OI    RECTLIND+X1,X10 SET EXPANDED CHCANNEL SUPPORT  IE  52708 56700021
*                                   FOR EREP                            56702021
RECMPLT1 EQU   *                                                        56710019
         NI    RECTLIND,X'BF'      TURN REC INCOMPLETE INDICATOR OFF TO 56730019
*                                    INDICATE RE COMPLETE.              56790015
         SPACE 2                                                        56880015
*                                                                       56970015
****       WRITE RECORD ON SYS1.LOGREC                                  57060015
*                                                                     * 57150015
         LA    TWORK5,TWRTCCW           GET ADDR OF WRITE CCW LIST      57330015
         ST    TWORK5,TICADDR           STORE AS TIC ADDR               57420015
         MVC   WRTRETIC(3),TICADDR+1    MOVE TO RE WRITE TIC CCW        57510015
         MVC   CTFLDID(5),TLASTTTR+2    SET CONT FIELD ID FOR RE        57600015
         BAL   TLINK,TIORTN             TO I/O ROUTINE FOR WRITE RE     57690015
         EJECT                                                          57780015
*                                                                       57870015
****    WRITE  END OF FILE (EOF)                                        57960015
*                                                                       58050015
*  EOF MUST BE WRITTEN TO CONFORM TO MOVE/COPY UTILITY'S NEED  FOR A    58140015
*  PARTITIONED  DATA SET.                                               58230015
*     IF THE RECORD WAS NOT WRITTEN ON THE LAST TRACK IN EXTENT, EOF    58320015
*  IS WRITTEN ON LAST TRACK. IF IT IS, EOF IS WRITTEN AS  NEXT RECORD.  58410015
*     WHEN EOF WON'T FIT, IT IS NOT WRITTEN -NO HARM,BECAUSE IT IS THE  58500015
*  END OF THE DATA SET.                                                 58590015
         SPACE 2                                                        58680015
         TM    TFLAGS,THDSWTCH          TEST IF HEAD SWITCHING REQUIRED 58770015
         BC    1,TSWITCH                BR-YES, WRT EOF ON LAST TRACK   58860015
         MVC   TSRCHAD(7),TLASTTTR      MOVE SEARCH ARGUMENT TO BUFFER  58950015
         BC    15,TWRTEOF               WRITE EOF AS NEXT RECORD        59040015
TSWITCH  MVC   TSRCHAD+2(4),TUPLIMIT    MOVE SEARCH ARGUMENT TO BUFFER  59130015
         MVI   TSRCHAD+6,0              SET ID FIELD TO ZERO            59220015
         MVC   TSEEKADR+3(4),TUPLIMIT   MOVE SEEK ADDR  OF LAST TRK     59310015
TWRTEOF  MVC   TEOFREC(4),TSEEKADR+3    MOVE CCHH TO EOF RECORD         59400015
         LA    TWORK5,TEOFCCW           GET ADDR OF WRITE EOF CCW LIST  59490015
         ST    TWORK5,TICADDR           STORE AS TIC ADDR               59580015
         MVC   EOFTIC(3),TICADDR+1      MOVE TO EOF WRITE TIC CCW       59670015
         BAL   TLINK,TIORTN             TO I/O ROUTINE FOR EOF WRITE    59760015
         SPACE 2                                                        59850015
*                                                                       59940015
*** REWRITE UPDATED HEADER RECORD                                       60030015
*                                                                       60120015
         LA    TWORK5,THDRCCW1          GET ADDR OF WRITE HDR CCW LIST  60210015
         ST    TWORK5,TICADDR           STORE AS TIC ADDR               60300015
         MVC   HDRWRTIC(3),TICADDR+1    MOVE TO HDR WRITE TIC CCW       60390015
         MVC   TSEEKADR+1(7),TDSADRSV   PLACE SEEK ADDRESS IN CCW LIST  60480015
         MVC   TSRCHAD(7),TDSADRSV                                      60570015
         BAL   TLINK,TIORTN            TO I/O ROUTINE  FOR HDR WRITE    60660015
         OI    COMNUC+4,X'80'      INDICATE RECORD ENTRY WRITTEN        60750015
         SPACE 2                                                        60840015
*                                                                       60930015
*** NORMAL END                                                          61020015
*      THIS IS THE NORMAL END EXIT FROM THIS MODULE.  IT IS USED WHEN A 61110015
*      CPU RECORD HAS BEEN WRITTEN SUCCESSFULLY, OR WHEN THE CPU RECORD 61200015
*      COULD NOT BE WRITTEN BECAUSE OF LACK OF RECORDING ROOM.  RETURN  61290015
*      IS MADE TO THE ASR NUCLEUS.                                      61380015
         SPACE                                                          61470015
END      EQU   *                                                        61560015
         CLI   RETYPE,C'C'         WAS THIS A CPU RECORDING             61650015
         BNE   TERMINB             BR NO                                61740015
         CLI   COMPSA+115,X'01'    IF YES, DID MCI OCCUR IN CCH         61830015
         BE    TERMCCH             BR YES, TO TERMINATE, CANT RECOVER   61920015
         L     TWORK1,CVTDCB  DCB FOR LOGREC DATA SET USED BY RMS 0MP   61960017
         LA    TWORK1,0(TWORK1)   C IS  SYS1.LOGREC IN             MP   62000017
         TM    OBRBIT(TWORK1),OBRMASK         USE BY OBR           MP   62040017
         BZ    CONTINUE            BR NO - CONTINUE NORMALLY            62100015
         SPACE                                                          62190015
*  CHECK IF MCI IN OBR (IF CURRENT TCB IS OBR, THE SIRB WILL BE OFF     62280015
*                            THAT TCB.)                                 62370015
         L     TWORK1,TOPRBP(TCBREG)  LOAD ADDR OF TOP RB               62460015
         TM    CVTDCB,TMVT         CHK MVT, NO WAIT TCB IN MFT     MP   62490017
         BZ    SIRBSRCH      SKIP NEXT TEST                        MP   62520017
         TM    XRBPSW(TWORK1),WAITBIT  IS THIS A WAIT TCB               62550015
         BO    NOTOBR                BR YES - NO RB  AND CURRENT NOTOBR 62640015
SIRBSRCH TM    TRBSTAB(TWORK1),TSIRB   TEST RB FOR SIRB TYPE            62700015
         BZ    NOTSIRB                 BR NO                            62760015
         TM    TRBSTAB(TWORK1),X'70'   INSURE RB IS SIRB                62820015
         BZ    OBRSIRB                 BR YES -CURRENT IS OBR           62880015
NOTSIRB  TM    TRBSTAB+1(TWORK1),TRBTCB   DOES LINK FIELD PNT TO TCB    62940015
         BC    1,NOTOBR            BR YES, END OF RB LIST, NOT OBR      63000015
         L     TWORK1,TRBLNK(TWORK1)    GET NEXT RB ADDR                63090015
         B     SIRBSRCH           CHECK NEXT RB FOR SIRB TYPE           63180015
*                                                                       63270015
*  CURRENT IS OBR - MCI IN OBR - CHANGE ASR'S RESUME PSW TO EXIT RTN    63360015
OBRSIRB  MVC   COMNUC+13(3),COMOBREX+1                                  63450015
         B     CONTINUE                                                 63540015
*                                                                       63630015
*  CURRENT IS NOT OBR (TASK SWITCH) - CHANGE SIRB PSW TO OBR EXIT RTN   63720015
*    IN THE ASR NUCLEUS.  THIS ROUTINE CAUSES OBR TO BE TERNINATED.     63810015
NOTOBR   L     TWORK1,COMSIRB       GET SIRB ADDRESS                    63900015
         MVC   21(3,TWORK1),COMOBREX+1                                  63990015
         SPACE                                                          64080015
CONTINUE EQU   *                                                        64170015
RETRN    LM    TCVTREG,TNUCREG,TREGSAVE                                 64260015
         TM   SWITCH,X40     THIS MODULE ADJUSTED THE LOGOUT  IE  53354 64262021
         BZ   NOTLOG1            NO- SKIP MOVE                IE  53354 64264021
         TM   SWITCH,X80          HAS LOG BEEN READJUSTED     IE  53354 64270021
         BZ   NOTLOG1       YES-SKIP MOVE                     IE  53354 64280021
         MVC   WORKLOG(D176),TEMPSPRE   MOVE LOG T0 WORK AREA IE  53354 64282021
         MVC   RECPULOG(D176),WORKLOG   MOVE LOG TO CORRECT   IE  53354 64284021
*                                 AREA IN THE MCH COMMON AREA IE  53354 64286021
         OI    SWITCH,X80          SET READJUSTED LOGOUT BIT  IE  53354 64286421
NOTLOG1  EQU  *                                               IE  53354 64288021
         TM    COMMSF,X04       CHECK FOR STORAGE RECONFIGURE      2K   64290018
         BO    PDAR2K               YES-CALLIN2K PDAR MODULE       2K   64320018
         MVC   COMNUC(4),TTRTABLE+2                                     64350015
         LH    R1,TTRTABLE                                              64440015
         BR    R13                                                      64530015
OBRBIT   EQU   299     INDEX FOR LOGREC DCB                        MP   64560017
OBRMASK  EQU   X'08'               OBR-IN-PROGRESS BIT            39987 64570020
PDAR2K   EQU   *                                                   2K   64593018
         MVC   COMNUC(FOUR),NEW2K2     NEW 2K PDAR ADDR            2K   64596018
         LH    R1,NEWPDAR                  ID FOR NEXT MODULE      2K   64599018
         BR    R13                     RETURN TO NUCLUES           2K   64602018
NEW2K2   EQU   NEWPDAR+2                                           2K   64605018
X04      EQU   X'04'                                               2K   64608018
X20      EQU   X'20'                                               2K   64611018
N1       EQU   1                                                   2K   64614018
FOUR     EQU   4                                                   2K   64617018
         SPACE 2                                                        64620015
*                                                                       64710015
*** ERROR TERMINATION                                                   64800015
*                                                                       64890015
*      THIS ERROR EXIT IS TAKEN BECAUSE OF-                             64980015
*        (1) I/O OVERRUN READING HEADRE RECORD                          65070015
*        (2) I/O ERROR IN SECTION 3 I/O ROUTINE, WHILE TRYING TO WRITE  65160015
*           CPU RECORD.                                                 65250015
*       (3) MCI IN CCH (WAIT CODE = AOB).                               65340015
*       (4) CHANNEL INBOARD ERROR RECORDING (WAIT CODE = AOA).          65430015
*                                                                       65520015
*  THE WAIT  CODES ARE SET FOR ASR NUCLEUS, WHICH PUTS THE              65610015
*  MACHINE IN WAIT STATE.  THE I/O ERRORS RETURN TO ASR NUCLEUS,        65700015
*  NORMALLY, WHERE IF THE ERROR IS SEVERE, FURTHER ACTION IS TAKEN.     65790015
         SPACE 2                                                        65880015
TERMCCH  EQU   *                                                    MCS 65940018
         LA    T0,XA0B             WAIT STATE CODE                  MCS 66000018
         MVC   COMMSG0+X1(D16),MCICCH    MOVE MSG TO BUFFER         MCS 66060018
         B     CKWRITE                                                  66150015
TERMNATE EQU   *                                                        66240015
         MVC   MESSAGE(16),CPUIOERR    MOVE MSG TO MOD BUF              66330015
         CLI   RETYPE,C'I'    IS THIS AN INBOARD RECORDING              66420015
         BE    TERMINB        BR YES                                    66510015
         CLI   COMPSA+115,X'01'    MCI OCCUR IN CCH                     66600015
         BE    TERMCCH             BR YES, CANT RECOVER                 66690015
         L     TWORK7,COMPRNT      ADDR OP NEXT BYTE IN BUFFER      MCS 66700018
         MVC   X0(X3,TWORK7),CPUIOERR  MOVE CODE TO BUFFER         MCS  66710018
         LA    TWORK7,X3(TWORK7)     UPD                           MCS  66720018
         ST    TWORK7,COMPRNT      UPDATE PTR                       MCS 66730018
         B     RETRN                                                    66780015
TERMINB  EQU   *                                                        66860018
         LA    T0,XA0A             WAIT STATE CODE                  MCS 66940018
         MVC   COMMSG0+X1(D16),INBIOERR  MOVE MSG TO BUFFER         MCS 67020018
CKWRITE  EQU   *                                                    MCS 67100018
         TM    COMNUC+X4,X80       WAS RECORD WRITTEN                   67180018
         BO    RETURN                                               MCS 67260018
X7       EQU   7                                                        67310018
         MVI   COMMSG0+X7,SEREPCD  SET SEREP CODE                   MCS 67360018
RETURN   EQU   *                                                    MCS 67420018
         TM   SWITCH,X40     THIS MODULE ADJUSTED THE LOGOUT  IE  53354 67430021
         BZ   NOTLOG2            NO- SKIP MOVE                IE  53354 67440021
         TM   SWITCH,X80          HAS LOG BEEN READJUSTED     IE  53354 67470021
         BZ   NOTLOG2       YES-SKIP MOVE                     IE  53354 67480021
         MVC   WORKLOG(D176),TEMPSPRE   MOVE LOG T0 WORK AREA IE  53354 67490021
         MVC   RECPULOG(D176),WORKLOG   MOVE LOG TO CORRECT   IE  53354 67492021
*                                 AREA IN THE MCH COMMON AREA IE  53354 67494021
         OI    SWITCH,X80          SET READJUSTED LOGOUT BIT  IE  53354 67494421
NOTLOG2  EQU  *                                               IE  53354 67496021
         L     TWORK7,COMNUC+4                                          67500015
         LM    TCVTREG,TNUCREG,TREGSAVE                                 67590015
         BR    TWORK7              RETURN TO NUCLEUS                    67680015
         SPACE 2                                                        67770015
         EJECT                                                          68490015
*********************************************************************** 68580015
*                                                                     * 68670015
* SECTION 3 -  I/O ROUTINE                                            * 68760015
*                                                                     * 68850015
*       THIS SECTION PERFORMS THE TIO - SIO - TIO SEQUENCE FOR THE    * 68940015
* CCW LISTS.                                                          * 69030015
*     - THE FIRST TIO CLEARS THE CHANNEL.                             * 69120015
*     - THE SIO INITIATES THE I/O OPERATION.  IF INITIATION IS NOT    * 69210015
*         POSSIBLE, THE TIO - SIO IS REPEATED 10 TIMES, AND THEN      * 69300015
*         CONTROL IS GIVEN TO THE NUCLEUS FOR A SEREP INTERFACE.      * 69390015
**    - THE SECOND TIO LOOPS UNTIL THE I/O OPERATION IS COMPLETED.    * 69480015
*                                                                     * 69570015
*     AN ALTERNATE TRACK MAY BE INDICATED, EITHER BY AN EOF INTER-    * 69660015
* RUPTION,OR BY A CE,DE,UNIT CHECK INTERRUPTION WITH ALT TRK BIT      * 69750015
* IN SENSE DATA.  WHEN EOF AND ALT TRK, THE SEEK ADDRESS DOES NOT     * 69840015
* EQUAL THE R0 ADDRESS. IF BOTH EOF AND ALT TRK BIT,THE SEEK ADDR     * 69930015
* IS SET TO R0 AND THE ENTIRE SEQUENCE IS REPEATED.                   * 70020015
         SPACE 2                                                        70110015
TIORTN   MVC   TIORCB+1(3),TICADDR+1    MOVE CCW START ADDR TO CCW      70200015
         LA    TWORK2,10                GET RETRY COUNT                 70290015
         LH    TWORK4,TSYSCUA      LOAD SYSRES DEVICE ADDRESS FOR I/O   70380015
TSIORTN1 LA    TWORK1,TIORCA             GET START CCW LIST ADDR        70470015
         ST    TWORK1,72                STORE IN CHANNEL ADDRESS WORD   70560015
         SPACE 2                                                        70650015
* TIO TO CLEAR ANY STATUS SO SIO CAN BE ISSUED                          70740015
TIOCLR2  TIO   0(TWORK4)      TEST I/O                                  70830015
         BC    6,TIOCLR2                TIO UNTIL FREE OR STATUS STORED 70920015
       SPACE 2                                                          71010015
* SIO INSTRUCTION                                                       71100015
         SIO   0(TWORK4)      START I/O                                 71190015
         BC    8,TIOINIT4               BR - I/O OPERATION INITIATED    71280015
TRYAGN3  BCT   TWORK2,TSIORTN1          BR - TRY OPERATION AGAIN        71370015
         B     TERMNATE                                                 71460015
         SPACE 2                                                        71550015
* TIO UNTIL OPERATION COMPLETES                                         71640015
TIOINIT4 TIO   0(TWORK4)      TEST I/O                                  71730015
         BC    2,TIOINIT4           BR- I/O OPERATION IN PROGRESS STILL 71820015
*                                       CHAN OR SUB CHANNEL BUSY        71910015
         SPACE 2                                                        72000015
* TEST IF ALTERNATE TRACK IN USE                                        72090015
         TM    68,X'0D'            TEST IF EOF - CE,DE,UNIT EX          72180015
         BC    14,TESTCSW5         BR- NOT END OF FILE                  72270015
         CLC   TSEEKADR+3(4),TBUFR0  COMPARE  R0 AND SEEK ADDR          72360015
         BC    8,TRYAGN3           BR- NOT ALT. TRACK                   72450015
         BC    15,TRKALT7          BR- SET FOR  LAT TRACK               72540015
         SPACE 2                                                        72630015
         SPACE 2                                                        72720015
*  TEST CSW FOR UNIT CHK,DE,OR ERRORS                                   72810015
TESTCSW5 TM    68,6                CHECK DE AND UNIT CHECK              72900015
         BC    1,TSENSE6           BR YES - SENSE AND CHECK FOR ALT TRK 72990015
         TM    68,X'0A'            CHECK CE AND UNIT CHECK              73080015
         BC    1,TSENSE6           BR YES - SENSE AND CHECK FOR ALT TRK 73170015
         TM    68,X'04'            TEST FOR DEVICE END                  73260015
         BC    14,TIOINIT4         BR - NOT DEVICE END                  73350015
         TM    69,X'FF'            CHECK FOR CHANNEL ERRORS             73440015
         BC    7,TRYAGN3           BR FOR RETRY - CHAN ERRORS           73530015
         BCR   15,TLINK            RETURN TO CALLER                     73620015
         SPACE 2                                                        73710015
*                                                                       73800015
****  SENSE TO CHECK FOR ALTERNATE TRACK                                73890015
*                                                                       73980015
TSENSE6  LR    TWORK8,TLINK         SAVE ORIGINAL LINK REG              74070015
         LA    TWORK1,TIORCF  SENSE CCW ADDRESS                         74160015
         ST    TWORK1,72      STORE IN CHANNEL ADDRESS WORD             74250015
         BAL   TLINK,TIOCLR2  BR - PERFORM  SENSE OP                    74340015
         TM    TSENSD,X'02'   CHECK FOR ALT TRK BIT                     74430015
         LR    TLINK,TWORK8        RESTORE ORIGINAL LINKAGE             74520015
         BC    14,TRYAGN3     BR TO COUNT RETRIES                       74610015
         SPACE 2                                                        74700015
*                                                                       74790015
****  SWITCH TO AN ALTERNATE TRACK                                      74880015
*                                                                       74970015
TRKALT7  MVC   TSEEKADR+3(4),TBUFR0          SET ALT TRK SEEK ADDR      75060015
         BC    15,TSIORTN1             SEEK AGAIN                       75150015
         EJECT                                                          75240015
*                                                                       75330015
***** CONSTANTS    **************************************************** 75420015
*                                                                       75510015
         SPACE 5                                                        75600015
TREKEY   DC    X'FF00'   RECORD ENTRY KEY                               75690015
TIDENTFY DC    C'MCH0'                                                  75750015
CCHNAME DC     C'MCI-CCH '    MACHINE CHECK IN CCH                      75810015
        DS    0D                                                        75870015
TD24HRS  DC    X'C5C10000'        24 HOUR PSEUDO CLOCK FACTOR           75960019
TDADJ    DC    X'3A3F0000'        PSEUDO-CLOCK CORRECTION FACTOR        76050019
         SPACE                                                          76140015
TSRCHAD  DC    XL8'0'         SEARCH    ADDRESS                         76230015
TSEEKADR DC    XL8'0'         SEEK ADDRESS                              76320015
TDSADRSV DC    XL8'0'         SAVE AREA FOR SYS1.LOGREC ADDRESS         76410015
TSENSD   DC    XL8'0'         SENSE DATA AREA                           76500015
TEOFREC  DC    XL4'0'         EOF RECORD                                76590015
         DC    X'FF000000'    ID OF EOF RECORD                          76680015
TBUFR0   DC    F'0'           R0  BUFFER                                76770015
WORKAREA DC    F'0'      CCW  DATA ADDRESS WORK AREA                    76860015
TICADDR  DC    XL4'0'         CCW START ADDRESS FOR TIC                 76950015
         SPACE 2                                                        77040015
MESSAGE  DC    2D'0'                                                    77130015
FUL90MSG DC    C'060'         LOGREC IS 90 PERCENT FULL           21021 77140021
TFULLMSG DC    C'033'              RUN EREP MSG CODE                MCS 77150018
CPUIOERR DC    C'028'              I/O ERR  MSG CODE                MCS 77170018
X0         EQU   0                                                      77190018
X3         EQU   X'03'                                                  77210018
XA0B     EQU   X'A0B'                                                   77230018
XA0A     EQU   X'A0A'                                                   77250018
D16      EQU   16                                                       77270018
X1       EQU   1                                                   MCS  77290018
X4       EQU   4                                                        77310018
X6       EQU   6                                                        77330018
X09     EQU    X'09'                                              62666 77332021
X10     EQU     X'10'                                                   77340021
X40     EQU    X'40'                                                    77342021
X80      EQU   X'80'                                                    77350018
XF1      EQU   X'F1'              CPU ID ONE                  IE  47195 77360021
XF2      EQU   X'F2'              CPU ID TWO                  IE  47195 77370021
X08      EQU   X'08'                                          IE  47195 77380021
D84      EQU   84                 MP FIELD IN INBOARD RECORD  IE  47195 77390021
MCICCH   DC    C'IGF012W  MCI-CCH'                                      77400015
INBIOERR DC    C'IGF013W CHAN ERR'                                      77490015
SEREPCD  EQU   C'S'                                                     77580015
SWITCH   DC   X'0'           LOCAL BIT SWITCHES               IE  53354 77670021
*                    80=LOGOUT READJUSTED                     IE  53354 77720021
*                    40=LOGOUT ADJUSTED                       IE  53354 77730021
WORKLOG DC    50F'0' TEMPORARY LOG ADJUSTMENT AREA            IE  53354 77850021
         EJECT                                                          77940015
*                                                                       78030015
****  CCW LISTS                                                         78120015
*                                                                       78210015
*     THE FOLLOWING CCWS  DIRECT ALL I/O DATA TRANSMISSION.  THE ADDR   78300015
*     FIELDS (TSRCHAD, TSEEKADR,  TIORCB+1=TICADDR) ARE DYNAMICALLY     78390015
*     SET BY THE MODULE.  THE ADDRESSES OF THESE ADDR FIELDS            78480015
*     ARE STORED IN THE CCWS IN SECTION 1 OF THIS MODULE.               78570015
         SPACE 2                                                        78660015
*  COMMON SEEK AND READ R0 ROUTINE                                      78750015
         DS    0D                                                       78840015
TIORCA   DC    X'07'     SEEK COMMAND                                   78930015
         DC    XL3'0'    SEEK ADDRESS                                   79020015
         DC    X'40'     COMMAND CHAINING                               79110015
         DC    XL2'0'    NOT USED                                       79200015
         DC    X'06'     COUNT                                          79290015
         SPACE                                                          79380015
         DC    X'16'     READ R0 COMMAND                                79470015
R0BUF    DC    XL3'0'    R0 BUFFER ADDRESS                              79560015
         DC    X'60'     COMMAND CHAINING AND SILI                      79650015
         DC    XL2'0'    NOT USED                                       79740015
         DC    X'08'     COUNT                                          79830015
         SPACE                                                          79920015
TIORCB   DC    X'08'     TRANSFER IN CHANNEL COMMAND                    80010015
         DC    XL3'0'    TIC ADDRESS                                    80100015
         DC    X'40'     CMND CHNG                                      80190015
         DC    XL2'0'    NOT USED                                       80280015
         DC    X'01'     COUNT                                          80370015
         SPACE 5                                                        80460015
*  SENSE DAD                                                            80550015
         SPACE                                                          80640015
TIORCF   DC    X'04'     SENSE I/O COMMAND                              80730015
         DC    XL3'0'    SENSE DATA AREA ADDRESS                        80820015
         DC    X'20'     SILI                                           80910015
         DC    XL2'0'    NOT USED                                       81000015
         DC    X'04'     COUNT                                          81090015
         SPACE 5                                                        81180015
*  READ  HEADER  RECORD                                                 81270015
THDRCCW  DC    X'31'     SEARCH ON ID EQUAL COMMAND                     81360015
         DC    XL3'0'    SEARCH ADDRESS                                 81450015
         DC    X'40'     CMND CHNG                                      81540015
         DC    XL2'0'    NOT USED                                       81630015
         DC    X'05'     COUNT                                          81720015
         SPACE                                                          81810015
         DC    X'08'     TRANSFER IN CHANNEL COMMAND                    81900015
HDRDTIC  DC    XL3'0'    THORCCW ADDRESS                                81990015
         DC    X'40'     CMND CHNG                                      82080015
         DC    XL2'0'    NOT USED                                       82170015
         DC    X'01'     COUNT                                          82260015
         SPACE                                                          82350015
         DC    X'06'     READ COMMAND TO READ HEADER RECORD             82440015
RDHDR    DC    XL3'0'    HEADER RECORD AREA ADDRESS                     82530015
         DC    X'00'                                                    82620015
         DC    XL2'0'    NOT USED                                       82710015
         DC    X'28'         COUNT                                21021 82800021
         SPACE 5                                                        82890015
*  WRITE HEADER RECORD                                                  82980015
         SPACE 2                                                        83070015
THDRCCW1 DC    X'31'     SEARCH ON ID EQUAL COMMAND                     83160015
         DC    XL3'0'    SEARCH ADDRESS                                 83250015
         DC    X'40'     CMND CHNG                                      83340015
         DC    XL2'0'    NOT USED                                       83430015
         DC    X'05'     COUNT                                          83520015
         SPACE                                                          83610015
         DC    X'08'     TRANSFER IN CHANNEL COMMAND                    83700015
HDRWRTIC DC    XL3'0'    THDRCCW1 ADDRESS                               83790015
         DC    X'40'     CMND CHNG                                      83880015
         DC    XL2'0'    NOT USED                                       83970015
         DC    X'01'     COUNT                                          84060015
         SPACE                                                          84150015
         DC    X'05'     WRITE COMMAND TO WRITE HEADER                  84240015
WRTHDR   DC    XL3'0'    HEADER RECORD AREA ADDRESS                     84330015
         DC    X'00'                                                    84420015
         DC    XL2'0'    NOT USED                                       84510015
         DC    X'28'         COUNT                                21021 84600021
         EJECT                                                          84690015
*  WRITE  RECORD  ENTRY                                                 84780015
         SPACE                                                          84870015
TWRTCCW  DC    X'31'     SEARCH ON ID EQUAL COMMAND                     84960015
         DC    XL3'0'    SEARCH ADDRESS                                 85050015
         DC    X'40'     CMND CHNG                                      85140015
         DC    XL2'0'    NOT USED                                       85230015
         DC    X'05'     COUNT                                          85320015
         SPACE                                                          85410015
         DC    X'08'     TRANSFER IN CHANNEL COMMAND                    85500015
WRTRETIC DC    XL3'0'    TWRTCCW ADDRESS                                85590015
         DC    X'40'     CMND CHNG                                      85680015
         DC    XL2'0'    NOT USED                                       85770015
         DC    X'01'     COUNT                                          85860015
         SPACE                                                          85950015
TWRTCCW1 DC    X'1D'     WRITE COUNT, KEY, DATA COMMAND                 86040015
         DC    XL3'0'    COUNT,KEY, DATA ADDRESS                        86130015
         DC    X'2000'                                                  86220015
TCOUNT   DC    XL2'0'         COUNT(8+(KEY=0)+ DATA LENGTH)       21021 86310021
         SPACE 5                                                        86400015
*    WRITE  EOF                                                         86490015
         SPACE                                                          86580015
TEOFCCW  DC    X'31'     SEARCH ON ID EQUAL COMMAND                     86670015
         DC    XL3'0'    SEARCH ADDRESS                                 86760015
         DC    X'40'     CMND CHNG                                      86850015
         DC    XL2'0'    NOT USED                                       86940015
         DC    X'05'     COUNT                                          87030015
         SPACE                                                          87120015
         DC    X'08'     TRANSFER IN CHANNEL COMMAND                    87210015
EOFTIC   DC    XL3'0'    TEOFCCW ADDRESS                                87300015
         DC    X'40'     CMND CHNG                                      87390015
         DC    XL2'0'    NOT USED                                       87480015
         DC    X'01'     COUNT                                          87570015
         SPACE                                                          87660015
         DC    X'1D'     WRITE COUNT,KEY, DATA,COMMAND                  87750015
EOFRECAD DC    XL3'0'    EOF RECORD AREA ADDRESS                        87840015
         DC    X'00'                                                    87930015
         DC    XL2'0'    NOT USED                                       88020015
         DC    X'08'     COUNT                                          88110015
         EJECT                                                          88200015
*                                                                       88290015
****     HEADER RECORD FROM SYS1.LOGREC                                 88380015
*            WHICH IS THE FIRST RECORD ON SYS1.LOGREC AND THIS IS       88440021
*            THE WORKAREA FOR THE FOLLOWING DSECT.                      88500021
THDRREC  DS    10F            AREA FOR HDR                              88560015
HDRKEY   EQU   THDRREC+0           HEADER KEY                     21021 88600021
LOWLIMIT EQU   THDRREC+2           LOW CCHH OF EXTENT             21021 88640021
TUPLIMIT EQU   THDRREC+6           HIGH CCHH OF EXTENT            21021 88680021
SPARE    EQU   THDRREC+7           SPARE BYTE                     21021 88720021
RESTAREA EQU   THDRREC+11          RE START AREA-BBCCHHR          21021 88760021
TBYTSREM EQU   THDRREC+18          BYTES REMAINING ON TRACK       21021 88800021
TRKCAP   EQU   THDRREC+20          TOTAL BYTES ON TRACK           21021 88840021
TLASTTTR EQU   THDRREC+22          LAST RE WRITTEN-BB             21021 88880021
TLASTTT2 EQU   THDRREC+24                          CCHH           21021 88920021
TLASTTT6 EQU   THDRREC+28                          R              21021 88960021
TRKPERCY EQU   THDRREC+29          TRACKS PER CYLINDER            21021 89000021
EWMC     EQU   THDRREC+31          90 PERCENT TRACK COUNT         21021 89040021
DEVCODE  EQU   THDRREC+33          DEVICE CODE                    21021 89080021
EWMT     EQU   THDRREC+34          90 PERCENT TRACK-CCHH          21021 89120021
SWITCHES EQU   THDRREC+38          SWITCHES                       21021 89160021
*                                  BIT0=EARLY WARNING MSG IS SCH  21021 89200021
TSFTYBYT EQU   THDRREC+39          CHECK BYTE-'FF'                21021 89240021
         SPACE 5                                                        89370015
*                                                                       89460015
****  INTERNAL MODULE FLAGS                                             89550015
*                                                                       89640015
         SPACE 2                                                        89730015
TFLAGS   DC    X'00'                                                    89820015
*        BIT 1---                                                       89910015
*        BIT 2---                                                       90000015
*        BIT 3---HEADER RECORD READ AND UPDATED SUCCESSFULLY            90090015
*        BIT 4---                                                       90180015
*        BIT 5---                                                       90270015
*        BIT 6---HEAD SWITCHING REQUIRED TO WRITE END OF FILE           90360015
THDSWTCH EQU   X'02'     EOF HEAD SWITCHING REQUIRED                    90450015
THDROK   EQU   X'10'     HEADER RECORD READ AND UPDATED                 90540015
         EJECT                                                          90630015
*                                                                       90720015
****  SYSRES DEVICE TYPE SUBTRACTION CONSTANT TABLE                     90810015
*                                                                       90900015
*        THESE CONSTANTS REPRESENT THE TOTAL BYTE REQUIREMENTS FOR      90990015
*       A M65 RECORD ON A TRACK (CPU OR I/O).     THE CONSTANTS         91080015
*        WERE COMPUTED USING THE GIVEN TRACK CAPACITY FORMULA FOR EACH  91170015
*     DEVICE TYPES. THE MCH DATA LENGTH RECORD IS 534 BYTES(WITHKEY).   91220021
*       THE INBOARD RECORD LENGTH IS 110 BYTES(WITH KEY).               91270021
*     THE USED DEVICE FORMULAS ARE THE FOLLOWING:                       91320021
*        2311       01     61+537(DL)/512                               91370021
*        2301       02     133+ DL                                      91420021
*        2303       03     108+ DL                                      91470021
*        2302       04     61+537(DL)/512                               91520021
*        2321       05     84+537(DL)/512                               91570021
*        2305A(M1)  06     434+ DL         NOT USED ON M65              91620021
*        2305C(M2)  07     91+ DL          NOT USED ON M65              91670021
*        2314       08     101+2137(DL)/2048                            91720021
*        3330       09     135+ DL                                      91770021
         DS    0H                                                       91820021
* MCH-CPU      CONSTANT  DEC  UCBTYPE   *  DEVICE                       91870021
TCONRE   DC    XL2'26E' (622)  X'01'    *   2311                  21021 91920021
         DC    XL2'29B' (667)  X'02'    *   2301                  21021 91970021
         DC    XL2'282' (642)  X'03'    *   2303                  21021 92020021
         DC    XL2'26E' (622)  X'04'    *   2302                  21021 92070021
         DC    XL2'285' (645)  X'05'    *   2321                  21021 92120021
         DC    XL2'000'          DUMMY                                  92250015
         DC    XL2'000'          DUMMY                                  92340015
         DC    XL2'293'        X'08'    *   2314                  21021 92430021
         SPACE 2                                                        92520021
*INBOARD       CONSTANT       UCBTYPE   *  DEVICE  ONLY USED WHEN       92610021
TCONIO   EQU   *                                  CCH IS NOT IN SYSTEM  92700021
         DC    XL2'B1'  (177)  X'01'    *   2311                  21021 92790021
         DC    XL2'F3'  (243)  X'02'    *   2301                  21021 92880021
         DC    XL2'DA'  (218)  X'03'    *   2303                  21021 92970021
         DC    XL2'B1'  (177)  X'04'    *   2302                  21021 93060021
         DC    XL2'C8'  (200)  X'05'    *   2321                  21021 93150021
         DC    XL2'0'            DUMMY                                  93330015
         DC    XL2'0'            DUMMY                                  93420015
         DC    XL2'D8'  (216)  X'08'    *   2314                  21021 93920021
CPU65    DC    X'021E'  (542)      176                                  94500015
IO65     DC    X'0076'       (118)  RECORD LENGHT(DATA,KEY,COUNT)  2K   95220018
TREGSAVE DC    D'0'                                                     95580015
**    MAITENANCE AREA                                                   95588021
MAITID   DC    CL8'IGFASR01'           CORE IDENTIFER                   95596021
MAINT    DC    S(*)                    DISPLACEMENT                     95604021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 95612021
         CNOP  4,8                                                      95620015
         DC    C'ASR'                                                   95670015
TABLOCAT DC    X'01'                                                    95760015
         END                                                            95850015
