         LCLA  &LEV,&REL                                                00010021
&LEV     SETA  41                                                       00020000
&REL     SETA  21                                                       00030021
&REL&LEV TITLE 'IGFASR0A LEVEL &LEV RMS-MCH CLR CHN MODULE-SYSRES'      00080021
IGFASR0A CSECT                                                          00140015
         EJECT                                                          00140915
* MODULE NAME...IGFASR0A                                                00141815
*                                                                       00142220
*STATUS/CHANGE LEVEL                                                    00142621
*                                                                       00142715
* FUNCTION/OPERATION...                                                 00143615
*    1. TO CLEAR A CHANNEL PATH TO SYSRES AND CONSOLE DEVICES AT INIT-  00144515
*       IAL ENTRY TO MCH. THIS INVOLVES SAVING NECESSARY I/O INTERRUPTS 00145415
*       SO THAT AN I/O OPERATION CAN BE ISSUED TO THE DEVICE WITHOUT    00146315
*       LOSS OF THE PREVIOUS CHANNEL ENVIRONMENT. BASIC OPERATION OF    00147215
*       THIS ROUTINE...                                                 00148115
*       A) RUNS ENTIRELY DISABLED FOR I/O INTERRUPTIONS                 00149015
*       B) USES TIO INSTRUCTION FOR CHECKING/SAVING INTERRUPTS          00149915
*       C) CLEARS TO SYSRES FIRST, THEN TO CONSOLE                      00150815
*       D) INTERRUPTS ARE SAVED IN I/O INTRPT SAVE QUEUE                00151715
*    2. TO PERFORM THE NORMAL TERMINATION OF MCH BACK TO THE SYSTEM     00152615
*       WHEN THIS MODULE IS REINSTATED AT THE END OF MCH OPERATION.     00153515
*       THERE ARE TWO BASIC WAYS OF RETURNING TO THE SYSTEM...          00154415
*       A) IF THERE WERE NO I/O INTERRUPTS SAVED DURING CLEAR CHANNEL,  00155315
*          CONTROL RETURNS TO THE CODE WHICH HAD ORIGINAL MCI.          00156215
*       B) IF THERE WERE I/O INTERRUPTS SAVED, THEY ARE RETURNED, ONE   00157115
*          AT A TIME TO IOS FOR PROCESSING, THEN THE ENVIRONMENT OF THE 00158015
*          CODE WHICH HAD THE MCI IS SET IN ITS TCB. THE ENVIRONMENT OF 00158915
*          THE TCB CONTAINED IN CVTHEAD IS SET UP AND CONTROL IS PASSED 00159815
*          TO THE DISPATCHER FORCING A TASK SWITCH.                     00160715
*                                                                       00161615
*                                                                       00162515
* ATTRIBUTES...                                                         00163415
*    TRANSIENT MODULE,SERIALLY REUSABLE,OPERATES IN SUPERVISOR MODE     00164315
*                                                                       00165215
*                                                                       00166115
* ENTRY POINTS...                                                       00167015
*    IGFN0001---ENTERED FROM MCHNUC TO CLEAR CHANNEL FUNCTION           00167915
*    IGFN0002---ENTERED FROM MCHNUC TO EXECUTE MCH TERMINATION          00168815
*                                                                       00169715
*                                                                       00170615
* EXITS...                                                              00171515
*    1. CLEAR CHANNEL FUNCTION EXITS TO MCH NUC                         00172415
*    2. TERMINATOR EXITS EITHER TO TO THE CODE WHICH HAD MCI(VIA MCH    00173315
*       RESUME PSW) OR TO THE DISPATCHER.                               00174215
*                                                                       00175115
*                                                                       00176015
* INPUTS...                                                             00176915
*    FOR CLEAR CHANNEL FUNCTION                                         00177815
*       1. RETURN ADDR TO MCH NUC...                                    00178715
*          A) IN COMNUC IF SUCCESSFUL                                   00179615
*          B) IN COMNUC+4 IF UNSUCCESSFUL                               00180515
*       2. ADDRESS OF I/O INTRPT SAVE QUEUE IN GPR2                     00181415
*       3. ADDRESS OF COMM AREA IN GPR 12                               00182315
*       4. COMCVT                                                       00183215
*    FOR TERMINATOR                                                     00184115
*       COMCVT,COMNUC,COMIOQ                                            00185015
*                                                                       00185915
*                                                                       00186815
* OUTPUTS...                                                            00187715
*    COMSYSRS, COMCNSL                                                  00188615
*                                                                       00189515
*                                                                       00190415
* EXTERNAL REFERENCES...                                                00191315
*    NONE                                                               00192215
*                                                                       00193115
*                                                                       00194015
* ERROR CONDITIONS...                                                   00194915
*    ANY I/O ERRORS ENCOUNTERED WHILE CLEARING A CHANNEL PATH WILL      00195815
*    CAUSE AN ERROR MESSAGE TO BE SET UP AND CONTROL RETURNED TO MCHNUC 00196715
*    AT THE EMERGENCY EXIT ROUTINE                                      00197615
*                                                                       00198515
*                                                                       00199415
* TABLES/WORKAREAS...                                                   00200315
*    MCH COMMUNICATION/RECORD ENTRY BUILD AREA, COMIOQ                  00201215
*                                                                       00202115
*                                                                       00203015
* RESTRICTIONS...                                                       00203915
*    1. SYSRES MUST BE CONNECTED TO 2860 SELECTOR CHANNEL               00204815
*    2. CONSOLE MAY BE ATTATCHED TO 2860 OR TO MPX INTEFACE OF 2870     00205715
         EJECT                                                          00206615
         USING CVTDSECT,CVTREG                                          00210015
CVTDSECT DSECT                                                          00280015
         CVT                                                            00350015
         EJECT                                                          00420015
         USING COMMRE,WKR12                                             00490015
COMMRE   DSECT                                                          00560015
         ASRMAC                                                         00630015
         EJECT                                                          00700015
         IEAQFX     65,MCH,1,GENCODE=NO                              MP 00730017
IGFASR0A CSECT                                                          00770015
         USING *,BRMOD                                                  00840015
*********************************************************************** 00910015
*                                                                     * 00980015
*****    CLEAR CHANNEL PATH TO SYSRES / ASR TERMINATOR            ***** 01050018
*                                                                     * 01120015
*********************************************************************** 01190015
         SPACE 2                                                        01260015
********************  ENTRY FOR ASR TERMINATOR  *********************** 01330015
         SPACE 2                                                        01400015
         DS    0H                                                       01470015
IGFN0002 EQU   *                                                        01540015
         BC    15,NTERM00                                               01610015
         SPACE 3                                                        01680015
*****    ENTRY FOR CLEAR CHANNEL PATH TO SYSRES                   ***** 01750018
         SPACE 1                                                        01820015
* GPR USAGES FOR THIS ROUTINE ARE...                                  * 01890015
* GPR 1 --CONTAINS CUA OF CURRENT DEVICE UNDER TIO OPERATION          * 01960015
* GPR 2 --CONTAINS CURRENT POINTER TO I/O INTERRUPT SAVE QUEUE        * 02030015
* GPR 3 --CONTAINS CURRENT TIO LOOP COUNT                             * 02100015
* GPR 4 --LINK REG TO QUEUE SAVED I/O INTERRUPT SUBROUTINE            * 02170015
* GPR 7 --LINK REG TO CSW ERROR CHECK SUBROUTINE                      * 02240015
* GPR 8 --CONTAINS ADDRESS OF CURRENT UCB                             * 02310015
* GPR 9 --CONTAINS ADDRESS OF CURRENT UCB POINTER                     * 02380015
* GPR 10--BASE REG FOR THE CVT DSECT                                  * 02450015
* GPR 14--BASE REG FOR ASR NUCLEUS                                    * 02520015
* GPR 15--BASE REG FOR THIS ROUTINE                                   * 02590015
*********************************************************************** 02660015
         SPACE 1                                                        02730015
* INITIALIZATION                                                        02800015
IGFN0001 EQU   *                                                        02870015
         B     NCLOAD                                                   02940015
NCTTR    EQU   *                                                        03010015
         DC    X'0000'                                                  03080015
         CNOP  0,4                                                      03150015
NCLOAD   EQU   *                                                        03220015
         L     WKR6,CVTSYSAD       GET SYSRES UCB ADDR FROM CVT         03290015
         MVC   NDEVICE(2),UCBCUA(WKR6)       GET SYSRES CUA             03360015
         NI    NDEVICE,X'07'       CLEAR HI-ORDER BITS IN CHNNL BYTE    03430015
         MVC   NDEVICE+2(1),UNITTYPE(WKR6)   SAVE UNIT TYPE             03500015
         MVC   COMSYSRS(4),NDEVICE      SAVE CUA IN COMM AREA           03570015
         TM    COMMSF,X'10'        CHK MULTIPROCESSING MODE          MP 03574018
         BZ    NCLR080             GO IF NOT                         MP 03578018
         TM    COMMSF,X'03'        CHK SHARED MODE                   MP 03582018
         BNZ   NCLR080            GO IF NOT                          MP 03586018
         SR    WKR3,WKR3                                             MP 03591017
         IC    WKR3,NDEVICE        GET CHANNEL NUMBER PORTION OF CUA MP 03598017
         SLL   WKR3,WKR1      DOUBLED                              MP   03605017
         TM    CHRECNUC-IPLPSW(WKR3),SEVEG  CHK IND.OF NOT-AVAIL    MP  03612017
         BNZ   NEROUT1             GO IF NOT AVAILABLE              MCS 03619018
NCLR080  EQU   *                                                     MP 03626017
         ST    WKR2,NIOQADDR       SAVE STARTING IOQ ADDR               03640015
         L     WKR9,CVTILK2        ADDR OF 1ST TWO BYTE UCB POINTER     03710015
         MVI   NSW2,X'00'          CLEAR PGM SWITCH                     03780015
         XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE AREA           03850015
         MVC   NCUTEST,NDEVICE+1   GET UA PORTION                       04060015
         CLI   NDEVICE+2,N2301     IS SYSRES A 2301 DRUM                04130015
         BC    EQ,NCU5BITS         --YES-CU ADDR IS HI-ORDER 5 BITS     04200015
*                                  --NO-CU ADDR IS HI-ORDER 4 BITS      04270015
         NI    NCUTEST,X'F0'       SET CU ADDR                          04340015
         MVI   NCUMASK,X'F0'        AND CU MASK                         04410015
         SPACE 2                                                        04550015
         SPACE 5                                                        06090015
NCLR2860 LH    WKR1,NDEVICE        SET CUA IN WORK REG                  06160015
****************                                                        06230015
* ISSUE TIO TO DEVICE--DETERMINE INITIAL STATUS                         06300015
         TIO   0(WKR1)             TIO TO DEVICE                        06370015
         BC    NOTOPER,NEROUT1     --NOT OPERATIONAL                MCS 06440018
         BC    BUSY,NSCNUCB0       --BUSY--GO TO SCAN UCB SUBR          06510015
         BC    AVAIL,NCLROK01      --AVAILABLE--PATH IS CLEAR           06580015
*                                  --CSW STORED--BEGIN CSW ANALYSIS     06650015
NCLR015  BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHK SUBROUTINE       06720015
         SPACE 1                                                        06790015
*        RETURN TO HERE--CSW HAS NO CATASTROPHIC ERRORS                 06860015
         TM    NCSWUS1,X'2C'       TEST CE,CUE,DE--ON/OFF/MOXED         06930015
         BC    ALLON,NCLR023         ALL ARE ON                         07000015
         BC    ALLOFF,NCLR002        ALL ARE OFF--NOW CHK FOR B,SM      07070015
*                                                                       07140015
         TM    NCSWUS1,X'0C'       TEST CE,DE--ON/OFF/MIXED             07210015
         BC    ALLON,NCLR023         BOTH ARE ON (CE,DE NOT CUE)        07280015
         BC    ALLOFF,NCLR003        BOTH ARE OFF (CUE ON ALONE)        07350015
*                                                                       07420015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      07490015
         BC    ALLON,NCLR023         ON (DE,NOT CE,CUE DON'T CARE)      07560015
*        DE IS OFF, CE IS ON, CUE DON'T KNOW YES                        07630015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     07700015
         BC    ALLON,NCLR004         ON (CE,CUE,NOT DE)                 07770015
         SPACE 1                                                        07840015
*        CE IS ON ALONE--MUST NOW GIVE TIO TO DEVICE FOR DE             07910015
         OI    NUSSAVE,X'08'       SET CE IN CSW UNIT STATUS SAVE BYTE  07980015
         SPACE 2                                                        08050015
* NOW ISSUE TIO TO DEVICE FOR POSSIBLE PENDING DE                       08120015
         SPACE 1                                                        08190015
NTIOSYS1 L     WKR3,NCNTR1         INITIALIZE LOOP COUNT                08260015
NTIOSYS2 TIO   0(WKR1)             TIO TO DEVICE                        08330015
         BC    NOTOPER,NEROUT1     --NOT OPERATIONAL                MCS 08400018
         BC    BUSY,NEROUT1     ***--BUSY--SHOULD NEVER OCCUR       MCS 08470018
         BC    AVAIL,NCLR031       --AVAILABLE                          08540015
         SPACE 1                                                        08610015
*        CSW STORED--BEGIN CSW ANALYSIS                                 08680015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHK SUBROUTINE       08750015
         SPACE 1                                                        08820015
*        RETURN TO HERE--CSW HAS NO CATASTROPHIC ERRORS                 08890015
         SPACE 1                                                        08960015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      09030015
         BC    ALLOFF,NCLR006        OFF--GO CHK LOOP COUNT             09100015
NCLR032  EQU   *                                                        09130015
         OC    NCSWUS1(2),NUSSAVE  OR STATUS SAVE BYTES INTO CSW        09170015
NCLR001  BC    15,NCLR023          GO Q THE INTRPT                      09270015
         SPACE 1                                                        09380015
NCLR006  BCT   WKR3,NTIOSYS2       REPEAT IF COUNT NOT ZERO             09450015
         SPACE 2                                                        09520015
         BC    15,NEROUT1          COUNT ZERO                       MCS 09560018
         SPACE 2                                                        09600015
NCLR031  EQU   *                                                        09610015
         CLC   NSTATSV(2),CLEARUA  ANY STATUS TO Q                      09620015
         BC    EQ,NCLROK03         BR IF NO                             09630015
         BC    15,NCLR032          Q THE STATUS                         09640015
         SPACE 1                                                        09660015
NCU5BITS NI    NCUTEST,X'F8'       SET CU ADDR                          09730015
         MVI   NCUMASK,X'F8'        AND CU MASK                         09800015
         B     NCLR2860                                             MCS 09870018
         SPACE 1                                                        09940015
         EJECT                                                          10150015
* CUE ON ALONE--MUST TIO DEVICE FOR POSSIBLE AVAILABLE OR DE            10220015
         SPACE 2                                                        10290015
NCLR003  OI    NUSSAVE,X'20'       SET CUE IN CSW UNIT STATUS SAVE BYTE 10360015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE               10430015
         SPACE 2                                                        10500015
*        CUE AND CE ON--MUST NOW GIVE TIO TO DEVICE FOR DE              10570015
NCLR004  OI    NUSSAVE,X'28'       SET CE+CUE IN CSW STATUS SAVE BYTE   10640015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE               10710015
         SPACE 2                                                        10780015
         SPACE 2                                                        11130015
* INITIAL TIO TO DEVICE FOUND CE,CUE,DE ALL OFF.                        11200015
* MUST NOW CHECK THE BUSY(B) AND STATUS MODIFIER(SM) BITS.              11270015
         SPACE 1                                                        11340015
NCLR002  TM    NCSWUS1,X'50'       TEST B,SM--ON/OFF/MIXED              11410015
         BC    ALLOFF,NEROUT1   *** BOTH OFF--SHOULD NEVER OCCUR    MCS 11480018
         BC    ALLON,NCUSCAN         BOTH ON--GO TO CNTRL UNIT SCAN     11550015
         TM    NCSWUS1,X'10'       TEST B--ON/OFF                       11620015
         BC    OFF,NEROUT1      *** OFF(SM ALONE)--SHOULD NEVER     MCS 11690018
         SPACE 1                                                        11760015
*        BUSY IS ON ALONE--THIS IMPLIES THAT THERE WILL BE A DE FROM    11830015
*        DEVICE. MUST GIVE TIO TO DEVICE FOR DE.                        11900015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE FOR DE        11970015
         EJECT                                                          12040015
*********************************************************************** 12110015
* THE INITIAL TIO TO DEVICE GAVE B+SM BITS. IF THE DEVICE DOES NOT    * 12180015
* SHARE A CONTROL UNIT, THEN THIS CU/DEVICE IS BUSY AND THE PGM MUST  * 12250015
* ISSUE TIO'S TILL DE COMES IN. IF CU IS SHARED, THIS MEANS...        * 12320015
* 1. CHANNEL IS AVAILABLE                                             * 12390015
* 2. CONTROL UNIT IS BUSY WITH EITHER...                              * 12460015
*        A. DEVICE                                                    * 12530015
*        B. SOME OTHER DEVICE ATTAHCHED TO THIS CONTROL UNIT          * 12600015
*                                                                     * 12670015
* THE PROGRAM MUST NOW FIND WHICH DEVICE IS KEEPING THE CU BUSY, BY   * 12740015
* ISSUING TIO'S TO ALL DEVICES ON THIS CU. THE CU SCAN IS MAINTAINED  * 12810015
* UNTIL ONE OF THE FOLLOWING OCCURS...                                * 12880015
* 1. CUE AND/OR DE IS RECEIVED                                        * 12950015
* 2. DEVICE IS FOUND NOT OPERATIONAL (CC=3)                           * 13020015
* 3. SCAN COUNT IS EXHAUSTED                                          * 13090015
*********************************************************************** 13160015
         SPACE 3                                                        13230015
NCUSCAN  CLI   NCUTEST,X'FF'       DOES DEVICE SHARE A CU               13300015
         BC    EQ,NTIOSYS1         --NO                                 13370015
         L     WKR3,NCNTR1         INITIALIZE SCAN LOOP COUNT           13440015
         OI    NSW2,X'20'          SET SAME CU AS DEVICE BIT            13510015
NCUSCAN1 BC    15,NSCNUCB1         GO TO SCAN UCB SUBR                  13580015
         SPACE 2                                                        13650015
*        RETURN TO HERE--CUA IS IN WKR1                                 13720015
NCUSCAN2 TIO   0(WKR1)             ISSUE TIO                            13790015
         BC    NOTOPER,NCLR007       NOT OPERATIONAL                    13860015
         BC    BUSY,NEROUT1     ***SHOULD NEVER OCCUR               MCS 13930018
         BC    AVAIL,NCLR008         AVAILABLE                          14000015
         SPACE 1                                                        14070015
*        CSW STORED--BEGIN CSW ANALYSIS                                 14140015
         BAL   WKR7,NCSWERCK       GOT O CSW ERROR CHK SUBROUTINE       14210015
         SPACE 1                                                        14280015
*        RETURN TO HERE-CSW HAS NO CATASTROPHIC ERRORS                  14350015
         TM    NCSWUS1,X'50'       TEST B,SM--ON/OFF                    14420015
         BC    ALLON,NCUSCAN1        BOTH ON--CU STILL BUSY OR DEVICE   14490015
*                                    KEEPING CU BUSY HASN'T YET         14560015
*                                    BEEN FOUND.                        14630015
         TM    NCSWUS1,X'24'       TEST CUE,DE--ON/OFF/MIXED            14700015
         BC    ALLOFF,NCLR030        BOTH OFF                           14770015
         BC    ALLON,NCLR009         BOTH ON--CU AND DEVICE ARE FREE    14840015
*                                                                       14910015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      14980015
         BC    OFF,NCLR010           OFF--CUE ON ALONE                  15050015
         SPACE 1                                                        15120015
*        DE IS ON--DEVICE IS NOW FREE                                   15190015
NCLR009  BAL   WKR4,NIOQ           GO TO QUEUE I/O INTRPT SUBR.         15260015
         CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEAR           15330015
         BC    EQ,NCLR050          BR IF YES                            15400015
NCLR021  LA    WKR2,10(WKR2)         NO-STEP I/O QUEUE POINTER          15470015
NCLR011  XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE AREA           15540015
         LH    WKR1,NDEVICE        GET DEVICE CUA                       15680015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE (POSSIBLE DE) 15750015
         SPACE 2                                                        15820015
NCLR010  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         15890015
         BC    NOTEQ,NCLR009       BR IF NO                             15940015
         OI    NUSSAVE,X'20'       SET CUE IN CSW UNIT STATUS SAVE BYTE 15990015
         BC    15,NTIOSYS1         TIO TO DEVICE FOR POSSIBLE DE        16060015
         SPACE 2                                                        16170015
NCLR007  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         16240015
         BC    EQ,NEROUT1          YES--DEVICE IS NOT OPERATIONAL   MCS 16310018
         BC    15,NCUSCAN1         NO--GO TO CU SCAN                    16380015
         SPACE 2                                                        16450015
NCLR008  CH    WKR1,NDEVICE         IS THIS DEVICE TO BE CLEARED        16550015
         BC    NOTEQ,NCUSCAN1        NO--GO TO CU SCAN                  16730015
         BC    15,NCLROK05         YES--PATH IS CLEAR                   16800015
         SPACE 2                                                        16808015
NCLR030  EQU   *                                                        16816015
         TM    NCSWUS1,X'03'       TEST UC/UE                           16824015
         BC    5,NCLR009           BR IF MIXED OR ONES                  16832015
         TM    NCSWCS1,X'F1'       TEST PCI,IL,PGM-PROT-CHAIN CHECK     16840015
         BC    5,NCLR009           BR IF MIXED OR ONES                  16848015
         BC    15,NEROUT1       ***ALL STAT BITS IN CSW ARE OFF     MCS 16858018
         EJECT                                                          16870015
***************  U C B   S C A N   R O U T I N E  ********************* 16940015
*                                                                     * 17010015
* THIS ROUTINE IS ENTERED WHENEVER...                                 * 17080015
* A.  A CC=2 (BUSY) WAS RECEIVED FROM THE INITIAL TIO TO DEVICE.      * 17150015
* B.  ALL DEVICES ATTACHED TO SAME CU AS DEVICE ARE TO BE SCANNED.    * 17220015
*                                                                     * 17290015
* FOR CASE A, ONE OF THE FOLLOWING IS POSSIBLE...                     * 17360015
*     1. THE CHANNEL IS BUSY (BURST MODE OPERATION) WITH EITHER       * 17430015
*        DEVICE TO BE CLEARED OR SOME OTHER DEVICE.                   * 17500015
*     2. THERE IS A PENDING CHANNEL INTERRUPT FROM A DEVICE OTHER     * 17570015
*        THAN THE ONE TO BE CLEARED.                                  * 17640015
* IN EITHER CASE, THE ACTION TO TAKE IS TO CONTINUALLY GIVE TIO'S TO  * 17710015
* ALL DEVICES UNTIL A CSW IS STORED (CC=1). THE CUA'S OF ALL THESE    * 17780015
* DEVICES ARE FOUND BY SCANNING THE UCB TABLES. A SCAN LOOP COUNT IS  * 17850015
* MAINTAINED. IF IT IS EXHAUSTED BEFORE A CC=1 IS RECEIVED, THE PGM   * 17920015
* COULD NOT FIND THE DEVICE KEEPING THE CHANNEL BUSY.                 * 17990015
*                                                                     * 18060015
*********************************************************************** 18130015
         SPACE 3                                                        18200015
NSCNUCB0 L     WKR3,NCNTR1         INITIALIZE SCAN LOOP COUNT           18270015
NSCNUCB1 LH    WKR8,0(WKR9)        LOAD ADDR OF UCB                     18340015
         LA    WKR9,2(WKR9)        STEP TO NEXT UCB POINTER ADDR        18410015
         LTR   WKR8,WKR8           TEST FOR END OF UCB ADDR TABLE       18480015
         BC    4,NCLR012              BR--END OF TABLE                  18550015
         BC    8,NSCNUCB1             BR--ZERO ENTRY--GET NEXT UCB      18620015
         MVC   NUCBCUA(2),UCBCUA(WKR8)  GET CUA FROM UCB                18690015
         NI    NUCBCUA,X'07'       CLEAR HI-ORDER BITS IN CHNNL BYTE    18760015
         LH    WKR1,NUCBCUA        PUT CUA INTO REG                     18830015
         CLC   NUCBCUA(1),NDEVICE  IS THIS SAME CHANNEL AS DEVICE       18900015
         BC    NOTEQ,NSCNUCB1             NO--GET NEXT UCB              18970015
         TM    NSW2,X'20'          SAME CUA AS DEVICE SWITCH-ON/OFF     19040015
         BC    OFF,NCLR013           OFF--ISSUE TIO TO THIS DEVICE      19110015
         NC    NUCBCUA+1(1),NCUMASK  ON--ZERO DEVICE ADDR--CU INTACT    19180015
         CLC   NUCBCUA+1(1),NCUTEST     IS THIS SAME CU AS DEVICE       19250015
         BC    NOTEQ,NSCNUCB1             NO--GET NEXT UCB              19320015
         BC    15,NCUSCAN2              YES--GO BACK TO CU SCAN TIO     19390015
         SPACE 2                                                        19460015
* DEVICE IS ON SAME CHNNL AS DEVICE TO BE CLEARED -GIVE IT A TIO        19530015
         SPACE 1                                                        19600015
NCLR013  TIO   0(WKR1)             ISSUE TIO                            19670015
         BC    NOTOPER,NCLR014       NOT OPERATIONAL                    19740015
         BC    BUSY,NSCNUCB1         BUSY--GET NEXT UCB                 19810015
         BC    AVAIL,NEROUT1    *** SHOULD NEVER OCCUR              MCS 19880018
* CSW STORED--CHNNL INTRPT HAS BEEN FOUND--BEGIN CSW ANALYSIS           19950015
         CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         20020015
         BC    EQ,NCLR015            YES--GO BACK TO DEVICE CSW ANALYS. 20090015
* CHNNL INTERRUPT CAUSED BY DEVICE OTHER THAN ONE TO BE CLEARED         20160015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHECK SUBROUTINE     20230015
         SPACE 1                                                        20300015
* RETURN HERE IF--NO CATASTROPHIC ERRORS IN CSW                         20370015
         TM    NCSWUS1,X'0C'       TEST CE,DE--ON/OFF/MIXED             20440015
         BC    ALLOFF,NEROUT1   *** SHOULD NEVER OCCUR              MCS 20510018
         BC    ALLON,NCLR023       BOTH ON--GO SAVE INTRPT              20580015
         SPACE 1                                                        20650015
         TM    NCSWUS1,X'08'       TEST CE--ON/OFF                      20720015
         BC    OFF,NEROUT1      *** SHOULD NEVER OCCUR              MCS 20790018
         SPACE 1                                                        20860015
* CE ON, DE OFF--DETERMINE IF DEVICE IS ON SAME CU AS DEVICE TO BE CLRD 20930015
         NC    NUCBCUA+1(1),NCUMASK     ZERO DEVICE ADDR-CU INTACT      21000015
         CLC   NUCBCUA+1(1),NCUTEST     ON SAME CU                      21070015
         BC    NOTEQ,NCLR017            --NO                            21140015
         SPACE 1                                                        21210015
* CE WAS RECEIVED FROM DEVICE ON SAME CU--NOW CHECK FOR CUE             21280015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     21350015
         BC    ON,NCLR023            ON--CE+CUE ON                      21420015
         SPACE 1                                                        21490015
* CE IS ON ALONE. CU IS STILL BUSY. MUST GIVE TIO'S TO THIS DEVICE      21560015
* UNTIL CUE AND/OR DE IS RECEIVED. THEN CHECK FOR A POSSIBLE PENDING    21630015
* DE FROM DEVICE TO BE CLEARED.                                         21700015
         SPACE 1                                                        21770015
         OI    NUSSAVE,X'08'       SET CE IN UNIT STATUS SAVE BYTE      21840015
         MVC   NCSWWK2(8),NCSWWK1  MOVE SAVED CSW TO WORK AREA 2        21910015
NCLR019  TIO   0(WKR1)             TIO TO THIS DEVICE                   21980015
         BC    NOTOPER,NCLR018       NOT OPERATIONAL                    22050015
         BC    10,NEROUT1       *** BUSY-AVAIL-SHOULD NEVER OCCUR   MCS 22120018
         SPACE 1                                                        22190015
* CSW STORED-BEGIN ANALYSIS                                             22260015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHECK SUBR.          22330015
* RETURN HERE--CSW HAS NO CATASTROPHIC ERRORS                           22400015
         TM    NCSWUS1,X'50'       TEST B,SM-NOTH ON                    22470015
         BC    ALLON,NCLR019         BOTH ON--CU IS STILL BUSY          22540015
         TM    NCSWUS1,X'24'       TEST CUE,DE--ON/OFF/MIXED            22610015
         BC    ALLOFF,NEROUT1   *** SHOULD NEVER OCCUR              MCS 22680018
         BC    ALLON,NCLR018         BOTH ON-CE,CUE,DE WERE ALL RECEIVD 22750015
         SPACE 1                                                        22820015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     22890015
         BC    ON,NCLR020            ON                                 22960015
* DE WAS RECEIVED (CE WAS PREVIOUSLY RECEIVED)                          23030015
NCLR018  OC    NCSWUS1(2),NUSSAVE  OR STATUS BYTES INTO CSW             23100015
NCLR016  BC    15,NCLR023          Q THE INTRPT                         23200015
         SPACE 2                                                        23310015
* CUE ON,DE OFF (CE WAS PREVIOUSLY RECEIVED)                            23380015
NCLR020  OI    NCSWWK2+4,X'20'     OR CUE INTO SAVED CSW IN WORK AREA 2 23450015
         OC    NCSWWK2+4(2),NSTATSV  PLUS ANY OTHER SAVED STATUS        23520015
         MVC   NCSWWK1(8),NCSWWK2    PUT INTO WORK AREA 1               23590015
         BC    15,NCLR023          Q THE INTRPT                         23660015
         SPACE 3                                                        23730015
* TIO TO DEVICE IN UCB SCAN RTN GAVE CC=3 (NOT OPERATIONAL)             23800015
NCLR014  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         23870015
         BC    EQ,NEROUT1           YES                             MCS 23940018
         BC    15,NSCNUCB1           NO--GET NEXT UCB                   24010015
         SPACE 3                                                        24080015
* CE ON ALONE--DEVICE NOT ON SAME CU AS DEVICE TO BE CLEARED            24150015
NCLR017  CH    WKR1,CNSLADDR       IS THIS CONSOLE                      24220015
         BC    NOTEQ,NCLR023       --NO-GO QUEUE THIS INTERRUPT         24290015
         SPACE 1                                                        24360015
* IF THE ABOVE CONDITION IS EQUAL,THIS MEANS THAT THIS 2860 CLEAR CHNNL 24430015
* ROUTINE IS CURRENTLY CLEARING TO THE SYSRES DEVICE AND THE CONSOLE    24500015
* IS ON THE SAME CHNNL AS SYSRES. CONSOLE PRESENTED A CE ONLY--MUST NOW 24570015
* ISSUE A TIO AND WAIT FOR DE TO COME IN.                               24640015
         OI    NUSSAVE,X'08'       SET CE IN STATUS SAVE                24710015
         L     WKR3,NCNTR1         INITIALIZE TIMING LOOP COUNT         24780015
NCLR025  TIO   0(WKR1)             TIO TO CONSOLE                       24850015
         BC    11,NEROUT1       *** ERROR                           MCS 24920018
*        CSW STORED                                                     24990015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHECK SUBR.          25060015
*        RETURN HERE IF NO CATASTROPHIC ERRORS OR NO UC                 25130015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      25200015
         BC    OFF,NCLR024         --OFF-GO CHECK LOOP COUNT            25270015
         OC    NCSWUS1(2),NSTATSV  'OR' SAVED STATUS INTO CSW           25340015
         OI    NSW2,X'10'          SET CONSOLE CLEARED SWITCH           25410015
NCLR023  BAL   WKR4,NIOQ           QUEUE I/O INTERPT                    25480015
NCLR050  LA    WKR2,10(WKR2)       STEP IOQ POINTER                     25520015
         CLI   NCUTEST,X'FF'       DOES NDEVICE SHARE A CTL UNIT        25560015
         BC    EQ,NTIOSYS1         BR IF NO                             25600015
NCLR022  OI    NSW2,X'20'          SET SAME CU AS NDEVICE SWITCH        25640015
         LH    WKR1,NDEVICE        GET DEVICE CUA                       25690015
         L     WKR3,NCNTR1         SET TIO LOOP COUNT                   25760015
         XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE BYTES          25790015
         BC    15,NCUSCAN2         GO TO CU SCAN                        25830015
         SPACE 3                                                        25900015
NCLR024  BCT   WKR3,NCLR025        BR IF LOOP COUNT NOT ZERO            25970015
         B     NEROUT1             LOOP COUNT EXHAUSTED--ERROR      MCS 26040018
         SPACE 1                                                        26110015
* END OF UCB TABLES--GO CHECK LOOP COUNT                                26180015
NCLR012  BCT   WKR3,*+8            IS LOOP COUNT EXHAUSTED              26250015
         B     NEROUT1             YES                              MCS 26320018
         L     WKR9,CVTILK2        BO--RESET UCB POINTER TO 1ST UCB     26390015
         BC    15,NSCNUCB1         GO BACK TO SCAN                      26460015
         EJECT                                                          26530015
*********************************************************************** 26600015
*                                                                     * 26670015
*******  C S W   E R R O R   C H E C K   S U B R O U T I N E  ********* 26740015
*                                                                     * 26810015
*********************************************************************** 26880015
* CSW ERROR CHECK SUBROUTINE (NEW)                                      26950015
NCSWERCK MVC   NCSWWK1(8),64       SAVE CSW                             27020015
         TM    NCSWCS1,X'0E'       TEST CCC,ICC,CDC--MIXED,ON/OFF       27090015
         BC    5,NEROUT1           --ANY ONE ON---ERROR             MCS 27160018
         TM    NCSWUS1,X'02'       TEST UC--ON/OFF                      27230015
         BC    ON,NCSWER2          --ON                                 27300015
         TM    NCSWUS1,X'80'       TEST ATTENTION                       27510015
         BC    ON,NCSWATT          BR IF ON                             27580015
NCSWEREX NI    68,X'01'            CLEAR UNIT STATUS EXCEPT UE IF ON    27650015
         OC    NSTATSV(2),68       SAVE CSW STATUS                      27720015
         BCR   15,WKR7             RETURN TO CALLER                     27790015
NCSWER2  CH    WKR1,NDEVICE        DID UC OCCUR ON DEVICE TO BE CLEARED 27860015
         BC    EQ,NSNS1            --YES--GO TO SENSE                   27930015
         CH    WKR1,CNSLADDR       DID UC OCCUR ON CONSOLE              28000015
         BC    NOTEQ,NCSWEREX      --NO--EXIT ROUTINE                   28070015
         SPACE 1                                                        28140015
*        SENSE ROUTINE                                                  28210015
         SPACE 1                                                        28280015
NSNS1    OC    NCSWUS1(2),NSTATSV  'OR' STATUS SAVE BYTES AND           28350015
         BAL   WKR4,NIOQ           QUEUE THE INTRPT                     28420015
         LA    WKR5,NSNSRD         GET SENSE READ IN AREA ADDRESS       28490015
         ST    WKR5,NSNSCCW         PUT ADDR INTO CSW                   28560015
         MVI   NSNSCCW,SENSE       SET SENSE OP IN CCW                  28630015
NSNS3    LA    WKR6,NSNSCCW        SET                                  28700015
         ST    WKR6,72                CAW                               28770015
         SIO   0(WKR1)             ISSUE SENSE                          28840015
         BC    NOTOPER,NEROUT1     --NOT OPERATIONAL                MCS 28910018
         BC    AVAIL,NSNS2         --AVAILABLE--SIO IS OK               28980015
*        CSW STORED--ONLY POSSIBLE CORRECT STATUS AT THIS TIME IS DE.   29050015
*        IF DE NOT ON, ASR MUST TERMINATE                               29120015
         TM    68,X'04'            DE--ON/OFF                           29190015
         BC    OFF,NEROUT1         --OFF-SENSE FAILED               MCS 29260018
         OI    6(WKR2),X'04'       SET DE IN PREVIOUSLY SAVED CSW       29330015
         BC    15,NSNS3            DO SENSE AGAIN                       29400015
         SPACE 1                                                        29470015
* SENSE STARTED--NOW GIVE TIO TILL SENSE IS FINISHED                    29540015
         SPACE 1                                                        29610015
NSNS2    TIO   0(WKR1)             TIO                                  29680015
         BC    NOTOPER,NEROUT1     --NOT OPERATIONAL                MCS 29750018
         BC    BUSY,NSNS2          --BUSY                               29820015
         BC    AVAIL,NSNS7         --AVAILABLE                          29890015
*        CSW STORED                                                     29960015
DEUCBITS EQU   68                                                  MP   29990017
SEVEG    EQU   X'78'                                                MP  30020017
TWEN     EQU   X'20'                                                MP  30050017
EIGHTY   EQU   X'80'                                                MP  30080017
SAVD     EQU   REGSGPR+48                                           MP  30110017
SAVD1    EQU   REGSGPR+60                                           MP  30140017
ZERO     EQU   0                                                   MP   30170017
         TM    DEUCBITS,WKR6              TEST DE AND UC            MP  30200017
         BZ    NSNS2               NEITHER ON, LOOP                MP   30230017
NSNS7    EQU   *                                                        30310015
         LA    WKR2,10(WKR2)       STEP IOQ POINTER                     30380015
         CH    WKR1,NDEVICE        WAS SENSE ISSUED TO DEVICE TO BE CLR 30450015
         BC    EQ,NCLREXA          YES-EXIT                         MCS 30520018
         OI    NSW2,X'11'          --NO-SET CNSL CLR+1ST MSG BUFRD SW   30590015
         BC    15,NCLR022          CONTINUE                             31010015
         SPACE 1                                                        31080015
*                                                                       33040015
NCSWATT  BAL   WKR4,NIOQ           Q THE INTERRUPT                      33110015
         LA    WKR2,10(WKR2)       STEP IOQ POINTER                     33150015
         BC    15,NCLREXA                                               33190015
         EJECT                                                          33250015
*************  QUEUE SAVED I/O INTERRUPT SUBROUTINE  ****************** 33320015
*                                                                       33390015
NIOQ     MVC   2(8,WKR2),NCSWWK1   QUEUE THIS CSW                       33460015
         STH   WKR1,0(WKR2)          AND CORRESPONDING CUA              33530015
         BCR   15,WKR4             GO BACK TO CALLER                    33600015
         SPACE 5                                                        33670015
         EJECT                                                          35350015
***************  P A T H   C L E A R   E X I T S  ********************* 35420015
         SPACE 3                                                        35490015
NCLREXA  EQU   *                                                        35560015
NCLROK01 EQU   NCLREXA                                                  35630015
NCLROK03 EQU   NCLREXA                                                  35700015
NCLROK05 EQU   NCLREXA                                                  35770015
         SPACE 1                                                        35840015
         MVI   0(WKR2),X'FF'       SET END-OF-QUEUE INDICATOR           35910015
         SPACE 1                                                        38080015
NCLROUT2 L     WKR6,COMNUC         GET ASRNUC RETURN ADDRESS            38150015
         BCR   15,WKR6             RETURN TO ASRNUC                     38220015
         EJECT                                                          38290015
******************************************************************* MCS 38350018
*        PART OF WTO ROUTINE -- SETS ALL TCB'S,EXCEPT THE CURRENT * MCS 38410018
*              NON-DISPATCHABLE-- LINK REG IS GPR 8               * MCS 38470018
*                                                                 * MCS 38530018
*                                                                 * MCS 38590018
******************************************************************* MCS 38650018
         SPACE 2                                                        38710018
SETTCBS  EQU   *                                                    MCS 38770018
         L     WKR1,CVTTCBP        GET CURRENT                      MCS 38830018
         L     WKR1,X4(WKR1)         TCB ADDRESS                    MCS 38890018
         L     WKR4,X0(WKR1)            GET BR FOR TCB               2K 38900018
         TM    D17(WKR4),X2             IS THIS WAIT TCB             2K 38910018
         BO    WTOEX                    YES, ISSUE NO MESSAGES       2K 38920018
         ST    WKR1,NCURTCB        SAVE CURRENT                     MCS 38950018
         MVC   NSVND(X2),NNONDSP(WKR1) SAVE NON-DISPATCH BYTES      MCS 39010018
         XC    NNONDSP(X2,WKR1),NNONDSP(WKR1) CLEAR TCB DISPATCH    MCS 39070018
         L     WKR4,CVTHEAD            GET TOP TCB ADDR                 39080020
         TM    CVTDCB,X20              MFT SYSTEM                  1541 39090020
         BO    NIOMFTA                 YES/BRANCH                  1541 39110020
         L     WKR5,CVTABEND       ADDR OF SECONDARY CVT            MCS 39190018
         L     WKR6,XC(WKR5)       GET ADDR OF TACT                 MCS 39250018
         L     WKR5,X4(WKR6)       LOAD NO.OF ENTRIES               MCS 39310018
         LA    WKR5,X1(WKR5)       INCREASE COUNT BY ONE            MCS 39370018
         TM    COMMSF,X10          CHK MP MODE                      MCS 39430018
         BZ    NIOR01A             NO, BRANCH                1521   MCS 39490020
         LA    WKR5,X1(WKR5)       INCREASE FOR WAIT TCB            MCS 39550018
         B     NIOR01A             BRANCH                           MCS 39610018
NIOMFTA  EQU   *                                                    MCS 39670018
         SR    WKR5,WKR5           ZERO REG                         MCS 39850018
         LA    WKR5,X2                 TO SKIP MFT-ONE TRANSIENT   2876 39910020
NIOR01A  EQU   *                                                    MCS 39970018
         BCT   WKR5,NIOR03A            TRANSIENT AREA TCB-BRANCH   2876 40030020
         LA    WKR5,X1(WKR5)       COUNT OF ONE FOR NO BRANCH       MCS 40090018
         CLR   WKR1,WKR4           IS THIS CURRENT TCB              MCS 40150018
         BC    EQ,NIOR03A          YES--LEAVE IT ALONE              MCS 40210018
         OI    N33(WKR4),X01     SET MASTER NON-DISPATCH BIT        MCS 40270018
         OI    N173(WKR4),X20          SET TEMP FLAG                MCS 40330018
NIOR03A  L     WKR4,NNXTTCB(WKR4)  GET NEXT TCB ADDR                MCS 40390018
         LTR   WKR4,WKR4           IS THIS LAST TCB                 MCS 40450018
         BNZ   NIOR01A             NO,CONTINUE                      MCS 40510018
         BR    WKR8                YES, RETURN TO CALLER            MCS 40570018
         SPACE 2                                                        40930018
******************************************************************* MCS 40990018
*                                                                 * MCS 41050018
*        PART OF WTO ROUTINE -- RESTORES TCB'S TO ORIGINAL STATE  * MCS 41110018
*                                                                 * MCS 41170018
******************************************************************* MCS 41230018
         SPACE 1                                                        41290018
RSETTCBS EQU   *                                                    MCS 41350018
         L     WKR4,CVTHEAD        GET TOP TCB ADDRESS              MCS 41410018
         L     WKR1,NCURTCB        GET CURRENT TCB ADDR             MCS 41470018
         MVC   NNONDSP(X2,WKR1),NSVND  RESTORE NON-DISPATCH BYTES  MCS  41530018
NIOR05A  CLR   WKR1,WKR4           IS THIS CURRENT TCB              MCS 41590018
         BC    EQ,NIOR06A          YES-LEAVE IT ALONE               MCS 41650018
         NI    N173(WKR4),XDF          TURN OFF TEMP FLAG          2MCS 41710018
         OC    N173(3,WKR4),N173(WKR4)   ANY OTHER FLAGS ON         MCS 41770018
         BNZ   NIOR06A           YES-NOT CLEAR MASTER NON-DISP      MCS 41830018
         NI    N33(WKR4),XFE       CLEAR MASTER NON-DISPATCH BIT    MCS 41890018
NIOR06A  L     WKR4,NNXTTCB(WKR4)  GET NEXT TCB                     MCS 41950018
         LTR   WKR4,WKR4           LAST TCB                         MCS 42010018
         BNZ   NIOR05A             NO CONTINUE                      MCS 42070018
         BR    WKR2                RETURN TO CALLER                 MCS 42130018
         SPACE 3                                                        42190018
******************************************************************* MCS 42250018
*                                                                 * MCS 42310018
*                         WTO ROUTINE                             * MCS 42370018
*                                                                 * MCS 42430018
*        THIS ROUTINE QUEUES  ALL IFORMATION MESSAGES REQUESTED   * MCS 42490018
*        BY THE RMS MODULES, FOR IOS TO HANDLE. THESE MESSAGES    * MCS 42550018
*        ARE QUEUED BY ISSUING SVC 35'S. ALL TCB'S EXCEPT THE     * MCS 42610018
*        CURRENT AREA SET NON-DISPATCHABLE AND THE RETURN PSW     * MCS 42670018
*        IS STORED INTO THE RB. AFTER ALL MESSAGES ARE QUEUED     * MCS 42730018
*        THE STATUS OF THE TCB'S AND RB IS RESTORED.              * MCS 42790018
*                                                                 * MCS 42850018
******************************************************************* MCS 42910018
         SPACE 2                                                        42970018
WTOCALL  EQU   *                                                    MCS 43030018
         L     WKR3,COMMSG1+D12    BEGINNING OF WTO BUFFER          MCS 43090018
         C     WKR3,COMPRNT        ANY ENTRIES                      MCS 43150018
         BE    WTOEX               NO-EXIT                          MCS 43210018
         BAL   WKR8,SETTCBS        GO SET TCB'S NON-DISPATCH        MCS 43270018
         LR    WKR8,WKR15          SAVE MOD BASE IN REG 8           MCS 43330018
         SPACE 1                                                        43390018
*        INITIALIZATION COMPLETE - NOW DETERMINE TYPE OF MESSAGE    MCS 43450018
WTOCONT  EQU   *                                                    MCS 43510018
         CLI   X0(WKR3),XF0        IS IT STATIC MSG                 MCS 43570018
         BE    SETSTAT             YES BRANCH                       MCS 43630018
         CLI   X0(WKR3),XF1        IS IT DYNAMIC MSG                MCS 43690018
         BE    SETDYN              YES BRANCH                       MCS 43750018
         CLI   X0(WKR3),XF2        IS IT SPECIAL 2K MSG             MCS 43810018
         BE    SETSPEC             YES BRANCH                       MCS 43870018
         CLI   X0(WKR3),XF3        SUBSYSTEM MESSAGE?                   43920020
         BE    SETSSPEC            BRANCH YES                           43922020
         B     WTOEXIT             IF NONE THEN ERROR - MUST EXIT   MCS 43930018
         SPACE 2                                                        43990018
*        DYNAMIC MESSAGE HANDLING ROUTINE                           MCS 44050018
*         -MOVES APPROPRIATE MESSAGE FROM TABLE TO SVC OUTPUT AREA  MCS 44110018
*         -MOVES DYNAMIC INFORMATION FROM WTO BUFFER TO SVC OUTPUT  MCS 44170018
*              AREA                                                 MCS 44230018
         SPACE 2                                                        44290018
SETDYN   EQU   *                                                    MCS 44350018
         LA    WKR6,DYMSGEND       END OF DYNAMIC MESSAGE TABLE     MCS 44410018
         LA    WKR4,DYNMSGS        BEGINNING OF TABLE               MCS 44470018
DYNCNT   CLC   X1(X2,WKR3),X1(WKR4) DOES MSG IN BUFFER EQUAL        MCS 44530018
*                                    MESSAGE IN TABLE               MCS 44590018
         BE    DYMSGFD             YES BRANCH                       MCS 44650018
         LA    WKR4,X4(WKR4)       UPDATE TABLE POINTER             MCS 44710018
         CR    WKR4,WKR6           END OF TABLE ?                   MCS 44770018
         BL    DYNCNT              NO, CONTINUE SEARCH              MCS 44830018
         B     WTOEXIT             YES, ERROR - MUST EXIT           MCS 44890018
DYMSGFD  EQU   *                                                    MCS 44950018
         MVC   WTOMSG1(X4),X0(WKR4)  MOVE MESSAGE FROM TABLE TO     MCS 45010018
*                                      WTO OUTPUT AREA              MCS 45070018
         MVC   WTOMSG2(X8),X3(WKR3)   MOVE DYNAMIC INFO FROM       MCS  45130018
*                                      BUFFER TO WTO OUTPUT AREA    MCS 45190018
         LA    WKR3,D11(WKR3)      UPDATE PTR TO NEXT ENTRY         MCS 45250018
         B     ISSUESVC            BRANC TO ISSUE SVC               MCS 45310018
         SPACE 3                                                        45370018
*        STATIC MESSAGE HANDLING ROUTINE                            MCS 45430018
*         -MOVES APPROPRIATE MESSAGE FROM TABLE TO SVC OUTPUT AREA  MCS 45490018
*                                                                   MCS 45550018
*                                                                   MCS 45610018
         SPACE 3                                                        45670018
SETSTAT  EQU   *                                                    MCS 45730018
         LA    WKR6,STMSGEND       END OF STATIC MESSAGE TABLE      MCS 45790018
         LA    WKR4,STATMSGS       BEGINNING OF TABLE               MCS 45850018
STCNT    CLC   X1(X2,WKR3),X1(WKR4)  DOES MSG IN BUFFER EQUAL MSG       45910018
*                                     IN TABLE                      MCS 45970018
         BE    STMSGFD             YES, BRANCH                      MCS 46030018
         LA    WKR4,D13(WKR4)      UPDATE TABLE POINTER             MCS 46090018
         CR    WKR4,WKR6           END OF TABLE                     MCS 46150018
         BL    STCNT               NO, CONTINUE SEARCH              MCS 46210018
         B     WTOEXIT             YES, ERROR - MUST EXIT           MCS 46270018
STMSGFD  MVC   WTOMSG1(D13),X0(WKR4) MOVE ENTIRE MSG FROM TABLE     MCS 46330018
*                                      TO WTO OUTPUT AREA           MCS 46390018
         LA    WKR3,X3(WKR3)       UPDATE PTR TO NEXT ENTRY         MCS 46450018
         B     ISSUESVC            BRANCH TO ISSUE SVC              MCS 46510018
         SPACE 3                                                        46570018
******************************************************************* MCS 46630018
*                                                                 * MCS 46690018
*             SPECIAL MESSAGE HANDLING ROUTINE                    * MCS 46750018
*              -OUTPUTS STORAGE DAMAGE RANGE AND JOBS ABENDED     * MCS 46810018
*               AND DATA SETS ASSOCIATED WITH THESE JOBS WHICH    * MCS 46870018
*               WERE LEFT OPEN                                    * MCS 46930018
*              -ALL INFORMATION IS PLACED IN WTO BUFFER AREA      * MCS 46990018
*               BY IGFASR2K MODULE                                * MCS 47050018
*              -OUTPUTS SUBSYSTEM MESSAGE IGF040I                       47100000
*                                                                 * MCS 47110018
******************************************************************* MCS 47170018
         SPACE 3                                                        47230018
SETSSPEC EQU   *                                                        47280020
         MVC   WTOSPEC4(X12),X1(WKR3)   MOVE MSG TO BUFFER    IE  42247 47282000
         LA    WKR3,X13(WKR3)      UPDATE BUFFER POINTER      IE  42247 47284000
         OI    ENDMSGSW,X1         SET END OF MSG SWITCH                47286020
         B     SPECSVC             GO ISSUE WTO                         47288020
SETSPEC  EQU   *                                                    MCS 47290018
         MVI   SPEC2K,X1           2K MESSAGE INDICATOR             MCS 47350018
         CLI   X3(WKR3),X6B        IS IT RANGE IDENTIFIER           MCS 47410018
         BNE   WTOEXIT             NO, ERROR - MUST EXIT            MCS 47470018
         MVC   WTOSPEC1(D52),MSGSPEC  MOVE MSG TO WTO OUTPUT AREA   MCS 47530018
         MVC   WTOSPEC2(D13),X4(WKR3) MOVE RANGE TO OUTPUT AREA     MCS 47590018
         LA    WKR3,D17(WKR3)         UPDATE WTO BUFFER PTR         MCS 47650018
ISSPSVC  BAL   WKR7,SPECSVC        GO ISSUE SVC                     MCS 47710018
         CLI   X0(WKR3),X6B        ANOTHER RANGE IDENTIFIER         MCS 47770018
         BNE   SPCHJOB             NO, CHECK JOB NAME IDENTIFIER    MCS 47830018
         MVC   WTOSPEC3(D14),MSGSPEC1  MOVE STORAGE DAMAGE          MCS 47890018
         MVC   WTOSPEC2(D13),X1(WKR3)  MOVE RANGE TO OUTPUT AREA    MCS 47950018
         LA    WKR3,D14(WKR3)          UPDAT WTO BUFFER PTR         MCS 48010018
         B     ISSPSVC             BRANCH TO ISSUE SVC              MCS 48070018
SPCHJOB  EQU   *                                                    MCS 48130018
         CLI   X0(WKR3),X5C        IS IT JOB NAME IDENTIFIER        MCS 48190018
         BE    MVJOB               YES, BRANCH                      MCS 48250018
         CLI   X0(WKR3),X4B        IS IT END OF MESSAGE IDENTIFIER  MCS 48310018
         BE    SPECEX              YES, EXIT                        MCS 48370018
         B     WTOEXIT             ERROR EXIT                       MCS 48430018
SPECEX   EQU   *                                                    MCS 48490018
         LA    WKR3,X1(WKR3)       UPDATE PTR                       MCS 48550018
         B     ENTBUF              CHECK FOR MORE ENTRIES IN BUFFER MCS 48610018
MVJOB    EQU   *                                                    MCS 48670018
         MVC   WTOSPEC3(X8),X1(WKR3) MOVE JOB NAME TO OUTPUT AREA   MCS 48730018
         LA    WKR3,X9(WKR3)         UPDATE PTR                     MCS 48790018
         LA    WKR4,X1             SET LINE COUNTER                 MCS 48850018
         LA    WKR5,WTOSPEC3+X8    SET ADDR OF OUTPUT AREA POINTER      48910018
SPECDS   EQU   *                                                    MCS 48970018
         CLI   X0(WKR3),X61        IS IT DATA SET IDENTIFIER        MCS 49030018
         BNE   CHJOBEND            NO, CHECK FOR JOB OR END OF MSG  MCS 49090018
         MVI   X0(WKR5),X4D        MOVE LEFT PAREN                  MCS 49150018
         MVC   X1(X8,WKR5),X1(WKR3) MOVE DATA SET NAME              MCS 49210018
         MVI   D9(WKR5),X5D        MOVE RIGHT PAREN                 MCS 49270018
         LA    WKR5,D10(WKR5)      UPDATE OUTPUT PTR                MCS 49330018
         LA    WKR3,D9(WKR3)       UPDATE BUFFER PTR                MCS 49390018
UPDCTR   LA    WKR4,X1(WKR4)       ADD ONE TO LINE CTR              MCS 49450018
         CH    WKR4,MASK4          HAS LINE COUNT BEEN EXCEEDED     MCS 49510018
         BL    SPECDS              BRANCH IF NOT EXCEEDED           MCS 49570018
         CLI   X0(WKR3),X61        IS IT DATA SET IDENTIFIER        MCS 49630018
         BE    NEXTDS              YES, BRANCH                      MCS 49690018
         CLI   X0(WKR3),X5C        IS IT JOB NAME IDENTIFIER        MCS 49750018
         BE    YESJOB              YES, BRANCH                      MCS 49810018
         B     SETENDMS            BRANCH TO EXIT                   MCS 49870018
         SPACE 2                                                        49930018
*        LINE COUNT HAS BEEN EXCEEDED - NEXT ENTRY IS DATA SET      MCS 49990018
NEXTDS   LA    WKR4,X0             RESET LINE CTR                   MCS 50050018
         LA    WKR5,WTOSPEC3       RESET PTR TO OUTPUT AREA         MCS 50110018
         LA    WKR7,SPECDS         ADDRESS FOR RETURN               MCS 50170018
         B     SPECSVC             GO ISSUE SVC                     MCS 50230018
*        LINE COUNT HAS BEEN EXCEEDED - NEXT ENTRY IS JOB NAME      MCS 50290018
YESJOB   EQU   *                                                    MCS 50350018
         MVI   0(WKR5),X5E         SET DELIMITER IN OUTPUT AREA     MCS 50410018
         LA    WKR7,MVJOB          ADDRESS FOR RETURN               MCS 50470018
         B     SPECSVC             GO ISSUE SVC                     MCS 50530018
CHJOBEND EQU   *                                                    MCS 50590018
         CLI   X0(WKR3),X5C        IS IT JOB NAME IDENTIFIER        MCS 50650018
         BNE   SETENDMS            NO, BRANCH                       MCS 50710018
         MVI   X0(WKR5),X5E        SET DELIMITER IN OUTPUT AREA     MCS 50770018
         MVC   X1(X8,WKR5),X1(WKR3)  MOVE JOB NAME TO OUTPUT AREA   MCS 50830018
         LA    WKR5,X9(WKR5)       UPDATE OUTPUT PTR                MCS 50890018
         LA    WKR3,X9(WKR3)       UPDATE BUFFER PTR                MCS 50950018
         B     UPDCTR              BRANCH TO UPDATE LINE CTR        MCS 51010018
SETENDMS EQU   *                                                    MCS 51070018
         LA    WKR3,X1(WKR3)       UPDATE BUFFER PTR                MCS 51130018
         OI    ENDMSGSW,X1         NO, SET END OF MSG SWITCH        MCS 51190018
         SPACE 1                                                        51250018
SPECSVC  EQU   *                                                    MCS 51310018
         L     WKR1,CVTCUCB        ADDR OF UCM                      MCS 51370018
         CLC   X2E(X2,WKR1),X3A(WKR1) ANY BUFFER SPACE      3249    MCS 51430020
         BE    WTOEXIT2                NO BUFFER-NO MESSAGE             51520020
         CNOP  0,4                                                  MCS 51610018
WTOSPEC  EQU   *                   ROUTER AND DESCRIPTOR CODES      MCS 51670018
         WTO 'IGF027I                                                ',*51730018
               ROUTCDE=(2),DESC=(4)                                     51790018
YES2K    EQU   *                                                    MCS 51850018
         LR    WKR15,WKR8          RESTORE MOD BASE                 MCS 51910018
         MVI   WTOSW,X2            WTO SWITCH                       MCS 51970018
         CLI   ENDMSGSW,X1         IS END OF MESSAGE SWITCH ON      MCS 52030018
         BE    ENTBUF              YES,CHECK FOR MORE ENTRIES       MCS 52090018
         MVI   WTOSPEC3,X40                                         MCS 52150018
         MVC   WTOSPEC3+X1(D46),WTOSPEC3  CLEAR WTO OUTPUT AREA     MCS 52210018
         BR    WKR7                RETURN TO CALLER                 MCS 52270018
         SPACE 3                                                        52330018
ISSUESVC EQU   *                   ROUTER AND DESCRIPTOR CODES ??   MCS 52390018
         L     WKR1,CVTCUCB        ADDR OF UCM                      MCS 52450018
         CLC   X2E(X2,WKR1),X3A(WKR1) ANY BUFFER SPACE      3249    MCS 52510020
         BE    WTOEXIT2                NO BUFFER-NO MESSAGE             52600020
         CLI   WTOMSG+D14,XC5          IS E TYPE MESSAGE          21021 52610021
         BNE   WTOMSG                  NO-SKIP CHANGES            21021 52620021
         MVI   WTOMSG+X18,X20          CHANGES DESC FROM 4 TO 3   21021 52630021
         MVI   WTOMSG+X1A,X80          CHANGE ROUTCDE FROM 2 TO 1 21021 52640021
         CNOP  0,4                                                  MCS 52690018
WTOMSG   EQU   *                                                    MCS 52750018
         WTO   'IGF             ',ROUTCDE=(2),DESC=(4)                  52810018
WTORTN   EQU   *                                                    MCS 52870018
         LR    WKR15,WKR8          RESTORE MOD BASE IN REG 15       MCS 52930018
         MVI   WTOSW,X1            WTO SWITCH                       MCS 52990018
         MVI   WTOMSG2,X40         CLEAR WTO OUTPUT AREA TO BLANKS  MCS 53050018
         MVC   WTOMSG2+X1(X7),WTOMSG2                               MCS 53110018
ENTBUF   C     WKR3,COMPRNT        ANY MORE ENTRIES                 MCS 53170018
         BL    WTOCONT             NO                               MCS 53230018
         SPACE 1                                                        53290018
WTOEXIT2 EQU   *                                                    MCS 53350018
         L     WKR3,COMMSG1+D12    STARTING POINT OF WTO BUFFER     MCS 53410018
         ST    WKR3,COMPRNT        RESTORE ADDR                     MCS 53470018
         MVC   X10(X8,WKR5),SAVRBPSW  RESTORE RB'S PSW              MCS 53530018
         BAL   WKR2,RSETTCBS       RESTORE TCB,S                    MCS 53590018
WTOEX    EQU   *                                                    MCS 53650018
         BR    WKR9                                                 MCS 53710018
         SPACE 3                                                        53770018
WTOEXIT  EQU   *                                                    MCS 53830018
         MVI   NOTFND,X1           SET NOT FOUND BIT                MCS 53890018
         B     WTOEXIT2                                                 53950018
         SPACE 3                                                        54010018
         SPACE 3                                                        54490018
******************************************************************* MCS 54550018
*                                                                 * MCS 54610018
*                          INFORMATION MESSAGES                   * MCS 54670018
*                                                                 * MCS 54730018
*        THREE TYPES OF MESSAGES WILL BE PLACED IN THE WTO        * MCS 54790018
*         BUFFER. THREE BYTES WILL BE PLACED IN THE BUFFER TO     * MCS 54850018
*         INDICATE TYPE OF MESSAGE (1 BYTE) AND TO IDENTIFY       * MCS 54910018
*         THE MESSAGE ITSELF (2 BYTES).                           * MCS 54970018
*                                                                 * MCS 55030018
*        THREE TYPES: DYNAMIC MESSAGES   CODE=0   NUMBER OF=SIX   * MCS 55090018
*                     STATIC MESSAGES    CODE=1   NUMBER OF=FOUR  * MCS 55150018
*                     SPECIAL 2K MESSAGE CODE=2   NUMBER OF=ONE   * MCS 55210018
*                                                                 * MCS 55270018
******************************************************************* MCS 55330018
         SPACE 2                                                        55390018
         DS    0F                                                       55450018
DYNMSGS  EQU   *                                                    MCS 55510018
         DC    C'021I'             NON-REFRESH RAM MFT              MCS 55570018
         DC    C'022I'             NON-REFRESH RAM CHAIN MFT        MCS 55630018
         DC    C'024I'             SET TASK NON-DISPATCH            MCS 55690018
         DC    C'025I'             SET TASK NON-DISPATCH            MCS 55750018
         DC    C'026I'             TASK ABEND                       MCS 55810018
         DC    C'032I'             SUCCESSFUL RETURN                MCS 55870018
DYMSGEND EQU   *                   END OF DYNAMIC MESSAGES          MCS 55930018
STATMSGS EQU   *                                                    MCS 55990018
         DC    C'020I  ABEND  '    P/P ABEND                        MCS 56050018
         DC    C'023I BLDL DLT'    BUILD L DELETE                   MCS 56110018
         DC    C'028I I/O ERR '    I/O ERROR SYSRES                 MCS 56170018
         DC    C'033I RUN EREP'    EREP FULL                        MCS 56230018
         DC    C'064I SBLD DLT'    SVC BLDL TABLE DELETED MESSAGE 21113 56240021
         DC    C'061E LOG 90%F'    LOGREC 90 PERCENT FULL         21021 56260021
STMSGEND EQU   *                                                    MCS 56290018
MSGSPEC  DC    C'027I STORAGE DAMAGE               '                    56350018
         DC    C'JOB ABEND(DS OPEN)'                                    56410018
         DS    0H                                                       56420021
         DS    0H                                                       56440021
         SPACE 2                                                        56470018
NEROUT3  EQU   *                                                    MCS 56530018
         LA    WKR0,XA07           WAIT STATE CODE                  MCS 56590018
         B     NEROUT2                                              MCS 56650018
NEROUT1  EQU   *                                                    MCS 56710018
         LA    WKR0,XA10           WAIT STATE CODE                  MCS 56770018
NEROUT2  EQU   *                                                    MCS 56830018
         TM    COMNUC+X4,X80       HAS ERROR RECORD BEEN RECORDED   MCS 56890018
         BC    ON,MSGWRIT          YES, LEAVE MSG ALONE             MCS 56950018
         MVI   NIOMSG+X6,SCON      SET SEREP CODE                   MCS 57010018
MSGWRIT  EQU   *                                                    MCS 57070018
         MVC   COMMSG0+X1(D16),NIOMSG    MOVE MSG TO BUFFER         MCS 57130018
         L     WKR3,COMNUC+X4      ERROR RETURN ADDR OF NUC         MCS 57190018
         BCR   15,WKR3             RETURN TO ASRNUC                 MCS 57250018
NEROUT4  EQU   *                                                    MCS 57310018
         LA    WKR0,X'A08'         WAIT STATE CODE                  MCS 57370018
         B     NEROUT2                                              MCS 57430018
NEROUT5  EQU   *                                                    MCS 57490018
         LA    WKR0,XA09           WAIT STATE CODE                  MCS 57550018
         B     NEROUT2                                              MCS 57610018
         EJECT                                                          60760015
*****************  A S R    T E R M I N A T O R  ********************** 60830015
         SPACE 2                                                        60900015
NTERM00  EQU   *                                                        60970015
         L     CVTREG,COMCVT       GET ADDR OF CVT                      61040015
         MVI   COMLEV0A,LEVEL          MODULE LEVEL                     61070021
         TM    COMNUC+9,X'02'      DISABLE WAIT STATE SET IN RESUME PSW 61110015
         BZ    NTERM06       NO,NOT WAIT STATE                    MP    61130017
         TM    COMNUCVD,X'FF'           YES-DISABLED               MP   61150018
         BZ    NWAIT      GO IF DISABLED,ANDNOT RESTORE I/O INT   MP    61170017
COMNUCVD EQU   COMNUC+8                                            MP   61190017
NTERM06  EQU   *                                                   MP   61210017
*                                  AND SYSTEM ENVIRONMENT--WE ARE GOING 61250015
*                                  DOWN ANYWAY.                         61320015
         SPACE 2                                                        61390015
* MUST RESTORE ACCESS MECHANISM TO POSITION IT HELD BEFORE ASR RECEIVED 61460015
* CONTROL. (DOES NOT HOLD TRUE IF SYSRES IS A DRUM).                    61530015
         SPACE 2                                                        61600015
         L     WKR5,CVTSYSAD       GET SYSRES UCB ADDR FROM CVT         61670015
         LA    WKR5,LASTSEEK(WKR5) STEP ADDR TO LAST SEEK SLOT-THIS     61740015
*                                  POINTS TO LAST BBCCHHR               61810015
         ST    WKR5,NPOSCCW        SET SEEK ADDR IN CCW                 61880015
         OI    NPOSCCW,X'07'       SET SEEK COMMAND CODE                61950015
         LA    WKR5,NPOSCCW        SET                                  62020015
         ST    WKR5,72                CAW                               62090015
         LH    WKR5,COMSYSRS       GET CUA OF SYSRES                    62160015
         SPACE 1                                                        62230015
         SIO   0(WKR5)             SEEK TO SYSRES                       62300015
         BC    7,NIOR00            ** ERROR                         MCS 62370018
NTERMTIO TIO   0(WKR5)                                                  62440015
         BC    9,NIOR00            ** ERROR                         MCS 62510018
         BC    2,NTERMTIO     *****BUSY                                 62580015
*        CSW STORED                                                     62650015
         TM    68,X'04'            DE ON/OFF                            62720015
         BC    OFF,NTERMTIO        OFF-REPEAT TIO                       62790015
         SPACE 2                                                        62860015
         SPACE 3                                                        63560015
*****************  RESTORE I/O INTERRUPTS ROUTINE  ******************** 63630015
*                                                                     * 63700015
* ASR MUST RESTORE ALL I/O INTERRUPTS PREVIOUSLY SAVED DURING THE     * 63770015
* CLEAR CHNNL PATH FUNCTIONS.  THIS ROUTINE WILL 'FEED' THESE INTRPTS * 63840015
* ONE AT A TIME BACK TO IOS FOR PROCESSING, BUT WITH ASR MAINTAINING  * 63910015
* CONTROL UNTIL ALL SAVED INTRPTS HAVE BEEN RETURNED.                 * 63980015
*                                                                     * 64050015
*********************************************************************** 64120015
         SPACE 3                                                        64190015
NIOR00   EQU   *                                                        64260015
         TM    COMPSA+D48,XFE          MCI IN DISABLE CODE?        5614 64350020
         BZ    NIORDIS       YES-GO TO DISABLE PROGROM             5614 64440020
*  MCI OCCURRED IN ENABLED I/O CODE                                     64530020
         L     WKR2,COMIOQ             GET START ADDR OF IOQ      35614 64620020
         CLI   X0(WKR2),XFF            IS RMS IOQ EMPTY?          35614 64710020
         BE    NTERM20                 YES-NO INTERRUPTS TO RETURN      64800020
*  THIS ROUTINE WILL HANDLE I/O INTERRUPTS,IF THE IOQ IS NOT EMPTY      64890020
*                                                                       64980020
* MUST NOW SET ALL TCB'S,EXCEPT CURRENT, NON-DISPATCHABLE               65140015
         SPACE 1                                                        65240015
         BAL   WKR8,NTCBND         GO TO NON-DISPTACH ROUTINE           65340015
         MVC   96(8),COMPSA+96     RESTORE SYSTEM SVC NEW PSW           65440015
NIOR09   XC    56(8),56            ZERO I/O OLD PSW                     65540015
NIOR02   MVC   64(8),2(WKR2)       SET CSW FROM ASR IOQ                 65640015
         MVC   58(2),0(WKR2)       SET CUA INTO I/O OLD PSW             65740015
NIOR0A   LA    WKR5,NIORRTN1       SET ASR RETURN ADDRESS               65840015
         ST    WKR5,60               INTO I/O OLD PSW                   65940015
         OI    57,X'04'            SET MCK ENABLED IN I/O OLD PSW       66040015
         MVC   120(8),COMPSA+120   RESTORE SYSTEM I/O NEW PSW           66140015
         LPSW  120       **********GO TO IOS*************************** 66240015
         SPACE 3                                                        66890015
******** RETURN TO HERE AFTER IOS HAS PROCESSED THE I/O INTERRUPT       66920015
         SPACE 1                                                        66990015
NIORRTN1 EQU   *                                                        67060015
         LA    WKR2,10(WKR2)       STEP TO NEXT SLOT IN ASR IOQ         67130015
         CLI   0(WKR2),X'FF'       IS IOQ EMPTY                         67200015
         BNE   NIOR09      NO--CONTINUE                      APAR 18948 67270017
         SPACE 1                                                        67340015
* ALL SAVED I/O INTERRUPTS HAVE BEEN RETURNED SUCCESSFULLY TO IOS       67410015
* MUST NOW RESTORE TCB'S TO THEIR ORIGINAL STATE                        67480015
NIORRTN5 EQU   *                                                        67510020
         SPACE 1                                                        67550015
         L     WKR4,CVTHEAD        GET TOP TCB ADDR                     67620015
         L     WKR1,NCURTCB        GET CURRENT TCB ADDR                 67690015
         MVC   NNONDSP(2,WKR1),NSVND    RESTORE NON-DISP BYTES IN TCB   67790015
NIOR05   CLR   WKR1,WKR4           IS THIS CURRENT TCB                  67970015
         BC    EQ,NIOR06           YES-LEAVE IT ALONE                   68040015
         NI    N173(WKR4),XDF          TURN OFF TEMP FLAG          2K   68090018
         OC    N173(3,WKR4),N173(WKR4)   ANY OTHER FLAGS ON        2K   68140018
         BNZ   NIOR06            YES-NOT CLEAR MASTER NON-DISP     2K   68190018
         NI    N33(WKR4),XFE       CLEAR MASTER NON-DISPATCH BIT   2K   68240018
NIOR06   L     WKR4,NNXTTCB(WKR4)  GET NEXT TCB                         68320015
         LTR   WKR4,WKR4           LAST TCB                             68390015
         BC    7,NIOR05            NO--CONTINUE                         68460015
         BC    15,NTERM01          ALL DONE                             68530015
         SPACE 1                                                        68600015
         SPACE 3                                                        69020015
* ORIGINAL MCI OCCURRED IN DISABLED I/O CODE                            69090015
         SPACE 1                                                        69160015
NIORDIS  EQU   *                                                        69230015
         LA    WKR5,NIORRTN2       SET RETURN ADDRESS                   69300015
         ST    WKR5,124              IN I/O NEW PSW                     69370015
* MUST NOW CREATE A PENDING I/O INTRPT IN ORDER TO KEEP SYSTEM DRIVEN   69440015
* IN CASE NO OTHER I/O INTRPTS ARE PENDING.                             69510015
* TWO CHAINED SEEKS (TO SAME BBCCHHR) WILL BE ISSUED TO SYSRES SUCH     69580015
* THAT A PENDING I/O CE,DE INTERRUPT WILL OCCUR SIMULTANEOUSLY.         69650015
* THE SEEK BBCCHH WILL BE THE LAST SEEK TO SYSRES BEFORE ASR GOT CNTRL. 69720015
         SPACE 1                                                        69790015
         L     WKR5,CVTSYSAD       GET SYSRES UCB ADDR                  69860015
         LA    WKR5,LASTSEEK(WKR5) GET ADDR OF LAST SEEK BBCCHHR        69930015
         ST    WKR5,NSKCCW1          AND                                70000015
         ST    WKR5,NSKCCW2             SEEK COMMAND                    70070015
         OI    NSKCCW1,X'07'               CODES INTO                   70140015
         OI    NSKCCW2,X'07'                         CCW'S              70210015
         LA    WKR5,NSKCCW1        SET                                  70280015
         ST    WKR5,72                CAW                               70350015
         LH    WKR5,COMSYSRS       GET CUA OF SYSRES                    70420015
         SIO   0(WKR5)             SEEK TO SYSRES                       70490015
         BC    7,NEROUT3        ***ERROR- SIO SHOULD GO             MCS 70560018
         SPACE 1                                                        70630015
* SIO PROCEEDING--MUST NOW GIVE TCH TO MAKE SURE INTRPT IS PENDING      70700015
         SPACE 1                                                        70770015
NIOR08   TCH   0(WKR5)                                                  70840015
         BC    9,NEROUT4        ***ERROR- AVAIL OR NOT OPERATIONAL  MCS 70910018
         BC    2,NIOR08            CHNNL IN BURST MODE                  70980015
*        CHNNL HAS PENDING INTRPT                                       71050015
         SPACE 1                                                        71120015
* WILL NOW RETURN TO DISABLED CODE UNTIL IT BECOMES ENABLED             71190015
         SPACE 1                                                        71260015
         LD    0,REGSFPR           RESTORE FPR'S                        71330015
         LD    2,REGSFPR+8                                              71400015
         LD    4,REGSFPR+16                                             71470015
         LD    6,REGSFPR+24                                             71540015
         MVC   0(80),COMPSA        RESTORE PSA EXCEPT TIMER + NEW PSW'S 71570015
         MVC   48(8),COMNUC+8      PUT RESUME PSW IN MCK OLD PSW        71610015
         ST    BRMOD,LOCOR168 SAVE TRANS AREA BASE REG        IE  46431 71630021
         ST    WKR12,LOCOR16C  SAVE COMMUNICATION AREA BASE REG   46431 71650021
         LM    0,15,REGSGPR        RESTORE GPR'S                        71680015
         LPSW  48                  RETURN TO SYSTEM ******************* 71750015
         SPACE 5                                                        71820015
* RETURN HERE VIA I/O NEW PSW WHEN CODE BECOMES ENABLED FOR I/O         71890015
         SPACE 1                                                        71960015
NIORRTN2 EQU   *                                                   MP   72020017
        ST     BRMOD,EXOLDPSW   SAVE SYSTEM BASE REG               MP   72080017
         L     BRMOD,LOCOR168 RESTORE TRANS AREA BASE REG     IE  46431 72140021
         STM   WKR12,WKR14,NCURTCB   SAVE REGS 12-14               MP   72200017
         L     WKR12,LOCOR16C RESTORE COMM AREA BASE REG      IE  46431 72260021
         L     WKR14,COMNEST       ADDR OF NEST SWITCH IN IOS           72310018
         CLI   1(14),X'F0'         DID ORIG MCI OCCUR IN IOS            72360015
         BC    EQ,NMCIOS1          BR IF YES                            72400015
         SPACE 1                                                        72440015
         STM   0,11,REGSGPR        SAVE GR 0-11                         72480015
         MVC   SAVD(WKR12),NCURTCB   MOVE SAVED REGS 12-14          MP  72540017
         MVC   SAVD1(WKR4),EXOLDPSW     SAVE GR 15                  MP  72600017
         STD   0,REGSFPR           SAVE                                 72680015
         STD   2,REGSFPR+8             FLOAT                            72720015
         STD   4,REGSFPR+16                 POINT                       72760015
         STD   6,REGSFPR+24                      REGS                   72800015
         MVC   COMNUC+8(8),56      SAVE I/O OLD PSW--NEW RESUME POINT   72840015
         L     CVTREG,COMCVT       SET CVT REG                          72880015
NIORRTN3 MVC   COMPSA(80),0        SAVE OLD PSW'S,CSW, CAW              72920015
         L     14,NBASESV          SET ASRNUC BASE REG                  72960015
         SPACE 3                                                        72965020
* HAVING RETURNED TO THE DISABLED PROGRAM AND THE PROGRAM ENABLES,      72970020
*   THE NEXT NSI IN MCH WILL DETERMINE IF THERE ARE ANY INTERRUPTS      72975020
*      TO RETURN                                                        72980020
         L     WKR2,COMIOQ             GET START ADDR OF IOQ  IE  46431 72990021
         BAL   WKR8,NTCBND         GO TO NON-DISPATCH ROUTINE           73000015
         LH    WKR5,COMSYSRS       GET CUA OF SYSRES                    73040015
         CH    WKR5,COMPSA+58      WAS THIS SYSRES INTRPT               73120015
         BNE   NIORRTN4                NO-NOT A SYSRES INTERRUPT        73130020
         MVC   X78(X8),COMPSA+X78      RESTORE SYS I/O NEW PSW          73132020
         CLI   X0(WKR2),XFF            IS RMS IOQ EMPTY?                73150020
         BE    NIORRTN5                YES-NO SAVED INTERRUPTS          73160020
NIORRTN4 EQU   *                                                        73170020
         TIO   0(WKR5)             CLEAR PENDING SYSRES INTRPT          73200015
         BC    11,NEROUT5       ***ERROR- CC=O,2,3                  MCS 73240018
*        CSW STORED--INTRPT CLEARED                                     73280015
         XC    56(2),56            CLEAR HI-2 BYTES OF I/O OLD          73320015
         MVC   64(8),COMPSA+64     RESTORE CSW                          73360015
         SL    WKR2,K10            DECREMENT IOQ POINTER                73400015
         BC    15,NIOR0A           RETURN THIS INTERRUPT                73440015
         SPACE 3                                                        73480015
* MCI OCCURRED IN IOS                                                   73520015
NMCIOS1  EQU   *                                                        73560015
         NI    1(14),X'0F'         RESET IOS NESTING SWITCH             73600015
         L     CVTREG,COMCVT       SET CVT REG                          73640015
         L     WKR7,CVTTCBP        GET CURRENT                          73680015
         L     WKR7,4(WKR7)                   TCB ADDRESS               73720015
         L     WKR5,0(WKR7)        GET ADDR OF RB                       73760015
         MVC   COMNUC+8(8),16(WKR5)     SAVE RSME PSW FROM RB           73800015
         BAL   WKR9,NTCBREC        GO SAVE TCB ENV IN ASR REC ENTRY     73840015
         BC    15,NIORRTN3                                              73880015
*                                                                       73883020
NTERM20  EQU   *                   COME FROM NIOR00, NO INTPS TO RET.MP 73886020
         TM    COMMSF,X'10'        CHK MULTIPROCESSING MODE          MP 73889020
         BZ    NTERM01                 GO IF NOT           APAR    3067 73892020
         TM    COMMSF,X'03'        CHK SHARED MODE                   MP 73895020
         BNZ   NTERM01                 GO IF NOT           APAR    3067 73898020
         CLI   COMNUCVD,ZERO       CHK IF SYSTEM MASK IS DISABLED   MP  73901020
          BE   NTERM01                 GO IF IS DISABLED   APAR    3067 73904020
         L     WKR3,CVTMPCVT       GET BASE                          MP 73907020
         MVC   LOCKAFF(WKR2,WKR3),LOCK00  ZEROLOCK + AFFINITY BYTES MP  73910020
NTERM01  EQU   *                                                        73990015
         BAL   WKR9,WTOCALL        WTO ROUTINE                      MCS 75180518
         L     WKR1,CVTTCBP        GET CONTENTS                         75181015
         LM    WKR6,WKR7,0(WKR1)     OF NEW-OLD TCB'S                   75182015
         TM    CVTDCB,UCMUF        IS SYSTEM MVT OR MFT             MP  75183017
         BO    NTMVT0              BR IF MVT                       MP   75184017
         MVC   X'30'(24,WKR7),REGSGPR+40     SAVE GR 10-15 IN OLD TCB   75185015
         MVC   X'48'(40,WKR7),REGSGPR        SAVE GR 0-9   IN OLD TCB   75186015
         TM    X1F(WKR7),X8   THIS MFT TCB HAS FPR SPACE      IE  21961 75186426
         BZ    NMFTFPR              NO-SKIP FPR RESTORE       IE  21961 75186826
NT0      L     WKR8,NEG32          WANT TO REFERENCE FP REG SAVE        75187015
         AR    WKR8,WKR7            AREA IN TCB                         75188015
         MVC   0(32,WKR8),REGSFPR  SAVE FP REG SINTO OLD TCB            75189015
NMFTFPR  EQU   *                                                        75189426
         L     WKR5,0(WKR7)        GET ADDR OF RB OLD TCB               75190015
LOCK00   EQU   *-2                 2-BYTE ZERO                       MP 75190517
         MVC   16(8,WKR5),COMNUC+8 PUT ASR RSME PSW INTO RSM PSW OF RB  75191015
         MVC   DISPATCH+5(3),CVT0DS+1   SET DISPATCHER RESUME PSW       75192015
         SR    WKR6,WKR6           CLEAR NEW TCB TO ZERO                75193015
         L     WKR7,CVTHEAD        GET HIGHEST PRIORITY TCB             75194015
         TM    COMMSF,UCMUF        CHK MULTIPROCESSING              MP  75194117
         BZ    NTVD          GO IF NOT                            MP    75194217
         L     WKR7,NNXTTCB(WKR7)     GETM LOWER TCB IF SO         MP   75194317
*                             DO NOT DISPATCH DUMMY TASK           MP   75194417
NTVD     EQU    *                                                  MP   75194517
         STM   WKR6,WKR7,0(WKR1)   STORE MODIFIED NEW-OLD               75195015
*                                                                       75196015
         BAL   WKR9,NTCBREC        GO SAVE TCB ENV IN ASR REC ENTRY     75197015
         LD    0,REGSFPR           RESTORE                              75200015
         LD    2,REGSFPR+8                FPR'S                         75201015
         LD    4,REGSFPR+16                                             75202015
         LD    6,REGSFPR+24                                             75203015
         MVC   0(80),COMPSA        RESTORE ALL PSA EXCEPT               75208015
         MVC   84(28),COMPSA+84      TIMER AND                          75209015
         MVC   120(8),COMPSA+120        MCK NEW PSW                     75209318
         MVC   D48(X8),DISPATCH        SET RESUME PSW IN MCK OLD PSW    75209720
         MVC   LOCOR170(8),COMPSA+112 SET MCK NEW PSW IN LOW CORE       75210218
         TM    COMMSF,X'10'        CHK MULTIPROCESSING MODE          MP 75210518
         BZ    NTERM05             GO IF NOT                         MP 75210818
         TM    COMMSF,X'03'        CHK SHARED MODE                   MP 75211118
         BNZ   NTERM05             GO IF NOT                         MP 75211418
         L     WKR3,PREFIX2        GET ADDRESS OF PREFIX AREA        MP 75212317
         MVC  X68(X8,WKR3),COMPSA+X68 IN SECOND CPU RESTORE         GTF 75262321
*                                         PROG NEW PSW  ORIGINAL    GTF 75272321
         OI    ASRFLAGS-IPLPSW(WKR3),WKR8  SET ASR-COMPLETE IND.    MP  75312321
*                                            IN OTHER PREFIX AREA    MP 75362321
NTERM05  EQU   *                                                     MP 75412321
         LM    0,15,REGSGPR        RESTORE REGS OF CVTHEAD              75462321
         MVC   112(8),LOCOR170     RESTORE MCK OLD PSW FROM LOW CORE    75512321
         LPSW  48                  RETURN TO SYSTEM ******************* 75562321
       SPACE 1                                                          75612321
*                                                                    MP 75662321
LOCKAFF  EQU   0       LOCK BYTE DISPLACEMENT IN MPCVT             MP   75712321
*                                                                    MP 75762321
NTMVT0   EQU   *                                                        75812321
         MVC   X'30'(64,WKR7),REGSGPR   SAVE GP 0-15 INTO OLD TCB       75862321
         BC    15,NT0                                                   75912321
*                                                                       75962321
         SPACE 3                                                        76230015
NWAIT    EQU   *                                                     MP 76240017
         TM    COMMSF,X'10'        CHK MULTIPROCESSING MODE          MP 76246018
         BZ    NWAIT0              GO IF NOT                         MP 76252018
         TM    COMMSF,X'03'        CHK SHARED MODE                   MP 76258018
         BNZ   NWAIT0              GO IF NOT                         MP 76264018
         L     WKR3,PREFIX2        GET ADDRESS OF PREFIX AREA        MP 76270017
         OI    ASRFLAGS-IPLPSW(WKR3),WKR8  SET ASR-COMPLETE IND.    MP  76280017
NWAIT0   EQU   *                                                        76285018
         L     WKR0,COMNUC+XC  WAIT STATE CODE FROM RESUME PSWIE  49186 76287026
         L     WKR7,COMNUC+X4      ERROR RETURN ADDRESS             MCS 76290018
         BR    WKR7                BR TO STANDAIO-WAIT RTN          MCS 76295018
*                                                                    MP 76300017
         SPACE 2                                                        76370015
         SPACE 3                                                        76376015
* THIS SUBROUTINE WILL EXTRACT THE GPR'S AND FPR'S FROM THE TCB WHOSE   76382015
* ADDRESS IS GIVEN IN GR 7  AND PUT THEM INTO THE ASR RECORD ENTRY      76388015
* BUILD AREA---REGSGPR AND REGSFPR. LINK REG IS GR9                     76394015
         SPACE 1                                                        76400015
NTCBREC  EQU   *                                                        76406015
         TM    CVTDCB,UCMUF   IS SYSTEM MVT OR MFT                  MP  76412017
         BO    NTCBMVT1            BR IF MVT                       MP   76418017
         MVC   REGSGPR+40(24),X'30'(WKR7)    SAVE GR 10-1               76424015
         MVC   REGSGPR(40),X'48'(WKR7)       SAVE GR 2-9                76430015
NTCBREC1 L     WKR8,NEG32          WANT TO REFERENCE FP REG SAVE AREA   76436015
         AR    WKR8,WKR7             IN CVTHEAD TCB                     76442015
         MVC   REGSFPR(32),0(WKR8)      SAVE FPR'S                      76448015
         BCR   15,WKR9                                                  76454015
         SPACE 1                                                        76460015
NTCBMVT1 MVC   REGSGPR(64),X'30'(WKR7)                                  76466015
         BC    15,NTCBREC1                                              76472015
*********************************************************************** 76478015
         SPACE 3                                                        76484015
* THIS SUBROUTINE WILL MAKE ALL TCB'S, EXCEPT THE CURRENT, NON-         76490015
* DISPATCHABLE--LINK REG IS GPR 8                                       76496015
         SPACE 1                                                        76502015
NTCBND   EQU   *                                                        76508015
         L     WKR1,CVTTCBP        GET CURRENT                          76514015
         L     WKR1,4(WKR1)                   TCB ADDRESS               76520015
         ST    WKR1,NCURTCB        SAVE IT                              76526015
         MVC   NSVND(2),NNONDSP(WKR1)   SAVE NON-DISP BYTES(20-21 HEX)  76532015
         XC    NNONDSP(2,WKR1),NNONDSP(WKR1) AND CLEAR THEM IN CURR TCB 76538015
         L     WKR4,CVTHEAD        GET ADDR OF TOP TCB                  76544015
         TM    COMMSF,UCMUF   CHK MULTIPROCESSING                   MP  76546017
         BO    NIOR03  GO IF SO,LEAVE DUMMY TCB ALONE             MP    76548017
NIOR01   CLR   WKR1,WKR4           IS THIS CURRENT TCB                  76550015
         BC    EQ,NIOR03           YES--LEAVE IT ALONE                  76556015
         OI    N33(WKR4),X01     SET MASTER NON-DISPATCH BIT       2K   76564018
         OI    N173(WKR4),X20          SET TEMP FLAG                    76572018
NIOR03   L     WKR4,NNXTTCB(WKR4)  GET NEXT TCB ADDR                    76580015
         LTR   WKR4,WKR4           IS THIS LAST TCB                     76586015
         BC    7,NIOR01            NO--CONTINUE                         76592015
         BCR   15,WKR8             YES--RETURN TO CALLER                76598015
         SPACE 1                                                        76604015
         SPACE 3                                                        76622015
         EJECT                                                          76650015
         EJECT                                                          80320015
**************************  E Q U A T E S  **************************** 80360015
WKR0     EQU   0                                                        80430015
WKR1     EQU   1                                                        80500015
WKR2     EQU   2                                                        80570015
WKR3     EQU   3                                                        80640015
WKR4     EQU   4                                                        80710015
WKR5     EQU   5                                                        80780015
WKR6     EQU   6                                                        80850015
WKR7     EQU   7                                                        80920015
WKR8     EQU   8                                                        80990015
WKR9     EQU   9                                                        81060015
WKR10    EQU   10                                                       81130015
WKR11    EQU   11                                                       81200015
WKR12    EQU   12                                                       81270015
WKR13    EQU   13                                                       81340015
WKR14    EQU   14                                                       81410015
WKR15    EQU   15                                                       81480015
BRMOD    EQU   15                  BASE REG FOR ASR MODULES             81550015
BRNUC    EQU   14                  BASE REG FOR ASR NUCLEUS             81620015
CVTREG   EQU   10                  POINTER TO COMM VECTOR TABLE         81690015
LOCOR168 EQU   X'168'         LOW CORE SAVE AREA FOR REG      IE  46431 81740021
LOCOR16C EQU    X'16C'        WHICH IS IN THE LOGOUT AREA BY 0A   46431 81750021
LOCOR170 EQU   X'170'              LOW CORE WORK AREA                   81760015
NRSV     EQU   X'174'              SV AREA FOR GR14 AT ENTRY TO ASRNUC  81830015
NBASESV  EQU   X'178'              SV AREA FOR ASRNUC BASE REG          81900015
LOGSIZE  EQU   176                 SIZE OF CPU LOG-OUT FOR MODEL 65     81970015
PSASIZE  EQU   128                 SIZE OF PSA AREA                     82040015
PSABEGIN EQU   0                   BEGINNING OF PSA AREA                82110015
LOGBEGIN EQU   128                 BEGINNING OF CPU LOG-OUT AREA        82180015
         SPACE 3                                                        82250015
NOTOPER  EQU   1                   NOT OPERATIONAL                      82320015
BUSY     EQU   2                   BUSY                                 82390015
CSWSTORE EQU   4                   CSW STORED                           82460015
AVAIL    EQU   8                   AVAILABLE                            82530015
ALLON    EQU   1                   ALL BITS ON                          82600015
ALLOFF   EQU   8                   ALL BITS OFF                         82670015
MIXED    EQU   4                   BITS ARE MIXED ONES/ZEROES           82740015
ON       EQU   1                   ON                                   82810015
OFF      EQU   8                   OFF                                  82880015
EQ       EQU   8                   EQUAL                                82950015
NOTEQ    EQU   7                   NOT EQUAL                            83020015
UCBCUA   EQU   4                   UCB DISPLACEMENT FOR CHANNEL/UNIT    83090015
SENSE    EQU   4                   SENSE COMMAND CODE                   83160015
UNITTYPE EQU   19                                                       83230015
UCBTYP   EQU   UNITTYPE                                                 83300015
N2301    EQU   2                   UCB UNIT TYPE FOR 2301 DRUM          83370015
* UNIT CONTROL MODULE OFFSETS                                           83440015
UCMVEA   EQU   68   UCM OFFSET FOR TABLE ENTRY POINTERS                 83510015
UCMOF    EQU   128  WTO SUPPORT                                         83580015
UCMUF    EQU   16   WTO DEVICE ACTIVE                                   83650015
UCMUCB   EQU   12   UCM POINTER TO UCB                                  83720015
UCMATR   EQU   25   UCM ATTRIBUTE FLAGS                                 83790015
         SPACE 1                                                        83860015
NSYSMC   EQU   30                  TCBFLGS+1                            83930015
NNONDSP  EQU   32                  TCBFLGS+3                            84000015
NNODISP1 EQU   X'40'               NON-DISPATCHABLE MASK                84070015
NNXTTCB  EQU   116                 NEXT TCB ADDR                        84140015
NDISPTCH EQU   X'BF'               MASK TO ZERO NON-DISPATCH BIT        84210015
LASTSEEK EQU   49                  SYSRES UCB DISPLACEMENT WHICH GIVES  84280015
*                                   BBCCHHR OF LAST SEEK                84350015
NSVR15   EQU   X'170'                                                   84420015
LEVEL    EQU   X'&LEV'                 MODULE LEVEL                     84440021
NGRAPHIC EQU   X'10'                    GRAPHIC DEVICE TYPE          GR 84460017
         SPACE 5                                                        84490015
********************  D O U B L E   W O R D S  ************************ 84560015
         SPACE 3                                                        84630015
         DS    0D                                                       84700015
NCSWWK1  DC    1D'0'               CSW WORK AREA 1                      84770015
NCSWUS1  EQU   NCSWWK1+4             UNIT STATUS BYTE OF CSW            84840015
NCSWCS1  EQU   NCSWWK1+5             CHANNEL STATUS BYTE OF CSW         84910015
NCSWWK2  DC    1D'0'               CSW WORK AREA 2                      84980015
NSNSCCW  DC    XL8'0400000020000006'    SENSE CCW                       85050015
NSKCCW1  DC    XL8'0000000060000006'    CCW'S TO CAUSE                  85120015
NSKCCW2  DC    XL8'0000000020000006'                  CE,DE INTERRUPT   85190015
NPOSCCW  DC    XL8'0000000020000006'    REPOSITION SYSRES ARM CCW       85260015
NCTBL    DC    C'0123456789ABCDEF'      CONVERSION TABLE                85400015
DISPATCH DC    XL8'0004FF0000000000'    DISPATCHER RESUME PSW           85470015
         SPACE 5                                                        85540015
****************************  W O R D S  ****************************** 85610015
         SPACE 3                                                        85680015
         DS    0F                                                       85750015
EXOLDPSW EQU   X'1C'         EXTERNAL OLD PSW SAVE                 MP   85780017
NCNTR1   DC    XL4'BFFFF'    TIO LOOP COUNT CONSTANT               MP   85830017
NDEVICE  DC    F'0'                DEVICE TO BE CLEARED                 85890015
NIOQADDR DC    1F'0'               SAVE AREA FOR IOQ ADDRESS            85960015
CLEARUA  DC    X'000000F8'    MASK TO GET CONTROL UNIT ADDRESS          86030015
CLEAR21  DC    X'000007FF'    MASK TO CLEAR SIGN AND ISOLATE CUA        86100015
* CONSOLE ADDRESS AND DEVICE TYPE                                       86170015
CNSLADDR DC    F'0'                                                     86240015
CNSLTYPE EQU   CNSLADDR+2                                               86310015
NCURTCB  DC    F'0'                SV AREA FOR CURRENT TCB ADDRESS      86380015
NSV7     DC    F'0'                SAVE GR7,GR13                   MP   86400017
BASNUC   DC    F'0'                SAVE GR14                       MP   86420017
K10      DC    XL4'0A'                                                  86450015
NEG32    DC    X'FFFFFFE0'                                              86620015
         SPACE 5                                                        86660015
**********************  H A L F   W O R D S  ************************** 86730015
         SPACE 3                                                        86800015
         DS    0H                                                       86870015
NUCBCUA  DC    XL2'0'              SV AREA FOR CURRENT CUA FROM UCB     86940015
NSTATSV  DC    XL2'0'              CSW STAUTS SAVE BYTES                87010015
NUSSAVE  EQU   NSTATSV                                                  87080015
NCSSAVE  EQU   NSTATSV+1                                                87150015
         SPACE 5                                                        87220015
****************************  B Y T E S  ****************************** 87290015
         SPACE 3                                                        87360015
NSNSRD   DC    XL6'0'              SENSE READ IN AREA                   87430015
NCUMASK  DC    XL1'0'              CU ADDR MASK                         87500015
NSW2     DC    XL1'0'    BIT       FUNCTION                             87570015
*                        0         CC=0OK IN TIO TO SYSRES FOR DE       87640015
*                        1         QUEUE SYSRES DE REQUIRED             87710015
*                        2         SAME CU AS SYSRES FOR UCB SCAN RTN   87780015
*                        3         CLEAR SYSRES CLEARED CONSOLE ALSO    87850015
*                        4         PCI MESSAGES ARE BUFFERED            87920015
*                        5                                              87990015
*                        6         2ND UNIT CHECK MSG BUFFERED          88060015
*                        7         1ST UNIT CHECK MSG BUFFERED          88130015
NCUTEST  DC    XL1'0'              SYSRES CU SAVE TEST AREA             88200015
NSVND    DC    XL2'0'              SV AREA FOR NON-DISPATCH BYTES       88270015
NIOMSG   DC    C'IGF006W I/O ERR '                                      88278018
         DS    0D                                                       88286018
WTORPSW  DC    X'0004000000000000' WTO RETURN PSW                   MCS 88294018
SAVRBPSW DC    D'0'                                                 MCS 88302018
MASK4    DC    X'0004'             LINE COUNTER                     MCS 88310018
NOTFND   DC    X'00'               MESSAGE NOT FOUND SWITCH         MCS 88318018
ENDMSGSW DC    X'00'               END OF MESSAGE SWITCH            MCS 88326018
WTOSW    DC    X'00'                                                MCS 88334018
SPEC2K   DC    X'00'               2K MESSAGE INDICATOR             MCS 88342018
         SPACE 2                                                        88350018
X4B      EQU   X'4B'               END OF MESSAGE IDENTIFIER        MCS 88358018
X61      EQU   X'61'               DATA SET IDENTIFIER              MCS 88366018
MSGSPEC1 EQU   MSGSPEC+5                                            MCS 88382018
WTOSPEC3 EQU   WTOSPEC+16                                           MCS 88390018
K12      EQU   12                  DECIMAL 12                           88392020
WTOSPEC4 EQU   WTOSPEC+K12         MESSAGE AREA IN WTO MACRO            88394020
X14      EQU   X'14'                                                MCS 88398018
X5C      EQU   X'5C'               JOB NAME IDENTIFIER              MCS 88406018
X9       EQU   X'09'                                                MCS 88414018
X5E      EQU   X'5E'               SEMI-COLON ; DELIMITER           MCS 88422018
X1       EQU   X'01'                                                MCS 88438018
X4D      EQU   X'4D'               LEFT PAREN FOR D/S               MCS 88446018
X5D      EQU   X'5D'               RIGHT PAREN                      MCS 88454018
X68      EQU   X'68'                                                GTF 88456021
D9       EQU   9                                                    MCS 88462018
D12      EQU   12                                                       88470018
D11      EQU   11                                                       88478018
D13      EQU   13                                                       88486018
D17      EQU   17                                                       88494018
D52      EQU   52                                                       88502018
XF0      EQU   X'F0'                                                    88510018
N33      EQU   33                                                  2K   88518018
N173     EQU   173                                                 2K   88526018
XDF      EQU   X'DF'                                               2K   88534018
X01      EQU   X'01'                                               2K   88542018
X18      EQU   X'18'                                                    88544021
X1A      EQU   X'1A'                                                    88546021
X1F      EQU   X'1F'                                                    88548026
X20      EQU   X'20'                                               2K   88550018
XF1      EQU   X'F1'                                                    88558018
XF2      EQU   X'F2'                                                    88566018
XF3      EQU   X'F3'               SUBSYSTEM MSG IDENTIFIER             88568020
D14      EQU   14                                                       88574018
D10      EQU   10                                                       88582018
D46      EQU   46                                                       88590018
D48      EQU   48                                                       88594020
X2E      EQU   X'2E'                                             3249   88616020
X3A      EQU   X'3A'                                             3249   88624020
X2       EQU   X'02'                                                MCS 88646018
XC       EQU   X'0C'                                                    88654018
X3       EQU   X'03'                                                    88662018
X40      EQU   X'40'                                                MCS 88670018
XC5      EQU   X'C5'                                              21021 88671021
X78      EQU   X'78'                                                    88672020
XFE      EQU   X'FE'                                                MCS 88678018
XFF      EQU   X'FF'                                                    88682020
X10      EQU   X'10'                                                MCS 88686018
X0       EQU   X'00'                                                MCS 88702018
X8       EQU   X'08'                                                MCS 88710018
WTOMSG1  EQU   WTOMSG+11           MSG NUMBER                       MCS 88726018
WTOMSG2  EQU   WTOMSG+16           MSG DATA                         MCS 88734018
X13      EQU   X'13'                                                MCS 88742018
X12      EQU   X'12'                                              42247 88750000
X7       EQU   X'07'                                                MCS 88758018
X6B      EQU   X'6B'               RANGE IDENTIFIER                 MCS 88766018
WTOSPEC1 EQU   WTOSPEC+11                                           MCS 88774018
WTOSPEC2 EQU   WTOSPEC+31                                           MCS 88782018
X80      EQU   X'80'                                                MCS 88806018
D16      EQU   16                                                   MCS 88814018
X4       EQU   4                                                    MCS 88822018
X6       EQU   6                                                    MCS 88830018
XA09     EQU   X'A09'                                                   88838018
XA07     EQU   X'A07'                                                   88846018
XA10     EQU   X'A10'                                                   88854018
SCON     EQU   X'E2'                                                MCS 88862018
         CNOP  4,8                                                      88930015
         DC    C'ASR'                                                   88970015
         DC    X'01'                                                    89040015
         END                                                            89110015
