         LCLA  &LEV,&REL                                                00150021
&LEV     SETA  20                                                       00160021
&REL     SETA  21                                                       00170021
&REL&LEV TITLE 'IGFASR10 LEVEL &LEV RMS-MCH REFRESH LOADER'             00180021
*TITLE 'REFRESH LOADER'                                               * 00200015
*                                                                     * 00300015
*STATUS  CHANGE LEVEL 000                                             * 00400015
*                                                                     * 00500015
*FUNCTION/OPERATION      THE FUNCTION OF THE PDAR REFRESH LOADER IS   * 00600015
*    TO RESTORE A SPECIFIED AREA OF MAIN STORAGE TO ITS ORIGINAL      * 00700015
*    CONTENTS BEFORE A MACHINE MALFUNCTION CAUSED IT TO BE CHANGED OR * 00800015
*    DAMAGED.                                                         * 00900015
*                                                                     * 01000015
*    THIS MODULE   IS COMPRISED OF THE FOLLOWING ROUTINES -           * 01008015
*       (1) PROGRAM INITIALIZATION/ TERMINATION - BRANCHES TO INIT RTN* 01016015
*              AND CONTAINS LOGIC TO TERMINATE THIS MODULE AND CALL   * 01024015
*              NEXT.                                                  * 01032015
*       (2) REFRESH ROUTINE - LOADS MODULE TEXT AND PROCESSES RLD REC-* 01040015
*              ORDS. ALSO CONTAINS LOGIC FOR SCATTER LOADING.         * 01048015
*       (3) I/O ROUTINE - CHECKS CHANNEL, EXTENT, AND HAS I/O LOGIC.  * 01056015
*       (4) CONVERT ROUTINE - CONVERTS TTR TO MBBCCHHR.               * 01064015
*       (5) CONTROL INITIALIZATION (INIT) - DETERMINES WHERE MODULE IS* 01072015
*       (6) SEARCH  ROUTINE - SCANS DIRECTORY FOR LOCATION OF MODULE  * 01080015
*              WHEN ONLY ITS NAMES IS PASSED.                         * 01088015
*                                                                       01094015
*    PROGRAM OPERATION - INFORMATION REQUIRED BY THE REFRESH LOADER   * 01100015
*    IS LOCATED IN PDARTAB(IN ASRMAC). UPON ENTRY, REFRESH LOADER     * 01200015
*    WILL CHECK THE 'REFRESH FLAGS' PORTION OF PDARTAB TO DETERMINE   * 01300015
*    WHETHER AN ABSOLUTE ADDRESS, RELATIVE ADDRESS, OR MODULE NAME IS * 01400015
*    PROVIDED IN THE 'NAME' FIELD.                                      01450015
*       IF AN ABSOLUTE ADDRESS IS GIVEN, SO IS THE LENGTH OF THE      * 01500015
*    MODULE,AND THE MODULE CAN BE LOADED WITHOUT FURTHER COMPUTING    * 01550015
*    BY THE REFRESH ROUTINE.                                          * 01600015
*       IF A TTR IS GIVEN, IT IS CONVERTED TO ABSOLUTE TRACK BEFORE   * 01650015
*    LOADING.                                                         * 01700015
*       IF A NAME IS GIVEN, THE DIRECTORY FOR THE PARTITIONED DATA    * 01750015
*    SET IS SEARCHED FOR THE RECORD ASSOCIATED WITH THE NAME. THIS    * 01800015
*    RECORD CONTAINS THE TTR FOR THE MODULE, WHICH IS THEN CONVERTED  * 01850015
*    TO ABSOLUTE TRACK AND THE MODULE IS LOADED.                      * 01900015
*                                                                     * 01950015
*                                                                     * 02000015
*                                                                     * 02100015
*ENTRY POINT   IGFASR10 FROM ASRNUC                                   * 02200015
*                                                                     * 02300015
*INPUT  ASRMAC COMMUNICATION AREA---PDARSTAT, PDARTAB AND REPDAR.     * 02400015
*                                                                     * 02500015
*OUTPUT  ASRMAC COMMUNICATION AREA----PDARTAB AND REPDAR              * 02600015
*                                                                     * 02700015
         EJECT                                                          02750015
*              PDAR REFRESH TABLE ( ASRMAC )                            02800015
*                                                                       02900015
*              ****************************************                 03000015
*   PDARSTAT   *  STAT  *      TCBAD                  *                 03100015
*              ****************************************                 03200015
*   PDARTAB    *         NAME                         *                 03300015
*              *       8 BYTES                        *                 03400015
*              ****************************************                 03500015
*              *  FLAG  *      ADDRESS                *                 03600015
*              ****************************************                 03700015
*              *     LENGTH      *                    *                 03800015
*              *     2 BYTES     *                    *                 03900015
*              ****************************************                 04000015
*                                                                     * 04200015
*              ****************************************                 04300015
*   PDARCUA    *  CUA(2 BYTES)    *  CUA (2 BYTES     *                 04400015
*              *  CUA             *  CUA              *                 04500015
*              *  CUA             *  CUA              *                 04600015
*              *  CUA             *  CUA              *                 04700015
*              *  CUA             *  CUA              *                 04800015
*              *  CUA             *  ZEROS            *                 04900015
*              ****************************************                 05000015
*                                                                     * 05100015
*   REPDAR                        ( ASRMAC )                            05200015
*              *******************                                      05300015
*        +16   *        *        *                                      05400015
*              *******************                                      05500015
*                                                                       05600015
*              *******************                                      05700015
*   COMSYSRS   *  CUA   *ATRB*   *                                      05800015
*              *******************                                      05900015
         SPACE 2                                                        06000015
* FIELD NAME   BYTES   FIELD DISCRIPTION                              * 06100015
*   STAT       1       PDAR STATUS BYTE, CODE 10 = TERMINATE SYSTEM   * 06200015
*        BIT   SETTING   MEANING                                      * 06300015
*        4     1         IRE IS TO BE SCHEDULED                       * 06400015
*        4     0         RESET TO ZERO IF REFRESH IS UNSUCCESSFUL     * 06500015
*   TCBAD      3       POINTER TO AFFECTED TASK CONTROL BLOCK         * 06600015
*   NAME       8       NAME OF PROGRAM TO BE SEARCHED IN THE LIBRARY, * 06700015
*                      OR RELATIVE OR ABSOLUTE TRACK ADDRESS OF THE   * 06800015
*                      LOAD MODULE TO BE REFRESHED. SEE FLAG.         * 06900015
*                                                                     * 07000015
         EJECT                                                          07050015
* FIELD NAME   BYTES   FIELD DISCRIPTION                              * 07100015
*   FLAG       1       REFRESH TABLE FLAGS                            * 07200015
*                                                                     * 07300015
*        BIT   SETTING   MEANING                                      * 07400015
*        0     0         ADDRESS IS ABSOLUTE STORAGE ADDRESS OF MODULE* 07500015
*                        TO BE REFRESHED, REFRESH LOADER WILL LOAD    * 07600015
*                        MODULE STARTING IN THIS LOCATION.            * 07700015
*        0     1         ADDRESS IS POINTER TO SCATTER LOAD EXTENT    * 07800015
*                        LIST.                                        * 07900015
*        1     1         MODULE IS IN SVC LIB                         * 08000015
*        2     1         MODULE IN ASR LIB (IMPLIES ABS TRK ADR)      * 08100015
*        3     1         NAME FIELD IS RELATIVE TRACK ADDRESS         * 08200015
*        4     1         NAME FIELD IS ABSOLUTE TRACK ADDRESS     -     08300015
*                        LENGTH IN PDARTAB+12 CONTAINS TEXT LENGTH      08400015
*        5     1         MODULE IS IN LINKLIB                         * 08500015
*        6     1         PRIMARY FAILURE                              * 08600015
*        7     1         SET BY LOADER IF REFRESH OF THIS MODULE OK   * 08700015
*                                                                     * 08900015
* FIELD NAME   BYTES   FIELD DISCRIPTION                              * 09000015
*   CUA        2       CHAN AND UNIT ADDRESS OF JOBLIB AND LINKLIB    * 09100015
*                      (UP TO ELEVEN UNITS ARE CLEARED BY ASRNUC)     * 09200015
*                                                                     * 09300015
*                                                                     * 09400015
* FIELD NAME   BYTES   FIELD DISCRIPTION                              * 09500015
*   ADDRESS    3       SEE FLAG BIT 0                                 * 09600015
*                                                                       09700015
* FIELD NAME   BYTES   FIELD DISCRIPTION                                09800015
*   LENGTH     2       SEE FLAG BIT 4                                   09900015
*                                                                       10000015
*                                                                     * 10100015
* FIELD NAME   BYTES   FIELD DISCRIPTION                              * 10200015
*   REPDAR+16  1       REPAIR SUCCESSFUL FLAGS                        * 10300015
*        BIT   SETTING   MEANING                                      * 10400015
*        3     0         REFRESH UNSUCCESSFUL, ERROR CONDITION        * 10500015
*        3     1         REFRESH SUCCESSFUL                           * 10600015
*        7     0         REFRESH UNSUCCESSFUL, NO IRE                 * 10700015
*        7     1         IRE IS SCHEDULED FOLLOWING EXECUTION OF THE  * 10800015
*                        REFRESH LOADER, REFRESH WAS SUCCESSFUL.      * 10900015
*                                                                     * 11000015
* FIELD NAME   BYTES   FIELD DISCRIPTION                              * 11100015
*   REPDAR+17  1       REFRESH LOADER COMPLETION CODES                  11200015
*                                00  -  SUCCESSFUL                      11300015
*                                FF  -  UNSUCCESSFUL                    11400015
*                                                                     * 11500015
* FIELD NAME   BYTES   FIELD DISCRIPTION                              * 11600015
*   CUA        2       CHAN AND UNIT ADR OF (SYSRES) ASRLIB DEVICE    * 11700015
*   ATRB       1       ATTRIBUTES-CYL/TRK OF (SYSRES) DEVICE          * 11800015
         SPACE                                                          11900015
*EXITS   IGFASR20             PDAR ABEND                              * 12000015
*        IGFASR2C             IRE RETRY                               * 12100015
*                                                                     * 12200015
*TABLES AND WORK AREAS  COMNUC                                        * 12300015
*                       PDARTAB                                       * 12400015
*                       REPDAR                                        * 12500015
*                                                                       12600015
*                                                                       12700015
*RESTRICTIONS- A MODULE IN OVERLAY FORMAT WILL NOT BE LOADED.         * 12800015
*              MODULES LACKING THE 'REFRESHABLE' ATTRIBUTE WILL NOT   * 12900015
*              BE LOADED.                                             * 13000015
*              THE MAXIMUM SIZE SCATTER TRANSLATE RECORD THAT CAN BE  * 13100015
*              HANDLED IS 1K BYTES, DUE TO STORAGE LIMITATIONS.       * 13200015
         EJECT                                                          13300015
IGFASR10 CSECT                      REFRESH-LOADER                      13400015
         USING IGFASR10,BASEREG    BASE FOR MODULE                      13500015
         USING ASRMAC,MACBASE      BASE FOR ASRMAC DSECT                13600015
         USING CVTMAC,CVTREG                                            13700015
         USING IHADEB,DEBREG                                            13800015
         USING IHADCB,DCBREG                                            13900015
*********************************************************************** 14000015
*              GPR EQUATES                                            * 14100015
*********************************************************************** 14200015
         SPACE 2                                                        14300015
*                                                                       14400015
*NAME          GPR                  FUNCTION OF REGISTER                14500015
*                                                                       14600015
W0       EQU   0                    WORK                                14700015
W1       EQU   1                    WORK                                14800015
W2       EQU   2                    WORK                                14900015
CUAREG   EQU   2    CUA FOR I/O ROUTINE                                 15000015
W3       EQU   3                    WORK                                15100015
W4       EQU   4                    WORK                                15200015
CNTREG   EQU   4    MAX RETRY COUNT FOR SIO                             15300015
W5       EQU   5                    WORK                                15400015
LINK2    EQU   5              SECONDARY LINK REG FOR I/O SENSE RTN      15500015
W6       EQU   6                    WORK                                15600015
W7       EQU   7                    WORK                                15700015
W8       EQU   8                    WORK                                15800015
W9       EQU   9                                                        15900015
LINKREG  EQU   9    INTERNAL LINKAGE REGISTER                           16000015
DEBREG   EQU   10   ADDR  OF DEB FOR LIBRARY OF MODULE TO BE REFRESHED  16100015
DCBREG   EQU   11   ADDR  OF DCB FOR LIBRARY OF MODULE TO BE REFRESHED  16200015
MACBASE  EQU   12   ASRMAC DSECT BASE, SET BY ASR NUCLEUS               16300015
CVTREG   EQU   13                                                       16400015
RETRNREG EQU   13   LINK REG BACK TO NUCLEUS                            16500015
NUCBASE  EQU   14   ASR NUCLEUS BASE REG, NOT TOUCHED                   16600015
BASEREG  EQU   15   MODULE BASE REG, SET BY ASR NUCLEUS                 16700015
         EJECT                                                          16800015
*********************************************************************** 16900015
*        PROGRAM INITIALIZATION / TERMINATION                         * 17000015
*********************************************************************** 17100015
         SPACE 2                                                        17200015
IGFASR10 CSECT                                                          17300015
START    EQU   *                                                        17400015
         ST    RETRNREG,SAVE       SAVE LINK BACK TO ASR NUCLEUS        17500015
         L     CVTREG,COMCVT       GET CVT ADDRESS FOR ADDRESSABILITY   17600015
         MVI   COMLEV10,LEVEL      MOVE MODULE CHANGE LEVEL             17700021
LEVEL    EQU   X'&LEV'                                                  17750021
         SPACE                                                          17800015
*  INITIALIZATION IN BACK. MAY BE OVERLAID IF SCATTER LOAD IMPLEMENTED. 17900015
         B     INIT                                                     18000015
         SPACE 2                                                        18100015
         DS    0D                   DOUBLE WORD BOUNDARY                18200015
TTRTABLE DC    C'2C'                IRE                                 18300015
         DC    4X'0'                                                    18400015
         DC    C'20'                PDAR TERMINATION                    18500015
         DC    4X'0'                                                    18600015
TABEND   DC    2X'0'                DELIMITER                           18700015
         SPACE 2                                                        18800015
* TERMINATION                                                           18900015
*      THE PROPER CODES TO CALL EITHER IRE OR PDER TERMINATION ARE SET  19000015
*      AND THE MODULE IS CALLED.                                        19100015
         SPACE 2                                                        19200015
* NORMAL RETURN                                                         19300015
RETURN   EQU   *                                                        19400015
         OI    PDARTAB+8,X'01'     SET REFRESH SUCCESSFUL               19500015
         OI    REPDAR+16,X'10'      SET SUCCESSFUL REPAIR               19600015
         TM    REPDAR+16,X'01'      SCHEDULE IRE                        19700015
         BZ    EXIT                                                     19800015
         LH    W1,TTRTABLE          CALL IRE                            19900015
         MVC   COMNUC(4),TTRTABLE+2                                     20000015
         L     RETRNREG,SAVE       GET  LINK BACK TO ASR NUCLEUS        20100015
         BR    RETRNREG            RETURN TO NUCLEUS                    20200015
         SPACE 2                                                        20300015
* THERE HAS BEEN AN ERROR AND THE MODULE WAS NOT REFRESHED.             20400015
NOREFRSH EQU   *                                                        20500015
         MVI   REPDAR+17,X'FF'    SET UNSUCCESSFUL REFRESH              20600015
         NI    REPDAR+16,X'EE'      RESET PRI. ERROR & SCHEDULE IRE     20700015
         TM    PDARTAB+8,X'64'     WAS MODULE SUC, ASR, OR LINK         20800015
         BZ    RSTIRE               BRANCH IF NO                        20900015
         MVI   PDARSTAT,X'10'       SET STAT 10,TERMINATE SYSTEM        21000015
RSTIRE   EQU   *                                                        21100015
         NI    PDARSTAT,X'F7'       RESET SCHEDULE IRE BIT              21200015
EXIT     EQU   *                                                        21300015
         LH    W1,TTRTABLE+6        CALL PDAR TERMINATION               21400015
         MVC   COMNUC(4),TTRTABLE+8                                     21500015
         L     RETRNREG,SAVE       GET LINK BACK TO ASR NUCLEUS         21600015
         BR    RETRNREG            RETURN TO NUCLEUS                    21700015
         EJECT                                                          21800015
*********************************************************************** 21900015
*        REFRESH ROUTINE                                                22000015
*              THE REFRESH ROUTINE WILL LOAD A PROGRAM MODULE INTO    * 22100015
*        THE SPECIFIED LOCATION(S) IN MAIN STORAGE AS INDICATED BY    * 22200015
*        THE ADDRESS FIELD OF THE PDAR REFRESH TABLE, OR THE EXTENT   * 22300015
*        LIST IF THE MODULE WAS LOADED IN THE SCATTER LOAD FORMAT.    * 22400015
*********************************************************************** 22500015
         SPACE                                                          22600015
REFRMOD  EQU   *                                                        22700015
         SPACE                                                          22800015
* CONVERT THE TTR                                                       22900015
*   ENTERED BY INITIALIZATION ROUTINE, SCATTER ROUTINE, AND  SEARCH     22930015
*      ROUTINE WHEN TTR MUST BE CONVERTED.                              22960015
CNVTTR   EQU   *                                                        23000015
         LM    W0,W1,LISTZ         GET TTR FOR FIRST TEXT               23100015
         SLDL  W0,16                TTR IN REG. ZERO                    23200015
         IC    W0,LISTCN                GET CONCATENATION NUMBER        23300015
         LA    W2,MEXTENT               ADDRESS FOR ABS TRK ADDR        23400015
         BAL   LINKREG,TTRCNVT          CONVERT TTRN                    23500015
* GET RELOCATION ORIGIN (WHERE IN STG MODULE IS TO BE LOADED) FOR CCWS  23600015
         L     W8,RPTR                                                  23700015
         TM    LISTATR2,X'40'      DOES ASSIGNED ORIGIN OF 1ST TEXT = 0 23800015
         BO    SETCCW                                                   23900015
         L     W2,LISTORIG         ORIG OF FIRST TEXT                   24000015
         SRL   W2,8                                                     24100015
         AR    W8,W2               ADD RELOC TO ORIGIN                  24200015
         SPACE 2                                                        24300015
*  INITIALIZATION BRANCHES HERE WHEN ABSOLUTE TRACK ADDRESS IS GIVEN.   24330015
*   IF SO, W8 IS ALREADY LOADED.                                        24360015
SETCCW   EQU   *                                                        24400015
         ST    W8,READTXT          RELOC  ORIG  TO CHAN PROG            24500015
         MVI   READTXT,X'06'            RESTORE OP                      24600015
         MVC   READTXT+6(2),LISTCNT     COUNT OF 1ST TEXT TO C P        24700015
         MVC   NEXTCNT(5),SRCHADDR      MOVE CCHHR FOR I/O EXTENT CHK   24800015
         TM    LISTATR1,X'01'      TEST ONE TEXT,NO RLD'S               24900015
         BZ    RDTXT               BRANCH IF MULTI RECS                 25000015
         NI    READTXT+4,X'BF'          TURN CC OFF                     25100015
         MVI   FLAGS+3,X'FF'        SET LAST INDICATOR                  25200015
* READ TEXT AND NEXT COUNT                                              25300015
RDTXT    EQU   *                                                        25400015
         LA    W1,READTXT     SET TIC ADDRESS TO READ TEXT              25500015
         ST    W1,TICADDR                                               25600015
         BAL   LINKREG,IOROUTNE         READ TEXT                       25700015
         CLI   FLAGS+3,X'FF'            LAST INDICATOR ON               25800015
         BE    RETURN              NO RLDS TO PROCESS                   25900015
         CLI   RLDBUF,X'04'        HAS THE LAST RLD BEEN PROCESSED YET. 26000015
         BE    RETURN              YES RETURN TO ASRNUC AND IRE         26100015
* READ RLD AND NEXT COUNT                                               26200015
         LA    W1,READRLD     SET TIC ADDRESS TO READ RLD               26300015
         ST    W1,TICADDR                                               26400015
         MVC   SRCHADDR(5),NEXTCNT      CCHHR OF RLD RECORD             26500015
         BAL   LINKREG,IOROUTNE         READ RLD                        26600015
         EJECT                                                          26700015
*              BUFFER TABLE PROCESSING                                  26800015
* THE FIRST BYTE OF THE RLD INDICATES IF RLD INFO IS PRESENT OR IF THE  26820015
*  LAST TEXT RECORD FOR THE MODULE IS NEXT.  THE RLD ALSO CONTAINS THE  26840015
*  NEXT READ CCW THAT IS USED.                                          26860015
TSTRLD   EQU   *                                                        26900015
         TM    RLDBUF,X'02'             TEST RLD'S                      27000015
         BZ    FTPCI01              BRANCH NO RLDS                      27100015
         B     FT017                TO RELOCATION                       27200015
FTPCI01  EQU   *                                                        27300015
         TM    RLDBUF,X'01'        TEST BUF FOR CONTROL.                27400015
         BZ    FTPCI05              BRANCH RLD ONLY                     27500015
         TM    FLAGS+1,X'FF'        TEST FOR SCATTER                    27600015
         BC    14,FTPCI021          BR NO SCATTER                       27700015
         LA    W4,RLDBUF+16        CALC LOC OF ID FOR                   27800015
         AH    W4,RLDBUF+6         NEXT RELOC FACTOR                    27900015
         LH    W4,0(W4)             LOAD TEXT ID                        28000015
         LA    W4,4(W4,W4)          2X  ID +4                           28100015
         A     W4,TRANS             PLUS TBL ADDRESS                    28200015
         LH    W4,0(W4)             LOAD TR TBL VALUE                   28300015
         SLL   W4,2                                                     28400015
         A     W4,SCAT              ADR OF RELOC FACTOR                 28500015
         MVC   RPTR(4),0(W4)                                            28600015
FTPCI021 EQU   *                                                        28700015
         LM    W4,W5,RLDBUF+8      LOAD NEXT TEXT CCW                   28800015
         A     W4,RPTR              RELOC TEXT CCW                      28900015
         STM   W4,W5,READTXT            STORE NEW READ TEXT CCW         29000015
FTPCI05  EQU   *                                                        29100015
         TM    RLDBUF,X'04'        TEST FOR END OF RLDS.                29200015
         BZ    FTPCI051             NO                                  29300015
         CLI   RLDBUF,X'0E'        LAST RLD                             29400015
         BE    RETURN          BR TES,  NO - ONE MORE TEXT              29500015
         NI    READTXT+4,X'BF'          CLEAR CC BIT                    29600015
         MVI   RLDBUF,X'04'        SET RLD LAST INDICATOR AND READ TXT. 29700015
FTPCI051 EQU   *                                                        29800015
         MVC   SRCHADDR(5),NEXTCNT      CCHHR OF NEXT TEXT RECORD       29900015
         B     RDTXT                                                    30000015
         EJECT                                                          30100015
*              INITIALIZATION FOR SCATTER                               30200015
         SPACE 2                                                        30300015
SCATRLD  EQU   *                                                        30400015
FT006    EQU   *                                                        30500015
         MVC   BDWD(4),LISTADDR+39     NO. OF BYTES IN TR/SC LIST       30600015
         LH    W1,BDWD              SCAT SIZE                           30700015
         LH    W2,BDWD+2            TR TABLE SIZE                       30800015
         LA    W1,4(W1,W2)          SC + TR SIZE                        30900015
         LA    W3,TRANSBUF          ADDR OF TRANSLATE BUFFER            31000015
         ST    W3,TRANS             PTR TO TRANSLATE LIST               31100015
         LA    W4,4(W3,W2)          ADDR OF SCATT LIST                  31200015
         ST    W4,SCAT                                                  31300015
         LR    W3,W1                SC + TR SIZE                        31400015
         LM    W0,W1,LISTADDR+20    TTR FOR SCATT LIST                  31500015
         SLDL  W0,16                ADJUST TTR                          31600015
         IC    W0,LISTCN                GET C.N.                        31700015
         LA    W2,MEXTENT               ADDRESS FOR ABS TRK ADDR        31800015
         ST    W3,SAVE+4                                                31900015
         BAL   LINKREG,TTRCNVT          CONVERT TTR                     32000015
         L     W3,SAVE+4                                                32100015
         A     W3,TRANS             END OF TR&SC LST-4                  32200015
FT00601  EQU   *                                                        32300015
         LA    W1,1020                                                  32400015
         SR    W3,W1                CALC SIZE OF SC/TR REC              32500015
         C     W3,TRANS             REC = OR GR THAN 1024               32600015
         BE    FT00602              EQUAL                               32700015
         BH    SCTERR               HIGH, SCATTER ERROR                 32800015
         AR    W3,W1                LOW, ADD BACK                       32900015
         S     W3,TRANS             GET SIZE AGAIN                      33000015
         STH   W3,READTXT+6             STORE SIZE LESS THAN 1024       33100015
FT00602  EQU   *                                                        33200015
         MVC   READTXT+1(3),TRANS+1    LIST ADDR TO CHAN PROG           33300015
         LA    W1,READTXT                                               33400015
         ST    W1,TICADDR                                               33500015
         BAL   LINKREG,IOROUTNE        READ LIST                        33600015
FT006023 EQU   *                                                        33700015
         L     W1,TRANS             ADDR OF T/S LIST                    33800015
         TM    0(W1),16             TEST FOR T/S TYPE REC               33900015
         BO    FT00603              BRANCH REC OK                       34000015
SCTERR   EQU   *                                                        34100015
         B     NOREFRSH                                                 34200015
FT00603  EQU   *                                                        34300015
         L     W2,BDWD              GET SIZE OS T/S LIST                34400015
         SRL   W2,18                NO. OF ENTRIES IN SCATT LIST        34500015
         BCTR  W2,0                                                     34600015
         L     W8,PDARTAB+8             GET EXTENT LIST ADDR            34700015
         CH    W2,6(W8)             COMPARE WITH EXTENT LIST            34800015
         BNE   SCTERR                                                   34900015
         L     W1,SCAT              ADDR OF SCATTER LIST                35000015
         LA    W3,4(W8)             INIT  EXT LIST POINTER              35100015
FT00604  EQU   *                                                        35200015
         LA    W1,4(W1)             INDEX SCATTER LIST POINTER          35300015
         LA    W3,4(W3)             EXTENT LIST POINTER                 35400015
         NI    0(W1),X'FC'          CLEAR 3 L. O. BITS OF ORIG          35500015
         BCT   W2,FT00605           BRANCH END                          35600015
         L     W2,LISTADDR+28       TOTAL LENGTH OF PROGRAM             35700015
         SRL   W2,8                 POS. IN L. O. 24 BITS               35800015
         S     W2,0(W1)             SUB LAST ORIG                       35900015
         CH    W2,2(W3)            COMPARE LAST LENGTH                  36000015
         BNE   SCTERR                                                   36100015
         B     INITRL                                                   36200015
         SPACE 2                                                        36300015
FT00605  EQU   *                                                        36400015
         L     W4,4(W1)             NEXT ORIG.                          36500015
         S     W4,0(W1)             CALC LENGTH                         36600015
         CH    W4,2(W3)            COMPARE WITH XLIST ENTRY             36700015
         BE    FT00604              EQUAL, OK                           36800015
         B     SCTERR               NOT, SCATTER ERROR                  36900015
INITRL   EQU   *                                                        37000015
         LA    W3,4(W3)             LAST ENTRY+4                        37100015
         L     W4,4(W8)             NO. OF ENTRIES IN EXT. LIST         37200015
         L     W2,SCAT              ADDR OF SCATTER LIST                37300015
FT00606  EQU   *                                                        37400015
         LA    W2,4(W2)             INDEX SCATTER LIST POINTER          37500015
         L     W1,0(W3)             CORE ALLOC ADDRESS                  37600015
         S     W1,0(W2)             ADD ORIG ADJUST                     37700015
         ST    W1,0(W2)             STORE RELOCATION FACTOR             37800015
         BCT   W4,FT00607           CHECK FOR END                       37900015
         SR    W3,W3                END                                 38000015
         IC    W3,LISTADDR+43       LEFT HALF FIRST TEXT ID             38100015
         SLL   W3,8                                                     38200015
         IC    W3,LISTADDR+44       RIGHT HALF ID                       38300015
         BAL   LINKREG,TBLLKUP                                          38400015
         MVC   RPTR(4),0(W3)        SAVE RELOCATION FACTOR              38500015
         MVI   FLAGS+1,X'FF'        PROGRAM BEING SCATTERED             38600015
         B     CNVTTR                                                   38700015
FT00607  EQU   *                                                        38800015
         LA    W3,4(W3)                                                 38900015
         B     FT00606                                                  39000015
         EJECT                                                          39100015
*                    RELOCATION ROUTINE                                 39200015
         SPACE 2                                                        39300015
FT017    EQU   *                                                        39400015
         LA    W1,RLDBUF+16             SET POINTER TO FIRST RPFA       39500015
         LR    W0,W1                                                    39600015
         AH    W0,RLDBUF+6              TOTAL SIZE OF BUFFER            39700015
FT018    EQU   *                                                        39800015
         TM    FLAGS+1,255          PROG BEING SCATT                    39900015
         BZ    FT020                BRANCH NOT SCATTER                  40000015
FT019    EQU   *                                                        40100015
         LH    W3,0(W1)             R PTR                               40200015
         BAL   LINKREG,TBLLKUP          TO GET RELOC FACTOR             40300015
         MVC   RPTR(4),0(W3)        R PTR STORED                        40400015
         LH    W3,2(W1)             P PTR                               40500015
         BAL   LINKREG,TBLLKUP          TO GET RELOC FACTOR             40600015
         MVC   PPTR(4),0(W3)                                            40700015
         B     FT021                                                    40800015
FT020    EQU   *                                                        40900015
         MVC   PPTR(4),RPTR                                             41000015
FT021    EQU   *                                                        41100015
         LA    W1,4(W1)             SET PTR TO FA                       41200015
         TM    0(W1),X'E0'          RELOC REQUIRED                      41300015
         BC    7,FT024              BRANCH NOT REQ                      41400015
         L     W2,0(W1)             ADDR OF LOAD CONST                  41500015
         A     W2,PPTR              RELOC ADDR OF LOAD CONST            41600015
FT02102  EQU   *                                                        41700015
         SR    W4,W4                NOT FULL WORD BOUNDARY              41800015
         ST    W4,BDWD              CLEAR BOUNDARY WORD                 41900015
         NI    0(W1),X'0F'          CLEAR UNWANTED FLAGS                42000015
         IC    W4,0(W1)             COUNT INTO REG                      42100015
         SRL   W4,2                                                     42200015
         LA    W3,BDWD+3            SET ADDR OF BDWD                    42300015
         SR    W3,W4                SET BD WD TO BYTES                  42400015
         EX    W4,FT025             MOVE ADCON TO BOUND WORD            42500015
         L     W5,BDWD              LOAD FROM BOUND WORD                42600015
         TM    0(W1),X'02'                                              42700015
         BC    8,FT022              BRANCH TO ADD                       42800015
         S     W5,RPTR              SUB RELOC FACTOR                    42900015
         B     FT023                                                    43000015
FT022    EQU   *                                                        43100015
         A     W5,RPTR              ADD RELOC FACTOR                    43200015
FT023    EQU   *                                                        43300015
         ST    W5,BDWD              RET TO BOUND WORD                   43400015
         EX    W4,FT026             RET RELOC ADCON                     43500015
FT024    EQU   *                                                        43600015
         LR    W3,W1                SAVE POINTER                        43700015
         LA    W1,4(W1)             ADD 4 TO COUNT                      43800015
         CR    W1,W0                DOES PTR=END                        43900015
         BC    8,FTPCI01            YES, RETURN FROM RELOC RTN          44000015
         TM    0(W3),X'01'          TEST TERM FLAG                      44100015
         BO    FT021+4              SAME R&P POINTERS                   44200015
         B     FT018                NEW R&P POINTERS                    44300015
FT025    EQU   *                                                        44400015
         MVC   0(1,W3),0(W2)                                            44500015
FT026    EQU   *                                                        44600015
         MVC   0(1,W2),0(W3)                                            44700015
         SPACE 2                                                        44800015
TBLLKUP  EQU   *                                                        44900015
         LA    W3,4(W3,W3)          2X ID+4=TR TBL VALUE                45000015
         A     W3,TRANS             INDEX PLUS TRANS TBL VALUE          45100015
         LH    W3,0(W3)                                                 45200015
         SLL   W3,2                 SCATTER INDEX VALUE                 45300015
         A     W3,SCAT              PLUS SCAT LIST ADDR                 45400015
         BR    LINKREG                                                  45500015
         EJECT                                                          45600015
*********************************************************************** 45700015
*        I/O ROUTINE                                                  * 45800015
*********************************************************************** 45900015
         SPACE 2                                                        46000015
IOROUTNE EQU   *                                                        46100015
         TM    PDARTAB+8,X'08'     IF ABSOLUTE TRACK BYPASS EXTENT      46200015
         BO    STARTIO             TESTS                                46300015
         SR    W3,W3     CLEAR REG                                      46400015
         IC    W3,MEXTENT     GET CURRENT EXTENT NUMBER                 46500015
         SLL   W3,4      FORM INDEX TO CURRENT EXTENT                   46600015
         LA    W3,DEBDVMOD(W3)   GET ADDRESS OF CURRENT EXTENT IN DEB   46700015
*  W3 POINTS TO CURRENT DEB EXTENT                                      46800015
         SPACE 2                                                        46900015
* GET CUA OF DEVICE TO BE READ     ASCERTAIN THAT ITS CHANNEL IS CLEAR  47000015
         SPACE                                                          47100015
RECYCLE  EQU   *                                                        47200015
         L     W5,0(W3)            GET UCB ADDR FOR CURRENT EXTENT      47300015
         LH    CUAREG,4(W5)        GET CUA FOR CURRENT EXTENT           47400015
         N     CUAREG,CUAMASK ISOLATE CUA                               47500015
CHKCHAN  CH    CUAREG,COMSYSRS     IS IT SYSRES                         47600015
         BE    CHKEXTNT            BR YES, ASR OR SVC LIB ON SYSRES     47700015
* AND SYSRES MUST BE CLEAR                                              47800015
         SPACE                                                          47900015
* ASCERTAIN THAT CHANNEL HAS BEEN CLEARED BY IGFASR1A OF PENDNG IO INTS 48000015
CHKCUA   LA    W0,11               NUMBER OF CUAS IN TABLE              48100015
         LA    W1,PDARCUA          GET ADDR OF TABLE WITH CLEARED CUAS  48200015
CMPCUA   CH    CUAREG,0(W1)        IS MOD CUA IN TABLE                  48300015
         BE    CHKEXTNT            BR YES, CHANNEL IS CLEARED           48400015
         LA    W1,2(W1)            STEP TO NEXT CUA                     48500015
         BCT   W0,CMPCUA           NOT EQUAL, CHECK NEXT                48600015
         B     NOREFRSH       SET REFRESH NOT POSSIBLE                  48700015
         SPACE 2                                                        48800015
* END OF EXTENT ROUTINE                                                 48900015
*    THIS CODE CHECKS THE CCHHR (NEXTCNT) TO ASCERTAIN THAT IT IS NOT   49000015
*    OUT OF THE EXTENT LIMITS SPECIFIED IN THE DEB. WHEN THE EXTENT IS  49100015
*    EXCEEDED, THE NEXT EXTENT IS OBTAINED AND CCHHR (NEXTCNT) IS       49200015
*    UPDATED.                                                           49300015
         SPACE                                                          49400015
CHKEXTNT EQU   *                                                        49500015
         CLC   NEXTCNT(4),6(W3)    TEST IF UNDER START LIMIT            49600015
         BL    OUTEXTNT            BR - LOWER THAN LOW ADDRESS          49700015
         CLC   NEXTCNT(4),10(W3)   TEST IF OVER END LIMIT               49800015
         BNH   STARTIO             BR EXTENT OK - NOT HIER END LIMIT    49900015
         SPACE                                                          50000015
* NEXTCNT HIGHER THAN END LIMIT, NEXT EXTENT NECESSARY                  50100015
OUTEXTNT EQU   *         ROUTINE TO UPDATE EXTENT                       50200015
         SR    W3,W3     CLEAR REG                                      50300015
         IC    W3,MEXTENT     GET CURRENT EXTENT NUMBER (0 TO N)        50400015
         LA    W3,1(0,W3)  INCREASE IT BY ONE FOR NEXT EXTENT           50500015
         SR    W1,W1     CLEAR REG                                      50600015
         IC    W1,DEBNMEXT    GET NUMBER OF EXTENTS IN THIS DEB (N+1)   50700015
         CR    W3,W1     WAS CURRENT LAST EXTENT IN DEB                 50800015
         BNE   NEXTEXT   NO, USE NEXT                                   50900015
         B     NOREFRSH       ERROR, CAN'T REFRESH                      51000015
         SPACE                                                          51100015
NEXTEXT  EQU  *          UPDATE EXTENT NUMBER AND SEEK ADDRESS          51200015
         STC   W3,MEXTENT     STORE NEW EXTENT NUMBER                   51300015
         SLL   W3,4      FORM INDEX TO NEW EXTENT                       51400015
         LA    W3,DEBDVMOD(W3)  GET ADDRESS OF NEW EXTENT               51500015
         MVC   SEEKADDR(6),4(W3)   GET STARTING BBCCHH                  51600015
         MVI   RECORD,X'01'             SET R TO ONE                    51700015
         MVC   NEXTCNT(4),SRCHADDR       UPDATE NEW SEARCH ADDRESS      51800015
         B     RECYCLE                                                  51900015
         SPACE                                                          52000015
* INITIATE I/O OPERATION                                                52100015
STARTIO  EQU   *                                                        52200015
         MVC   TIC+1(3),TICADDR+1  MOVE CCW START ADDR TO TIC CCW       52300015
         LA    CNTREG,10           SET RETRY COUNT TO 10                52400015
SIORTN   LA    W1,SEEK   GET SEEK CCW ADDR                              52500015
         ST    W1,72     STORE IN CAW                                   52600015
         SPACE                                                          52700015
TIO1     TIO   0(CUAREG) TEST I/O                                       52800015
         BC    8,SIO     IF NOT AVAILABLE, DEVICE NOT CLEARED OR OPER   52900015
         B     NOREFRSH            SET NO REFRESH                       53000015
         SPACE                                                          53100015
SIO      SIO   0(CUAREG) START I/O                                      53200015
         BC    8,TIO2    BR IF IO OPERATION INITIATED OKAY              53300015
TRYAGAIN BCT   CNTREG,SIORTN  IF NOT, TRY OPERATION OVER                53400015
         B     NOREFRSH       SET  REFRESH NOT POSSIBLE                 53500015
TIO2     TIO   0(CUAREG) TEST I/O                                       53600015
         BC    2,TIO2    LOOP UNTIL CHAN FINISHES                       53700015
         SPACE 2                                                        53800015
* TEST IF ALTERNATE TRACK IN USE                                        53900015
         TM    68,X'0D'       TEST IF EOF - CE,DE,UNIT EXCEPTION        54000015
         BC    14,TESTCSW     BR - NOT END OF FILE                      54100015
         CLC   SRCHADDR(4),R0BUFFER     COMPARE R0 AND SEEK ADDR        54200015
         BE    TRYAGAIN       BR - EQUAL, NOT ALT TRACK                 54300015
         B     ALTRK          BR - SET FOR ALT TRACK                    54400015
         SPACE                                                          54500015
* TEST CSW FOR UNIT CHECK, DE, OR ERRORS.                               54600015
TESTCSW  TM    68,X'06'       CHECK DE AND UNIT CHECK                   54700015
         BO    SENSE          BR YES -  SENSE AND CHECK FOR ALT TRK     54800015
         TM    68,X'0A'       CHECK CE AND UNIT CHECK                   54900015
         BO    SENSE          BR YES - SENSE AND CHECK FOR ALT TRK      55000015
         TM    68,X'04'       TEST FOR DEVICE END                       55100015
         BC    14,TIO2        BR - NOT DEVICE END                       55200015
         TM    69,X'FF'       CHECK FOR CHANNEL ERRORS                  55300015
         BC    7,TRYAGAIN     BR FOR RETRY - CHAN ERRORS                55400015
         BR    LINKREG        RETURN TO CALLER                          55500015
         SPACE                                                          55600015
* SENSE TO CHECK ALTERNATE TRACK AND END OF CYLINDER                    55700015
SENSE    EQU   *                                                        55800015
         LA    W1,SENSECCW         GET SENSE CCW ADDRESS                55900015
         ST    W1,72               STORE IN CAW                         56000015
         LR    LINK2,LINKREG       SAVE PREVIOUS LINKAGE                56100015
         BAL   LINKREG,TIO1              BR TO SENSE                    56200015
         LR    LINKREG,LINK2       RESTORE EARLIER LINKAGE              56300015
         TM    SENSDATA,X'02'      CHECK FOR ALT TRK BIT (TRK CNDTN CHK 56400015
         BO    ALTRK               BR TO SWITCH TO ALT TRK              56500015
         TM    SENSDATA+1,X'20'    CHECK FOR END OF CYLINDER            56600015
         BC    14,TRYAGAIN                                              56700015
         SPACE                                                          56800015
* UPDATE CYLINDER POSITION                                              56900015
         MVI   NEXTCNT+3,255       SET HEAD TO MAX COUNT                57000015
         L     (W5),0(W3)     GET  CURRENT EXTENTS UCB ADDRESS          57100015
         CLI   19(W5),5       IS UNIT TYPE 2321                         57200015
         BE    CYL2321                                                  57300015
         SPACE                                                          57400015
         MVI   NEXTCNT+2,255       SET HEAD TO MAX COUNT                57500015
CYLUPTD  EQU   *                                                        57600015
         L     W1,NEXTCNT               GET LAST USER CYLINDER POSITION 57700015
* IT IS SET TO MAX                                                      57800015
         A     W1,TIC+4            ADD 1 TO FORCE NAXT ADDRESS          57900015
         ST    W1,NEXTCNT               UPDATED CYLINDER ADDRESS        58000015
         MVI   NEXTCNT+4,1              SET R TO 1                      58100015
         MVC   SRCHADDR(5),NEXTCNT      TO SEEK ADDR                    58200015
         BR    LINKREG                                                  58300015
         SPACE                                                          58400015
CYL2321  EQU   *    END OF CYLINDER FOR 2321                            58500015
*   SUB-CELL   STRIP   CYLINDER   HEAD                                  58600015
*    0-19       0-9       0-4     0-19                                  58700015
         SPACE                                                          58800015
         CLI   NEXTCNT+2,4           LAST CYLINDER                      58900015
         BL    CYLUPTD        BR, NO                                    59000015
         MVI   NEXTCNT+2,255       SET CYLINDER TO MAX COUNT            59100015
         CLI   NEXTCNT+1,9    LAST STRIP                                59200015
         BL    CYLUPTD        BR,NO                                     59300015
         MVI   NEXTCNT+1,255       SET STRIP TO MAX COUNT               59400015
         B     CYLUPTD                                                  59500015
         SPACE 2                                                        59600015
* SWITCH TO AN ALTERNATE TRACK                                          59700015
ALTRK    MVC   SRCHADDR(4),R0BUFFER     SET ALT TRK SEEK ADDR           59800015
         B     SIORTN                   SEEK AGAIN                      59900015
         EJECT                                                          60000015
*********************************************************************** 60100015
*        CONVERT ROUTINE                                              * 60200015
*        THIS ROUTINE CONVERTS A RELATIVE DIRECT ACCESS ADDRESS AND   * 60300015
*        CONCATENATION NUMBER, TTRN, INTO ITS ABSOLUTE EQUIVALENT,    * 60400015
*        MBBCCHHR.                                                    * 60500015
* REGISTER USAGE                                                        60600015
*        WO = CONTAINS TTRN, WHERE N IS CONCATENATION FACTOR            60700015
*        W2 = ADDRESS OF MEXTENT FOR RESULTING MBBCCHHR                 60800015
*        W1 = ADDRESS FOR DEB EXTENT                                  * 60900015
         SPACE                                                          61000015
* FOR EACH EXTENT, THE AMOUNT TT IS REDUCED BY THE NUMBER OF TRACKS IN  61100015
* THE EXTENT. THE PROPER EXTENT IS REACHED WHEN BALANCE IS NEGATIVE.    61200015
* ( A TTRN OF ZERO YIELDS ADDRESS IN 1ST EXTENT (EXTENT 0).)            61300015
*********************************************************************** 61400015
         SPACE                                                          61500015
TTRCNVT  EQU   *         TTRN TO MBBCCHHR CONVERT ROUTINE               61600015
         SR    W3,W3                                                    61700015
         IC    W3,DEBNMEXT          NUMBER OF EXTENTS                   61800015
         LR    W4,W3                USE FOR LIMIT                       61900015
         LA    W7,X'FF'             MASK                                62000015
         NR    W7,W0                CONCATENATION NUMBER (N)            62100015
         BZ    CNVTA                IS N ZERO                           62200015
         LR    W6,W3                NUMBER OF EXTENTS                   62300015
         SLL   W6,4                 TIMES 16                            62400015
         AR    W6,W7                ADD N                               62500015
         IC    W7,DEBDVMOD-1(W6)     FIRST M OF DATA SET N              62600015
         SR    W4,W7                ADJUST LIMIT                        62700015
         SLL   W7,4                 TIMES 16                            62800015
CNVTA    EQU   *                                                        62900015
         LA    W1,32(DEBREG)       GET DEB EXTENT ADDR                  63000015
* W1  POINTS TO DEB EXTENT                                              63100015
         AR    W1,W7          ADJUST REG-W7 CONTAINS 0 OR OFFSET TO EXT 63200015
         SRL   W0,8           REMOVE N                                  63300015
         STC   W0,7(W2)             SAVE R                              63400015
         SRL   W0,8           GET TT                                    63500015
CNVTB    EQU   *                                                        63600015
         SH    W0,14(W1)           DECREASE BY TRKS IN EXTENT           63700015
         BM    CNVTC          BR IF LESS THAN 0. IT IS PROPER EXTENT.   63800015
         LA    W1,16(W1)             OR GO TO NEXT EXTENT               63900015
         BCT   W4,CNVTB             Q. STILL WITHIN DEB                 64000015
         B     NOREFRSH       SET REFRESH NOT POSSIBLE                  64100015
CNVTC    EQU   *                                                        64200015
         SR    W3,W4                DEVELOP M                           64300015
         AH    W0,14(W1)           ADD BACK OVERDRAW                    64400015
         STC   W3,0(W2)             STORE M                             64500015
         MVC   1(6,W2),4(W1)       GET BBCCHH FROM EXTENT               64600015
         BCR   8,LINKREG      BR IF RESULT W0 IS 0. ELSE DIVIDE NECESS. 64700015
*              PICKUP LOCATION OF APPROPRIATE DEVICE CONSTANTS          64800015
         L     W5,0(W1)            UCB ADDRESS                          64900015
         IC    W5,19(W5)            GET DEVICE TYPE CODE                65000015
         LA    W6,15                MASK                                65100015
         NR    W5,W6                LEAVE 4 L.O. BITS                   65200015
         L     W6,CVTZDTAB    GET DEVICE TABLE ATTRIBUTES ADDRESS       65300015
         IC    W5,0(W5,W6)          DISPLACEMENT FOR DEVICE             65400015
         LH    W3,2(W5,W6)          TRKS/CYL                            65500015
         LR    W5,W0                DIVIDE REG.                         65600015
         AH    W5,8(W1)       STARTING HH                               65700015
         LA    W4,0           SET EVEN TO 0                             65800015
         DR    W4,W3                QUO=CYLS,REN=TRKS                   65900015
         STC   W4,6(W2)             STORE H                             66000015
         AH    W5,6(W1)       PLUS CC START                             66100015
         STC   W5,4(W2)             STORE C                             66200015
         BR    LINKREG        RETURN                                    66300015
         EJECT                                                          66400015
*********************************************************************** 66500015
*     CONSTANTS, BUFFERS, AND CHANNEL PROGRAMS                        * 66600015
*********************************************************************** 66700015
         SPACE 2                                                        66800015
* CHANNEL PROGRAM  BASE                                                 66900015
         DS    0D                                                       67000015
SEEK     CCW   7,SEEKADDR-START,X'40',6      CC                         67100015
READR0   CCW   22,R0BUFFER-START,X'60',8     CC + SILI                  67200015
SRCHIDEQ CCW   49,SRCHADDR-START,X'40',5     CC                         67300015
SRCHTIC  CCW   8,SRCHIDEQ-START,X'40',1  CC                             67400015
TIC      CCW   8,TICADDR-START,X'00',1  TIC TO READ TXT OR RLD.         67500015
         SPACE                                                          67600015
* READ TEXT DATA AND NEXT COUNT (USUALLY RLD)                           67700015
READTXT  CCW   6,0,X'60',1024           CC + SILI                       67800015
         CCW   146,NEXTCNT-START,0,8         STOP                       67900015
         SPACE                                                          68000015
* READ RLD DATA AND NEXT COUNT (USUALLY TEXT)                           68100015
READRLD  CCW   6,RLDBUF-START,X'60',260      CC + SILI                  68200015
         CCW   146,NEXTCNT-START,0,8    STOP                            68300015
         SPACE                                                          68400015
* READ PDS BLOCK AND COUNT                                              68500015
READPDS  CCW   146,NEXTCNT-START,X'40',8     READ COUNT                 68600015
SRCHHIEQ CCW   105,0,X'40',8                 SEARCH KEY HIGH OR EQUAL   68700015
         CCW   8,READPDS-START,X'00',1                                  68800015
         CCW   6,RDAREA-START,X'00',256      READ BLOCK                 68900015
         SPACE 5                                                        69000015
SENSECCW CCW   4,SENSDATA-START,X'20',4      SILI                       69100015
         SPACE 2                                                        69200015
MEXTENT  DC    X'0'      M   -CURRENT EXTENT NUMBER                     69300015
SEEKADDR DC    XL2'0'    BB  -SEEK ON BBCCHHR                           69400015
SRCHADDR DC    XL4'0'    CCHH-SEARCH ON CCHHR                           69500015
RECORD   DC    X'0'      R   -ID OF RECORD                              69600015
         SPACE                                                          69700015
SENSDATA DC    D'0'      BUFFER FOR SENSE DATA                          69800015
NEXTCNT  DC    D'0'           NEXT CCHHR (SRCHADDR) FOR RLD OR TEXT.    69900015
R0BUFFER DC    D'0'  BUFFER FOR RECORD 0                                70000015
TICADDR  DC    F'0'      ADDRESS OF READTXT OF READRLD OR READ PDS.     70100015
         SPACE                                                          70200015
*                                                                       70300015
*  BUILD LIST -  CONSTRUCTED AS FOLLOWS                                 70400015
*    (1) WHEN NAME= NAME, BY SEARCH ROUTINE                             70500015
*    (2) WHEN NAME = ABS TRK OR TTR, AS A DUNMY BY INITIALIZATION       70600015
*                                                                       70700015
         DS    0F                                                       70800015
LISTADDR DC    H'1'                NUMBER OF ENTRIES IN LIST (FF)       70900015
LISTLL   DC    H'44'          NUMBER OF BYTES IN LIST ENTRY             71000015
LISTNAME DC    8X'0'          MEMBER NAME                               71100015
LISTTT   DC    H'0'           RELATIVE TRACK                            71200015
LISTR    DC    X'0'           RECORD                                    71300015
LISTCN   DC    X'0'           CONCATENATION NUMBER                      71400015
LISTZ    DC    X'0'           Z=0  FOR BOUNDARY. IF NAME IN LINKLIB,Z=1 71500015
*                                                IF NAME IN JOBLIB ,Z=2 71600015
LISTC    DC    X'0'           BIT 3-7 = NUMBER OF HALF-WDS IN USER FLD  71700015
LISTDATA DC    15H'0'         USER DATA FIELD                           71800015
* USER DATA FIELD                                                       71900015
LISTTTR  EQU   LISTDATA       TTR  FOR FIRST TEXT                       72000015
LISTATR1 EQU   LISTDATA+8     ATTRIBUTE FIELD (2 BBYTES)                72100015
LISTATR2 EQU   LISTDATA+9                                               72200015
LISTORIG EQU   LISTDATA+18    ORIGIN OF FIRST TEXT                      72300015
LISTCNT  EQU   LISTDATA+13    COUNT (LENGTH) OF FIRST TEXT              72400015
         SPACE 2                                                        72500015
SCAT     DC    F'0'                                                     72600015
TRANS    DC    A(0)               ADDR OF TRANSLATE LIST                72700015
RPTR     DC    F'0'                                                     72800015
PPTR     DC    F'0'                                                     72900015
BDWD     DC    F'0'                                                     73000015
FLAGS    DC    F'0'                                                     73100015
RDAREA   DS    0D                      DIRECTORY READ BUFFER            73200015
RLDBUF   DC    33D'0'         RELOCATION DICTIONARY FOR REFRESH ROUTINE 73300015
CUAMASK  DC    X'000007FF'    MASK TO ISOLATE CUA FROM UCB              73400015
SAVE     DC    D'0'                SAVE AREA FOR REG 13 AND W3 SCTR     73500015
MAXCT    DC    H'1024'        MAX COUNT WHEN TTR PASSED FOR MODULE      73600015
         DS    0F                                                       73700015
* TRANSBUF MUST BE LOCATED AT LESS THAN 800 TO ALLOW 1K FOR SCATTER     73750015
TRANSBUF DC    64F'0'             TRANSLATE/SCATTER RECORD BUFFER       73800015
         SPACE 2                                                        73900015
C14      DC    H'14'                                                    74000015
H256     DC    H'256'                                                   74100015
         EJECT                                                          74200015
*********************************************************************** 74300015
*        CONTROL INITIALIZATION ROUTINE                               * 74400015
*  THIS ROUTINE RELOCATES THE CCWS, DETERMINES WHICH LIBRARY THE MODULE 74430015
*  TO BE REFRESHED IS ON, AND SETS UP A BUILD LIST FOR THE REFRESH RTN. 74460015
*********************************************************************** 74500015
         SPACE 2                                                        74600015
INIT     EQU   *                                                        74700015
         SPACE                                                          74800015
* RELOCATE CCWS                                                         74900015
         LA    W1,14     GET NUMBER OF CCWS TO BE RELOCATED             75000015
         LA    W2,SEEK             GET ADDR OF CCWS                     75100015
LOOP     LR    W3,BASEREG          GET MODULE BASE                      75200015
         A     W3,0(W2)                                                 75300015
         ST    W3,0(W2)                                                 75400015
         LA    W2,8(W2)                                                 75500015
         BCT   W1,LOOP                                                  75600015
         SPACE 2                                                        75700015
*  TEST  PDARTAB FLAG TO DETERMINE THE LIB OF MODULE. GET SVCLIB DCB OR 75800015
*  IF PRESENT, A JOBLIB DCB. OTHERWISE, LINKLIB DCB IS OBTAINED.        75840015
*   IN BUILD LIST:  Z=0 PRIVATE LIBRARY                                 75880015
*                   Z=1 LINK LIBRARY                                    75920015
*                   Z=2 JOB LIBRARY                                     75960015
         SPACE                                                          76000015
         SR    DCBREG,DCBREG                                            76100015
         TM    PDARTAB+8,X'60'          IS MODULE ON ASRLIB OR SVCLIB   76200015
         BZ    TSTLINK             BR NO, TEST FOR LINK                 76300015
         L     DCBREG,CVTSVDCB     GET  SVCLIB DCB ADDR                 76400015
         B     GETDEB                                                   76500015
TSTLINK  TM    PDARTAB+8,X'04'          IS LINKLIB SPECIFIED            76600015
         BO    SETLNK              GO LOAD LINKLIB DCB                  76700015
         L     DCBREG,PDARSTAT   USE CURRENT TCB ADDRESS TO GET         76800015
         L     DCBREG,40(DCBREG)             JOBLIB DCB ADDRESS         76900015
         LTR   DCBREG,DCBREG     IS A JOBLIB ASSIGNED TO THIS TASK      77000015
         BZ    SETLNK              NO JOBLIB PRESENT  SET LINKLIB       77100015
         MVI   LISTZ,2        NO DCB PTR, INDICATE JOBLIB BY Z=2        77200015
         B     GETDEB                                                   77300015
SETLNK   EQU   *                                                        77400015
         L     DCBREG,CVTLINK      GET  LINKLIB DCB ADDR                77500015
         MVI   LISTZ,1        INDICATE LINKLIB BY Z=1                   77600015
         MVI   LISTCN,0            SET CONCATENATION NUMBER TO ZERO     77700015
GETDEB   L     DEBREG,DCBDEBAD          GET DEB ADDR                    77800015
         SPACE 2                                                        77900015
*  DETERMINE IF TTR, ABSOLUTE ADDRESS, OR NAME  FOR MODULE TO BE REFRSD 78000015
TSTTR    EQU   *                                                        78100015
         TM    PDARTAB+8,X'10'          IS NAME FIELD A TTR             78200015
         BO    MOVETTR             BR YES                               78300015
         TM    PDARTAB+8,X'08'          IS IT ABS TRK ADDR              78400015
         BO    MOVEADDR       BR YES                                    78500015
         SPACE                                                          78550015
* THE MODULES NAME HAS BEEN PASSED. THE PDS MUST BE READ AND SEARCHED.  78600015
         MVC   LISTNAME(8),PDARTAB      MOVE NAME TO BUILD LIST         78700015
         B     SRCHPDS        READ IN BUILD LIST; THEN REFRESH MODULE   78800015
         SPACE                                                          78900015
* ABSOLUTE TRACK OR TTR PASSED.                                         78960015
*  INITIALIZE A DUMMY BUILD LIST FOR REFRESH ROUTINE                    79020015
         SPACE                                                          79100015
* THE ABSOLUTE TRACK ADDRESS IS GIVEN. IT IS MOVED FOR USE IN THE CHPRG 79200015
MOVEADDR EQU   *                                                        79300015
         MVC   SEEKADDR(7),PDARTAB+1    MOVE ABS TRK ADDR TO SEEK ADDR  79400015
         MVC   LISTCNT(2),PDARTAB+12    MOVE COUNT (LENGTH) TO LIST     79500015
         LH    CUAREG,COMSYSRS     SET SYSRES CUA FOR START I/O RTNE    79600015
         SPACE                                                          79700015
* A TTR IS GIVEN IN THE NAME FIELD.                                     79800015
MOVETTR  EQU   *                                                        79900015
         MVI   LISTC,X'16'    SET HALF-WDS IN USER DATA FIELD (C = 22)  80000015
*                              ATTRIBUTES = NO RLD ITEMS, ONE BLOCK OF  80100015
*                               TEXT, ORIGIN =0 , AND ENTRY POINT =0 .  80200015
         LA    W1,X'168'                                                80300015
         STH   W1,LISTATR1                                              80400015
         MVC   RPTR+1(3),PDARTAB+9      GET STG ADR FOR RELOCATION FCTR 80500015
         L     W8,RPTR             GET IN REG FOR REFRESH ROUTINE       80600015
         SPACE                                                          80700015
         TM    PDARTAB+8,X'08'     IS THIS ABS TRK ADDR                 80800015
         BO    SETCCW              BR YES TO SET UP CHAN PROG- TO REFR  80900015
         SPACE 2                                                        81000015
         MVC   LISTTTR(3),PDARTAB+4     MOVE TTR OF 1ST BLOCK OF TEXT   81100015
         MVC   LISTCNT(2),MAXCT         MOVE MAX COUNT TO LIST          81200015
         B     CNVTTR                                                   81300015
         TITLE     'ASR-MCH REFRESH LOADER SEARCH ROUTINE'              81400015
*********************************************************************** 81500015
*        SEARCH ROUTINE                                               * 81600015
*        THE SEARCH ROUTINE READS THE DIRECTORY OF THE PARTITIONED DATA 81700015
*  SET UPON WHICH THE MODULE RESIDES. THE DIRECTORY STARTS ON THE FIRST 81800015
*  TRACK IN THE EXTENT ALLOCATED TO THE DATA SET. THIS ROUTINE THEN     81900015
*  SEARCHES FOR THE NAME OF THE MODULE AND WHEN FOUND, SAVES THE RECORD 82000015
*  ASSOCIATED WITH IT (THIS RECORD MAKES THE BUILD LIST).               82100015
*********************************************************************** 82300015
         SPACE                                                          82400015
SRCHPDS  EQU   *                                                        82500015
         SPACE                                                          82700015
* USE TTR CONVERT ROUTINE TO GET ABS TRK ADDR FOR PDS ON LIBRARY        82800015
         MVI   LISTR,0        ZERO R FIELD                              82900015
INSERTCN EQU   *                                                        83000015
         SR    W0,W0          ZERO TTRN REG FOR TTRCNVT                 83100015
NEXTCN   EQU   *                                                        83200015
         IC    W0,LISTCN      INSERT C. N.                              83300015
         LA    W2,MEXTENT       ADDR OF MBBCCHHR (IN 1ST DEB EXTENT)    83400015
         BAL   LINKREG,TTRCNVT     TO TTR CONVERT ROUTINE TO GET ABS AD 83500015
         SPACE                                                          83600015
*  READ DIRECTORY BLOCK WITH LOGICAL RECORD CONTAINING NAME OF MOD      83700015
*  THE BLOCK KEY CONTAINS THE NAME OF THE LOGICAL RECORD WITH THE       83800015
*  HIGHEST BINARY VALUE. (THE LAST BLOCKS KEY IS FFFFFFFFFFFFFFFF.)     83900015
*  THE SEARCH WITH NAME IS HIGH OR EQUAL.                               84000015
         LA    W1,READPDS     GET READ BLK CCW ADDR                     84100015
         ST    W1,TICADDR     PUT IN CP BASE TIC ADDR                   84200015
         LA    W1,LISTNAME    GET ADDR OF NAME IN BLDL LIST             84300015
         ST    W1,SRCHHIEQ    STORE IN CCW FOR SEARCH KEY               84400015
         MVI   SRCHHIEQ,105   RESTORE OP CODE                           84500015
         MVC   NEXTCNT(5),SRCHADDR  MOVE CCHH FOR I/O EXTENT CHK        84600015
READBLCK EQU   *                                                        84700015
         BAL   LINKREG,IOROUTNE    READ DIRECTORY                       84800015
         SPACE                                                          84900015
* SCAN DIRECTORY BLOCK FOR CORRECT RECORD                               85000015
         LA    W3,RDAREA-1         MINUS ONE FOR END OF READ            85100015
         AH    W3,RDAREA           SET END ADDRESS (RDAREA-1+C)         85200015
         LA    W1,RDAREA+2  GET ADDR OF FIRST LOGICAL RECORD            85300015
         LA    W0,X'1F'     MASK FOR  C BYTE IN RECORD                  85400015
COMPARE  CLC   0(8,W1),LISTNAME         COMPARE NAMES                   85500015
         BE    NAMEFND                                                  85600015
         BH    NOTDIRCT                 NOT IN THIS DIRECTORY SECTION   85700015
* DIRECTORY NAME IS LOW, COMPARE NEXT                                   85800015
         IC    W2,11(W1)            GET USERS FIELD LENGTH              85900015
         NR    W2,W0                MASK 3 H.O. BITS                    86000015
         LA    W2,12(W2,W2)         ENTIRE ENTRY LENGTH IN 2            86100015
         BXLE  W1,W2,COMPARE            MORE RECORDS IN BLOCK           86200015
         B     TSTEND              CHECK LIBRARY                        86300015
MOVE     EQU   *                                                        86400015
         MVC   LISTC(1),11(W1)          MOVE C + USER DATA FROM RDAREA  86500015
*                                TO BLDL LIST.  LENGTH COMPUTED IN W4.  86600015
NAMEFND  EQU   *                                                        86700015
         MVC   LISTTT(3),8(W1)          MOVE TTR                        86800015
         IC    W4,11(W1)            GET C FROM DIRECTORY                86900015
         NR    W4,W0                MASK 3 HIGH ORDER BITS              87000015
         LH    W5,LISTLL                GET USERS LL                    87100015
         SH    W5,C14               SUBTRACT CONSTANT 14                87200015
         BM    NOREFRSH       BR IF LL LESS THAN MINIMUM LENGTH OF 14   87300015
         BXLE  W4,W4,MOVEDATA           IS REG 5 MORE THAN 2(REG4)      87400015
         LR    W4,W5                USE SMALLER COUNT                   87500015
MOVEDATA EX    W4,MOVE                  MOVE INTO USERS LIST            87600015
         MVC   RPTR+1(3),PDARTAB+9          GET RELOCATION FACTOR       87700015
         SPACE                                                          87800015
         TM    LISTATR1,X'04'      SCATTER FORNAT                       87900015
         BO    TSTSCTR             BR YES, CHK IF SCATTER SPECIFIED     88000015
         TM    PDARTAB+8,X'80'          NO, WAS SCATTER SPECIFIED       88100015
         BO    SCTERR               YES, CAN'T DO IT                    88200015
         B     CNVTTR        NO,BLOCK LOADED - GO TO REFRESH ROUTINE    88300015
         SPACE                                                          88400015
TSTSCTR  EQU   *                                                        88500015
         TM    PDARTAB+8,X'80'     WAS SCATTER SPECIFIED                88600015
         BO    SCATRLD             BR YES, SCATTER LOADED FOR SURE      88700015
* MUST BE BLOCK EXTENT LIST                                             88800015
         MVC   RPTR+1(3),XLIST+13  GET ADR FOR RELOCATION FACTOR        88900015
         B     REFRMOD             GO READ MODULE                       89000015
         SPACE 2                                                        89100015
CHKLIBCN EQU   *                                                        89200015
         CLC   DEBAMIND(1),LISTCN       CHECK C.N.                      89300015
         BH    ANOTHRDS                 MORE DATA SETS IN CNCTNTN       89400015
         B     TSTEND                                                   89500015
ANOTHRDS EQU   *                                                        89600015
         IC    W4,LISTCN                                                89700015
         LA    W4,1(W4)                 INCREMENT C.N.                  89800015
         STC   W4,LISTCN                                                89900015
         B     INSERTCN                                                 90000015
         SPACE 2                                                        90100015
*              NOT IN THIS DIRECTORY SECTION                            90200015
NOTDIRCT EQU   *                                                        90300015
         CLI   0(W1),255            CHECK FOR CONTINUATION POINTER      90400015
         BL    CHKLIBCN       NOT HIGH NAME                             90500015
         CLC   1(7,W1),0(W1)        MAKE SURE                           90600015
         BL    CHKLIBCN       REALLY NOT HIGH NAME                      90700015
         SPACE                                                          90800015
*  STEP TO NEXT JOBLIB,ELSE SET TO SEARCH LINKLIB                       90900015
TSTEND   EQU   *                                                        91000015
         CLI   LISTZ,X'01'         IS IT LINKLIB                        91100015
         BE    NOREFRSH                                                 91200015
         L     DEBREG,DEBAMIND     LOAD POINTER TO NEXT DEB             91300015
         LA    DEBREG,0(DEBREG)    CLEAR EXTRA INFO                     91400015
         LTR   DEBREG,DEBREG       ANY MORE JOBLIBS                     91500015
         BZ    SETLNK              BR NO TO SEARCH LINKLIB              91600015
         B     SRCHPDS             FIND PDS OF NEXT JOBLIB              91700015
         SPACE 2                                                        91800021
***  MAINTENANCE  AREA  ***                                             91850021
MAINTID  DC    CL8'IGFASR10'           CORE IDENTIFIER                  91860021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              91870021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 91880021
         SPACE 2                                                        91890021
         CNOP  4,8                                                      91900015
         DC    C'ASR'                                                   92000015
DISP     EQU   TTRTABLE-START                                           92100015
TABLOC   DC    AL1(DISP/8)                                              92200015
         EJECT                                                          92300015
ASRMAC   DSECT                                                          92400015
         ASRMAC                                                         92500015
INADDR   EQU   PDARTAB+8                                                92600015
XLIST    EQU   PDARTAB+8      START OF SCATTER/BLOCK EXTENT LIST        92700015
         EJECT                                                          92800015
*              DEB DEFINITION                                           92900015
IHADEB   DSECT                                                          93000015
         DC    F'0'                                                     93100015
DEBAMIND DS    X                                                        93200015
         DS    11X                                                      93300015
DEBNMEXT DS    X                                                        93400015
         DS    15X                                                      93500015
DEBDVMOD DC    F'0'                                                     93600015
DEBBINUM DC    H'0'                                                     93700015
DEBSTRCC DC    H'0'                                                     93800015
DEBSTRHH DC    H'0'                                                     93900015
DEBENDCC DC    H'0'                                                     94000015
DEBENDHH DC    H'0'                                                     94100015
DEBNMTRK DC    H'0'                                                     94200015
         SPACE 2                                                        94300015
*              DCB  DUMMY-SECTION                                       94400015
         DCBD                                                           94500015
*                                                                       94600015
CVTMAC   CVT                                                            94700015
         END                                                            94800015
