         LCLA  &LEV,&REL                                                00150021
&LEV     SETA  20                                                       00160021
&REL     SETA  21                                                       00170021
&REL&LEV TITLE 'IGFASR1A LEVEL &LEV RMS-MCH CLEAR CHAN RERESH LOADER'   00180021
IGFASR1A CSECT                                                          00200015
         EJECT                                                          00202015
* MODULE NAME...IGFASR1A                                                00204015
*                                                                       00206015
*                                                                       00208015
* FUNCTION/OPERATION...                                                 00210015
*    TO CLEAR CHANNEL PATHS TO THOSE DASD'S WHICH THE REFRESH LOADER    00212015
*    WILL ACCESS FOR THE PURPOSE OF LOADING REFRESHABLE MODULES. THIS   00214015
*    MODULE OPERATES EXACTLY LIKE IGFASR0A IN SO FAR AS THE ACTUAL      00216015
*    TIO'S TO THE DEVICES ARE CONCERNED.                                00218015
*                                                                       00220015
*                                                                       00222015
* ENTRY POINT...                                                        00224015
*    IGFASR1A---ENTERED FROM MCHNUC,REQUESTED BY SYSTEM ANALYSIS        00226015
*                                                                       00228015
*                                                                       00230015
* EXITS...                                                              00232015
*    TO MCHNUC                                                          00234015
*                                                                       00236015
*                                                                       00238015
* INPUT...                                                              00240015
*    1. TWO BYTE UCB POINTERS IN PDARCUA                                00242015
*    2. RETURN ADDR TO MCHNUC IN COMNUC+4 FOR I/O ERROR RETURN          00244015
*    3. COMIOQ                                                          00246015
*                                                                       00248015
*                                                                       00250015
* OUTPUT...                                                             00252015
*    1. I/O INTERRUPT SAVE QUEUE                                        00254015
*    2. TTRL OF REFRESH LOADER IN COMNUC                                00256015
*                                                                       00258015
*                                                                       00260015
* EXTERNAL REFERENCES...NONE                                            00262015
*                                                                       00264015
*                                                                       00266015
* ERROR CONDITIONS...                                                   00268015
*    ANY I/O PROBLEMS CAUSE AN ERROR MESSAGE TO BE BUFFERED AND CONTROL 00270015
*    RETURNED TO MCH NUC  EMERGENCY EXIT ROUTINE.                       00272015
*                                                                       00274015
*                                                                       00276015
* TABLES/WORKAREAS                                                      00278015
*    1. COMM/RE AREA                                                    00280015
*    2. I/O SAVE QUEUE                                                  00282015
*                                                                       00284015
*                                                                       00286015
* RESTRICTIONS...                                                       00288015
*    1. ONLY DASD ATTACHED TO 2860 WILL BE CLEARED                      00290015
*    2. MAX OF 11 DEVICES                                               00292015
         EJECT                                                          00294015
         USING CVTDSECT,CVTREG                                          00300015
         USING COMMON,WKR12                                             00400015
         IEAQFX     65,MCH,1,GENCODE=NO                              MP 00430017
IGFASR1A  CSECT                                                    MP   00460017
         USING *,WKR15                                                  00500015
         SPACE 1                                                        00600015
         B     START1A                                                  00700015
         ORG   IGFASR1A+8                                               00800015
TTRTABLE DC    C'10'               REFRESH LOADER I.D.                  00900015
         DC    X'00000000'         REFRESH LOADER TTRL                  01000015
TABEND   DC    X'0000'                                                  01100015
         SPACE 2                                                        01200015
         SPACE 1                                                        01300015
*********************************************************************** 01400015
*********************************************************************** 01500015
*                                                                     * 01600015
*****      CLEAR  CHANNEL  PATH  FOR  REFRESH  LOADER            ****** 01700015
*                                                                     * 01800015
*********************************************************************** 01900015
*********************************************************************** 02000015
         SPACE 2                                                        02100015
*********************************************************************** 02200015
* GPR USAGES FOR THIS MODULE ARE ...                                  * 02300015
* GPR 1 --CONTAINS CUA OF CURRENT DEVICE UNDER TIO OPERATION          * 02400015
* GPR 2 --CONTAINS CURRENT POINTER TO I/O INTERRUPT SAVE QUEUE        * 02500015
* GPR 3 --CONTAINS CURRENT TIO LOOP COUNT                             * 02600015
* GPR 4 --LINK REG TO QUEUE SAVED I/O INTERRUPT SUBROUTINE            * 02700015
* GPR 6 --CALCULATING PDARCUA POINTER                                 * 02800015
* GPR 7 --LINK REG TO CSW ERROR CHECK SUBROUTINE                      * 02900015
* GPR 8 --CONTAINS ADDRESS OF CURRENT UCB                             * 03000015
* GPR 9 --CONTAINS ADDRESS OF CURRENT UCB POINTER                     * 03100015
* GPR 10--BASE REG FOR THE CVT DSECT                                  * 03200015
* GPR 12--BASE REG FOR THE ASRMAC DSECT                               * 03300015
* GPR 13--RETURN TO ASR NUCLEUS                                       * 03400015
* GPR 14--BASE REG FOR ASR NUCLEUS                                    * 03500015
* GPR 15--BASE REG FOR THIS ROUTINE                                   * 03600015
*********************************************************************** 03700015
         SPACE 2                                                        03800015
*                                                                     * 03900015
******         I N I T I A L I Z A T I O N                       ****** 04000015
*                                                                     * 04100015
         SPACE 1                                                        04200015
START1A  EQU   *                                                        04300015
LEVEL    EQU   X'&LEV'                                                  04340021
         MVI   COMLEV1A,LEVEL     MODULE LEVEL                          04360021
         LA    WKR6,PDARCUA        OBTAIN STARTING ADR OF PDARCUA       04400015
         ST    WKR6,UCBNADR        SAVE PDARCUA STARTING ADR            04500015
         SPACE 1                                                        04600015
IGFA1003 EQU   *                                                        04700015
         LH    WKR1,0(WKR6)        OBTAIN CUA POINTER FROM PDARCUA      04800015
         SLL   WKR1,16             CLEAR THE                            04900015
         SRL   WKR1,16               HI-ORDER BITS.                     05000015
         MVC   NDEVICE(2),UCBCUA(WKR1)       GET SYSTEM CUA             05100015
         NI    NDEVICE,X'07'                 CLEAR HI-ORDER BITS        05200015
         MVC   NDEVICE+2(1),UNITTYPE(WKR1)   SAVE UNIT TYPE.            05300015
         L     WKR1,UCBNADR                  FILL IN CUA                05400015
         MVC   0(2,WKR1),NDEVICE               INTO PDARCUA.            05500015
         SPACE 1                                                        05600015
         L     WKR1,COMIOQ         GET ADDR OF ASR I/O Q                05700015
IGFA1001 TM    0(WKR1),X'FF'        POINTER FROM COMM  AREA             05800015
         BC    1,IGFA1002            TO COMPUTE THE STARTING ADR IN     05900015
         LA    WKR1,10(WKR1)          THE QUEUE FOR THIS MODULE.        06000015
         BC    15,IGFA1001         REPEAT THE SEARCH                    06100015
IGFA1002 ST    WKR1,NIOQADDR       SAVE THE NEW POINTER IN NIOQADDR     06200015
         LR    WKR2,WKR1           REG 2 CONTAINS I/O INTERRP SAVE Q    06300015
         SPACE 1                                                        06400015
         L     WKR10,COMCVT        OBTAIN CVT ADR FROM COMM. AREA       06500015
         L     WKR9,CVTILK2        ADDR OF 1ST TWO BYTE UCB POINTER     06600015
         MVI   NSW2,X'00'          CLEAR PGM SWITCH                     06700015
         XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE AREA           06800015
         MVC   NCUTEST,NDEVICE+1   GET UA PORTION                       06900015
         CLI   NDEVICE+2,N2301     IS IT ON A 2301 DRUM                 07000015
         BC    EQ,NCUBITS          YES,CU ADR IS HI-ORDER 5 BITS        07100015
*                                   NO,CU ADR IS HI-ORDER 4 BITS        07200015
         NI    NCUTEST,X'F0'       SET CU ADDR                          07300015
         MVI   NCUMASK,X'F0'        AND CU MASK                         07400015
         SPACE 2                                                        07500015
*********************************************************************** 07600015
***          START  TO  CLEAR  2860  CHANNEL                        *** 07700015
*********************************************************************** 07800015
         SPACE 1                                                        07900015
*                                                                       08000015
* ISSUE TIO TO DEVICE--DETERMINE INITIAL STATUS                         08100015
*                                                                       08200015
         SPACE 1                                                        08300015
STARTCLR EQU   *                                                        08400015
         TM    COMMSF,X'10'        CHK MULTIPROCESSING FEATURE       MP 08410017
         BZ    BYPASS              GO IF NOT AVAILABLE               MP 08420017
         SR    WKR3,WKR3                                             MP 08430017
         IC    WKR3,NDEVICE        GET CHANNEL-ADR-PORTION OF CUA    MP 08440017
         SLL   WKR3,1              DOUBLE (AS EACH CHL HAS 2-B.FIELD)MP 08450017
         TM    CHRECNUC-IPLPSW(WKR3),X'78' CHK IND. OF NOT-AVAIL.    MP 08460017
         BNZ   NEROUT1             ANY BIT INDICATES NOT-AVAILABLE  MLS 08470018
BYPASS   EQU   *                                                     MP 08480017
         LH    WKR1,NDEVICE        SET CUA IN WORK REG.                 08500015
         TIO   0(WKR1)             TIO TO DEVICE                        08600015
         BC    NOTOPER,NEROUT1     --NOT OPERATIONAL                MCS 08700018
         BC    BUSY,NSCNUCB0       --BUSY--GO TO SCAN UCB SUBR          08800015
         BC    AVAIL,NCLROK01      --AVAILABLE--PATH IS CLEAR           08900015
*                                  --CSW STORED--BEGIN CSW ANALYSIS     09000015
NCLR015  BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHK SUBROUTINE       09100015
         SPACE 1                                                        09200015
*        RETURN TO HERE--CSW HAS NO CATASTROPHIC ERRORS                 09300015
         TM    NCSWUS1,X'2C'       TEST CE,CUE,DE--ON/OFF/MOXED         09400015
         BC    ALLON,NCLR017         ALL ARE ON                         09500015
         BC    ALLOFF,NCLR002        ALL ARE OFF--NOW CHK FOR B,SM      09600015
*                                                                       09700015
         TM    NCSWUS1,X'0C'       TEST CE,DE--ON/OFF/MIXED             09800015
         BC    ALLON,NCLR017         BOTH ARE ON (CE,DE NOT CUE)        09900015
         BC    ALLOFF,NCLR003        BOTH ARE OFF (CUE ON ALONE)        10000015
*                                                                       10100015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      10200015
         BC    ALLON,NCLR017         ON (DE, NOT CE,CUE DON'T CARE)     10300015
*        DE IS OFF, CE IS ON, CUE DON'T KNOW YES                        10400015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     10500015
         BC    ALLON,NCLR004         ON (CE,CUE,NOT DE)                 10600015
         SPACE 1                                                        10700015
*        CE IS ON ALONE--MUST NOW GIVE TIO TO DEVICE FOR DE             10800015
         OI    NUSSAVE,X'08'       SET CE IN CSW UNIT STATUS SAVE BYTE  10900015
         SPACE 2                                                        11000015
* NOW ISSUE TIO TO DEVICE FOR POSSIBLE PENDING DE                       11100015
         SPACE 1                                                        11200015
NTIOSYS1 L     WKR3,NCNTR1         INITIALIZE LOOP COUNT                11300015
NTIOSYS2 TIO   0(WKR1)             TIO TO DEVICE                        11400015
         BC    NOTOPER,NEROUT1     --NOT OPERATIONAL                MCS 11500018
         BC    BUSY,NEROUT2     *** BUSY--SHOULD NEVER OCCUR        MCS 11600018
         BC    AVAIL,NCLR031       --AVAILABLE                          11700015
         SPACE 1                                                        11800015
*        CSW STORED--BEGIN CSW ANALYSIS                                 11900015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHK SUBROUTINE       12000015
         SPACE 1                                                        12100015
*        RETURN TO HERE--CSW HAS NO CATASTROPHIC ERRORS                 12200015
         SPACE 1                                                        12300015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      12400015
         BC    ALLOFF,NCLR006        OFF--GO CHK LOOP COUNT             12500015
NCLR032  EQU   *                                                        12550015
         OC    NCSWUS1(2),NUSSAVE  OR STATUS SAVE BYTES INTO CSW        12600015
NCLR001  BC    15,NCLR017          GO Q THE INTRPT                      12700015
         SPACE 1                                                        12900015
NCLR006  BCT   WKR3,NTIOSYS2       REPEAT IF COUNT NOT ZERO             13000015
         BC    15,NEROUT2          COUNT ZERO                       MCS 13050018
         SPACE 2                                                        13110015
NCLR031  EQU   *                                                        13120015
         CLC   NSTATSV(2),ALL0S    ANY STATUS TO Q                      13130015
         BC    EQ,NCLROK03         BR IF NO                             13140015
         BC    15,NCLR032          Q THE STATUS                         13150015
         SPACE 2                                                        13200015
NCUBITS  NI    NCUTEST,X'F8'       SET CU ADR                           13300015
         MVI   NCUMASK,X'F8'        AND CU MASK                         13400015
         BC    15,STARTCLR         START CLEAR FUNCTION                 13500015
         EJECT                                                          13600015
* CUE ON ALONE--MUST TIO TO DEVICE FOR POSSIBLE AVAILABLE OR DE         13700015
         SPACE 2                                                        13800015
NCLR003  OI    NUSSAVE,X'20'       SET CUE IN CSW UNIT STATUS SAVE BYTE 13900015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE               14000015
         SPACE 2                                                        14100015
*        CUE AND CE ON--MUST NOW GIVE TIO TO DEVICE FOR DE              14200015
NCLR004  OI    NUSSAVE,X'28'       SET CE+CUE IN CSW STATUS SAVE BYTE   14300015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE               14400015
         SPACE 2                                                        14500015
         SPACE 2                                                        15000015
* INITIAL TIO TO DEVICE FOUND CE,CUE,DE ALL OFF.                        15100015
* MUST NOW CHECK THE BUSY(B) AND STATUS MODIFIER(SM) BITS.              15200015
         SPACE 1                                                        15300015
NCLR002  TM    NCSWUS1,X'50'       TEST B,SM--ON/OFF/MIXED              15400015
         BC    ALLOFF,NEROUT2   *** BOTH OFF--SHOULD NEVER OCCUR    MCS 15500018
         BC    ALLON,NCUSCAN         BOTH ON--GO TO CNTRL UNIT SCAN     15600015
         TM    NCSWUS1,X'10'       TEST B--ON/OFF                       15700015
         BC    OFF,NEROUT2      *** ERROR                           MCS 15800018
         SPACE 1                                                        15900015
*        BUSY IS ON ALONE--THIS IMPLIES THAT THERE WILL BE A DE FROM    16000015
*        DEVICE. MUST GIVE TIO TO DEVICE FOR DE.                        16100015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE FOR DE        16200015
         EJECT                                                          16300015
*********************************************************************** 16400015
* THE INITIAL TIO TO DEVICE GAVE B+SM BITS. IF THE DEVICE DOES NOT    * 16500015
* SHARE A CONTROL UNIT, THEN THIS CU/DEVICE IS BUSY AND THE PGM MUST  * 16600015
* ISSUE TIO'S TILL DE COMES IN. IF CU IS SHARED, THIS MEANS...        * 16700015
* 1. CHANNEL IS AVAILABLE                                             * 16800015
* 2. CONTROL UNIT IS BUSY WITH EITHER...                              * 16900015
*        A. DEVICE                                                    * 17000015
*        B. SOME OTHER DEVICE ATTAHCHED TO THIS CONTROL UNIT          * 17100015
*                                                                     * 17200015
* THE PROGRAM MUST NOW FIND WHICH DEVICE IS KEEPING THE CU BUSY, BY   * 17300015
* ISSUING TIO'S TO ALL DEVICES ON THIS CU. THE CU SCAN IS MAINTAINED  * 17400015
* UNTIL ONE OF THE FOLLOWING OCCURS...                                * 17500015
* 1. CUE AND/OR DE IS RECEIVED                                        * 17600015
* 2. DEVICE IS FOUND NOT OPERATIONAL (CC=3)                           * 17700015
* 3. SCAN COUNT IS EXHAUSTED                                          * 17800015
*********************************************************************** 17900015
         SPACE 3                                                        18000015
NCUSCAN  CLI   NCUTEST,X'FF'       DOES DEVICE SHARE A CU               18100015
         BC    EQ,NTIOSYS1         --NO                                 18200015
         L     WKR3,NCNTR1         INITIALIZE SCAN LOOP COUNT           18300015
         OI    NSW2,X'20'          SET SAME CU AS DEVICE BIT            18400015
NCUSCAN1 BC    15,NSCNUCB1         GO TO SCAN UCB SUBR                  18500015
         SPACE 2                                                        18600015
*        RETURN TO HERE--CUA IS IN WKR1                                 18700015
NCUSCAN2 TIO   0(WKR1)             ISSUE TIO                            18800015
         BC    NOTOPER,NCLR007       NOT OPERATIONAL                    18900015
         BC    BUSY,NEROUT2     *** ERROR                           MCS 19000018
         BC    AVAIL,NCLR008         AVAILABLE                          19100015
         SPACE 1                                                        19200015
*        CSW STORED--BEGIN CSW ANALYSIS                                 19300015
         BAL   WKR7,NCSWERCK       GOT O CSW ERROR CHK SUBROUTINE       19400015
         SPACE 1                                                        19500015
*        RETURN TO HERE-CSW HAS NO CATASTROPHIC ERRORS                  19600015
         TM    NCSWUS1,X'50'       TEST B,SM--ON/OFF                    19700015
         BC    ALLON,NCUSCAN1        BOTH ON--CU STILL BUSY OR DEVICE   19800015
*                                    KEEPING CU BUSY HASN'T YET         19900015
*                                    BEEN FOUND.                        20000015
         TM    NCSWUS1,X'24'       TEST CUE,DE--ON/OFF/MIXED            20100015
         BC    ALLOFF,NCLR030        BOTH OFF                           20200015
         BC    ALLON,NCLR009         BOTH ON--CU AND DEVICE ARE FREE    20300015
*                                                                       20400015
         TM    NCSWUS1,X'04'       TEST DE--ON/OFF                      20500015
         BC    OFF,NCLR010           OFF--CUE ON ALONE                  20600015
         SPACE 1                                                        20700015
*        DE IS ON--DEVICE IS NOW FREE                                   20800015
NCLR009  BAL   WKR4,NIOQ           GO TO QUEUE I/O INTRPT SUBR.         20900015
         CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEAR           21000015
         BC    EQ,NCLR050          BR IF YES                            21100015
NCLR021  LA    WKR2,10(WKR2)         NO-STEP I/O QUEUE POINTER          21200015
NCLR011  XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE AREA           21300015
         LH    WKR1,NDEVICE        GET DEVICE CUA                       21500015
         BC    15,NTIOSYS1         GO ISSUE TIO TO DEVICE (POSSIBLE DE) 21600015
         SPACE 2                                                        21700015
NCLR010  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         21800015
         BC    NOTEQ,NCLR009       BR IF NO                             21860015
         OI    NUSSAVE,X'20'       SET CUE IN CSW UNIT STATUS SAVE BYTE 21920015
         BC    15,NTIOSYS1         TIO TO DEVICE FOR POSSIBLE DE        22000015
         SPACE 2                                                        22200015
NCLR007  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         22300015
         BC    EQ,NEROUT1          YES--DEVICE NOT OPERATIONAL      MCS 22400018
         BC    15,NCUSCAN1         NO--GO TO CU SCAN                    22500015
         SPACE 2                                                        22600015
NCLR008  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         22800015
         BC    NOTEQ,NCUSCAN1        NO--GO TO CU SCAN                  23000015
         BC    15,NCLROK05         YES--PATH IS CLEAR                   23100015
         SPACE 2                                                        23110015
NCLR030  EQU   *                                                        23120015
         TM    NCSWUS1,X'03'       TEST UC/UE                           23130015
         BC    5,NCLR009           BR IF MIXED OR ONES                  23140015
         TM    NCSWCS1,X'F1'       TEST PCI,IL,PGM-PROT-CHAIN CHECK     23150015
         BC    5,NCLR009           BR IF MIXED OR ONES                  23160015
         BC    15,NEROUT2       *** ERROR                               23180018
         EJECT                                                          23200015
***************  U C B   S C A N   R O U T I N E  ********************* 23300015
*                                                                     * 23400015
* THIS ROUTINE IS ENTERED WHENEVER...                                 * 23500015
* A.  A CC=2 (BUSY) WAS RECEIVED FROM THE INITIAL TIO TO DEVICE.      * 23600015
* B.  ALL DEVICES ATTACHED TO SAME CU AS DEVICE ARE TO BE SCANNED.    * 23700015
*                                                                     * 23800015
* FOR CASE A, ONE OF THE FOLLOWING IS POSSIBLE...                     * 23900015
*     1. THE CHANNEL IS BUSY (BURST MODE OPERATION) WITH EITHER       * 24000015
*        DEVICE TO BE CLEARED OR SOME OTHER DEVICE.                   * 24100015
*     2. THERE IS A PENDING CHANNEL INTERRUPT FROM A DEVICE OTHER     * 24200015
*        THAN THE ONE TO BE CLEARED.                                  * 24300015
* IN EITHER CASE, THE ACTION TO TAKE IS TO CONTINUALLY GIVE TIO'S TO  * 24400015
* ALL DEVICES UNTIL A CSW IS STORED (CC=1). THE CUA'S OF ALL THESE    * 24500015
* DEVICES ARE FOUND BY SCANNING THE UCB TABLES. A SCAN LOOP COUNT IS  * 24600015
* MAINTAINED. IF IT IS EXHAUSTED BEFORE A CC=1 IS RECEIVED, THE PGM   * 24700015
* COULD NOT FIND THE DEVICE KEEPING THE CHANNEL BUSY.                 * 24800015
*                                                                     * 24900015
*********************************************************************** 25000015
         SPACE 3                                                        25100015
NSCNUCB0 L     WKR3,NCNTR1         INITIALIZE SCAN LOOP COUNT           25200015
NSCNUCB1 LH    WKR8,0(WKR9)        LOAD ADDR OF UCB                     25300015
         LA    WKR9,2(WKR9)        STEP TO NEXT UCB POINTER ADDR        25400015
         LTR   WKR8,WKR8           TEST FOR END OF UCB ADDR TABLE       25500015
         BC    4,NCLR012              BR--END OF TABLE                  25600015
         BC    8,NSCNUCB1             BR--ZERO ENTRY--GET NEXT UCB      25700015
         MVC   NUCBCUA(2),UCBCUA(WKR8)  GET CUA FROM UCB                25800015
         NI    NUCBCUA,X'07'       CLEAR HI-ORDER BITS IN CHNNL BYTE    25900015
         LH    WKR1,NUCBCUA        PUT CUA INTO REG                     26000015
         CLC   NUCBCUA(1),NDEVICE  IS THIS SAME CHANNEL AS DEVICE       26100015
         BC    NOTEQ,NSCNUCB1             NO--GET NEXT UCB              26200015
         TM    NSW2,X'20'          SAME CUA AS DEVICE SWITCH-ON/OFF     26300015
         BC    OFF,NCLR013           OFF--ISSUE TIO TO THIS DEVICE      26400015
         NC    NUCBCUA+1(1),NCUMASK  ON--ZERO DEVICE ADDR--CU INTACT    26500015
         CLC   NUCBCUA+1(1),NCUTEST     IS THIS SAME CU AS DEVICE       26600015
         BC    NOTEQ,NSCNUCB1             NO--GET NEXT UCB              26700015
         BC    15,NCUSCAN2              YES--GO BACK TO CU SCAN TIO     26800015
         SPACE 2                                                        26900015
* DEVICE IS ON SAME CHNNL AS DEVICE TO BE CLEARED -GIVE IT A TIO        27000015
         SPACE 1                                                        27100015
NCLR013  TIO   0(WKR1)             ISSUE TIO                            27200015
         BC    NOTOPER,NCLR014       NOT OPERATIONAL                    27300015
         BC    BUSY,NSCNUCB1         BUSY--GET NEXT UCB                 27400015
         BC    AVAIL,NEROUT2    *** ERROR                               27500018
* CSW STORED--CHNNL INTRPT HAS BEEN FOUND--BEGIN CSW ANALYSIS           27600015
         CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         27700015
         BC    EQ,NCLR015            YES--GO BACK TO DEVICE CSW ANALYS. 27800015
* CHNNL INTERRUPT CAUSED BY DEVICE OTHER THAN ONE TO BE CLEARED         27900015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHECK SUBROUTINE     28000015
         SPACE 1                                                        28100015
* RETURN HERE IF--NO CATASTROPHIC ERRORS IN CSW                         28200015
         TM    NCSWUS1,X'0C'       TEST CE,DE--ON/OFF/MIXED             28300015
         BC    ALLOFF,NEROUT2   *** ERROR                           MCS 28400018
         BC    ALLON,NCLR017         BOTH ON--GO SAVE INTRPT            28500015
         SPACE 1                                                        28600015
         TM    NCSWUS1,X'08'       TEST CE--ON/OFF                      28700015
         BC    OFF,NEROUT2      *** ERROR                           MCS 28800018
         SPACE 1                                                        28900015
* CE ON, DE OFF--DETERMINE IF DEVICE IS ON SAME CU AS DEVICE TO BE CLRD 29000015
         NC    NUCBCUA+1(1),NCUMASK     ZERO DEVICE ADDR-CU INTACT      29100015
         CLC   NUCBCUA+1(1),NCUTEST     ON SAME CU                      29200015
         BC    NOTEQ,NCLR017            --NO                            29300015
         SPACE 1                                                        29400015
* CE WAS RECEIVED FROM DEVICE ON SAME CU--NOW CHECK FOR CUE             29500015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     29600015
         BC    ON,NCLR017            ON--CE+CUE ON                      29700015
         SPACE 1                                                        29800015
* CE IS ON ALONE. CU IS STILL BUSY. MUST GIVE TIO'S TO THIS DEVICE      29900015
* UNTIL CUE AND/OR DE IS RECEIVED. THEN CHECK FOR A POSSIBLE PENDING    30000015
* DE FROM DEVICE TO BE CLEARED.                                         30100015
         SPACE 1                                                        30200015
         OI    NUSSAVE,X'08'       SET CE IN UNIT STATUS SAVE BYTE      30300015
         MVC   NCSWWK2(8),NCSWWK1  MOVE SAVED CSW TO WORK AREA 2        30400015
NCLR019  TIO   0(WKR1)             TIO TO THIS DEVICE                   30500015
         BC    NOTOPER,NCLR018       NOT OPERATIONAL                    30600015
         BC    10,NEROUT2       *** ERROR                           MCS 30700018
         SPACE 1                                                        30800015
* CSW STORED-BEGIN ANALYSIS                                             30900015
         BAL   WKR7,NCSWERCK       GO TO CSW ERROR CHECK SUBR.          31000015
* RETURN HERE--CSW HAS NO CATASTROPHIC ERRORS                           31100015
         TM    NCSWUS1,X'50'       TEST B,SM-NOTH ON                    31200015
         BC    ALLON,NCLR019         BOTH ON--CU IS STILL BUSY          31300015
         TM    NCSWUS1,X'24'       TEST CUE,DE--ON/OFF/MIXED            31400015
         BC    ALLOFF,NEROUT2   *** ERROR                           MCS 31500018
         BC    ALLON,NCLR018         BOTH ON-CE,CUE,DE WERE ALL RECEIVD 31600015
         SPACE 1                                                        31700015
         TM    NCSWUS1,X'20'       TEST CUE--ON/OFF                     31800015
         BC    ON,NCLR020            ON                                 31900015
* DE WAS RECEIVED (CE WAS PREVIOUSLY RECEIVED)                          32000015
NCLR018  OC    NCSWUS1(2),NUSSAVE  OR STATUS BYTES INTO CSW             32100015
NCLR016  BC    15,NCLR017          Q THE INTRPT                         32200015
         SPACE 2                                                        32400015
* CUE ON,DE OFF (CE WAS PREVIOUSLY RECEIVED)                            32500015
NCLR020  OI    NCSWWK2+4,X'20'     OR CUE INTO SAVED CSW IN WORK AREA 2 32600015
         OC    NCSWWK2+4(2),NSTATSV  PLUS ANY OTHER SAVED STATUS        32700015
         MVC   NCSWWK1(8),NCSWWK2    PUT INTO WORK AREA 1               32800015
         BC    15,NCLR017          Q THE INTRPT                         32900015
         SPACE 3                                                        33000015
* TIO TO DEVICE IN UCB SCAN RTN GAVE CC=3 (NOT OPERATIONAL)             33100015
NCLR014  CH    WKR1,NDEVICE        IS THIS DEVICE TO BE CLEARED         33200015
         BC    EQ,NEROUT1          YES-- WE'VE HAD IT               MCS 33300018
         BC    15,NSCNUCB1           NO--GET NEXT UCB                   33400015
         SPACE 3                                                        33500015
NCLR017  BAL   WKR4,NIOQ           QUEUE I/O INTERPT                    33600015
NCLR050  LA    WKR2,10(WKR2)       STEP IOQ POINTER                     33700015
NCLR022  OI    NSW2,X'20'          SET SAME CU AS NDEVICE SWITCH        33800015
         LH    WKR1,NDEVICE        GET DEVICE CUA                       33900015
         L     WKR3,NCNTR1         SET TIO LOOP COUNT                   34000015
         XC    NSTATSV(2),NSTATSV  CLEAR CSW STATUS SAVE BYTES          34050015
         BC    15,NCUSCAN2         GO TO CU SCAN                        34100015
         SPACE 3                                                        34200015
* END OF UCB TABLES--GO CHECK LOOP COUNT                                34300015
NCLR012  BCT   WKR3,*+8            IS LOOP COUNT EXHAUSTED              34400015
         BC    15,NEROUT2       YES                                 MCS 34500018
         L     WKR9,CVTILK2        BO--RESET UCB POINTER TO 1ST UCB     34600015
         BC    15,NSCNUCB1         GO BACK TO SCAN                      34700015
         EJECT                                                          34800015
*********************************************************************** 34900015
*                                                                     * 35000015
*******  C S W   E R R O R   C H E C K   S U B R O U T I N E  ********* 35100015
*                                                                     * 35200015
*********************************************************************** 35300015
* CSW ERROR CHECK SUBROUTINE (NEW)                                      35400015
NCSWERCK MVC   NCSWWK1(8),64       SAVE CSW                             35500015
         TM    NCSWCS1,X'0E'       TEST CCC,ICC,CDC--MIXED,ON/OFF       35600015
         BC    5,NEROUT2        *** ERROR                           MCS 35700018
         TM    NCSWUS1,X'02'       TEST UC--ON/OFF                      35800015
         BC    ON,NCSWER2          --ON                                 35900015
NCSWEREX NI    68,X'01'            CLEAR UNIT STATUS EXCEPT UE IF ON    36200015
         OC    NSTATSV(2),68       SAVE CSW STATUS                      36300015
         BCR   15,WKR7             RETURN TO CALLER                     36400015
NCSWER2  CH    WKR1,NDEVICE        DID UC OCCUR ON DEVICE TO BE CLEARED 36500015
         BC    NOTEQ,NCSWEREX      --NO--EXIT ROUTINE                   36800015
         SPACE 1                                                        36900015
*        SENSE ROUTINE                                                  37000015
         SPACE 1                                                        37100015
NSNS1    OC    NCSWUS1(2),NSTATSV  'OR' STATUS SAVE BYTES AND           37200015
         BAL   WKR4,NIOQ           QUEUE THE INTRPT                     37300015
         LA    WKR5,NSNSRD         GET SENSE READ IN AREA ADDRESS       37400015
         ST    WKR5,NSNSCCW         PUT ADDR INTO CSW                   37500015
         MVI   NSNSCCW,SENSE       SET SENSE OP IN CCW                  37600015
NSNS3    LA    WKR6,NSNSCCW        SET                                  37700015
         ST    WKR6,72                CAW                               37800015
         SIO   0(WKR1)             ISSUE SENSE                          37900015
         BC    NOTOPER,NEROUT2  *** NOT OPERATIONAL                 MCS 38000018
         BC    AVAIL,NSNS2         --AVAILABLE--SIO IS OK               38100015
*        CSW STORED--ONLY POSSIBLE CORRECT STATUS AT THIS TIME IS DE.   38200015
*        IF DE NOT ON, ASR MUST TERMINATE                               38300015
         TM    68,X'04'            DE--ON/OFF                           38400015
         BC    OFF,NEROUT2      *** OFF--SENSE FAILED               MCS 38500018
         OI    6(WKR2),X'04'       SET DE IN PREVIOUSLY SAVED CSW       38600015
         BC    15,NSNS3            DO SENSE AGAIN                       38700015
         SPACE 1                                                        38800015
* SENSE STARTED--NOW GIVE TIO TILL SENSE IS FINISHED                    38900015
         SPACE 1                                                        39000015
NSNS2    TIO   0(WKR1)             TIO                                  39100015
         BC    NOTOPER,NEROUT2  *** NOT OPERATIONAL                 MCS 39200018
         BC    BUSY,NSNS2          --BUSY                               39300015
         BC    AVAIL,NSNS7         --AVAILABLE                          39400015
*              CSW  STORED                                              39500015
         TM    68,X'04'            TEST DE                              39600015
         BC    ON,NSNS7            ON--SENSE ENDED O.K.                 39700015
         TM    68,X'02'            TEST UNIT CHECK                      39800015
         BC    OFF,NSNS2           OFF--LOOP                            39900015
NSNS7    EQU   *                                                        40000015
         LA    WKR2,10(WKR2)       STEP IOQ POINTER                     40100015
         SPACE 1                                                        41500015
         BC    15,NCLREXA          EXIT                                 42500015
         SPACE 2                                                        42600015
         EJECT                                                          43600015
*************  QUEUE SAVED I/O INTERRUPT SUBROUTINE  ****************** 43700015
*                                                                       43800015
NIOQ     MVC   2(8,WKR2),NCSWWK1   QUEUE THIS CSW                       43900015
         STH   WKR1,0(WKR2)          AND CORRESPONDING CUA              44000015
         BCR   15,WKR4             GO BACK TO CALLER                    44100015
         SPACE 5                                                        44200015
         EJECT                                                          46600015
***************  P A T H   C L E A R   E X I T S  ********************* 46700015
         SPACE 3                                                        46800015
NCLREXA  EQU   *                                                        46900015
NCLROK01 EQU   NCLREXA                                                  47000015
NCLROK03 EQU   NCLREXA                                                  47100015
NCLROK05 EQU   NCLREXA                                                  47200015
         SPACE 1                                                        47300015
         MVI   0(WKR2),X'FF'       SET END-OF-QUEUE INDICATOR           47400015
         SPACE 1                                                        48300015
COMPLETE EQU   *                                                        48400015
         L     WKR6,UCBNADR        OBTAIN UCB ADR OF PDARTAB            48500015
         LA    WKR6,2(WKR6)        INCREMENT BY 2 TO GET THE NEXT ADR.  48600015
         CLC   0(2,WKR6),ALL0S     IS THE COMCPLETED                    48700015
         BC    8,EXIT              YES,BRANCH TO EXIT.                  48800015
         ST    WKR6,UCBNADR        NO,SAVE THE ADR FOR NEXT ROUND       48900015
         BC    15,IGFA1003         REPEAT THE ROUTINES AGAIN.           49000015
EXIT     EQU   *                                                        49100015
         LH    WKR1,TTRTABLE            REFRESH LOADER I.D.             49200015
         MVC   COMNUC(4),TTRTABLE+2     REFRESH LOADER TTRL             49300015
         BCR   15,WKR13                                                 49400015
         EJECT                                                          49500015
NEROUT1  EQU   *                                                    MCS 50500018
         L     WKR6,UCBNADR        LOAD ADDR OF PDARCUA             MCS 51500018
         OI    X0(WKR6),X80        INDICATES ERROR OCCURRED        MCS  52500018
         B     COMPLETE            RETURN TO CHECK NEXT CUA         MCS 53500018
         SPACE 2                                                        54500018
NEROUT2  EQU   *                                                    MCS 55500018
         TM    COMNUC+4,X80        HAS ERROR RECORD BEEN WRITTEN    MCS 56500018
         BC    ON,MSGWRIT          YES, LEAVE MSG ALONE             MCS 57500018
         MVI   NIOMSG+X6,SCON      SET SEREP CODE                   MCS 58500018
MSGWRIT  EQU   *                                                    MCS 59500018
         MVC   COMMSG0+X1(D16),NIOMSG    MOVE MSG TO BUFFER         MCS 60500018
         LA    WKR0,XA12           WAIT STATE CODE                 MCS  61500018
         L     WKR3,COMNUC+X4      ERROR RETURN ADDR OF NUC        MCS  62500018
         BCR   15,WKR3             RETURN TO ASRNUC                 MCS 63500018
         EJECT                                                          72300015
**************************  E Q U A T E S  **************************** 72400015
WKR0     EQU   0                                                        72500015
WKR1     EQU   1                                                        72600015
WKR2     EQU   2                                                        72700015
WKR3     EQU   3                                                        72800015
WKR4     EQU   4                                                        72900015
WKR5     EQU   5                                                        73000015
WKR6     EQU   6                                                        73100015
WKR7     EQU   7                                                        73200015
WKR8     EQU   8                                                        73300015
WKR9     EQU   9                                                        73400015
WKR10    EQU   10                                                       73500015
WKR11    EQU   11                                                       73600015
WKR12    EQU   12                                                       73700015
WKR13    EQU   13                                                       73800015
WKR14    EQU   14                                                       73900015
WKR15    EQU   15                                                       74000015
CVTREG   EQU   10                  POINTER TO COMM VECTOR TABLE         74300015
         SPACE 3                                                        74400015
NOTOPER  EQU   1                   NOT OPERATIONAL                      74500015
BUSY     EQU   2                   BUSY                                 74600015
CSWSTORE EQU   4                   CSW STORED                           74700015
AVAIL    EQU   8                   AVAILABLE                            74800015
ALLON    EQU   1                   ALL BITS ON                          74900015
ALLOFF   EQU   8                   ALL BITS OFF                         75000015
MIXED    EQU   4                   BITS ARE MIXED ONES/ZEROES           75100015
ON       EQU   1                   ON                                   75200015
OFF      EQU   8                   OFF                                  75300015
EQ       EQU   8                   EQUAL                                75400015
NOTEQ    EQU   7                   NOT EQUAL                            75500015
UCBCUA   EQU   4                   UCB DISPLACEMENT FOR CHANNEL/UNIT    75600015
SENSE    EQU   4                   SENSE COMMAND CODE                   75700015
UNITTYPE EQU   19                                                       75800015
N2301    EQU   2                                                        75900015
UCBTYP   EQU   UNITTYPE                                                 76000015
         SPACE 5                                                        76100015
********************  D O U B L E   W O R D S  ************************ 76200015
         SPACE 3                                                        76300015
         DS    0D                                                       76400015
NCSWWK1  DC    1D'0'               CSW WORK AREA 1                      76500015
NCSWUS1  EQU   NCSWWK1+4             UNIT STATUS BYTE OF CSW            76600015
NCSWCS1  EQU   NCSWWK1+5             CHANNEL STATUS BYTE OF CSW         76700015
NCSWWK2  DC    1D'0'               CSW WORK AREA 2                      76800015
NSNSCCW  DC    XL8'0400000020000006'    SENSE CCW                       76900015
NIOMSG   DC    C'IGF006W I/O ERR '                                  MCS 77200018
         SPACE 5                                                        77500015
****************************  W O R D S  ****************************** 77600015
         SPACE 3                                                        77700015
         DS    0F                                                       77800015
NCNTR1   DC    XL4'3FFFF'          TIO LOOP COUNT CONSTANT           MP 77900017
NDEVICE  DC    F'0'                DEVICE TO BE CLEARED                 78000015
NIOQADDR DC    1F'0'               SAVE AREA FOR IOQ ADDRESS            78100015
         SPACE 5                                                        79000015
**********************  H A L F   W O R D S  ************************** 79100015
         SPACE 3                                                        79200015
         DS    0H                                                       79300015
NUCBCUA  DC    XL2'0'              SV AREA FOR CURRENT CUA FROM UCB     79400015
NSTATSV  DC    XL2'0'              CSW STAUTS SAVE BYTES                79500015
NUSSAVE  EQU   NSTATSV                                                  79600015
NCSSAVE  EQU   NSTATSV+1                                                79700015
         SPACE 5                                                        79800015
****************************  B Y T E S  ****************************** 79900015
         SPACE 3                                                        80000015
NSNSRD   DC    XL6'0'              SENSE READ IN AREA                   80100015
NCUMASK  DC    XL1'0'              CU ADDR MASK                         80200015
NSW2     DC    XL1'0'    BIT       FUNCTION                             80300015
*                        0         CC=0OK IN TIO TO SYSRES FOR DE       80400015
*                        1         QUEUE SYSRES DE REQUIRED             80500015
*                        2         SAME CU AS SYSRES FOR UCB SCAN RTN   80600015
*                        3         CLEAR SYSRES CLEARED CONSOLE ALSO    80700015
*                        4                                              80800015
*                        5                                              80900015
*                        6         2ND UNIT CHECK MSG BUFFERED          81000015
*                        7         1ST UNIT CHECK MSG BUFFERED          81100015
NCUTEST  DC    XL1'0'              SYSRES CU SAVE TEST AREA             81200015
X0       EQU   0                                                        81300018
X1       EQU   1                                                   MCS  81400018
X80      EQU   X'80'                                                    81500018
XA12     EQU   X'A12'                                                   81600018
X4       EQU   X'04'                                                    81700018
D16      EQU   16                                                   MCS 81800018
X6       EQU   6                                                    MCS 81900018
SCON     EQU   X'E2'                                                MCS 82000018
         CNOP  0,4                                                      82100015
SAVE89   DC    2F'0'                                                    82200015
SAVE7    DC    F'0'                                                     82300015
UCBNADR  DC    F'0'                                                     82400015
ALL0S    DC    X'0000'                                                  82500015
         SPACE 2                                                        82510021
***   MAINTENANCE  AREA  ***                                            82520021
MAINTID  DC    CL8'IGFASR1A'           CORE IDENTIFIER                  82530021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              82540021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 82542021
         SPACE 2                                                        82544021
         CNOP  4,8                                                      82550015
         DC    C'ASR'                                                   82600015
TABLOCAT DC    X'01'                                                    82700015
         SPACE 1                                                        82800015
CVTDSECT DSECT                                                          82900015
         CVT                                                            83000015
         SPACE 2                                                        83100015
COMMON   DSECT                                                          83200015
         ASRMAC                                                         83300015
         END                                                            83400015
