         LCLA  &LEV,&REL                                                00100021
&LEV     SETA  40                                                       00100400
&REL     SETA  21                                                       00100521
&REL&LEV TITLE 'IGFASR2D LEVEL &LEV RMS-MCH STORAGE SCAN'               00101321
*TITLE  'SCAN MAIN STORAGE'                                           * 00102821
*                                                                     * 00103621
*STATUS CHANGE LEVEL                                                  * 00104421
*                                                                     * 00105221
*FUNCTION/OPERATION      THE FUNCTION IS TO SAVE THE CONTENTS OF THE  * 00106021
*              FAILING LOCATION, IT ALSO EXERCISES AND ANALYZES THE   * 00106821
*              MAIN STORAGE FOR FAILURES ASSOCIATED WITH THE DRIVING  * 00107621
*              AND SENSING LOGIC IN THE CORE ARRAY.                   * 00108421
*                                                                     * 00109221
*              PROGRAM OPERATION - KNOWN TEST PATTERNS ARE GENERATED  * 00110021
*              TO CHECK THE FAILING LOCATION(S). THE PRIMARY ERROR    * 00110821
*              AND ADDITIONAL ERRORS FOUND WHILE SCANNING THE MAIN    * 00111621
*              STORAGE WILL BE TESTED BY ONE, TWO, OR THREE EXERCISER * 00112421
*              ROUTINES DEPENDING UPON THE DEGREE OF ERROR.           * 00113221
*                                                                     * 00114021
*              ADDITIONAL ERROR SEARCH - THIS ROUTINE WILL SEARCH FOR * 00114821
*              ADDITIONAL MAIN STORAGE FAILURES. THE SEARCH FOR       * 00115621
*              ADDITIONAL ERRORS IS A NON-DESTRUCTIVE READ-OUT        * 00116421
*              OPERATION. THIS ROUTINE WILL -                           00117221
*                  1- EXERCISE AND ANALYZE THE PRIMARY ERROR LOCATION.* 00118021
*                  2- SEARCH FOR ADDITIONAL ERRORS BY PERFORMING      * 00118821
*                     LOAD OPERATION FROM THE ADDRESS LOCATION ZERO   * 00119621
*                     TO THE MAXIMUM ADDRESS OF MAIN STORAGE.         * 00120421
*                  3- EXERCISE AND ANALYZE ADDITIONAL ERRORS.         * 00121221
*                                                                     * 00122021
*ENTRY POINT   IGFASR2D FROM ASRNUC                                   * 00122821
*                                                                     * 00123621
*INPUT   ASR RECORD ENTRY BUILD AREA - ISUM1                          * 00124421
*                                    - ISUMBAD                        * 00125221
*                                    - REMEST TABLE                   * 00126021
*                                                                     * 00126821
         EJECT                                                          00127621
*OUTPUT  ASR RECORD ENTRY BUILD AREA - REMEST TABLE                   * 00128421
*                                                                     * 00129221
*                   *****  REMEST  TABLE  *****                       * 00130021
*                                                                     * 00130821
*             *************************************************       * 00131621
*             *************************************************       * 00132421
*             *  0  *  1  *  2  *  3  *  4  *  5  *  6  *  7  * BYTES * 00133221
*             *************************************************       * 00134021
*DOUBLE-WORD0 *  A  *  B  *  C  *  D  *  II *  H  *  SPARE E  *GEN.INF* 00134821
*             *************************************************       * 00135621
*DOUBLE-WORD1 *  F  *  G  *  V  *  X  *          I            *PRIMARY* 00136421
*             *************************************************       * 00137221
*DOUBLE-WORD2 *  N1 * O1  *       P1        *        Q1       *BLOCK  * 00147600
*             *************************************************FAILING* 00148421
*DOUBLE-WORD3 *  N2 * O2  *       P2        *        Q2       *REPORT * 00149200
*             *************************************************       * 00150021
*DOUBLE-WORD4 *  N3 * O3  *       P3        *        Q3       *       * 00150800
*             *************************************************       * 00151621
*DOUBLE-WORD5 *  R1 * S1  *       T1        *        U1       *UNIT   * 00152400
***************************************************************       * 00156421
*                                                                       00156800
**DOUBLE-WORDS6-13 ARE USED FOR THE MVTABLE(PDAR) AND/OR MCHSUB.        00156900
         EJECT                                                          00157221
*                                                                     * 00158021
* EXPLANATION                                                         * 00158821
*                                                                     * 00159621
*  A ----  NO. OF DOUBLE-WORD ENTRIES IN REMEST                       * 00160421
*  B ----  NO. OF SECONDARY ERROR ENTRIES                             * 00161221
*  C ----  NO. OF FAILING BLOCK ENTRIES                               * 00162021
*  D ----  NO. OF FAILING STORAGE UNIT                                * 00162821
*  II----  RECOMMENDED DIAGNOSTIC PROGRAM TO C.E.                     * 00163621
*            X'00' --- NONE                                           * 00164421
*            X'01' --- DIAGNOSTIC PROGRAM E3A1                        * 00165221
*            X'02' --- DIAGNOSTIC PROGRAM E3A2                        * 00166021
*            X'03' --- DIAGNOSTIC PROGRAM E3A1 AND E3A2               * 00166821
*            X'04' --- DIAGNOSTIC PROGRAM FOR SPF                     * 00167621
*            X'05' --- DIAGNOSTIC PROGRAM FOR SPF AND E3A1            * 00168421
*            X'06' --- DIAGNOSTIC PROGRAM FOR SPF AND E3A2            * 00169221
*            X'07' --- DIAGNOSTIC PROGRAM FOR SPF AND E3A1 AND E3A2   * 00170021
*                                                                     * 00170821
*   H ----  SPARE                                                  2K   00171621
*  E ---- NUMBER OF 2K SOLID ERRORS IN A BLOCK                     2K   00172421
*                                                                       00173221
* E+1 - NUMBER OF 2K SOLID ERRORS IN A UNIT                        2K   00174021
*                                                                       00174821
*  F ----  BIT 0  EQUALS 1  INDICATES PRIMARY ERROR ENTRY             * 00175621
*          BIT 1  EQUALS 1  INDICATES REPAIRABLE INTERMITTENT DATA    * 00176421
*          BIT 2  EQUALS 1  INDICATES REPAIRABLE INTERMITTENT SPF     * 00177221
*          BIT 3  EQUALS 1  INDICATES HIGH INTERMITTENT               * 00178021
*          BIT 4  EQUALS 1  INDICATES UNREPAIRABLE INTERMITTENT ERROR * 00178821
*          BIT 5 TO BIT 7  ARE  NOT USED.                             * 00179621
*                                                                     * 00180421
*  G ----  BIT 0  EQUALS 1  INDICATES ERROR CHECK CIRCUITRY FAILURE   * 00181221
*          BIT 1  EQUALS 1  INDICATES SPF FAILURE                     * 00182021
*          BIT 2  EQUALS 1  INDICATES SSK/ISK FAILURE                 * 00182821
*          BIT 3  EQUALS 1 INDICATES KEY MATCHING FAILURE             * 00183621
*          BIT 4  EQUALS 1  INDICATES ADDRESS FAILURE                 * 00184421
*          BIT 5  EQUALS 1  INDICATES DATA FAILURE                    * 00185221
*          BIT 6  EQUALS 1  INDICATES MARK FAILURE                    * 00186021
*          BIT 7  EQUALS 1  INDICATES NO ERROR FOUND                  * 00186821
*                                                                     * 00187621
*  I ----  ADDRESS OF ERROR LOCATION                                  * 00188421
*                                                                     * 00194821
*  N ----  BIT 0  EQUALS 1  INDICATES PRIMARY ERROR IN THIS BLOCK/UNIT* 00195621
*          BIT 1,2,4-7  ARE NOT USED                                  * 00196421
*          BIT 3  EQUALS 1  INDICATES HIGH INTERMITTENT ERROR         * 00197221
*                                                                     * 00198021
*  O ----  SAME AS G ABOVE                                            * 00198821
*                                                                     * 00199621
*  P ----  POINTER TO BLOCK ERROR REPORT                              * 00200421
*                                                                     * 00201221
*  Q ----  ENDING ADDRESS OF BLOCK ERROR REPORT                       * 00202021
*                                                                     * 00202821
*                                                                     * 00203621
*  R ----  SAME AS N ABOVE                                            * 00204421
*                                                                     * 00205221
*  S ----  SAME AS G ABOVE                                            * 00206021
*                                                                     * 00206821
*  T ----  STARTING ADDRESS OF UNIT ERROR REPORT                      * 00207621
*                                                                     * 00208421
*  U ----  ENDING ADDRESS OF UNIT ERROR REPORT                        * 00209221
*                                                                     * 00210021
*  V ----  CONTENTS OF FAILING ADDRESS IN HEX BEFORE REFRESHED OR     * 00210821
*          SPF KEY                                                    * 00211621
*                                                                     * 00212421
*                                                                     * 00214021
*  X ----  CONTENTS OF FAILING ADDRESS IN HEX AFTER  REFRESHED        * 00214821
*                                                                     * 00215621
*                                                                     * 00217221
*                                                                     * 00218021
*EXTERNAL ROUTINES   NOT APPLICABLE                                   * 00218821
*                                                                     * 00219621
*EXITS    NORMAL - IGFASR00 - PDAR                                    * 00220421
*         ABNORMAL - (UNEXPECTED MACHINE CHECK) TO ASRNUC ABNORMAL    * 00221221
*         TERMINATION ROUTINE.                                        * 00222021
*                                                                     * 00222821
*TABLES/WORKAREAS - REMEST                                            * 00223621
*                                                                     * 00224421
*ATTRIBUTES - SERIALL REUSABLE                                        * 00225221
*           - PRIVILEGED                                              * 00226021
*RESTRICTIONS   THIS MODULE IS MODEL DEPENDENT FOR SYSTEM/360 MODEL 65* 00226821
*                                                                     * 00227621
         EJECT                                                          00228421
IGFASR2D CSECT                                                          00229221
         IEAQFX     65,MCH,1,GENCODE=NO                            MP   00230017
IGFASR2D CSECT                                                       MP 00260017
         USING *,BASEREG                                                00300015
         USING CVTTAB,WKR6                                              00400015
         USING COMMON,COMREG                                            00500015
FLAGS  EQU     15                                                       00600015
MKOLD    EQU   48                                                       00700015
MKNEW  EQU     112                                                      00800015
DATLOG   EQU   294                                                      00900015
         L     WKR6,COMCVT                                              00950017
         B     STARRT                                                   01000015
         ORG   IGFASR2D+8                                               01100015
TTRTABLE DC    C'00'               PDAR I D                             01200015
         DC    X'00000000'         PDAR TTRL                            01300015
TABEND   DC    X'0000'                                                  01400015
STARRT   EQU   *                                                        01500015
         MVI   COMLEV2D,LEVEL   MOVE IN MODULE LEVEL                    01960021
LEVEL  EQU   X'&LEV'                                                    02030021
         TM    MEST89,TWO       IS MARK REG. FAILURE REPORTED IE  42247 02100000
         BC    8,SETUP             NO,BRANCH                            02200015
         OI    MARKCHK,X'01'       YES,SET THE INDICATION               02300015
SETUP    EQU   *                                                        02400015
         LA    WKR1,MKINT          ADJUST                               02500015
         ST    WKR1,MKINTA          MCI                                 02600015
         LA    WKR1,MEMFH            HANDLING                           02700015
         ST    WKR1,SECMCI            ROUTINE.                          02800015
         MVC   PRIMERAD(4),COMSBAD      OBTAIN FIALING ADR FROM IRA  MP 03100017
         NI    PRIMERAD+3,FEIGHT      CLEAR BITS                   MP   03300018
         MVC   ASRPSW(8),112       SAVE ASR NEW PSW.                    03500015
         SPACE 1                                                        03600015
*********************************************************************** 03700015
*              S C A N   M E M O R Y                                  * 03800015
*********************************************************************** 03900015
         SPACE 1                                                        04000015
         L     WKR7,PRIMERAD  FAILING ADDR                         2K   04100018
         SRL   WKR7,VD18      ONLY UNIT LOW  ADDR WHICH CONTAINS   2K   04200018
         SLL   WKR7,VD18      THE ERROR IS CREATED                 2K   04300018
         ST    WKR7,UNISTART                 ADDRESS                    04500015
         A     WKR7,UNIADR                    OF STORAGE                04600015
         ST    WKR7,UNIEND                     UNIT WILL BE TESTED.     04700015
         SR    WKR2,WKR2              CLEAR REG 2                  2K   04730018
         B     SCAN1         SKIP FOR FIRST BLOCK                  2K   04760018
SCAN2    EQU   *                                                        04800015
         SR    WKR2,WKR2                     CLEAR REG 5           2K   04900018
         IC    WKR2,BLKCHCTR           NUMBER OF BLOCKS SCANNED    2K   05000018
         LA    WKR2,ONE(WKR2)                UPDATED               2K   05100018
SCAN1    EQU    *                                                  2K   05200018
         STC   WKR2,BLKCHCTR           IF EQUAL 4, WE GO TO UNIT ERR2K  05300018
         SLL   WKR2,3                LOAD TEST ADR.                     05500015
         L     WKR3,TST1(WKR2)     STARTING ADR.                        05600015
         L     WKR4,TST1+4(WKR2)   ENDING ADR.                          05700015
         A     WKR3,UNISTART  STARTING ADDR ADJUSTED TO UNIT       2K   05730018
         A     WKR4,UNISTART  ENDING   ADDR ADJUSTED TO UNIT       2K   05760018
         ST    WKR3,STARTA         STARTING AND ENDING                  05800015
         ST    WKR4,ENDA            ADR OF THISBBLOCK.                  05900015
         CLI   MARKCHK,X'01'           IS MARK REG. FAILURE             06000015
         BE    UNITCHVD  YES,SET UNIT INDICATORS GO TO UNIT REPORT 2K   06700018
SCAN3    EQU   *                                                        07400015
         BAL   WKR10,ENAB          ENABLE                               07500015
         BC    15,*-4                MCI.                               07600015
SCAN4    MVC   117(3),SECMCI+1     SET UP TO HANDLE MCI                 07700015
*     REG 2 CONTAINS BLOCK COUNT ADDR INDEX                        2K   07710018
         LA    WKR7,CEE                 SET MASK                    MP  07720017
         LA    WKR2,FSSEMAP-IPLPSW(WKR2)   CORRECT POINT IN FSSEMAP  MP 07730017
SCAN15   EQU   *                                                     MP 07740017
         TM    COMMSF,TEN       CHECK FOR MULTIPROCESSING MODE      MP  07750017
         BZ    SCAN5           NO                                  MP   07760017
         STH   WKR2,NEXTTM      YES,SET UP TEST INSTRUCTION         MP  07770017
         EX    WKR7,TM        TEST FSSEMAP BITS                      MP 07780017
         BNZ   SCAN13         SECTION OF CORE NOT AVAILABLE          MP 07790017
         LA    WKR5,MAXVD       SET LOOP                            MP  07800017
SCAN5    EQU   *                                                     MP 07810017
         ST    WKR3,DWADDR        SAVE ACTUAL ADDR                 2K   07815018
         LD    WKR2,0(WKR3)   LOAD DOUBLE TO GET BAD ADR.            MP 07820017
         LA    WKR3,8(WKR3)   INCREMEN BY 8                          MP 07830017
         TM    COMMSF,TEN          CHECK MULTIPROCESSING MODE       MP  07840017
         BZ    SCAN7         NOT MULTI PROCESSING                  MP   07850017
         BCT   WKR5,SCAN5     256 LOOP CONTROL X 8= 2048             MP 07860017
         B     SCAN14         SKIP INCREMENT                         MP 07870017
SCAN13   EQU   *                                                     MP 07880017
         LA    WKR3,KKK(WKR3)      INCREMENT BY 1K BYTES            MP  07890017
SCAN14   EQU   *                                                     MP 07900017
         SRL   WKR7,2              SHIFT MASK                        MP 07910017
         LTR   WKR7,WKR7           CHECK IF MASK IS 00               MP 07920017
         BNZ   SCAN7               NO                                MP 07930017
         LA    WKR7,CEE            RESET MASK TO'CO'                MP  07940017
         LH    WKR2,NEXTTM         MODIFY TEST INSTRUCTION(TM)      MP  07950017
         LA    WKR2,1(WKR2)        BY ONE BYTE                       MP 07960017
SCAN7    EQU   *                                                     MP 07970017
         CLR   WKR3,WKR4           IS IT THE END OF THE BLOCK        MP 07980017
         BNE   SCAN15              NO, CONTINUE BLOCK SCAN          MP  07990017
         BAL   WKR10,BLKCHA        BRANCH TO BLOCK ERROR ANALYSIS.      08200015
SCAN8    EQU    *                                                  2K   08260018
         CLI   BLKCHCTR,THREEVD        UNIT COMPLETED              2K   08320018
         BC    8,UNITCHA           YES,GO TO UNIT ERROR ANALYSIS        08400015
         B     SCAN2               NEXT 64K BLOCK                  2K   08900018
SCAN10   BAL   WKR10,PRIMARY       CHECK FOR PRIMARY.                   09500015
         SPACE 1                                                        09508017
**********************************************************************  09516017
EXIT     EQU   *                                                     MP 09940017
         XC    BITCTR(VD18),BITCTR           CLEAR BYTES           2K   10020018
         BAL   WKR10,ENAB          ENABLE MCI                           10100015
         BC    15,*-4                                                   10200015
         MVC   112(8),ASRPSW       RESTORE ASRNUC PSW.                  10300015
         LH    WKR1,TTRTABLE       PDAR I.D.                            10400015
         MVC   COMNUC(4),TTRTABLE+2 PDAR TTRL                           10500015
         BCR   15,ASRNUCR                                               10600015
TM       TM    FSSEMAP-IPLPSW,ZER0VD    MODIFIED INSTRUCTION        MP  10606017
ZER0VD   EQU   0                                                        10612017
TWOTWO   EQU   22                                                   MP  10618017
KKK      EQU   2048                                                 MP  10624017
MAXVD    EQU   256                                                  MP  10630017
TEN      EQU   X'10'                                                MP  10636017
CEE    EQU     X'C0'                                                MP  10642017
FEIGHT   EQU   X'F8'                                                MP  10648017
         SPACE 1                                                        10700015
***            PRIMARY  ERROR  CHECK                                *** 10800015
         SPACE 1                                                        10900015
PRIMARY  TM    ISUM1+1,X'02'       IS PRIMARY ER-OR INVOLVED MEMORY     11000015
         BC    1,PRIMARY1          YES,BRANCH                           11100015
         BCR   15,WKR10            RETURN                               11200015
PRIMARY1 TM    COMMST+8,X'80'      IS PRIMARY ERROR REPORTED            11300015
         BC    8,PRIMARY2          NO,BRANCH                            11400015
         BCR   15,WKR10            RETURN                               11500015
         SPACE 1                                                        11600015
PRIMARY2 EQU   *                                                     MP 11700017
         L     WKR3,PRIMERAD       LOAD PRIMARY ERROR ADR,              11800015
         ST    WKR3,TSTADR         STORE PRIMARY ERROR INTO TEST ADR    11900015
         OI    FORPRTST,X'01'      SET FORCING PRIMARY ERROR TEST.      12000015
         OI    PRIMERID,X'01'      SET PRIMARY TEST I.D.                12100015
         OI    REMEST+4,X'01'          RECOMMEND C.E. TO RUN DIAG.PROM. 12200015
         LD    WDR2,0(WKR3)             SAVE                            12300015
         STD   WDR2,SAVEDW                OF                            12500015
         AD    WDR2,ALL0S          CONTENTS                             12550015
         L     WKR1,COMSBAD             FAILING ADR                  MP 12620017
         IC    WKR3,0(WKR1)                 IN                          12700015
         STC   WKR3,ERRBYTE                  REMEST.                    12800015
         BC    15,MEMFHB           BRANCH TO TEST PRIMARY.              12900015
         SPACE 1                                                        17700015
*********************************************************************** 17800015
*              MEMORY   FAILURE   HANDLING                            * 17900015
*********************************************************************** 18000015
         SPACE 1                                                        18100015
MEMFH    STM   WKR1,BASEREG,REGSAV SAVE REGS.1 TO 15                    18200015
         BAL   WKR10,DISAB         DISABLE MACHINE CHECK                18300015
         MVC   OLPSWSAV(8),48      SAVE OLD PSW.                        18400015
         TM    164,X'02'           IS IT ADR CHECK.                     18500015
         BC    8,MEMFH1            NO,BRANCH                            18600015
         OI    ERRTYPE,X'08'       ADDR FAILURE INDICATION.             18700015
         BC    15,MEMFH22                                               18800015
MEMFH1   TM    164,X'01'           IS IT DATA CHECK                     18900015
         BC    8,MEMFH22                                                19000015
         OI    ERRTYPE,X'04'       DATA FAILURE INDICATION.             19100015
MEMFH22  EQU   *                                                        19200015
         ST    WKR3,TSTADR         STORE FAILING ADR. INTO TEST         19300015
         ST    WKR3,TSTADR1                FOR COMPUTING ACTUAL ADR.    19400015
         LD    WDR2,0(WKR3)        SAVE DATA                            19500015
         STD   WDR2,SAVEDW          OF FAIL G ADR                       19700015
         AD    WDR2,ALL0S          CLEAR BAD PARITY                     19750015
         STD   WDR2,0(WKR3)        STORE ALL 0 YNTO BAD LOCATION        19800015
         LA    WKR3,8(WKR3)        SAVE THE NEXT                        19900015
         LD    WDR2,0(WKR3)         DOUBLE WORD                         20000015
         STD   WDR2,NXTDW            FOR ANALYZING I/O ACTIVITY.        20100015
         BAL   WKR10,BYTELOC1      FIND BAD BYTE LOCATION.              20200015
         OC    TSTADR1+3(1),BYTELOC        ACTUAL FAILING ADR.          20300015
         L     WKR1,TSTADR1        SAVE CONTENTS                        20400015
         IC    WKR3,0(WKR1)         OF FAILNG                           20500015
         STC   WKR3,ERRBYTE          LOCATION.                          20600015
MEMFHA   EQU   *                                                        20700015
         CLC   TSTADR+1(3),PRIMERAD+1  IS THIS PRIMARY ERROR.           20800015
         BC    7,MEMFHC            NO,BRANCH                            20900015
         OI    PRIMERID,X'01'      YES,SET PRIMARY ERROR I.D.           21000015
         BC    15,*+8                                                   21100015
         SPACE 1                                                        21200015
MEMFHB   STM   WKR1,BASEREG,REGSAV SAVE REG. 1 TO 15                    21300015
MEMFHC   BAL   WKR10,ENAB          BLEED                                21400015
         BC    15,*-4                MCI.                               21500015
         MVC   MKNEW+5(3),MKINTA+1 SETUP MCI HANDLING                   21600015
*********************************************************************** 21605017
*              B A S I C     E X E R C I S O R                        * 21610017
*********************************************************************** 21615017
         SPACE 1                                                        21620017
BASICEX  STM   WKR0,WKR8,REGSAVX   SAVE REGS. 0 TO 8                    21625017
         LA    WKR9,BASERANL     TO SETUP RETURN REG IF MCI        MP   21630017
         LA    WKR1,100            SETUP COUNTER TO FETCH 100 TIMES.    21635017
         L     WKR2,TSTADR          LOAD FAI3&5G  4                     21640017
BASICEX1 LD    WDR2,0(WKR2)        FETCHING FAILING ADR                 21645017
BASICEX2 BCT   WKR1,BASICEX1        FOR 100 TIMES.                      21650017
         MVC   BASICF(1),MCICTR    TRANSFER COUNTS TO BASIC CTR.        21655017
         XC    MCICTR(3),MCICTR    CLEAR ERROR RECORD.                  21660017
         LA    WKR1,100            SETUP COUNTER TO STORE 100 TIMES.    21665017
         L     WKR2,TSTADR          LOAD FAI3&5G  4                     21670017
         LD    WDR4,ONES           LOAD TEST PATTERNS OF ALL ONES.      21675017
BASICEX3 STD   WDR4,0(WKR2)        STORE TO FAILING ADR                 21680017
BASICEX4 BCT   WKR1,BASICEX3        100 TIMES.                          21685017
         MVC   BASICS(1),MCICTR    TRANSFER MCI COUNTER TO  BASIC CTR.  21690017
         XC    MCICTR(3),MCICTR    CLEAR ERROR RECORD.                  21695017
*********************************************************************** 21700017
*              BASIC  EXERCISOR  SUMMARY                             *  21705017
*********************************************************************** 21710017
         SPACE 1                                                        21715017
BASERANL CLI   BASICS,X'0'         ANY ERROR OCCURRED IN STORING        21720017
         BC    8,BASER1             THE FAILURE LOCATION,NO--BRANCH     21725017
         CLI   BASICS,X'02'        DOES IT OCCUR MORE THAN 2 TIMES.     21730017
         BC    10,BASER3           YES,IT CONSIDERS AS SOLID ERROR.     21735017
BASER1   CLI   BASICF,X'0'         ANY ERROR OCCURRED IN FETCHING       21740017
         BC    8,BASER2            NO,BRANCH                            21745017
         CLI   BASICF,X'02'        DOES IT OCCUR MORE THAN 2 TIMES.     21750017
         BC    10,BASER3           YES,IT CONSIDERS AS SOLID ERROR.     21755017
BASER2   B     INTEREX       GO TO INTERMEDIATE EXERCISOR            MP 21760017
BASER3   OI    ERRKIND,X'10'       SOLID ERROR.                         21765017
         XC    BASICS(4),BASICS    CLEAR ERROR RECORD.                  21770017
         OI    NUMBYTE,TWO    SET NUMBER OF 2K BLOCKS              2K   21773018
         B     MAPSET              TO SET SOLID IN FSSEM AP        2K   21776018
*********************************************************************** 21780017
*              I N T E R M E D I A T E   E X E R C I S O R            * 21785017
*********************************************************************** 21790017
         SPACE 1                                                        21795017
INTEREX  EQU   *                                                     MP 21800017
         LA    WKR9,MEMFH2      TO SETUP RETURN REG IF MCI         MP   21805017
         LA    WKR0,24                                                  21810017
         L     WKR2,TSTADR          LOAD FAI3&5G  4                     21815017
         L     WKR4,PATTERN1       LOAD TEST PATTERN                    21820017
         LR    WKR5,WKR4            INTO BOTH REGS. 4 AND 5.            21825017
INTEREX1 STM   WKR4,WKR5,0(WKR2)   STORE TEST PATTERN INTO FAILING ADR. 21830017
         LM    WKR6,WKR7,0(WKR2)   FETCH ORIGINAL TEST PATTERN          21835017
         A     WKR6,ALL0S          CLEAR BAD PARITY                     21840017
         A     WKR7,ALL0S            IN THE REGS.                       21845017
INTEREX2 CLR   WKR4,WKR6            OUT OF FAILING ADR                  21850017
         BC    7,ERR1                TO CHECK FOR                       21855017
INTEREX3 CLR   WKR5,WKR7              POSSIBLE ERRORS.                  21860017
         BC    7,ERR1              GO TO ERR. ANALYSIS,IF THERE IS ERR. 21865017
INTEREX4 L     WKR8,ONES           LOAD ONES                            21870017
         XR    WKR4,WKR8           COMPLEMENT THE                       21875017
         XR    WKR5,WKR8            TEST PATTERN                        21880017
         BCT   WKR0,INTEREX1       CONTINUE THE TEST.                   21885017
         MVC   INTSUMB(1),MCICTR   TRANSFER COUNT. TO INTER. CTR.       21890017
         XC    MCICTR(3),MCICTR    CLEAR ERROR RECORD.                  21895017
         LM    WKR0,WKR8,REGSAVX   RESTORE REGS. 0 TO 8                 21900017
INTEREX5 B     MEMFH2        GO TO INTERM ERROR ANALYSIS             MP 21905017
ERR1     ST    WKR1,SAVE1          SAVE REG.1                           21910017
         CLI   INTDRP,X'02'         IS ERROR OCCURRED 2 TIMES           21915017
         BC    8,INTEREX5              YES,BRANCH                       21920017
         SR    WKR1,WKR1           CLEAR REG.1                          21925017
         IC    WKR1,INTDRP         OBTAIN INTERMEDIATE ERROR COUNTER.   21930017
         LA    WKR1,1(WKR1)        INCREASE ERROR COUNT                 21935017
         STC   WKR1,INTDRP          BY ONE.                             21940017
         L     WKR1,SAVE1          RESTORE REG.1                        21945017
         BC    15,INTEREX4         RETURN                               21950017
         SPACE 1                                                        21955017
MEMFH2   EQU   *                                                     MP 21960017
         BAL   WKR9,INTERNAL       INTERMEDIATE ERROR ANALYSIS          22000015
MEMFH3   BAL   WKR9,ADVEX          GO TO ADVANCED EXERCISOR             22100015
         BAL   WKR9,ADVEXANL       GO TO ADV. ERR. ANALYSIS.            22200015
MEMFHSUM BAL   WKR10,DISAB         DISABLE MCI.                         22300015
         L     WKR3,TSTADR         RESTORE ORIGINAL CONTENTS            22400015
         LD    WDR2,SAVEDW         AND                                  22500015
         STD   WDR2,0(WKR3)        DETERMINE THAT                       22600015
         AD    WDR2,ALL0S          CLEAR BAD PARITY                     22630015
         STD   WDR2,SAVEDW           IN FPT. AND SAVE AREA.             22660015
         CLI   PRIMERID,X'01'      IS IT PRIMARY ERROR                  22700015
         BC    8,PRR               YES,BRANCH TO PRIMARY REPORT.        22800015
         LA    WKR3,8(WKR3)         I/O ACTIVITY                        22900015
         LD    WDR2,0(WKR3)          HAD READ                           23000015
         CD    WDR2,NXTDW             NEW DATA                          23100015
         BC    8,MEMFH4                INTO                             23200015
         OI    ERRKIND,X'80'            FAILING LOCATION.               23300015
MEMFH4   EQU   *                                                        23400015
         CLI   BITCTR,X'05'        IS IT MORE THAN 5 BIT FAILURE REPORT 23500015
         BC    8,MEMFHEY           YES,BRANCH                           23600015
         SR    WKR1,WKR1                                                23700015
         IC    WKR1,BITCTR         OBTAIN BIT FAILURE REPORT COUNTER    23800015
         SLL   WKR1,3                                                   23900015
         LA    WKR2,BITERR(WKR1)                                        24000015
         MVC   0(3,2),ERRKIND      REPORT ERROR STATUS                  24100015
         L     WKR3,TSTADR1        ACTUAL FAILING ADR.                  24200015
         ST    WKR3,4(WKR2)        ADR OF FAILING BIT                   24300015
         XC    ERRKIND(3),ERRKIND  CLEAR ERROR COUNTERS.                24400015
         SR    WKR1,WKR1           UP DATE                              24500015
         IC    WKR1,BITCTR          BIT                                 24600015
         LA    WKR1,1(WKR1)          FAILURE                            24700015
         STC   WKR1,BITCTR             COUNTER.                         24800015
         BC    15,MEMFHEX          BRANCH TO RETURN                     24900015
PRR1     NI    FORPRTST,X'0'       CLEAR FORCE PRIMARY ERR TST I.D.     25000015
         BC    15,EXIT             BRANCH TO COMPLETION                 25300015
         SPACE 1                                                        25400015
***            PRIMARY  ERROR  REPORT                               *** 25500015
         SPACE 1                                                        25600015
PRR      MVC   TALVD(WKR4),COMSBAD       PRIM.ERROR  ADR            MP  25700017
         OI    REMEST+4,X'01'          RECOMMEND C.E. TO RUN DIAG.PROM. 25800015
         BAL   WKR10,UPDATCTR      UPDATE ENTRY COUNTER.                25900015
         OI    ERRKIND,X'80'            THERE IS PRIMARY ERROR ENTRY.   26000015
         MVC   REMEST+8(3),ERRKIND      ERROR REPORT.                   26100015
         NI    PRIMERID,X'0'            CLEAR                           26200015
MEMFHEY  EQU   *                                                   2K   26250018
         XC    ERRKIND(2),ERRKIND         ERROR RECORD.                 26300015
MEMFHEX  LM    WKR1,BASEREG,REGSAV      RESTORE REGS.                   26400015
         CLI   FORPRTST,X'01'           IS IT FORCE PRIMARY ERROR TEST  26500015
         BC    8,PRR1                   YES,BRANCH PRIMARY ERR. RECORD. 26600015
         BAL   WKR10,ENAB               ENABLE MCI.                     26700015
         BC    15,*-4                                                   26800015
         MVC   48(8),OLPSWSAV           SET RETRUN TO CONTINUE TEST.    26900015
         MVC   MKNEW+5(3),SECMCI+1 RESTORE SECTION NEW MACH. PSW        27000015
         LPSW  48                       RETURN TO CONTINUE TEST.        27100015
         SPACE 1                                                        27200015
         SPACE 1                                                        27500015
UPDATCTR EQU   *                                                        27600015
         SR    WKR6,WKR6           UP DATE                              27700015
         IC    WKR6,REMEST          TOTAL                               27800015
         LA    WKR6,1(WKR6)          ENTRIES                            27900015
         STC   WKR6,REMEST            COUNTER.                          28000015
         BCR   15,WKR10            RETURN                               28100015
         SPACE 1                                                        28200015
*                                                                     * 28300015
***      LOCATION OF BAD BYTE WITHIN THE DOUBLE WORD BOUNDARY       *** 28400015
*                                                                     * 28500015
         SPACE 1                                                        28600015
BYTELOC1 TM    DATLOG,X'10'        ******************************       28700015
         BC    8,LOC2              *  THIS ROUTINE USING        *       28800015
         OI    BYTELOC,X'00'       *  LOGOUT AREA TO LOCATE     *       28900015
         BCR   15,WKR10            *  THE FAILING BYTE IN       *       29000015
LOC2     TM    DATLOG+1,X'70'      ******************************       29100015
         BC    8,LOC3                                                   29200015
         TM    DATLOG+1,X'30'                                           29300015
         BC    4,LOC4                                                   29400015
         OI    BYTELOC,X'01'                                            29500015
         BCR   15,WKR10            RETURN                               29600015
         SPACE 1                                                        29700015
LOC4     TM    DATLOG+1,X'20'                                           29800015
         BC    8,LOC5                                                   29900015
         OI    BYTELOC,X'02'                                            30000015
         BCR   15,WKR10            RETURN                               30100015
         SPACE 1                                                        30200015
LOC5     OI    BYTELOC,X'03'                                            30300015
         BCR   15,WKR10            RETURN                               30400015
         SPACE 1                                                        30500015
LOC3     TM    DATLOG+1,X'0C'                                           30600015
         BC    8,LOC6                                                   30700015
         TM    DATLOG+1,X'08'                                           30800015
         BC    8,LOC7                                                   30900015
         OI    BYTELOC,X'04'                                            31000015
         BCR   15,WKR10            RETURN                               31100015
         SPACE 1                                                        31200015
LOC7     OI    BYTELOC,X'05'                                            31300015
         BCR   15,WKR10            RETURN                               31400015
         SPACE 1                                                        31500015
LOC6     TM    DATLOG+1,X'02'                                           31600015
         BC    8,LOC8                                                   31700015
         OI    BYTELOC,X'06'                                            31800015
         BCR   15,WKR10            RETURN                               31900015
         SPACE 1                                                        32000015
LOC8     OI    BYTELOC,X'07'                                            32100015
         BCR   15,WKR10            RETURN                               32200015
         SPACE 1                                                        32300015
*********************************************************************** 38000015
*              A D V A N C E D    E X E R C I S O R                   * 38100015
*********************************************************************** 38200015
         SPACE 1                                                        38300015
ADVEX    STM   WKR0,WKR8,REGSAVX   SAVE REGS. 0 TO 8                    38400015
         L     WKR4,TSTADR         LOAD TEST ADR.                       38500015
         MVI   ADVPT,X'01'         SET ALL ONES TEST PATTERN I.D.       38600015
ADVEXB   LA    WKR0,50             SETUP TO BEAT THE SAME ADR. 50 TIMES 38700015
         LA    WKR1,TSTTAB         LOAD STARTING ADR OF TEST TABLE.     38800015
         L     WKR2,SINST          SINST IS TESTING INSTRUCTION.        38900015
ADVEX1   ST    WKR2,0(WKR1)        CONSTRUCT THE TEST TABLE WITH        39000015
         LA    WKR1,4(WKR1)         50 EXERCISOR                        39100015
         BCT   WKR0,ADVEX1           INSTRUCTIONS.                      39200015
         L     WKR2,TSTR1          AFTER EXERCISE RETURN TO ADVEX2      39300015
         ST    WKR2,0(WKR1)          AT THE END OF TEST TABLE.          39400015
         LD    WDR2,CONT1          LOAD TEST PATTERN OF ALL ONES.       39500015
         BC    15,TSTTAB           TO EXECUTE THE TABLE                 39600015
ADVEX2   LD    WDR6,0(WKR4)        LOAD FAILING LOCATION                39700015
         CDR   WDR6,WDR2           CHECK FOR ERROR WHEN STORING.        39800015
         BC    8,ADVEX3            NO ERROR,THEN CONTINUE               39900015
         BAL   WKR1,ADVSUM          GO TO SUMMARY FOR THIS ROUTINE      40000015
ADVEX3   OI    SINST,X'68'         CHANGE TEST INSTRUCTION TO LD.       40100015
         CLI   ADVPT,X'01'         IS IT TESTING FOR ALL ONES.          40200015
         BC    8,ADVEX3A           YES,SETUP TO GO TO TEST ALL ZEROS.   40300015
         MVC   TSTR1(4),TSTR3      NO,SETUP TO GO TO SUMMARY.           40400015
         BC    15,ADVEXB                                                40500015
ADVEX3A  MVC   TSTR1(4),TSTR2      AFTER EXERCISE RETURN TO ADVEX4      40600015
         BC    15,ADVEXB           RETURN TO CONSTRUCT TABLE.           40700015
         SPACE 1                                                        40800015
ADVEX4   LD    WDR6,0(WKR4)        LOAD FAILING LOCATION.               40900015
         CDR   WDR2,WDR6           CHECK FOR ERROR WHEN FETCHING.       41000015
         BC    8,ADVEX5            IF NO ERROR,BRANCH TO SETUP TEST,    41100015
         BAL   WKR1,ADVSUM          GO TO SUMMARY FOR THIS ROUTINE      41200015
ADVEX5   OI    SINST,X'60'         CHANGE TEST INSTRUCTION TO STD.      41300015
         MVC   TSTR1(4),TSTR4      SETUP TO CHECK TO STORING ZEROS.     41400015
         MVC   CONT1(8),ALL0S      LOAD ALL ZEROS FOR TEST PATTERN.     41500015
         MVI   ADVPT,X'0'          TURN OFF ALL ONES TEST INDICATOR.    41600015
         BC    15,ADVEXB           RETURN TO CONSTRUCT TABLE.           41700015
ADVEX6   BAL   WKR1,ADVSUM         ADVANCED EXERCISOR SUMMARY.          41800015
         LM    WKR0,WKR8,REGSAVX   RESTORE REGS. 0 TO 8                 41900015
         BCR   15,WKR9             RETURN.                              42000015
         SPACE 1                                                        42100015
*********************************************************************** 42200015
*            ROUTINE TO ENABLE MK AND SETUP TO HANDLE INTERRUPT       * 42300015
*********************************************************************** 42400015
         SPACE 1                                                        42500015
ENAB     MVC   BUFFER(4),INPSW     SET KEY AND MK MASK UP.              42600015
         ST    WKR10,MKNEW+4       SET MK NEW PSW.                      42700015
         LA    WKR10,4(WKR10)                                           42800015
         ST    WKR10,BUFFER+4                                           42900015
         LA    WKR0,22             22 DOUBLE WORDS IN LOGOUT AREA.      43000015
         LA    WKR10,128           STARTING ADDRESS OF LOGOUT AREA.     43100015
         LD    WDR6,ALL0S                                               43200015
ENABB    STD   WDR6,0(WKR10)       CLEAR AREA.                          43300015
         LA    WKR10,8(WKR10)      STEP TO NEXT DOUBLE WORD.            43400015
         BCT   WKR0,ENABB                                               43500015
         LPSW  BUFFER              ENABLE MACHINE CHECK.                43600015
         SPACE 1                                                        43700015
*********************************************************************** 43800015
*              ROUTINE TO DISABLE MK AND RESTORE MK NEW PSW          *  43900015
*********************************************************************** 44000015
         SPACE 1                                                        44100015
DISAB    MVC   BUFFER(4),MKNEWS    SET KEY AND SET MK MASK OFF.         44200015
         ST    WKR10,BUFFER+4                                           44300015
         LPSW  BUFFER              RETURN AT 0(10) WITH MK DISABLED.    44400015
         SPACE 1                                                        44500015
*********************************************************************** 46200015
*              INTERMEDIATE  EXERCISOR  SUMMARY                       * 46300015
*********************************************************************** 46400015
         SPACE 1                                                        46500015
INTERNAL CLI   INTSUMB,X'0'        ANY ERROR OCCURRED IN INTER. EXR.    46600015
         BC    8,INTER1            NO,BRANCH TO CHECK OTHER CONDITION   46700015
         CLI   INTSUMB,X'02'       DOES ERROR OCCUR MORE THAN 2 TIMES.  46800015
         BC    8,INTER3            YES,IT IS CONSIDERED AS SOLID ERROR. 46900015
INTER1   CLI   INTDRP,X'0'         ANY ERROR OCCURRED                   47000015
         BC    8,INTER2            NO,BRANCH                            47100015
         CLI   INTDRP,X'02'        DOES IT OCCUR MORE THAN 2 TIMES.     47200015
         BC    8,INTER3            YES,IT IS CONSIDERED AS SOLID ERROR. 47300015
INTER2   BCR   15,WKR9             NO,BRANCH TO CALL IN ADVANCED EXER.  47400015
INTER3   OI    ERRKIND,X'10'       SOLID ERROR.                         47500015
         XC    BASICS(4),BASICS    CLEAR ERROR RECORD.                  47600015
         OI    NUMBYTE,TWO    SET NUMBER OF 2K BLOCKS              2K   47660018
         B     MAPSET              TO SET SOLID IN FSSEM AP        2K   47720018
*********************************************************************** 47800015
*              ADVANCED  EXERCISOR  SUMMARY                           * 47900015
*********************************************************************** 48000015
         SPACE 1                                                        48100015
ADVEXANL CLI   ADVF,X'0'           ANY ERROR OCCURRED                   48200015
         BC    7,ADV1              YES,BRANCH TO MORE ANALYSIS          48300015
         OI    ERRKIND,X'40'       REPAIRABLE INTERMITTENT              48400015
         OI    ERRTYPE,X'01'       NO ERROR FOUND                       48500015
         BCR   15,WKR9             RETURN.                              48600015
ADV2     CLI   ERRKIND,X'08'       IS IT ADR FAILED                     48700015
         BC    8,ADV3              YES,BRANCH                           48800015
         OI    ERRTYPE,X'04'       DATA FAILURE                         48900015
         BCR   15,WKR9             RETURN.                              49000015
ADV3     OI    ERRTYPE,X'08'       ADR FAILURE                          49100015
         BCR   15,WKR9             RETURN.                              49200015
ADV1     CLI   ADVF,X'02'          DOES IT OCCUR MORE THAN 2 TIMES.     49300015
         BC    7,ADV2              NO,IT IS INTERMITTENT                49400015
         OI    ERRKIND,X'10'       SOLID ERROR.                         49500015
         XC    BASICS(4),BASICS    CLEAR ERROR RECORD.                  49600015
         OI    NUMBYTE,TWO    SET NUMBER OF 2K BLOCKS              2K   49660018
         B     MAPSET              TO SET SOLID IN FSSEM AP        2K   49720018
*********************************************************************** 49800015
*              MACHINE   CHECK   HANDLING                             * 49900015
*********************************************************************** 50000015
         SPACE 1                                                        50100015
MKINT    SR    WKR4,WKR4           MACHINE CHECK INTERRUPT              50200015
         CLI   MCICTR,X'02'        SET LIMITED FOR COUNTER.             50300015
         BC    8,MKINT2                                                 50400015
         OI    REMEST+4,X'01'          RECOMMEND C.E. TO RUN DIAG.PROM. 50500015
         IC    WKR4,MCICTR          COUNTER TO                          50600015
         LA    WKR4,1(WKR4)          REGISTER                           50700015
         STC   WKR4,MCICTR            ALL MCI                           50800015
         TM    164,X'01'           IS IT DATA FAILURE                   50900015
         BC    1,MKINT1            YES,BRANCH                           51000015
         OI    ERRTYPE,X'08'       SET ADDRESS FAILURE                  51100015
         BC    15,MKINT3           BRANCH                               51200015
MKINT1   OI    ERRTYPE,X'04'       SET DATA FAILURE                     51300015
MKINT3   BAL   WKR10,ENAB          ENABLE                               51400015
         BC    15,*-4                MCI                                51500015
         MVC   MKNEW+5(3),MKINTA+1      SETUP TO HANDLE MCI             51600015
         LPSW  MKOLD               RETURN                               51700015
MKINT2   MVC   BASICS(1),MCICTR    SAVE                                 51800015
         MVC   BASICS+1(3),BASICS    RECORDS.                           51900015
         NI    MCICTR,X'0'         CLEAR ERROR COUNTS.                  52000015
         LM    WKR0,WKR8,REGSAVX   RESTORE REGS. 0 TO 8                 52100015
         BCR   15,WKR9             RETURN                               52200015
         SPACE 1                                                        52300015
         SPACE 1                                                        52400015
ADVSUM   MVC   ADVF(1),MCICTR      DITTO                                52500015
         XC    MCICTR(3),MCICTR    CLEAR ERROR RECORD.                  52600015
         BCR   15,WKR1                                                  52700015
         SPACE 1                                                        52800015
         SPACE 1                                                        52900015
***            BLOCK  ERROR  ANALYSIS                               *** 53000015
         SPACE 1                                                        53100015
BLKCHA   CLI   BITCTR,X'0'         ANY BIT ERROR REPORTED               53200015
         BC    7,BLKCHA1           YES,BRANCH                           53300015
         BCR   15,WKR10            RETURN                               53400015
BLKCHA1  EQU   *                                                   2K   53800018
         STM    WKR6,WKR8,BLKREGS   SAVE REGS 6 TO8                2K   54200018
         BAL   WKR10,DISAB               DISABLE MCI               2K   54600018
         SR    WKR6,WKR6                     CLEAR                 2K   55000018
         SR    WKR7,WKR7                     REGS                  2K   55400018
         IC    WKR6,MEST6              SOLID 2K CTR                2K   55800018
         IC    WKR7,MEST7              SOLID 25 TOTAL PER UNIT     2K   56200018
         AR    WKR7,WKR6                       UPDATE              2K   56600018
         STC   WKR7,MEST7                     UNIT CTR             2K   57000018
         CLI   BITCTR,FIVEVD        5 ERRORS IN 64K BLOCK          2K   57400018
         BNE   BLKCHAVD                 NO- LESS THAN FIVE         2K   57800018
         SR    WKR6,WKR6           CLEAR REG.6                          58700015
         IC    WKR6,BLKCTR         OBTAIN BLOCK FAILURE COUNTER         58800015
         SLL   WKR6,3                                                   58900015
BLKCHA3A LA    WKR7,BLKERR+2       STARTING ADR OF BLOCK RECORD         59000015
         AR    WKR6,WKR7           SET TO RIGHT LOCATION                59100015
         MVC   0(3,6),STARTA+1     FILL STARTING ADR INTO BLOCK RECORD  59200015
         A     WKR6,THREE          ADD THREE MORE LOCATION              59300015
         MVC   0(3,6),ENDA+1        FOR FILLING THE ENDING ADR.         59400015
         S     WKR6,FIVE           SHIFT BACK                           59500015
         OC    BITERR(2),BITERR+8    TO                                 59600015
         OC    BITERR(2),BITERR+16    FILL                              59700015
         OC    BITERR(2),BITERR+24    UP                                59800015
         OC    BITERR(2),BITERR+32      MORE                            59900015
         NI    BITERR,X'80'            CLEARUNWANTED BITS          2K   59930018
         TM    MEST6,X32            32-2K SOLID ERRORS             2K   59960018
         BNE   BLKCLEAR                NO -INTERMITTED BLOCK ERROR 2K   59990018
         OI     BITERR,TEN             SET SOLID BLOCK ERROR       2K   60020018
BLKCLEAR EQU     *                                                 2K   60050018
         NI    BITERR+1,X'FE'            BITS.                          60100015
         MVC   0(2,6),BITERR              DETAILS.                      60200015
         TM    BLKCTR,TWO              FIRST,SEC,OR THIRD BLOCK   37994 60210020
         BH    BLKEND                  NO-SKIP NEXT INSTRUCTIONS        60220020
         MVC   MEST64(N24),BLKERR      FILL IN REMEST BLOCK ENTRY 37994 60230020
         BAL   WKR10,UPDATCTR          UPDATE TOTAL ENTRIES CTR    2K   60240018
         SR    WKR7,WKR7               CLEAR REG                   2K   60250018
         IC    WKR7,MEST2              TO UPDATE                   2K   60260018
         LA    WKR7,ONE(WKR7)             BLOCK                    2K   60270018
         STC   WKR7,MEST2                 COUNTER                  2K   60280018
BLKCHAVD EQU   *                                                        60290020
         SR    WKR6,WKR6           CLEAR REG.6                          60300015
         IC    WKR6,BLKCTR         UP DATE                              60400015
         LA    WKR6,1(WKR6)         BLOCK RECORD                        60500015
         STC   WKR6,BLKCTR           COUNTER.                           60600015
BLKEND   EQU   *                                                        60650020
         XC    ERRKIND(2),ERRKIND  CLEAR ALL                            60700015
         NI    BITCTR,X'0'           ERROR RECORDS                      60800015
         NI    MEST6,ZERO           CLEAR SOLID 2K CTR             2K   60850018
         XC    BITERR(40),BITERR      OF BIT FAILURE.                   60900015
         LM    WKR6,WKR8,BLKREGS   RESTORE REGS.                        61000015
         BC    15,SCAN8            RETURN TO SCAN.                      61100015
         SPACE 1                                                        61200015
***            UNIT   ERROR   ANALYSIS                              *** 61300015
         SPACE 1                                                        61400015
UNITCHA  BAL   WKR10,DISAB         DISABLE MCI                          61500015
         CLI   BLKCTR,TWO                2 BLOCKERRS= UNIT ERROR   2K   62500018
         BL    UNITCHB             NO                              2K   63500018
         SPACE 1                                                        65100015
UNITCHA1 STM   WKR6,WKR8,BLKREGS   SAVE REGS. 6 TO 8                    65200015
         MVC   UNITERR+2(3),UNISTART+1  SETUP                           65300015
         MVC   UNITERR+5(3),UNIEND+1     ERROR                          65400015
         OC    BLKERR(2),BLKERR+8         REPORT                        65500015
         OC    BLKERR(2),BLKERR+16         FOR                          65600015
         MVC   UNITERR(2),BLKERR            COMMUNICATION AREA.         65700015
         LA    WKR7,MEST88        FILL UNIT ERROR                  2K   66000018
         MVC   ZERO(OCT,WKR7),UNITERR   REPORT  INTO COMMUNICATION 2K   66300018
         BAL   WKR10,UPDATCTR      UPDATE ENTRY COUNTER.                66600015
         MVI   MEST3,ONE          SET UNIT TO ONE                  2K   67200018
         OI    MEST88,X10                        PRIMARY UNIT           67800020
UNITCHB  EQU   *                                                   2K   68400018
         LM    WKR6,WKR8,BLKREGS   RESTORE REGS                    2K   69000018
         BC    15,SCAN10                RETURN TO SCAN.                 69600015
UNITCHVD EQU   *                                                   2K   69602018
         TM    MEST88,EIGHTY                SOLID MARK REG         2K   69604018
         BZ    EXIT                  NO-- REPORT UNIT ERROR        2K   69606018
         OI    NUMBYTE,N128          NUMBER OF 2K BLOCKS TO SET    2K   69608018
         MVC   DWADDR(FOUR),UNISTART   STARTING UNIT ADDR          2K   69610018
         SPACE 4                                                        69612018
*    THIS ROUTINE IS ENTERED VIA A SOLID FAILURE.  IF THE SYSTEM   2K   69614018
*   IS MULTI-PROCESSING THE FSSEMAP WILL BE SET BY THIS ROUTINE    2K   69616018
*    IN BOTH PREFIX AREAS.                                         2K   69618018
MAPSET   EQU   *                                                    2K  69620018
         TM    COMMSF,TEN          CHECK FOR MULTI-PROCESSING       2K  69622018
         BZ    MAPSET9             NO-RETURN TO MAIN BODY           2K  69624018
         OI    COMMSF,X04      SET SOLID INDIC FOR CALLING 2K      2K   69626018
         L     WKR4,DWADDR         ACTUAL ADDR                      2K  69628018
         SRL   WKR4,ONEONE         OF ERROR WILL                    2K  69630018
         SLL   WKR4,ONEONE         BE ON 2K BOUNDARY                2K  69632018
         LM    WKR1,WKR2,MAPMASK   MASKS USED TO SELECT MAP BITS    2K  69634018
         NR    WKR1,WKR4           SAVE LOW 2BITS OF ACTUAL ADDR    2K  69636018
         SRL   WKR1,XTEN           POSITION REG1 FOR BYTE IN MAP    2K  69638018
         SRL   WKR2,ZERO(WKR1)     POSITION REG2 FOR WITHIN BYTE    2K  69640018
         LA    WKR1,ZERO(WKR4)     CLEAR HI BYTE IN ADDR            2K  69642018
         SRL   WKR1,ONE3           GET DISPLACEMENT OF MAP BYTE     2K  69644018
         LA    WKR6,FSSEMAP(WKR1)  GET ADDR OF MAP BYTE IN PREFIX   2K  69646018
         STC   WKR2,DWADDR3       SAVE BYTE MASK                   2K   69648018
         OC    0(ONE,WKR6),DWADDR3   OR BYTE MASK INFSSEMAP        2K   69650018
         LR    WKR5,WKR6               FSSEMAP DISPLACEMENT        2K   69652018
         A     WKR5,PREFIX2                 FSSEMAP AREA           2K   69654018
         MVC   ZERO(ONE,WKR5),ZERO(WKR6)     SET OTHER MAP         2K   69656018
         CLI   NUMBYTE,TWO   SET ONLY ONE 2K BIT IN FSSEMAP        2K   69658018
         BE    MAPSET9             YES-RETURN                       2K  69660018
         CLI   NUMBYTE,N128          A SOLID UNIT ERR/R            2K   69662018
         BE    MAPSET8                 YES- SET 128                2K   69664018
MAPSET9  EQU   *                                                    2K  69666018
         TM    MEST89,TWO    A SOLID MARK REG IN A REGULAR SYS     2K   69668018
         BO    EXIT          YES- RETURN                           2K   69670018
         B     MEMFHSUM            FAILURE SUMMARY                  2K  69672018
MAPSET8  EQU   *                                                   2K   69674018
         N     WKR5,MASK            CLEAR MAP BYTR                 2K   69676018
         N     WKR6,MASK               TO UNIT LEVEL               2K   69678018
         MVI   ZERO(WKR5),SOLUNIT      SET EACH FSSEMAP            2K   69680018
         MVI   ZERO(WKR6),SOLUNIT          BYTE TO '55'            2K   69682018
         MVC   ONE(N64,WKR5),ZERO(WKR5)    SET ONE UNIT ERROR IN   2K   69684018
         MVC   ONE(N64,WKR6),ZERO(WKR6)         BOTH FSSEMAPS      2K   69686018
         B     EXIT                           RETURN               2K   69688018
         SPACE 2                                                        69700015
**********************************************************************  69800015
*                              E Q U A T E S                         *  69900015
**********************************************************************  70000015
         SPACE 2                                                        70100015
WKR0     EQU   0                                                        70200015
WKR1     EQU   1                                                        70300015
WKR2     EQU   2                                                        70400015
WKR3     EQU   3                                                        70500015
WKR4     EQU   4                                                        70600015
WKR5     EQU   5                                                        70700015
WKR6     EQU   6                                                        70800015
WKR7     EQU   7                                                        70900015
WKR8     EQU   8                                                        71000015
WKR9     EQU   9                                                        71100015
WKR10    EQU   10                                                       71200015
WKR11    EQU   11                                                       71300015
COMREG   EQU   12                                                       71400015
ASRNUCR  EQU   13                                                       71500015
NOTUSE   EQU   14                                                       71600015
BASEREG  EQU   15                                                       71700015
WDR0     EQU   0                                                        71800015
WDR2     EQU   2                                                        71900015
WDR4     EQU   4                                                        72000015
WDR6     EQU   6                                                        72100015
         SPACE 1                                                        72200015
*********************************************************************** 72300015
*              D A T A   C O N S T A N T S                            * 72400015
*********************************************************************** 72500015
         SPACE 1                                                        72600015
         CNOP  0,8                                                      72700015
ASRPSW   DC    XL8'0'                                                   72800015
OLPSWSAV DC    XL8'0'                                                   72900015
BITERR   DC    5D'0'               BIT ERRORS                           73000015
BLKERR   DC    D'0'          BLOCK ERROR                           2K   73060018
         DC    2D'0'                   FOR  SEC& THIRD BLOCKS ERR 37994 73090020
MASK     DC    X'FFFFFFE0'             MASK FOR LAST 5 BITS TO ZERO2K   73120018
UNITERR  DC    D'0'                  UNIT ERROR                         73200015
ONES     DC    8X'FF'                                                   73300015
CONT1    DC    8X'FF'                                                   73400015
ALL0S    DC    XL8'0'                                                   73500015
BUFFER   DC    D'0'                                                     73600015
SAVEDW   DC    XL8'0'                                                   73700015
NXTDW    DC    XL8'0'                                                   73800015
*   ADDRESS RANGES OF EACH BLOCK WITHIN ONE UNIT                   2K   73850018
TST1     DC    X'0000000000010000'                                      73900015
TST2     DC    X'0001000000020000'                                      74000015
TST3     DC    X'0002000000030000'                                      74100015
TST4     DC    X'0003000000040000'                                      74200015
         CNOP  0,8                                                      75500015
SAVE1    DC    F'0'                                                     75600015
REGSAV   DC    16F'0'                                                   75800015
REGSAVX  DC    9F'0'                                                    75900015
PATTERN1 DC    4X'55'                                                   76000015
INPSW    DC    X'00040000'                                              76100015
TSTADR   DC    F'0'                                                     76200015
TSTADR1  DC    XL4'0'                                                   76300015
UNIADR   DC    XL4'40000'     LENGTH OF ONE UNIT                   2K   76380018
UNISTART DC    F'0'           START AND END ADDRESSES OF THE       2K   76460018
UNIEND   DC    F'0'           UNIT WHICH CONTAINS THE PRIM ERROR   2K   76540018
STARTA   DC    F'0'      START ADDR  OF BLOCK                      2K   76620018
ENDA     DC    F'0'      END   ADDR  OF BLOCK                      2K   76700018
DWADDR   DC    F'0'                ACTUAL FAILING DW                2K  76780018
MAPMASK  DC    F'6144,64'          MASKS FOR BITS IN A MAP BYTE     2K  76860018
THREE    DC    F'3'                                                     77000015
FIVE     DC    F'5'                                                     77100015
BLKREGS  DC    3F'0'                                                    77300015
PRIMERAD DC    XL4'0'              PRIMARY ERROR ADDRESS                77600015
         CNOP  0,4                                                      77700015
* BRANCH INSTRUCTIONS USED IN ADVANCE EXERCISOR ROUTINE            2K   77750018
TSTR1    BC    15,ADVEX2                                                77800015
TSTR2    BC    15,ADVEX4                                                77900015
TSTR3    BC    15,ADVEX6                                                78000015
TSTR4    BC    15,ADVEX2                                                78100015
SINST    STD   2,0(4)                                                   78200015
         CNOP  0,4                                                      78300015
MKNEWS   DC    X'000000000F'                                            78400015
         CNOP  0,4                                                      78500015
MKINTA   DC    XL4'0'                                                   78600015
SECMCI   DC    XL4'0'                                                   78700015
         CNOP  0,4                                                      78800015
TSTTAB   DS    204C                                                     78900015
BITCTR   DC    X'0'      NUMBER OF BIT ERRORS                      2K   79000018
BLKCTR   DC    X'0'      NUMBER OF BLOCK ERRORS                    2K   79100018
MCICTR   DC    X'0'      NUMBER OF MACHINE CHECKS                  2K   79200018
ERRKIND  DC    X'0'                                                     79300015
ERRTYPE  DC    X'0'                                                     79400015
ERRBYTE  DC    X'0'      ACTUAL CONTENTS OF BAD BYTE               2K   79500018
BYTELOC  DC    X'0'                     LOCATION OF BAD BYTE.           79600015
INTDRP   DC    X'0'                                                     79700015
BASICS   DC    X'0'                                                     79800015
BASICF   DC    X'0'                                                     79900015
INTSUMB  DC    X'0'                                                     80000015
ADVF     DC    X'0'                                                     80100015
INTERMIT DC    X'0'                                                     80200015
BLKCHCTR DC    X'0'      NUMBER OF 64K(BLOCKS) TESTED              2K   80300018
FORPRTST DC    X'0'                FORCING PRIMARY ERROR TEST.          80400015
ADVPT    DC    X'0'      SWITCH USED IN ADVANCE EXER  ROUTINE      2K   80500018
PRIMERID DC    X'0'                                                     80700015
MARKCHK  DC    X'0'      IF ON, MARK CHECK FAILURE                 2K   81200018
NUMBYTE  DC    X'0'          NUMBER OF BLOCKS                      2K   81700018
***  MAINTENANCE  AREA  ***                                             81750021
MAINTID  DC    CL8'IGFASR2D'           CORE IDENTIFIER                  81800021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              81850021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 81900021
         CNOP  4,8                                                      82350015
         DC    C'ASR'                                                   82400015
TABLOCAT DC    X'01'                                                    82500015
         SPACE 1                                                        82600015
COMMON   DSECT                                                          82700015
         ASRMAC                                                         82800015
COMMST   EQU   REMEST                                                   82900015
BLKERR2  EQU   BLKERR+2                                            2K   82903018
ZERO     EQU   0                                                   2K   82906018
ONE      EQU   1                                                   2K   82909018
TWO      EQU   2                                                   2K   82912018
THREEVD  EQU   3                                                   2K   82915018
FOUR     EQU   4                                                   2K   82918018
FIVEVD   EQU   5                                                   2K   82921018
XTEN     EQU   10                                                   2K  82924018
EIGHTY   EQU   X'80'                                               2K   82927018
SOLUNIT  EQU   X'55'                                                2K  82930018
N64      EQU   32                                                  2K   82933018
N128     EQU   128                                                 2K   82936018
ONEONE   EQU   11                                                   2K  82939018
ONE3     EQU   13                                                   2K  82942018
X04      EQU   X'04'                                               2K   82945018
VD18     EQU   18                                                  2K   82948018
N24      EQU   24                                                       82950020
X10      EQU   X'10'                                                    82952020
X32      EQU   X'32'                                               2K   82954018
OCT      EQU   8                                                   2K   82957018
MEST2    EQU   REMEST+2                                            2K   82963018
MEST3    EQU   REMEST+3                                            2K   82966018
MEST6    EQU   REMEST+6                                            2K   82969018
MEST7    EQU   REMEST+7                                            2K   82972018
MEST64   EQU   REMEST+16                                      IE  42247 82981000
MEST88   EQU   REMEST+40                                      IE  42247 82984000
MEST89   EQU   REMEST+41                                      IE  42247 82987000
DWADDR3  EQU    DWADDR+3                                           2K   82990018
    EJECT                                                               83000000
CVTTAB   DSECT                                                          83100015
         CVT                                                            83200015
TALVD    EQU   REMEST+12                                            MP  83240017
NEXTTM   EQU   TM+2                                                 MP  83260017
         END                                                            83300015
