         LCLA  &LEV,&REL                                                00140021
&LEV     SETA  20                                                       00150021
&REL     SETA  21                                                       00160021
&REL&LEV TITLE 'IGFASR2K LEVEL &LEV MCH-STG RECONFIGURATION'            00170021
IGFASR2K CSECT                                                          00180018
         USING CVTDSECT,CVTREG                                          00270018
         USING COMMON,WKRG12                                            00360018
         USING TCBSECT,TCBREG           CURRENT TCB                     00450018
         USING IEAMPCVT,WKRG10                                          00540018
*********************************************************************** 00541018
*********************************************************************** 00542018
*                                                                     * 00543018
*TITLE 'IGFASR2K'                                                     * 00544018
*                                                                     * 00545018
*STATUS  CHANGE LEVEL 00                                              * 00546021
*                                                                     * 00547018
*FUNCTION/OPERATION: STORAGE RECONFIGURATION, ACTING IN A MULTI-      * 00548018
*   PROCESSING ENVIRONMENT, IS ENVOKED AFTER A SOLID ERROR HAS BEEN   * 00549018
*   FOUND IN DYNAMIC STORAGE AND FLAGGED IN THE FSSEMAP.  IF THE      * 00550018
*   ERROR IS IN UNALLOCATED STORAGE, THE NUMBER OF 2K BLOCKS          * 00551018
*   CONTAINING THE ERROR ARE REMOVED FROM THE SYSTEM FBQE CHAIN AND   * 00552018
*   MARKED OFFLINE IN THE FSSEMAP. FOR ALLOCATED STORAGE, THE         * 00553018
*   CORRESPONDING JSTCB FOR THE REGION IS FLAGGED FOR LATER ABENDING. * 00554018
*   A LATER MODULE WILL INSPECT THIS REGION AND MARK ANY AFFECTED     * 00555018
*   STORAGE OFFLINE IN THE FSSEMAP, INCORPORATING THE REST INTO THE   * 00556018
*   SYSTEM FBQE'S.  IF CONTROL BLOCKS FOR THE DATA SETS LIE IN        * 00557018
*   AFFECTED CORE, THE CORRESPONDING DEB'S ARE DEQUEUED TO PREVENT    * 00558018
*   MACHINE CHECK INTERRUPTIONS WHILE ABEND IS CLOSING DATA SETS.     * 00559018
*                                                                     * 00560018
*ENTRY POINT: IGFASR2K                                                * 00561018
*                                                                     * 00562018
*INPUT: FSSEMAP WITH SOLID STORAGE FAILURES FOUND BY IGFASR2D.        * 00563018
*                                                                     * 00564018
*OUTPUT: FSSEMAP UPDATED TO SHOW ALL SOLID ERRORS FOUND IN THE  SYSTEM* 00565018
*   FREE AREA NOW OFFLINE.  EACH JSTCB FOR AN AFFECTED REGION FLAGGED * 00566018
*   FOR ABEND. MESSAGES ARE ISSUED WITH THE FOLLOWING INFORMATION:THE * 00567018
*   BEGINING AND ENDING ADDRESS OF EACH RANGE OF SOLID STORAGE FAILURE* 00568018
*   THE JOBNAME OF THE JOB ABENDING BECAUSE OF A SOLID FAILURE IN ITS * 00569018
*   REGION. THE DATA SETS WHICH CANNOT BE CLOSED BECAUSE OF CONTROL   * 00570018
*   BLOCKS LYING IN THE AFFECTED AREA. THE MESSAGES ARE FORMATED AS   * 00571018
*   FOLLOWS:                                                            00572018
*      STORAGE DAMAGE(BEGINING AND ENDING ADDRESS) JOB ABEND(DS OPEN) * 00573018
*      JOBNAME(NAMES OF DATASETS OPEN),JOBNAME(...),...               * 00574018
*                                                                     * 00575018
*EXTERNAL ROUTINES: I/O PURGE                                         * 00576018
*                                                                     * 00577018
*EXITS-NORMAL: PASSES CONTROL VIA IGFNUC00 TO IGFASR20.               * 00578018
*     -ERROR-NONE                                                       00579018
*                                                                     * 00580018
*TABLES/WORK AREAS: STORAGE RECONFIGURATION OVERLAYS PART OF THE      * 00581018
*   RECORD ENTRY BUILD AREA IN THE COMMUNICATIONS AREA WITH THREE     * 00582018
*   TABLES:                                                           * 00583018
*        JOBSTPS TABLE-CONTAINS THE ADDRESS OF READER, WRITER, CURRENT* 00584018
*                      INITIATOR, AND JOBSTEP TCBS.                   * 00585018
*        STGRNGS TABLE-STARTING AND ENDING REGION ADDRESS             * 00586018
*                      CORRESPONDING TO EACH TCB IN JOBSTPS TABLE     * 00587018
*        DDNAME TABLE-DATA SET INFORMATION FILLED IN FOR EACH         * 00588018
*                     AFFECTED ENTRY IN JOBSTPS TABLE                 * 00589018
*   TWO TABLES (ADRTBL1 AND ADRTBL2) CONTAIN THE STARTING AND ENDING  * 00590018
*   ADDRESS FOR EACH RANGE CONTAINING A STORAGE FAILURES.  THIS IS    * 00591018
*   USED FOR MESSAGES                                                 * 00592018
*                                                                     * 00593018
*ATTRIBUTES-SERIALLY REUSABLE, PRIVILEGED, TRANSIENT                  * 00594018
*                                                                     * 00595018
*NOTES-IF THE JOBSTPS TABLE OVERFLOWS, AN OVERFLOW INDICATOR IS SET   * 00596018
*   IN THE HIGH ORDER BYTE OF THE FIRST ELEMENT OF THE TABLE.         * 00597018
*   PROCESSING IS TERMINATED WITH THE NORMAL EXIT PATH TAKEN. IF NOT  * 00598018
*   ENOUGH ROOM CAN BE FOUND FOR ABEND TO CLOSE DATA SETS, EACH DEB   * 00599018
*   IS DEQUED FOR THE CORRESPONDING TCB AND DESCENDENTS.              * 00600018
*                                                                     * 00601018
*********************************************************************** 00602018
*********************************************************************** 00603018
         IEAQFX                   65,MCH,1,GENCODE=NO                   00630018
CVTDSECT DSECT                                                          00720018
         CVT                                                            00810018
         MPCVT                                                          00900018
COMMON   DSECT                                                          00990018
         ASRMAC                                                         01080018
         ORG   RELABEL             POSITION JOBSTEP COMMUNICATOINS      01140018
*                                 TABLE INFO FOR IGFASR20               01200018
JOBSTPS  DC    25F'0'      JOBSTEP TABLE WITN 25 ENTRIES POSSIBLE       01260018
*        FIRST ENTRY...BYTE 1...(X'FF' IN FIRST IS OVERFLOW INDICATION) 01350018
*                               (X'AB'...WHERE A IS AND 8 FOR AFFECTED  01440018
*                                  JOBSTEPS (0 FOR UNAFFECTED JOBSTEPS, 01530018
*                                  AND B IS THE JOB ID...AND CORRELATES 01620018
*                                  TO THE ID IN THE STORAGE RANGE TBL.) 01710018
*                      BYTES 2 THRU 4...A POINTER TO THE JOBSTEP TCB    01800018
*        ADDITIONAL ENTRIES ARE THE SAME, EXCEPT THEY DO NOT GET THE    01890018
ENDTAB   EQU   *                   TABLE OVERFLOW INDICATION (X'FF')    01980018
*                                                                       02070018
STGRNGS  DC    100F'0'   STORAGE RANGE TABLE WITH 50 ENTRIES POSSIBLE   02160018
*        FIRST ENTRY...BYTE 1...SAME AS BYTE 1 OF JOBSTEP TABLE         02250018
*                      BYTES 2 THRU 4...STORAGE RANGE STARTING ADR.     02340018
*                      BYTE 5...UNUSED                                  02430018
*                      BYTES 6 THRU 8...STORAGE RANGE ENDING ADDRESS    02520018
*        ADDITIONAL ENTRIES ARE THE SAME (MINUS THE OVERFLOW IND.)      02610018
STREND   EQU   *                                                        02700018
        ORG   RECPULOG            POSITION TIOT TABLE                   02705018
DDNAME   DC    40F'0'             TIOT ENTRY TABLE                      02710018
*                                 WORDS 1 AND 2...JOB NAME              02715018
*                                 WORDS 3 AND 4...STEP NAME             02720018
*                                 WORD 5...                             02725018
*                                       BYTE 1...COUNT OF ENTRIES       02730018
*                                         (OTHERWISE SAME AS 1ST        02735018
*                                         BYTE OF WORD 6 ON.)           02740018
*                                      BYTES 2 THRU 4...PTR TO          02745018
*                                         TIOT ENTRY(+4=NAME)           02750018
*                                 WORDS 6 ON...                         02755018
*                                       BYTE 1...0, NOT CLOSEABLE       02760018
*                                            ...X'80', OK               02765018
*                                      BYTES 2 THRU 4...SAME ABOVE      02770018
TIOPTR   EQU   DDNAME+16           FIRST TIOT ENTRY PTR                 02775018
         ORG   RESPARE+8           POSITION SAVE AREA                   02780018
SAVE     DS    15F                 SAVE AREA                            02785018
*                   DESECT FOR TCB                                    * 02790018
*                                                                     * 02880018
TCBSECT  DSECT                                                          02970018
TCBRBP   DS    CL4                      POINTER TO TOP RB ON RB QUEUE   03060018
TCBPIE   DS    CL4                      ADDR OF PROGRAM INTERRUPT ELEMT 03150018
TCBDEB   DS    CL4                      ADDR OF LAST DEB ON DEB QUEUE   03240018
TCBTIO   DS    CL4                      ADDR OF TASK I/O TABLE          03330018
TCBCMP   DS    CL4                      TASK COMPLETION CODE            03420018
TCBTRN   DS    CL4                      ADDR OF TESTRAN CONTROL CORE    03510018
TCBNROC  DS    CL1                 ROLLOUT ELIGIBILITY                  03600018
TCBMSS   DS    CL3                 ADR OF LAST SPQE ON MSS QUEUE        03690018
TCBPKF   DS    CL1                      TASK PROTECTION KEY             03780018
TCBFLGS  DS    CL5                     TASK CONTROL FLAG BYTES          03870018
TCBLMP   DS    CL1                      TASK LIMIT PRIORITY             03960018
TCBDSP   DS    CL1                      TASK DISPATCHING PRIORITY       04050018
TCBLLS   DS    CL4                      PTR TO TASK LOAD LIST ELEMENT   04140018
TCBJLB   DS    CL4                      ADDRESS OF JOB LIBRARY DCB      04230018
TCBJPQ   DS    CL4                      PTR TO CONTENT DIRECTORY ENTRYS 04320018
TCBGRS   DS    CL64                     CONTENTS OF GENERAL REGISTER    04410018
TCBFSA   DS    CL4                      ADDRESS OF FIRST PP SAVE AREA   04500018
TCBTCB   DS    CL4                      PTR TO NEXT TCB ON READY QUEUE  04590018
TCBTME   DS    CL4                      ADDR OF TIMER QUE ELEMENT       04680018
TCBJSTCB DS    CL4                      ADDR OF JOBSTEP TCB             04770018
TCBNTC   DS    CL4                      ADDRESS OF NEXT SISTER TCB      04860018
TCBOTC   DS    CL4                      ADDRESS OF MOTHER(ORIGIN) TCB   04950018
TCBLTC   DS    CL4                      ADDRESS OF LAST DAUGHTER TCB    05040018
TCBIQE   DS    CL4                      ADDRESS OF IQE FOR EXTR         05130018
TCBECB   DS    CL4                      ADDR OF ECB TO POST AT COMPLETN 05220018
TCBSTAE  DS    CL4                      ENTRY ADDR OF STAE ROUTINE      05310018
TCBPQE   DS    CL4                      POINTER TO PQE FOR THE JOB STEP 05400018
TCBAQE   DS    CL4                      PTR TO LAST ALLOCATED QUE AREA  05490018
*                                                                     * 05580018
IGFASR2K CSECT                                                          05670018
         USING *,WKR15                                                  05760018
         MVI   COMLEV2K,LEVEL           SET LEVEL IND                   05850018
        B     START2K             GO TO BEGIN                           05940018
TTRTABLE DC  C'20'                TERMINATION ID                        06030018
        DC    XL4'0'              TTRL FOR IGFASR20                     06120018
        DC    XL2'0'              DELIMITER OF END                      06210018
START2K  EQU   *                                                        06300018
         STM   WKRG12,RETREG,SAV12 SAVE REGS 12, 13, 14                 06480018
         L     CVTREG,COMCVT       BASE FOR CVT                         06570018
         L     WKRG1,COMPRNT       ADDR OF NEXT BYTE IN BUFFER      MCS 06620018
         MVC   X0(X3,WKRG1),MSGID  MSG ID TO BUFFER                 MCS 06670018
         LA    WKRG1,X3(WKRG1)     UPDATE PTR                       MCS 06720018
         ST    WKRG1,COMPRNT       RESTORE IT                       MCS 06770018
         L     WKRG1,CVTNUCB                                            06790018
         ST    WKRG1,SQSENDA                                            06810018
         LA    JSTABL,JOBSTPS                                           06840018
*                                                                       06930018
         L     TCBREG,CVTHEAD      HIGHEST PRIORITY TASK                07020018
         L     TCBREG,TCBOTC       GET MOTHER (MASTER SCHEDULER)        07110018
         ST    TCBREG,MSTCB        SAVE TCBPTR FOR MASTER SCHEDULER     07200018
         L     PQEREG,TCBPQE       GET DUMMY PQE                        07290018
         L     PQEREG,PQEPTR(PQEREG)    ADR OF MS PQE                   07380018
         L     LOLIM,PARTBEG(PQEREG)    GET PART.BEGIN OF MS            07470018
         LA    LOLIM,0(LOLIM)      CLR HI-ORDER BYTE                    07560018
         ST    LOLIM,MSPTBEG      SAVE BEGINNING OF MS                  07650018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 07740018
*        JOBSTEP TCB TABLE CONSTRUCTOR                                  07830018
         LA    TBLCNT,TBLNUM       SET CONTROL FOR MAX ENTRIES          07920018
         XC    INDEX(JSLNGTH,JSTABL),INDEX(JSTABL) CLR OUT JOBSTEP TBL  08010018
         L     TCBREG,CVTHEAD      GET HIGHEST PRIORITY TCB             08100018
TCBNEXT  L     TCBREG,TCBTCB       SKIP DUMMY/NEXT TCB IN QUEUE         08190018
         LTR   TCBREG,TCBREG       CHK END OF TCB QUEUE                 08370018
         BZ    REGTBLA                  GO BLD TBL OF RGN ADDRS         08460018
         TM    TCBWIRE,TCBFSM           IS THIS A WIRED IN SYSTEM TASK  08550018
         BO    TCBNEXT             SKIP THIS TCB                        08640018
         L     JSTCBR,TCBJSTCB     GET JOBSTEP POINTER                  08730018
         CR    JSTCBR,TCBREG       IS THIS TCB A JOBSTEP                08820018
         BNE   TCBNEXT             SKIP THIS TCB                        08910018
         L     WKRG2,TCBOTC             GET TCB MOTHER FIELD            09000018
         CL    WKRG2,MSTCB              CHK IF MOM IS MS, L-SHAPE RTN   09090018
         BE    TCBNEXT             GO IF SO, DO NOT ENTER TCB           09180018
         L     WKRG2,GRANDMA(WKRG2)     GET GRANDMOTHER                 09190018
GRANDMA  EQU   X'84'                                                    09200018
         CL    WKRG2,MSTCB         AND CHK IF IT IS MS,                 09210018
         BE    CRNTCK              IF SO INITIATOR, GO CHK CURRENT      09220018
*                                                                       09270018
TCBCK1   EQU   *                                                        09310018
         ST    TCBREG,INDEX(JSTABL)     ENTER TCB ADDR IN TABLE         09380018
         LA    JSTABL,JSTELNG(JSTABL)   UPDATE POINTER TO TABLE         09450018
         BCT   TBLCNT,TCBNEXT      CONTINUE WITH NEXT TCB               09540018
*                                                                       09630018
         MVI   JOBSTPS,OVRFLOW     SET OVERFLOW-OF-TABLE INDICATOR      09720018
         B     EXIT                EXIT 2K STORAGE RECONFIGURATION      09810018
*                                                                       09900018
CRNTCK   EQU   *                   INITIATOR, NOW CHK IF CURRENT        09910018
         TM    TCBPKF,FOXFOX       CHK IF WTR....                       09920018
         BZ    TCBCK1              GO IF SO                             09930018
         CL    TCBREG,TCBOLD            CHK AGAINST OLD PTR             09940018
         BNE   TCBNEXT             AND DONT ENTER IF NOT                09950018
         B     TCBCK1              OTHERWISE DO ENTER                   09960018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 09990018
*              ORDER TCB ROUTINE                                        10080018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 12240018
REGTBLA  EQU   *                   NOW BUILD TABLE OF REGION ADDRESSES  12330018
         LA    WKRG1,JOBSTPS       GET JOBSTEP-TCB TABLE START          12420018
         LA    WKRG5,TBLNUM        AND MAX NUMBER OF ENTRIES            12510018
         LA    WKRG3,STGRNGS       START ADR OF STORAGE RANGE TABLE     12600018
         LA    WKRG2,ONE           CONTROL FOR INDICATORS OF ID         12690018
         LA    WKRG7,STREND        REG HAS TABLE END POINTER            12780018
REGTBLD  L     TCBREG,INDEX(WKRG1)      GET TCB ADDR                    12870018
         LTR   TCBREG,TCBREG       CHK END OF TCB-TABLE                 12960018
         BZ    REGEND              GO IF END                            13050018
         STC   WKRG2,INDEX(WKRG1)       SET STEP ID IN TCB TABLE        13140018
         L     PQEREG,TCBPQE       GET DUMMY PQE                        13230018
REGTBLB  L     PQEREG,PQEPTR(PQEREG)    GET REAL PQE ADR                13320018
         LTR   PQEREG,PQEREG            SEE IF ANY PARTITION ASSOCIATED 13410018
         BZ    REGTBLC             GO IF NONE                           13500018
         L     LOLIM,PARTBEG(PQEREG)    GET START ADR                   13590018
         L     HILIM,PARTLNG(PQEREG)         GET LENGTH OF PARTITION    13680018
         AR    HILIM,LOLIM         ADD TO GET END ADDRESS               13770018
         STM   LOLIM,HILIM,INDEX(WKRG3) SAVE RANGE ADRS IN TABLE        13860018
         STC   WKRG2,INDEX(WKRG3)       SET UP ID IN RANGE TABLE        13950018
         TM    PQEFLGS(PQEREG),BORROW  CHK IF PQE IS NOT OWNED          14040018
         BZ    REGTBLE             GO IF OWNED                          14130018
         OI    INDEX(WKRG3),NOTOWN      SET IND THAT REGION IS BORROWED 14220018
REGTBLE  EQU   *                                                        14310018
         LA    WKRG3,STGRNGL(WKRG3)     UPDATE POINTER TO TABLE         14400018
         CR    WKRG3,WKRG7         CHK STG RANGE TABLE FULL             14490018
         BL    REGTBLB             CONTINUE                             14580018
         B     REGEND              DONE, EXCEED TABLE CAPACITY          14670018
REGTBLC  EQU   *                                                        14760018
         LA    WKRG2,ONE(WKRG2)    STEP ID REGISTER                     14850018
         LA    WKRG1,JSTELNG(WKRG1) STEP TCB TABLE POINTER              14940018
         BCT   WKRG5,REGTBLD       CONTINUE STG RNG TBL CONSTRUCTION    15030018
*        FINISH TABLE, PERMIT 50 RANGES, 2 PER TCB                      15120018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 15210018
*                                                                       15300018
*              ORDER TABLE OF STORAGE RANGE ADDRESSES                   15390018
REGEND   EQU   *                                                        15480018
         LA    WKRG7,STGRNGS       GET NUMBER OF STG RNG TBL ENTRIES    15570018
         SR    WKRG3,WKRG7         DIFF. OF PTRS                        15660018
         SRL   WKRG3,LEN3               DIV. BY EIGHT                   15750018
         ST    WKRG3,STGRNUM       SAVE NUMBER OF RANGES IN TABLE       15840018
TBLORD   LA    WKRG1,STGRNGS       FIRST ENTRY PTR                      15930018
         LA    WKRG2,H8(WKRG1)          AND THE NEXT ENTRY PTR          16020018
         L     TBLCNT,STGRNUM           GET NUMBER OF ENTRIES           16110018
         LTR   TBLCNT,TBLCNT       CHK ZERO ENTRIES                     16200018
         BZ    RNGMSG                   YES, GO COMPUTE ADDRESSES       16250018
         BCTR  TBLCNT,INDEX             DECREMENT COUNT                 16300018
         LTR   TBLCNT,TBLCNT       CHK ZERO NOW                         16370018
         BZ    RNGMSG                   YES, GO COMPUTE ADDRESSES       16420018
TBLORDA  EQU   *                                                        16470018
         L     WKRG5,INDEX(WKRG1)       GET FIRST ENTRY                 16560018
         L     WKRG6,INDEX(WKRG2)       AND NEXT ENTRY                  16650018
         LA    WKRG5,INDEX(WKRG5)       ZERO HI-ORDER BYTE              16740018
         LA    WKRG6,INDEX(WKRG6)       ZERO HI-ORDER BYTE              16830018
         CR    WKRG5,WKRG6         COMPARE IF SWAP IS NECESSARY         16920018
         BH    TBLSWAP             YES                                  17010018
         LR    WKRG1,WKRG2         LOAD NEXT ENTRY POINTER              17100018
         LA    WKRG2,STGRNGL(WKRG2)  AND ONE FOLLOWING                  17190018
         BCT   TBLCNT,TBLORDA      CONTINUE                             17280018
         B     RNGMSG                   YES, GO COMPUTE ADDRESSES       17370018
*                                                                       17460018
TBLSWAP  EQU   *                   SWAP ENTRIES IN RNG TABLE            17550018
         LM    WKRG7,WKRG8,INDEX(WKRG1)   GET FIRST                     17640018
         MVC   INDEX(H8,WKRG1),INDEX(WKRG2)  MOVE SECOND TO FIRST       17730018
         STM   WKRG7,WKRG8,INDEX(WKRG2)   AND FIRST TO SECOND           17820018
         B     TBLORD              RESTART ORDERING                     17910018
*                                                                       18000018
TBLEND   EQU   *              FINISHED ORDERING STORAGE RANGE TABLE     18090018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 18180018
GAPCHKR  L     TBLCNT,STGRNUM      GET NUMBER OF RANGE ENTRIES          18450018
         LA    WKRG1,STPPTR             PTR TO FIRST COMP ADR (-4)      18540018
         LA    WKRG2,STGRNGS       GET POINTER TO NEXT  COMPARE ADR     18630018
         L     WKRG10,CVTMPCVT     GET PTR TO SEC CVT                   18720018
         L     WKRG4,CVTGOV       AND PTR TO GOVRFLB                    18810018
         L     WKRG4,PQEPTR(WKRG4) GET POINTER TO DUMMY PQE             18840018
         L     WKRG4,PQEPTR(WKRG4) GET POINTER TO       PQE             18870018
         LA    WKRG4,INDEX(WKRG4)       CLEAR HI-ORDER BYTE             18900018
         ST    WKRG4,INDEX(WKRG4)       PQE ADDR IN FORWARD AND         18930018
         ST    WKRG4,DISPL(WKRG4)       BACKWARD PTR ON FBQE CHAIN      18960018
         ST    WKRG4,PQEADR        SAVE PTR TO BACK CHAIN               18990018
         ST    WKRG4,LASFPTR       SAVE AS LAST POINTER                 19080018
GAPCHK   L     LOLIM,DISPL(WKRG1)       LOAD END-OF-RANGE ADDR          19170018
         LA    LOLIM,INDEX(LOLIM)       ZERO HI-ORDER BYTE              19260018
         L     HILIM,INDEX(WKRG2)       LOAD START-OF-RANGE ADDR        19350018
         LA    HILIM,INDEX(HILIM)       ZERO HI-ORDER BYTE              19440018
         CR    LOLIM,HILIM         CHECK GAP EXISTS                     19530018
         BL    GAPFND              GO IF FIND GAP                       19620018
GAPCON   EQU   *                                                        19710018
         LR    WKRG1,WKRG2         UPDATE POINTERS TO                   19800018
         LA    WKRG2,STGRNGL(WKRG2) ENTRIES IN STG RANGE TABLE          19890018
         BCT   TBLCNT,GAPCHK       CONTINUE CHECK                       19980018
         L     HILIM,MSPTBEG      GET MASTER SCHEDULER ADR              20070018
         L     LOLIM,DISPL(WKRG1)       GET LAST ADDR FROM STG RNG TBL  20160018
         LA    LOLIM,INDEX(LOLIM)       ZERO HI-ORDER BYTE              20250018
GAPCK2   CR    LOLIM,HILIM         CHK GAP.NEAR MS AREA                 20340018
         BE    GAPEND              FINISH GAP CHECK                     20430018
*                                                                       20520018
GAPFND   EQU   *                   FOUND A GAP, NOW ADD TO NEW FBQE CH. 20610018
         BAL   RETREG,FSENT1      GO SEARCH FSSEMAP FOR RENGE           20700018
         LA    RETREG,GAPCON       RETURN HERE WHEN GAP PROCESSED       20790018
         B     GAPSIZE1            CONTINUE                             20880018
         LA    RETREG,FSENT3       SET UP TO RETURN TO FSSEMAP CHECK    20970018
         EX    WKRG7,OIINST      OR BOTH BITS ON                        21150018
GAPSIZE1 EQU   *                                                        21240018
         LR    WKRG7,LOLIMR            LOAD BAD ADDRESS POINTER         21330018
         SR    WKRG7,LOLIM         GET SIZE OF FBQE                     21420018
         LTR   WKRG7,WKRG7         CHK IF ZERO SIZE FBQE WOULD EXIST    21510018
         BZ    GAPCK1              GO IF YES, NOT SET ONE UP            21600018
         ST    WKRG7,H8(LOLIM)     PUT SIZE IN FBQE                     21690018
         L     WKRG7,LASFPTR       GET ADR OF LAST FBQE                 21780018
         MVC   INDEX(DISPL,LOLIM),PQEADR  BACK CHAIN FBQE TO PQE        21870018
         ST    LOLIM,INDEX(WKRG7)       PUT PTR TO THIS FBQE            21960018
         ST    WKRG7,H4(LOLIM)     PUT BACK POINTER IN FBQE             22050018
         ST    LOLIM,LASFPTR       SAVE LAST FBQE ADR                   22140018
         L     WKRG7,PQEADR        GET ADR OF PQE                       22230018
         MVC   DISPL(DISPL,WKRG7),LASFPTR PQE FLD HAS PTR TO LAST FBQE  22300018
         CL    HILIM,MSPTBEG       CHK PROCESSING NEAR MASTER SCHED.    22370018
        BE    GAPSIZE2            YES, DONE                             22420018
GAPSIZE3 LR    LOLIM,LOLIMR        NO, UPDATE POINTERS                  22490018
         B     GAPCK1              AND CHK IF GAP PROCESSED             22530018
GAPSIZE2 EQU   *                                                        22570018
         LA    WKRG0,FSENT3        CHK IF GAP DONE PROCESSING           22610018
         CR    WKRG0,RETREG        DONE SIGNALED BY RETURRN             22650018
         BNE   GAPSIZE3            TO BAL+4, YES                        22690018
         CR    LOLIMR,HILIM        OR POINTERS EQUAL                    22730018
         BNE   GAPSIZE3            GO IF NOT                            22770018
GAPSIZE4 LM    WKRG11,RETREG,FSSAVE   RESTORE REGS                      22810018
         B     GAPEND              EXIT GAPCHKER                        22850018
*                                                                       22890018
*                                                                       23040018
GAPCK1   LA    LOLIM,H2048(LOLIM)  ADJUST LOWER LIMIT BY 2K             23130018
         CR    LOLIM,HILIM         CHK IF GAP PROCESSED                 23220018
         BL    FSENT3              GO IF NOT                            23310018
         C     HILIM,MSPTBEG       IS PROCESSED, NOW CHK IF GAP         23400018
*                                  IS ADJACENT TO THE MS AREA           23490018
         BE    GAPSIZE4            YES, TRULY FINISHED                  23540018
         LM    WKRG11,RETREG,FSSAVE  RESTORE REGS                       23590018
         B     GAPCON              CONTINUE CHKING GAP                  23640018
*                                                                       23690018
*                                                                       23760018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 23850018
*                                  STORAGE RANGE COMPARED VS FSSEMAP    23940018
FSENT1   EQU   *                   ENTER WITH REGS AS FOLLOWS...        24030018
         STM   WKRG11,RETREG,FSSAVE   LOLIM AT LOW END OF RANGE         24120018
FSENT4   EQU   *                                                        24160018
         CR    LOLIM,HILIM             HAS END OF DYNAMIC STORAGE       24170018
*                                      BEEN REACHED?                    24180018
         BNL   EXFSCK1                 IF SO,RETURN TO CALLER           24190018
         LR    LOLIMR,LOLIM             HILIM AT HI END OF RANGE        24210018
*                                 RETREG IS RETURN REG                  24300018
*                                  EXIT WITH LOLIMR AT FIRST BAD ADR    24390018
*                                       (OR NEXT 2K BLOCK TO BE CHKED)  24480018
FSADADJ  LR    WKRG12,LOLIMR      ADR OF 2K BLOCK TO CHK                24570018
         SRL   WKRG12,S2048       DIV. BY 2048                          24660018
         SR    WKRG13,WKRG13            ZERO QUARTER BYTE PTR           24750018
         SRDL  WKRG12,QTRPTR      INSERT QTR PTR, OTHER REG IS          24840018
         LA    WKRG12,FSSEMAP(WKRG12)   BYTE PTR (MULT. OF 8K)          24930018
         SRL   WKRG13,ADJUST      ADJUST TO 2-BIT PTR                   25290018
         LA    WKRG7,MASK          GET X'C0' MASK                       25380018
         SRL   WKRG7,INDEX(WKRG13)      AND ADJUST PER 2-BIT PTR        25470018
FSCHK    EX    WKRG7,FSTMCHK      DO TEST OF FSSEMAP, WKRG7 HAS MASK    25560018
         BNZ   EXFSCK                   EXIT AS BAD CORE FOUND          25650018
*                                                                       25740018
FSENT2   LA    LOLIMR,H2048(LOLIMR)     UPDATE CURRENT 2K PTR           25830018
         CR    LOLIMR,HILIM        CHK DONE SEARCH OF ADR RANGE         25920018
         BNL   EXFSCK1             DONE, EXIT SEARCH ROUTINE            26010018
*                                                                       26100018
         SRL   WKRG7,QTRPTR       ADJUST QUARTER PTR                    26190018
         LTR   WKRG7,WKRG7        CHK ZERO                              26280018
         BNZ   FSCHK               GO IF NOT                            26370018
         LA    WKRG7,MASK         NEW MASK AND                          26460018
         LA    WKRG12,ONE(WKRG12) INCREMENT TO NEXT 8K BYTE CONSIDER    26550018
         B     FSCHK               CONTINUE CHK                         26640018
*                                                                       26730018
EXFSCK   EQU   *                                                        26820018
         LA    RETREG,H8(RETREG)  UPDATE TO BAD-CORE-FOUND POINT        27000018
         BR    RETREG             RETURN                                27090018
*                                                                       27180018
EXFSCK1   LM   WKRG11,RETREG,FSSAVE  GET SAVED REGS                     27270018
         BR    RETREG             RETURN TO GOOD-CORE PONT              27360018
*                                                                       27450018
FSENT3   L     RETREG,RETSAVE           RESTORE RETURN REG              27540018
         B     FSENT4              AND CONTINUE                         27630018
*                                                                       27720018
FSENT5   L     RETREG,RETSAVE           RESTORE RETURN REG              27740018
         B     FSENT2                   GO CONTINUE PROCESSING          27760018
*                                                                       27780018
GAPEND   EQU   *                  END OF GAPCHECKER                     27810018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27900018
*        ROUTINE TO CHECK ANY REGIONS AFFECTED BY STORAGE FAILURE       27990018
         L     TBLCNT,STGRNUM      GET NUMBER OF RANGE ENTIES           28170018
         LA    WKRG1,STGRNGS      PTR TO FIRST RANGE                    28260018
         XC    RNGAFF(ONE),RNGAFF       ZERO IND. OF JOBS AFFECTED      28350018
REGCK1   EQU   *                                                        28440018
         L     LOLIM,INDEX(WKRG1)       GET LOW LIMIT OF RANGE          28530018
         LA    LOLIM,INDEX(LOLIM)       ZERO HIGH-ORDER BYTE            28620018
         L     HILIM,DISPL(WKRG1)       GET HI LIMIT OF RANGE           28710018
         LA    HILIM,INDEX(HILIM)       ZERO HI-ORDER BYTE              28800018
         BAL   RETREG,FSENT1       GO CHK ANY BAD CORE WITHIN RANGE     28890018
         B     REGOK              RETURN HERE IF OKAY                   28980018
         NOP   NEXT                                                     29070018
NEXT     L     WKRG12,SAV12             RESTORE REG 12                  29160018
         OI    RNGAFF,JOBBAD      SET JOB AFFECTED INDICATOR            29250018
         OI    INDEX(WKRG1),RNGBAD      INDICATE STG RNG IS AFFECTED    29340018
REGOK    LA    WKRG1,STGRNGL(WKRG1) UPDATE STORAGE RNG TABLE PTR        29430018
         BCT   TBLCNT,REGCK1      CONTINUE STG RANGE TBLE CHK           29520018
         B     ENDTBL                                                   29560018
RNGMSG   EQU   *    THIS ROUTINE COMPUTES THE ADDRESSES OF THE STORAGE  29880018
*                   RANGE VARIED OUT                                    29970018
         XC    ADRTBL1(CLEAR),ADRTBL1   CLEAR ADDR TABLES               30060018
         LA    WKRG2,ONE                SET UP CNT CNTRL FOR BLOCKS     30150018
         LA    WKRG1,ADRTBL1       RANGE PTR                            30240018
         LM    LOLIM,HILIM,SQSENDA SQS END AND MS BEGIN                 30330018
         ST    LOLIM,STARTA        SAVE START ADR                       30420018
         BAL   RETREG,FSENT1     GO CHECK ANY BAD CORE                  30510018
         B     ENDCOM            END OF DYNAMIC AREA CHECK              30600018
        B     *+4                 SHOULD NEVER GET HERE                 30690018
         EX    WKRG7,FSTMCHK            SEE IF STG ALREADY OFFLINE      30720018
         BO    FSENT5                   YES, GO GET NEXT 2K BLOCK       30750018
*                                                                       30780018
         C     LOLIMR,STARTA       CHK IF START BLOCK IS BAD            30810018
         BNE   RNGMSG1             GO IF NOT                            30840018
*                                                                       30870018
         ST    LOLIMR,INDEX(WKRG1)      SAVE FIRST ADR OF BAD RANGE     30900018
         B     RNGMSG2             GO SAVE COUNT OF BAD BLOCKS          30930018
*                                                                       30960018
RNGMSG1  CR    LOLIMR,LOLIM        CHK IF BLOCK IS NEXT SEQUENTIAL      30990018
         BE    RNGMSG2             YES, DO NOT SAVE ADR, JUST COUNT     31020018
         C     LOLIM,SQSENDA            CHK IF FIRST PASS               31050018
         BE    RNGMSG3             BYPASS LA IF STARTING                31080018
         LA    WKRG1,DISPL(WKRG1)       CHANGE RNG TABLE PTR            31110018
RNGMSG3  EQU   *                                                        31140018
         ST    LOLIMR,INDEX(WKRG1)      SAVE BAD RANGE START ADR        31170018
         ST    LOLIMR,STARTA       SAVE THIS NEW START ADR              31200018
         LA    WKRG2,ONE                INITIALIZE                      31260018
         LR    LOLIM,LOLIMR        RESET PTR TO NEXT SEQUENTIAL BLOCK   31320018
RNGMSG2  STC   WKRG2,INDEX(WKRG1)       STORE COUNT OF BAD BLOCKS       31420018
         LA    WKRG2,ONE(WKRG2)         UPDATE COUNT OF BAD BLOCKS      31520018
         LA    LOLIM,H2048(LOLIM)    UPDATE LOW LIMIT TO NEXT BLK       31770018
         B     FSENT3              RETURN TO CHK OTHER BLOCKS           31860018
*                                                                       31950018
ENDCOM   EQU   *                                                        32040018
         LA    WKRG1,ADRTBL1     POSITION TO START OF TABLES            32130018
ENDC1    L     WKRG5,INDEX(WKRG1)       GET FIRST ADR                   32220018
         LTR   WKRG5,WKRG5       CHK IF NONE                            32310018
         BZ    ENDC2             GO IF NONE LEFT                        32400018
*                                                                       32490018
         SR    WKRG4,WKRG4       ZERO CTL REG                           32580018
         SLDL  WKRG4,H8                 SHIFT COUNT OF 2K BLKS INTO CTL 32680018
         SRL   WKRG5,H8                 REPOSITION START ADDRESS        32780018
         MH    WKRG4,X2048         COMPUTE LENGTH OF BLOCK              32940018
         AR    WKRG4,WKRG5         TO COMPUTE END OF RANGE              33030018
         ST    WKRG4,TBLDISP(WKRG1)     STORE STOP ADR                  33130018
         LA    WKRG1,DISPL(WKRG1)       UPDATE TABLE POINTER            33230018
         B     ENDC1             GET NEXT ENTRY                         33390018
*                                                                       33480018
ENDC2    EQU   *                                                        33570018
         LA    WKRG9,ADRTBL1     POINT TO ADR TABLE                     33660018
         LA    WKRG8,ADRTBL2       PTR TO OTHER ADR TBL                 33750018
CNVRT3   L     WKRG2,COMPRNT       ADDR OF NEXT BYTE IN BUFFER      MCS 33840018
         LR    WKRG1,WKRG9       LOAD IN WORK                           33930018
         L     WKRG3,INDEX(WKRG1)       CHECK IF ALL OF                 34020018
         LTR   WKRG3,WKRG3       RANGES ARE CONVERTED                   34110018
         BZ    TBLEND                                                   34200018
*                                                                       34290018
*                                                                       34560018
CNVRT    EQU   *                                                        34650018
         MVI   X0(WKRG2),X6B       MOVE RANGE INDENTIFIER           MCS 34680018
         LA    WKRG2,X1(WKRG2)     UPDATE PTR                       MCS 34710018
         LA    WKRG7,2           MSG CTL, ADR1 THEN ADR2                34740018
CNVRT1   LA    WKRG3,3           COUNT OF BYTES TO CONVERT              34830018
         SR    WKRG4,WKRG4       HOUSEKEEP                              34920018
CNVRT2   IC    WKRG4,1(WKRG1)    GET 2 DIGITS                           35010018
         SRDL  WKRG4,4                                                  35100018
         IC    WKRG6,NTBLCV(WKRG4) CONVERT FIRST DIGIT                  35190018
         STC   WKRG6,0(WKRG2)    STORE FIRST                            35280018
         SR    WKRG4,WKRG4       HOUSEKEEP                              35370018
         SLDL  WKRG4,4                                                  35460018
         IC    WKRG6,NTBLCV(WKRG4) CONVERT SECOND DIGIT                 35550018
         STC   WKRG6,1(WKRG2)    STORE SECOND                           35640018
         LA    WKRG2,2(WKRG2)    UPDATE STORE CTL                       35730018
         LA    WKRG1,1(WKRG1)    UPDATE FETCH CTL                       35820018
         BCT   WKRG3,CNVRT2      LOOP FOR ONE ADDRESS                   35910018
*                                                                       36000018
         LR    WKRG1,WKRG8                                              36090018
         MVI   X0(WKRG2),X60       MOVE DELIMITER                   MCS 36130018
         LA    WKRG2,1(WKRG2)    UPDATE MESSAGE POSITION                36180018
         BCT   WKRG7,CNVRT1      GO DO SECOND ADR                       36270018
         S     WKRG2,VONE                                               36310018
*                                                                       36360018
         LA    WKRG8,4(WKRG8)    UPDATE ADR TABLE POINTER               36630018
         LA    WKRG9,4(WKRG9)    UPDATE ADR TABLE POINTER               36720018
         ST    WKRG2,COMPRNT       UPDATE PTR TO BUFFER             MCS 36920018
         B     CNVRT3            GO DO NEXT PAIR OF ADRS                37260018
*                                                                       37350018
ENDTBL   EQU   *                                                        37440018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 37530018
         TM    RNGAFF,JOBBAD      CHK ANY RANGES FOUND AFFECTED         37620018
         BZ    EXIT                     PREPARE TO LEAVE                37710018
*        ROUTINE TO CHECK ANY JOBS TO BE SCHEDULED FOR PURGE            37800018
         L     TBLCNT,STGRNUM      LOAD CTL OF RANGES TO PROCESS        37890018
         LA    LOLIM,STGRNGS      AND PTR TO RANGE TABLE                37980018
*                                                                       38070018
JOBAFF   EQU   *                                                        38160018
         LA    WKRG1,JOBSTPS       GET PTR TO JOBSTEP TABLE             38250018
         TM    INDEX(LOLIM),RNGBAD      CHK RANGE MARKED BAD            38340018
         BZ    JOBAF1             NOT AFFECTED, UPDATE RANGE PTR        38430018
JOBAF4   LA    WKRG4,TBLNUM       MAXIMUM NUMBER OF JOBS                38520018
JOBAF3   L     WKRG2,HEX1F         GET MASK TO LOAD JOB ID ONLY         38610018
         N     WKRG2,INDEX(LOLIM)       AND LOAD IT                     38700018
         SRL   WKRG2,H24           SHIFT TO RIGHT END                   38790018
         STC   WKRG2,JOBID         SAVE IT                              38880018
JOBAF7   EQU   *                                                        38920018
         CLC   JOBID(ONE),INDEX(WKRG1)  CHECH TABLE ENTRY               38990018
         BE    JOBAF2             GO IF THIS JOB AFFECTED               39060018
         LA    WKRG1,JSTELNG(WKRG1) UPDATE JOBSTEP PTR TO NEXT ENTRY    39150018
         BCT   WKRG4,JOBAF7            CONTINUE, MUST BE ONE OF THEM    39240018
         B     JOBAF1              OR ANOTHER RANGE MARKED IT AFFECTED  39330018
JOBAF2   EQU   *                                                        39420018
         TM    INDEX(LOLIM),NOTOWN      CHK IF REGION NOT OWNED         39510018
         BO    JOBAF5              GO IF NOT WONED                      39600018
         OI    INDEX(WKRG1),JOBBAD      OWNED-SET JOB BAD INDICATOR     39650018
         L     WKRG5,ZERO(WKRG1)   GET PTR TO TCB                       39700018
         L     WKRG5,DUMPQE(WKRG5)      GET DUMMY PQE PTR               39706018
DUMPQE   EQU   X'98'                                                    39712018
         L     WKRG5,PQEPTR(WKRG5)     GET REAL PQE PTR                 39720018
         TM    PQEFLGS(WKRG5),ROLLOUT  CHK JOB ROLLED OUT               39730018
ROLLOUT  EQU   X'40'                                                    39740018
         BZ    JOBAF1              GO IF NOT                            39750018
         OI    PQEFLGS(WKRG5),NOTRIN   SET RORI INHIBIT BIT             39760018
NOTRIN   EQU   16                      ROLLIN NOT TO PROCEED, BAD STO   39770018
JOBAF1   LA    LOLIM,STGRNGL(LOLIM) UPDATE RNG PTR TO NEXT              39780018
         BCT   TBLCNT,JOBAFF       CONTINUE CHK OF RANGES               39870018
         B     JOBCKND             EXIT, DONE                           39960018
JOBAF5   EQU   *                                                        40050018
         OI    INDEX(WKRG1),NOTOWN      SET NOT OWNED INDICATOR         40140018
         B     JOBAF1              CONTINUE CHECK                       40230018
*                                                                       40320018
JOBCKND  EQU   *    AT THIS POINT ALL RANGES AND RESPECTIVE JOBSTEPS    40410018
*                   ARE FLAGGED, AS AFFECTED.                           40500018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 40590018
         LA    TBLCNT,TBLNUM      LOAD TABLE COUNT                      40680018
         LA    WKRG1,JOBSTPS      PTR TO JOBSTEP TABLE                  40770018
JOBPURG  EQU   *                                                        40860018
         L     WKRG7,INDEX(WKRG1)       CHK IF TCB PTR                  40950018
         LTR   WKRG7,WKRG7       IS IN USE                              41040018
         BZ    ABENDMM             NO, END OF CHK                       41130018
         TM    INDEX(WKRG1),JOBBAD      CHK IF AFFECTED                 41220018
         BO    SVCPUR             GO IF YES                             41310018
JOBPG1   LA    WKRG1,JSTELNG(WKRG1) UPDATE PTR TO NEXT ENTRY            41400018
         BCT   TBLCNT,JOBPURG     CONTINUE CHK OF AFFECTED JOBSTEPS     41490018
         B     ABENDMM             DONE, CONTINUE                       41580018
*                                                                       41670018
SVCPUR   STM   WKRG1,TBLCNT,FSSAVE INTERFACE WITH SVC PURGE TO          41760018
         LA    WKRG7,SCANTREE      ELIMINATE CURRENT AND PENDING I/O    41850018
         L     WKRG4,INDEX(WKRG1)       FOR AFFECTED JOBSTP  & DESCEND  41940018
         BALR  MAINLINE,WKRG7      GO TO SCANTREE                       42030018
         B     LM                 RESTORE REGS AND CONT. JOBS CHK       42120018
         LA    WKRG1,PARMLIST           LOAD ADDR OF PARMLIST IN GPR1   42210018
         L     CVTREG,COMCVT       START OF CVT                         42300018
*        L     WKRG4,0(WKRG3)           GET NEW OLD POINTER             42390018
*        L     WKRG4,4(WKRG4)           GET CURRENT TCB                 42480018
         L     WKRG6,CVTABEND      GET ABEND SEC. CVT PTR               42570018
         L     WKRG6,K32(WKRG6)         GET PTR TO SVC PURGE            42660018
SVCPRG   EQU   *                                                        42750018
         STM   WKRG0,WKRG15,SAVE       SAVE REGS                        42760018
         ST   WKRG12,ACT174        SAVE BASE REG                        42770018
ACT174   EQU   X'174'                                                   42780018
         LR    WKRG5,WKRG4             TEMP SVC PURGE FIX               42790018
         SH    WKRG5,HEX1C             TEMP SVC PURGE FIX               42800018
        L     WKRG7,TCBRBP            GET RB ADR                        42810018
         NI    SUPMOD(WKRG7),H6    SET SUPERVISOR MODE                  42820018
SUPMOD   EQU   17                  DISPLACEMENT FOR M ASK               42830018
H6       EQU   6                                                        42840018
         ST    TCB,H4(WKRG1)            PUT ADDR OF TCB IN PARM LIST    42930018
         BALR  RETREG,WKRG6             BRANCH TO SVC PURGE  RTN        43020018
         L    WKRG12,ACT174        RESTORE BASE REG                     43080018
         LM    WKRG0,WKRG15,SAVE   RESTORE REGS                         43140018
         BR    RET                      GET TCB ADDR                    43200018
LM       LM    WKRG1,TBLCNT,FSSAVE CONTINUE SEEKING JOBSTEPS AFFECTED   43290018
         B     JOBPG1             HERE                                  43380018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 48240018
*                                                                       48330018
*                                                                       48420018
*  DATA SET NAME TABLE...USED TO DEDUCE WHICH DATA SETS CAN BE          48510018
*        PROCESSED BY ABEND CLOSE AND WHICH WOULD RESULT IN             48600018
*        MACHINE CHECK BECAUSE OF A SOLID STORAGE MALFUNCTION           48690018
*        IN THE AREA OF THE CONTROL INFORMATION.                        48780018
*                                 TIOT, AND DATA SET NAME DERIVATION    48870018
DDNAM0   EQU   *                                                        48960018
         ST    WKRG2,STPPTR        JOBSTEP PTR                          49050018
         L     WKRG1,TCBTIO       GET PTR TO TIOT FROM THIS TCB         49140018
         SR    WKRG2,WKRG2        CLEAR ACCUMULATOR REG                 49230018
         LA    WKRG3,DDNAME       PTR TO NAME TABLE                     49320018
         LA    WKRG7,DDEND         GET PTR TO END OF TABLE              49380018
DDEND    EQU   DDNAME+160          END OF DD NAME TABLE                 49440018
*                                                                       49500018
         SR    WKRG5,WKRG5        CLEAR LENGTH FIELD REG                49590018
         MVC   0(16,WKRG3),0(WKRG1)     MOVE JOB AND STEP NAMES         49680018
         LA    WKRG3,16(WKRG3)    UPDATE POINTER                        49770018
         LA    WKRG1,H24(WKRG1)         UPDATE TIOT PTR                 49860018
DDNAM1   IC    WKRG5,INDEX(WKRG1)       GET LENGTH OF ENTRY             49950018
         LTR   WKRG5,WKRG5        CHK LAST ENTY                         50040018
         BZ    DDNAM2             GO IF SO                              50130018
*                                                                       50220018
         LA    WKRG2,ONE(WKRG2)         UPDATE COUNT OF ENTRIES         50310018
         ST    WKRG1,INDEX(WKRG3)       SAVE POINTER TO ENTRY           50400018
         XC    INDEX(ONE,WKRG3),INDEX(WKRG3)  CLEAR HI-BYTE             50490018
         AR    WKRG1,WKRG5         UPDATE TIOT PTR BY LENGTH OF ENTRY   50580018
         LA    WKRG3,DISPL(WKRG3)       UPDATE TABLE PTR                50670018
         CR    WKRG7,WKRG3         CHK EXCEED TABLE SIZE                50760018
         BH    DDNAM1              CONTINUE                             50850018
*                                                                       50940018
DDNAM2   EQU   *                                                        51030018
         STC   WKRG2,TIOPTR             SAVE NUMBER OF ENTRIES          51120018
DDNAM3   L     WKRG2,STPPTR        RESTORE POINTER TO JOBSTEP           51210018
         TM    TIOPTR,FOXFOX            CHK ANY ENTRIES                 51240018
         BZ    NXTJS01             GO IF NONE                           51270018
         B     SPINSPCT            GO PRECURSE CLOSE ROUTE              51300018
*        THE FOLLOWING CODE WILL DETERMINE IF THE CLOSE FUNCTION        51390018
*   CAN BE PERFORMED. IF THE CLOSE FUNCTION CAN BE PERFORMED THIS       51480018
*   ROUTINE WILL NEXT DETERMINE IF ANY OF THE DATA SET INFORMATION(IE   51570018
*   DCBS,IOBS AND BUFFER SPACE) LIES WITHIN DAMAGED CORE. IF ANY OF     51660018
*   THESE BLOCKS LIE WITHIN DAMAGED CORE THE ASSOCIATED DEB WILL BE     51750018
*   DEQUEUED FROM THE DEB QUEUE OFF THE TCB. IF ALL THE DEBS ARE THUS   51840018
*   REMOVED FROM THE QUEUE THE TCBDEB FIELD WILL BE ZEROED AND NO DATA  51930018
*   SETS WILL BE CLOSED.                                                52020018
*                                                                       52110018
ABENDMM  EQU   *                                                        52200018
         LA    WKRG2,JOBSTPS      GET BEGIN OF TCB TABLE                52290018
NXTJSTCB EQU   *                                                        52380018
         L     TCB,INDEX(WKRG2)         SET UP TCB BASE REG             52470018
         TM    INDEX(WKRG2),JOBBAD      CHK JOB AFFECTED                52560018
         BO    DDNAM0              YES, BRANCH                          52650018
NXTJS01  LA    WKRG2,DISPL(WKRG2)       PT TO NEXT TABLE ENTRY          52740018
         LA    WKRG1,ENDTAB        CHK END OF JOBS TABLE                52830018
         CR    WKRG1,WKRG2                                              52920018
         BE    EXIT                GO IF EXCEED TABLE                   53010018
         L     WKRG1,INDEX(WKRG2)       GET TCB ADDR                    53100018
         LTR   WKRG1,WKRG1                                              53190018
         BZ    EXIT                GO IF DONE                           53280018
         B     NXTJSTCB            GO PROCESS NEXT JOBSTEP              53370018
*                                                                       53460018
NXTJS02  L     WKRG2,STPPTR        GET JOBSTEP PTR                      53550018
         B     NXTJS01             CHK NEXT STEP AFFECTED               53640018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 53730018
*                                                                       53820018
*        SEE IF THERE IS 512 AVAILABLE BYTES IN SUBPOOL 252             53910018
*                                                                       54000018
SPINSPCT EQU   *                                                        54090018
*                                                                       54180018
*                                                                       54270018
*                                                                       54360018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54450018
         XC    SPFLGS(DISPL),SPFLGS     ZERO WORD FOR SUBPOOL RTN       54451018
         L     TCBREG,INDEX(WKRG2)      GET JOBSTEP TCB                 54452018
SPSEARCH LA    RET,SCANTREE             CHECK TCB AND DESCENDENTS       54453018
TCBFIND  BALR  MAINLINE,RET             GET LOWEST TCB ON CHAIN         54454018
         B     SPTEST                   WHEN JOBSTEP TCB IS FOUND       54455018
         L     WKRG2,TCBNROC            GET ADDR OF SPQE                54456018
SPHERE   LA    WKRG2,INDEX(WKRG2)       HOUSEKEEP ADDR                  54457018
         LTR   WKRG2,WKRG2              IS THERE A SUBPOOL PRESENT      54458018
         BNZ   FOLLOW                   GO CHECK THIS SPQE              54459018
         L     WKRG2,SPFLGS             GET SAVED SPQE ADDR             54460018
         LA    WKRG2,INDEX(WKRG2)       CLEAR HI ORDER BYTE             54461018
         LTR   WKRG2,WKRG2              IS ANOTHER SPQE PRESENT         54462018
         BZ    TCBFIND                  NO, GET ANOTHER TCB             54463018
         XC    SPSAVE(LEN3),SPSAVE      CLEAR OUT FOR NEXT TIME         54464018
FOLLOW   L     WKRG5,DISPL(WKRG2)       DQE ADDR OR OWNING SPQE         54465018
         LA    WKRG5,INDEX(WKRG5)       HOUSEKEEP ADDR                  54466018
         TM    INDEX(WKRG2),SPSHARE     IS THIS SUBPOOL SHARED          54467018
         BO    SPOWNER                  YES, GET OWNER SPQE             54468018
         LTR   WKRG5,WKRG5              IS A DQE PRESENT                54469018
         BZ    NXTSPQE                  NO, GET NEXT SPQE               54470018
         TM    SPFLGS,FLGS              IS THIS SECOND TIME             54471018
         BO    TAKE                     YES, GET CORE FROM THIS SUBPOOL 54472018
         OI    SPFLGS,FLG1              SHOW A SUBPOOL WAS FOUND        54473018
         TM    DISPL(WKRG2),SPID        IS IT SUBPOOL 252               54474018
         BNO   NXTSPQE                  NO, GO GET NEXT SPQE            54475018
TAKE     L     LOLIM,INDEX(WKRG5)       GET FQE PTR                     54476018
         LA    LOLIM,INDEX(LOLIM)       HOUSEKEEP ADDR                  54477018
         LTR   LOLIM,LOLIM              IS THERE A FQE                  54478018
         BZ    STEAL                    NO, GO MAKE ONE                 54479018
         L     HILIM,DISPL(LOLIM)       GET SIZE OF FREE AREA           54480018
         LA    HILIM,INDEX(HILIM)       HOUSEKEEP                       54481018
         AR    HILIM,LOLIM              COMPUTE ENDING ADDR             54482018
         NI    SPFLGS,SWOFF             SHOW COMING FROM HERE           54483018
         LA    WKRG3,CBCHECK            IF 2K GOOD, GO TO NEXT TEST     54484018
SPSAFE   EQU   *                                                        54485018
         BAL   RETREG,FSENT1            GO CHECK FOR BAD CORE           54486018
SAVEFQE  ST    LOLIM,INDEX(WKRG5)       SET UP FQE PTR TO GOOD ADDR     54487018
         B     FINISH                                                   54488018
         LM    WKRG11,RETREG,FSSAVE     GET SAVED REGS                  54489018
         SR    LOLIMR,LOLIM             WAS 2K PROCESSED BEFORE BAD     54490018
         LTR   LOLIMR,LOLIMR                 CORE WAS FOUND             54491018
         BNZ   SAVEFQE                  YES, GO SAVE - NO MORE NEEDED   54492018
         LA    LOLIM,H2048(LOLIM)       NO, UPDATE BY 2K                54493018
         CR    LOLIM,HILIM              END OF AREA REACHED?            54494018
         BL    SPSAFE                   NO, GO CHECK NEW 2K             54495018
         TM    SPFLGS,ATSW              HAS DQE AREA BEEN TESTED        54496018
         BZ    STEAL                    NO, GO CREATE FQE               54497018
NXTSPQE  L     WKRG2,INDEX(WKRG2)       GET ADDR OF NEXT SPQE           54498018
         B     SPHERE                   GO TEST IT                      54499018
SPOWNER  MVC   SPSAVE(LEN3),ONE(WKRG2)  SAVE ADDR OF NEXT SPQE          54500018
         LR    WKRG2,WKRG5              GET OWNING SPQE                 54501018
         B     SPHERE                   GO TEST THIS SPQE               54502018
SPTEST   NI    SPFLGS,SWOFF             TURN OFF SWITCH                 54503018
         CLI   SPFLGS,FLG1              WAS A SUBPOOL FOUND             54504018
         BNE   LEAVE                    NO, CAN'T CLOSE DATA SETS       54505018
         OI    SPFLGS,FLGS              PREPARE FOR SECOND TIME         54506018
         B     SPSEARCH                 GO BACK AND CHECK FQE           54507018
STEAL    LM    LOLIM,HILIM,H8(WKRG5)    GET ADDR AND SIZE OF DQE AREA   54508018
         LA    LOLIM,INDEX(LOLIM)       HOUSEKEEP                       54509018
         LA    HILIM,INDEX(HILIM)                 ADDRESSES             54510018
         AR    HILIM,LOLIM              GET ENDING ADDRESS              54511018
         OI    SPFLGS,ATSW              SHOW TESTING DQE                54512018
         BAL   WKRG3,SPSAFE             GO SEE IF IN AFFECTED CORE      54513018
         XC    INDEX(H8,LOLIM),INDEX(LOLIM)  CLEAR AREA FOR FQE         54514018
         LA    WKRG6,H2048              GET 2K SIZE                     54515018
         ST    WKRG6,DISPL(LOLIM)       SET UP OF NEW FQE               54516018
         B     CBCHECK                                                  54517018
FINISH   BR    WKRG3                    RETURN TO CALLER                54518018
LEAVE    OI    SPFLGS,NOCLOSE           SHOW NO ROOM FOR CLOSE          54519018
NOCLOSE  EQU   X'FF'                                                    54520018
CBCHECK  EQU   *                                                        54521018
*        SEE IF DCBS,IOBS OR BUFFRS LIE IN DAMAGED STORAGE              54540018
*                                                                       54630018
*        ENTER HERE AFTER SUBPOOL INSPECTION                            54720018
         LA    RET,SCANTREE                                             54810018
         L     WKRG2,STPPTR            REFRESH REG WITH TBL PTR         54850018
         L     TCBREG,INDEX(WKRG2)      GET JOBSTEP TCB                 54920018
VALCHK   EQU   *                                                        54990018
         BALR  MAINLINE,RET       GO GET LOWEST TASK IN STEP            55080018
         B     DSMSGS              GO PREPARE DS NAME MESSAGES          55170018
         L     DEB,TCBDEB         GET PTR TO DEB QUEUE                  55260018
         LTR   DEB,DEB                  IS POINTER 0                    55350018
         BZ    VALCHK              YEA, RETURN AND GET TCB              55440018
NXTDCB   TM    SPFLGS,NOCLOSE           CAN DATA SETS BE CLOSED         55470018
         BO    DEQUED                   NO, GO REMOVE DEB               55500018
         L     DCB,DEBDCBAD(DEB)        GET DCB ADDR                    55560018
         LA    DCB,INDEX(DCB)           CLEAR FLAG BYTES                55630018
         LR    BEG,DCB                  GET BEGINNING ADDR              55710018
         LA    END,K96(DCB)             CALCULATE END ADDR              55800018
         BAL   RETREG,FSENT1      GO CHK STRRAGE RANGE OK               55890018
         B     AMSEARCH            RETURN HERE IF OK                    55980018
         NOP   DEQUED                   SHOULD NEVER GET HERE           56070018
         B     DEQUED              RETURN HERE IF BAD                   56160018
*                                                                       56250018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 56340018
*        THIS ROUTINE WILL DETERMINE THE ACCESS METHOD BEING USED       56430018
*  AND THE DISPLACEMENT OF THE IOB ADDR  WITHIN THE DCB.                56520018
*                                                                       56610018
AMSEARCH EQU   *                                                        56700018
         TM    DCBDSORG(DCB),SAMPAM     TEST FOR BPAM,BSAM,QSAM         56790018
         BZ    AMTEST                   NOT BPAM,BSAM,QSAM              56880018
         TM    DCBOPTCD(DCB),CHAINSCD   IS CHAINED SCHED BEING USED     56970018
         BO    ONEIOB                   YES,TAKE BRANCH                 57060018
         SR    INDEX,INDEX              SET INDEX FOR IOB TO ZERO       57100018
IOBDCB   EQU   68                                                       57140018
         L     IOB,IOBDCB(DCB)          GET IOB ADDR FROM DCB           57180018
FIRSIOB  TM    ZERO(IOB),ONE       CHK FIRST IOB                        57250018
         BO    IOBPROC                  GO CHECK IT IF SO               57260018
         L     IOB,ZERO(IOB)       BET NEXT ON CHAIN                    57270018
         B     FIRSIOB             (TO START PROCESSING)                57280018
AMTEST   TM    GAMORG(DCB),GAM          IS AM=GAM                       57380018
         BZ    AMTEST2                  NO, GO CHECK FOR BDAM           57480018
         LA    INDEX,GAMNDX             INDEX FOR IOB DISPLACEMENT      57580018
GAMNDX   EQU   40                       POSITION FOR NEXT IOB ADDR      57680018
*  FOR GAM THE DISPLACEMENT IS FROM THE PREFIX                          57780018
         L     IOB,K28(DCB)             GET IOB ADDR FROM DCB           57880018
DECREASE A     IOB,MINUS4               GET PREFIX ADDR                 57980018
         B     IOBPROC                  GO CHECK IF IOB IN BAD CORE     58080018
AMTEST2  TM    DCBDSORG(DCB),BDAM       IS AM=BDAM                      58180018
         BZ    AMTEST3                  NO, GO TRY ANOTHER              58280018
         LA    INDEX,BDAMNDX                                            58380018
         B     GETIOB                   GO GET IOB ADDR FROM DCB        58480018
AMTEST3  EQU   *                                                        58580018
         TM    DCBDSORG(DCB),ISQTTAM    IS IT ISAM,QTAM,TAM             58680018
ISQTTAM  EQU   X'9C'                                                    58780018
         BM    GETNXTDB                 YES, GET NEXT DEB               58880018
ONEIOB   EQU   *                        REMAINING AM HAVE ONE IOB       58980018
         OI    TCBSTAE,SINGIOB          INDICATE ONE IOB                59080018
GETIOB   L     IOB,K28(DCB)             GET IOB ADDR FROM TCB           59180018
IOBPROC  EQU   *                                                        59280018
         LR    BEG,IOB                  GET BEG ADDR OF IOB             59380018
         LA    END,IOBEND(IOB)          GET END ADDR OF IOB             59480018
IOBEND   EQU   96                                                       59580018
         BAL   RETREG,FSENT1            GO CHK IF LIES IN BAD CORE      59680018
         B     BITTEST                  RTN HERE IF RANGE IS OK         59780018
         NOP   DEQUED                   SHOULD NEVER GET HERE           59880018
         B     DEQUED                   RETURN HERE IF BAD              59980018
*                                                                       60080018
*                    GET NEXT IOB                                       60180018
*                                                                       60280018
BITTEST  EQU   *                                                        60380018
         TM    TCBSTAE,SINGIOB                                          60480018
         BO    PRGTNXDB                 GO TURN OFF SWITCH              60580018
NXTIOB   AR    IOB,INDEX                                                60680018
         L     WKREG,INDEX(IOB)         GET NEXT IOB ADDR               60780018
         LA    WKREG,INDEX(WKREG)                                       60880018
         LTR   WKREG,WKREG                                              60980018
         BZ    TSTBUFRS                 NO, GO CHK FOR BAD BUFFERS      61080018
         CR    IOB,WKREG                                                61180018
         BE    TSTBUFRS                 NO, GO CHK FOR BAD BUFFERS      61280018
         LR    IOB,WKREG                USE NEW IOB ADDR FOR PROCESSING 61380018
         TM    GAMORG(DCB),GAM                                          61480018
         BO    DECREASE                 YES, GO GET PREFIX ADDR         61580018
         TM    DCBDSORG(DCB),BDAM       AM=BDAM                         61680018
         BZ    IOBPROC                  NO, GO CHK IOB                  61780018
         CLI   BDAMNDX(IOB),ZERO        IS IOB AVAILABLE                61880018
         BZ    IOBPROC                  GO CHK IOB                      61980018
         B     NXTIOB                   GO GET NEXT IOB ON CHAIN        62080018
PRGTNXDB EQU   *                                                        63270018
         NI    TCBSTAE,SINGOFF          TURN OFF SINGIOB FLAG           63360018
*        B     TSTBUFRS            GO CHK BUFFERS                       63450018
*                                                                       63540018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 63630018
*        THIS ROUTINE WILL CHECK TO SEE IF THE ASSOCIATED IO BUFFERS    63720018
*        LIE IN DAMAGED STORAGE.                                        63810018
*                                                                       63900018
TSTBUFRS EQU   *                                                        63990018
         TM    GAMORG(DCB),GAM          IS AM=GAM                       64080018
         BO    RECORDDD           YES, BRANCH                           64170018
*                                                                       64440018
*        THE FOLLOWING BUFFER HANDLING IS FOR BTAM,ISAM,BDAM,BSAM,BPAM  64530018
*        AND QSAM.                                                      64620018
         SR    BUFNO,BUFNO                                              64710018
         IC    BUFNO,DCBBUFNO(DCB)      GET # OF BUFFERS FROM DCB       64800018
         LTR   BUFNO,BUFNO              ANY BUFFERS                     64980018
         BZ    RECORDDD                 NO,UPDATE OUTPUT TABLE          65070018
         LH    END,DCBBUFL(DCB)         GET BUFFER LENGTH               65160018
         MR    BEG,BUFNO                CALCULATE LENGTH OF BUFFER POOL 65340018
         L     BEG,DCBBUFNO(DCB)        GET ADDR OF BUFFER POOL CB      65430018
         LA    BEG,INDEX(BEG)           CLEAR HIGH-ORDER BYTE           65520018
         AR    END,BEG                  CALCULATE END ADDR OF BPCB      65610018
         BAL   RETREG,FSENT1      GO CHK STORAGE RANGE IS OI            65700018
         B     RECORDDD            RETURN HERE IF OKAY                  65790018
         NOP   DEQUED                   SHOULD NEVER GET HERE           65880018
         B     DEQUED              RETURN HERE IF BAD                   65970018
*                                                                       66060018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 66150018
RECORDDD EQU   *                                                        66240018
         LH    WKRG7,DCBTIOT(DCB)       GET TIOT ENTRY DISPLACEMENT     66330018
         L     WKRG1,JSTCBA       GET JOBSTEP TCG ADR                   66420018
         L WKRG1,NTRYTIOT(WKRG1)        GET ADDR OF TIOT ENTRY          66480018
NTRYTIOT EQU   X'0C'                                                    66540018
         AR    WKRG1,WKRG7        GET ADR OF TIOT ENTRY                 66600018
         LA    WKRG7,TIOPTR                                             66690018
         SR    WKRG2,WKRG2        ZERO ENTRY CTL REG                    66780018
         IC    WKRG2,INDEX(WKRG7)       GET NUMB. OF TIOT ENTRIES       66840018
         LTR   WKRG2,WKRG2         CHK IF NO ENTRIES                    66900018
         BZ    GETNXTDB            GO IF NONE                           66930018
RECORD1  MVC   KCMPFLD(LEN3),ONE(WKRG7) MOVE PTR TO COMPARE FIELD       66990018
         CL    WKRG1,CMPFLD       COMPARE ENTRY ADR WITH PTR            67050018
         BE    RECORD2            FOUND IT                              67140018
         LA    WKRG7,DISPL(WKRG7)       GET ANOTHER PTR AND TRY         67230018
         BCT   WKRG2,RECORD1      FOR FIT                               67320018
         B     GETNXTDB            FORGET IT, GER NEXT DEB              67410018
RECORD2  OI    INDEX(WKRG7),CANCLOS     SET CAN CLOSE INDICATOR         67500018
         B     GETNXTDB           GO TO NEXT DEB                        67590018
*                                                                       67680018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 67770018
*        THIS SUBROUTINE WILL DEQUE THE DEB GIVEN AS INPUT FROM         67860018
*  THE TCBDEB FIELD OF THE TCB IT IS CHAIUD OFF                         67950018
DEQUED   EQU   *                                                        68040018
         LM    WKRG11,RETREG,FSSAVE  GET SAVED REGS                     68130018
         L     WKREG,DEBTCBAD(DEB)      GET TCB ADDR                    68220018
         LR    PREVDEB,WKREG            GET TCB ADDR                    68310018
         L     WKREG,H8(WKREG)          GET PTR TO FIRST DEB            68340018
         CR    WKREG,DEB           CHK IF FIRST DEB IS THIS ONE         68370018
         BNE   COMPDEB             GO IF NOT                            68400018
         XC    TCBDEB(H4),TCBDEB        OTHERWISE CLEAR DEB PTR         68430018
         B     VALCHK              AND EXIT                             68460018
COMPDEB  EQU   *                                                        68490018
         CR    WKREG,DEB                IS THIS THE DEB TO BE DEQUEUED  68580018
         BE    DEQDEB                   YES BRANCH                      68670018
         LR    PREVDEB,WKREG                                            68760018
         L     WKREG,DEBDEBAD(WKREG)    GET PTR TO NEXT DEB             68850018
         LA    WKREG,INDEX(WKREG)       CLEAR FLAG BYTES                68940018
         B     COMPDEB             CONTINUE COMPARE                     69030018
DEQDEB   EQU   *                                                        69120018
         MVC   WKRG5(LEN3,PREVDEB),WKRG5(WKREG)    DEQ DEB              69210018
GETNXTDB L     DEB,DEBDEBAD(DEB)        POINT TO NEXT DEB               69300018
         LA    DEB,INDEX(DEB)           CLEAR FLAG BYTE                 69390018
         LTR   DEB,DEB                  IS THERE ANOTHER DEB            69480018
         BZ    VALCHK                   GET NEXT TCB                    69570018
         B     NXTDCB             GET NEXT DCB                          69660018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 69750018
OUTPTMSG EQU   *                                                        69840018
DSMSGS   EQU   *                                                        69930018
         L     WKRG1,COMPRNT       ADDR OF NEXT BYTE IN BUFFER      MCS 70030018
         MVI   X0(WKRG1),X5C       JOB NAME IDENTIFIER              MCS 70130018
         MVC   X1(X8,WKRG1),DDNAME MOVE JOB NAME TO MSG BUFFER      MCS 70230018
         LA    WKRG1,X9(WKRG1)     UPDATE PTR                       MCS 70330018
         SR    WKRG0,WKRG0         CLR CNTL                             70470018
         IC    WKRG0,TIOPTR        GET CNT OF TIOT ENTRIES              70560018
         LTR   WKRG0,WKRG0         CHK IF ZERO                          70650018
         BZ    OUTP3               GO IF YES                            70740018
*                                                                       70830018
         SLL   WKRG0,TBLNUM             ZERO DS-CLOSEABLE-BIT           70920018
         SRL   WKRG0,TBLNUM             REPOSITION                      71010018
         LA    WKRG3,TIOPTR        PUT PTR AT FIRST ENTRY POINTER       71100018
OUTP1    TM    0(WKRG3),CANCLOS    CHKIF ENTRY IS CLOSEABLE             71190018
         BO    OUTP2               GO IF IS, DO NOT PRINT IT            71280018
*                                                                       71370018
         L     WKRG7,0(WKRG3)      GET PTR TO TIOT ENTRY                71460018
         MVI   X0(WKRG1),X61             DATA SET IDENTIFIER        MCS 71560018
         MVC   X1(X8,WKRG1),DISPL(WKRG7) DATA SET NAME TO BUFFER    MCS 71660018
         LA    WKRG1,X9(WKRG1)     UPDATE PTR                       MCS 71760018
OUTP2    LA    WKRG3,4(WKRG3)      UPDATE PTR TO ENTRY POINTERS         71910018
         BCT   WKRG0,OUTP1         CONTINUE CHK                         72000018
*                                                                       72090018
OUTP3    EQU   *                                                        72180018
         ST    WKRG1,COMPRNT       UPDATE PTR IN BUFFER             MCS 72280018
         B     NXTJS02             CHK OTHER JOBSTEP TCBS               72450018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   72540018
EXIT     EQU   *                                                        72630018
         LM    WKRG12,RETREG,SAV12 RESTORE REGS 12, 13, 14              72720018
         MVC   COMNUC(H4),CALL202       MOVE TTRL FOR 20                74160018
         LH     WKRG1,CALL20      GET  ID FOR 20                        74250018
         L     WKRG13,SAV13      GET RETURN REGISTER                    74340018
         BR    WKRG13             EXIT FOR NUCLEUS                      74430018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 74520018
SCANTREE EQU   *                                                        74610018
         LA    TCB,INDEX(TCB)           ZERO HI-ORDER BYTE              74700018
         ST    TCB,JSTCBA          SAVE JOBSTEP TCB PTR                 74790018
SCAN1    L     WKRG7,TCBLTC      CHK DAUGHTER TASK                      74880018
         LTR   WKRG7,WKRG7       IS THERE A DAUGHTER                    74970018
         BZ    NODAUGHT          NO THERE IS NOT                        75060018
         L     TCB,TCBLTC        YES, PUT IN PTR                        75150018
         B     SCAN1             GO GET HER DAUGHTER                    75240018
*                                                                       75330018
NODAUGHT EQU   *                                                        75420018
         BAL   RET,SUBCOM               TEST IF TASK COMPLETE           75510018
TRYSIS   EQU   *                                                        75600018
         L     WKRG7,TCBNTC      CHK A SISTER TASK                      75690018
         LTR   WKRG7,WKRG7       EXISTS                                 75780018
         BZ    GTMOTHER          NO SISTER, GO TO MOTHER                75870018
         L     TCB,TCBNTC        YES, CHK HER OUT                       75960018
         B     SUBCOM                   TEST IF SELECTED TASK COMPLETE  76050018
GTMOTHER EQU   *                                                        76140018
         L     WKRG7,TCBJSTCB      CHK IF THIS IS THE JOBSTEP           76230018
         C     WKRG7,JSTCBA        AGAINST SAVED VALUE                  76320018
        BNE   MOTHER              GO GET MOTHER, THEN                   76410018
         LA    RET,LSTIME               PREPARE FOR LAST TIME ENTRY     76500018
         B     SUBCOM              PREPARE TO EXIT TASK SELECT ROUTINE  76590018
LSTIME   EQU   *                                                        76680018
         BR    MAINLINE                 FINAL RETURN                    76770018
MOTHER   EQU   *                                                        76860018
         L     TCB,TCBOTC               GET MOTHER                      76950018
SUBCOM   EQU   *                                                        77040018
         TM    TCBDONE,TCBFC            IS THE SUBTASK COMPLETE         77130018
         BCR   ONE,RET                  YES, GET ANOTHER TCB            77220018
         B     DISPL(MAINLINE)          RETURN TO CALLER                77310018
*                                                                       77400018
*        REGISTER EQUATES                                               77490018
*                                                                       77580018
DEB      EQU   6                  DEB POINTER                           77670018
DCB      EQU   5                        DCB OFF DEB BEING PROCESSED     77760018
BEG      EQU   8                        BEGN ADDR OF AREA TO BE CHECKED 77850018
END      EQU   9                        END  ADDR OF AREA TO BE CHECKED 77940018
WKREG    EQU   7                  UTILITY REG                           78030018
PREVDEB  EQU   10                       ADDR OF PREVIOUS DEB            78120018
INDEX    EQU   0                        INDEX VALUE TO POINT TO IOB     78210018
IOB      EQU   3                  IOB PTR                               78300018
BUFNO    EQU   1                  NO. OF BUFFERS                        78390018
*              CONSTANTS                                                78480018
*                                                                       78570018
CANCLOS  EQU   X'80'               CAN-CLOSE INDICATOR                  78660018
DEBDCBAD EQU   24                       DCB POINTER IN DEB              78750018
DEBTCBAD EQU   0                        ADDR OF TCB                     78840018
DEBDEBAD EQU   4                        PTR TO NEXT DEB                 78930018
DCBDSORG EQU   26                       DISP TO DCBDSORG FIELD          79020018
SAMPAM   EQU   X'42'                    AM IS BSAM,BPAM OR QSAM         79110018
DCBOPTCD EQU   52                       DISP TO DCBOPTCD FIELD          79200018
CHAINSCD EQU   X'20'                    CHAINED SCHED WITH BSAM,BPAM OR 79290018
*                                       QSAM                            79380018
DISPL    EQU   4                   DISPLACEMANT OF TIOEDDNM IN ENTRY    79650018
MSGID    DC    C'227 '                                                  79740018
EIGHT    DC    H'8'                     ADDITION CONSTANT               79830018
GAM      EQU   X'80'                    GRAPHICS AM MASK                80010018
BDAM     EQU   X'20'                    BDAM MASK                       80100018
SINGIOB  EQU   X'01'                    MASK TO TELL IF AM HAS ONE IOB  80370018
DCBBUFNO EQU   20                       NO OF BUFFERS                   80460018
DCBBUFL  EQU   24                       LENGTH OF BUFFER                80550018
HEX1C    DC    XL2'001C'           RB LINK FIELD DISPLACEMENT           80680018
LEVEL    EQU   X'&LEV'                                                  80720021
FOXFOX   EQU   X'FF'               MASK                                 80760018
WKRG1    EQU   1                  WORK REG                              80820018
ONE      EQU   1                   VALUE OF ONE                         80910018
JSTABL   EQU   1                   PTR TO JOBSTEP TABLE                 81000018
WKRG2    EQU   2                  WORK REG                              81090018
QTRPTR   EQU   2                   AMT TO SHIFT FOR QUARTER-BYTE PTR    81180018
WKRG3    EQU   3                  WORK REG                              81270018
TBLCNT   EQU   3         REGISTER FOR COUNT CONTROL OF TABLE ENTRIES    81360018
WKRG4    EQU   4                  WORK R                                81450018
TCBREG   EQU   4                  TCB PTR REG                           81540018
TCB      EQU   4                   TCB PTR                              81630018
JSTELNG  EQU   4         LENGTH OF EACH ENTRY IN JOBSTEP TABLE          81720018
WKRG5    EQU   5                  WORK R                                81810018
PQEREG   EQU   6                  PQE PTR REG                           81900018
WKRG6    EQU   6                  WORK R                                81990018
WKRG7    EQU   7                                                        82080018
JSTCBR   EQU   7         REGISTER USED FOR POINTER IN JOBSTEP TABLE     82170018
WKRG8    EQU   8                  WORK R                                82260018
STGRNGL  EQU   8                   STORAGE RANGE TABLE ENTRY LENGTH     82350018
PQEPTR   EQU   8         DISPLACEMENT IN PQE FOR PQE POINTER            82440018
H8       EQU   8                  CONSTANT OF 8                         82530018
MAINLINE EQU   9                   RETURN REGISTER                      82620018
WKRG9    EQU   9                  WORK R                                82710018
WKRG10   EQU   10                 WORK R                                82800018
LOLIMR   EQU   10                  ADR BLK PTR CURRENTLY ACTIVE         82890018
WKRG11   EQU   11                 WORK R                                82980018
RET      EQU   13                LINKREG                                83070018
S2048    EQU   11                  DIVISION FACTOR FOR 2048             83160018
CVTREG   EQU   11                                                       83250018
WKRG12   EQU   12                 WORK R                                83340018
WKRG13   EQU   13                 WORK REG                              83430018
RETREG   EQU   14                                                       83520018
WKR15    EQU   15                  BASE REG                             83610018
PARTLNG  EQU   20        DISPLACEMENT IN PQE FOR PARTITION LENGTH       83700018
PARTBEG  EQU   24        DISPLACEMENT IN PQE FOR PARTITION BEGIN        83790018
H24      EQU   24                  SHIFT AMT FOR JOB ID                 83880018
TBLNUM   EQU   25        NUMBER OF JOBSTEPS TABLE CAN ACCOMODATE        83970018
ADJUST   EQU   29                  ADJUST AMT TO RIGHT-ADJUST (-1)      84060018
BORROW   EQU   X'80'                   BORROWED INDICATOR               84150018
PQEFLGS  EQU   28                  DISPL. OF PQE FLAGS                  84240018
NOTOWN   EQU   X'40'               NOT-OWN-THIS-PQE INDICATOR           84330018
TCBFC    EQU   X'80'                    INDICATES TASK IS COMPLETE      84420018
TCBFSM   EQU   X'80'              SYSTEM TASK INDICATOR                 84510018
JOBBAD   EQU   X'80'              BIT POSIOION FOR JOB AFFECTED INDIC.  84600018
RNGBAD   EQU   X'80'              INDICATOR THAT RANGE IS AFFECTED      84690018
MASK     EQU   192                 MASK (EQUALS HEX C0)                 84780018
OVRFLOW  EQU   255       INDICATOR OF JOBSTEP TABLE OVERFLOW            84870018
BASESAVE EQU   X'174'                   SAVE AREA FOR BASE REG          84960018
H2048    EQU   2048                INCREMENTAL VALUE OF 2048            85050018
CALL20  EQU  TTRTABLE                                                   85230018
CALL202 EQU  TTRTABLE+2                                                 85320018
FSTMCHK  TM    0(WKRG12),ZERO      EXECUTED INST, WKRG12 HAS ADR        85410018
OIINST OI      ZERO(WKRG12),ZERO EXECUTED INST, SETS FSSEMAP            85500018
*                                INDICATOR TO 11, WAS 01                85590018
K28      EQU   28                 CONSTANT                              85680018
H4       EQU   4                  CONSTANT                              85770018
LOLIM    EQU   8                                                        85860018
HILIM    EQU   9                                                        85950018
WKRG15   EQU   WKR15                                                    86040018
SPSHARE  EQU   X'80'                    CHECK TO SEE IF SUBPOOL SHARED  86050018
SPID     EQU   252                      TO LOCATE SUBPOOL 252           86060018
FLG1     EQU   X'80'                    TO SHOW A SUBPOOL WAS FOUND     86070018
FLGS     EQU   X'C0'                    TO SHOW SECOND TIME THRU        86080018
ATSW     EQU   X'0F'                    TO SHOW COMING FROM DQE         86090018
SWOFF    EQU   X'F0'                    TO TURN SWITCH OFF              86100018
         DS    0F                                                       86105018
SPFLGS   DS    X                        CONTROLLING SWITCHES            86110018
SPSAVE   DS    3X                                                       86120018
RNGAFF   DC    XL1'0'             JOB AFFECTED INDICATOR                86130018
JOBID    DC    XL1'0'              STORAGE RNG ID, CORR. TO JOBSTEP     86220018
STARTA   DC    F'0'                SAVED START ADR                      86260018
FSSAVE   DC    4F'0'               SAVE AREA FOR REGS                   86330018
HEX1F    DC    XL4'1F000000'      MASK OF X'1F' FOR JOB ID              86400018
CMPFLD   DC    XL4'0'             COMPARE FIELD                         86490018
KCMPFLD EQU   CMPFLD+1            DISPL IN COMPARE FIELD                86520018
LEN3     EQU   3                   LENGTH OF OPERAND                    86550018
JSTCBA   DC    F'0'                SAVED TCB PTR                        86580018
LASFPTR  DC    F'0'                POINTER TO LAST FBQE PTR/GOVRFLB     86670018
PQEADR   DC    F'0'     POINTER TO PQE PTR TO FIRST FBQE                86850018
MSTCB    DC    F'0'                PTR TO MASTER SCHEDULER TCB          86940018
X2048    DC    XL2'0800'           ADJUSTMENT FACTOR                    87030018
SAV12    DC    F'0'                REG12 SAVED                          87120018
SAV13    DC    F'0'              RETURN REGISTER CONTENTS               87210018
SAV14   DC    F'0'                REG 14 SAVED                          87300018
STPPTR   DC    F'0'                JOBSTEP PTR                          87390018
SQSENDA  DC    F'0'                DYNAMIC AREA START/SQS STOP          87480018
MSPTBEG  DC    F'0'                SAVED MASTER SCHEDULER BEGIN ADDRESS 87520018
STGRNUM  DC    F'0'                STORAGE RANGE TABLE ENTRIES          87570018
ADRTBL1  DC    XL40'0'           TABLE OF VARIED ADRS (START)           87660018
ADRTBL2  DC    XL40'0'           TABLE OF VARIED ADRS (STOP)            87750018
WKRG0    EQU   0                   WORK REG                             89100018
ZERO     EQU   0                   ZERO CONSTANT                        89280018
NTBLCV  DC    C'0123456789ABCDEF' CONVERT TABLE                         89730018
         DS    0F                                                       89740018
VONE     DC    X'00000001'                                              89750018
X0       EQU   0                                                        89760018
X6B      EQU   X'6B'                                                    89770018
X1       EQU   1                                                        89780018
X60      EQU   X'60'                                                    89790018
X5C      EQU   X'5C'                                                    89800018
X8       EQU   8                                                        89810018
X9       EQU   9                                                        89820018
X61      EQU   X'61'                                                    89830018
X3       EQU   3                                                        89840018
         DS    0H                                                       89850018
MAXTIME  DC    XL2'7FFF'           VALUE TO SPIN FOR 53 SECONDS         89860018
XTAB     DS    0F                                                       89910018
PARMLIST DC    X'22000000'              PARAMETER LIST FOR SVC PURGE    90000018
        DC    XL4'0'              2ND WORD OF PARM LIST                 90100018
        DC    XL4'0'              3RD WORD OF PARM LIST                 90200018
JSLNGTH  EQU   ENDTAB-JOBSTPS                                           90206018
TCBWIRE  EQU   TCBFLGS+2                                                90212018
TCBOLD   EQU   IEATCBP+4                                                90218018
RETSAVE  EQU   FSSAVE+12                                                90224018
CLEAR    EQU   80                                                       90230018
TBLDISP  EQU   40                                                       90236018
K32      EQU   32                                                       90242018
K96      EQU   96                                                       90248018
SINGOFF  EQU   254                                                      90254018
DCBTIOT  EQU   40                                                       90260018
TCBDONE  EQU   TCBFLGS+4                                                90266018
GAMORG   EQU   DCBDSORG+1                                               90272018
BDAMNDX  EQU   44                                                       90278018
MINUS4   DC    F'-4'                                                    90284018
         SPACE 3                                                        90294021
*** MAINTENANCE  AREA  ***                                              90296021
MAINTID  DC    CL8'IGFASR2K'           CORE IDENTIFIER                  90298021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              90298421
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 90298821
         ORG   IGFASR2K+3068      ROUND UP TO NEAR CSECT END            90300018
        DC    C'ASR'              IEHIOSUP TABLE CONTROL                90400018
        DC    X'1'                DISPLACEMENT IN DOUBLEWORDS FROM      90500018
*                                 CSECT START OF TABLE TO BE PROCESSED  90600018
         END                                                            90720018
