         TITLE 'IGFCCH35 - CHANNEL ANALYSIS MODULE'                     00400021
IGFCCH35 CSECT                                                          00800021
*********************************************************************** 01200021
*                                                                     * 01600021
* STATUS ----- 21.0           SUPPORT CODE - 21055                    * 02000021
*                                                                     * 02400021
* FUNCTION --- THIS IS THE 135 CHANNEL DEPENDENT ANALYSIS MODULE OF   * 02800021
*              CCH. THIS ROUTINE WILL MOVE THE EXTENDED CHANNEL STATUS* 03200021
*              WORD TO THE LAST PART OF THE WORK ERPIB AND MOVE THE   * 03600021
*              EXTENDED CHANNEL LOGOUT TO THE RECORD ENTRY. ON A TIO  * 04000021
*              INTERCEPTION, IT WILL MAKE A UNIT ADDRESS MATCH AND    * 04400021
*              RESET THE PROPER VALIDITY BITS IF THE ADDRESSES DO NOT * 04800021
*              MATCH. TWO LOGOUT LENGTHS WILL BE CREATED BY THIS      * 05200021
*              MODULE. THE FIRST WILL CONSIST OF A 96 BYTE BODY PLUS  * 05600021
*              A 24 BYTE HARDWARE LOGOUT; THE SECOND WILL CONSIST ONLY* 06000021
*              OF THE 96 BYTE BODY IN THE CASE WHEN THE HARDWARE DID  * 06400021
*              NOT LOG OUT ON THE ERROR. THE ROUTINE WILL HOUSEKEEP   * 06800021
*              THE UNIT ADDRESS LOCATION AND THE EXTENDED LOGOUT.     * 07200021
*                                                                     * 07600021
* ENTRY POINTS-IGFCCH35                                               * 08000021
*                                                                     * 08400021
* INPUT ------ EXTENDED CHANNEL STATUS WORD                           * 08800021
*              EXTENDED CHANNEL LOGOUT                                * 09200021
*              UNIT ADDRESS FROM IOS                                  * 09600021
*              UNIT ADDRESS FROM HARDWARE                             * 10000021
*              WORK ERPIB POINTER                                     * 10400021
*              RECORD ENTRY POINTER                                   * 10800021
*                                                                     * 11200021
* OUTPUT ----- COMPLETED ERPIB                                        * 11600021
*              LOGOUT IN RECORD ENTRY                                 * 12000021
*                                                                     * 12400021
* EXTERNAL REFERENCES -                                               * 12800021
*              ECSW                                                   * 13200021
*              EXTENDED I/O LOG POINTER                               * 13600021
*              UNIT ADDRESS LOCATION                                  * 14000021
*                                                                     * 14400021
* EXIT,NORMAL- CCHRETURN,IN ERPIBSET ROUTINE IN CENTRAL MODULE        * 14800021
*                                                                     * 15200021
* EXIT,ERROR - NONE                                                   * 15600021
*                                                                     * 16000021
* TABLES ----- ERBIB                                                  * 16400021
*              RECORD ENTRY                                           * 16800021
*                                                                     * 17200021
* ATTRIBUTES - SERIALLY REUSABLE, PRIVILEGED, DISABLED                * 17600021
*                                                                     * 18000021
*********************************************************************** 18400021
         USING *,RTNADRG                                                18800021
         USING IBWORK,WKERPIB      BASE FOR WORK ERPIB DSECT            19200021
         USING RECENTRY,REREG      BASE FOR RECORD ENTRY DSECT          19600021
*    CONSTANTS                                                          20000021
CCHTIOB  EQU   X'20'               TIO BIT IN PROGRAM FLAGS             20400021
STORFLAG EQU   X'80'               MASK TO TEST FOR ECSW STORED         20450021
NOLIST   EQU   X'10'               RECORD ONLY - NO ERPIB TO LIST       20500021
SYSTERM  EQU   X'80'               SIGNAL FOR SYSTEM TERMINATION        20550021
RECLGTH  EQU   84                  LENGTH OF RECORD BODY                20800021
LOGLGTH  EQU   23                  LENGTH OF HARDWARE LOGOUT MINUS ONE  21200021
LOGLGTH1 EQU   24                  LENGTH OF HARDWARE LOGOUT            21600021
ALLFS    EQU   X'FF'               BYTE OF ONES                         22000021
XFE      EQU   X'FE'               MASK                                 22400021
ZERO     EQU   0                   NUMBER                               22800021
FOUR     EQU   4                   NUMBER                               23200021
TRE      EQU   3                   NUMBER                               23600021
TWO      EQU   2                   NUMBER                               24000021
*    FIXED CORE LOCATIONS                                               24400021
IOEL     EQU   172                 POINTER TO LOG BUFFER                24800021
ECSWBGN  EQU   176                 BEGINNING OF ECSW                    24850021
ECSWLOC  EQU   177                 EXTENDED CHANNEL STATUS WORD         25200021
UNITADR  EQU   186                 HARDWARE STORED UNIT ADDRESS         25600021
*    REGISTER DEFINITION                                                26000021
RTNADRG  EQU   3                   ROUTINE BASE REGISTER                26400021
UAREG    EQU   6                   UNIT ADDRESS FROM IOS                26800021
WKERPIB  EQU   8                   WORK ERPIB ADDRESS REGISTER          27200021
LINKRG2  EQU   10                  RETURN LINK REGISTER                 27600021
LOGPTR   EQU   11                  LOG BUFFER ADDRESS                   28000021
MOVEREG  EQU   12                  CONTAINS LENGTH OF LOG FOR EX        28400021
REREG    EQU   13                  ADDRESS OF RECORD ENTRY              28800021
CCHSTART DS    0C                  START OF MODULE                      29200021
         TM    ECSWBGN,STORFLAG    WAS ECSW STORED                      29250021
         BNO   MOVECSW             YES, CONTINUE NORMAL PROCESSING      29300021
         OI    CCHSW1,NOLIST       SET INTERNAL RECORD ONLY SWITCH      29350021
         OI    CCHSW2,SYSTERM      SIGNAL SYSTEM TERMINATION            29400021
MOVECSW  MVC   ERPECSW(TRE),ECSWLOC MOVE ECSW TO ERPIB                  29600021
         TM    IBPRGFG1,CCHTIOB    IS INSTRUCTION A TIO                 30000021
         BNO   LOGTEST             NO,GO TEST FOR VALID LOG             30400021
         CH    UAREG,UNITADR       DOES IOS UNIT ADDR EQU HDW UA        30800021
         BE    LOGTEST             YES,GO TEST FOR VALID LOG            31200021
         NI    IBEXCSW1,XFE        NO,SET UNIT ADDR INVALID             31600021
LOGTEST  LTR   REREG,REREG         IS A RECORD BEING CREATED            32000021
         L     LOGPTR,IOEL         GET EXTENDED LOGOUT                  32400021
         BZ    HSKEEP              NO,SKIP TO HOUSEKEEPING              32800021
         MVC   TIOADR(TWO),UNITADR SAVE HDW UNIT ADDR IN RECORD         33200021
         CLC   ZERO(FOUR,LOGPTR),FOXES  IS LOG VALID                    33600021
         BE    HEADER              NO,JUST BUILD RECORD BODY            34000021
         MVC   LOGOUT(LOGLGTH1),ZERO(LOGPTR) MOVES IOEL TO RECORD       34800021
         MVI   COUNT7,RECLGTH+LOGLGTH1  STORE LENGTH IN COUNT FIELD     34850021
HSKEEP1  MVI   ZERO(LOGPTR),ALLFS  MOVE IN FOR FOXING                   36000021
         MVC   ONE(LOGLGTH,LOGPTR),ZERO(LOGPTR)   PROPAGATE             36400021
HSKEEP   XC    UNITADR(TWO),UNITADR     CLEAR HDW UA LOCATION           36800021
         MVI   ECSWBGN,ALLFS       HOUSEKEEP FIRST ECSW BYTE            36850021
         BR    LINKRG2             RETURN TO GENERAL ROUTINE            37200021
HEADER   MVI   COUNT7,RECLGTH      MOVE IN BODY LENGTH                  37600021
         B     HSKEEP1             GO FOX LOG                           38000021
FOXES    DC    F'-1'               WORD OF ONES                         38400021
CCHEND   DS    0C                  END OF MODULE                        38800021
MODLEN   EQU   CCHEND-CCHSTART     MODULE LENGTH                        39200021
*                                                                       39600021
IBWORK   DSECT                                                          40000021
IBUCB    DS    CL4                 UCB ADDRESS                          40400021
IBPRGFG1 DS    CL1                 FIRST PROGRAM FLAGS                  40800021
ERPECSW  DS    CL1                 START OF ECSW FIELD                  41200021
IBEXCSW1 DS    CL1                 VALIDITY FLAGS                       41600021
IBEXCSW2 DS    CL1                 TERM AND SEQUENCE CODES              42000021
CCHSWS   DS    0CL2                CCH INTERNAL SWITCHES                42050021
CCHSW1   DS    CL1                 FIRST BYTE SWITCHES                  42100021
CCHSW2   DS    CL1                 SECOND BYTE OF SWITCHES              42110021
RECBYTE  DS    1C                  RECORD BYTE                          42150021
*                                                                       42400021
RECENTRY DSECT                                                          42800021
COUNT    DS    CL7                 COUNT FIELD                          43200021
COUNT7   DS    CL1                 RECORD LENGTH LOCATION               43600021
RECIDFD  DS    CL2                 KEY                                  44000021
RECSWCH  DS    CL2                 SWITCHES                             44400021
OTHER    DS    CL68                RECORD ENTRY FIELDS                  44800021
CHANID   DS    CL1                 CHANNEL ID                           45200021
OTHER2   DS    CL9                 REMAINING RECORD HEADER              45600021
TIOADR   DS    CL2                 UNIT ADDRESS SAVED BY HARDWARE       46000021
LOGOUT   DS    CL96                I/O EXTENDED LOGOUT                  46400021
         EJECT                                                          46800021
*FUNCTION                                                         19E03 47200021
*   THIS ROUTINE WILL OBTAIN A PARAMETER LIST FROM NIP,WHICH WILL 19E03 47600021
*   CONTAIN A BUFFER AREA ADDRESS,USING THAT ADDRESS THIS ROUNINE 19E03 48000021
*   WILL MOVE THE MODULE TO WHICH IT IS ATTACHED INTO THAT AREA   19E03 48400021
*   AND RETURN TO NIP WITH THE NEXT UNUSED BUFFER ADDRESS         19E03 48800021
*ENTRY POINTS                                                     19E03 49200021
*   CCHNIPIN - FROM NIP                                           19E03 49600021
*INPUT                                                            19E03 50000021
*   A POINTER TO THE STARTING ADDRESS OF THE BUFFER AREA INTO     19E03 50400021
*   WHICH THE MODULE IS TO BE MOVED                               19E03 50800021
*OUTPUT                                                           19E03 51200021
*   1. THE MODULE IS MOVED TO THE BUFFER AREA                     19E03 51600021
*   2. THE CHANNEL POINTER TABLE IN THE CCH CENTRAL MODULE IS     19E03 52000021
*      FILLED IN WITH THE ADDRESS OF THE NEW MODULE LOCATION      19E03 52400021
*   3. THE END ADDRESS OF THE MODULE IS GIVEN BACK TO NIP         19E03 52800021
*EXTERNAL REFERENCES                                              19E03 53200021
*   CVT - TO FIND THE POINTER TO THE LOGREC DCB                   19E03 53600021
*   LOGREC DCB - TO FIND THE POINTER TO CCH CENTRAL               19E03 54000021
*   CCH CENTRAL - TO FILL IN THE NEW MODULE ADDRESS FOR           19E03 54400021
*                 COMMUNICATION                                   19E03 54800021
*EXITS,NORMAL                                                     19E03 55200021
*   RETURN IS VIA LINK REGISTER BACK TO NIP                       19E03 55600021
*EXITS,ERROR                                                      19E03 56000021
*   NONE                                                          19E03 56400021
*TABLES/WORK AREA                                                 19E03 56800021
*   NONE                                                          19E03 57200021
*ATTRIBUTES                                                       19E03 57600021
*   DISABLED,PRIVILEGED AND REUSABLE                              19E03 58000021
*NOTES                                                            19E03 58400021
*   AFTER THIS ROUTINE IS COMPLETED THE CHANNEL DEPENDENT         19E03 58800021
*   ANALYSIS MODULE IS MOVED AND THIS ROUTINE IS DISREGARDED      19E03 59200021
*   CHARACTER CODE DEPENDCIES                                     19E03 59600021
*   THIS CODE IS CHARACTER CODE INDEPENTENT                       19E03 60000021
         EJECT                                                    19E03 60400021
CCHNIPIN CSECT                                                    19E03 60800021
PARMREG1 EQU   1                        PARAMETER REGISTER        19E03 61200021
CVTREG   EQU   2                        CVT ADDR                  19E03 61600021
CCHTABRG EQU   3                        CCH ANAL MOD PTRS         19E03 62000021
POINTREG EQU   4                        CCH COMM TAB ADDR         19E03 62400021
BLOCKREG EQU   5                        MAX SIZE FOR MVC(256)     19E03 62800021
EXREG    EQU   6                        MAX DYN LEN FOR MVC(255)  19E03 63200021
SIZEREG  EQU   7                        SIZE OF MODULE            19E03 63600021
MODULREG EQU   8                        BEGINNING OF MODULE       19E03 64000021
BUFFEREG EQU   9                        ADDR OF BUFFER            19E03 64400021
RETNREG  EQU   14                       RETURN ADDR               19E03 64800021
BASEREG  EQU   15                       BASE ADDR FOR MOVE RTN    19E03 65200021
*                                                                 19E03 65600021
*                                                                 19E03 66000021
TWO55    EQU   255                      MAX DYN LEN  FOR MVC      19E03 66400021
BLKSIZE  EQU   256                      MAXIMUM MVC LENGTH        19E03 66800021
SIXTEEN  EQU   16                       CONSTANT                  19E03 67200021
LOGREC   EQU   X'74'                    DISPL OF LOGREC DCB(CVT)  19E03 67600021
II       EQU   2                        NUMBER                          68000021
DEPMODID EQU   X'35'                    CHAN ID CONSTANT          19E03 68400021
THREE    EQU   3                        CONSTANT                  19E03 68800021
ONE      EQU   1                        CONSTANT                  19E03 69200021
ENDLIST  EQU   X'FF'              END OF LIST DELIMITER           19E03 69600021
         USING CCHNIPIN,BASEREG                                   19E03 70000021
         ENTRY CCHNIPIN                                           19E03 70400021
         USING CCHSECT,POINTREG                                   19E03 70800021
         L     MODULREG,MODADDR         GET BEG OF MODULE         19E03 71200021
         LA    SIZEREG,MODLEN           GET MODULE LENGTH         19E03 71600021
         LA    EXREG,TWO55              MAX DYN MVC LENGTH        19E03 72000021
         LA    BLOCKREG,BLKSIZE         MAX MVC LENGTH            19E03 72400021
         L     CVTREG,SIXTEEN           PTR TO CVT                19E03 72800021
         L     POINTREG,LOGREC(CVTREG)  PTR TO LOGREC DCB         19E03 73200021
         L    POINTREG,ZERO(POINTREG)   PTR TO CCH COMM TAB       19E03 73600021
         L     CCHTABRG,CCHANTAB        PTR TO CCH DEP MODUL PTRS 19E03 74000021
         L     BUFFEREG,ZERO(PARMREG1)  GET BUFFER ADDR FROM PLIST19E03 74400021
COMPARE  CLI   THREE(CCHTABRG),DEPMODID PTR TO DEP MODULE NEEDED  19E03 74800021
         BNE   UPINDEX                  NO-TRY NEXT SLOT          19E03 75200021
         OC    ONE(II,CCHTABRG),ONE(CCHTABRG)   IN USE            19E03 75600021
         BNZ   UPINDEX            YES,  SKIP                      19E03 76000021
         MVC   ONE(THREE,CCHTABRG),ONE(PARMREG1)  STORE ADDR      19E03 76400021
UPINDEX  LA    CCHTABRG,FOUR(CCHTABRG)  GET NEXT ADDR LOCATION    19E03 76800021
         CLI   ZERO(CCHTABRG),ENDLIST   DONE                      19E03 77200021
         BNE   COMPARE                  YES-GO MOVE MODULE        19E03 77600021
COMPAR   CR    SIZEREG,BLOCKREG         LESS THEN 256 B TO MOVE   19E03 78000021
         BNH   LASTMOVE                 YES-BRANCH                19E03 78400021
         EX    EXREG,MOVEMOD            MOVE 256 BYTES INTO BUFR  19E03 78800021
         AR    BUFFEREG,BLOCKREG        UPDATE BUFFER ADDR        19E03 79200021
         AR    MODULREG,BLOCKREG        UPDATE ORIGIN ADDR        19E03 79600021
         SR    SIZEREG,BLOCKREG         DECREMENT LENGTH TO MOVE  19E03 80000021
         B     COMPAR              GO COMPARE                     19E03 80400021
LASTMOVE LR    BLOCKREG,SIZEREG         SAVE OVERFLOW             19E03 80800021
         BCTR  SIZEREG,ZERO             ADJUST DYNAMICALLY SIZE   19E03 81200021
         LTR   SIZEREG,SIZEREG          TEST DONE?                19E03 81600021
         BL    RETURNIP                 IF NEG,DONE               19E03 82000021
         EX    SIZEREG,MOVEMOD          MOVE LAST REMAINING BYTES 19E03 82400021
UPADDR   AR    BUFFEREG,BLOCKREG        ADJUST BUFR ADR TO UNUSED 19E03 82800021
RETURNIP ST    BUFFEREG,ZERO(PARMREG1)  STORE FOR NIP             19E03 83200021
         BR    RETNREG                  RETURN                    19E03 83600021
MOVEMOD  MVC   ZERO(ZERO,BUFFEREG),ZERO(MODULREG)  MOVES MODULE   19E03 84000021
MODADDR  DC    A(CCHSTART)              HOLDS MODULE START ADDR   19E03 84400021
*                                                                 19E03 84800021
CCHSECT  DSECT                                                    19E03 85200021
ERPIBFD  DS    F                   ADDRESS OF ERPIB FIELD         19E03 85600021
RECORD   DS    F                   ADDRESS OF RECORD ENTRY FIELD  19E03 86000021
CCHBASE  DS    F                   BASE ADDRESS OF CCH            19E03 86400021
CCHANTAB DS    F                   ADDRESS OF DEPENDENT RTN ADRS  19E03 86800021
         END   CCHNIPIN                                                 87200021
