         TITLE 'IGFCCH68 - CHANNEL ANALYSIS MODULE'                     00200020
IGFCCH68 CSECT                                                          00500020
*********************************************************************** 00510020
*                                                                     * 00520020
* STATUS ----- 21.0          SUPPORT CODE - 20302                21055* 00530000
*                                                                     * 00540020
* FUNCTION --- THIS IS THE 145 CHANNEL DEPENDENT ANALYSIS MODULE OF   * 00550000
*              CCH. THIS ROUTINE WILL MOVE THE EXTENDED CHANNEL STATUS* 00560020
*              WORD TO THE LAST PART OF THE WORK ERPIB AND MOVE THE   * 00570020
*              EXTENDED CHANNEL LOGOUT TO THE RECORD ENTRY.           * 00580020
*              ON A TIO INTERCEPTION, IT WILL MAKE A UNIT ADDRESS     * 00590020
*              MATCH AND RESET THE PROPER VALIDITY BITS IF THE        * 00600020
*              ADDRESSES DO NOT MATCH. LOGOUT LENGTH IS DETERMINED    * 00607020
*              EITHER FROM THE RECORD IN THE CASE OF MULTIPLEX OR AS  * 00614020
*              CONSTANT FOR THE BLOCK MULTIPLEX AND SELECTOR CHANNELS.* 00621020
*              BEFORE RETURNING TO THE CENTRAL MODULE, THE ROUTINE    * 00628020
*              WILL HOUSEKEEP THE UNIT ADDRESS LOCATION AND THE       * 00635020
*              EXTENDED LOGOUT.                                       * 00642020
*                                                                     * 00650020
* ENTRY POINTS-IGFCCH68                                               * 00660020
*                                                                     * 00670020
* INPUT ------ EXTENDED CHANNEL STATUS WORD                           * 00680020
*              EXTENDED CHANNEL LOGOUT                                * 00690020
*              UNIT ADDRESS FROM IOS                                  * 00700020
*              UNIT ADDRESS FROM HARDWARE                             * 00710020
*              WORK ERPIB POINTER                                     * 00720020
*              RECORD ENTRY POINTER                                   * 00730020
*                                                                     * 00740020
* OUTPUT ----- COMPLETED ERPIB                                        * 00750020
*              LOGOUT IN RECORD ENTRY                                 * 00760020
*                                                                     * 00770020
* EXTERNAL REFERENCES -                                               * 00780020
*              ECSW                                                   * 00790020
*              EXTENDED I/O LOG POINTER                               * 00800020
*              UNIT ADDRESS LOCATION                                  * 00810020
*                                                                     * 00820020
* EXIT,NORMAL -CCHRETURN,IN ERPIBSET ROUTINE IN CENTRAL MODULE        * 00830020
*                                                                     * 00840020
* EXIT,ERROR -- NONE                                                  * 00850020
*                                                                     * 00860020
* TABLES ----- ERPIB                                                  * 00870020
*              RECORD ENTRY                                           * 00880020
*                                                                     * 00890020
* ATTRIBUTES - SERIALLY REUSABLE, PRIVILEGED, DISABLED                * 00900020
*                                                                     * 00910020
*********************************************************************** 00920020
         USING *,RTNADRG                                                01000020
         USING IBWORK,WKERPIB      BASE FOR WORK ERPIB DSECT            01500020
         USING RECENTRY,REREG      BASE FOR RECORD ENTRY DSECT          02000020
*    CONSTANTS                                                          02500020
CCHTIOB  EQU   X'20'               TIO BIT IN PROGRAM FLAGS             03000020
NOLIST   EQU   X'10'               RECORD ONLY - NO ERPIB TO LIST       03050000
HEX80    EQU   X'80'               BYTE MPX VALIDITY BIT MASK           03200020
RECLGTH  EQU   84                  RECORD LENGTH WITHOUT LOGOUT   21055 03500000
RECLGTH1 EQU   85                  RECORD ENTRY LENGTH MINUS LOG  21055 04000000
ZERO     EQU   0                   NUMBER                               04500020
TWO      EQU   2                   NUMBER                               05000020
TRE      EQU   3                   NUMBER                               05500020
XFE      EQU   X'FE'               CONSTANT MASK                        06000020
THRTY6   EQU   36                  NUMBER                               06060020
SVN2     EQU   76                       NUMBER                   50582  06172000
ALLFS    EQU   X'FF'               BYTE OF ONES                         06180020
LOGLGTH  EQU   95                  LENGTH OF EXTENDED LOGOUT MINUS ONE  06240020
*    SWITCHES                                                           06300020
HEXONE   EQU   X'01'               BYTE MULTIPLEX INDICATOR             06360020
ICCMASK  EQU   X'02'               INTERFACE CONTROL CHECK MASK         06420020
*    FIXED CORE LOCATIONS                                               06500020
IOEL     EQU   172                 POINTER TO LOG BUFFER                07000020
ECSWBGN  EQU   176                 BEGINNING OF EXTENDED CHAN STAT WD   07050000
ECSWLOC  EQU   177                 EXTENDED CHANNEL STATUS WORD         07500020
UNITADR  EQU   186                 HARDWARE STORED UNIT ADDRESS         08000020
UNITSTAT EQU   69                  UNIT STATUS BYTE IN CSW              08200020
*    REGISTER  DEFINITION                                               08500020
RTNADRG  EQU   3                   ROUTINE BASE REGISTER                09000020
UAREG    EQU   6                   UNIT ADDRESS FROM IOS                09500020
WKERPIB  EQU   8                   WORK ERPIB ADDRESS REGISTER          10000020
LINKRG2  EQU   10                  RETURN LINK REGISTER                 10500020
LOGPTR   EQU   11                  LOG BUFFER ADDRESS                   11000020
MOVEREG  EQU   12                  CONTAINS LENGTH OF LOG FOR EX        11500020
REREG    EQU   13                  ADDRESS OF RECORD ENTRY              12000020
CCHSTART DS    0C                  START OF MODULE                      12500020
         TM    ECSWBGN,HEX80       WAS ECSW STORED VALIDLY              12550000
         BNO   MOVECSW             YES, CONTINUE NORMAL PROCESSING      12600000
         OI    CCHSW1,NOLIST       SET INTERNAL RECORD ONLY SWITCH      12650000
         OI    CCHSW2,HEX80        SIGNAL SYSTEM TERMINATION NECESSARY  12700000
MOVECSW  MVC   ERPECSW(TRE),ECSWLOC MOVE ECSW TO ERPIB                  13000000
         TM    IBPRGFG1,CCHTIOB    IS INSTRUCTION A TIO                 13500020
         BNO   LOGTEST             NO, GO TEST FOR VALID LOG            14000020
         CH    UAREG,UNITADR       DOES IOS UNIT ADDR EQU HDW UA        14500020
         BE    LOGTEST             YES,GO TEST FOR VALID LOG            15000020
         NI    IBEXCSW1,XFE        NO,SET UNIT ADDR INVALID             15500020
LOGTEST  LTR   REREG,REREG         IS A RECORD BEING CREATED            16000020
         L     LOGPTR,IOEL         GET EXTENDED LOGOUT                  16200020
         BZ    HSKEEP              NO,SKIP TO HOUSEKEEPING              16500020
         MVC   TIOADR(TWO),UNITADR SAVE HDW UNIT ADDR IN RECORD         17000020
         SR    MOVEREG,MOVEREG     CLEAR MOVE REGISTER                  17500020
         CLC   ZERO(FOUR,LOGPTR),FOXES  VALID LOG                       17700020
         BE    HEADER              NO, JUST BUILD HEADER                17900020
         CLI   CHANID,HEXONE       IS BYTE MULTIPLEX                    18100020
         BE    BYTEMPX             YES, BYTE MPS                        18300020
         IC    MOVEREG,ZERO(LOGPTR)     NO, GET LENGTH FROM LOG         18500020
         LTR   MOVEREG,MOVEREG     IS THERE A VALID LOG                 18700020
         BZ    HEADER              NO, SKIP LOG MOVE TO RECORD ENTRY    18900020
MOVE     BCTR  MOVEREG,ZERO        SET UP LENGTH FOR EXECUTING          19100020
         EX    MOVEREG,MOVELOG     MOVE LOG TO RECORD                   19300020
         LA    MOVEREG,RECLGTH1(MOVEREG)     GET TOTAL LENGTH           19500020
         STC   MOVEREG,COUNT7      STORE IN COUNT FIELD OF RECORD       19700020
HSKEEP1  MVI   ZERO(LOGPTR),ALLFS  MOVE IN FOR FOXING                   19900020
         MVC   ONE(LOGLGTH,LOGPTR),ZERO(LOGPTR)  SET LOGOUT TO ONES     20100020
HSKEEP   XC    UNITADR(TWO),UNITADR     CLEAR HDW UA LOCATION           20300020
         BR    LINKRG2             RETURN TO GENERAL RTN                20500020
BYTEMPX  TM    ZERO(LOGPTR),HEX80  LOG APPLY TO ERROR                   20700020
         BNO   HEADER              NO, BUILD HEADER                     20900020
         TM    UNITSTAT,ICCMASK    IS THIS ICC                          21100020
         BNO   SEVNTY2             NO, LOG LENGTH IS 72                 21300020
         LA    MOVEREG,THRTY6      USE 36 LENGTH                        21500020
         B     MOVE                GO MOVE RECORD TO RE AREA            21700020
SEVNTY2  LA    MOVEREG,SVN2        USE 72 LENGTH                        21900020
         B     MOVE                GO MOVE RECORD TO RE AREA            22100020
HEADER   MVI   COUNT7,RECLGTH      MOVE IN HEADER LENGTH          21055 22300000
         B     HSKEEP1             GO FOX LOG                           22500020
MOVELOG  MVC   LOGOUT(ZERO),ZERO(LOGPTR) MOVES IOEL TO RECORD           24500020
FOXES    DC    F'-1'               WORD OF ONES                         24700020
CCHEND   DS    0C                  END OF MODULE                        25000020
MODLEN   EQU   CCHEND-CCHSTART     MODULE LENGTH                        25500020
*                                                                       26000020
IBWORK   DSECT                                                          26500020
IBUCB    DS    CL4                 UCB ADDRESS                          27000020
IBPRGFG1 DS    CL1                 FIRST PROGRAM FLAGS                  27500020
ERPECSW  DS    CL1                 START OF ECSW FIELD                  28000020
IBEXCSW1 DS    CL1                 VALIDITY FLAGS                       28500020
IBEXCSW2 DS    CL1                 TERM AND SEQUENCE CODES              29000020
CCHSWS   DS    0CL2                CCH INTERNAL SWITCHES                29050000
CCHSW1   DS    CL1                 FIRST BYTE OF SWITCHES               29100000
CCHSW2   DS    CL1                 SECOND BYTE OF SWITCHES              29150000
RECBYTE  DS    1C                  RECORD BYTE                          29200000
*                                                                       29500020
RECENTRY DSECT                                                          30000020
COUNT    DS    CL7                 COUNT FIELD                          30500020
COUNT7   DS    CL1                 RECORD LENGTH LOCATION               31000020
RECIDFD  DS    CL2                 KEY                                  31500020
RECSWCH  DS    CL2                 SWITCHES                             32000020
OTHER    DS    CL68                RECORD ENTRY FIELDS                  32200020
CHANID   DS    CL1                 CHANNEL ID                           32400020
OTHER2   DS    CL9                 REMAINING RECORD HEADER              32600020
TIOADR   DS    CL2                 UNIT ADDRESS SAVED BY HARDWARE       33000020
LOGOUT   DS    CL96                I/O EXTENDED LOGOUT                  33500020
         EJECT                                                          33700020
*FUNCTION                                                         19E03 34000020
*   THIS ROUTINE WILL OBTAIN A PARAMETER LIST FROM NIP,WHICH WILL 19E03 34500020
*   CONTAIN A BUFFER AREA ADDRESS,USING THAT ADDRESS THIS ROUNINE 19E03 35000020
*   WILL MOVE THE MODULE TO WHICH IT IS ATTACHED INTO THAT AREA   19E03 35500020
*   AND RETURN TO NIP WITH THE NEXT UNUSED BUFFER ADDRESS         19E03 36000020
*ENTRY POINTS                                                     19E03 36500020
*   CCHNIPIN - FROM NIP                                           19E03 37000020
*INPUT                                                            19E03 37500020
*   A POINTER TO THE STARTING ADDRESS OF THE BUFFER AREA INTO     19E03 38000020
*   WHICH THE MODULE IS TO BE MOVED                               19E03 38500020
*OUTPUT                                                           19E03 39000020
*   1. THE MODULE IS MOVED TO THE BUFFER AREA                     19E03 39500020
*   2. THE CHANNEL POINTER TABLE IN THE CCH CENTRAL MODULE IS     19E03 40000020
*      FILLED IN WITH THE ADDRESS OF THE NEW MODULE LOCATION      19E03 40500020
*   3. THE END ADDRESS OF THE MODULE IS GIVEN BACK TO NIP         19E03 41000020
*EXTERNAL REFERENCES                                              19E03 41500020
*   CVT - TO FIND THE POINTER TO THE LOGREC DCB                   19E03 42000020
*   LOGREC DCB - TO FIND THE POINTER TO CCH CENTRAL               19E03 42500020
*   CCH CENTRAL - TO FILL IN THE NEW MODULE ADDRESS FOR           19E03 43000020
*                 COMMUNICATION                                   19E03 43500020
*EXITS,NORMAL                                                     19E03 44000020
*   RETURN IS VIA LINK REGISTER BACK TO NIP                       19E03 44500020
*EXITS,ERROR                                                      19E03 45000020
*   NONE                                                          19E03 45500020
*TABLES/WORK AREA                                                 19E03 46000020
*   NONE                                                          19E03 46500020
*ATTRIBUTES                                                       19E03 47000020
*   DISABLED,PRIVILEGED AND REUSABLE                              19E03 47500020
*NOTES                                                            19E03 48000020
*   AFTER THIS ROUTINE IS COMPLETED THE CHANNEL DEPENDENT         19E03 48500020
*   ANALYSIS MODULE IS MOVED AND THIS ROUTINE IS DISREGARDED      19E03 49000020
*   CHARACTER CODE DEPENDCIES                                     19E03 49500020
*   THIS CODE IS CHARACTER CODE INDEPENTENT                       19E03 50000020
         EJECT                                                    19E03 50500020
CCHNIPIN CSECT                                                    19E03 51000020
PARMREG1 EQU   1                        PARAMETER REGISTER        19E03 51500020
CVTREG   EQU   2                        CVT ADDR                  19E03 52000020
CCHTABRG EQU   3                        CCH ANAL MOD PTRS         19E03 52500020
POINTREG EQU   4                        CCH COMM TAB ADDR         19E03 53000020
BLOCKREG EQU   5                        MAX SIZE FOR MVC(256)     19E03 53500020
EXREG    EQU   6                        MAX DYN LEN FOR MVC(255)  19E03 54000020
SIZEREG  EQU   7                        SIZE OF MODULE            19E03 54500020
MODULREG EQU   8                        BEGINNING OF MODULE       19E03 55000020
BUFFEREG EQU   9                        ADDR OF BUFFER            19E03 55500020
RETNREG  EQU   14                       RETURN ADDR               19E03 56000020
BASEREG  EQU   15                       BASE ADDR FOR MOVE RTN    19E03 56500020
*                                                                 19E03 57000020
*                                                                 19E03 57500020
TWO55    EQU   255                      MAX DYN LEN  FOR MVC      19E03 58000020
BLKSIZE  EQU   256                      MAXIMUM MVC LENGTH        19E03 58500020
SIXTEEN  EQU   16                       CONSTANT                  19E03 59000020
LOGREC   EQU   X'74'                    DISPL OF LOGREC DCB(CVT)  19E03 59500020
II       EQU   2                   NUMBER                               60000020
DEPMODID EQU   X'68'                    CHAN ID CONSTANT          19E03 60500020
THREE    EQU   3                        CONSTANT                  19E03 61000020
ONE      EQU   1                        CONSTANT                  19E03 61500020
FOUR     EQU   4                        CONSTANT                  19E03 62000020
ENDLIST  EQU   X'FF'              END OF LIST DELIMITER           19E03 62500020
         USING CCHNIPIN,BASEREG                                   19E03 63000020
         ENTRY CCHNIPIN                                           19E03 63500020
         USING CCHSECT,POINTREG                                   19E03 64000020
         L     MODULREG,MODADDR         GET BEG OF MODULE         19E03 64500020
         LA    SIZEREG,MODLEN           GET MODULE LENGTH         19E03 65000020
         LA    EXREG,TWO55              MAX DYN MVC LENGTH        19E03 65500020
         LA    BLOCKREG,BLKSIZE         MAX MVC LENGTH            19E03 66000020
         L     CVTREG,SIXTEEN           PTR TO CVT                19E03 66500020
         L     POINTREG,LOGREC(CVTREG)  PTR TO LOGREC DCB         19E03 67000020
         L    POINTREG,ZERO(POINTREG)   PTR TO CCH COMM TAB       19E03 67500020
         L     CCHTABRG,CCHANTAB        PTR TO CCH DEP MODUL PTRS 19E03 68000020
         L     BUFFEREG,ZERO(PARMREG1)  GET BUFFER ADDR FROM PLIST19E03 68500020
COMPARE  CLI   THREE(CCHTABRG),DEPMODID PTR TO DEP MODULE NEEDED  19E03 69000020
         BNE   UPINDEX                  NO-TRY NEXT SLOT          19E03 69500020
         OC    ONE(II,CCHTABRG),ONE(CCHTABRG)   IN USE            19E03 70000020
         BNZ   UPINDEX            YES,  SKIP                      19E03 70500020
         MVC   ONE(THREE,CCHTABRG),ONE(PARMREG1)  STORE ADDR      19E03 71000020
UPINDEX  LA    CCHTABRG,FOUR(CCHTABRG)  GET NEXT ADDR LOCATION    19E03 71500020
         CLI   ZERO(CCHTABRG),ENDLIST   DONE                      19E03 72000020
         BNE   COMPARE                  YES-GO MOVE MODULE        19E03 72500020
COMPAR   CR    SIZEREG,BLOCKREG         LESS THEN 256 B TO MOVE   19E03 73000020
         BNH   LASTMOVE                 YES-BRANCH                19E03 73500020
         EX    EXREG,MOVEMOD            MOVE 256 BYTES INTO BUFR  19E03 74000020
         AR    BUFFEREG,BLOCKREG        UPDATE BUFFER ADDR        19E03 74500020
         AR    MODULREG,BLOCKREG        UPDATE ORIGIN ADDR        19E03 75000020
         SR    SIZEREG,BLOCKREG         DECREMENT LENGTH TO MOVE  19E03 75500020
         B     COMPAR              GO COMPARE                     19E03 76000020
LASTMOVE LR    BLOCKREG,SIZEREG         SAVE OVERFLOW             19E03 76500020
         BCTR  SIZEREG,ZERO             ADJUST DYNAMICALLY SIZE   19E03 77000020
         LTR   SIZEREG,SIZEREG          TEST DONE?                19E03 77500020
         BL    RETURNIP                 IF NEG,DONE               19E03 78000020
         EX    SIZEREG,MOVEMOD          MOVE LAST REMAINING BYTES 19E03 78500020
UPADDR   AR    BUFFEREG,BLOCKREG        ADJUST BUFR ADR TO UNUSED 19E03 79000020
RETURNIP ST    BUFFEREG,ZERO(PARMREG1)  STORE FOR NIP             19E03 79500020
         BR    RETNREG                  RETURN                    19E03 80000020
MOVEMOD  MVC   ZERO(ZERO,BUFFEREG),ZERO(MODULREG)  MOVES MODULE   19E03 80500020
MODADDR  DC    A(CCHSTART)              HOLDS MODULE START ADDR   19E03 81000020
*                                                                 19E03 81500020
CCHSECT  DSECT                                                    19E03 82000020
ERPIBFD  DS    F                   ADDRESS OF ERPIB FIELD         19E03 82500020
RECORD   DS    F                   ADDRESS OF RECORD ENTRY FIELD  19E03 83000020
CCHBASE  DS    F                   BASE ADDRESS OF CCH            19E03 83500020
CCHANTAB DS    F                   ADDRESS OF DEPENDENT RTN ADRS  19E03 84000020
         END   CCHNIPIN                                                 84500020
