         TITLE 'IGFCCH80 2880 LOGOUT ANALYSIS ROUTINE'            19E03 00100020
IGFCCH80 CSECT                                                    19E03 00200020
*STATUS --                                                        19E03 00300020
*   CHANGE LEVEL 21.00                                            21055 00400021
         SPACE                                                          00500020
*FUNCTION --                                                      19E03 00600020
*   THIS ROUTINE ANALYZES THE CHANNEL LOGOUT CREATED BY THE 2880  19E03 00700020
*   CHANNEL ON CHANNEL DETECTED ERRORS-INTERFACE CONTROL CHECK,   19E03 00800020
*   CHANNEL CONTROL CHECK,AND ALSO CHANNEL DATA CHECK. FROM THIS  19E03 00900020
*   ANALYSIS IT SETS BITS IN THE WORK ERPIB. IF THE LOGOUT AREA   19E03 01000020
*   HAS A WORD OF ALL ONES IN IT,THE CHANNEL HAS FAILED TO LOG.   19E03 01100020
*   IN THIS CASE,THE SYSTEM TERMINATION(SYSTERM) BIT IS SET. ALSO 19E03 01200020
*   IF THE LOGOUT OCCURRED ON A MAJOR SCAN BUT THE UNIT CONTROL   19E03 01300020
*   WORD ADDRESS REGISTER PARITY BIT IS NOT ON,THE SYSTERM BIT IS 19E03 01400020
*   SET. IT IS ALSO SET IF A TEST I/O TO A BLOCK NULTIPLEX        19E03 01500020
*   RESULTED IN A SUBCHANNEL STATUS PARITY CHECK,OR IF THE        19E03 01600020
*   CONDITION WAS NOT A MAJOR OPERATION(SIO,TIO,ETC),NO DATA WAS  19E03 01700020
*   BEING TRANSFERRED AND WAS NOT AN INTERRUPT RESPONSE,OR IF AN  19E03 01800020
*   UNUSUAL CONDITION WAS DETECTED WHILE A HALT I/O WAS ISSUED TO 19E03 01900020
*   A BUSY SUBCHANNEL.                                            19E03 02000020
*                                                                 19E03 02100020
*   THE RECORD ONLY BIT IS SET IF A LOGOUT OCCURRED ON A MAJOR    19E03 02200020
*   SCAN OPERATION AND THE UNIT CONTROL WORD ADDRESS REGISTER     19E03 02300020
*   (UCWAR) PARITY CHECK BIT WAS ON, OR IF ON AN INTERRUPT,THE    19E03 02400020
*   INTERRUPT CONTROL BITS ARE UP.                                19E03 02500020
*                                                                 19E03 02600020
*   OTHERWISE, TERMINATION CODES OF FROM ZERO TO THREE AND        19E03 02700020
*   RETRY CODES OF FROM ZERO TO FIVE ARE SET.                     19E03 02800020
*                                                                 19E03 02900020
*   ON EXIT FROM THIS ROUTINE, A FUNCTION HEREIN DEFINED AS       19E03 03000020
*   HOUSEKEEPING THE LOG IS PERFORMED. IT CONSISTS OF INITIALIZ-  19E03 03100020
*   ING THE RECORD ENTRY LENGTH,MOVING THE LOG TO THE RECORD      19E03 03200020
*   ENTRY AND SETTING THE LOG TO ONES.                            19E03 03300020
         SPACE                                                          03400020
*ENTRY POINTS --                                                  19E03 03500020
*      IGFCCH80  IS THE PRIMARY AND ONLY ENTRYPOINT. IT IS        19E03 03600020
*   ENTERED ANYTIME THE 2880 CHANNEL LOGS OUT AND THE CHANNEL     19E03 03700020
*   CHECK HANDLER IS IN THE SYSTEM.                               19E03 03800020
         SPACE                                                          03900020
*INPUT                                                            19E03 04000020
*   1. THE RECORD ENTRY IN REGISTER 13.                           19E03 04100020
*   2. THE WORK ERPIB IN REGISTER 8.                              19E03 04200020
*   3. THE CHANNEL LOGOUT.                                        19E03 04300020
*   4. THE COMMUNICATIONS VECTOR TABLE IN REGISTER 9.             19E03 04400020
         SPACE                                                          04500020
*OUTPUT                                                           19E03 04600020
*   1. CHANNEL LOGOUT AREA(28 WORDS) SET TO ALL ONES.             19E03 04700020
*   2. WORK ERPIB COMPLETED WITH VALIDITY BITS AND RETRY AND      19E03 04800020
*   TERMINATION CODES.                                            19E03 04900020
*   3. SYSTEM OR RECORD ONLY BITS SET IF CERTAIN CONDITIONS       19E03 05000020
*   DESCRIBED IN THE FUNCTION SECTION ARE MET.                    19E03 05100020
         SPACE                                                          05200020
*EXTERNAL REFERENCES --                                           19E03 05300020
*       LOGREC DCB -- TO GET THE POINTER TO THE CCH COMMUNICATION 19E03 05400020
*   TABLE.                                                        19E03 05500020
*       THE CHANNEL LOGOUT LOCATED AT DIFFERENT LOCATIONS         19E03 05600020
*   DEPENDING ON THE CENTRAL PROCESSING UNIT TO WHICH THE CHANNEL 19E03 05700020
*   IS ATTACHED.                                                  19E03 05800020
         SPACE                                                          05900020
*EXITS,NORMAL --                                                  19E03 06000020
*       CCH80RET IS THE ONLY EXIT POINT FROM THIS ROUTINE. RETURN 19E03 06100020
*   IS VIA THE CCH SECONDARY LINK REGISTER,LINKRG2.               19E03 06200020
         SPACE                                                          06300020
*EXITS,ERROR --                                                   19E03 06400020
*   NONE                                                          19E03 06500020
         SPACE                                                          06600020
*TABLES/WORKAREAS --                                              19E03 06700020
*   1. WORK ERPIB -- USED TO INDICATE VALIDITY BITS AND RETRY AND 19E03 06800020
*   TERMINATION CODES.                                            19E03 06900020
*   2. RECORD ENTRY -- USED TO INDICATE THE CHANNEL LOGOUT.       19E03 07000020
*   3. MODEL IDENTIFICATION TABLE(MODELS).-- INDICATES'THE'       19E03 07100020
*   CENTRAL PROCESSOR ON WHICH THE SYSTEM IS RUNNING.             19E03 07200020
*   4. LOGOUT LOCATION TABLE(LOGLOCS) -- INDICATES THE ADDRESS OF 19E03 07300020
*   THE CHANNEL LOGOUT AREAS ON THE VARIOUS CENTRAL PROCESSORS.   19E03 07400020
         SPACE                                                          07500020
*ATTRIBUTES --                                                    19E03 07600020
*   THIS ROUTINE IS PRIVILEGED,DISABLED,AND REUSABLE              19E03 07700020
         SPACE                                                          07800020
*NOTES --                                                         19E03 07900020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT.                   19E03 08000020
         SPACE                                                          08100020
***************************************************************** 19E03 08200020
*REGISTER DEFINITION                                            * 19E03 08300020
***************************************************************** 19E03 08400020
         SPACE                                                          08500020
RTNADRG  EQU   3                        BASE FOR LOGOUT ROUTINE   19E03 08600020
LOGBASE  EQU   4                        BASE FOR I/O LOGOUT(2880) 19E03 08700020
CUAREG   EQU   6                        HOLDS CHANNEL UNIT ADDR   19E03 08800020
CVTREG   EQU   9                        ADDRESS OF CVT            19E03 08900020
WORKREG9 EQU   9                        WORK REGISTER             19E03 09000020
WKERPIB  EQU   8                        BASEREG FOR WORK ERPIB    19E03 09100020
LINKRG2  EQU   10                       SECONDARY LINK REGISTER   19E03 09200020
WORKREGB EQU   11                       WORK REGISTER             19E03 09300020
WORKREGC EQU   12                       WORK REGISTER             19E03 09400020
REREG    EQU   13                       ADDRESS OF RECORD ENTRY   19E03 09500020
         SPACE                                                          09600020
***************************************************************** 19E03 09700020
*   DEFINITIONS -- THOSE NOT IN STANDARDS                       * 19E03 09800020
*                                                               * 19E03 09900020
*   BEG    --  BEGINNING                                        * 19E03 10000020
*   CC     --  CONTROL CHECK                                    * 19E03 10100020
*   CMD    --  COMMAND                                          * 19E03 10200020
*   CPUID  --  CENTRAL PROCESSING UNIT IDENTIFICATION           * 19E03 10300020
*   CUR    --  CONTROL UNIT REGISTER                            * 19E03 10400020
*   CVT    --  COMMUNICATIONS VECTOR TABLE                      * 19E03 10500020
*   DISP   --  DISPLACEMENT                                     * 19E03 10600020
*   ID(S)  --  IDENTIFICATION(S)                                * 19E03 10700020
*   SCS    --  SUBCHANNEL STATUS                                * 19E03 10800020
*   SYS    --  SYSTEM                                           * 19E03 10900020
*   UA     --  UNIT ADDRESS                                     * 19E03 11000020
*   UCWAR  --  UNIT CONTROL WORD ADDRESS REGISTER               * 19E03 11100020
***************************************************************** 19E03 11200020
         SPACE                                                          11300020
***************************************************************** 19E03 11400020
*GENERAL EQUATES                                                * 19E03 11500020
***************************************************************** 19E03 11600020
         SPACE                                                          11700020
ZERO     EQU   0                        DISPLACEMENT              19E03 11800020
O        EQU   0                        DISPLACEMENT              19E03 11900020
ONE      EQU   1                        CONSTANT-DISPLACEMENT     19E03 12000020
TWO      EQU   2                        CONSTANT-DISPLACEMENT     19E03 12100020
THREE    EQU   3                        LOOP CONTROL,DISPLACEMENT 19E03 12200020
FOUR     EQU   4                        CONSTANT-DISPLACEMENT     19E03 12300020
FIVE     EQU   5                        DISPLACEMENT              19E03 12400020
SIX      EQU   6                        DISPLACEMENT              19E03 12500020
SEVEN    EQU   7                        CONSTANT-ANDING MASK      19E03 12600020
EIGHT    EQU   8                        CONSTANT- MASK            19E03 12700020
TWELVE   EQU   12                       DISPLACEMENT              19E03 12800020
FOURTEEN EQU   14                       CONSTANT-MASK             19E03 12900020
FIFTEEN  EQU   15                       ANDING MASK               19E03 13000020
LOGPT80  EQU   16                       DISPLACEMENT OF LOG PT    19E03 13100020
OLDIOPSW EQU   X'38'                    I/O OLD PSW LOCATION      19E03 13200020
CSWLOC   EQU   64                       CSW LOCATION              19E03 13300020
ONE08    EQU   108                      DISP OF LAST LOGWORD      19E03 13400020
RECLENTH EQU   192                      RECORD ENTRY DATA LENGTH  21055 13500021
ONE11    EQU   111                      LENGTH                    19E03 13600020
ONE12    EQU   112                      LOGOUT LENGTH             19E03 13700020
FOXFOX   EQU   X'FF'                    CONSTANT-TO FILL LOG      19E03 13800020
CCC      EQU   X'04'                    CHANNEL CONTROL CHECK     19E03 13900020
ICC      EQU   X'02'                    INTERFACE CONTROL CHECK   19E03 14000020
         SPACE                                                          14100020
***************************************************************** 19E03 14200020
*2880 -- LOGOUT BIT INTERPRETATIONS                             * 19E03 14300020
***************************************************************** 19E03 14400020
         SPACE                                                          14500020
CCHDCIN  EQU   X'01'                    DISCONNECT IN INDICATION  19E03 14600020
SCANMAJR EQU   X'80'                    SCAN MAJOR BIT            19E03 14700020
UCWARCK  EQU   X'20'               UCWAR UNIT ADDR CHECK       EC715005 14800020
HIOBUSY  EQU   X'02'                    HALT I/O BUSY             19E03 14900020
TIOSYNCL EQU   X'40'                    TIO SYNCH LATCH           19E03 15000020
PSEUDOCC EQU   X'80'                    PSEUDO CONTROL CHECK      19E03 15100020
SCSPCK   EQU   X'04'                    SCS PARITY CHECK          19E03 15200020
PRIORCK  EQU   X'80'                    PRIORITY CHECK            19E03 15300020
HIONBUSY EQU   X'08'                    HIO NOT BUSY              19E03 15400020
OPIN     EQU   X'20'                    OP-IN BIT                 19E03 15500020
SIOMAJOR EQU   X'20'                    SIO MAJOR OP              19E03 15600020
IRPTRESP EQU   X'20'                    INTERRUPT RESPONSE BIT    19E03 15700020
CCRESELM EQU   X'02'                    CC RESELECT MAJOR         19E03 15800020
CCWLATCH EQU   X'80'                    CCW LATCH BIT             19E03 15900020
CMDADDRV EQU   X'04'                    CMD ADDRESS VALID         19E03 16000021
USVALID  EQU   X'08'                    UNIT STATUS VALID         19E03 16100021
CMDOUT   EQU   X'80'                    CMD OUT SENT              19E03 16200020
DATAXFER EQU   X'40'                    DATA TRANSER INDICATOR    19E03 16300020
INITDATA EQU   X'10'                    INITIAL DATA              19E03 16400020
DATAXMAJ EQU   X'04'                    DATA XFER MAJOR           19E03 16500020
CURMAJOR EQU   X'40'                    CUR MAJOR OP              19E03 16600020
UCW0111  EQU   X'18'                    UCW0,1 ON                 19E03 16700020
TIOMAJOR EQU   X'10'                    TIO MAJOR OP              19E03 16800020
ICBD     EQU   10                       ICB EQUAL 5               19E03 16900020
UNITSEL  EQU   X'80'                    UNIT SELECT               19E03 17000020
BLKMPX   EQU   X'10'                    BLOCK MULTIPLEX BIT       19E03 17100020
SHARSUBC EQU   X'10'                    SHARED SUBCHANNEL BIT     19E03 17200020
         SPACE                                                          17300020
***************************************************************** 19E03 17400020
*DEFINITION OF BITS IN ERPIB                                    * 19E03 17500020
***************************************************************** 19E03 17600020
         SPACE                                                          17700020
CCHNRYB  EQU   X'01'                    NO RETRY BIT              19E03 17800020
CCHCPU   EQU   X'80'                    CPU IS SOURCE OF ERROR    19E03 17900020
CCHCHNL  EQU   X'40'                    CHAN IS SOURCE OF ERROR   19E03 18000020
CCHSTG   EQU   X'10'                    STG IS SOURCE OF ERROR    19E03 18100020
CCHINTFC EQU   X'08'                    I/F IS SOURCE OF ERROR(CU)19E03 18200020
CCHRCV   EQU   X'10'                    RETRY CODE VALID          19E03 18300020
CCHUSV   EQU   X'08'                    UNIT STATUS VALID         19E03 18400020
CCHCMDV  EQU   X'04'                    CMD ADDRESS VALID         19E03 18500020
CCHCAV   EQU   X'02'                    CHANNEL ADDRESS VALID     19E03 18600020
CCHDAV   EQU   X'01'                    DEVICE ADDRESS VALID      19E03 18700020
COMPSYS  EQU   X'C0'                    SYSTEM RESET              19E03 18800020
COMPSEL  EQU   X'80'                    SELECTIVE RESET           19E03 18900020
COMPFES  EQU   X'40'                    FORCED ENDING SEQUENCE    19E03 19000020
COMPID   EQU   X'00'                    INTERFACE DISCONNECT      19E03 19100020
CCHDI    EQU   X'08'                    DISCONNECT IN             19E03 19200020
RTCODE0  EQU   X'00'                    RETRY                     19E03 19300020
RTCODE1  EQU   X'01'                      CODE                    19E03 19400020
RTCODE2  EQU   X'02'                        VALUES                19E03 19500020
RTCODE3  EQU   X'03'                          FOR                 19E03 19600020
RTCODE4  EQU   X'04'                           ERPIB              19E03 19700020
RTCODE5  EQU   X'05'                            FOR 2880          19E03 19800020
CCHSCU   EQU   X'20'                    STG CU IS SOURCE OF ERR   19E03 19900020
IBPRGFGA EQU   4                        1ST PROG CONTROLLED SW    19E03 20000020
CCHSIOB  EQU   X'80'                    SIO BIT                   19E03 20100020
CCHINTB  EQU   X'40'                    INTERRUPT BIT             19E03 20200020
CCHTIOB  EQU   X'20'                    TIO BIT                   19E03 20300020
CCHHIOB  EQU   X'10'                    HIO BIT                   19E03 20400020
         SPACE                                                          20500020
***************************************************************** 19E03 20600020
*CCH INTERNAL SWITCHES                                          * 19E03 20700020
***************************************************************** 19E03 20800020
         SPACE                                                          20900020
***************************************************************** 19E03 21000020
*SWITCH BYTE ONE                                                * 19E03 21100020
***************************************************************** 19E03 21200020
         SPACE                                                          21300020
CCHCMDRG EQU   X'80'                    COMMAND REGISTER PARITY   19E03 21400020
CCHNORE  EQU   X'40'                    NO RECORD ENTRY AVAILABLE 19E03 21500020
CCHERFRE EQU   X'20'                    ERPIB FREED FROM LIST     19E03 21600020
CCHNOLST EQU   X'10'                    RECORD ONLY               19E03 21700020
CCHHAND  EQU   X'08'                    D.E. OR ATTENTION         19E03 21800020
CCHIBC   EQU   X'04'                    ERPIB ALREADY CREATED     19E03 21900020
UCBNVBIT EQU   X'02'                    UCB INVALID               19E03 22000020
         SPACE                                                          22100020
***************************************************************** 19E03 22200020
*SWITCH BYTE TWO                                                * 19E03 22300020
***************************************************************** 19E03 22400020
         SPACE                                                          22500020
SYSTERM  EQU   X'80'                    SIGNAL FOR TERMINATION    19E03 22600020
INTRTN2  EQU   X'40'                    ALTERNAMT RETURN SWITCH   19E03 22700020
NOMODEL  EQU   X'20'                    NO MODEL FOUND FOR LOGOUT 19E03 22800020
NOLOG    EQU   X'10'                    INDICATES ABSENCE  OF LOG 19E03 22900020
         EJECT                                                          23000020
***************************************************************** 19E03 23100020
*THIS IS THE ENTRYPOINT FOR THIS ROUTINE                        * 19E03 23200020
***************************************************************** 19E03 23300020
         SPACE                                                          23400020
         USING CCH02880,RTNADRG         BASE FOR THIS ROUTINE     19E03 23500020
         USING RECENTRY,REREG           BASE FOR RECORD ENTRY     19E03 23600020
         USING IBWORK,WKERPIB           BASE FOR WORK ERPIB       19E03 23700020
         USING IOLOG,LOGBASE            BASE FOR LOGOUT           19E03 23800020
         SPACE                                                          23900020
***************************************************************** 19E03 24000020
*   THIS SECTION INITIALIZES THE CHANNEL LOGOUT POINTER         * 19E03 24100020
***************************************************************** 19E03 24200020
         SPACE                                                          24300020
CCH02880 L     WORKREGC,LOGREC(CVTREG)  GET POINTER TO LOGREC     19E03 24400020
         L     WORKREGC,ZERO(WORKREGC)  POINTER TO CCH COMM TABLE 19E03 24500020
         L     LOGBASE,LOGPT80(WORKREGC) GET LOGOUT LOCATION      19E03 24600020
         LTR   LOGBASE,LOGBASE          IS IT INITIALIZED         19E03 24700020
         BP    TSTNOLOG                 YES-GO CHECK LOG VALIDITY 19E03 24800020
         SPACE                                                          24900020
***************************************************************** 19E03 25000020
*   IF THE MODEL NUMBER CANNOT BE FOUND,THE SYSTEM IS TERMINATED* 19E03 25100020
*   BY THE FOLLOWING CODE BEING EXECUTED.                       * 19E03 25200020
***************************************************************** 19E03 25300020
         SPACE                                                          25400020
         OI    CCHSW2,NOMODEL           SET NO MODEL FOUND SWITCH 19E03 25500020
         NI    CCHSW2,FOXFOX-NOLOG      RESET NO LOGOUT SWITCH    19E03 25600020
         B     SETRCINV                 GO TERMINATE SYSTEM       19E03 25700020
         SPACE                                                          25800020
***************************************************************** 19E03 25900020
*   THIS SECTION INSURES THAT THE CHANNEL HAS LOGGED. IF IT HAS * 19E03 26000020
*   FAILED,THE SYSTEM WILL TAKE THE TUBES,MEANING TERMINATE.      19E03 26100020
***************************************************************** 19E03 26200020
         SPACE                                                          26300020
TSTNOLOG TM    CCHSW2,NOLOG             NO LOGOUT SWITCH SET      19E03 26400020
         BZ    CCHLOGOK                      NO-BRANCH-NORMAL     19E03 26500020
         NI    CCHSW2,FOXFOX-SYSTERM-NOLOG   RESET INTERNAL SW    19E03 26600020
         NI    CCHSW1,FOXFOX-CCHNOLST   RESET RECORD ONLY SWITCH  19E03 26650020
         SR    WORKREGC,WORKREGC        INITIALIZE WORK REGISTER  44408 26660021
         IC    WORKREGC,CHANLID         GET CHANNEL NUMBER        19E03 26700020
         SRL   WORKREGC,FOUR            CLEAR GARBAGE             19E03 26800021
         SR    WORKREGB,WORKREGB        INITIALIZE WORK REGISTER  44408 26850021
         IC    WORKREGB,OLDIOPSW+TWO    GET CHANNEL NUMBER-PSW    19E03 27100020
         CR    WORKREGC,WORKREGB        CHAN ID IN LOG EQ PSW     19E03 27200020
         BNE   SETRCINV                      NO-BR-TERMINATE      19E03 27300020
         L     WORKREGC,LOGREC(O,CVTREG)     GET LOGREC DCB       19E03 27400020
         L     WORKREGC,ZERO(O,WORKREGC)     GET CCH COMM AREA    19E03 27500020
         L     WORKREGC,TWELVE(O,WORKREGC)   GET CHAN PT TABLE    19E03 27600020
         IC    WORKREGB,OLDIOPSW+TWO    GET CHANNEL NUMBER        19E03 27700020
         SLL   WORKREGB,TWO                  ADJUST FOR INDEXING  19E03 27800020
         LA    WORKREGB,ZERO(WORKREGB,WORKREGC)   GET SLOT ADDR   19E03 27900020
         ST    RTNADRG,ZERO(O,WORKREGB)      CORRECT ADDR IN SLOT 19E03 28000020
         MVI   ZERO(WORKREGB),EIGHT          SELECTOR CHAN ID     19E03 28100020
         TM    CCHSW1,CCHNORE                RECORD ENTRY TO USE  19E03 28200020
         BC    ONE,CCHLOGOK                  NO-BR-CHECK LOGOUT   19E03 28300020
         MVI   CHANID,EIGHT                  YES-PUT IN CHAN ID   19E03 28400020
         SPACE                                                          28500020
CCHLOGOK CLC   ZERO(FOUR,LOGBASE),ALLONES    DID CHAN FAIL TO LOG 19E03 28600020
         BE    SETRCINV                      YES-BR-TERMINATE     19E03 28700020
         CLC   ONE08(FOUR,LOGBASE),ALLONES   TEST FAILURE AGAIN   19E03 28800020
         BE    SETRCINV                      YES-BR-TERMINATE     19E03 28900020
         SPACE                                                          29000020
***************************************************************** 19E03 29100020
*THIS IS WHERE THE LOGOUT ANALYSIS BEGINS                       * 19E03 29200020
***************************************************************** 19E03 29300020
         SPACE                                                          29400020
         TM    CSWLOC+FIVE,CCC+ICC      INTERFACE OR CHANNEL ERR  19E03 29500020
         BZ    CKTIOADR                 NO-BR-MUST BE CDC         19E03 29600020
         TM    LW1,CCHDCIN              WAS UNIT DISCONNECTED     19E03 29700020
         BZ    ANALBEG                  NO-BRANCH-SKIP SETTING    19E03 29800020
         OI    IBEXCSW2,CCHDI           SET DISCONNECT IN BIT     19E03 29900020
ANALBEG  TM    LW3,SCANMAJR             IS THIS MAJOR SCAN        19E03 30000020
         BC    FOURTEEN,CHECKCLR        NO-BRANCH                 19E03 30100020
         TM    LW1,UCWARCK              IS THIS UCWAR UA CHECK EC715005 30200020
         BC    FOURTEEN,SET0303         YES-BRANCH,SET CODES      19E03 30300020
SET0301  OI    IBEXCSW2,RTCODE3+COMPFES SET RETRY TO 3,TERM TO 1  19E03 30400020
         B     SETNOLST                 GO RECORD ONLY            19E03 30500020
*                                                                 19E03 30600020
SET0303  OI    IBEXCSW2,RTCODE3+COMPSYS SET RETRY TO 3,TERM TO 3  19E03 30700020
         B     SETSYSTR                 GO TERMINATE              19E03 30800020
*                                                                 19E03 30900020
CHECKCLR TM    RECBYTE,CCHINTB          WAS THIS AN INTERRUPT     19E03 31000020
         BC    ONE,CKPSEUDO             YES-BRANCH-CK PSEUDO CC   19E03 31100020
         TM    RECBYTE,CCHTIOB          WAS THIS A TEST I/O       19E03 31200020
         BC    ONE,TIOSYNCH             YES-BRANCH-TEST SYNCH LCH 19E03 31300020
         TM    LW3+THREE,HIOBUSY        WAS THIS HALT I/O BUSY    19E03 31400020
         BC    FOURTEEN,CKPSEUDO        NO-BRANCH-SEE IF PSEUDOCC 19E03 31500020
SETRCINV NI    IBEXCSW1,FOXFOX-CCHRCV   SET RETRY CODE INVALIC    19E03 31600020
         B     SETSYSTR                 YES-BR-TERMINATE          19E03 31700020
*                                                                 19E03 31800020
TIOSYNCH TM    LW27,TIOSYNCL            TIO SYNCH LATCH UP        19E03 31900020
         BC    ONE,CKPSEUDO             YES-BRANCH-CK PSEUDO CC   19E03 32000020
         LH    WORKREGB,LW2             GET TIO UA                19E03 32100020
         N     WORKREGB,ARMASK          CLEAR UNWANTED            19E03 32200020
         LH    WORKREGC,LW2+TWO         GET UCWAR AND IAB         19E03 32300020
         N     WORKREGC,ARMASK          CLEAR UNWANTED            19E03 32400020
         CR    WORKREGB,WORKREGC        TIO UA EQUALS UCWAR+IAB   19E03 32500020
         BNE   CCHDAINV                 NO-SET SYSTEM TERMINATION 19E03 32600020
CKPSEUDO OI    IBEXCSW1,CCHDAV          SET UNIT ADDRESS VALID    19E03 32700020
CCHDAINV TM    LW0+ONE,PSEUDOCC         IS THIS PSEUDO CONTROL CK 19E03 32800020
         BC    FOURTEEN,HIONBCK         NO-GO CHECK IF HIO BUSY   19E03 32900020
         LA    WORKREGC,FIFTEEN         GET ANDING MASK           19E03 33000020
         IC    WORKREGB,LW23            GET DIAGNOSE INDICATORS   19E03 33100020
         NR    WORKREGB,WORKREGC        IS THIS A DIAGNOSE        19E03 33200020
         BC    EIGHT,HIONBCK            NO-BRANCH-TEST HIO        19E03 33300020
         B     CKDIAGN                  SEE IF DIAGNOSE           19E03 33400020
*                                                                 19E03 33500020
HIONBCK  TM    LW3,HIONBUSY             IS HIO NOT BUSY STATE SET 19E03 34200020
         BC    FOURTEEN,TESTSIOM        NO-BRANCH-TEST SIO MAJOR  19E03 34300020
         TM    LW7+ONE,OPIN             IS OP-IN UP               19E03 34400020
         BC    FOURTEEN,SET0401         NO- GO SET CODES          19E03 34500020
SET0410  OI    IBEXCSW2,RTCODE4+COMPSEL SET RETRY 4,TERM 10    EC715005 34600020
         B     LASTVAL                  GO CK LAST VALIDITY BITS  19E03 34700020
*                                                                 19E03 34800020
TESTSIOM TM    LW3,SIOMAJOR             IS THIS SIO MAJOR OP      19E03 34900020
         BC    ONE,CKCCWLCH             YES-BRANCH-TEST CCW LCA   19E03 35000020
         TM    LW3,CCRESELM             IS THIS CC RESELECT MAJOR 19E03 35100020
         BC    FOURTEEN,CKDATATR        NO-GO CK DATA XFER        19E03 35200020
CKCCWLCH TM    LW3+TWO,CCWLATCH         IS CCW LATCH SET          19E03 35300020
         BC    ONE,CKCMDOUT             YES-BRANCH-SEE IF CMD OUT 19E03 35400020
SET0401  OI    IBEXCSW2,RTCODE4+COMPFES SET RETRY TO 4,TERM TO 01 19E03 35500020
LASTVAL  TM    LW0+TWO,SCSPCK           IS THIS SCS P CHECK       19E03 35600020
         BC    ONE,SETSYSTR             YES-SET SYS TERMINATION   19E03 35700020
         TM    LW2,CMDADDRV             IS CMD ADDRESS VALID      19E03 35800020
         BC    FOURTEEN,CKUSVAL         NO-BRANCH-CHECK US VALID. 19E03 35900020
         OI    IBEXCSW1,CCHCMDV         SET CMD ADDRESS VALID BIT 19E03 36000020
CKUSVAL  TM    LW2,USVALID              IS UNIT STATUS VALID      19E03 36100020
         BC    FOURTEEN,SETRCVAL        NO-BRANCH-SET RC VALID    19E03 36200020
         OI    IBEXCSW1,CCHUSV          SET UNIT STATUS VALID BIT 19E03 36300020
SETRCVAL OI    IBEXCSW1,CCHRCV          SET RETRY CODE VALID BIT  19E03 36400020
CKDCIN   TM    LW1,CCHDCIN              WAS UNIT DISCONNECTED     19E03 36500020
         BZ    KPHOUSE                  NO-GO HOUSEKEEP LOG,EXIT  19E03 36600020
         NI    IBEXCSW2,FOXFOX-COMPSYS  RESET TERMINATION CODE    19E03 36700020
         OI    IBEXCSW2,COMPSEL         SET SELECTIVE RESET       19E03 36800020
         B     KPHOUSE                  HOUSEKEEP LOG-THEN EXIT   19E03 36900020
*                                                                 19E03 37000020
CKCMDOUT TM    LW3+THREE,CMDOUT         HAS CMD OUT BEEN SET      19E03 37100020
         BC    ONE,CKDATAXR             YES-BRANCH-CK DATA XFER   19E03 37200020
         B     SET0410                  GO SET RETRY 4,TERM 10 EC715005 37300020
*                                                                 19E03 37400020
CKDATAXR TM    LW9,DATAXFER             HAS DATA BEEN XFERRED     19E03 37500020
         BC    ONE,CKINDATA             YES-BRANCH-TEST IF INIT   19E03 37600020
SET0110  OI    IBEXCSW2,RTCODE1+COMPSEL SET RETRY 1,TERM 10    EC715005 37700020
         B     LASTVAL                  GO CK LAST VALIDITY       19E03 37800020
*                                                                 19E03 37900020
CKINDATA TM    LW9,INITDATA             INITIAL DATA              19E03 38000020
         BC    ONE,SET0210              YES-BRANCH-SET CODES   EC715005 38100020
SET0310  OI    IBEXCSW2,RTCODE3+COMPSEL SET RETRY 3,TERM 10    EC715005 38200020
         B     LASTVAL                  CHECK LAST OF VALIDITY    19E03 38300020
*                                                                 19E03 38400020
SET0210  OI    IBEXCSW2,RTCODE2+COMPSEL SET RETRY 2,TERM 10    EC715005 38500020
         B     LASTVAL                  GO CK LAST VALIDITY       19E03 38600020
*                                                                 19E03 38700020
CKDATATR TM    LW3,DATAXMAJ             IS THIS DATA XFER MAJOR   19E03 38800020
         BC    ONE,CKINDATA             YES-BRANCH-CK INIT DATA   19E03 38900020
         TM    LW3,CURMAJOR             CUR MAJOR UP              19E03 39000020
         BC    FOURTEEN,CKTIOMAJ        NO-BRANCH-CK TIO MAJOR    19E03 39100020
         TM    LW3+THREE,CMDOUT         CMD OUT SENT              19E03 39200020
         BC    FOURTEEN,SETUAINV        NO-BRANCH-SET UA INVALID  19E03 39300020
         TM    LW2+TWO,SHARSUBC         IS THIS A SHARED SUBCHAN  19E03 39400020
         BC    FOURTEEN,SET0510         NO-BRANCH-SET CODES       19E03 39500020
         TM    LW3+THREE,UCW0111        UCW 0,1 BOTH ONES         19E03 39600020
         BC    ONE,SET0510              YES-BRANCH-SET CODES      19E03 39700020
SETUAINV NI    IBEXCSW1,FOXFOX-CCHDAV   SET UNIT ADDRESS INVALID  19E03 39800020
SET0510  OI    IBEXCSW2,RTCODE5+COMPSEL SET RETRY TO 5,TERM TO 10 19E03 39900020
         B     LASTVAL                  GO CK LAST VALIDITY,EXIT  19E03 40000020
*                                                                 19E03 40100020
SET0501  OI    IBEXCSW2,RTCODE5+COMPFES SET RETRY TO 5,TERM TO 1  19E03 40200020
         B     LASTVAL                  GO CHECK VALIDITY         19E03 40300020
*                                                                 19E03 40400020
CKTIOMAJ TM    LW3,TIOMAJOR             IS THIS TIO MAJOR OP      19E03 40500020
         BC    ONE,CKSCS                YES-BRANCH-CHECK SCS      19E03 40600020
         TM    LW3+ONE,IRPTRESP         IRPT RESPONSE UP          19E03 40700020
         BC    FOURTEEN,SETSYSTR        NO-SET SYSTEM TERMINATION 19E03 40800020
         TM    LW2+TWO,FOURTEEN         ICB EQUAL 7               19E03 40900020
         BC    ONE,SET0501              YES-BRANCH-SET CODES            41000020
         TM    LW2+TWO,ICBD             ICB EQUAL D               19E03 41100020
         BC    ONE,SET0501              YES-BRANCH-SET CODES            41200020
CKUNITSL TM    LW9,UNITSEL              UNIT SELECT               19E03 41300020
         BC    ONE,SET0010              YES-BR-HARDWARE TIO    EC715005 41400020
SET0001  OI    IBEXCSW2,RTCODE0+COMPFES SET RETRY TO 0,TERM TO 01 19E03 41500020
         B     LASTVAL                  GO CK LAST VALIDITY       19E03 41600020
*                                                                 19E03 41700020
SET0010  OI    IBEXCSW2,RTCODE0+COMPSEL SET RETRY 0,TERM 10    EC715005 41720020
         B     LASTVAL                  GO FINISH LAST VALIDITY   19E03 41740020
*                                                                 19E03 41760020
CKSCS    IC    WORKREGB,LW22            GET SCS INDICATORS        19E03 41800020
         LA    WORKREGC,FOURTEEN        GET ANDING MASK           19E03 41900020
         NR    WORKREGB,WORKREGC        CLEAR UNWANTED            19E03 42000020
         IC    WORKREGB,SCSLIST(WORKREGB)  GET SCS EQUALS 1 IND   19E03 42100020
         CR    WORKREGB,WORKREGC        SCS EQUAL 1               19E03 42200020
         BNE   SET0001                  NO-BRANCH-SET CODES       19E03 42300020
         B     CKUNITSL                 GO SEE IF UNIT SELECTED   19E03 42400020
*                                                                 19E03 42500020
CKDIAGN  B     HIONBCK                  GO SEE IF HIO NOT BUSY    19E03 42600020
         SPACE                                                          42700020
CKTIOADR TM    RECBYTE,CCHTIOB          WAS THIS TIO              19E03 42800020
         BZ    SETNOLST                 NO-GO RECORD ONLY         19E03 42900020
         LA    WORKREGB,TWO55      GET ANDING CONSTANT          GB1/71  43000020
         NR    WORKREGB,CUAREG          GET UNIT ADDRESS ONLY     19E03 43100020
         SR    WORKREGC,WORKREGC        CLEAR GARBAGE             19E03 43200020
         IC    WORKREGC,LW2+THREE       GET IAB ADDRESS           19E03 43300020
         CR    WORKREGC,WORKREGB        PROPER ADDRESS            19E03 43400020
         BE    SETNOLST                 YES-BR-GO RECORD          19E03 43500020
         SPACE                                                          43600020
***************************************************************** 19E03 43700020
*THIS SECTION SETS THE SYSTEM TERMINATION(SYSTERM) BIT AND/OR   * 19E03 43800020
*THE RECORD ONLY(CCHNOLST) BIT AND PERFORMS A HOUSEKEEPING      * 19E03 43900020
*FUNCTION ON THE CHANNEL LOGOUT. IT SETS THE LOGOUT AREA TO ONES* 19E03 44000020
*IF A RECORD ENTRY EXISTS,PUTS THE LOG IN THE RECORD ENTRY,     * 19E03 44100020
*RECORDS THE BLAME FIELD AND RETURNS VIA LINKRG2.               * 19E03 44200020
***************************************************************** 19E03 44300020
         SPACE                                                          44400020
SETSYSTR OI    CCHSW2,SYSTERM           SIGNAL SYSTEM TERMINATION 19E03 44500020
SETNOLST OI    CCHSW1,CCHNOLST          SET RECORD ONLY SWITCH    19E03 44600020
*                                                                 19E03 44700020
KPHOUSE  TM    CCHSW2,NOMODEL           MODEL IDENTIFICATION GONE 19E03 44800020
         BC    ONE,TESTRESW             YES-DO NOT RECORD BLAME   19E03 44900020
         IC    WORKREGB,BLAME           GET SOURCE OF ERROR       19E03 45000020
         SLL   WORKREGB,THREE           FORMAT IT                 19E03 45100020
         STC   WORKREGB,IBPRGFG2        RECORD IT                 19E03 45200020
TESTRESW TM    CCHSW1,CCHNORE           NO RE AVAILABLE SET       19E03 45300020
         BC    ONE,CCH80RET             YES-BRANCH-RETURN         19E03 45400020
         MVI   RELENGTH+ONE,RECLENTH    PUT RE LENGTH IN RE       19E03 45500020
         TM    CCHSW2,NOMODEL           MODEL IDENTIFICATION GONE 19E03 45600020
         BC    ONE,CCH80RET             YES - RETURN - BRANCH     19E03 45700020
         MVC   CHNLOG,IOLOG             PUT I/O LOG IN REC ENTRY  19E03 45800020
         MVI   IOLOG,FOXFOX             GET ALL ONES              19E03 45900020
         MVC   IOLOG+ONE(ONE11),IOLOG   PROPAGATE ALL ONES        19E03 46000020
CCH80RET BR    LINKRG2                  RETURN TO ERPIBSET        19E03 46100020
         SPACE 2                                                        46200020
***************************************************************** 19E03 46300020
*THE FOLLOWING CONSTANTS DO NOT CHANGE DURING THE EXECUTION OF  * 19E03 46400020
*THIS ROUTINE                                                   * 19E03 46500020
***************************************************************** 19E03 46600020
         SPACE                                                          46700020
ALLONES  DC    F'-1'                    FOR LOG HOUSEKEEPING      19E03 46800020
ARMASK   DC    X'000001FF'              ANDING MASK               19E03 46900020
SCSLIST  DC    X'0E'                    SUBCHANNEL STATUS BITS    19E03 47000020
         DC    5X'00'                   PADDING                   19E03 47100020
         DC    X'0E000E'                SUBCHANNEL STATUS BITS    19E03 47200020
         DC    6X'00'                   PADDING                   19E03 47300020
CCHSTART EQU   CCH02880                 BEGINNING OF MODULE       19E03 47400020
CCHEND   DS    0C                       END OF THIS ROUTINE       19E03 47500020
MODLEN   EQU   CCHEND-CCHSTART          LENGTH OF ANALYSIS MODULE 19E03 47600020
         SPACE                                                          47700020
***************************************************************** 19E03 47800020
*THE FOLLOWING DSECT IS OF THE LOGOUT AREA FOR THE 2880         * 19E03 47900020
***************************************************************** 19E03 48000020
         SPACE                                                          48100020
IOLOG    DSECT                          2880 CHANNEL LOGOUT AREA  19E03 48200020
LW0      DS    F                        I/O LOGOUT WORD 0         19E03 48300020
LW1      DS    F                        I/O LOGOUT WORD 1         19E03 48400020
LW2      DS    0F                       I/O LOGOUT WORD 2         19E03 48500020
CHANLID DS     C                        CHANNEL NUMBER,BITS 3-6   19E03 48600020
         DS    3C                       REMAINDER OF WORD 2       19E03 48700020
LW3      DS    F                        I/O LOGOUT WORD 3         19E03 48800020
LW4      DS    F                        I/O LOGOUT WORD 4         19E03 48900020
LW5      DS    F                        I/O LOGOUT WORD 5         19E03 49000020
LW6      DS    F                        I/O LOGOUT WORD 6         19E03 49100020
LW7      DS    F                        I/O LOGOUT WORD 7         19E03 49200020
LW8      DS    F                        I/O LOGOUT WORD 8         19E03 49300020
LW9      DS    F                        I/O LOGOUT WORD 9         19E03 49400020
LW10     DS    F                        I/O LOGOUT WORD 10        19E03 49500020
LW11     DS    F                        I/O LOGOUT WORD 11        19E03 49600020
LW12     DS    F                        I/O LOGOUT WORD 12        19E03 49700020
LW13     DS    F                        I/O LOGOUT WORD 13        19E03 49800020
LW14     DS    F                        I/O LOGOUT WORD 14        19E03 49900020
LW15     DS    F                        I/O LOGOUT WORD 15        19E03 50000020
LW16     DS    F                        I/O LOGOUT WORD 16        19E03 50100020
LW17     DS    F                        I/O LOGOUT WORD 17        19E03 50200020
LW18     DS    F                        I/O LOGOUT WORD 18        19E03 50300020
LW19     DS    F                        I/O LOGOUT WORD 19        19E03 50400020
LW20     DS    F                        I/O LOGOUT WORD 20        19E03 50500020
LW21     DS    F                        I/O LOGOUT WORD 21        19E03 50600020
LW22     DS    F                        I/O LOGOUT WORD 22        19E03 50700020
LW23     DS    F                        I/O LOGOUT WORD 23        19E03 50800020
LW24     DS    F                        I/O LOGOUT WORD 24        19E03 50900020
LW25     DS    F                        I/O LOGOUT WORD 25        19E03 51000020
LW26     DS    F                        I/O LOGOUT WORD 26        19E03 51100020
LW27     DS    0F                       I/O LOGOUT WORD 27        19E03 51200020
OPERATN  DS    CL1                      MAJOR OPERATION INDICATOR 19E03 51300020
BLAME    DS    CL1                      SOURCE OF ERROR           19E03 51400020
         DS    CL2                      LAST TWO BYTES N/A        19E03 51500020
         SPACE                                                          51600020
***************************************************************** 19E03 51700020
*WORK ERPIB DSECT                                               * 19E03 51800020
***************************************************************** 19E03 51900020
IBWORK   DSECT                          WORK ERPID DSECT          19E03 52000020
IBUCB    DS    CL4                      UCB FIELD                 19E03 52100020
IBPRGFG1 DS    CL1                      FIRST PGM CONTROLLED SW   19E03 52200020
IBPRGFG2 DS    CL1                      SECOND PGM CONTROLLED SW  19E03 52300020
IBEXCSW1 DS    CL1                      EXTENDED                  19E03 52400020
IBEXCSW2 DS    CL1                        STATUS BYTES            19E03 52500020
CCHSW1   DS    CL1                      BYTE 1-INTERNAL CCH SWS   19E03 52600020
CCHSW2   DS    CL1                      BYTE 2-INTERNAL CCH SWS   19E03 52700020
RECBYTE  DS    CL1                      RECORD BYTE               19E03 52800020
         SPACE                                                          52900020
***************************************************************** 19E03 53000020
*RECORD ENTRY DSECT                                             * 19E03 53100020
***************************************************************** 19E03 53200020
         SPACE                                                          53300020
RECENTRY DSECT                          RECORD ENTRY DSECT        19E03 53400020
COUNT    DS    0C                       BEGINNING OF RECORD ENTRY 19E03 53500020
         DS    CL6                      NOT PERTINENT HERE        19E03 53600020
RELENGTH DS    CL2                      ACTUAL RECORD ENTRY LNG   19E03 53700020
         DS    CL72                     NOT PERTINENT HERE        19E03 53800020
CHANID   DS    C                        CHANNEL IDENTIFICATION    19E03 53900020
         DS    CL7                      NOT PERTINENT HERE        19E03 54000020
CHNLOG   DS    CL112                    CHANNEL LOGOUT FIELD      19E03 54100020
 TITLE   ' CCH RMS MOVE ROUTINE FOR IGFCCH80'                           54200020
CCHNIPIN CSECT                          BEGINNING OF MOVE ROUTINE 19E03 54300020
         SPACE                                                          54400020
*FUNCTION                                                         19E03 54500020
*   THIS ROUTINE WILL OBTAIN A PARAMETER LIST FROM NIP,WHICH WILL 19E03 54600020
*   CONTAIN A BUFFER AREA ADDRESS,USING THAT ADDRESS THIS ROUNINE 19E03 54700020
*   WILL MOVE THE MODULE TO WHICH IT IS ATTACHED INTO THAT AREA   19E03 54800020
*   AND RETURN TO NIP WITH THE NEXT UNUSED BUFFER ADDRESS         19E03 54900020
         SPACE                                                          55000020
*ENTRY POINTS                                                     19E03 55100020
*   CCHNIPIN - FROM NIP                                           19E03 55200020
         SPACE                                                          55300020
*INPUT                                                            19E03 55400020
*   A POINTER TO THE STARTING ADDRESS OF THE BUFFER AREA INTO     19E03 55500020
*   WHICH THE MODULE IS TO BE MOVED                               19E03 55600020
         SPACE                                                          55700020
*OUTPUT                                                           19E03 55800020
*   1. THE MODULE IS MOVED TO THE BUFFER AREA                     19E03 55900020
*   2. THE CHANNEL POINTER TABLE IN THE CCH CENTRAL MODULE IS     19E03 56000020
*      FILLED IN WITH THE ADDRESS OF THE NEW MODULE LOCATION      19E03 56100020
*   FOR EACH SLOT WITH THE ONE BYTE MODULE IDENTIFICATION         19E03 56200020
*   3. THE NEXT BYTE PAST THE END OF THE MODULE IS RETURNED TO    19E03 56300020
*   NIP AS THE UNUSED BUFFER ADDRESS.                             19E03 56400020
         SPACE                                                          56500020
*EXTERNAL REFERENCES                                              19E03 56600020
*   CVT - TO FIND THE POINTER TO THE LOGREC DCB                   19E03 56700020
*   LOGREC DCB - TO FIND THE POINTER TO CCH CENTRAL               19E03 56800020
*   CCH CENTRAL - TO FILL IN THE NEW MODULE ADDRESS FOR           19E03 56900020
*                 COMMUNICATION                                   19E03 57000020
         SPACE                                                          57100020
*EXITS,NORMAL                                                     19E03 57200020
*   RETURN IS VIA LINK REGISTER BACK TO NIP                       19E03 57300020
         SPACE                                                          57400020
*EXITS,ERROR                                                      19E03 57500020
*   NONE                                                          19E03 57600020
         SPACE                                                          57700020
*TABLES/WORK AREA                                                 19E03 57800020
*   NONE                                                          19E03 57900020
         SPACE                                                          58000020
*ATTRIBUTES                                                       19E03 58100020
*   DISABLED,PRIVILEGED AND REUSABLE                              19E03 58200020
         SPACE                                                          58300020
*NOTES                                                            19E03 58400020
*   AFTER THIS ROUTINE IS COMPLETED THE CHANNEL DEPENDENT         19E03 58500020
*   ANALYSIS MODULE IS MOVED AND THIS ROUTINE IS DISREGARDED      19E03 58600020
         SPACE                                                          58700020
*   CHARACTER CODE DEPENDENCIES                                   19E03 58800020
*   THIS CODE IS CHARACTER CODE INDEPENDENT                       19E03 58900020
         EJECT                                                    19E03 59000020
***************************************************************** 19E03 59100020
*   EQUATES- REGISTER AND GENERAL                               * 19E03 59200020
***************************************************************** 19E03 59300020
         SPACE                                                          59400020
PARMREG1 EQU   1                        PARAMETER REGISTER        19E03 59500020
BUFFEREG EQU   2                        ADDR OF BUFFER            19E03 59600020
CCHTABRG EQU   3                        CCH ANAL MODULE PTS       19E03 59700020
POINTREG EQU   4                        CCH COMM TAB ADDR         19E03 59800020
BLOCKREG EQU   5                        MAX SIZE FOR MVC(256)     19E03 59900020
EXREG    EQU   6                        MAX DYN LNG FOR MVC(255)  19E03 60000020
SIZEREG  EQU   7                        SIZE OF MODULE            19E03 60100020
MODULREG EQU   8                        BEGIN ADDR OF MODULE      19E03 60200020
RETNREG  EQU   14                       RETURN ADDR               19E03 60300020
BASEREG  EQU   15                       BASE FOR MOVE ROUTINE     19E03 60400020
BLKSIZE  EQU   256                      MAX LENGTH FOR MOVE       19E03 60500020
TWO55    EQU   255                      MAX DYN LNG  FOR MVC      19E03 60600020
ENDLIST  EQU   X'FF'                    END OF LIST DELIMITER     19E03 60700020
SIXTEEN  EQU   16                       CONSTANT FOR DISPLACEMENT 19E03 60800020
LOGREC   EQU   X'74'                    DISPL OF LOGREC DCB(CVT)  19E03 60900020
DEPMODID EQU   X'80'                    MODULE ID FLAG            19E03 61000020
         SPACE                                                          61100020
         USING CCHNIPIN,BASEREG         BASE FOR THIS MODULE      19E03 61200020
         ENTRY CCHNIPIN                     PRIMARY ENTRY POINT   19E03 61300020
         USING CCHSECT,POINTREG         BASE FOR DSECT            19E03 61400020
         L     MODULREG,MODADDR         GET BEG OF MODULE         19E03 61500020
         LA    SIZEREG,MODLEN           GET MODULE LENGTH         19E03 61600020
         LA    EXREG,TWO55              MAX DYN MVC LENGTH        19E03 61700020
         LA    BLOCKREG,BLKSIZE         MAX MVC LENGTH            19E03 61800020
         L     CVTREG,SIXTEEN           PTR TO CVT                19E03 61900020
         L     POINTREG,LOGREC(CVTREG)  PTR TO LOGREC DCB         19E03 62000020
         L     POINTREG,ZERO(POINTREG)  PTR TO CCH COMM TAB       19E03 62100020
         L     CCHTABRG,CCHANTAB        PTR TO CCH DEP MODUL PTRS 19E03 62200020
         L     BUFFEREG,ZERO(PARMREG1)  GET BUFFER ADDR FROM PLIST19E03 62300020
COMPARE  CLI   THREE(CCHTABRG),DEPMODID PTR TO DEP MODULE NEEDED  19E03 62400020
         BNE   UPINDEX                  NO-TRY NEXT SLOT          19E03 62500020
         OC    ONE(TWO,CCHTABRG),ONE(CCHTABRG)    IN USE          19E03 62600020
         BNZ   UPINDEX                  YES,SKIP                  19E03 62700020
         MVC   ONE(THREE,CCHTABRG),ONE(PARMREG1)  STORE ADDRESS   19E03 62800020
UPINDEX  LA    CCHTABRG,FOUR(CCHTABRG)  GET NEXT ADDR LOCATION    19E03 62900020
         CLI   ZERO(CCHTABRG),ENDLIST   DONE                      19E03 63000020
         BNE   COMPARE                  YES-GO MOVE MODULE        19E03 63100020
COMPAR   CR    SIZEREG,BLOCKREG       LESS THAN 256 BYTES TO MOVE 19E03 63200020
         BNH   LASTMOVE                YES-BRANCH                 19E03 63300020
         EX    EXREG,MOVEMOD            MOVE 256 BYTES INTO BFR   19E03 63400020
         AR    BUFFEREG,BLOCKREG        UPDATE BUFFER ADDR        19E03 63500020
         AR    MODULREG,BLOCKREG        UPDATE ORIGIN ADDR        19E03 63600020
         SR    SIZEREG,BLOCKREG         DECREMENT LENGTH TO MOVE  19E03 63700020
         B     COMPAR                   LOOP BACK                 19E03 63800020
LASTMOVE LR    BLOCKREG,SIZEREG         SAVE OVERFLOW             19E03 63900020
         BCTR  SIZEREG,ZERO             ADJUST DYNAMICALLY SIZE   19E03 64000020
         LTR   SIZEREG,SIZEREG          TEST DONE                 19E03 64100020
         BL    RETURNIP                 IF NEG,DONE               19E03 64200020
         EX    SIZEREG,MOVEMOD          MOVE LAST REMAINING BYTES 19E03 64300020
UPADDR   AR    BUFFEREG,BLOCKREG        ADJUST BFR ADR TO UNUSED  19E03 64400020
RETURNIP ST    BUFFEREG,ZERO(PARMREG1)  STORE FOR NIP             19E03 64500020
         BR    RETNREG                  RETURN                    19E03 64600020
         SPACE                                                          64700020
***************************************************************** 19E03 64800020
*   INSTRUCTIONS EXECUTED INTO BY MAINLINE AND CONSTANTS        * 19E03 64900020
***************************************************************** 19E03 65000020
         SPACE                                                          65100020
MOVEMOD  MVC   ZERO(ZERO,BUFFEREG),ZERO(MODULREG)  MOVES MODULES  19E03 65200020
*                                                                 19E03 65300020
MODADDR  DC    A(CCHSTART)              HOLDS MODULE START ADDR   19E03 65400020
         SPACE                                                          65500020
CCHSECT  DSECT                          MAP OF CCH COMM TABLE     19E03 65600020
ERPIBFD  DS    F                        ADDRESS OF ERPIBS         19E03 65700020
RECORD   DS    F                        ADDRESS OF RECORDS        19E03 65800020
CCHBASE  DS    F                        CCH ENTRY POINT           19E03 65900020
CCHANTAB DS    F                        CHANNEL POINTER TABLE     19E03 66000020
         END   CCHNIPIN                                                 66100020
