IGFDDR02 CSECT                                                          00400021
*************************************************************           00404021
*                                                                       00408021
* STATUS:                                                               00412021
*                                                                       00416021
*    RELEASE 21.8                                                       00420021
*                                                                       00424021
*                                                                       00428021
* FUNCTION:                                                             00432021
*                                                                       00436021
*    THIS MODULE IS THE CHANNEL END APPENDAGE FOR DDR. IT GETS CONTROL  00440021
*    VIA SVC 15 WITH THE IOB EXCEPTION AND ERROR BITS OFF. IT WILL      00444021
*    BRANCH INTO A VECTOR TABLE WITHIN IOS FOR A FUNCTION TO BE         00448021
*    PERFORMED BY IOS. THESE FUNTIONS INCLUDE EXCP AND POST WITH OR     00452021
*    WITHOUT CONTROL OF THE DEVICE; SWAPPING THE UCB INFORMATION;       00456021
*    CANCELLING DDR PROCESSING; AND RETRYING THE FAILING REQUEST.       00460021
*                                                                       00464021
*                                                                       00468021
* ENTRY POINT:                                                          00472021
*                                                                       00476021
*         IGFDDR02 - FIRST INSTRUCTION OF MODULE.                       00480021
*                                                                       00484021
*                                                                       00488021
* INPUT:                                                                00492021
*                                                                       00496021
*    FOR ALL ENTRIES, REG 1 = DDR RQE ADDR, REG 2 = DDR IOB ADDR,       00500021
*    REG 3 = DDR DEB ADDR, REG 4 = DDR DCB ADDR, REG 7 = UCB ADDR.      00504021
*    BIT SETTINGS ARE:                                                  00508021
*    CANCEL IN DDRFLGSC TO CANCEL DDR PROCESSING. SET BY IGC0008E,      00512021
*    AND IGC0208E.                                                      00516021
*    IONOCTRL IN DDRFLGSC TO EXCP WITHOUT CONTROL OF THE DEVICE. SET    00520021
*    BY IGC0108E, IGC0308E AND IGC0408E.                                00524021
*    SWAPUCB IN DDRFLGSC TO SWAP UCB INFORMATION. SET BY IGC0108E,      00528021
*    IGC0308E AND IGC0408E.                                             00532021
*    IOCONTRL IN DDRFLGSD TO EXCP WITH CONTROL OF THE DEVICE. SET BY    00536021
*    IGC0408E, IGC0608E AND IGC0708E.                                   00540021
*    FORSPACE IN DDRFLGSD TO FOWARD SPACE FILE. SET BY IGC0408E.        00544021
*    READ IN DDRFLGSD TO READ A RECORD. SET BY IGC0408E.                00548021
*    RETRY IN DDRFLGSE TO RETRY THE FAILING RQE. SET BY IGC0208E AND    00552021
*    IGC0408E.                                                          00556021
*    IF NONE OF THE ABOVE ARE ON, DDR SVC IS TO BE POSTED WITH CONTROL  00560021
*    OF THE DEVICE.                                                     00564021
*                                                                       00568021
*                                                                       00572021
* OUTPUT:                                                               00576021
*                                                                       00580021
*    FOR ALL EXITS BUT RETRY USER, THE REGISTERS ABOVE REMAIN THE SAME. 00584021
*    FOR RETRY USER, REGISTER 1 = USER RQE ADDR.                        00588021
*    FOR OPERATOR SWAPS, FFRFLGSC MAY HAVE THE ERPINPRO BIT ON.         00592021
*                                                                       00596021
*                                                                       00600021
* EXTERNAL REFERENCES:                                                  00604021
*                                                                       00608021
*         IOS/DDR VECTOR TABLE WITHIN IOS.                              00612021
*                                                                       00616021
*                                                                       00620021
* EXITS-NORMAL:                                                         00624021
*                                                                       00628021
*         TO IOS VIA BRANCH ENTRY INTO THE VECTOR TABLE FOR THE         00632021
*    FOLLOWING FUNCTION:                                                00636021
*    VECTOR TABLE                                                       00640021
*    +4  = EXCP WITH CONTROL OF THE DEVICE.                             00644021
*    +8  = EXCP WITHOUT CONTROL OF THE DEVICE.                          00648021
*    +12 = POST DDR WITHOUT CONTROL OF THE DEVICE.                      00652021
*    +16 = POST DDR WITH CONTROL OF THE DEVICE.                         00656021
*    +20 = RETRY USER'S RQE.                                            00660021
*    +24 = SWAP UCB INFORMATION.                                        00664021
*    +28 = CANCEL DDR PROCESSING.                                       00668021
*                                                                       00672021
*                                                                       00676021
* EXITS-ERROR:                                                          00680021
*                                                                       00684021
*         NONE.                                                         00688021
*                                                                       00692021
*                                                                       00696021
* TABLES/WORK AREAS:                                                    00700021
*                                                                       00704021
*         IORMSCOM - THE DDR COMMUNICATIONS AREA.                       00708021
*         IOS/DDR VECTOR TABLE IN IOS.                                  00712021
*                                                                       00716021
*                                                                       00720021
* ATTRIBUTES:                                                           00724021
*                                                                       00728021
*         RESIDENT. DISABLED. SERIALLY REUSABLE.                        00732021
*                                                                       00736021
*                                                                       00740021
* CHARACTER CODE DEPENDENCY:                                            00744021
*                                                                       00748021
*         NONE.                                                         00752021
*                                                                       00756021
*                                                                       00757021
*        APAR 66517 (INCORRECT POSITIONING)   9/12/73                   00758021
*        APAR  63472  (WRONG UCB FILE COUNT FIELD)  9/14/73             00758521
*        APAR 69365 (USER CANCELLED DURING REPOS. -- DDR ATTEMPTS       00758621
*                    TO RETRY -- UCBERR FLAG LEFT ON)  3/6/74           00758721
*      APAR  71001 ( INCORRECT PROCESSING OF FLAGS)            @SA71001 00758821
*        PTM 0028                                                       00759021
*************************************************************           00760021
         SPACE 2                                                        00764021
         TITLE '   IGFDDR02 - CHANNEL END APPENDAGE '                   00800021
         USING *,BASE                   MODULE ADDR                     01200021
         L     CVTREG,CVTPTR            CVT PTR                         01600021
         USING CVTDSECT,CVTREG          CVT ADDR                        02000021
         L     COMMPTR,CVTDCB           LOGREC DCB PTR                  02400021
         L     COMMPTR,N0(COMMPTR)      IORMSCOM PTR                    02800021
         USING IORMS,COMMPTR            IORMSCOM ADDR                   03200021
         DROP  CVTREG                   NO LONGER NEED CVT PTR          03600021
*                                                                       04000021
         L     IOVTPTR,IOSVT            IOS/DDR VECTOR TABLE PTR        04400021
         L     WKREG13,USRDCB           USER DCB PTR                    04800021
         LA    WKREG13,N0(WKREG13)       CLEAR HIGH ORDER BYTE          05000021
         NI    DDRFLGSF,ALL-REENTRY     TURN OFF REENTRY BIT            05200021
         NI    DDRDCB+N44,ALL-NOERP     RESET ERP BIT FOR ERP USE       05600021
         SPACE 2                                                        05650021
*                                                                       05700021
***   CANCEL DDR                                                        05750021
* CANCEL CODE MOVED TO BEGINNING OF MODULE TO PREVENT ERRORS   @SA71001 05760021
* IF OTHER FLAGS ARE NOT CLEANED UP.                           @SA71001 05770021
         TM    DDRFLGSC,CANCEL     IS DDR TO BE CANCELLED               05800021
         BZ    CKERP               NO - CONTINUE                        05850021
         LH    RQEPTR,USRRQE       USER RQE PTR                         05900021
         B     N28(IOVTPTR)        CANCEL DDR REQUEST                   05950021
         SPACE 2                                                        06000021
*                                                                       06400021
***      ERP IN PROCESS                                                 06800021
*                                                                       07200021
CKERP    EQU   *                                                        07400021
         TM    DDRFLGSA,OPINIT          IS THIS OPERATOR SWAP           07600021
         BZ    CKNOCTRL                 NO, SEE IF EXCP W/O CTRL WANTED 08000021
          LTR    WKREG13,WKREG13        IS THIS A DASD SWAP        *    08050021
          BZ     CKNOCTRL               YES, SKIP DCB CHECKS       *    08100021
          SPACE                                                         08150021
*   NOTE:   USE OF DCB IN 'CHKRETRY' SECTION AND 'CHKREAD' SECTION      08200021
*           SHOULD BE OKAY ,,, SHOULD NOT BE DOING THESE OPERATIONS     08250021
*           UNLESS IT IS A TAPE SWAP.                          @S00000P 08300021
          SPACE                                                         08350021
         TM    N44(WKREG13),ERPIN       IS ERP IN PROCESS               08400021
         BZ    CKNOCTRL                 NO, SEE IF EXCP W/O CTRL WANTED 08800021
         TM    N18(FMUCB),TAPE     IS DEVICE TAPE                 60486 08850021
         BZ    CKNOCTRL            NO, DISREGARD ERP IN PROCESS   60486 08900021
         OI    DDRFLGSC,ERPINPRO        FOR ERP IN PROCESS MSG IGF504I  09200021
         B     N12(IOVTPTR)             POST DDR SVC W/O CONTROL        09600021
         SPACE 2                                                        10000021
*                                                                       10400021
***                                                                     10800021
*        RE-EXCP WITHOUT CONTROL                                        11200021
CKNOCTRL EQU   *                                                        11600021
         TM    DDRFLGSC,IONOCTRL        IS EXCP W/O CTRL WANTED         12000021
         BZ    WITHCTRL                 NO, SEE IF EXCP W/CTRL WANTED   12400021
         NI    DDRFLGSC,ALL-IONOCTRL    TURN OFF INDICATOR              12800021
         B     N8(IOVTPTR)              RE-EXCP WITHOUT CONTROL         13200021
         SPACE 2                                                        13600021
*                                                                       14000021
***      RE-EXCP WITH CONTROL                                           14400021
*                                                                       14800021
WITHCTRL EQU   *                                                        15200021
         TM    DDRFLGSD,IOCONTRL        IS EXCP WITH CONTROL WANTED     15600021
         BZ    CHKSWAP                  NO, SEE IF UCB SWAP IS WANTED   16000021
         NI    DDRFLGSD,ALL-IOCONTRL    TURN OFF INDICATOR              16400021
         B     N4(IOVTPTR)              RE-EXCP WITH CONTROL            16800021
         SPACE 2                                                        17200021
*                                                                       17600021
***      SWAP UCB INFORMATION                                           18000021
*                                                                       18400021
CHKSWAP  EQU   *                                                        18800021
         TM    DDRFLGSC,SWAPUCB         IS UCB INFO TO BE SWAPPED       19200021
         BZ    CHKRETRY                 NO, SEE IF USER IS TO BE RETRID 19600021
         LA    WKREG0,DDRFMUCB          ADDR OF UCB PTRS IN REG 0       20000021
         B     N24(IOVTPTR)             SWAP UCB INFO                   20400021
         SPACE 2                                                        20800021
*                                                                       21200021
***      RETRY USER                                                     21600021
*                                                                       22000021
CHKRETRY EQU   *                                                        22400021
         TM    DDRFLGSE,RETRY           SHOULD USER BE RETRIED          22800021
         BZ    CHKFSF                   NO, SEE IF FOWARD SPACE WANTED  23200021
* FOLLOWING CHECK ADDED TO TEST FOR PURGED RQE                 @SA69365 23220021
         L     WKREG11,N0(IOVTPTR)      LOAD DDR WAITQ PTR              23240021
         TM    N4(WKREG11),PURGE        TEST FOR THIS RQE PURGED        23280021
         BZ    CONRETRY                 NO -- CONTINUE RETRY            23320021
PURGED   NI    N4(WKREG11),ALL-PURGE    RQE IS PURGED,TURN OFF          23360021
         OI    DDRFLGSG,WTQPURGD        SET INDICATOR -- PURGED         23400021
         OI    DDRFLGSB,DDREND          TERMINATE SWAP                  23440021
         B     N12(IOVTPTR)             POST DDR W/O CONTROL            23480021
CONRETRY EQU   *                                                        23520021
         LH    RQEPTR,USRRQE            USER RQE PTR           @SM0028K 23720021
         CLI   N18(FMUCB),TAPE          IS DEVICE TAPE                  24000021
         BNE   GORETRY                  NO, GO RETRY USER               24400021
         TM    DDRFLGSG,DVCEND          DEVICE END ON INITIAL ERR       24800021
         BZ    GORETRY                  NO, GO RETRY USER         37949 25600021
         L     WKREG11,N12(WKREG13)     USER DCB BLK CNT          37949 26000021
         TM    DDRFLGSF,NEGCOUNT        IS USER READING BACK      37949 26050000
         BO    ADD                      YES, ADD TO HIS BLK CNT   37949 26100000
         SH    WKREG11,N28(OURIOB)      SUBT INCREMENT FROM COUNT 37949 26400021
*                                                                       26550000
STORECNT EQU   *                                                        26600000
         ST    WKREG11,N12(WKREG13)     STORE ADJUSTED COUNT      37949 26800021
*                                                                       27050000
GORETRY  EQU   *                                                        27200021
* RETRY LOGIC ASSUMES THAT AT THIS POINT THE USER RQE IS VALID AND      27250021
* WILL BE RETRIED BY IOS, I.E., THERE IS NO CONDITION THAT WILL         27300021
* PREVENT IOS FROM PERFORMING THE RETRY. NOTE THAT THIS MODULE          27350021
* EXECUTES DISABLED AND A CHECK HAS BEEN MADE ABOVE TO ENSURE           27400021
* THAT THE RQE HAS NOT BEEN PURGED.                                     27450021
         OI    DDRFLGSG,RETRIED    SET FLAG. USER RETRIED.              27500021
         B     N20(IOVTPTR)             RETRY USER RQE                  27600021
*                                                                       27650000
ADD      EQU   *                                                        27700000
         AH    WKREG11,N28(OURIOB)      ADD INCREMENT TO COUNT    37949 27750000
         B     STORECNT                 GO STORE NEW COUNT        37949 27800000
         SPACE 2                                                        28000021
*                                                                       28400021
***      FOWARD SPACE FILE                                              28800021
*                                                                       29200021
CHKFSF   EQU   *                                                        29600021
         TM    DDRFLGSD,FORSPACE        IS FORWARD SPACE FILE WANTED    30000021
         BZ    CHKREAD                  NO SEE IF READ IS WANTED        30400021
         CLC   N36(N2,FMUCB),FILECNT  ARE FILE COUNTS EQUAL     63472   30800021
         BNE   ADDFILE                  NO, GO ADD 1 TO DDR FILE COUNT  31200021
         NI    DDRFLGSD,ALL-FORSPACE    TURN OFF FSF INDICATOR          31600021
         OI    DDRFLGSD,READ            TO READ A RECORD                32000021
*                                                                       32400021
         TM    DDRFLGSG,NEGBLKCT        USER BLOCK CT. NEG.             32800021
         BZ    INITBLK                  NO, GO INIT BLOCK COUNT         33200021
         MVI   DDRWORK,BACKSPAC         BACK SPACE FILE COMMAND IN CCW  33600021
         B     N4(IOVTPTR)              RE-EXCP WITH CONTROL            34000021
*                                                                       34400021
ADDFILE  EQU   *                                                        34800021
         OI    DDRFLGSF,REINIT          TO RE-INITIALIZE DDR BLK COUNT  35200021
         LH    WKREG11,FILECNT          DDR FILE COUNT                  35600021
         AH    WKREG11,ONE              ADD ONE TO IT                   36000021
         STH   WKREG11,FILECNT          STORE NEW COUNT                 36400021
         B     N4(IOVTPTR)              RE-EXCP WITH CONTROL            36800021
         SPACE 2                                                        37200021
*                                                                       37600021
***      READ RECORD                                                    38000021
*                                                                       38400021
CHKREAD  EQU   *                                                        38800021
         TM    DDRFLGSD,READ            IS RECORD TO BE READ            39200021
         BZ    POSTDDR                  POST DDR WITHOUT CONTROL        39600021
*                                                                       40000021
INITBLK  EQU   *                                                        40400021
         TM    DDRFLGSF,REINIT          IS BLK CNT TO BE REINITIALIZED  40800021
         BZ    CKBLKCNT                 NO, SEE IF BLK CNTS ARE EQUAL   41200021
         NI    DDRFLGSF,ALL-REINIT      TURN OF REINIT INDICATOR        41600021
         LA    WKREG11,N1               TO RE-INIT BLK COUNT            41950000
         TM    DDRFLGSF,NEGCOUNT        IS COUNT TO BE INIT TO -1       41960000
         BZ    INITZERO                 NO, INIT COUNT TO ZERO          41970000
         LNR   WKREG11,WKREG11          NEGATIVE 1 FOR INIT             41980000
         ST    WKREG11,DDRDCB+N12       INIT BLK COUNT TO -1            41990000
         B     CKBLKCNT                 GO CHECK THE BLOCK COUNT        41992000
*                                                                       41994000
INITZERO EQU   *                                                        41996000
         XC    DDRDCB+N12(N4),DDRDCB+N12 CLEAR DDR BLOCK COUNT          42000021
         TM    DDRFLGSA,OPINIT          IS THIS OPERATOR SWAP           42400021
         BO    CKBLKCNT                 YES, SEE IF BLK CNTS ARE EQUAL  42800021
         TM    DDRFLGSG,NEGBLKCT        IS USER BLOCK CT. NEG.          43600021
         BZ    INITONE                  NO, GO INIT COUNT TO ONE        44000021
         LNR   WKREG11,WKREG11          NEGATIVE ONE FOR INIT           44400021
         ST    WKREG11,DDRDCB+N12       INIT DDR BLK CNT TO -1          44800021
         B     CKBLKCNT                 GO SEE IF BLK CNTS ARE EQUAL    45200021
*                                                                       45600021
INITONE  TM    DDRFLGSG,DVCEND          DEVICE END PRESENT IN           46000021
*                                       USER STATUS?                    46090021
         BZ    NOSTORE             NO, INIT TO ZERO               66517 46180021
         ST    WKREG11,DDRDCB+N12  YES, INIT TO ONE               66517 46240021
NOSTORE  L     WKREG13,USRDCB      RESTORE USER DCB               66517 46300021
*                                                                       46400021
CKBLKCNT EQU   *                                                        46800021
         CLC   DDRDCB+N12(N4),BLKCNT    ARE BLOCK COUNTS EQUAL          47200021
         BE    GOPOST                   YES, GO PREPARE TO POST DDR SVC 47600021
         MVI   DDRWORK,READDATA         READ COMMAND INTO CCW           48000021
         TM    DDRFLGSG,NEGBLKCT        USER BLOCK CT. NEG.             48400021
         BZ    N4(IOVTPTR)              NO, RE-EXCP WITH CONTROL        48800021
         MVI   DDRWORK,READBACK         READ BACKWARD COMMAND INTO CCW  49200021
         B     N4(IOVTPTR)              RE-EXCP WITH CONTROL            49600021
*                                                                       50000021
GOPOST   EQU   *                                                        50400021
         OI    DDRFLGSF,COMPLETE        TO INDICATE REPOS. COMPLETE     50550000
         NI    DDRFLGSD,ALL-READ        TURN OFF READ INDICATOR         50800021
         TM    DDRFLGSA,OPINIT          IS THIS OPERATOR SWAP           51200021
         BO    N12(IOVTPTR)             YES - POST DDR WO CNTRL         51600021
* FOLLOWING CHECK ADDED TO TEST FOR PURGED RQE                 @SA69365 51650021
         L     WKREG11,N0(IOVTPTR)      GET WAIT QUEUE PTR              51700021
         TM    N4(WKREG11),PURGE        RQE PURGED?                     51800021
         BZ    N16(IOVTPTR)             NO -- POST DDR                  51900021
         B     PURGED                   YES -- CLEAN UP                 52000021
         SPACE 2                                                        52400021
*                                                                       52800021
***   POST DDR WITH CONTROL                                             53200021
*                                                                       53600021
POSTDDR  EQU   *                                                        54000021
         B     N16(IOVTPTR)             POST DDR WITH CONTROL           54200021
      SPACE                                                             54800021
* CANCEL CODE MOVED TO BEGINNING OF MODULE                     @SA71001 55400021
         SPACE 5                                                        56000021
*                                                                       56400021
***      REGISTER EQUATES                                               56800021
*                                                                       57200021
WKREG0   EQU   0                        PARM REG TO IOS FOR UCB SWAP    57600021
RQEPTR   EQU   1                        RQE PTR                         58000021
OURIOB   EQU   2                        DDR IOB PTR                     58400021
FMUCB    EQU   7                        'FROM' UCB PTR                  58800021
COMMPTR  EQU   10                       IORMSCOM PTR                    59200021
CVTREG   EQU   11                       CVT PTR                         59600021
WKREG11  EQU   11                       WORK REGISTER                   60000021
IOVTPTR  EQU   12                       IOS/DDR VECTOR TABLE PTR        60400021
WKREG13  EQU   13                       WORK REGISTER                   60800021
BASE     EQU   15                       MODULE BASE REGISTER            61200021
         SPACE 3                                                        61600021
*                                                                       62000021
***      INTEGER EQUATES                                                62400021
*                                                                       62800021
N0       EQU   0                        DISPLACEMENT VALUE              63200021
N1       EQU   1                        DISPLACEMENT VALUE              63600021
N2       EQU   2                        DISPLACEMENT VALUE              64000021
N4       EQU   4                        DISPLACEMENT VALUE              64400021
N6       EQU   6                        DISPLACEMENT VALUE              64800021
N8       EQU   8                        DISPLACEMENT VALUE              65200021
N12      EQU   12                       DISPLACEMENT VALUE              65600021
N16      EQU   16                       DISPLACEMENT VALUE              66000021
N18      EQU   18                       DISPLACEMENT VALUE              66400021
N20      EQU   20                       DISPLACEMENT VALUE              66800021
N24      EQU   24                       DISPLACEMENT VALUE              67200021
N28      EQU   28                       DISPLACEMENT VALUE              67600021
N36      EQU   36            DISP VALUE                        63472    67800021
N38      EQU   38                       DISPLACEMENT VALUE              68000021
N44      EQU   44                       DISPLACEMENT VALUE              68400021
         SPACE 3                                                        68800021
***      GENERAL EQUATES                                                69200021
*                                                                       69600021
ALL      EQU   X'FF'                    MASK FOR 'AND' INSTRUCTIONS     70000021
BACKSPAC EQU   X'2F'                    BACK SPACE FILE COMMAND         70400021
DEVICEND EQU   X'04'                    DEVICE END STATUS               70800021
ERPIN    EQU   X'40'                    DCB BIT TO SHOW ERP IN PROCESS  71200021
NOERP    EQU   X'0C'                    NEVER USE ERP BIT IN DCB        72000021
READBACK EQU   X'0C'                    READ BACKWARD COMMAND           72400021
READDATA EQU   X'02'                    READ COMMAND                    72800021
TAPE     EQU   X'80'                    MAGNETIC TAPE BIT IN UCB TYPE   73200021
UCBERR   EQU   X'01'                    UCB ERROR FLAG                  73600021
PURGE   EQU    X'80'                    IND.=WAIT QUEUE PURGED          73800021
*                                                                       74000021
         DS    0F                       FULL WORD BOUNDRY               74400021
ONE      DC    H'1'                     HALFWORD CONSTANT OF ONE        74800021
*                                                                       75200021
CVTDSECT DSECT                                                          75600021
         CVT                                                            76000021
*                                                                       76400021
         IORMSCOM                                                       76800021
*/*IGFDDR02:      CHART                                              */ 96050000
*/*IGFDDR02:      E IGFDDR02                                         */ 96100000
*/*               P ESTABLISH ALL ADDRESSABILITY                     */ 96150000
*/*               P GET @ OF IOS DDR VECTOR TABLE. PUT IN IOVTPTR    */ 96200000
*/*               P TURN OFF REENTRY BIT                             */ 96250000
*/*               P TURN OFF ERP BIT IN DDR DCB                      */ 96300000
*/*               D (YES,,NO,CKNOCTRL) IS THIS AN OPERATOR SWAP ?    */ 96350000
*/*               D (YES,,NO,CKNOCTRL) IS ERP IN PROCESS ?           */ 96400000
*/*               P TURN ON ERP IN PROCESS BIT                       */ 96450000
*/*               L () IOS - BRANCH TO IOVTPTR + 12                  */ 96460000
*/*               COMMENT (2,6) POST DDR W/O                         */ 96470000
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96480000
*/*CKNOCTRL:      D (YES,,NO,WITHCTRL) IS EXCP W/O CONTROL WANTED ?  */ 96490000
*/*               P TURN OFF IONOCTRL BIT                            */ 96492000
*/*               L () IOS - BRANCH TO IOVTPTR + 8                   */ 96494000
*/*               COMMENT (2,6) RE-EXCP W/O                          */ 96496000
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96498000
*/*WITHCTRL:      D (YES,,NO,CHKSWAP) IS EXCP WITH CONTROL WANTED ?  */ 96498400
*/*               P TURN OFF IOCONTROL BIT                           */ 96498800
*/*               L () IOS - BRANCH TO IOVTPTR + 4                   */ 96499200
*/*               COMMENT (2,6) RE-EXCP WITH                         */ 96499600
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96499700
*/*CHKSWAP:       D (YES,,NO,CHKRETRY) IS UCB INFO. TO BE SWAPPED ?  */ 96499800
*/*               P PUT ADDRESS OF DDRFMUCB IN R0                    */ 96499900
*/*               L () IOS - BRANCH TO IOVTPTR + 24                  */ 96549900
*/*               COMMENT (2,6) SWAP UCB                             */ 96559900
*/*               COMMENT (3,6) INFORMATION                          */ 96569900
*/*CHKRETRY:      D (YES,,NO,CHKFSF) IS USER TO BE RETRIED ?         */ 96579900
*/*               P PUT USER RQE @ IN R1                             */ 96589900
*/*               D (YES,,NO,GORETRY) IS THIS AN ERROR SWAP FOR TAPE?*/ 96591900
*/*               D (YES,,NO,GORETRY) DEVICE END ON INITIAL ERROR ?  */ 96593900
*/*               P SUBTRACT IOB INCREMENT FROM USER BLOCK COUNT     */ 96595900
*/*GORETRY:       L () IOS - BRANCH TO IOVTPTR + 20                  */ 96597900
*/*               COMMENT (2,6) RETRY USER                           */ 96598300
*/*               COMMENT (3,6) AFTER SWAP                           */ 96598700
*/*CHKFSF:        D (YES,,NO,CHKREAD) IS FRWD. SPACE FILE WANTED ?   */ 96599100
*/*               D (YES,,NO,ADDFILE) DOES UCB FILECNT = DDR FILECNT */ 96599500
*/*               P TURN OFF FWDSPACE BIT                            */ 96599600
*/*               P TURN ON READ BIT                                 */ 96599700
*/*               D (YES,,NO,INITBLK) IS USER BLOCK COUNT NEGATIVE ? */ 96599800
*/*               P SET BSF COMMAND IN CCW                           */ 96649800
*/*               L () IOS - BRANCH TO IOVTPTR + 4                   */ 96659800
*/*               COMMENT (2,6) RE-EXCP WITH                         */ 96669800
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96679800
*/*CHKREAD:       D (YES,,NO,CKCANCEL) IS THE READ BIT ON ?          */ 96689800
*/*INITBLK:       D (YES,,NO,CKBLKCNT) IS REINIT BIT ON ?            */ 96691800
*/*               P TURN OFF REINIT BIT                              */ 96693800
*/*               D (NO,,YES,CKBLKCNT) IS SWAP OPERATOR INITIATED ?  */ 96695800
*/*               D (YES,,NO,INITONE) IS THE USER BLOCK COUNT NEG. ? */ 96697800
*/*               P INITIALIZE DDR BLOCK COUNT TO NEGATIVE ONE       */ 96698200
*/*CKBLKCNT:      D (NO,,YES,GOPOST) ARE USER AND DDR BLKCNTS EQUAL? */ 96698600
*/*               P SET UP CCW FOR READ                              */ 96699000
*/*               D (YES,,NO,%A) IS THE USER BLOCK COUNT NEG. ?      */ 96699400
*/*               P SET UP CCW FOR READ BACKWARD                     */ 96699500
*/*%A:            L () IOS - BRANCH TO IOVTPTR + 4                   */ 96699600
*/*               COMMENT (2,6) RE-EXCP WITH                         */ 96699700
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96749700
*/*INITONE:       P (,CKBLKCNT) INITIALIZE DDR BLOCK COUNT TO 1      */ 96759700
*/*GOPOST:        P TURN OFF READ INDICATOR BIT                      */ 96769700
*/*               D (NO,,YES,%B) IS THIS AN OPERATOR SWAP ?          */ 96779700
*/*               L () IOS - BRANCH TO IOVTPTR + 16                  */ 96789700
*/*               COMMENT (2,6) POST DDR WITH                        */ 96791700
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96793700
*/*%B:            L () IOS - BRANCH TO IOVTPTR + 12                  */ 96795700
*/*               COMMENT (2,6) POST DDR W/O                         */ 96797700
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96798100
*/*ADDFILE:       P TURN ON REINIT BIT                               */ 96798500
*/*               P ADD ONE TO THE DDR FILE COUNT                    */ 96798900
*/*               L () IOS - BRANCH TO IOVTPTR + 4                   */ 96799300
*/*               COMMENT (2,6) RE-EXCP WITH                         */ 96799400
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96799500
*/*CKCANCEL:      D (YES,,NO,%C) IS THE CANCEL BIT ON ?              */ 96799600
*/*               L () IOS - BRANCH TO IOVTPTR + 28                  */ 96849600
*/*               COMMENT (2,6) DDR REQUEST CANCELLED                */ 96859600
*/*               COMMENT (3,6) BY OPERATOR                          */ 96869600
*/*%C:            L () IOS - BRANCH TO IOVTPTR + 16                  */ 96879600
*/*               COMMENT (2,6) POST DDR WITH                        */ 96889600
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 96891600
*/*IGFDDR02:      END                                                */ 96893600
         END                                                            96899600
