IGFDDR03 CSECT                                                          00600021
**********************************************************************  00608021
*                                                                       00616021
* STATUS:                                                               00624021
*                                                                       00632021
*    RELEASE 21.8                                                       00640021
*                                                                       00648021
*                                                                       00656021
* FUNCTION:                                                             00664021
*                                                                       00672021
*    THIS MODULE IS THE ABNORMAL END APPENDAGE FOR ALL IO OPERATIONS    00680021
*    INVOLVING DDR CONTROL BLOCKS. WHILE MOST ERRORS ARE SENT BACK TO   00688021
*    IOS TO BE HANDLED NORMALLY BY IOS, SOME CONDITIONS FOR TAPE        00696021
*    PROCESSING ARE ACCEPTED AND PROCESSING CONTINUES.                  00704021
*                                                                       00712021
*                                                                       00720021
* ENTRY POINT:                                                          00728021
*                                                                       00736021
*         IGFDDR03 - FIRST INSTRUCTION OF MODULE.                       00744021
*                                                                       00752021
*                                                                       00760021
* INPUT:                                                                00768021
*                                                                       00776021
*    REG 1 = DDR RQE ADDR, REG 2 = DDR IOB ADDR, REG 3 = DDR DEB ADDR,  00784021
*    REG 4 = DDR DCB ADDR, REG 7 = UCB ADDR.                            00792021
*    CSW STATUS.                                                        00800021
*    SENSE INFORMATION.                                                 00808021
*    DDRFLGSF WILL HAVE THE REENTRY BIT ON IF THE ERP'S ARE             00816021
*    UNSUCCESSFUL RETRYING THE IO ERROR.                                00824021
*    DDRFLGSE WILL HAVE THE LABLPROC BIT ON IF THE ERROR WAS            00832021
*    DURING TAPE LABEL PROCESSING.                                      00840021
*                                                                       00848021
*                                                                       00856021
* OUTPUT:                                                               00864021
*                                                                       00872021
*    FOR ANY EXIT, THE ABOCE REGISTERS REMAIN THE SAME.                 00880021
*    IF THE ERROR SHOULD BE SENT BACK TO IOS, DDRFLGSF WILL             00888021
*    HAVE THE REENTRY BIT ON.                                           00896021
*    FOR TAPE, THE BLOCK COUNT IN DDR'S DCB MAY BE INCREMENTED.         00904021
*                                                                       00912021
*                                                                       00920021
* EXTERNAL REFERENCES:                                                  00928021
*                                                                       00936021
*         IOS/DDR VECTOR TABLE WITHIN IOS.                              00944021
*                                                                       00952021
*                                                                       00960021
* EXITS-NORMAL:                                                         00968021
*                                                                       00976021
*         BRANCH INTO THE VECTOR TABLE TO EXCP OR POST WITH             00984021
*         CONTROL OF THE DEVICE OR POST DDR WITHOUT CONTROL OF THE      00992021
*         DEVICE.                                                       01000021
*                                                                       01008021
*                                                                       01016021
* EXITS-ERROR:                                                          01024021
*                                                                       01032021
*         BR 14 TO IOS FOR ERP RETRY OF DDR IO ERROR.                   01040021
*                                                                       01048021
*                                                                       01056021
* TABLES/WORK AREAS:                                                    01064021
*                                                                       01072021
*         IORMSCOM - THE DDR COMMUNICATIONS AREA.                       01080021
*         IOS/DDR VECTOR TABLE IN IOS.                                  01088021
*                                                                       01096021
*                                                                       01104021
* ATTRIBUTES:                                                           01112021
*                                                                       01120021
*         RESIDENT. DISABLED. SERIALLY REUSABLE.                        01128021
*                                                                       01136021
*                                                                       01144021
* CHARCTER CODE DEPENDENCY:                                             01152021
*                                                                       01160021
*         NONE.                                                         01168021
*                                                                       01176021
*  UPDATE ACTIVITY                                             @SAXXXXX 01178021
*                                                              @SAXXXXX 01180021
*      APAR  64475  (FREED RQE)                                @SA64475 01182021
*****************************************************************       01184021
         SPACE 2                                                        01192021
         TITLE '   IGFDDR03 - ABNORMAL END APPENDAGE '                  01200021
         USING *,BASE                   MODULE ADDR                     01800021
         L     CVTREG,CVTPTR            CVT PTR                         02400021
         USING CVTDSECT,CVTREG          CVT ADDR                        03000021
         L     COMMPTR,CVTDCB           LOGREC DCB PTR                  03600021
         L     COMMPTR,N0(COMMPTR)      IORMSCOM PTR                    04200021
         USING IORMS,COMMPTR            IORMSCOM ADDR                   04800021
         DROP  CVTREG                   NO LONGER NEED CVT PTR          05400021
*                                                                       06000021
         L     IOVTPTR,IOSVT            IOS/DDR VECTOR TABLE PTR        06600021
*                                                                       06650021
TSTINTCP DS    0H                                             JE A64640 06700021
         CLI   N4(IOBPTR),INTCEPT1 IS THIS 7E INTCPT          JE A64640 06750021
         BE    INTRCEPT            YES GO HANDLE              JE A64640 06800021
         CLI   N4(IOBPTR),INTCEPT2 IS THIS 44 INTCPT          JE A64640 06850021
         BNE   TSTENTER            NO, GO TO COMMON           JE A64640 06900021
*                                                                       06950021
INTRCEPT TM    DDRFLGSB,FIRSTIO    IS THIS FIRST I/O          JE A64640 07000021
         BZ    TSTENTER            NO, GO TO COMMON           JE A64640 07050021
         NI    N0(IOBPTR),ALL-EXCPTION TURN IOB EXCEPTION     JE A64640 07100021
         NI    DDRFLGSF,ALL-REENTRY TURN OF REEENTRY          JE A64640 07150021
         B     N4(IOVTPTR)         RE-EXCP WITH CONTROL       JE A64640 07160021
*                                                                       07170021
TSTENTER DS    0H                                             JE A64640 07180021
         CLI   N4(IOBPTR),X'41'   PERM ERROR DECLARED          @SA64475 07200021
         BE    ERRORON            YES -- PROCESS               @SA64475 07800021
         TM    DDRFLGSE,LABLPROC        IS LABEL PROCESSING IN PROGRESS 08400021
         BO    GOERP                    YES, GO PREPARE TO GO TO ERP    09000021
*                                                                       09600021
         TM    N0(IOBPTR),IOBERR        IS ERROR ROUTINE IN CONTROL     10200021
         BCR   N1,RETURN                YES, RETURN TO ERP              10800021
         TM    N16(IOBPTR),CC3          IS SIO COND. CODE 3             11400021
         BNO   UNITCHK                  NO, SEE IF UNIT CK IS INDICATED 12000021
         OI    DDRDCB+N44,NOERP         DO NOT ALLOW ERP TO BE USED     12600021
         TM    N4(IOBPTR),IOPOSTED      HAS I/O BEEN POSTED COMPLETE    13200021
         BCR   N1,RETURN                YES, RETURN TO IOS              13800021
ERRORON  OI    DDRFLGSC,ERROR           TO INDICATE ERROR               14400021
         CLI   N18(FMUCB),TAPE          IS DEVICE TAPE            42805 14510000
         BE    N16(IOVTPTR)             YES, POST WITH CONTROL    42805 14520000
         TM    DDRFLGSE,READFROM        IS ERROR DURING 3330 READ 42805 14530000
         BO    N16(IOVTPTR)             YES, POST WITH CONTROL    42805 14540000
         B     N12(IOVTPTR)             POST WITHOUT CONTROL      42805 14542000
*                                                                       15600021
UNITCHK  EQU   *                                                        16200021
         TM    N12(IOBPTR),UNITCHEK     IS UNIT CHECK INDICATED         16800021
         BZ    GOERP                    NO, PREPARE TO GO TO ERP        17400021
         NI    N0(IOBPTR),ALL-EXCPTION  TURN OFF IOB EXCEPTION BIT      18000021
         TM    N2(IOBPTR),INTREQ        IS INTERVENTION REQUIRED        18600021
         BZ    CKDEVICE                 NO, GO CHECK FOR DEVICE TYPE    19200021
         CLI   N18(FMUCB),TAPE          IS THIS TAPE                    19800021
         BNE   N16(IOVTPTR)             NO, POST DDR WITH CONTROL       20400021
         TM    N3(IOBPTR),STATUSB       IS UNIT STATUS B INDICATED      21000021
         BZ    ERRORON                  NO, GO INDICATE ERROR           21600021
         CLI   DDRWORK,RUN              IS COMMAND TO REWIND-UNLOAD     22200021
         BNE   EXCEPTON                 NO, TURN ON EXCEPTION BIT       22800021
         B     N16(IOVTPTR)             POST DDR WITH CONTROL           23400021
*                                                                       24000021
CKDEVICE EQU   *                                                        24600021
         CLI   N18(FMUCB),TAPE          IS THIS TAPE                    25200021
         BNE   EXCEPTON                 NO, TURN ON IOB EXCEPTION BIT   25800021
         TM    N3(IOBPTR),LOADPT        IS TAPE AT LOAD POINT           26400021
         BO    N16(IOVTPTR)             YES, POST DDR WITH CONTROL      27000021
         TM    N2(IOBPTR),OVERRUN       IS OVERRUN INDICATED            27600021
         BO    ADDBLOCK                 YES, GO INCREMENT BLOCK COUNT   28200021
         TM    N2(IOBPTR),DATACHK       IS DATA CHECK INDICATED         28800021
         BO    CHKRESID                 YES, GO CHECK RESIDUAL COUNT    29400021
*                                                                       30000021
EXCEPTON EQU   *                                                        30600021
         OI    N0(IOBPTR),EXCPTION      TURN EXCEPTION BIT BACK ON      31200021
*                                                                       31800021
GOERP    EQU   *                                                        32400021
         TM    DDRFLGSE,WRONGVOL        IS THIS FOR WRONG VOLUME        33000021
         BO    N4(IOVTPTR)              YES, RE-EXCP WITH CONTROL       33600021
         OI    N6(FMUCB),UCBERROR       TURN ERROR FLAG BACK ON         34050000
         OI    DDRFLGSF,REENTRY         TO INDICATE THIS APPDG REENTERD 34200021
         NI    DDRDCB+N44,ALL-NOERP     LET ERP GET CONTROL             34800021
         BR    RETURN                   GO TO ERP                       35400021
*                                                                       36000021
CHKRESID EQU   *                                                        36600021
         SR    WKREG13,WKREG13          WORK REG                        37200021
         CH    WKREG13,N14(IOBPTR)      IS RESIDUAL COUNT ZERO          37800021
         BE    ADDBLOCK                 YES, GO INCREMENT DDR BLK COUNT 38400021
         TM    N3(IOBPTR),NOISE         IS NOISE INDICATED              39000021
         BZ    N4(IOVTPTR)              NO, RE-EXCP WITH CONTROL        39600021
*                                                                       40200021
ADDBLOCK EQU   *                                                        40800021
         L     WKREG13,DDRDCB+N12       DDR BLOCK COUNT                 41400021
         AH    WKREG13,N28(IOBPTR)      ADD INCREMENT TO IT             42000021
         ST    WKREG13,DDRDCB+N12       STORE NEW COUNT                 42600021
         CLC   DDRDCB+N12(N4),BLKCNT    ARE BLOCK COUNTS EQUAL          43200021
         BNE   N4(IOVTPTR)              NO, RE-EXCP WITH CONTROL        43800021
         NI    DDRFLGSD,ALL-READ        TURN OFF READ INDICATOR         44400021
         B     N16(IOVTPTR)             POST DDR WITH CONTROL           45000021
         SPACE 5                                                        45600021
*                                                                       46200021
***      REGISTER EQUATES                                               46800021
*                                                                       47400021
IOBPTR   EQU   2                        DDR IOB PTR                     48000021
FMUCB    EQU   7                        UCB PTR                         48600021
COMMPTR  EQU   10                       IORMSCOM PTR                    49200021
CVTREG   EQU   11                       CVT PTR                         49800021
IOVTPTR  EQU   12                       IOS/DDR VECTOR TABLE PTR        50400021
WKREG13  EQU   13                       WORK REGISTER                   51000021
RETURN   EQU   14                       RETURN REGISTER                 51600021
BASE     EQU   15                       BASE REGISTER                   52200021
         SPACE 2                                                        52800021
*                                                                       53400021
***      INTEGER EQUATES                                                54000021
*                                                                       54600021
N0       EQU   0                        DISPLACEMENT VALUE              55200021
N1       EQU   1                        DISPLACEMENT VALUE              55800021
N2       EQU   2                        DISPLACEMENT VALUE              56400021
N3       EQU   3                        DISPLACEMENT VALUE              57000021
N4       EQU   4                        DISPLACEMENT VALUE              57600021
N6       EQU   6                        DISPLACEMENT VALUE              58050000
N12      EQU   12                       DISPLACEMENT VALUE              58200021
N14      EQU   14                       DISPLACEMENT VALUE              58800021
N16      EQU   16                       DISPLACEMENT VALUE              59400021
N18      EQU   18                       DISPLACEMENT VALUE              60000021
N28      EQU   28                       DISPLACEMENT VALUE              60600021
N44      EQU   44                       DISPLACEMENT VALUE              61200021
         SPACE 2                                                        61800021
*                                                                       62400021
***      GENERAL EQUATES                                                63000021
*                                                                       63600021
ALL      EQU   X'FF'                    MASK FOR 'AND' INSTRUCTIONS     64200021
CC3      EQU   X'30'                    CONDITION CODE 3                64800021
DATACHK  EQU   X'08'                    DATA CHECK                      65400021
EXCPTION EQU   X'04'                    IOB EXCEPTION                   66000021
INTREQ   EQU   X'40'                    INTERVENTION REQUIRED           66600021
IOBERR   EQU   X'20'                    IOB ERROR                       67200021
IOPOSTED EQU   X'20'                    IO POSTED COMPLETE              67800021
LOADPT   EQU   X'08'                    LOAD POINT                      68400021
NOERP    EQU   X'0C'                    NEVER USE ERP BIT IN DCB        69000021
NOISE    EQU   X'80'                    NOISE                           69600021
OVERRUN  EQU   X'04'                    OVERRUN                         70200021
RUN      EQU   X'0F'                    REWIND-UNLOAD COMMAND           70800021
STATUSB  EQU   X'20'                    STATUS B IN SENSE BYTE 1        71400021
TAPE     EQU   X'80'                    UCB MAGNETIC TAPE BIT           72000021
UCBERROR EQU   X'01'                    ERROR FLAG IN UCB FLAGS 1       72550000
UNITCHEK EQU   X'02'                    UNIT CHECK                      72600021
INTCEPT1 EQU   X'7E'               ECB COMPLETION CODE        JE A64640 72650021
INTCEPT2 EQU   X'44'               ECB COMPLETION CODE        JE A64640 72700021
         SPACE 2                                                        73200021
CVTDSECT DSECT                                                          73800021
         CVT                                                            74400021
*                                                                       75000021
         IORMSCOM                                                       75600021
*/*IGFDDR03:      CHART                                              */ 86850000
*/*IGFDDR03:      E IGFDDR03                                         */ 86900000
*/*               P ESTABLISH  ALL ADDRESSABILITY                    */ 86950000
*/*               P GET @ OF IOS DDR VECTOR TABLE. PUT IN IOVTPTR    */ 87000000
*/*               D (NO,,YES,ERRORON) IS THIS SECOND ENTRY FROM ERP? */ 87050000
*/*               D (NO,,YES,GOERP) IS LABEL PROCESSING IN PROGRESS? */ 87100000
*/*               D (NO,,YES,%A) IS ERROR ROUTINE IN CONTROL ?     ? */ 87150000
*/*               D (YES,,NO,UNITCHK) IS SIO CC=3 ?                  */ 87200000
*/*               P DO NOT ALLOW ERP TO GET CONTROL                  */ 87250000
*/*               D (YES,,NO,ERRORON) IS I/O POSTED COMPLETE ?       */ 87300000
*/*               R RETURN TO IOS                                    */ 87350000
*/*%A:            R RETURN TO IOS                                    */ 87400000
*/*ERRORON:       P TURN ON ERROR BIT                                */ 87450000
*/*               L () IOS - BRANCH TO IOVTPTR + 12                  */ 87460000
*/*               COMMENT (2,6) POST DDR W/O                         */ 87470000
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 87480000
*/*UNITCHK:       D (YES,,NO,GOERP) IS UNIT CHECK INDICATED ?        */ 87490000
*/*               P TURN OFF EXCEPTION BIT IN IOB                    */ 87492000
*/*               D (YES,,NO,CKDEVICE) IS INTERVENTION REQUIRED ?    */ 87494000
*/*               D (YES,,NO,%B) IS THIS A TAPE SWAP ?               */ 87496000
*/*               D (YES,,NO,ERRORON) IS UNIT STATUS B ON ?          */ 87498000
*/*               D (YES,,NO,EXCEPTON) IS COMMAND TO REW. & UNLOAD ? */ 87498400
*/*               L () IOS - BRANCH TO IOVTPTR + 16                  */ 87498800
*/*               COMMENT (2,6) POST DDR WITH                        */ 87499200
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 87499600
*/*%B:            L () IOS - BRANCH TO IOVTPTR + 16                  */ 87499700
*/*               COMMENT (2,6) POST DDR WITH                        */ 87499800
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 87499900
*/*CKDEVICE:      D (YES,,NO,EXCEPTON) IS THIS A TAPE SWAP ?         */ 87549900
*/*               D (NO,,YES,%C) IS TAPE AT LOAD POINT ?             */ 87559900
*/*               D (NO,,YES,ADDBLOCK) IS OVERRUN INDICATED ?        */ 87569900
*/*               D (NO,,YES,CHKRESID) IS DATA CHECK INDICATED ?     */ 87579900
*/*EXCEPTON:      P TURN ON EXCEPTION BIT IN IOB                     */ 87589900
*/*GOERP:         P TURN ON REENTRY BIT                              */ 87591900
*/*               P LET ERP GET CONTROL                              */ 87593900
*/*               R RETURN TO IOS                                    */ 87595900
*/*%C:            L () IOS - BRANCH TO IOVTPTR + 16                  */ 87597900
*/*               COMMENT (2,6) POST DDR WITH                        */ 87598300
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 87598700
*/*CHKRESID:      D (NO,,YES,ADDBLOCK) IS THE RESIDUAL COUNT 0 ?     */ 87599100
*/*               D (NO,,YES,ADDBLOCK) IS NOISE INDICATED ?          */ 87599500
*/*               L () IOS - BRANCH TO IOVTPTR + 4                   */ 87599600
*/*               COMMENT (2,6) RE-EXCP WITH                         */ 87599700
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 87599800
*/*ADDBLOCK:      P ADD ONE TO DDR BLOCK COUNT                       */ 87649800
*/*               D (YES,,NO,%D) DOES DDR BLKCNT = USER BLKCNT ?     */ 87659800
*/*               P TURN OFF READ BIT                                */ 87669800
*/*               L () IOS - BRANCH TO IOVTPTR + 16                  */ 87679800
*/*               COMMENT (2,6) POST DDR WITH                        */ 87689800
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 87691800
*/*%D:            L () IOS - BRANCH TO IOVTPTR + 4                   */ 87693800
*/*               COMMENT (2,6) RE-EXCP WITH                         */ 87695800
*/*               COMMENT (3,6) CONTROL OF UCB                       */ 87697800
*/*IGFDDR03:      END                                                */ 87698200
         END                                                            87699800
