         TITLE 'IGFDDR04 - TAPE REPOSITIONING - ABNORMAL END APPENDAGE' 00600019
IGFDDR04 CSECT                                                          01200019
*********************************************************************** 01800019
*                                                                       02400019
*                        INTRODUCTORY COMMENTS                          03000019
*                                                                       03600019
*STATUS -- RELEASE 19                                                   04200019
*                                                                       04800019
*FUNCTION -- TO DETERMINE IF TAPE REPOSITIONING CAN CONTINUE AFTER AN   05400019
*   ERROR DURING REPOSITIONING. THIS MODULE WILL HANDLE ERROR WHICH DO  06000019
*   NOT AFFECT MOVEMENT OF THE TAPE, SUCH AS DATA CHECKS AND OVERRUN    06600019
*   CONDITIONS. ANY ERRORS THAT CANNOT BE HANDLED BY DDR WILL BE DONE   07200019
*   SO BY THE ERP'S.                                                    07800019
*                                                                       08400019
*ENTRY POINTS -- IGFDDR03 -- FIRST INSTRUCTION OF THIS MODULE           09000019
*                                                                       09600019
*INPUT -- BIT SETTINGS IN COMMUNICATIONS AREA                           10200019
*   CONVENTIONAL REGISTER SETTINGS FOR APPENDAGES                       10800019
*   POINTER TO VECTOR TABLE IN COMMUNICATIONS AREA                      11400019
*                                                                       12000019
*OUTPUT -- BIT SETTINGS IN COMMUNICATIONS AREA                          12600019
*                                                                       13200019
*EXTERNAL REFERENCES --                                                 13800019
*        IORMSCOM -- DUMMY SECTION MAPPING DDR'S COMMUNICATIONS AREA    14400019
*        IOSVT -- POINTER TO IOS VECTOR TABLE                           15000019
*                                                                       15600019
*EXITS,NORMAL --                                                        16200019
*        BRANCH TO IOS FROM A DISPLACEMENT IN VECTOR TABLE              16800019
*                                                                       17400019
*EXITS,ERROR --                                                         18000019
*        NONE                                                           18600019
*                                                                       19200019
*TABLES/WORK AREAS -- NONE                                              19800019
*                                                                       20400019
*ATTRIBUTES -- RESIDENT                                                 21000019
*                                                                       21600019
*********************************************************************** 22200019
         USING *,BASE                                                   22800019
         L     CVTBASE,CVTPTR           CVT PTR                         23400019
         USING CVTDSCT,CVTBASE          CVT ADDR                        24000019
         L     COMMBASE,CVTDCB          LOGREC DCB PTR                  24600019
         L     COMMBASE,N0(COMMBASE)    COMM AREA PTR                   25200019
         USING IORMS,COMMBASE           COMM AREA ADDR                  25800019
         DROP  CVTBASE                                                  26400019
         L     IOVTPTR,IOSVT            VECTOR TABLE PTR                27000019
         TM    DDRFLGSD,PROCLABL        IS LABEL PROCESSING IN PROCESS  27600019
         BO    REENTON                  YES-LET ERP HANDLE ERROR        28200019
         SPACE 5                                                        28800019
*                                                                       29400019
***      SECOND ENTRY - PERMANENT ERROR                                 30000019
*                                                                       30600019
CHKENTRY TM    DDRFLGSD,REENTRY         IS RE-ENTRY ON                  31200019
         BZ    CHKOPER                  NO-GO SEE IF DEVICE IS OPERATNL 31800019
         NI    DDRFLGSD,ENTRYOFF        TURN OFF REETNRY                32400019
         OI    DDRFLGSC,ERROR           TURN ON ERROR                   33000019
         B     N12(IOVTPTR)             POST DDR RELINQUISH CONTROL     33600019
         SPACE 5                                                        34200019
*                                                                       34800019
***      CHECK FOR DEVICE NOT OPERATIONAL                               35400019
*                                                                       36000019
CHKOPER  TM    N16(IOBPTR),CC3          DOES SIO COND.=3                36600019
         BNO   CHKUNIT                  NO-GO CHECH FOR UNIT CHECK      37200019
         OI    DDRDCB+N44,NOERP         DO NOT ALLOW ERP'S TO BE USED   37300019
         TM    N4(IOBPTR),NORMAL        IS NORMAL COMPLETION INDICATED  37400019
         BCR   N1,RETURN                YES-NORMAL RETURN TO IOS        37500019
NOTOPON  OI    DDRFLGSB,INVALID         FOR INVALID MESSAGE             37800019
         B     N12(IOVTPTR)             POST DDR-RELINQUISH CONTROL     38400019
         SPACE 5                                                        39000019
*                                                                       39600019
***      CHECK FOR UNIT CHECK                                           40200019
*                                                                       40800019
CHKUNIT  TM    N12(IOBPTR),UNITCHK      IS UNIT CHECK INDICATED         41400019
         BZ    REENTON                  NO-GO TURN ON REENTRY           42000019
         NI    N0(IOBPTR),EXCEPOFF      TURN OFF EXCEPTION BIT          42600019
         TM    N3(IOBPTR),LOADPT        IS TAPE AT LOAD POINT           43200019
         BO    N16(IOVTPTR)             POST DDR RETAIN CONTROL         43800019
         TM    N3(IOBPTR),STATUS        ARE STATUS BYTES A AND B ZERO   44400019
         BZ    NOTOPON                  YES-GO TURN ON NOT OPERATIONAL  45000019
         TM    N2(IOBPTR),INTREQ        IS INTERVENTION REQUIRED        45600019
         BZ    CHKRUN                   NO-GO CHECK FOR OVERRUN         46200019
         TM    DDRWORK,RUNCOMMD         IS COMMAND TO REWIND-UNLOAD     46800019
         BO    N16(IOVTPTR)             YES-GO POST DDR-RETAIN CONTROL  47400019
         B     EXCEPTON                 NO-GO TURN ON EXCEPTION BIT     48000019
CHKRUN   TM    N2(IOBPTR),OVERRUN       IS OVERRUN INDICATED            48600019
         BO    ADDBLOCK                 YES-GO INCREMENT BLOCK COUNT    49200019
         TM    N2(IOBPTR),DATACHK       IS DATA CHECK INDICATED         49800019
         BO    CHKRESID                 YES-GO CHECK REDISUAL COUNT     50400019
EXCEPTON OI    N0(IOBPTR),EXCPTION      TURN EXCEPTION BIT BACK ON      51000019
REENTON  OI    DDRFLGSD,REENTRY         TURN ON RE-ENTRY BIT            51600019
         NI    DDRDCB+N44,ERPIN         LET ERP'S GET CONTROL           51900019
         NI    DDRFLGSD,LABELOFF        TURN OFF LABEL PROCESSING BIT   52000000
         BR    RETURN                   GO TO ERP                       52200019
         SPACE 5                                                        52800019
*                                                                       53400019
***      CHECK RESIDUAL COUNT AND NOISE                                 54000019
*                                                                       54600019
CHKRESID SR    WKREG8,WKREG8            CLEAR WORK REG                  55200019
         CH    WKREG8,N14(IOBPTR)       IS RESIDUAL COUNT ZERO          55800019
         BE    ADDBLOCK                 YES-GO INCREMENT BLOCK COUNT    56400019
         TM    N3(IOBPTR),NOISE         IS NOISE INDICATED              57000019
         BZ    N4(IOVTPTR)              NO-RE-EXCP RETAIN CONTROL       57600019
ADDBLOCK L     WKREG8,N12(DCBPTR)       GET BLOCK COUNT                 58200019
         AH    WKREG8,N28(IOBPTR)       ADD INCREMENT TO IT             58800019
         ST    WKREG8,N12(DCBPTR)       STORE NEW COUNT                 59400019
         CLC   N12(N4,DCBPTR),BLKCNT    ARE BLK COUNTS EQUAL            60000019
         BNE   N4(IOVTPTR)              NO-RE-EXCP - RETAIN CONTROL     60600019
         NI    DDRFLGSC,READOFF         TURN OFF READ                   61200019
         OI    DDRFLGSB,COMPLETE        TURN ON COMPLETE                61800019
         B     N12(IOVTPTR)             POST DDR-RELINQUISH CONTROL     62400019
         SPACE 5                                                        63000019
*********************************************************************** 63600019
*                                                                     * 64200019
*                          REGISTER EQUATES                           * 64800019
*                                                                     * 65400019
*********************************************************************** 66000019
RQEPTR   EQU   1                        RQE POINTER                     66600019
IOBPTR   EQU   2                        IOB POINTER                     67200019
DEBPTR   EQU   3                        DEB POINTER                     67800019
DCBPTR   EQU   4                        DCB POINTER                     68400019
UCBPTR   EQU   7                        UCB POINTER                     69000019
COMMBASE EQU   10                       COMMUNICATIONS AREA POINTER     69600019
CVTBASE  EQU   11                       CVT POINTER                     70200019
WKREG8   EQU   12                       WORK REGISTER                   70800019
IOVTPTR  EQU   13                       VECTOR TABLE POINTER            71400019
RETURN   EQU   14                       IOS RETURN POINTER              72000019
BASE     EQU   15                       BASE REGISTER                   72600019
         SPACE 5                                                        73200019
*                       ABSOLUTE NUMBER EQUATES                       * 73800019
N0       EQU   0                        DISPLACEMENT CONSTANT           74400019
N1       EQU   1                        DISPLACEMENT CONSTANT           75000019
N2       EQU   2                        DISPLACEMENT CONSTANT           75600019
N3       EQU   3                        DISPLACEMENT CONSTANT           76200019
N4       EQU   4                        DISPLACEMENT CONSTANT           76800019
N12      EQU   12                       DISPLACEMENT CONSTANT           77400019
N14      EQU   14                       DISPLACEMENT CONSTANT           78000019
N16      EQU   16                       DISPLACEMENT CONSTANT           78600019
N28      EQU   28                       DISPLACEMENT CONSTANT           78900019
N44      EQU   44                                                       79000019
         SPACE 5                                                        79200019
*                           GENERAL EQUATES                           * 79800019
CC3      EQU   X'30'                    MASK FOR CONDITION CODE 3       80400019
DATACHK  EQU   X'08'                    MASK TO CHECK DATA CHECK        81000019
ENTRYOFF EQU   X'7F'                    TO TURN OFF 2ND ENTRY FLAG      81600019
ERPIN    EQU   X'F3'                                                    81900019
EXCEPOFF EQU   X'FB'                    TO TURN OFF IOB EXCEPTION FLAG  82200019
EXCPTION EQU   X'04'                    TO TURN ON EXCEPTION FLAG       82800019
INTREQ   EQU   X'40'                    MASK FOR INTERVENTION REQUIRED  83400019
LABELOFF EQU   X'FD'                    TO TURN OFF LABEL PROC BIT      83700000
LOADPT   EQU   X'08'                    MASK FOR LOAD POINT             84000019
NOERP    EQU   X'0C'                                                    84300019
NOISE    EQU   X'80'                    MASK FOR NOISE                  84600019
NORMAL   EQU   X'20'                                                    84900019
OVERRUN  EQU   X'04'                    MASK FOR OVERRUN                85200019
READOFF  EQU   X'FD'                    TO TURN OFF READ FLAG           85800019
RUNCOMMD EQU   X'0F'                    COMMAND TO REWIND-UNLOAD        86400019
STATUS   EQU   X'60'                    MASK FOR UNIT STATUS A AND B    87000019
UNITCHK  EQU   X'02'                    MASK FOR UNIT CHECK             87600019
         SPACE 5                                                        88200019
CVTDSCT  DSECT                                                          88800019
         CVT                                                            89400019
         SPACE 5                                                        90000019
         IORMSCOM                                                       90600019
         END                                                            91200019
