         TITLE 'IGFDDRMF - MFT RB FOR RESIDENT ROUTINE'                 01000019
IGFDDRMF CSECT                                                          01500019
         SPACE 2                                                        02040019
*********************************************************************** 02080019
*                                                                       02120019
*                        INTRODUCTORY COMMENTS                          02160019
*                                                                       02200019
*                                                                       02240019
*STATUS -- RELEASE 19                                                   02280019
*                                                                       02320019
*FUNCTION --  IGFDDR11 IS THE RB UNDER WHICH IGFDDR01 PROCESSES.        02360019
*    IGFDDR01 IS THE DDR RESIDENT WAIT MODULE.  IT ISSUES SVC 85 WHEN   02400019
*    IT GAINS CONTROL.  FOR OPERATOR INITIATED SYSRES DDR IT PASSES     02440019
*    CONTROL TO THE DDR SYSRES ROUTINES.  WHEN THIS MODULE REGAINS CON- 02480019
*    TROL FOLLOWING THE SVC OR FROM THE DDR SYSRES ROUTINES, IT ISSUES  02520019
*    A WAIT FOR THE NEXT DDR.                                           02560019
*                                                                       02600019
*ENTRY POINTS --                                                        02640019
*        IORMSSVC                                                       02680019
*                                                                       02720019
*INPUT --  REGISTER 3 CONTAINS THE ADDRESS OF THE CVT, REGISTER 11 THE  02760019
*    ADDRESS OF THE I/O RMS COMMUNICATIONS AREA, REGISTER 12 THE MODULE 02800019
*    BASE ADDRESS, AND REGISTER 14 THE ADDRESS OF THE WAIT INSTRUCTION. 02840019
*                                                                       02880019
*OUTPUT --  NONE                                                        02920019
*                                                                       02960019
*EXTERNAL REFERENCES --  THE I/O RMS COMMUNICATIONS AREA.  THE FIRST    03000019
*    WORD OF THE SYS1.LOGREC DCB POINTS TO THIS AREA.                   03040019
*                                                                       03080019
*EXITS -- NORMAL                                                        03100019
*        NONE                                                           03120019
*                                                                       03140019
*EXITS -- ERROR                                                         03160019
*        NONE                                                           03180019
*                                                                       03240019
*TABLES/WORK AREAS --  NONE                                             03280019
*                                                                       03320019
*ATTRIBUTES --  REUSABLE, DISABLED                                      03360019
*                                                                       03400019
*NOTES --  THIS MODULE USES THE PRIVATE MACRO 'IORMSCOM' TO MAP THE I/O 03440019
*    RMS COMMUNICATIONS AREA.  THE RB UNDER WHICH IT OPERATES IS PRE-   03480019
*    ASSEMBLED WITH A RESUME PSW POINTING TO THE SVC 85 INSTRUCTION.    03520019
*    THE TCB GENERAL REGISTER SAVE AREA IS PRE-ASSEMBLED TO HAVE THE    03560019
*    STATED INPUT REGISTERS' VALUES.                                    03600019
*    THERE IS NO CHARACTER CODE DEPENDENCE.                             03640019
*                                                                       03680019
*                                                                       03720019
*********************************************************************** 03760019
         SPACE 2                                                        03800019
         ENTRY DDRRB                                                    12000019
         ENTRY IGFDDR11                                                 13000019
         DS    0D                       ALIGN BOUNDARY                  15000019
IGFDDR11 DS    0H                       NAME USED BY TCB                17000019
DDRRB    DS    0H                       NAME USED BY DDRECB             19000019
         DC    CL8'IGFDDR01'            PROGRAM NAME                    21000019
         DC    XL2'0004'                SIZE OF RB IN DOUBLE WORDS      23000019
         DC    XL2'00D0'                FLAG BYTES                      25000019
         DC    AL1(0)                   USE COUNT                       27000019
         DC    VL3(IORMSSVC)            ENTRY POINT ADDRESS             29000019
         DC    XL4'00040000'            USER'S OLD PSW WITH MACHINE     31000019
         DC    VL4(IORMSSVC)             CHECK ENABLED, POINT TO SVC 85 33000019
         DC    AL4(0)                   RESERVED                        35000019
         DC    XL1'01'                  WAIT COUNT                      37000019
         DC    VL3(IGFRMTCB)            TCB POINTER                     39000019
         TITLE 'IGFDDRMF  -  IGFDDR01'                                  41000019
IGFDDR01 DS    0H                       ENTRY POINT                     43000019
         ENTRY IGFDDR01                                                 54150019
         ENTRY IORMSSVC                                                 54200019
         ENTRY IORMSWT                                                  54300019
         ENTRY IGFDDRFC                                                 54400019
         ENTRY IGFDDRND                                                 54500019
BASEREG  EQU   12                                                       54600019
COMREG   EQU   11                       I/O RMS COMM AREA ADDRESS       54700019
CVTREG   EQU   3                   CVT POINTER                          54800019
RETREG   EQU   14                  RETURN REGISTER                      54900019
LINKREG  EQU   15                  LINKREG FOR SYSRES BRANCH            55000019
ZERO     EQU   0                        OFFSET VALUE                    55100019
DDRSVC   EQU   85                                                       55200019
NOTONES  EQU   12                       CONDITION CODE VALUE            55600019
         USING *,BASEREG           SET ADDRESSABILITY FOR THIS RTN      56000019
         USING  CVTDSECT,CVTREG    SET ADDRESSABILITY FOR CVT           58000019
         USING IORMS,COMREG        SET ADDRESSABILITY FOR I/O RMS AREA  60000019
IORMSWT  WAIT  ECB=DDRECB          WAIT FOR DDR REQUEST                 62000019
IORMSSVC SVC   DDRSVC              GET DDR ROUTER ROUTINE               64000019
         TM    DDRFLGSD,SYSRESBR+DDRMSG  IS A BRANCH TO SYSRES RTN RQRD 66000019
         BC    NOTONES,IORMSWT               NO, GO TO WAIT             68000019
         L     LINKREG,SYSRESAD    PICK UP SYSRES EFFECTOR ADRS         70000019
         BR    LINKREG             YES, GO TO SYSRES                    72000019
IGFDDRFC DS    0D                       ALIGN BOUNDARY FOR FQE          74000019
         DC    AL4(0)                   POINTER TO NEXT FQE             76000019
         DC    AL4(984)                 SIZE IN BYTES OF FREE CORE      78000021
         DS    246F                     FREE CORE DEFINITION      21048 81000021
IGFDDRND EQU   *                                                        84000019
CVTDSECT DSECT                                                          86000019
         CVT                                                            88000019
         IORMSCOM                                                       90000019
         END                                                            92000019
