         TITLE 'IGFDDRMV - IGFDDR01'                                    01000019
IGFDDRMV CSECT                                                          01600019
         ENTRY IGFDDR01                                                 02200019
         SPACE 2                                                        03060019
*********************************************************************** 03120019
*                                                                       03180019
*                        INTRODUCTORY COMMENTS                          03240019
*                                                                       03300019
*                                                                       03360019
*STATUS -- RELEASE 19                                                   03420019
*                                                                       03480019
*FUNCTION -- THIS IS THE RESIDENT DDR WAIT ROUTINE FOR AN MVT CONTROL   03540019
*   PROGRAM.  THE RB UNDER WHICH IT OPERATES IS PRE-ASSEMBLED AT SYSTEM 03600019
*   GENERATION WITH THE RESUME PSW POINTING TO 'IORMSSVC' INSTRUCTION.  03660019
*   THUS WHEN THE DDR ECB IN THE I/O RMS COMMUNICATIONS AREA IS POSTED  03720019
*   AND THIS ROUTINE GAINS CONTROL, IT ISSUES SVC 85.  UPON RE-GAINING  03780019
*   CONTROL, IT TESTS IF DDR FOR SYSTEM RESIDENCE VOLUME IS TO BE       03840019
*   ENTERED.  IF YES, A DIRECT BRANCH IS MADE TO THAT ROUTINE.  OTHER-  03900019
*   WISE, THE ROUTINE EXECUTES THE WAIT INSTRUCTION.                    03960019
*                                                                       04020019
*ENTRY POINTS --                                                        04080019
*        IORMSSVC                                                       04140019
*                                                                       04200019
*INPUT --  THE REGISTERS ARE LOADED FROM THE TCB GENERAL REGISTER SAVE  04260019
*   AREA WHICH IS PRE-ASSEMBLED AT SYSTEM GENERATION WITH THE VALUES    04320019
*   STATED BELOW.                                                       04380019
*   REGISTER 3 CONTAINS THE CVT ADDRESS, REGISTER 11 THE I/O RMS COM-   04440019
*   MUNICATIONS AREA ADDRESS, REGISTER 12 THE BASE ADDRESS, AND REG-    04500019
*   ISTER 14 THE WAIT INSTRUCTION ADDRESS.                              04560019
*                                                                       04620019
*OUTPUT --  NONE                                                        04680019
*                                                                       04740019
*EXTERNAL REFERENCES --  THE FOLLOWING FIELDS IN THE I/O RMS COMMUNI-   04800019
*   CATIONS AREA--DDRFLGSD (OFFSET X'20'), SYSRESAD (OFFSET X'14'), AND 04860019
*   DDRECB (OFFSET X'3C').                                              04920019
*                                                                       04980019
*EXITS --  NORMAL                                                       05020019
*        A BRANCH TO DDRSYSRES                                          05060019
*                                                                       05100019
*EXITS --  ERROR                                                        05140019
*        NONE                                                           05180019
*                                                                       05220019
*TABLES/WORK AREAS --  NONE                                             05280019
*                                                                       05340019
*ATTRIBUTES -- RE-USABLE                                                05400019
*                                                                       05460019
*NOTES --  THIS MODULE USES THE PRIVATE MACRO 'IORMSCOM' WHICH MAPS THE 05520019
*   I/O RMS COMMUNICATIONS AREA.  THERE IS NO CHARACTER CODE DEPENDENCE 05580019
*                                                                       05640019
         SPACE 2                                                        05700019
         ENTRY IORMSWT                                                  09000019
         ENTRY IORMSSVC                                                 12000019
BASEREG  EQU   12                       BASE REGISTER                   15000019
COMREG   EQU   11                       I/O RMS COMMUNICATION AREA ADDR 18000019
CVTREG   EQU   3                   CVT POINTER                          21000019
RETREG   EQU   14                  RETURN REGISTER                      24000019
LINKREG  EQU   15                  LINKREG FOR SYSRES BRANCH            27000019
ZERO     EQU   0                        OFFSET VALUE                    30000019
DDRSVC   EQU   85                                                       33000019
NOTONES  EQU   12                       CONDITION CODE VALUE            34000019
IGFDDR01 DS    0H                       ENTRY POINT                     35000019
         USING *,BASEREG           SET ADDRESSABILITY FOR THIS RTN      36000019
         USING  CVTDSECT,CVTREG    SET ADDRESSABILITY FOR CVT           39000019
         USING IORMS,COMREG        SET ADDRESSABILITY FOR I/O RMS AREA  42000019
IORMSWT  WAIT  ECB=DDRECB          WAIT FOR DDR REQUEST                 45000019
IORMSSVC SVC   DDRSVC              GET DDR ROUTER ROUTINE               48000019
         TM    DDRFLGSD,SYSRESBR+DDRMSG  IS A BRANCH TO SYSRES RTN RQRD 51000019
         BC    NOTONES,IORMSWT          NO, GO TO WAIT                  54000019
         L     LINKREG,SYSRESAD    PICK UP SYSRES EFFECTOR ADRS         57000019
         BR    LINKREG             YES, GO TO SYSRES                    60000019
CVTDSECT DSECT                                                          63000019
         CVT                                                            66000019
         IORMSCOM                                                       69000019
         END                                                            72000019
