         LCLA  &LEV,&REL                                                00060021
&LEV     SETA  41                                                       00110000
&REL     SETA  21                                                       00112021
&REL&LEV TITLE 'IGFMCH10 LEVEL &LEV RMS-MCH 85 NUCLEUS'                 00114021
IGFMCH10 CSECT                                                          00120020
*                                                                       00180020
*                                                                       00240020
*                                                                       00300020
* ATTRIBUTES...                                                         00360020
*    PERMANENTLY RESIDENT,SERIALLY REUSABLE,OPERATES IN SUPERVISOR MODE 00420020
*    AND USES PRIVILEGED INSTRUCTIONS                                   00480020
*                                                                       00540020
*                                                                       00600020
* ENTRY POINTS...                                                       00660020
* IGFN0000--ENTERED VIA MCK NEW PSW. THE ADDRESS OF THIS LABEL IS       00720020
*              CONTAINED IN THE MCK NEW PSW                             00780020
*                                                                       00840020
*                                                                       00900020
* NMODRTRN - MODULE COMMON RETURN POINT(MODULE SCHEDULING)              00950020
*                                                                       01000020
* NMODLDR - ENTRY TO MODULE LOADER SUBROUTINE FROM MODULE               01050020
*            SCHEDULING SUBROUTINE.                                     01100020
*                                                                       01150020
* NIOSINTF - ENTRY TO IOS INTERFACE SUBROUTINE                          01200020
*                  1. MODULE LOADER SUBROUTINE                          01250020
*                  2.PDAR REFRESH LOADER(IGFMCHF4)                      01300020
*                  3.PDAR SYSTEM ANALYSIS(IGFMCHF2)                     01350020
*                                        REFERENCE TO ASRLIB            01400020
*                  4. ERROR RECORDER(IGFMCH17)                          01450020
*                                        REFERENCE TO LOGREC            01500020
* IGFPOST1--FROM TERMINATOR(12) TO CALL THE OS POST ROUTINE TO       IO 01560020
*           POST THE RMS ECB WHICH IS AWAITED BY THE COMMUNICATIONS  IO 01620020
*           TASK.                                                    IO 01680020
* IGFPOST2--FROM THE OS SUPERVISOR WHENEVER THE DISPATCHER (OS)      IO 01740020
*           HAS RECEIVED CONTROL AND THE SPECIAL RMS INDICATOR       IO 01800020
*           IS SET.                                                  IO 01860020
* EXITS...                                                              01920020
*    RESIDENT MCH NUC HAS THE FOLLOWING EXITS...                        01980020
*    EXITS TO DISABLED WAIT STATE                                       02040020
*    1. UNEXPECTED HARD MCI OR PGM INTERRUPT IN MCH CODE                02100020
*    2. CATASTROPHIC 2880 FAILURE-NO CHANNEL LOGOUT POSSIBLE            02160020
*       AND HARDWARE FORCES A MCI.                                   IO 02220020
*    EXITS TO LOADED MCH MODULES                                        02280020
*       AFTER EACH MCH MODULE IS SUCCESSFULLY LOADED, MCH NUC GIVES     02340020
*       CONTROL TO THE MODULE AT THE BEGINNING OF THE TRANSIENT AREA    02400020
*       AFTER I/O REQUEST HAS BEEN COMPLETED FOR ONE OF THE MCH      IO 02460020
*       TRANSIENT MODULES.                                           IO 02520020
*                                                                       02580020
*                                                                       02640020
* INPUTS...                                                             02700020
*    THE INPUTS TO RMS/85 NUCLEUS ARE CLASSIFIED BY THE TWO             02760020
*    FOLLOWING CATEGORIES.....                                          02820020
*    1. HARDWARE GENERATED---THERE ARE TWO TYPES OF HARDWARE GENERATED  02880020
*                            INPUTS...                                  02940020
*        A. THE FAILING ENVIRONMENT CONTAINS THE FOLLOWING INFORMATION  03000020
*            . GPRS                                                     03060020
*            . FPRS                                                     03120020
*            . MICROFICHE LOGOUT                                        03180020
*            . CRT AND CRT PARITY LOGOUT                                03240020
*            . CHANNEL LOGOUT                                           03300020
*            . CONTENTS OF LOW CORE LOCATIONS(0 TO 128 DECIMAL)         03360020
*        B. THE HARDWARE RETRY FACILITIES ENVIRONMENT CONTAINS THE      03420020
*           FOLLOWING INFORMATION..                                     03480020
*            . HARDWARE INSTRUCTION RETRY AND ECC COUNTERS              03540020
*            . STATUS LOGOUT(MCAR,MCDR,MNT,MCRR)                        03600020
*                                                                       03660020
*                                                                       03720020
*    2. SOFTWARE GENERATED---THIS SOFTWARE INPUT CONSISTS OF ANY        03780020
*                            PARAMETERS OR STATUS INFORMATION GENERATED 03840020
*                            BY THE MCHNIP FUNCTION AT IPL TIME OR   IO 03900020
*                            BY AN RMS/85 MODULE USED AND INTERROGATED  03960020
*                            BY THE RMS/85 NUCLEUS TO MAKE LOGICAL      04020020
*                            DECISIONS ABOUT FURTHER RMS/85 OPERATION.  04080020
*                            THE SOFTWARE GENERATED INPUT TO THE RMS/85 04140020
*                            NUCLEUS IS AS FOLLOWS..                    04200020
*       A. RMSTTRS TABLE AND RMSNXMOD TABLE SET UP BY MCHNIP.        IO 04260020
*       B. DISPLACEMENT OF THE RMS/85 NUCLEUS SUCCESSOR IN RMSNXIDS  IO 04320020
*          TABLE IS SET IN RMSNXMOD+1 BY MCHNIP FOR MODULE           IO 04380020
*          SCHEDULING.                                               IO 04440020
*       C. VCONS IN RMS/85 NUCLEUS RESOLVED BY MCHNIP.               IO 04500020
*       D. TTR OF FIRST CHECKSUM RECORD ON SYS1.ASRLIB RESOLVED      IO 04560020
*          BY MCHNIP.                                                   04620020
*       E. ID OF SUCCESSOR OF EACH TRANSIENT MODULE SET IN           IO 04680020
*          RMSNXMOD FIELD BY A TRANSIENT MODULE AFTER IT             IO 04740020
*          DETERMINES WHO SHOULD SUCCEED IT.                         IO 04800020
*                                                                       04860020
*                                                                       04920020
* FUNCTIONS...                                                          04980020
*    THE MCH RESIDENT NUCLEUS SERVES AS THE CONTROL PROGRAM FOR THE     05040020
*    TOTAL MCH OPERATION.  ITS MAJOR FUNCTIONS ARE...                   05100020
*    1. RECEIVES CONTROL VIA THE MCK NEW PSW.                           05160020
*    2. DETERMINES TYPE OF ENTRY--INTERCEPT ERROR,CATASTROPHIC       IO 05220020
*       CONDITION IN CCH,2880 CHANNEL FAILURE,OR  VALID MACHINE         05280020
*       CHECK ERROR CONDITION                                        IO 05340020
*    3. INITIALIZES SOME AREAS IN COMM. AREA AND RECORD BUILD AREA   IO 05400020
*    4. LOADS MCH TRANSIENT MODULES                                  IO 05460020
*    5. PERFORMS ALL IO THROUGH SPECIAL INTERFACE WITH IOS.          IO 05520020
*    6. HANDLES UNEXPECTED HARD MCI DURING RMS/85 PROCESSING.        IO 05580020
*    7. HANDLES PROGRAM CHECKS DURING RMS/85 PROCESSING.             IO 05640020
*       (MONITOR CALL PGM INTERRUPTION RECOGNIZED AND IGNORED)    GTF   05690021
*    8. INTERFACES WITH POST ROUTINE(OS) FOR WTO'S.                  IO 05700020
*                                                                       05760020
*    NOTE...A SHORT NARRATIVE IS GIVEN BEFORE EACH ROUTINE IN THIS      05820020
*           LISTING DESCRIBING THE OPERATION OF THE RESPECTIVE ROUTINE  05880020
* OUTPUTS...                                                            05940020
*                                                                       06240020
*    TO ALL MCH MODULES...                                              06300020
*    1. ENTRY POINT IN GPR 15                                           06360020
*    2. RETURN ADDRESS TO MCH NUC IN GPR 14                             06420020
*    3. ADDR OF INDEPENDENT COMMON AREA IN GPR 11                       06480020
*    4. ENVIRONMENT OF CPU IN COMM/REC ENTRY BUILD AREA                 06540020
*    5. ADDR OF CVT IN GPR 10.                                       IO 06600020
*    6. ADDR OF   DEPENDENT COMMON AREA IN GPR 13                       06660020
*                                                                       06720020
* ENTRY REFERENCES AND V-TYPE ADDRESS CONSTANTS...                      06780020
*    THE FOLLOWING ARE ENTRY REFERENCES AND V-TYPE ADCONS FROM THE MCH  06840020
*********************************************************************** 06900020
* VCONS IN MCH NUCLEUS RESOLVED BY MCHNIP FUNCTION.                  IO 06960020
*    NCOMAREA - BEGINNING ADDRESS OF COMMON AREA.                    IO 07020020
*    NMODBASE - ADDRESS OF MCH TRANSIENT AREA.                       IO 07080020
*    IGFCINT  - ENTRY POINT OF FLIH OF IOS FOR RMS INTERFACE.        IO 07140020
*********************************************************************** 07200020
*                                                                       07260020
*                                                                       07320020
* ERROR CONDITIONS...                                                   07380020
*    REFER TO EXITS                                                     07440020
*                                                                       07500020
* TABLES AND WORKAREAS...                                               07560020
*    MCH COMMUNICATION AND RECORD ENTRY BUILD AREAS                     07620020
*                                                                       07680020
*                                                                       07740020
* RESTRICTONS/CONVENTIONS...                                            07800020
*    1. MCH PROGRAM AND ITS CORE STORAGE MAY NOT BE USED BY OS/360 OR   07860020
*       ANY PROBLEM PROGRAM                                             07920020
*    2. MCH SUPPORTS ONLY                                               07980020
*       A) MODEL 85 SIMPLEX                                             08040020
*       B) MFT2/MVT VERSIONS OF OS                                      08100020
         EJECT                                                          08160020
         SPACE                                                          08220020
**************************  E Q U A T E S  **************************** 08280020
WKR0     EQU   0                                                        08340020
WKR1     EQU   1                                                        08400020
WKR2     EQU   2                                                        08460020
WKR3     EQU   3                                                        08520020
WKR4     EQU   4                                                        08580020
WKR5     EQU   5                                                        08640020
REG6     EQU   6                                                        08700020
WKR6     EQU   6                                                        08760020
WKR7     EQU   7                                                        08820020
WKR8     EQU   8                                                        08880020
WKR9     EQU   9                                                        08940020
WKR10    EQU   10                                                       09000020
REG10    EQU   10                                                       09060020
ADDR1    EQU   10                                                       09120020
ADDR2    EQU   11                                                       09180020
REG12    EQU   12                                                       09240020
WKR13    EQU   13                                                       09300020
CVTREG   EQU   10                  POINTER TO COMM VECTOR TABLE         09360020
BRCOM    EQU   11                    INDEPENDENT COMMON AREA BASE REG   09420020
BRNUC    EQU   12                       BASE REG FOR MCH NUCLEUS     IO 09480020
DEPREG   EQU   13                      DEPENDENT COMMON AREA BASE REG   09540020
REG14    EQU   14                                                       09600020
RETURN   EQU   14                       RETURN POINT                    09660020
ENTRY    EQU   15                       MODULE ENTRY POINT              09720020
REG15    EQU   15                                                       09780020
CS       EQU   C'S'                                                     09840020
N0       EQU   0                                                        09960020
N1       EQU   1                                                        10020020
N2       EQU   2                                                        10080020
N3       EQU   3                                                        10140020
N4       EQU   4                                                        10200020
N5       EQU   5                                                        10260020
N6       EQU   6                                                        10320020
N7       EQU   7                                                        10380020
N8       EQU   8                                                        10440020
N9       EQU   9                                                        10500020
N10      EQU   10                                                       10560020
N12      EQU   12                                                       10620020
N13      EQU   13                                                       10680020
N14      EQU   14                                                       10740020
N15      EQU   15                                                       10800020
N16      EQU   16                                                       10860020
N17      EQU   17                                                       10920020
N18      EQU   18                                                       10980020
N19      EQU   19                                                       11040020
N20      EQU   20                                                       11100020
N21      EQU   21                                                       11160020
N24      EQU   24                                                       11220020
N25      EQU   25                                                       11280020
N28      EQU   28                                                       11340020
N29      EQU   29                                                       11400020
N30      EQU   30                                                       11460020
N32      EQU   32                                                       11520020
N33      EQU   33                                                    IO 11580020
N35      EQU   35                                                    IO 11640020
N36      EQU   36                                                       11700020
N38      EQU   38                                                       11760020
N39      EQU   39                                                    IO 11820020
N40      EQU   40                                                       11880020
N44      EQU   44                                                       11940020
N48      EQU   48                                                       12000020
N51      EQU   51                                                       12060020
N52      EQU   52                                                       12120020
N56      EQU   56                                                       12180020
N60      EQU   60                                                       12240020
N64      EQU   64                                                       12300020
N68      EQU   68                                                       12360020
N88      EQU   88                                                       12420020
N92      EQU   92                                                       12480020
N104     EQU   104                                                      12540020
N120     EQU   120                                                      12600020
N176     EQU   176                                                      12660020
N186     EQU   186                                                      12720020
N192     EQU   192                                                      12780020
N200     EQU   200                                                      12840020
N224     EQU   224                                                      12900020
N232     EQU   232                                                      12960020
N256     EQU   256                                                      13020020
N368     EQU   368                                                      13080020
N512     EQU   512                                                      13140020
N736     EQU   736                                                      13200020
N760     EQU   760                                                      13260020
N833     EQU   833                                                      13320020
N992     EQU   992                                                      13380020
N1016    EQU   1016                                                     13440020
N1024    EQU   1024                                                     13500020
N1248    EQU   1248                                                     13560020
N1272    EQU   1272                                                     13620020
N3072    EQU   3072                                                     13680020
X00      EQU   0                                                        13740020
X01      EQU   1                                                        13800020
X02      EQU   2                                                        13860020
X03      EQU   3                                                        13920020
X04      EQU   4                                                        13980020
X05      EQU   5                                                        14040020
X07      EQU   7                                                        14100020
X08      EQU   8                                                        14160020
X09      EQU   9                                                        14220020
X0A      EQU   10                                                       14280020
X0B      EQU   11                                                       14340020
X0C      EQU   12                                                       14400020
X0D      EQU   13                                                       14460020
X0E      EQU   14                                                       14520020
X0F      EQU   15                                                       14580020
X10      EQU   16                                                       14640020
X13      EQU   X'13'                                                    14650021
X17      EQU   X'17'                                                    14690021
X1C      EQU   28                                                       14700020
X20      EQU   32                                                       14760020
X27      EQU   39                                                       14820020
X30      EQU   48                                                       14880020
X38      EQU   X'38'                                                    14910020
X40      EQU   64                                                       14940020
X41      EQU   X'41'                                                 IO 15000020
X42      EQU   66                                                       15060020
X44      EQU   X'44'                                                 IO 15120020
X50      EQU   80                                                       15180020
X54      EQU   84                                                       15240020
X5C      EQU   92                                                       15300020
X60      EQU   96                                                       15360020
X78      EQU   120                                                      15420020
X7F      EQU   127                                                      15480020
X80      EQU   128                                                      15540020
X85      EQU   133                                                      15600020
X90      EQU   144                                                      15660020
X9F      EQU   159                                                      15720020
XBC      EQU   188                                                      15780020
XBF      EQU   191                                                      15840020
XDF      EQU   223                                                      15900020
XF0      EQU   240                                                      15960020
XFE      EQU   X'FE'                                                    16020020
XFF      EQU   255                                                      16080020
XFB      EQU   X'FB'                                                    16100020
X2E0     EQU   X'2E0'        START OF IC BITS                      IO   16120020
X800     EQU   X'800'                  EQUALS 2K                     IO 16140020
XA02     EQU   2562                                                     16200020
* LOGOUT, STARTING AT X'80' IS MOVED INTO RECPULOG. THE FIRST 736    IO 16260020
* BYTES ARE MOVED IN AND THEN A SPACE OF 24 BYTES IS JUMPED BEFORE   IO 16320020
* THE REST OF THE LOGOUT CONTINUES. THESE 24 BYTES ARE USED BY THE   IO 16380020
* ERROR RECORDER WHEN FORMATTING THE 2ND PART OF THE CPU RECORD.     IO 16440020
XRBQ     EQU   24                       ADR OF REQ ELEMENT IN SIRB      16500020
PSABEGIN EQU   0                       BEGIN. OF PERM.STOR.ASSIGN.   IO 16620020
LOGBEGIN EQU   128                     START OF CPU LOG-OUT AREA     IO 16680020
IOLOGBEG EQU   304                     START OF I/O LOGOUT              16740020
IOLOGSIZ EQU   24                      SIZE OF I/O LOGOUT               16800020
PSASIZE  EQU   128                 SIZE OF PSA AREA                     16860020
NREG12SV EQU   1612                                                     16920020
ACTPOST  EQU   X'40'                                                    16980020
NPGMNPSW EQU   104                      PGM NEW PSW                     17040020
NMCIOPSW EQU   X'30'                   LOCATION MC OLD PSW           IO 17100020
NMCINPSW EQU   112                      MCI NEW PSW                     17160020
NCAW     EQU   72                                                       17220020
NBASESV  EQU   1608                     RMS BASE SAVE                   17280020
NSWIPSW  EQU   1608                     ESTABLISH WAIT STATE PSW        17340020
MASKFOX  EQU   15                                                    IO 17400020
IONEWPSW EQU   120                      PSA LOCATION OF IO NEW PSW   IO 17460020
*********************************************************************** 17520020
***************      EQUATES USED BY MODULE LOADER     **************IO 17580020
***************              SUBROUTINE                **************IO 17640020
         SPACE 1                                                        17700020
NMASKTEN EQU   X'10'                                                    17820020
HISTLEN  EQU   26                       2 LESS THAN SIZE OF HISTORY  IO 17880020
*                                       TABLE.                       IO 17940020
SRCHIDEQ EQU   49                  SEARCH ID EQUAL COMMAND CODE         18000020
TIC      EQU   08                  TRANSFER IN CHANNEL COMMAND CODE     18060020
READ1    EQU   6                   READ DATA COMMAND                    18120020
READ2    EQU   134                 READ DATA COMMAND WITH MULTI-TRACK   18180020
X1       EQU   1                                                        18230021
X2       EQU   2                                                        18280021
X3       EQU   3                                                        18290021
X4       EQU   4                                                        18292021
X5       EQU   5                                                        18294021
X8       EQU   8                                                 GTF    18296021
PCUNEQ   EQU   7                   NOT EQUAL (AFTER COMPARE)            18298021
PGMOPSW  EQU   X'28'                                                    18298421
PCBRANCH EQU   X'47'               BRANCH OP CODE                 GTF   18298821
PCMONCAL EQU   X'AF'               MONITOR CALL AF                GTF   18299221
XC0      EQU    X'C0'                                                   18299621
         SPACE 1                                                        18300020
         ENTRY IGFN0000                                                 18360020
         ENTRY IGFPOST1,IGFPOST2                                        18420020
         EJECT                                                          18480020
         USING *,ENTRY             SET UP ADDRESSABILITY                18540020
         L     WKR6,LIMITS         GET ADDRESS OF START OF CODE         18600020
         SR    WKR6,WKR0           COMPUTE DIFFERENCE                   18660020
         LA    WKR2,IGFIORTN       GET PTR TO THE IOS                   18720020
         SR    WKR2,WKR6           INTERFACE SUBROUTINE                 18780020
         ST    WKR2,N24(WKR1)      AND SAVE FOR INIT. LATER             18840020
         LA    WKR2,IGFLOAD        GET PTR TO THE RMS                   18900020
         SR    WKR2,WKR6           MODULE LOADER SUBROUTINE             18960020
         ST    WKR2,N28(WKR1)      AND SAVE FOR INIT. LATER             19020020
         LA    WKR2,IGFPOST1       GET PTR TO RMS ECB                   19080020
         SR    WKR2,WKR6           POSTING SUBROUTINE                   19140020
         ST    WKR2,N32(WKR1)      AND SAVE FOR INIT. LATER             19200020
         LA    WKR2,NCOMAREA       GET PTR TO LOCATION                  19260020
         SR    WKR2,WKR6           WHICH IS TO BE INIT. TO              19320020
         ST    WKR2,N40(WKR1)      POINT TO THE IND. COMM. AREA         19380020
         LA    WKR2,NMODBASE       GET PTR TO LOCATION                  19440020
         SR    WKR2,WKR6           WHICH IS TO BE INIT. TO              19500020
         ST    WKR2,N36(WKR1)      POINT TO THE MCH TRANS. AREA         19560020
         LA    WKR2,IGFCINT        GET PTR TO LOCATION                  19620020
         SR    WKR2,WKR6           WHICH IS TO BE INIT. TO              19680020
         ST    WKR2,N48(WKR1)      POINT TO IOS INT. HANDLER            19740020
         LA    WKR2,PARMLIST-N4    GET PTR TO LOCATIONS                 19800020
         SR    WKR2,WKR6           WHICH ARE TO BE INIT. FOR            19860020
         ST    WKR2,N56(WKR1)      USE BY RMS ECB POSTING RTN.          19920020
         LA    WKR2,IGFPOST2    GET PTR WHICH                 IE  45542 19970021
         SR    WKR2,WKR6     IS TO BE INIT. TO                IE  45542 20020021
         ST    WKR2,N68(WKR1)    POINT TO POST2               IE  45542 20070021
         LR    WKR1,WKR0           COPY REG FOR EXIT                    20340020
         LA    WKR7,LIST           GET PTR TO LIST OF PTRS FOR UPDATING 20400020
         SPACE 2                                                        20460020
UPDAT    EQU   *                                                        20520020
         CLI   N0(WKR7),XFF        END OF TABLE                         20580020
         BE    QUIT                YES                                  20640020
         L     WKR4,N0(WKR7)       GET PTR TO ADCON                     20700020
         L     WKR2,N0(WKR4)       GET ACTUAL ADDRESS                   20760020
         SR    WKR2,WKR6           ADJUST FOR RELOCATION                20820020
         ST    WKR2,N0(WKR4)       STORE UPDATED VALUE                  20880020
         LA    WKR7,N4(WKR7)       BUMP TO NEXT ADCON                   20940020
         B     UPDAT               CONTINUE                             21000020
         EJECT                                                          21060020
QUIT     EQU   *                                                        21120020
         LM    WKR4,WKR5,LIMITS    GET PTRS TO BEGINNING AND            21180020
*                                  ENDING OF CODE TO BE RELOCATED.      21240020
         SPACE                                                          21300020
*   ASSUME GPR0 CONTAINS A PTR TO THE SPOT IN THE OS NUCLEUS WHERE    * 21360020
* NIP WANTS THIS RELOCATOR TO PUT THE RMS NUCLEUS CODE.               * 21420020
         SPACE                                                          21480020
         SR    WKR5,WKR4           COMPUTE SIZE                         21540020
         LR    WKR7,WKR0           COPY REG                             21600020
         AR    WKR0,WKR5           COMPUTE NEW BOUND OF OS NUC          21660020
         SRL   WKR5,N8             DIVIDE BY 256                        21720020
         LA    WKR5,N1(WKR5)       ADD ONE FOR ANY REMAINING CODE       21780020
RELOCATE EQU   *                                                        21840020
         MVC   N0(N256,WKR7),N0(WKR4) RELOC. 256 BYTES OF PROG.         21900020
         LA    WKR4,N256(WKR4)     BUMP TO NEXT BLOCK                   21960020
         LA    WKR7,N256(WKR7)     BUMP TO NEXT BLOCK                   22020020
         BCT   WKR5,RELOCATE       CONTINUE UNTIL ALL RELOCATED         22080020
         BR    RETURN              RETURN TO NIP                        22140020
         SPACE 2                                                        22200020
LIMITS   DC    A(IGFSTART)         PTR TO START OF MCH NUC. PROG.       22260020
         DC    A(IGFEND)           PTR TO END OF MCH NUC. PROG.         22320020
LIST     DC    A(IECISPSW+N4)                                           22380020
         DC    A(IECISDIS+N4)                                           22440020
         DC    A(LOADCCWS+N8)                                           22500020
         DC    A(NAPPNDGE)                                              22560020
         DC    A(NAPPNDGE+N4)                                           22620020
         DC    A(NAPPNDGE+N8)                                           22680020
         DC    A(NAPPNDGE+N12)                                          22740020
         DC    A(NAPPNDGE+N16)                                          22800020
         DC    A(NMKEMERZ+N4)                                           22860020
         DC    A(NGPRPSW+N4)                                            22920020
         DC    A(NMKDSABL+N4)                                           22980020
         DC    A(NGPRPSW2+N4)                                           23040020
         DC    A(NMKDSAB2+N4)                                           23100020
         DC    A(NSHUTPSW+N4)                                           23160020
         DC    A(NSHUTENB+N4)                                           23220020
         DC    A(NSHUTDIS+N4)                                           23230020
         DC    A(NSHUTEN2+N4)                                           23240020
         DC    A(BLEEDPSW+N4)                                           23250020
         DC    A(NPCKPSW+N4)                                            23260021
         DC    A(NMKEGPR)                                               23280020
         DC    X'FF'               END OF LIST INDICATOR                23340020
         EJECT                                                          23400020
****************  INITIAL ENTRY POINT INTO RMS NUCLEUS  *************** 23460020
*                                                                     * 23520020
* ENTER HERE ON THE OCCURRENCE OF A MCK VIA THE MCK NEW PSW           * 23580020
* POSSIBLE TYPES OF ENTRY ARE...                                        23640020
* 1. CATASTROPHIC ERROR IN CHANNEL CHECK HANDLER(CCH)RESULTS IN CCH *IO 23700020
*    PASSING CONTROL TO MCH WITH FOLLOWING INPUT:                 *  IO 23760020
*              A.BYTE 115 IN MC NEW PSW CONTAINS A '0F' TO       *   IO 23820020
*                 INDICATE CATASTROPHIE IN CCH AND AN INBOARD    *   IO 23880020
*                 RECORD IS ALREADY FORMATTED.                   *   IO 23940020
*              B.REG 13 CONTAINS PTR TO INBOARD RECORD CCH       *   IO 24000020
*                 WANTS MCH TO WRITE OUT TO SYS1.LOGREC.         *   IO 24060020
* 2. 2880 CHANNEL FAILURE-CATASTROPHIC CONDITION CAUSES MCI SINCE       24120020
*    NO CHANNEL LOGOUT POSSIBLE IN THIS INSTANCE. THE FOLLOWING  *   IO 24180020
*    CONDITIONS INDICATE THIS POSSIBLE ENTRY:                     *  IO 24240020
*               A.BYTE 51 IN MC OLD PSW CONTAINS CODE OF '04' TO *   IO 24300020
*                 INDICATE 2880 CHANNEL FAILURE                         24360020
*               B.BYTE 41B IN LOGOUT BIT 0 ALSO INDICATES 2880          24420020
*                 CHANNEL FAILURE                                *   IO 24480020
*               C.BYTE 272(BITS 4-7) AND BYTE 273(B-REG CONTENTS *   IO 24540020
*                 IN LOGOUT) GIVE THE CHANNEL UNIT ADDRESS WHICH  *N IO 24600020
*                 EXPERIENCED THE FAILURE.                       *   IO 24660020
* 3. LEGITIMATE MCI. BYTES 115 AND 50 WILL CONTAIN X'00'.             * 24720020
* INITIAL RUNNING STATE IS DISABLED FOR ALL INTERRUPTS                * 24780020
*                                                                     * 24840020
*********************************************************************** 24900020
         SPACE 1                                                        24960020
         DS    0D                                                       25020020
IGFSTART EQU   *                                                        25080020
IGFN0000 EQU   *                                                        25140020
         USING *,BRNUC                                                  25200020
         USING MCHCOM,BRCOM                                             25240020
         USING ASRCOM,DEPREG                                            25280020
         USING CVTDSECT,CVTREG                                          25320020
         ST    BRNUC,NREG12SV           SAVE GPR 12 IN LOW CORE      IO 25380020
         L     BRNUC,NMCINPSW+N4        SET GPR 12 AS RMS NUC BASE   IO 25440020
         ST    BRNUC,NBASESV            SAVE RMS/85 NUCLEUS BASE REG    25500020
         SPACE 1                                                        25560020
         TM    NMCIOPSW+N3,X0A          INTERCEPT ERROR                 25620020
         BNO   NCCHTST                  NOPE                            25680020
         MVI   NMCIOPSW+N3,X00          CLR ERROR CODE                  25740020
         L     BRNUC,NREG12SV           RESTORE GPR 12               IO 25800020
         LPSW  NMCIOPSW                 RETURN TO SYSTEM                25860020
         SPACE 1                                                        25920020
NCCHTST  EQU   *                                                        25980020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *    IO 26040020
*****   *     *   INITIALIZATION AND HOUSEKEEPING   *    *   *****   IO 26100020
**      *                   FUNCTION                    *      **    IO 26160020
*  THE LOGOUT IN LOW CORE,THE PSA AREA,ALL GPR'S AND FPR'S           IO 26220020
*  ARE MOVED OR SAVED IN THE MCH COMMON AREA                         IO 26280020
         EJECT                                                          26340020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *    IO 26400020
         SPACE 1                                                        26460020
         ST    BRCOM,NSVREG11           SAVE GPR11                      26520020
         L     BRCOM,NCOMAREA           SET GPR11 AS RMS COMMON BASE    26580020
         ST    DEPREG,NSVREG13         SAVE REG 13                      26680020
         L     DEPREG,N0(BRCOM)        SET REG 13 AS DEPENDENT COMMON   26780020
*                                                AREA BASE              26880020
         MVC   REIOLOG(IOLOGSIZ),IOLOGBEG    MOVE I/O LOG TO RE         27060020
         MVC   RECPULOG(N256),LOGBEGIN                 * SAVE           27120020
         MVC   RECPULOG+N256(N256),LOGBEGIN+N256       *  CPU           27180020
         MVC   RECPULOG+N512(N224),LOGBEGIN+N512       *   LOG          27240020
         XC    RECPULOG+N736(N24),RECPULOG+N736        *    IN          27300020
         MVC   RECPULOG+N760(N256),LOGBEGIN+N736       *     RECORD     27360020
         MVC   RECPULOG+N1016(N256),LOGBEGIN+N992      *      ENTRY     27420020
         MVC   RECPULOG+N1272(N232),LOGBEGIN+N1248     *       AREA     27480020
         MVC   RECPULOG+N176(N16),RECPULOG+N368   ADJUST FOR IO         27540020
         XC    RECPULOG+N192(N8),RECPULOG+N192     LOGOUT PROTECT       27600020
         MVC   COMPSA(PSASIZE),PSABEGIN         SAVE PSA                27660020
         MVC   NPGMNPSW(N8),NPCKPSW    SET PROG NEW PSW           GTF   27720021
         MVC   NMCINPSW(N8),NMKEMERZ    SET FOR EMER RTN                27840020
* CLEAR ANY PENDING MCI THAT MAY HAVE OCCURRED AS A RESULT OF THE       27900020
* PREVIOUS ENVIRONMENT SAVING OPERATION                                 27960020
         SPACE 1                                                        28020020
         LPSW  NGPRPSW                  ENAB MCI                        28080020
NGPRSV1  EQU   *                                                        28140020
*********************************************************************** 28200020
*  IF A HARD MCI OCCURS AS A RESULT OF MOVING THE LOGOUT OR          IO 28260020
*  PSA AREA,A DISABLED WAIT STATE IS IMMEDIATELY TAKEN SINCE         IO 28320020
*  FURTHER ANALYSIS WOULD BE FRUITLESS.                              IO 28380020
*********************************************************************** 28440020
         LPSW  NMKDSABL                 DSABL MCI                       28500020
NGPRSV2  EQU   *                                                        28560020
         SPACE 2                                                        28620020
         STM   WKR0,ENTRY,REGSGPR       SAVE GPR0 TO 15                 28680020
         MVC   REGSGPR+N44(N4),NSVREG11 MOVE ORIG REG 11 CONTENTS       28740020
         MVC   REGSGPR+N48(N4),NREG12SV MOVE ORIG REG 12 CONTENTS       28800020
         MVC   REGSGPR+N52(N4),NSVREG13 MOVE ORIG REG 13 CONTENTS       28830020
         SPACE 2                                                        28860020
         STD   WKR0,REGSFPR             SAVE                            28920020
         STD   WKR2,REGSFPR+N8           FPR                            28980020
         STD   WKR4,REGSFPR+N16           REGS                          29040020
         STD   WKR6,REGSFPR+N24            ****                         29100020
         LM    WKR13,WKR10,N0           CLEAR REGS OF PARITY ERROR   IO 29160020
         LD    WKR0,N0                  CLR                             29220020
         LD    WKR2,N0                   ANY                            29280020
         LD    WKR4,N0                    FPR                           29340020
         LD    WKR6,N0                     ERR                          29400020
         MVC   NMCINPSW+N4(N4),NMKEGPR  CLR ANY                    6069 29460020
NGPRSV3  LPSW  NGPRPSW2                  MCI FROM                       29520020
NGPRSV4  LPSW  NMKDSAB2                   REG ERR                       29580020
NGPRSV5  EQU   *                                                        29640020
         B     NCONT                   CONTINUE WITH PROCESSING      IO 29700020
NCLRMCIZ EQU   *                                                        29760020
         CLI   NMCIOPSW+N3,X08          ECC SOFT                        29820020
         BE    NGPRSV1                  YES, CONTINUE                   29880020
         LPSW  NWAITPSW                 NO, CATASTROPHIC ERROR          29940020
NCONT    EQU   *                                                        30000020
         L     CVTREG,MCHCVT           SET CVT BASE REG                 30020020
         L     DEPREG,MCHDPADR         SET DEPENDENT COMMON AREA BASE   30040020
         L     ENTRY,NMODBASE          ADDR TRANS AREA               IO 30060020
         LA    RETURN,NRETPT           SET UP FOR RETURN                30120020
         LA    WKR3,OBREXIT            GET ADR OF OBR EXIT RTN          30126020
         ST    WKR3,COMOBREX           STORE IN COM AREA                30132020
         LA    WKR3,NSHUT              SET SHUT ADDR                    30138020
         ST    WKR3,COMSHUT            IN COMM AREA                     30144020
**       BRANCH TO INIALIZATION MODULE                                  30150020
         B     N8(ENTRY)               ENTER AT DISP OF 8               30180020
NRETPT   EQU   *                                                        30240020
*    RETURN POINT FROM MCH INITIALIZATION (IGFMCH12)                    30300021
*********************************************************************** 30720020
         MVC   NMCINPSW(N8),NSHUTPSW   SET MCI NEW PSW                  30840020
         MVC   MCHDISPL(N1),MCH1STDS   DISP OF 12 TTR ENTRY             30900020
         MVI   RMSNXMOD,X01            SET UP FUNCTIONAL PATH        IO 30960020
*                                      NUMBER FOR RMS/85 NUC MUST    IO 31020020
*                                      BE 1 SINCE ONLY 5B EVER       IO 31080020
*                                      FOLLOWS THE NUCLEUS.          IO 31140020
         MVI   RMSEXLEV,RMS85LEV       MOVE LEVEL OF NUCLEUS INTO    IO 31200020
*                                      HISTORY TABLE.                IO 31260020
RMS85LEV EQU   X'&LEV'        LEVEL OF RMS NUCLEUS                      31350021
         MVI   RMSNXHIS,RMS85ID        SET ID OF NUCLEUS IN             31440020
RMS85ID  EQU   X'85'                   ID OF NUCLEUS IN HEX          IO 31500020
         EJECT                                                          31620020
*********************************************************************** 31680020
         SPACE 1                                                        31740020
***************  M O D U L E   S C H E D U L I N G  ******************* 31800020
*                                                                     * 31860020
* THIS SUBROUTINE IS ENTERED FROM ALL TRANSIENT MCH MODULES WHEN  *  IO 31920020
* A SUCCESSOR IS TO BE LOADED IN AND FROM MCH NUCLEUS WHEN THE    *  IO 31980020
* FIRST MODULE - IGFMCH13 - IS TO BE LOADED. WHEN CONTROL IS GIVEN*  IO 32040020
* TO THIS SUBROUTINE,RMSNXMOD IN THE COMM AREA CONTAINS A VALUE   *  IO 32100020
* WHICH IS USED TO DETERMINE THE SUCCESSORS'S TTR. THE VALUE IS   *  IO 32160020
* SET IN BY THE MCH NUCLEUS,FOR 1ST LOAD, OR A TRANSIENT MODULE   *  IO 32220020
* TO INDICATE ITS SUCCESSOR. USING THIS VALUE,RATHER THAN AN ID,  *  IO 32280020
* WHICH IS THE FUNCTIONAL PATH NUMBER OF THE SUCCESSOR. THE RMSDISPL IO 32340020
* INDICATOR IN THE COMM AREA CONTAINS THE DISPLACEMENT OF THE        IO 32400020
* CURRENT TRANS. MODULE IN THE MODULE SUCCESSOR LIST-RMSNXIDS. THE   IO 32460020
* DISPLACEMENT POINTS TO THE RELATIVE POSITION OF THE FIRST POSS-    IO 32520020
* IBLE SUCCESSOR OF THE CURRENT TRANS. MODULE.                       IO 32580020
*                                                                     * 32640020
*********************************************************************** 32700020
*********************  MODULE COMMON RETURN POINT  ******************** 32760020
NMODRTRN EQU   *                       MODULE SCHEDULER ROUTINE      IO 32820020
*                                      USING FUNCTIONAL PATHS.       IO 32880020
         L     BRNUC,NBASESV       PICK UP NUC BASE                  IO 32940020
         L     BRCOM,NCOMAREA           RE-ESTABLISH REG COMM AREA   IO 33000020
         L     DEPREG,MCHDPADR         SET DEPENDENT COMMON AREA BASE   33030020
         L     CVTREG,MCHCVT           RESET CVT BASE REG(REG 10)       33060020
         SR    WKR1,WKR1                CLEAR REG                    IO 33120020
         IC    WKR1,RMSDISPL            GET DISPLACEMENT INTO        IO 33180020
*                                       SUCCESSOR LIST.              IO 33240020
         L     WKR2,MCHNXIDS            PTR TO SUCCESSOR ID TABLE    IO 33300020
         AR    WKR2,WKR1                DISP + ADDR TABLE            IO 33360020
         BCT      WKR2,REDUCT   SUBTRACT ONE TO GET PROPER ADDR      IO 33420020
REDUCT  EQU  *                                                          33480020
         IC    WKR1,RMSNXMOD            FUNCTIONAL SUCCESSOR PATH NO.IO 33540020
         AR    WKR2,WKR1                ADDRESS OF DESIRED SUCCESSOR IO 33600020
*                                       ID.                          IO 33660020
         L     WKR1,MCHTTRS             PTR TO TTR TABLE             IO 33720020
NMODCHEK EQU   *                                                     IO 33780020
         CLC   N0(N1,WKR1),N0(WKR2)     SEARCH TABLE FOR MODULE ID   IO 33840020
         BE    NIDFOUND                 ID FOUND                     IO 33900020
         LA    WKR1,N5(WKR1)            BUMP TO NEXT 5 BYTE ENTRY    IO 33960020
         B     NMODCHEK                 CONTINUE SEARCH              IO 34020020
NIDFOUND EQU   *                                                     IO 34080020
         MVC   RMSTTRIN(N3),N2(WKR1)   PUT TTR IN FIELD FOR MOD.     IO 34140020
*                                      LOADER-LEFT JUSTIFIED.        IO 34200020
         MVC   RMSDISPL(N1),N1(WKR1)   SAVE DISPLACEMENT FOR NEXT    IO 34260020
*                                      SCHEDULING                    IO 34320020
         MVC   MCHHISTY(HISTLEN),MCHHISTY+N2  MOVE TABLE ENTRIES OVERIO 34380020
*                                             BY 2 SO THAT NEXT MOD. IO 34440020
*                                             CAN PUT IN LEVEL AND   IO 34500020
*                                             SCHEDULER CAN PUT IN   IO 34560020
*                                       ID IN SAME PLACE EACH TIME.  IO 34620020
*                                       AS EACH SUCCESSOR COMES IN   IO 34680020
*                                       THE TABLE INCREASES IN LENGTHIO 34740020
*                                       AND IN THE ORDER THEY WERE   IO 34800020
*                                       CALLED,I.E. PRELIM.ANALYSIS  IO 34860020
*                                       WILL BE FIRST.               IO 34920020
         MVC   RMSNXHIS(N1),N0(WKR1)   PUT NEXT TRANS MOD SCHEDULED  IO 34980020
*                                      IN HISTORY TABLE.             IO 35040020
         MVI   RMSEXLEV,XFF             INIT LAST ENTRY TO X'FF'     IO 35100020
*                                      UNTIL OVERLAID                IO 35160020
         L     WKR3,NMODBASE           ADDR OF TRANS AREA FOR IO     IO 35340020
         ST    WKR3,NREADCCW           INITIALIZE 1ST TEXT CCW       IO 35400020
         MVI   NREADCCW,READ1          AND RESTORE OP CODE           IO 35460020
         LA    WKR3,N1024(WKR3)        BUMP BY 1024 BYTES            IO 35520020
         ST    WKR3,NREADCCW+N16       2ND POSSIBLE TEXT RECORD READ    35580020
         LA    WKR3,N1024(WKR3)        BUMP FOR 3RD POSSIBLE READ    IO 35640020
         ST    WKR3,NREADCCW+N32       3RD POSSIBLE TEXT RECORD      IO 35700020
         MVI   NREADCCW+N16,READ2      RESTORE READ OP CODE          IO 35760020
         MVI   NREADCCW+N32,READ2      RESTORE READ OP CODE          IO 35820020
         LA    ENTRY,NMODLDR           EP TO MODULE LOADER           IO 35880020
         LA    WKR3,LOADCCWS           CHANNEL PROGRAM FOR           IO 35940020
*                                      MODULE LOADING                IO 36000020
         ST    WKR3,RMSIOB+N16         SET IN IOB                    IO 36060020
         MVI   N1STENTR,NMASKTEN       SET BIT 3 TO INDICATE TRANS.  IO 36120021
*                                      MODULE TO BE LOADED.          IO 36180020
         L     WKR1,CVTSVDCB           SVCLIB DCB PTR                IO 36240020
         L     WKR1,N44(WKR1)          DEB PTR FROM DCB NOW LOADED   IO 36300020
         LA    WKR1,N0(WKR1)           CLEAR HIGH ORDER BYTE         IO 36360020
         BALR  RETURN,ENTRY            GO TO MODULE LOADER           IO 36420020
*  INPUT PRIOR TO GIVING CONTROL TO THE MODULE LOADER SUBROUTINE *   IO 36480020
*  IS AS FOLLOWS:                                                *   IO 36540020
*          1. REG 14 CONTAINS RETURN POINT IN MODULE SCHEDULER   *   IO 36600020
*             AT NIODONE.                                        *   IO 36660020
*          2. REG 15 CONTAINS THE EP TO THE MODULE LOADER        *   IO 36720020
*             SUBROUTINE AT NMODLDR.                             *   IO 36780020
*          3. REG 1 CONTAINS THE ADDRESS OF THE DEB OF THE       *   IO 36840020
*             SYS1.SVCLIB.                                       *   IO 36900020
*          4. THE ADDRESS OF THE CHANNEL PROGRAM TO BE EXECUTED  *   IO 36960020
*             IS PLACED IN THE IOB USED BY THE IOS INTERFACE     *   IO 37020020
*             SUBROUTINE.                                        *   IO 37080020
*          5. THE TTR OF THE MODULE TO BE LOADED IN, FROM THE    *   IO 37140020
*             SYS1.SVCLIB,IS PLACED IN THE COMM AREA AT RMSTTRIN.    IO 37200020
NIODONE  EQU   *                                                        37260020
*  RETURN BRANCH TABLE FROM IOS INTERFACE SUBROUTINE.                IO 37320020
*          DISPLACEMENT=0=SUCCESSFUL I/O                             IO 37380020
*          DISPLACEMENT=4=I/O FAILED                                 IO 37440020
         B     NIOSUCCS                RETURN AT DISP.0=SUCCESS      IO 37500020
         B     NIOFAIL                 RETURN AT DISP.4=FAILURE      IO 37560020
NIOSUCCS EQU   *                       SUCCESSFUL LOAD               IO 37620020
         L     ENTRY,NMODBASE      SET MOD BASE REG                     37680020
         LA    RETURN,NMODRTRN         COMMON RETURN POINT FOR       IO 37740020
*                                      ALL TRANSIENT MODULES.        IO 37800020
*  THREE POINTERS USED BY SUBSYSTEM INTERFACE MODULES                   37810020
         LA    WKR2,MCHEXLEV          LEVEL INDICATOR                   37820020
         LA    WKR3,MCHNXMOD           MODULE SUCCESSOR                 37830020
         L     WKR9,MCHSUBP            SUBSYSTEM AREA                   37840020
         BR    ENTRY                   GO TO TRANSIENT MODULE        IO 37860020
NIOFAIL  EQU   *                       UNSUCCESSFUL LOAD             IO 37920020
         XC    RMSIBUF(N30),RMSIBUF    CLEAR OUT BUFFER              IO 37980020
         MVC   RMSIBUF(N20),NLDRMSG-N2  PUT IO ERROR MSG IN          IO 38040020
         B     NSHUT                   AND GO TO EMERGENCY EXIT      IO 38100020
         EJECT                                                          38160020
*********************************************************************** 38220020
         SPACE 1                                                        38280020
*******************  RMS MODULE LOADER SUBROUTINE  ******************** 38340020
*                                                                     * 38400020
* THIS SUBROUTINE RECEIVES CONTROL (1) FROM MOD SCHEDULER WHEN A  *  IO 38460020
* SUCCESSOR TRANSIENT MODULE TO BE LOADED.                              38660020
* WHEN THIS SUBROUTINE IS GIVEN CONTROL RMSTTRIN   CONTAINS THE   *  IO 38880020
* TTR OF THE MEMBER OF THE SVCLIB TO BE READ IN MCH TRANS AREA          38920020
* (2) FROM IGFMCHF1 TO REFRESH THE SVC TRANIENT AREAS.                  38960020
* READ IN. THE ROUTINES WHICH CALL THIS SUBROUTINE HAVE ALREADY   *  IO 39000020
* DONE THE FOLLOWING: 1. SET ADDR OF CHANNEL PROGRAM IN IOB.      *  IO 39060020
*                     2. DEB ADDRESS IN REGISTER 1                   IO 39120020
*                     3. PUT TTR IN COMM AREA- RMSTTRIN           *  IO 39180020
* THE MOD LOADER PICKS UP THE TTR FROM RMSTTRIN AND REFERENCES    *  IO 39240020
* THE EXTENT IN THE DEB TO CONVERT THE TTR TO AN ABSOLUTE ADDRESS.*  IO 39300020
* THE DEVICE TYPE IS PICKED UP FROM THE UCB WHOSE ADDRESS IS IN   *  IO 39360020
* THE EXTENT, IN ORDER TO DETERMINE NUMBER OF TRACKS PER CYLINDER  * IO 39420020
* AND SIZE OF TRACKS. THE RESULT(MBBCCHHR) IS PLACED IN THE IOB IN   IO 39480020
* THE COMM AREA. THE MOD LOADER PUTS THE ADDRESS OF THE IOB IN    *  IO 39540020
* REG 1,LOADS REG 15 WITH THE ADDRESS OF IOS INTERFACE SUBROUTINE,*  IO 39600020
* RESTORES OTHER REGS,AND BRANCHES TO THE IOS INTERFACE (NIOSINTF)*  IO 39660020
* SUBROUTINE.                                                     *  IO 39720020
         SPACE 1                                                        39780020
*********************************************************************** 39840020
         SPACE 1                                                        39900020
IGFLOAD  EQU   *                                                        39960020
NMODLDR  EQU   *                                                        40020020
         SPACE 1                                                        40080020
         STM   WKR0,ENTRY,RMSMLSAV      SAVE ALL REGS OF CALLER      IO 40200020
         L     BRNUC,NBASESV           PICK UP NUC BASE                 40230020
         SPACE 1                                                        40260020
         SR    WKR4,WKR4                INITIALIZE      ***          IO 40320020
         SR    WKR3,WKR3                INITIALIZE REG.              IO 40440020
         L     WKR2,RMSTTRIN            PICK UP TTR PASSED BY CALLER.IO 40500020
         LA    WKR5,N0                 SET EXTENT BEING EXAMINED     IO 40560020
*                                      TO 0 FOR 1ST EXTENT.          IO 40620020
         IC    WKR3,N16(WKR1)          PICK UP NO. EXTENTS           IO 40680020
         LA    WKR4,N32(WKR1)           ADDR 1ST EXTENT.             IO 40740020
         MVC   RMSIOB+N21(N3),N25(WKR1) MOVE DCB PTR IN DEB TO IOB   IO 40800020
         MVC   RMSIOBSK+N7(N1),RMSTTRIN+N2  MOVE RECORD NO. FROM     IO 40860020
*                                      3RD BYTE OF TTR TO SEEK FLD.  IO 40920020
         LH    WKR2,RMSTTRIN           PICK UP RELATIVE TRACK ADDR.  IO 40980020
NEXTCHK  EQU   *                        CHECK TTR AGAINST EACH EXT.  IO 41040020
         SH    WKR2,N14(WKR4)           SUBTRACT NO TRACKS IN EXTENT.IO 41100020
         BM    CNVTTTR                  IF LESS THAN 0,IT IS RIGHT   IO 41160020
         LA    WKR4,N16(WKR4)           OTHERWISE, GET  NEXT EXTENT  IO 41220020
         LA    WKR5,N1(WKR5)           BUMP TO NEXT EXTENT NO.       IO 41340020
         BCT   WKR3,NEXTCHK                                          IO 41400020
*                            INCORRECT TTR OR WROMG DEB                 41500020
         XC    RMSIBUF(N30),RMSIBUF    CLEAR PRT BUFFER              IO 41760020
         MVC   RMSIBUF(N20),NLDRMSG-N2   PUT MESSAGE IN BUFF         IO 41820020
         B     NSHUT                    EMER OUT                        41880020
CNVTTTR  EQU   *                        BEGIN CONVERSION             IO 41940020
         LR    WKR7,WKR4               PUT EXTENT PTR IN REG 7       IO 42000020
         STC   WKR5,RMSIOBSK           SET EXTENT NO. IN SEEK FIELD  IO 42060020
         AH    WKR2,N14(WKR4)           ADD BACK NO.TRACKS IN EXTENT IO 42120020
         BZ    TTRCOMPT                                              IO 42180020
         L     WKR3,N0(WKR4)           PICK UP UCB PTR               IO 42240020
         LA    WKR3,N0(WKR3)           CLEAR HI BYTE                    42270020
         IC    WKR4,N19(WKR3)           GET  UNIT TYPE FROM UCBTYPE  IO 42300020
         LA    WKR5,MASKFOX             GET MASK OF 0F IN LOW ORDER  IO 42360020
         NR    WKR4,WKR5                LEAVE 4 LOW ORDER BITS       IO 42420020
         LR    WKR3,WKR2               PUT TT IN ODD REG             IO 42480020
         L     WKR6,CVTZDTAB            ADDR IO CHARACTERISTICS TBL  IO 42540020
         IC    WKR4,N0(WKR4,WKR6)       USE INDEX FOR DEVICE FACTOR  IO 42600020
         LH    WKR4,N2(WKR4,WKR6)       GET 2 BYTE CONVERSION FACTOR IO 42660020
         SR    WKR2,WKR2               CLEAR EVEN REG                   42720020
         DR    WKR2,WKR4                AS A RESULT OF THIS DIVISION IO 42780020
*                                       THE QUOTIENT IS THE CYLINDER IO 42840020
*                                       DISPLACEMENT AND THE REMAIN- IO 42900020
*                                       DER (IN REG 2) IS THE HEAD   IO 42960020
*                                       DISPLACEMENT FROM THE START  IO 43020020
*                                       OF THE DATA SET              IO 43080020
*                                       AND GET ACTUAL ADDRESS ON    IO 43140020
*                                       DEVICE                       IO 43200020
         AH    WKR3,N6(WKR7)           ADD STARTING ABSOLUTE CYL.    IO 43220020
         AH    WKR2,N8(WKR7)           ADD STARTING ABSOLUTE TRK.    IO 43240020
         CR    WKR2,WKR4                CHECK TO SEE IF CC MUST BE   IO 43260020
*                                       INCREASED BY 1 IF NO.TRACKS  IO 43320020
*                                       GREATER THAN FACTOR          IO 43380020
         BL    NTTRC1                   BRANCH IF NO                 IO 43440020
         SR    WKR2,WKR4                OTHERWISE SUBTRACT TRACK NO. IO 43500020
         LA    WKR3,N1(WKR3)            AND INCREASE CYLINDER BY 1.  IO 43560020
NTTRC1   EQU   *                                                     IO 43620020
         STH   WKR3,NCCHHFLD            STORE CC                     IO 43800020
         STH   WKR2,NCCHHFLD+N2         STORE HH                     IO 43860020
         MVC   RMSIOBSK+N3(N4),NCCHHFLD MOVE IOB SEEK FIELD          IO 43920020
*                                      BYTES 35 - 38                 IO 43980020
NTTRC2   EQU   *                        CONTINUE SET-UP              IO 44040020
*                                       THE SEEK FIELD WILL HAVE     IO 44100020
*                                      M=EXTENT NUMBER MINUS ONE     IO 44160020
*                                       BB=00                        IO 44220020
*                                       CC=ABSOLUTE CYLINDER         IO 44280020
*                                       HH=         TRACK            IO 44340020
*                                       R =         RECORD NUMBER    IO 44400020
         MVC   NSEEKFLD(N8),RMSIOBSK   SET SEEK ADDR AS SEARCH ARG   IO 44460020
         L     WKR5,RMSIOB+N16         PICK UP ADDR CHANNEL PROGRAM  IO 44520020
*                                      IN IOB-SET IN BY REQUESTOR    IO 44580020
         LA    WKR8,NSRCHFLD           PTR TO CCHHRR SEEK ADDR.      IO 44640020
         STH   WKR8,N2(WKR5)           SET LOW ORDER 2 BYTES IN      IO 44700020
         SRL   WKR8,N16                FIRST CCW-BYTES 2 AND 3       IO 44760020
         STC   WKR8,N1(WKR5)           AND THEN 3RD LOW ORDER BYTE   IO 44820020
*                                      IN CCW 1. THIS FIRST          IO 44880020
*                                      CCW IS FOR SEARCH ID EQUAL    IO 44940020
*                                      AND THE PTR BEING SET IN      IO 45000020
*                                      POINTS TO THE CCHHR PORTION   IO 45060020
*                                      OF THE SEEK ADDRESS.          IO 45120020
         LA    ENTRY,NIOSINTF           PICK UP ADDR IOS INTF SUBRTN IO 45180020
         LM    WKR0,RETURN,RMSMLSAV     RESTORE REGS                 IO 45240020
         LA    WKR1,RMSIOB              GET IOB ADDR FOR IOSINTF     IO 45300020
         BR    ENTRY                    BRANCH-NEVER TO RETURN       IO 45360020
TTRCOMPT EQU   *                                                     IO 45420020
         MVC   RMSIOBSK+N3(N4),N6(WKR7)  MOVE STARTING ABSOLUTE      IO 45480020
*                                      CYLINDER AND TRACK IN IOB     IO 45540020
         B     NTTRC2                   RETURN TO RESUME SET-UP      IO 45600020
         EJECT                                                          45660020
*****************************************************************    IO 45720020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   45780020
         SPACE  2                                                       45840020
*                                                               *    IO 45900020
*****                         NIOSINTF                      *****    IO 45960020
*                   IOS INTERFACE SUBROUTINE                    *    IO 46020020
*                                                               *    IO 46080020
*  THIS SUBROUTINE IS ENTERED FROM THE FOLLOWING:               *    IO 46140020
*                  1. MOD LOADER SUBROUTINE -NMODLDR - IN MCHNUC     IO 46200020
*                  2. PDAR REFRESH LOADER -IGFMCHF4                  IO 46260020
*                  3  ERROR RECORDER      -IGFMCH17                  IO 46320020
*                                                                    IO 46380020
*  INPUT TO THIS SUBROUTINE CONSISTS OF THE ADDR OF THE IOB TO       IO 46440020
*  BE USED,IN REG 1. BECAUSE OF THIS THE SUBROUTINE IS INDEPENDENT   IO 46500020
*  OF THE DCB,DEB AND IOB BEING USED. THUS,PDAR REFRESH LOADER AND   IO 46560020
* ERROR RECORDER CAN COME DIRECTLY TO THIS SUBROUTINE FOR I/O RE-    IO 46620020
* QUESTS WHICH INVOLVE A JOBLIB,LINKLIB OR LOGREC DCB AND DEB,RATHER IO 46680020
* THAN THE SVCLIB OR ASRLIB.                                         IO 46740020
*                                                               *    IO 46800020
*****************************************************************    IO 46860020
         SPACE  2                                                       46920020
IGFIORTN EQU   *                                                        46980020
NIOSINTF EQU   *                                                     IO 47040020
         SPACE  2                                                       47100020
         STM   WKR0,ENTRY,RMSMLSAV      SAVE CALLER'S REGS           IO 47160020
         L     BRNUC,NBASESV       PICK UP NUC BASE                  IO 47220020
         MVC   NIOPSWNW(N8),IONEWPSW    SAVE I/O NEW PSW             IO 47280020
         LA    WKR2,NIOFLIH             SET UP TO FIELD I/O INTER.   IO 47340020
         ST    WKR2,IONEWPSW+N4                                      IO 47400020
         OI    RMSECB,WAITBIT           SET WAIT BIT ON IN ECB       IO 47460020
         LA    WKR2,RMSECB              PICK UP ECB ADDR FROM COMM   IO 47520020
         MVI   MCHIOB,X42               RESET IOB                       47580020
         ST    WKR1,IOBSVAD            SAVE IOB ADDR                    47610020
         ST    WKR2,N4(WKR1)            STORE IN IOB,2ND WORD        IO 47640020
         L     WKR2,N20(WKR1)           PICK UP DCB ADDR FROM IOB    IO 47700020
         L     WKR3,N44(WKR2)           PICK UP DEB ADDR FROM DCB    IO 47760020
         MVC   NUCBSAVE+N1(N3),N33(WKR3)  SAVE UCB ADDR              IO 47820020
         C     WKR3,NDEBSAVE        HAS THIS ROUTINE BEEN ENTERED       47830020
*                                      LAST FOR THIS  LIBRARY           47840020
         BE    SKIPAPEN                YES-SKIP APPEND SAVE             47850020
         MVC   NAPPNSVE(N4),N28(WKR3)   SET ASIDE PTR TO APPEND.RTNS IO 47880020
SKIPAPEN  EQU  *                                                        47910020
         ST    WKR3,NDEBSAVE            SAVE DEB ADDR                IO 47940020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   48120020
*                                                                       48180020
*                                                                       48300020
         LA    WKR4,NAPPNDGE           ADDR OWN APPENDAGE ROUTINES   IO 48360020
         STH   WKR4,N30(WKR3)           SET IN 3 BYTE                IO 48420020
         SRL   WKR4,N16                 ADDRESS OF OWN APPENDAGES    IO 48480020
         STC   WKR4,N29(WKR3)           WITHOUT DESTROYING EXT.SCALE IO 48540020
*                                                                       48600020
         L     WKR1,RMSMLSA4          LOAD REG1 WITH IOB ADDR           48660020
         L     ENTRY,MCHIOENT           EP TO SPECIAL IOS INTERFACE  IO 48720020
         CNOP  2,4                                                40762 48770021
         BALR  RETURN,ENTRY            GO TO IOS VIA REG 15          IO 48780020
*                                                               *    IO 48840020
MCHIOSWD DC    F'0'                    IOS INTERFACE WORD         40762 48890021
*              BYTE 0                                             40762 48892021
*                 BIT 0- IOS TO ATTEMPT LOAD                      40762 48894021
*                 BIT 1- TO CLEAR UCB STATUS & LOAD               40762 48896021
*                 BIT 2- TIME OUT RECURSION                       40762 48898021
         SPACE                                                          48900020
         L     BRNUC,NBASESV           SET RMS BASE                     48960020
         L     BRCOM,NCOMAREA           RE-ESTABLISH REG COMM AREA   IO 49020020
         L     DEPREG,MCHDPADR         SET DEPENDENT COMMON AREA BASE   49050020
         L     WKR2,NUCBSAVE           GET UCB ADDR IN REG 2 FOR     IO 49080020
*                                      SELECTIVE ENABLE I/O INT.     IO 49140020
*                                                                       49200020
**                           SELECTIVE ENABLE                           49240020
   IOSGEN  SELSSM,WKR2,(WKR6,WKR7,WKR8,WKR9),0,AUTH=IGFMCH10            49280020
*                                                                       49320020
         LA    WKR1,XFF                GET TIME FOR TIME OUT      40762 49370021
         SLL   WKR1,N12                SET REG TO ONE MILLION     40762 49372021
*                                                        * ENABLE    IO 49380020
WAITSPIN EQU   *                                                     IO 49440020
         TM    RMSECB,WAITBIT           WAIT BIT STILL ON IN ECB?    IO 49500020
WAITBIT  EQU   X'80'                                                 IO 49560020
         BZ    NIODISAB                 NO-STOP BIT SPIN      IH  40762 49620021
         BCT   WKR1,WAITSPIN           YES-CONTINUE BIT SPIN      40762 49670021
         OI    COMINTEL+N1,X08         INDICATE TIME OUT          40762 49672021
         OI    MCHIOSWD,X20            SET TIMEOUT RECURSION      40762 49674021
NIODISAB EQU   *                        OTHERWISE CAN NOW DISABLE    IO 49680020
**                           DISABLE IO INTERRUPTS                      49720020
         IOSGEN  SELSSM,,,1,AUTH=IGFMCH10                               49760020
NMODULIN EQU   *                                                        49920020
         L     WKR2,MCHIODCB           PTR TO DCB                       49980020
         L     WKR3,N44(WKR2)          AND ACCESS DEB                IO 50040020
         MVC   N28(N4,WKR3),NAPPNSVE   RESTORE APPEND TABLE ADDR.    IO 50100020
         MVC   IONEWPSW(N8),NIOPSWNW    RESTORE REAL FLIH            IO 50160020
         TM    MCHIOSWD,X20            HAS A TIME OUT OCCURRED    40762 50210021
         BNO   NOTYET                 NO-CHECK FOR SUCCESSFUL I/O 40762 50212021
         NI    MCHIOSWD,XDF            CLEAR TIME OUT INDICATOR   40762 50214021
         L     CVTREG,MCHCVT           RESET CVT BASE             40762 50216021
         TM    MCHIOSWD,X40            A SECOND TIMEOUT           40762 50218021
         BO    NIOFAIL                 YES-UNSUCCESSFUL LOAD      40762 50218421
         B     NSHUT22C                NO-ONE TOME OUT ONLY       40762 50218821
         SPACE 2                                                        50219221
NOTYET   EQU   *                                                  40762 50219621
         XC    MCHIOSWD(X4),MCHIOSWD CLEAR IOS INTERFACE          40762 50219721
         TM    RMSECB,X7F               SUCCESSFUL COMPLETION?       IO 50220020
         BNO   NIOERR                   BRANCH IF UNSUCCESSFUL       IO 50280020
         LM    WKR0,ENTRY,RMSMLSAV      RESTORE REGS                 IO 50340020
         B     N0(RETURN)               RETURN OFFSET 0              IO 50400020
         SPACE 2                                                        50460020
         SPACE 2                                                        51780020
NIOERR  EQU  *                                                          51840020
         LM    WKR0,ENTRY,RMSMLSAV      RESTORE REGS                 IO 51900020
         B     N4(RETURN)               RETURN OFFSET 4 FOR BAD I/O  IO 51960020
         EJECT                                                          52020020
*****************************************************************    IO 52080020
*                        ABNORMAL END APPENDAGE ROUTINE         *    IO 52140020
*                      ECB=X'7F' 1ST ENTRY FROM ERROR CONDITION *    IO 52200020
*                                RETURN TO IOS OFFSET 0         *    IO 52260020
*                      ECB=X'41' PERMANENT ERROR CONDITION      *    IO 52320020
*                                RETURN TO IOS OFFSET 12        *    IO 52380020
*                      ECB=X'44' IF FIRST I/O REQUEST,DEVICE    *    IO 52440020
*                                END ERROR DOESN'T BELONG TO    *    IO 52500020
*                                RMS; THEREFORE                 *    IO 52560020
*                                RETURN TO IOS OFFSET 8         *    IO 52620020
*                                IF AFTER 2ND OR HIGHER I/O     *    IO 52680020
*                                REQUEST,ECB IS POSTED WITH     *    IO 52740020
*                                A X'41' TO INDICATE PERMANENT  *    IO 52800020
*                                ERROR ON RMS I/O AND           *    IO 52860020
*                                RETURN TO IOS OFFSET 12        *    IO 52920020
*                      ECB=NONE OF THE ABOVE, X'41' POSTED AND  *    IO 52980020
*                                RETURN TO IOS OFFSET 12        *       53040020
*****************************************************************    IO 53100020
         SPACE  2                                                       53160020
NABNLAPP EQU   *                        ABNORMAL END APPENDAGE       IO 53220020
*                                                               *    IO 53280020
         USING *,ENTRY                                                  53340020
         LA    BRCOM,N16                SET REG 11 TO INDEX 16          53400020
         BAL   ENTRY,APNTEST       GO TO APPENDAGE TEST ROUTINE         53460020
         USING *,ENTRY                 USE EP REG=15 AS BASE         IO 53520020
         L     BRCOM,NCOMAREA          RESTORE REG 11 IN ORDER       IO 53580020
*                                      TO ACCESS COMM AREA.          IO 53640020
         CLI   MCHIOECB,X7F             CHECK FIRST ENTRY               53740020
         BE    N0(RETURN)               RETURN TO IOS OFFSET 0          53840020
         CLI   MCHIOECB,X44             DEVICE END ERROR                53940020
         BE    N8(RETURN)               RETURN TO IOS OFFSET 8          54040020
         MVI   RMSECB,X41              SET PERM ERROR CONDITION      IO 54360020
*                                      IF NOT ALREADY ON. M          IO 54420020
         B     N12(RETURN)              RETURN AT OFFSET OF 12       IO 54480020
         DROP   ENTRY                                                   54780020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   54840020
*                                                                       54900020
NNORMAPP EQU   *                                                     IO 54960020
*                        NORMAL END APPENDAGE                   *    IO 55020020
*   CONTROL IS GIVEN TO THIS ROUTINE BY IOS AFTER AN I/O INTER- *    IO 55080020
*   RUPT SHOWS GOOD STATUS. THE IOB EXCEPTION BIT IS TESTED AND *    IO 55140020
*   IF ON,A TEST IS MADE FOR END OF FILE CONDITION BY LOOKING   *    IO 55200020
*   AT THE PREVIOUS CCW WHICH WILL HAVE A READ WITH NO DATA     *    IO 55260020
*   TRANSFER IF SO. AN END OF FILE IS NORMAL WHEN A RMS/85      *    IO 55320020
*   TRANSIENT MODULE IS BEING LOADED IN AND THE FORMAT IS IN 1 K     IO 55380020
*   TEXT RECORDS.  THE IOB EXCEPTION BIT IS TURNED OFF AND      *    IO 55440020
*   CONTROL IS RETURNED TO IOS WITH A X'7F' IN THE ECB. IF NOT  *    IO 55500020
*   AN END OF FILE, THE IOB EXCEPTION BIT IS AGAIN TURNED OFF   *    IO 55560020
*   AND THE ECB IS POSTED WITH A X'41' TO INDICATE A PERMANENT  *    IO 55620020
*   ERROR CONDITION AND CONTROL IS RETURNED TO IOS AT OFFSET    *    IO 55680020
*   OF 12.   IF THE IOB EXCEPTION BIT IS NOT ON, THE            *    IO 55740020
*   ECB IS POSTED WITH A X'7F' AND CONTROL IS GIVEN BACK TO IOS *    IO 55800020
*   AT AN OFFSET OF 12. WHEN THIS APPENDAGE IS ENTERED, THE 1ST *    IO 55860020
*   ENTRY SWITCH IS SET ON SO THAT ALL SUBSEQUENT ENTRIES TO    *    IO 55920020
*   ANY APPENDAGE WILL INDICATE 1ST ENTRY HAS ALREADY OCCURRED. *    IO 55980020
         USING *,ENTRY                                                  56040020
         LA    BRCOM,N12                                                56100020
         BAL   ENTRY,APNTEST       GO TO APPENDAGE TEST ROUTINE         56160020
         USING *,ENTRY                                               IO 56220020
         L     BRCOM,NCOMAREA          RESTORE REG 11 IN ORDER       IO 56280020
*                                      TO ACCESS COMM AREA.          IO 56340020
         TM    RMSIOB,IOBEXCEP          IOB EXCEPTION-BIT 5 ON?      IO 56520020
         BO    BITON                                                 IO 56580020
NORMRETR EQU   *                        RETURN PT.                   IO 56640020
         MVI   RMSECB,X7F               SET SUCCESSFUL COMP.CODE     IO 56700020
         B     N12(RETURN)             RETURN TO IOS AT DISP=12      IO 56760020
BITON    EQU   *                        EXCEPTION BIT ON IN IOB      IO 56820020
*                                                                       56880020
         TM    N1STENTR,NMASKTEN       ?TRANS MODULE BEING LOADED    IO 56940020
         BO    NCSWCHK                 IF SO,CHECK FOR EOF           IO 57000020
         SPACE 2                                                        57060020
NCHNGCDE EQU   *                                                        57120020
         NI    RMSIOB,XFB               CLEAR IOB EXCEPTION BI<         57150020
         MVI   RMSECB,X41              CHANGE CODE FOR ERROR CND.    IO 57180020
         B     N12(RETURN)             RETURN TO IOS OFFSET 12       IO 57240020
IOBEXCEP EQU   X'04'                                                 IO 57480020
NCSWCHK  EQU   *                       THE LAST CCW ADDRESS IS       IO 57540020
*                                      CHECKED TO MAKE SURE IT       IO 57600020
*                                      WAS FOR READ WITH NO DATA     IO 57660020
*                                      TRANSFER                      IO 57720020
         STM   WKR5,WKR6,NTEMPSAV      SET REGS 5 AND 6 ASIDE        IO 57780020
         L     WKR5,RMSIOB+N8          CCW ADDR IN CSW STORED        IO 57840020
         LA    WKR6,N8                 SIZE OF CCW=8 BYTES           IO 57900020
         SR    WKR5,WKR6               BACK UP TO LAST CCW EXECUTED  IO 57960020
         TM    N4(WKR5),X10            NO DATA TRANSFER SPECIFIED?   IO 58020020
*                                      BIT 7 IN 5TH BYTE CCW= NO     IO 58080020
*                                      DATA TRANSFER.                IO 58140020
         LM    WKR5,WKR6,NTEMPSAV      RESTORE REGS 5 AND 6          IO 58200020
         BNO   NCHNGCDE                ERROR CONDITION                  58220020
**                            IF BIT ON, END OF FILE WAS REACHED        58240020
         XI    RMSIOB,IOBEXCEP         TURN EXCEPTION BIT OFF        IO 58280020
         B     NORMRETR                GO BACK TO IOS                IO 58320020
         DROP  ENTRY                                                    58380020
         SPACE 2                                                        58440020
***    FIRST LEVEL INTERRUPT HANDLER                                    58500020
NIOFLIH  EQU   *                        I/O INTERRUPT INTERCEPTOR    IO 58560020
         USING *,WKR6                   SET UP BASE                     58640020
         L     WKR6,IONEWPSW+N4         PICK UP ADDRESS                 58720020
         L     WKR6,IGFCINT             LOAD IOS ENTRY BRANCH           58800020
         BR    WKR6                     GO TO REAL I/O INT.HANDLER      58880020
         DROP  WKR6                                                     58960020
**             END OF EXTENT APPENDAGE                                  59040020
ENDEXT   EQU   *                                                        59100020
         USING *,ENTRY                                                  59160020
         SR    BRCOM,BRCOM              SET REG 11 TO 0 INDEX           59220020
         BAL   ENTRY,APNTEST       GO TO APPENDAGE TEST ROUTINE         59280020
         BR    RETURN              RTN TO IOS                           59340020
**             START IO APPENDAGE                                       59400020
SIOAPN   EQU   *                                                        59460020
         USING *,ENTRY                                                  59520020
         LA    BRCOM,N4                 SET REG 11 TO 4 INDEX           59580020
         BAL   ENTRY,APNTEST       GO TO APPENDAGE TEST ROUTINE         59640020
         BR    RETURN              RTN TO IOS                           59700020
**             PCI  APPENDAGE                                           59760020
PCIAPN   EQU   *                                                        59820020
         USING *,ENTRY                                                  59880020
         LA    BRCOM,N8                 SET REG 11 TO 8 INDEX           59940020
         BAL   ENTRY,APNTEST       GO TO APPENDAGE TEST ROUTINE         60000020
         BR    RETURN              RTN TO IOS                           60060020
APNTEST  EQU   *                                                        60120020
         BALR  REG10,N0                SET UP BASE REG                  60180020
         USING *,REG10                                                  60240020
         C     WKR2,IOBSVAD          COMPARE MCH IOB TO EXECUTING IOB   60300020
         BCR   N8,ENTRY            SAME-BRANCH TO APPENDAGE             60360020
         SPM   RETURN              SET PROGRAM MASK                     60420020
         L     ENTRY,NAPPNSVE      PTR TO APPEND.RTNS TABLE             60480020
         L     ENTRY,N0(BRCOM,ENTRY) LOAD APPENDAGES ADDRESSES          60540020
         BR    ENTRY               BRANCH TO APPEN                      60600020
         DROP  REG10                                                    60640020
         DROP  ENTRY                                                    60680020
         EJECT                                                          60690021
PROGCHEK EQU   *                                                  * GTF 60700021
*                                                                 * GTF 60710021
* THIS ROUTINE INTERCEPTS PGM CHK NEW PSW                         * GTF 60712021
*  1- TO DETERMINE IF A MONITOR CALL.                             * GTF 60714021
*  2- TO ALLOW PROCESSING TO CONTINUE AT NSI IF IT IS.            * GTF 60716021
*  3- TO PROCEED TO UNUSUAL PGM INTERRUPT HANDLER IF IT IS NOT    * GTF 60718021
*                                                                 * GTF 60718421
*                                                                 * GTF 60718821
*  THE LOGOUT AREA IS USED AS A SAVE AREA IN CASE RETURN IS TO NSI. GTF 60719221
         STM   WKR9,REG12,LOGOUT   FREE SOME WORK REGS              GTF 60719621
LOGOUT   EQU   X'88'               SAVE AREA FOR WORK REGS          GTF 60719721
         L     BRNUC,NBASESV         SET RMS BASE                   GTF 60719821
         MVC   NPGMNPSW(N8),NSHUTPSW  SEND PGM CHKS TO SHUT         GTF 60719921
         LA    WKR9,MCEXIT         SET EXIT TO ORIGINAL HANDLER     GTF 60739921
         CLI   PGMOPSW+X03,X01     OPERATION EXCEPTION?             GTF 60749921
         BCR   PCUNEQ,WKR9         NO - TRUE PGM CHK                GTF 60759921
MCNOP    TM    PGMOPSW+X04,XC0     IS INSTR LNG SIX?                GTF 60766621
         BCR   X01,WKR9            YES, TRUE PROG. CHECK            GTF 60768621
         TM    PGMOPSW+X04,X40     INSTR LNG TWO?                   GTF 60770621
         BCR   X01,WKR9            ELIMINATE TWO-BYTE INSTR       GTF   60772621
*                                  (BOTH AF & 44 4-BYTE INSTR)     GTF  60773021
         L     WKRA,PGMOPSW+X04    2ND HALF OF OLD PSW IS NSI     GTF   60773121
         SH    WKRA,PCK4           BACK UP TO INSPECT OP CODE     GTF   60773221
WKRA     EQU   10                                                  GTF  60789921
* TEST THE CONTEXT: 44-00-0-PTR, 47-00-0-DDD ONLY GOOD COMBINATION GTF  60799921
         CLI   X4(WKRA),PCBRANCH   INSTR. AFTER PCK IS BRANCH?     GTF  60801921
         BCR   PCUNEQ,WKR9         IF NOT, GO PROG. CHK            GTF  60803921
         TM    X5(WKRA),XF0        WILL IT BE NO-OP?               GTF  60805921
         BCR   X5,WKR9             BR IF BITS 8-11 ARE NON- ZERO   GTF  60806321
* TEST THE CONTEXT: AF-0C-0-DDD, 47-0C-0-DDD ONLY GOOD COMBINATION GTF  60806421
         CLI   N0(WKRA),PCMONCAL   POTENTIAL MONITOR CALL ?       GTF   60806521
         BE    PCGONSI             YES- GO TO NEXT SEQ.            GTF  60812121
         CLC   N0(X2,WKRA),PCEXEC  NO- IS IT THE EXECUTE?         GTF   60814121
         BCR   PCUNEQ,WKR9         NOT EXECUTE, NO MONITOR CALL   GTF   60816121
         TM    X2(WKRA),XF0        BASE MUST BE ZERO FOR CMT      GTF   60816521
         BCR   X5,WKR9             NON ZERO, BAD CMT              GTF   60816921
         LH    WKRA,X2(WKRA)       GET CLASS MASK TABLE PTR       GTF   60817321
         CLC   N0(X2,WKRA),PCKAF00 2ND HALF WD INDICATE CMT?      GTF   60817421
         BCR   PCUNEQ,WKR9         NO- NOT A MONITOR CALL         GTF   60817521
* GOOD MONITOR CALL ASSUMED AT THIS TIME; TREATED AS NO-OP.       GTF   60817621
PCGONSI  MVC   NPGMNPSW(N8),NPCKPSW SEND PGM CHKS TO PROGCHEK      GTF  60823221
         LM    WKR9,REG12,LOGOUT   RESTORE WORK REGS               GTF  60823321
         LPSW PGMOPSW              RETURN TO NSI (WHICH IS NO-OP)  GTF  60825321
*  THIS POINT IS REACHED WHEN NO MONITOR CALL EXISTS               GTF  60827321
         DS    0F                                                       60827721
         EJECT                                                          60828121
         EJECT                                                          60828821
**********  SPECIAL HANDLER OF UNUSUAL TERMINATIONS (SHUT)  *********** 60834421
*                                                                     * 60840020
* THIS ROUTINE IS ENTERED WHENEVER...                                 * 60900020
*   1. A MODULE DETERMINES AN ERROR REQUIRING IMMEDIATE WAIT STATE.   * 60960020
*        PRIOR TO ENTERING THIS ROUTINE AN ERROR MSG HAS BEEN SET IN  * 61020020
*        COMIBUF AND A WAIT STATE CODE LOADED IN REG 0. THIS ROUTINE  * 61080020
*        WILL ATTEMPT TO WRITE THE MSG ON THE MASTER CONSOLE AND ENTER* 61140020
*        A DISABLED WAIT STATE.                                       * 61200020
*   2. AN UNEXPECTED HARD MCI OCCURS IN RMS CODE.                     * 61260020
*        IF THE ORIGINAL ERROR WAS SOFT A MESSAGE IS SCHEDULED AND THE* 61320020
*          MODULE IGFMCH12(TERMINTOR) IS LOADED AND GIVEN CONTROL. IF   61380020
*        THE ORIGINAL ERROR WAS HARD AN ATTEMPT IS MADE TO WRITE A MSG* 61440020
*        ON THE MASTER CONSOLE AND WAIT STATE IS ENTERED.             * 61500020
*   3. A PROGRAM CHECK OCCURS IN RMS CODE.                            * 61560020
*        ACTION IS THE SAME AS FOR AN UNEXPECTED MCI.                 * 61620020
*                                                                     * 61680020
*********************************************************************** 61740020
         SPACE 1                                                        61800020
NSHUT    EQU   *                                                        61860020
         OI    COMINTEL,X20             MSG IN BUF                      61920020
NSHUT1   EQU   *                                                        61970021
MCEXIT   EQU   *                                                   GTF  62030021
         L     BRNUC,NBASESV            SET RMS BASE                    62040020
         OI    NPGMNPSW+N1,X02          SET PGM WAIT BIT                62100020
         LA    WKR0,XA02                WAIT CODE                       62160020
         ST    WKR0,NPGMNPSW+N4         PUT IN PGM PSW                  62220020
         OI    NPGMNPSW+N7,X01     SET PGM WAIT CODE                    62280020
         OI    NMCINPSW+N1,X02          SET MCI WAIT BIT                62340020
         ST    WKR0,NMCINPSW+N4         PUT WAIT CODE IN MCI PSW        62400020
         LPSW  NSHUTENB                 ENABLE MCI                      62460020
NSHUT2   EQU   *                                                        62520020
         L     BRCOM,NCOMAREA           SET COMM BASE                   62640020
         L     DEPREG,MCHDPADR         SET DEPENDENT COMMON AREA BASE   62670020
         TM    REPRIANL+N2,X10         SECOND TIME ENTER                62672020
         BO    NSHUT22A                YES-BYPASS STATUS SAVE           62674020
         MVC   REIOLOG+N24(N16),N40    SAVE OLD PROG&MCI PSWS           62676020
         LPSW  NSHUTDIS                DISABLE MCI                      62678020
NSHUT20A EQU   *                                                        62680020
         STM   WKR0,ENTRY,TEMPSPRE      SAVE REGS                       62682020
         MVC   NMCINPSW(N8),BLEEDPSW   SETUP NEW MCI PSW                62684020
BLEEDMCI EQU   *                                                        62686020
         LPSW NSHUTEN2                 ENABLE MCI                       62688020
NSHUT21A EQU   *                                                        62690020
         OI    NMCINPSW+N1,X02         SET MCI WAIT PSW                 62692020
         ST    WKR0,NMCINPSW+N4        PUT WAIT CODE IN MCI PSW         62694020
NSHUT22A EQU   *                                                        62696020
         LM   RETURN,WKR10,N0          CLEAR REG PARITY                 62698020
         L     ENTRY,NMODBASE           SET MOD BASE                    62700020
         USING   CVTDSECT,CVTREG                                        62720020
         L     CVTREG,MCHCVT           ESTABLISH BASE                   62740020
         TM    COMINTEL,X20             EMER EXIT                       62760020
         BO    NSHUT4                   YES                             62820020
         OI    REPRIANL+N2,X10          SET MCK OR PCK BIT              62880020
         TM    COMINTEL,X04             5A SCHED                        62940020
         BO    NSHUT3                   YES                             63000020
         TM    COMINTEL,X80             SYS RETURN POSSIBLE             63060020
         BO    NSHUT2A                  NO                              63120020
NSHUT22C EQU   *                                                  40762 63170021
         TM    COMPSA+N51,X08           ORIG ERR SOFT                   63180020
         BO    NSHUT2B                  YES                             63240020
         TM    REMCOPSW+N3,X08     HARD RECOVERED             IH  21961 63290021
         BO    NSHUT2B             YES                        IH  21961 63292021
NSHUT2A  EQU   *                                                        63300020
         TM    COMINTEL,X10       HAS 17 BEEN SCHE FROM SHUT   IE  4927 63350000
         BO    NSHUT2C            YES-THE SECOND TIME-TO 12    IE  4927 63352000
         OI    COMINTEL,X40             SET RMS TO WAIT ON TERM         63360020
*                                                                       63420020
         CLI   RMSNXHIS,X17           WAS ERROR RECORDER LAST ONE 40762 63480021
*                                      SCHEDULED?                    IO 63540020
         BNE   NNEXTID                 IF NOT, CHECK FOR NEXT        IO 63600020
*                                      TO LAST ONE SCHEDULED         IO 63660020
         CLI   RMSEXLEV,XFF            DID 17 EVER GET CONTROL    40762 63720021
         BNE   NSHUT2C                 IF SO,SCHEDULE TERM.          IO 63780020
NSCHD51  EQU   *                                                        63840020
         MVI   RMSNXMOD,X03         DISP IN 12 ENTRY FOR 17       40762 63880021
         OI    COMINTEL,X10            SET IGFMCH17 HAS BEEN SCHED      63920020
         OI    MCHIOSWD,X40            SET SECOND TIME OUT        40762 63930021
         B     NSHUT2D                 CONTINUE                      IO 63960020
NNEXTID  EQU   *                                                        64020020
         CLI   RMSNXHIS-N2,X17         NEXT TO LAST?              40762 64080021
         BNE   NSCHD51                 IF NEITHER,SCHEDULE IT NOW    IO 64140020
         B     NSHUT2C                 OTHERWISE SCHEDULE TERMINATOR IO 64200020
         SPACE 4                                                        64250021
***  SOFT ERROR                                                         64252021
NSHUT2B  EQU   *                                                        64260020
         L     WKR1,COMIPTR             SCHED                           64320020
         MVI   N0(WKR1),N1             UNEX ERR CODE                    64380020
         LA    WKR1,N1(WKR1)              MSG AND                       64440020
         ST    WKR1,COMIPTR                UPDATE PTR                   64500020
         CLI   RMSNXHIS,RMS85ID     HAS AN ATTEMPTED LOAD OCCURED 40762 64550021
         BE    NSHUT2C1                NO-GO TO LOAD 12           40762 64552021
         CLI   RMSNXHIS,X13            HAS A LOAD OCCURRED        40762 64554021
         BNE   NSHUT2C                 YES-GO TO LOAD 12          40762 64556021
         CLI   RMSEXLEV,XFF         HAS THE FIRST MODULE EXECUTED 40762 64558021
         BNE   NSHUT2C                 YES- 13 HAS EXECUTED       40762 64558421
         OI    COMINTEL,X40            SET RMS TO WAIT            40762 64558821
NSHUT2C  EQU   *                                                        64560020
         OI    MCHIOSWD,X40            SET SECOND TIME OUT        40762 64610021
NSHUT2C1 EQU   *                                                  40762 64620021
         OI    COMINTEL,X04            SET 12 SCHED BIT                 64660020
         MVI   RMSNXMOD,X02            DISP IN 12 ENTRY FOR 12          64750020
NSHUT2D  EQU   *                                                        64850020
         MVC   MCHDISPL(N1),MCH1STDS   DISP OF 12 TTR ENTRY             64880020
         MVC   NPGMNPSW(N8),NPCKPSW     RESTORE PROG + MCI        GTF   64920021
         MVC   NMCINPSW(N8),NSHUTPSW     PSW TO SHUT                    64980020
         B     NMODRTRN                GO TO SCHEDULE NEXT TRANS   IO   65280020
NSHUT3   EQU   *                                                        65580020
         XC    COMIBUF(N30),COMIBUF     CLR MSG BUF                     65640020
         MVC   COMIBUF(N21),NEXERR-N2   MOVE IN MSG                     65700020
NSHUT4   EQU   *                                                        65760020
         LA    WKR2,MCHIBUF+N2          GET MESSAGE ADDR                65850020
         L     WKR6,MCHMSB             GET MSB ADDR                     65950020
         USING RMSMSB,WKR6             ESTABLISH MSB BASE               66050020
         LM    WKR7,WKR8,MSBMSCON      GET MASTER AND HARDCOPY          66150020
*                                            CONSOLE UCB ADDR           66250020
         LTR   WKR8,WKR8               BACKUP HARDCOPY AVAILABLE        66350020
         BZ    HARDCOPY                NO-MASTER IS HARDCOPY            66450020
         SPACE 2                                                        66550020
*     THIS ROUTINE GETS CCWS FOR GRAPHICS CONSOLE WRITE                 66650020
         SPACE                                                          66750020
         L     WKR9,CVTCUCB            GET UCM ADDR                     66850020
         LA    WKR4,N4                 GET DECREMENT VALUE              66950020
         SR    WKR9,WKR4               ADJUST ADDR                      67050020
         L     WKR9,N0(WKR9)           GET PREFIX ADDR                  67150020
         L     WKR3,N0(WKR9)           GET MASTER UCM ADDR              67250020
         USING MCSUCM,WKR9             PREFIX BASE                      67350020
         USING UCMLIST,WKR3            UCM ENTRY BASE                   67450020
         SPACE                                                          67550020
         L     WKR7,UCMUCB             GET LAST MASTER UCB              67650020
         ST    WKR7,MSBMSCON          UPDATE MSB MASTER UCB ADDR        67750020
         SPACE                                                          67850020
         L     WKR1,UCMXB              GET DCM ADDR                     67950020
         LTR   WKR1,WKR1          IS MASTER CONSOLE GRAPHICS       5741 67960020
         BNZ   MASTGRAF                 YES-WRITE TO MASTER G      5741 67970020
         LA    WKR1,NBELCCW1           GET BELL CCW ADDR           5741 67980020
         LA    WKR3,CCW2740            GET CCW ADDRESS             5741 67990020
         B     GOWRITE                 SKIP GRAPHICS               5741 68000020
MASTGRAF EQU   *                                                   5741 68010020
         SR    WKR3,WKR3               CLEAR REG                        68050020
         IC    WKR3,N20(WKR1)          GET WRITE CCW COUNT              68150020
         L     WKR1,N20(WKR1)          GET CCW STRING ADDR FOR WRITE    68250020
         LA    WKR1,N0(WKR1)       CLEAR HI-ORDER BYTE        IE  21961 68300021
         BCTR  WKR3,WKR0               DCREMENT FOR CORRECT COUNT       68350020
         SLL   WKR3,N3                 GET DISPLACEMENT TO WRITE CCW    68450020
         AR    WKR3,WKR1               GET ACTUAL ADDRESS               68550020
GOWRITE  EQU   *                                                   5741 68600020
         BAL   WKR4,WPRNT              GO WRITE MESSAGE                 68650020
         SPACE                                                          68750020
         L     WKR3,UCMHCUCM           GET HARDCOPY ENTRY               68850020
         L     WKR7,UCMUCB             GET HARDCOPY UCB ADDR            68950020
         ST    WKR7,MSBHDCPY           UPDATE MSB FIELD                 69050020
         DROP  WKR3,WKR6,WKR9                                           69150020
         SPACE 2                                                        69250020
HARDCOPY EQU   *                                                        69350020
         LTR   WKR7,WKR7               ANY CONSOLE AVAILABLE            69450020
         BZ    SKIPMSG                 NO-BYPASS MESSAGE WRITE          69550020
         LA    WKR1,NBELCCW1           GET BELL CCW ADDR                69650020
         LA    WKR3,CCW2740            GET CCW ADDRESS                  69750020
         BAL   WKR4,WPRNT              GO WRITE MESSAGE                 69850020
SKIPMSG  EQU   *                                                        69950020
         B     NSHUT9                                                   70050020
         SPACE 2                                                        70260020
WPRNT    EQU   *                                                        70350020
         TM    COMINTEL,N1             ERR REC WRITTEN                  70440020
         BO    WRITE1                   YES-                            70530020
         MVI   COMIBUF+X0B,CS     N/-INDICATE SERER TO BE SCH.          70620020
WRITE1   EQU   *                                                        70710020
         USING UCBSECT,WKR7            UCB BASE                         70800020
         LH    WKR7,UCBCHA             GET CUA                          70890020
         DROP  WKR7                                                     70980020
         ST    WKR1,NCAW               SET CCW ADDR IN CAW              71070020
         ST    WKR2,N0(WKR3)           PUT MSG ADDR IN CCW              71160020
         MVI   N7(WKR3),N30        PUT LENGTH IN CCW          IE  21961 71210021
         MVI   N0(WKR3),N1             RESTORE COMMAND CODE             71250020
         L     WKR5,NLCNT              SET TIO LOOP COUNT               71340020
WRITE3   EQU   *                                                        71430020
         TIO   N0(WKR7)                TEST I/O                         71520020
         BC    N2,NBUSY                 BUSY LOOP                       71610020
         BC    N9,WRITE4                OK-TRY SIO                      71700020
         TM    X44,X38                 CUE,BUSY,OR CE             37457 71790020
         BC    N7,WRITE3                BRANCH IF ANY ON                71880020
WRITE4   EQU   *                                                        71970020
         SIO   N0(WKR7)                START I/O FOR WRITE              72060020
         BR    WKR4                    RETURN                           72150020
NBUSY    EQU   *                                                        72240020
         BCT   WKR5,WRITE3             LOOP TILL ZERO                   72330020
         B     WRITE4                   TRY SIO                         72420020
         SPACE                                                          72510020
         SPACE 2                                                        72600020
NSHUT9   EQU   *                                                        73320020
         L     CVTREG,COMCVT        SET CVT BASE REG                    73380020
         LA    CVTREG,N0(CVTREG)                                        73440020
         SH    CVTREG,VALUE8       SET DISP. FOR MOD ID                 73500020
         CLI   N3(CVTREG),X85      IS IT MODEL 85                       73560020
         BNE   NSHUT10                  N0                              73620020
         MVC   RECPULOG+N368(N16),RECPULOG+N176   PUT DATA BACK         73680020
         MVC   LOGBEGIN(N256),RECPULOG            RESTORE               73740020
         MVC   LOGBEGIN+N256(N256),RECPULOG+N256   THE                  73800020
         MVC   LOGBEGIN+N512(N224),RECPULOG+N512    CPU                 73860020
         MVC   LOGBEGIN+N736(N256),RECPULOG+N760     LOG                73920020
         MVC   LOGBEGIN+N992(N256),RECPULOG+N1016     OUT               73980020
         MVC   LOGBEGIN+N1248(N232),RECPULOG+N1272     AREA             74040020
         MVC   IOLOGBEG(IOLOGSIZ),REIOLOG         RESTORE IO LOG        74100020
NSHUT10  EQU   *                                                        74280020
         MVC   NWAITPSW+N6(N2),COMIBUF  PUT WAIT CODE IN PSW            74340020
         MVC   NSWIPSW(N8),NWAITPSW     MOVE PSW TO LOW CORE            74400020
         LPSW  NSWIPSW                  ENTER DSABLD WAIT               74520020
         EJECT                                                          74580020
*      OBR EXIT ROUTINE                                                 74640020
*                                                                       74700020
*  THIS ROUTINE IS USED WHEN OBR HAS BEEN IN CONTROL AND A MCI THEN     74760020
*  OCCURRED.  OBR MAY HAVE BEEN THE CURRENT TCB OR THERE COULD HAVE     74820020
*  BEEN A TASK SWITCH.  IN EITHER CASE, THIS ROUTINE IS EXECUTED.       74880020
*  IT SIMULATES THE TERMINATION (RETURNS REQUEST ELEMENT  TO FREELIST)  74940020
*  OF OBR, SO THAT THE MCI RECORD WRITTEN BY RMS IS NOT OVERLAID BY     75000020
*  THE RECORD TO BE WRITTEN BY OBR.                                     75060020
         SPACE 1                                                        75120020
OBREXIT  EQU   *                                                        75180020
         L     BRNUC,NMCINPSW+N4        GET RMS BASE FOR ADDRESSABILITY 75240020
         L     WKR1,MCHSIRB          PUT RQE IN PARM REG 1              75300020
         L     WKR1,XRBQ(WKR1)          TERMINATE                       75360020
         SVC   N15                       THE OBR                        75420020
         SVC   N3                         TASK                          75480020
         EJECT                                                          75540020
********************  D O U B L E   W O R D S  ************************ 75600020
         SPACE 1                                                        75660020
         DS    0D                                                       75720020
NWAITPSW DC    X'0002000000000A15'      WAIT STATE PSW                  75780020
NMKEMERZ DC    XL5'0'                   PSW TO FIRST MCI                75840020
         DC    AL3(NCLRMCIZ)             EMER RTN                       75900020
NGPRPSW  DC    XL5'0004000000'          PSW TO                          75960020
         DC    AL3(NGPRSV1)              ENAB MCI                       76020020
NMKDSABL DC    XL5'0'                   PSW TO                          76080020
         DC    AL3(NGPRSV2)              DSABL MCI                      76140020
NGPRPSW2 DC    XL5'0004000000'          PSW TO                          76200020
         DC    AL3(NGPRSV4)              ENAB MCI                       76260020
NMKDSAB2 DC    XL5'0'                   PSW TO                          76320020
         DC    AL3(NGPRSV5)              DSABL MCI                      76380020
NSEEKFLD DC    1D'0'                    SEEK/SRCH FLD 2                 76440020
LOADCCWS EQU   *             CHANNEL PROGRAM FOR LOADING  IN TRANS-  IO 76500020
NSRCHCCW EQU   *                                                        76560020
*                                      IENT MODULES.                 IO 76620020
         CCW   SRCHIDEQ,NSRCHFLD,X60,N5 --SEARCH RECORD ID EQUAL        76680020
         CCW   TIC,NSRCHCCW,X60,N1         --TIC TO SEARCH CCW          76740020
NREADCCW EQU   *                                                        76800020
         CCW   READ1,*,X60,N1024       READ SLI,COMMAND CHAINING        76890020
         CCW   READ2,*,X50,N20             --READ       M-T  NO TRANSFR 76980020
         CCW   READ2,*,X60,N1024           --READ  SLI  M-T             77100020
         CCW   READ2,*,X50,N20             --READ       M-T  NO TRANSFR 77160020
         CCW   READ2,*,X60,N1024            --READ  SLI  M-T            77220020
         CCW   READ2,*,X50,N20             --READ       M-T  NO TRANSFR 77280020
         SPACE 1                                                        77340020
NBELCCW1 CCW   X0B,0,X60,1             RING BELL                        77460020
CCW2740  CCW   N1,*,X20,N30             WRITE DATA                      77490020
NPCKPSW  DC    XL5'0004000000'         ENABLED PSW FOR PROG. CHKS GTF   77500021
         DC    AL3(PROGCHEK)           PTR TO PGM. CHK. HNDL.      GTF  77510021
NSHUTPSW DC    XL5'0'                  PGM AND MCI                   IO 77520020
         DC    AL3(NSHUT1)             NEW PSW                       IO 77580020
NSHUTENB DC    XL5'0004000000'         PSW TO ENABLE FOR             IO 77640020
         DC    AL3(NSHUT2)             3RD LEVEL MCI.                IO 77700020
NSHUTDIS DC    XL5'0'                  PSW TO DISABLE FOR MCI           77708020
         DC    AL3(NSHUT20A)                DURING SAVING REGS          77716020
NSHUTEN2 DC    XL5'0004000000'         PSW TO ENABLE FOR MCI            77724020
         DC    AL3(NSHUT21A)                AFTER STORE                 77732020
BLEEDPSW DC    XL5'0'                  NEW MCI PSW DURING THE           77740020
         DC    AL3(BLEEDMCI)              BLEEDING OFF PROCESS          77748020
NSRCHFLD EQU   NSEEKFLD+N3             CCHHR OF SEEK ADDRESS         IO 77760020
WORKAREA DC    14F'0'                  MAINTAINENCE AREA                77850020
         SPACE 1                                                        77940020
****************************  W O R D S  ****************************** 78000020
         SPACE 1                                                        78060020
         DS    0F                                                       78120020
*********************************************************************IO 78180020
********************  VCONS RESOLVED BY MCHNIP **********************IO 78240020
NCOMAREA DC    A(0)                BEGINNING ADDR OF COMM AREA          78300020
NMODBASE DC    A(0)                BEGINNING ADDR OF TRANS. AREA        78360020
IGFCINT  DC    A(0)                EP TO IOS INT. HANDLER               78420020
*********************************************************************** 78480020
NSVREG11 DC    F'0'                     SAVE REG 11                     78660020
NSVREG13 DC    F'0'                    SAVE AREA REG 13                 78690020
NAPPNDGE EQU   *                        APPENDAGE ROUTINES           IO 78720020
         DC    A(ENDEXT)           END/EXTEND APPEN                     78780020
         DC    A(SIOAPN)           SIO APPEN                            78840020
         DC    A(PCIAPN)           PCI APPEN                            78900020
         DC    AL4(NNORMAPP)           NORMAL END APPENDAGE          IO 78960020
         DC    AL4(NABNLAPP)           ABNORMAL END APPENDAGE        IO 79020020
RMSECB   DC    F'0'                    RMS ECB FOR SYSTEM I/O           79080020
NTEMPSAV DC    2F'0'                                                    79140020
NDEBSAVE DC    F'0'          DEBSAVE AREA                               79200020
NUCBSAVE DC    F'0'                     UCB STORE WORD               IO 79260020
NIOPSWNW DC    F'0'                     SAVE FOR I/O NEW PSW         IO 79320020
NCCHHFLD DC    F'0'                                                  IO 79380020
NLCNT    DC    XL4'00A00000'           LOOP TIO COUNT=10 MILLION        79440020
IOBSVAD  DC    F'0'                    SAVE IOB ADDRESS                 79500020
NAPPNSVE DC    F'0'                     SAVE FOR APPEND TABLE PTR    IO 79560020
*************************  H A L F   W O R D S  *********************** 79620020
         SPACE 1                                                        79680020
         DS    0H                                                       79740020
VALUE8   DC    H'8'                DECIMAL VALUE 8 IN A HALFWORD        79800020
PCK4     DC    H'4'                CONSTANT OF 4                   GTF  79850021
*                                                                       79980020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   80040020
*                                                                       80100020
N1STENTR DC    X'00'                   SWITCH TO INDICATE 1ST IO     IO 80160020
*                                      INTERRUPT BEING HANDLED-      IO 80220020
*                                      COULD BELONG TO RMS.          IO 80280020
         SPACE 1                                                        80340020
*************************  M E S S A G E S  *************************** 80400020
         SPACE 1                                                        80460020
         DC    X'0A04'                 WAIT CODE                        80520020
NLDRMSG  DC    C'*IGF006W   I/O ERR'       *                            80580020
         DC    X'0A14'                 WAIT CODE                        80640020
NEXERR   DC    C'*IGF015W   UNEX ERR'           *                       80700020
         SPACE 1                                                        80760020
****************************  B Y T E S  ****************************** 80820020
         DS    0F                                             IE  1069  80870021
NMKEGPR  DC    AL4(NGPRSV3)            MCI PSW ADR                      80880020
PCKAF00  DC    X'AF00'             CLASS MASK TABLE ENTRY         GTF   80990021
PCEXEC   DC    X'4400'             EXECUTE IS FOLLOWED BY ZEROES  GTF   81040021
         EJECT                                                          81060020
*                                                                       81120020
**  RMS POST ROUTINE                                                    81180020
*                                                                       81240020
         DS    0H                                                       81300020
IGFPOST1 EQU   *                                                        81360020
         L     BRNUC,NBASESV     SET MCH BASE                 IE  45542 81370021
         STM   ADDR1,ADDR2,SAV6        SAVE REGS                        81390020
         TM    FLAGBYTE,ACTPOST    IS THIS RTN ALREADY IN PROCESS       81480020
         BO    SKIPPOST            YES                                  81540020
         TM    MCHPSA+N48,XFE      WAS I/O DISABLED WHEN MCI            81600020
         BNZ   RMSPOST1            NO                                   81660020
         OI    FLAGBYTE,ACTPOST    INDICATE  BUSY                       81720020
         L     ADDR1,ADDRS         GET ADDRESS OF NOP IN DISPATCHER     81780020
         MVC   SAVENOP1(N1),N1(ADDR1) SAVE I2 FIELD OF NOP              81840020
         MVI   N1(ADDR1),XF0       MAKE NOP AN UNCONDITIONAL BRANCH     81900020
         LM    ADDR1,ADDR2,SAV6    RESTORE REGS                         81960020
SKIPPOST EQU   *                                                        82020020
         BR    WKR2                                                     82080020
RMSPOST1 EQU   *                                                        82140020
         STM   REG10,REG15,SAV6        SAVE REGS                        82200020
         L     REG15,ADPOST        GET ENTRY POINT TO POST              82260020
         LM    REG10,REG12,PARMLIST GET PARAMETER LIST FOR POST         82320020
         BALR  REG14,REG15         LINK TO POST RTN.                    82380020
         DROP  12                                                       82440020
         USING *,14                                                     82500020
         LM    REG10,REG15,SAV6        RESTORE REGS                     82560020
         BR    WKR2          RETURN TO CALLER                           82620020
         DROP  14                                                       82680020
         EJECT                                                          82740020
*  ENTRY VIA GPR 15 FROM OS SUPERVISOR                                  82800020
IGFPOST2 EQU   *                                                        82860020
         USING *,15                                                     82920020
         STM   10,14,SAV6          SAVE REGS                            82980020
         L     ADDR1,ADDRS         GET ADDRESS OF NOP IN DISPATCHER     83040020
         MVC   N1(N1,ADDR1),SAVENOP1 RESTORE I2 FIELD OF NOP            83100020
         LM    REG10,REG12,PARMLIST GET PARAMETER LIST FOR POST         83160020
         L     REG15,ADPOST        GET ENTRY POINT TO POST RTN          83220020
         BALR  REG14,REG15         LINK TO POST                         83280020
         DROP  15                                                       83340020
         USING *,14                                                     83400020
         NI    FLAGBYTE,XFF-ACTPOST CLEAR BUSY FLAG                     83520020
         L     CVTREG,MCHCVT           RESTORE CVT BASE       IE  51213 83570000
         L     REG15,CVT0DS      ADDRESS OF PT. IN DISPATCHER IE  51213 83580000
         LM    REG10,REG14,SAV6        RESTORE REGS                     83610020
         BR    REG15               GIVE CONTROL BACK TO DISPATCHER      83640020
*********************************************************************** 83700020
*                                                                     * 83760020
*  NOTE - THE FOLLOWING 5 WORDS MUST BE CONTIGUOUS AND IN THIS ORDER  * 83820020
*        SO THAT THE MCH INITIALIZATION MODULE CAN INITIALIZE         * 83880020
*        THEM CORRECTLY.   (WORDS 'ADDRS' THROUGH 'ADPOST')           * 83940020
*                                                                     * 84000020
*********************************************************************** 84060020
ADDRS    DC    A(0)                PTR TO NOP IN BEGIN. OF DISPATCHER   84120020
PARMLIST EQU   *                                                        84180020
         DC    F'0'                ADDR OF ERROR RECORDER INTFACE WD    84240020
         DC    F'0'                ADDRESS OF RMS ECB                   84300020
         DC    A(0)                ADDRESS OF COM. TASK TCB             84360020
ADPOST   DC    A(0)                ADDRESS OF ENTRY TO POST RTN.        84420020
SAV6     DS    6F                  SAVE AREA                            84480020
SAVENOP1 DC    X'00'                                                    84540020
FLAGBYTE DC    X'00'                                                    84600020
         SPACE 3                                                        84650021
***   MAINTENANCE  AREA  ***                                            84652021
MAINTID  DC    CL8'IGFMCH10'           CORE IDENTIFIER                  84654021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              84656021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 84658021
IGFEND   EQU   *                                                        84660020
         EJECT                                                          84720020
MCHCOM   DSECT                                                          84780020
         MCHMAC                                                         84840020
COMIBUF  EQU   MCHIBUF                                             IO   84900020
COMPSA   EQU   MCHPSA                                              IO   84960020
COMINTEL EQU   MCHINTEL                                                 85020020
COMCVT   EQU   MCHCVT                                              IO   85080020
COMIPTR  EQU   MCHIPTR                                             IO   85140020
RMSIBUF  EQU   MCHIBUF                                                  85200020
RMSDISPL EQU   MCHDISPL                                                 85260020
RMSEXLEV EQU   MCHEXLEV                                                 85320020
RMSIOB   EQU   MCHIOB                                                   85380020
RMSIOBSK EQU   MCHIOBSK                                                 85440020
RMSMLSAV EQU   MCHMLSAV                                                 85500020
RMSMLSA4 EQU   RMSMLSAV+4          IOB SAVE AREA                        85560020
RMSNXHIS EQU   MCHNXHIS                                                 85620020
RMSNXMOD EQU   MCHNXMOD                                                 85680020
RMSTTRIN EQU   MCHTTRIN                                                 85740020
ASRCOM   DSECT                                                          85770020
         ASRMAC85                                                       85800020
CVTDSECT DSECT                                                          85860020
         CVT                                                            85920020
RMSMSB   DSECT                                                          85980020
         RMSMSB   MOD=85                                                86040020
UCMSECT  DSECT                                                          86100020
         IEECUCM                                                        86160020
UCBSECT  DSECT                                                          86180020
         IEFUCBOB                                                       86200020
         END                                                            86220020
