         LCLA  &LEV,&REL                                                00150021
&LEV     SETA  40                                                       00160000
&REL     SETA  21                                                       00170021
&REL&LEV TITLE 'IGFMCH13 LEVEL &LEV RMS-MCH PRELIMINARY ERROR ANALYSIS' 00180021
*********************************************************************** 00200020
*                                                                     * 00300020
* MODULE  IGFMCH13 - PRELIMINARY ERROR ANALYSIS                         00400020
*                                                                     * 00500020
* FUNCTION/OPERATION                                                  * 00600020
*       THE PRELIMINARY ERROR ANALYSIS MODULE HAS THE PRIMARY FUNCTION* 00700020
*   OF ANALYZING THE MACHINE CHECK INTERRUPTION INFORMATION AND SOME  * 00800020
*   LOGOUT INFORMATION TO DETERMINE THE RECOVERY STRATEGY FOR RMS/85. * 00900020
*                                                                     * 01000020
*       BESIDES THIS MAJOR FUNCTION, CERTAIN OTHER BASIC FUNCTIONS ARE* 01100020
*   PROVIDED. THEY ARE AS FOLLOWS - THE RMS/85 STATUS IS COMPARED WITH* 01200020
*   THE ACTUAL MACHINE STATUS AND AN ERROR MESSAGE IS SCHEDULED IF    * 01300020
*   THERE IS ANY DISCREPANCY. THE INSTRUCTION AT WHICH THE INTERRUPT  * 01400020
*   OCCURRED AND IT'S ADDRESS ARE FOUND. TWO CPU ADDRESS GENERATION   * 01500020
*   ROUTINES(2365 AND 2385) ARE PROVIDED FOR THE PURPOSE OF FINDING   * 01600020
*   THE ADDRESS OF THE STORAGE LOCATION WHICH WAS BEING REFERENCED    * 01700020
*   WHEN EITHER AN SPF KEY CHECK OR A STORAGE MARK OR DATA CHECK      * 01800020
*   OCCURRED. THE MCW IS SET UP FOR AUTOMATIC SWITCHING TO COUNTER    * 01900020
*   MODE IF THE OPERATOR SPECIFIED AN ERROR COUNT THRESHOLD AND THE   * 02000020
*   THRESHOLD COUNT HAS BEEN REACHED.                                 * 02100020
*                                                                     * 02200020
* ENTRY POINT - IGFMCH13                                                02300020
*                                                                     * 02400020
* INPUT - HIR AND ECC COUNTERS, STATUS LOGOUT, MICROFICHE LOGOUT, CRT * 02500020
*   LOGOUT AND CRT PARITY LOGOUT, MACHINE CHECK OLD PSW, AND RETHIR,  * 02600020
*   RETECC, RELHIR AND RELECC RECORD ENTRY BUILD AREA FIELDS OF THE   * 02700020
*   MCH COMMON AREA.                                                  * 02800020
*                                                                     * 02900020
* OUTPUT - CPU ERROR INFORMATION FOR PDAR MODULES, ERROR INFORMATION  * 03000020
*   FOR SPF AND STORAGE ANALYSIS MODULES, AND ERROR MESSAGE CODES FOR * 03100020
*   WTO ROUTINE.                                                      * 03200020
*                                                                     * 03300020
* EXITS-NORMAL - VIA MCHNUC TO ONE OF THE FOLLOWING MODULES - SYSTEM  * 03400020
*   ANALYSIS(IGFMCHF1-F3), SPF ANALYSIS(IGFMCH15), MAIN STORAGE       * 03500020
*   ANALYSIS(IGFMCH19), BUFFER CONTROL(IGFMCH16), ALTERNATE MULTIPLY  * 03600020
*   CONTROL(IGFMCH18), OR ERROR RECORDER(IGFMCH17)                      03700020
*                                                                     * 03800020
* EXITS-ERROR - TO THE SHUT ROUTINE LOCATED WITHIN IGFNUC00.          * 03900020
*                                                                     * 04000020
* TABLES/WORK AREAS - LOCATED WITHIN THE MCH COMMON AREA.             * 04100020
*                                                                     * 04200020
* ATTRIBUTES - TRANSIENT, SERIALLY REUSABLE, OPERATES IN SUPERVISOR   * 04300020
*   MODE.                                                             * 04400020
*                                                                     * 04500020
*********************************************************************** 04600020
         SPACE 2                                                        04700020
*********************************************************************** 04800020
*                                                                     * 04900020
*     P R E L I M I N A R Y   E R R O R   A N A L Y S I S             * 05000020
*                                                                     * 05100020
*********************************************************************** 05200020
         SPACE 1                                                        05300020
IGFMCH13 CSECT                                                          05400020
         USING *,BASEREG                                                05500020
         USING MCHCOM,COMREG                                            05550020
         USING ASRCOM,DEPREG                                            05600020
         USING  RMSMSB,MSBREG                                           05650020
         SPACE 1                                                        05700020
*                        E Q U A T E S                                * 05800020
WKR0     EQU   0                   WORK REG                             05900020
WKR1     EQU   1                   WORK REG                             06000020
WKR2     EQU   2                   WORK REG                             06100020
WKR3     EQU   3                   WORK REG                             06200020
WKR4     EQU   4                   WORK REG                             06300020
WKR5     EQU   5                   WORK REG                             06400020
WKR6     EQU   6                   WORK REG                             06500020
WKR7     EQU   7                   WORK REG                             06600020
WKR8     EQU   8                   WORK REG                             06700020
WKR9     EQU   9                   WORK REG                             06800020
MSBREG   EQU   10                      MSB BASE REG                     06900020
COMREG   EQU   11                    INDEPENDENT COMMON AREA BASE REG   07000020
BASEREG  EQU   12                  BASE REG FOR THIS MODULE             07100020
DEPREG   EQU   13                      DEPENDENT COMMON AREA BASE REG   07200020
ASRNUCR  EQU   14                  NUCLEUS RETURN REG                   07300020
EPREG    EQU   15                  ENTRY POINT REG                      07400020
OFF      EQU   8                   BRANCH ON CONDITION INDICATOR        07500020
ZERO     EQU   0                   IMMEDIATE DATA                       07600020
UNO      EQU   1                   IMMEDIATE DATA                       07700020
TWO      EQU   2                   IMMEDIATE DATA                       07800020
THREE    EQU   3                   IMMEDIATE DATA                       07900020
FOUR     EQU   4                   IMMEDIATE DATA                       08000020
FIVE     EQU   5                   IMMEDIATE DATA                       08100020
SIX      EQU   6                   IMMEDIATE DATA                       08200020
EIGHT    EQU   8                   IMMEDIATE DATA                       08300020
ANLNGTH  EQU   8                   LENGTH OF PREL. ANALYSIS REPORT AREA 08400020
D14      EQU   14                  IMMEDIATE DATA                       08500020
D24      EQU   24                  IMMEDIATE DATA                       08600020
D72      EQU   72                  IMMEDIATE DATA                       08700020
TWENTY   EQU   20                  IMMEDIATE DATA                       08800020
TWENTWO  EQU   22                  IMMEDIATE DATA                       08900020
REMLNGTH EQU   104                 LENGTH OF REMEST FIELD               09000020
CI       EQU   C'I'                IMMEDIATE DATA                       09100020
XFF      EQU   X'FF'               IMMEDIATE DATA                       09200020
XFC      EQU   X'FC'               IMMEDIATE DATA                       09300020
XF0      EQU   X'F0'               IMMEDIATE DATA                       09400020
XE0      EQU   X'E0'               IMMEDIATE DATA                       09500020
XC0      EQU   X'C0'               IMMEDIATE DATA                       09600020
X80      EQU   X'80'               IMMEDIATE DATA                       09700020
X7F      EQU   X'7F'               IMMEDIATE DATA                       09800020
X50      EQU   X'50'               IMMEDIATE DATA                       09900020
X42      EQU   X'42'               IMMEDIATE DATA                       10000020
X40      EQU   X'40'               IMMEDIATE DATA                       10100020
X3C      EQU   X'3C'               IMMEDIATE DATA                       10200020
X38      EQU   X'38'               IMMEDIATE DATA                       10300020
X30      EQU   X'30'               IMMEDIATE DATA                       10400020
X20      EQU   X'20'               IMMEDIATE DATA                       10500020
X1C      EQU   X'1C'               IMMEDIATE DATA                       10600020
X19      EQU   X'19'               IMMEDIATE DATA                       10700020
X14      EQU   X'14'               IMMEDIATE DATA                       10800020
X13      EQU   X'13'               IMMEDIATE DATA                       10900020
X12      EQU   X'12'                IMMEDIATE DATA                  IO  10950020
X11      EQU   X'11'               IMMEDIATE DATA                       11000020
X10      EQU   X'10'               IMMEDIATE DATA                       11100020
X0F      EQU   X'0F'               IMMEDIATE DATA                       11200020
X0E      EQU   X'0E'               IMMEDIATE DATA                       11300020
X0D      EQU   X'0D'               IMMEDIATE DATA                       11400020
X0C      EQU   X'0C'               IMMEDIATE DATA                       11500020
X0B      EQU   X'0B'               IMMEDIATE DATA                       11600020
X09      EQU   X'09'               IMMEDIATE DATA                       11700020
X08      EQU   X'08'               IMMEDIATE DATA                       11800020
X07      EQU   X'07'               IMMEDIATE DATA                       11900020
X04      EQU   X'04'               IMMEDIATE DATA                       12000020
X03      EQU   X'03'               IMMEDIATE DATA                       12100020
X02      EQU   X'02'               IMMEDIATE DATA                       12200020
X01      EQU   X'01'               IMMEDIATE DATA                       12300020
X0       EQU   X'0'                IMMEDIATE DATA                       12400020
X0A      EQU   X'0A'       HEX CONSTANT                             IO  12410020
NEXT5F   EQU   X'04'       BUFFER CONTROL                           IO  12420020
NEXT6F   EQU   X'05'       ALT. MULTI CONTROL                       IO  12430020
NEXT5D   EQU   X'03'       SPF ANAYLSIS                             IO  12440020
NEXT7D   EQU   X'06'       MAIN STORAGE ANALYSIS(SCAN)              IO  12450020
NEXT50   EQU   X'01'       PDAR ID                                  IO  12460020
NEXT51   EQU   X'02'       RECORDER ID                              IO  12470020
         SPACE 1                                                        12500020
         LR    WKR0,BASEREG        SAVE REG 12                          12800020
         LR    BASEREG,EPREG       SET UP BASE REG                      12900020
         L     MSBREG,MCHMSB           ESTABLISH BASE                   12950020
         SPACE 1                                                        15300020
*********************************************************************** 15400020
***     BEGINNING OF ERROR ANALYSIS                                 *** 15500020
*********************************************************************** 15600020
         SPACE 1                                                        15700020
START    EQU   *                                                        15800020
         MVI   MCHEXLEV,LEVEL          MODULE LEVEL                     16200021
LEVEL    EQU   X'&LEV'                                                  16250021
         XC    REPRIANL(ANLNGTH),REPRIANL    CLEAR PRI ANAL REPORT AREA 16600020
         XC    REMEST(REMLNGTH),REMEST  CLEAR REMEST TABLE              16700020
         L     WKR4,MCHIPTR        POINTER TO MESSAGE BUFFER        IO  16800020
         TM    COMINTEL+UNO,X02        TEST FOR 2880 HANG DETECT        16830020
         BO    LOADERR                 YES- GO TO RECORD                16860020
         SPACE                                                          16900020
VALIDLOG EQU   *                                                        18500020
         CLI   RETYPE,CI           IS THIS AN INBOARD RECORDING         18600020
         BE    LOADERR             YES,BRANCH TO LOAD ERROR RECORDER    18700020
         TM    MCIOPSW2,X20        IS IT A VALID LOGOUT                 18800020
         BO    CHKSTAT             YES,BRANCH TO CHECK STATUS           18900020
         TM    L497,X10            IS PART OF LOG VALID                 19000020
         BZ    INVLOG              NO,BRANCH TO INVALID LOGOUT          19100020
         OI    REPRIAN2,X20        REPORT PARTIAL LOG VALID             19200020
         B     CHKSTAT             BRANCH TO CHECK STATUS               19300020
INVLOG   OI    REPRIAN2,X40        REPORT INVALID LOGOUT                19400020
         TM    MCIOPSW3,X08        IS IT A SOFT MCI                     19500020
         BO    SOFTMCI             YES,BRANCH                           19600020
NORETRY  CLI   MCIOPSW3,X04        IS IT AN UNRETRYABLE ERROR           19700020
         BE    GODOWN              YES,BRANCH TO PUT SYSTEM DOWN        19800020
         CLI   MCIOPSW3,X14        IS IT AN UNRETRYABLE ERROR           19900020
         BE    GODOWN1             YES,BRANCH TO PUT SYSTEM DOWN        20000020
GETIC    L     WKR7,L8C            LOAD RETRY IC                        20100020
         LA    WKR7,ZERO(WKR7)     CLEAR HIGH ORDER BYTE                20200020
         ST    WKR7,REPDARI        STORE ADDR OF INST                   20300020
         OI    REPDAR1,X80         SET UP TERMINATION NECESSARY         20400020
         B     LOADPDAR            BRANCH TO LOAD PDAR                  20500020
GODOWN1  OI    STERROR,X04         MARK STORAGE DATA FAILURE            20600020
         OI    REMERTYP,X40        MULTIPLE BIT ERROR                   20700020
         OI    REPRIANL,X40        REPORT MULTIPLE BIT ERROR            20800020
GODOWN   OI    COMINTEL,X40        SET SYSTEM PUT DOWN BIT              20900020
         OI    REPRIANL,X04        REPORT UNRETRYABLE                   21000020
         B     LOADERR             BRANCH TO LOAD ERROR RECORDER        21100020
**    COMPARE RMS STATUS WITH ACTUAL STATUS                          ** 21200020
         SPACE                                                          21300020
         SPACE                                                          21400020
CHKSTAT  EQU   *                                                        21500020
GETSTAT  LA    WKR5,LB8            GET STARTING ADDR OF SECTOR ADR REGS 21600020
         LA    WKR6,EIGHT          NUMBER OF SETS OF 4                  21700020
         SR    WKR7,WKR7           CLEAR REG                            21800020
         SR    WKR8,WKR8           CLEAR REG                            21900020
GETSTAT1 LA    WKR9,FOUR           GET 4 SECTOR DELETE BITS             22000020
         LR    WKR3,WKR5               GET UPDATED ADDRESS              22100020
GETSTAT2 SLL   WKR8,UNO            POSITION FOR NEXT BIT                22200020
         IC    WKR7,FOUR(WKR3)         GET SECTOR DELETE BIT            22300020
         OR    WKR8,WKR7           OR BIT TO DATA REG                   22400020
         LA    WKR3,D72(WKR3)     BUMP ADDR TO NEXT SECT ADDR REG       22500020
         BCT   WKR9,GETSTAT2       DO 4 BITS AT A TIME                  22600020
         LA    WKR5,EIGHT(WKR5)    UPDATE ADDR TO NEXT DOUBLEWORD       22700020
         BCT   WKR6,GETSTAT1       DO 8 SETS OF 4                       22800020
         ST    WKR8,TEMPSTO        TEMP STORE SECTOR DELETE BITS        22900020
         C     WKR8,RESECT         DOES STATUS AGREE                    23000020
         BNE   BADSTAT             NO,BRANCH TO SCHEDULE MSG            23100020
         LM    WKR2,WKR3,RESMCW    LOAD RMS MCW INTO REGS               23200020
         N     WKR2,MULTDIS        ZERO ALL BUT MULT DISABLE BIT        23300020
         N     WKR3,MODEBUF        ZERO ALL BUT BUF DIS AND MODE BITS   23400020
         L     WKR7,L478           LOAD BITS FROM ACTUAL MCW            23500020
         SLL   WKR7,TWO            GET TEST BIT IN CORRECT POSITION     23600020
         N     WKR7,MULTDIS        ZERO ALL BUT MULT DISABLE BIT        23700020
         CLR   WKR2,WKR7           ARE MULT DISABLE BITS EQUAL          23800020
         BNE   BADSTAT             NO,BRANCH TO SCHEDULE STATUS ERR MSG 23900020
         SR    WKR6,WKR6           CLEAR REGISTER                       24000020
         L     WKR7,L480           LOAD BITS FROM ACTUAL MCW            24100020
         SLDL  WKR6,D14            SHIFT BITS                           24200020
         SLL   WKR7,TWO            GET RID OF UNUSED BITS               24300020
         SLDL  WKR6,FOUR           GET MODE BITS                        24400020
         SLL   WKR6,D24            ALIGN BITS IN CORRECT POSITION       24500020
         N     WKR6,MODEBUF        ZERO ALL BUT BUF DIS AND MODE BITS   24600020
         CLR   WKR3,WKR6           ARE BUF DIS AND MODE BITS EQUAL      24700020
         BE    FAILINST            YES,BRANCH TO GET FAILING INST. ADDR 24800020
BADSTAT  EQU   *                                                        24860020
         MVI   ZERO(WKR4),X0A      REQUEST IGF041 STATUS ERR MSG    IO  24920020
         LA    WKR4,UNO(WKR4)      INCREASE MESSAGE BUFFER POINTER      25000020
         OI    REPRIAN2,X80        REPORT STATUS ERROR                  25100020
         SPACE                                                          25200020
***           GET ADDRESS OF FAILING INSTRUCTION                    *** 25300020
         SPACE                                                          25400020
FAILINST EQU   *                                                        25500020
         L     WKR7,L8C            GET ADDR OF INST AT INTERRUPT        25600020
         LA    WKR7,ZERO(WKR7)     CLEAR HIGH ORDER BYTE                25700020
         ST    WKR7,REPDARI        STORE ADDRESS OF INSTRUCTION         25800020
         SPACE 1                                                        25900020
***   CHECK FOR HARD OR SOFT MACHINE CHECK INTERRUPTION             *** 26000020
         SPACE 1                                                        26100020
HARDSOFT EQU   *                                                        26200020
         TM    MCIOPSW3,X08        IS IT A SOFT MCI                     26300020
         BO    SOFTMCI             BRANCH,IF YES                        26400020
***     CHECK FOR MCI THAT OCCURRED DURING CCH OPERATION            *** 26500020
*                                                                       26600020
         CLI   CCHMCI,X01          CHECK TO SEE WHETHER THE MCI         26700020
         BE    ERRMSG1              COMES FROM CCH---BRANCH,IF YES      26800020
         SPACE 1                                                        26900020
***     CHECK FOR VALIDITY OF INTERRUPT CODE OF MCK OLD PSW         *** 27000020
         SPACE 1                                                        27100020
VALIDCHK EQU   *                                                        27200020
         CLI   MCIOPSW3,X0         CHECK THE VALIDITY OF INTERRUPT CODE 27300020
         BE    ERRMSG2             BRANCH,IT IS AN INVALID INT. CODE    27400020
         SPACE 1                                                        27500020
***   CHECK FOR UNCORRECTABLE STORAGE DATA ERROR                    *** 27600020
         SPACE 1                                                        27700020
         TM    MCIOPSW3,X10        IS IT AN UNCORRECTABLE ST. DATA ERR. 27800020
         BZ    HARDMCI             BRANCH,IF IT IS NOT MULTI-BIT ERROR  27900020
         OI    REMERTYP,X40        MULTIPLE BIT ERROR                   28000020
         OI    REPRIANL,X40        REPORT MULTIPLE BIT ERROR            28100020
         OI    STERROR,X04         MARK STORAGE DATA FAILURE            28200020
HARDCHK  EQU   *                                                        28300020
         CLI   MCIOPSW3,X11        IS IT UNSUCCESSFUL RETRY             28400020
         BE    LOAD7D              YES,BRANCH TO LOAD STG ANAL MOD      28500020
         CLI   MCIOPSW3,X14        IS IT UNRETRYABLE                    28600020
         BNE   ERRMSG2             NO,BRANCH TO INVALID INT. CODE       28700020
         OI    REPRIANL,X04        REPORT UNRETRYABLE                   28800020
         OI    REPDAR1,X80         SET UP TERMINATION NECESSARY         28900020
         B     LOAD7D              BRANCH TO LOAD STG ANAL MOD          29000020
         SPACE 1                                                        29100020
***   HARD MCI EVALUATION --UNRETRYABLE OR UNSUCCESSFUL RETRY ERROR *** 29200020
         SPACE 1                                                        29300020
HARDMCI  EQU   *                                                        29400020
         CLI   MCIOPSW3,X04        IS IT AN UNRETRYABLE ERROR           29500020
         BE    UNRETRY             BRANCH,IF YES                        29600020
         CLI   MCIOPSW3,X01        IS IT AN UNSUCCESSFUL RETRY ERROR    29700020
         BNE   ERRMSG2             BRANCH,IF NO                         29800020
         SPACE 1                                                        29900020
**   ERROR ANALYSIS FOR AN UNSUCCESSFUL RETRY FAILURE                ** 30000020
         SPACE 1                                                        30100020
         BAL   WKR9,TESTSPF        BRANCH TO TEST FOR SPF CHECK         30200020
         B     LOADSPF             BRANCH TO LOAD SPF ANAL. MODULE      30300020
         TM    REPRIAN2,X20        IS IT PARTIALLY INVALID LOGOUT       30400020
         BO    CONTINU2            YES,BRANCH AROUND HSM CHECKS         30500020
CONTINU1 TM    HIMULTIP,XFC        IS IT HI-SPEED MULTIPLY ERROR        30600020
         BNZ   LOADHSM             YES,BRANCH TO LOAD ALTERNATE MULT.   30700020
         TM    HMULTIP1,XF0        IS IT HI-SPEED MULTIPLY ERROR        30800020
         BNZ   LOADHSM             YES,BRANCH TO LOAD ALTERNATE MULT.   30900020
CONTINU2 TM    WCSERROR,X38        IS IT A WCS ERROR                    31000020
         BNZ   REGMULCK            BRANCH,IF YES                        31100020
         SPACE 1                                                        31200020
**   CPU ERROR  SETUP FAILURE INFORMATION FOR PDAR                   ** 31300020
         SPACE 1                                                        31400020
CONTINU3 EQU   *                                                        31500020
         OI    REPDAR1,X80         SET UP TERMINATION NECESSARY         31600020
         BAL   WKR9,TESTBUF        BRANCH TO TEST FOR BUFFER ERROR      31700020
         B     CONTINU6            BRANCH TO CONTINUE                   31800020
         SPACE 1                                                        31900020
UNRETRY  EQU   *                                                        32000020
         OI    REPRIANL,X04        REPORT UNRETRYABLE                   32100020
         OI    REPDAR1,X80         SET UP TERMINATION NECESSARY         32200020
         TM    L490,X10            IS RETRY IC VALID                    32300020
         BO    CONTINU5            YES,BRANCH TO TEST PART INVALID LOG  32400020
         OI    REPDAR1,X10         SET IC INDETERMINATE                 32500020
CONTINU5 TM    REPRIAN2,X20        IS IT PARTIALLY INVALID LOGOUT       32600020
         BO    CONTINU7            YES,BRANCH AROUND HSM CHECKS         32700020
         TM    HIMULTIP,XFC        IS IT HI-SPEED MULTIPLY ERROR        32800020
         BNZ   LOADHSM1            YES,BRANCH TO LOAD ALTERNATE MULT.   32900020
         TM    HMULTIP1,XF0        IS IT HI-SPEED MULTIPLY ERROR        33000020
         BNZ   LOADHSM1            YES,BRANCH TO LOAD ALTERNATE MULT.   33100020
CONTINU7 TM    WCSERROR,X38        IS IT A WCS ERROR                    33200020
         BZ    BUFTST              NO,BRANCH TO TEST FOR BUFFER ERROR   33300020
         TM    L3F4,X80            IS IT IN WCS                         33400020
         BZ    BUFTST              NO,BRANCH TO TEST FOR BUFFER ERROR   33500020
         OI    REPRIAN1,X20        REPORT WCS ERROR                     33600020
         TM    MCWBIT8,X20         IS REGULAR MULTIPLY IN WCS           33700020
         BZ    BUFTST              NO,BRANCH TO TEST FOR BUFFER ERROR   33800020
         BAL   WKR9,MPLYTST        BRANCH TO TEST FOR MULTIPLY OP CODE  33900020
         B     BUFTST              NOT MULT OP CODE - BRANCH            34000020
         B     REFRWCS             IT IS MULT OP CODE - BRANCH          34100020
BUFTST   BAL   WKR9,TESTBUF        BRANCH TO TEST FOR BUFFER ERROR      34200020
         BAL   WKR9,TESTSPF        BRANCH TO TEST FOR SPF CHECK         34300020
         B     LOADSPF             BRANCH TO LOAD SPF ANAL. MODULE      34400020
CONTINU6 BAL   WKR9,TESTSTG        BRANCH TO TEST FOR STG ADDR OR MARK  34500020
LOADPDAR EQU   *                                                        34600020
         MVI   RMSNXMOD,NEXT50     PDAR AS SUCCESSOR                IO  34700020
         B     EXIT                BRANCH TO LOAD PDAR                  34800020
         SPACE 1                                                        34900020
***   S O F T   M C I   E V A L U A T I O N                         *** 35000020
         SPACE 1                                                        35100020
SOFTMCI  EQU   *                                                        35200020
         OI    REPRIANL,X80        REPORT SOFT CHECK                    35400020
         TM    MCIOPSW3,X07        IS IT ECC SUCCESSFUL (BITS-29,30,31) 35500020
         BZ    ECCSUCC             BRANCH,IF YES                        35600020
         CLI   MCIOPSW3,X09        IS IT A SUCCESSFUL H. I. R.(BIT 31)  35700020
         BE    HIRSUCC             BRANCH,IF YES                        35800020
         CLI   MCIOPSW3,X19        IS IT A SUCCESSFUL H. I. R. (UCE)    35900020
         BE    HIRSUCC             BRANCH,IF YES                        36000020
         B     ERRMSG2             BRANCH TO INVALID INTERRUPT CODE     36100020
         SPACE 1                                                        36200020
***     S U C C E S S F U L    E. C. C.                             *** 36300020
         SPACE 1                                                        36400020
ECCSUCC  EQU   *                                                        36500020
         OI    REPRIANL,X20        REPORT ECC SUCCESSFUL                36600020
         OI    STERROR,X04         MARK STORAGE DATA FAILURE            36700020
         MVI   ZERO(WKR4),X0E      REQUEST IGF044I ECC MESSAGE      IO  36800020
         LA    WKR4,UNO(WKR4)      INCREASE MESSAGE BUFFER POINTER      36900020
         OI    REMERTYP,X80        ECC SINGLE BIT ERROR                 37000020
         TM    RESMCW4,X01         CHECK FOR ECC COUNT MODE             37100020
         BO    LOAD7D              YES,LOAD STORAGE SCAN MODULE         37200020
         SR    WKR1,WKR1           CLEAR WKR1                           37300020
         L     WKR2,RETECC         GET THE ECC THRESHOLD COUNTS         37400020
         CLR   WKR1,WKR2           IS THE ECC THRESHOLD COUNT EQUAL 0   37500020
         BE    LOAD7D              YES,BRANCH TO SETUP FOR STG SCAN MOD 37600020
         L     WKR3,RELECC         GET THE ECC COUNTS OF STATUS INF.    37700020
         AH    WKR3,ONE            INCREASE THE COUNT BY ONE            37800020
         ST    WKR3,RELECC         SAVE THE COUNT                       37900020
         OI    COMINTEL,X02        SET STATUS CHANGE BIT                38000020
         CLR   WKR3,WKR2           IS THE ECC COUNT REACHES THRESHOLD   38100020
         BNE   LOAD7D              NO,BRANCH TO SETUP FOR STG SCAN MOD  38200020
         OI    RESMCW4,X01         SET UP MCW TO SWITCH ECC TO CTR MODE 38300000
         OI    COMINTEL,X02        SET STATUS CHANGE BIT                38400020
         SR    WKR3,WKR3             ZERO REG                 IE  51374 38500000
         ST    WKR3,RELECC         ZERO MSB ECC COUNT         IE  51374 38600000
         MVI   ZERO(WKR4),X0D      REQUEST IGF043 MSG               IO  38700020
         LA    WKR4,UNO(WKR4)      INCREASE MESSAGE BUFFER POINTER      38800020
         B     LOAD7D              LOAD STORAGE SCAN MODULE             38900020
         SPACE 1                                                        39000020
**    THIS SUBROUTINE CHECKS THE REGULAR MULTIPLY ERROR IN MCW       ** 39100020
         SPACE 1                                                        39200020
REGMULCK EQU   *                                                        39300020
         TM    L3F4,X80            IS IT IN WCS                         39400020
         BZ    CONTINU3            BRANCH,IF NO                         39500020
         OI    REPRIAN1,X20        REPORT WCS ERROR                     39600020
         TM    MCWBIT8,X20         IS REGULAR MULTIPLY IN WCS           39700020
         BZ    CONTINU3            BRANCH,IF NO                         39800020
         BAL   WKR9,MPLYTST        BRANCH TO TEST FOR MULTIPLY OP CODE  39900020
         B     CONTINU3            BRANCH NOT MULT OP CODE              40000020
         OI    REPDAR1,X20         SET RETRY POSSIBLE                   40100020
REFRWCS  OI    REPRIAN1,X10        REPORT WCS REFRESH OF MULTIPLY ALG.  40200020
         B     LOADALT             YES,BRANCH TO ALTERNATE MULT. MOD.   40300020
*                                                                     * 40400020
*  THIS ROUTINE CHECKS FOR A MULTIPLY OP CODE                         * 40500020
*                                                                     * 40600020
MPLYTST  L     WKR1,L8C            GET ADDRESS OF FAILING INSTRUCTION   40700020
         LA    WKR2,MULTINS        GET ADDRESS OF MULT OP CODES         40800020
TESTOP   CLC   ZERO(WKR1),ZERO(WKR2)    CHECK FOR MULTIPLY OP CODE      40900020
         BE    FOUR(WKR9)          YES,RETURN                           41000020
         LA    WKR2,UNO(WKR2)      UPDATE ADDRESS TO NEXT BYTE          41100020
         TM    ZERO(WKR2),XFF      IS THIS END OF TABLE                 41200020
         BCR   OFF,WKR9            NOT MULT OP CODE - RETURN            41300020
         B     TESTOP              BRANCH TO TEST NEXT OP CODE          41400020
         SPACE 1                                                        41500020
***      S U C C E S S F U L   I N S T R U C T I O N   R E T R Y    *** 41600020
         SPACE 1                                                        41700020
HIRSUCC  EQU   *                                                        41800020
         OI    REPRIANL,X10        REPORT SUCCESSFUL RETRY              41900020
         MVI   ZERO(WKR4),X12      REQUEST IGF048 MSG               IO  42000020
         LA    WKR4,UNO(WKR4)      INCREASE MESSAGE BUFFER POINTER      42100020
         TM    RESMCW4,X04         CHECK FOR HIR COUNT MODE             42200020
         BO    BUFFSTOR            YES,BRANCH TO CHK FOR BUF OR ST ERR  42300020
         SR    WKR1,WKR1           CLEAR REG.1                          42400020
         L     WKR2,RETHIR         GET THE H.I.R. THRESHOLD COUNTS      42500020
         CLR   WKR1,WKR2           IS THE HIR THRESHOLD COUNT EQUAL 0   42600020
         BE    BUFFSTOR            YES,BRANCH TO CHK FOR BUF OR ST ERR  42700020
         L     WKR3,RELHIR         GET H.I.R. COUNTS                    42800020
         AH    WKR3,ONE            INCREASE THE COUNT BY ONE            42900020
         ST    WKR3,RELHIR         SAVE THE COUNTS                      43000020
         OI    COMINTEL,X02        SET STATUS CHANGE BIT                43100020
         CLR   WKR3,WKR2           IS HIR COUNTS REACH THRESHOLD COUNT  43200020
         BNE   BUFFSTOR            NO,BRANCH TO CHK FOR BUF OR ST ERR   43300020
         OI    RESMCW4,X04         SETUP MCW TO SWITCH HIR TO CTR MODE  43400000
         OI    COMINTEL,X02        SET STATUS CHANGE BIT                43500020
         SR    WKR3,WKR3             ZERO REG                 IE  51374 43550000
         ST    WKR3,RELHIR         ZERO MSB HIR COUNT         IE  51374 43600000
         MVI   ZERO(WKR4),X0C      REQUEST IGF043 MSG               IO  43800020
         LA    WKR4,UNO(WKR4)      INCREASE MESSAGE BUFFER POINTER      43900020
         SPACE 1                                                        44000020
BUFFSTOR EQU   *                                                        44100020
         TM    MCIOPSW3,X10        IS IT UNCORRECTABLE ST. DATA ERROR   44200020
         BZ    BUFCHK              NO,BRANCH TO CHECK BUFFER            44300020
         OI    REMERTYP,X40        MULTIPLE BIT ERROR                   44400020
         OI    REPRIANL,X40        REPORT MULTIPLE BIT ERROR            44500020
         OI    STERROR,X04         MARK STORAGE DATA FAILURE            44600020
         TM    REPRIAN2,X40        IS IT INVALID LOGOUT                 44700020
         BO    LOADERR             YES,BRANCH TO LOAD ERROR RECORDER    44800020
         BAL   WKR8,FAILADR        GET FAILING ADDRESS                  44900020
         ST    WKR2,REMADR         STORE IN REMEST TABLE                45000020
         B     LOADERR             BRANCH TO LOAD ERROR RECORDER        45100020
BUFCHK   EQU   *                                                        45200020
         TM    REPRIAN2,X40        IS IT INVALID LOGOUT                 45300020
         BO    LOADERR             YES,BRANCH TO LOAD ERROR RECORDER    45400020
         BAL   WKR9,TESTBUF        BRANCH TO TEST FOR BUFFER ERROR      45500020
         BAL   WKR9,TESTSPF        BRANCH TO TEST FOR SPF CHECK         45600020
         B     LOADERR             BRANCH TO LOAD ERROR RECORDER        45700020
         BAL   WKR9,TESTSTG        BRANCH TO TEST FOR STG ADDR OR MARK  45800020
LOADERR  EQU   *                                                        45900020
         MVI   RMSNXMOD,NEXT51     ERROR RECORDER AS SUCCESSOR      IO  46000020
         B     EXIT                BRANCH TO LOAD ERROR RECORDER MODULE 46100020
         SPACE 1                                                        46200020
LOAD7D   EQU   *                                                        46300020
         TM    REPRIAN2,X40        IS IT INVALID LOGOUT                 46400020
         BO    LOADERR             YES,BRANCH TO LOAD ERROR RECORDER    46500020
         BAL   WKR8,FAILADR             GET FAILING ADDRESS             46600020
         ST    WKR2,REMADR                FOR STORAGE SCAN              46700020
         MVI   RMSNXMOD,NEXT7D     SCAN AS SUCCESSOR                IO  46800020
         B     EXIT                BRANCH TO LOAD STG SCAN MODULE       46900020
         SPACE 1                                                        47000020
LOADSPF  EQU   *                                                        47100020
         MVI   RMSNXMOD,NEXT5D     SPF AS SUCCESSOR                 IO  47200020
         B     EXIT                BRANCH TO LOAD SPF ANALYSIS MODULE   47300020
         SPACE 1                                                        47400020
LOADHSM  EQU   *                                                        47500020
         OI    REPDAR1,X20         SET RETRY POSSIBLE                   47600020
LOADHSM1 OI    REPRIAN1,X40        REPORT HI-SPEED MULTIPLY ERROR       47700020
LOADALT  EQU   *                                                        47760020
         MVI   RMSNXMOD,NEXT6F     HMC AS SUCCESSOR                 IO  47820020
         B     EXIT                BRANCH TO LOAD ALTERNATE MULT. MOD.  47900020
         SPACE 1                                                        48000020
*  SETUP UNIQUE WAIT STATE CODE                                       * 48100020
         SPACE 1                                                        48200020
ERRMSG1  EQU   *                                                        48300020
         OI    REPRIAN1,X08        REPORT MCI FROM CCH                  48400020
         B     SETPSW              BRANCH TO SET UP WAIT STATE PSW      48500020
ERRMSG2  EQU   *                                                        48600020
         OI    REPRIAN1,X04        REPORT INVALID INTERRUPT CODE        48700020
SETPSW   EQU   *                                                        48800020
         MVC   MCHRPSW(EIGHT),WAITPSW  SET UP WAIT STATE PSW        IO  48900020
         OI    COMINTEL,X40        SET SYSTEM PUT DOWN BIT              49000020
         B     LOADERR             BRANCH TO LOAD ERROR RECORDER        49100020
*********************************************************************** 49200020
*                                                                     * 49300020
*****               TEST FOR STG ADDR OR MARK CHECK               ***** 49400020
*                                                                     * 49500020
*   THIS ROUTINE TESTS FOR STORAGE ADDRESS AND/OR MARK ERRORS. IF ANY * 49600020
*   ARE FOUND, THEY ARE RECORDED.                                     * 49700020
*                                                                     * 49800020
*   THIS ROUTINE IS ENTERED BY A BAL ON REG 9 TO THE ENTRY POINT      * 49900020
*   TESTSTG. RETURN IS MADE VIA REG 9.                                * 50000020
*                                                                     * 50100020
*********************************************************************** 50200020
*                                                                     * 50300020
TESTSTG  EQU   *                                                        50400020
         TM    L381,XC0            IS IT A STORAGE ADDRESS FAILURE      50500020
         BZ    STMKERR             NO,BRANCH TO CHECK FOR MARK FAILURE  50600020
         OI    STERROR,X08         MARK STORAGE ADDRESS FAILURE         50700020
         OI    REPRIAN1,X02        RECORD STORAGE ADDRESS FAILURE       50800020
STMKERR  TM    L381,X0C            IS IT A STORAGE MARK FAILURE         50900020
         BCR   OFF,WKR9            NO,RETURN                            51000020
         OI    STERROR,X02         MARK STORAGE MARK FAILURE            51100020
         OI    REPRIAN1,X01        RECORD STORAGE MARK FAILURE          51200020
         BAL   WKR8,FAILADR        GET FAILING ADDRESS                  51300020
         ST    WKR2,REMADR         STORE IN REMEST TABLE                51400020
         BR    WKR9                RETURN                               51500020
*********************************************************************** 51600020
*                                                                     * 51700020
*****                  TEST FOR BUFFER ERROR                      ***** 51800020
*                                                                     * 51900020
*   THIS ROUTINE TESTS FOR BUFFER ERRORS. IF ANY ARE FOUND THEY ARE   * 52000020
*   REPORTED, AND THE SET UP FOR LOADING THE BUFFER CONTROL MODULE    * 52100020
*   IS PERFORMED.                                                     * 52200020
*                                                                     * 52300020
*   THE ROUTINE IS ENTERED BY A BAL ON REG 9 TO THE ENTRY POINT       * 52400020
*   TESTBUF. IF NO BUFFER ERROR RETURN IS MADE VIA REG 9.             * 52500020
*                                                                     * 52600020
*********************************************************************** 52700020
*                                                                     * 52800020
TESTBUF  EQU   *                                                        52900020
         TM    L3A9,X10            IS IT SCU ADDR CHECK                 53000020
         BCR   UNO,WKR9            YES,RETURN                           53100020
         TM    L3AA,X3C            IS IT BUF DATA BUS OUT ERROR         53200020
         BNZ   LOADBUFF            YES,BRANCH TO LOAD BUFF CONTROL MOD  53300020
         TM    L3AB,XF0            IS IT BUF DATA BUS OUT ERROR         53400020
         BNZ   LOADBUFF            YES,BRANCH TO LOAD BUFF CONTROL MOD  53500020
         TM    L3A9,X0C            IS IT BUF BLOCK VALID,OR BUF IN-KEY  53600020
         BNZ   LOADBUFF            YES,BRANCH TO LOAD BUFF CONTROL MOD  53700020
         TM    L3AA,X80            IS IT BUF MARK CHECK                 53800020
         BNZ   LOADBUFF            YES,BRANCH TO LOAD BUFF CONTROL MOD  53900020
         TM    L3AD,X1C            IS IT BUF SECT COMP,MPLE COMP,OR KEY 54000020
         BNZ   LOADBUFF            YES,BRANCH TO LOAD BUFF CONTROL MOD  54100020
         TM    L3AE,X80            IS IT BUF ADDRESS CHECK              54200020
         BNZ   LOADBUFF            YES,BRANCH TO LOAD BUFF CONTROL MOD  54300020
         BR    WKR9                RETURN                               54400020
LOADBUFF EQU   *                                                        54500020
         MVC   BUFREP4(FOUR),TEMPSTO    MOVE SECTOR DELETE BITS         54600020
         OI    REPRIANL,X08        REPORT HI-SPEED BUFFER ERROR         54700020
         MVI   RMSNXMOD,NEXT5F     BUFFER CONTROL AS SUCCESSOR      IO  54800020
         B     EXIT                BRANCH TO LOAD BUFFER CONTROL MODULE 54900020
*********************************************************************** 55000020
*                                                                     * 55100020
*****                   TEST FOR SPF CHECK                        ***** 55200020
*                                                                     * 55300020
*   THIS ROUTINE TESTS FOR SPF ERRORS. IF ANY ARE FOUND THEY ARE      * 55400020
*   RECORDED.                                                         * 55500020
*                                                                     * 55600020
*   THE ROUTINE IS ENTERED BY A BAL ON REG 9 TO THE ENTRY POINT       * 55700020
*   TESTSPF. RETURN IS MADE VIA REG 9.                                * 55800020
*                                                                     * 55900020
*********************************************************************** 56000020
*                                                                     * 56100020
TESTSPF  EQU   *                                                        56200020
         TM    SPFERROR,X30        IS IT AN SPF KEY FAILURE             56300020
         BNZ   INOUTKEY            YES,BRANCH TO CHECK KEY              56400020
         TM    SPFADRER,X04        IS SPF ADR CHECK BIT ON              56500020
         BZ    FOUR(WKR9)          NO,RETURN                            56600020
         OI    STERROR,X40         SET SPF FAILURE                      56700020
         OI    REMSPF,X20          SET SPF ADR CHK                      56800020
         OI    REPRIAN1,X80        REPORT SPF ADR CHK                   56900020
         BR    WKR9                RETURN                               57000020
INOUTKEY EQU   *                                                        57100020
         OI    STERROR,X40         SET SPF FAILURE                      57200020
         BAL   WKR8,FAILADR        GET FAILING ADDRESS                  57300020
         ST    WKR2,REMADR         STORE IN REMEST TABLE                57400020
         TM    SPFERROR,X20        IS IT AN IN-KEY ERROR                57500020
         BZ    OUTKEY              NO,BRANCH TO MARK OUT-KEY FAILURE    57600020
         OI    REMSPF,X40          IN-KEY FAILURE                       57700020
         OI    REPRIANL,X02        REPORT SPF IN-KEY ERROR              57800020
         TM    SPFERROR,X10        IS IT ALSO OUT-KEY ERROR             57900020
         BZ    SPFADRCK            NO,BRANCH TO CHECK IF ALSO ADR CHK   58000020
OUTKEY   OI    REMSPF,X80          OUT-KEY FAILURE                      58100020
         OI    REPRIANL,X01        REPORT SPF OUT-KEY ERROR             58200020
SPFADRCK TM    SPFADRER,X04        IS SPF ADR CHECK BIT ALSO ON         58300020
         BCR   OFF,WKR9            NO,RETURN                            58400020
         OI    REMSPF,X20          SET SPF ADR CHK                      58500020
         OI    REPRIAN1,X80        REPORT SPF ADR CHK                   58600020
         BR    WKR9                RETURN                               58700020
         SPACE 1                                                        58800020
EXIT     EQU   *                                                        58900020
         ST    WKR4,MCHIPTR        UPDATE MSG BUFFER                IO  59100020
         BR    ASRNUCR             RETURN TO NUCLEUS                    59300020
         SPACE 1                                                        59400020
*  GET THE FAILING ADDRESS IN WKR2                                      59500020
         SPACE 1                                                        59600020
FAILADR  EQU   *                                                        59700020
         TM    STGTYPE,X10              IS IT A 2365                    59800020
         BZ    ADDR85                   NO                              59900020
*********************************************************************** 60000020
*                                                                     * 60100020
*****               2365 CPU ADDRESS GENERATION                   ***** 60200020
*                                                                     * 60300020
**   1.  CPU ADDRESS IS GENERATED FROM DATA IN MICROFICHE FRAME A1   ** 60400020
**       OF LOGOUT., SPECIFICALLY LINE 7 AND 9 .                     ** 60500020
*                                                                     * 60600020
**   2.  CPU ADDRESS GENERATED POINTS TO THE DOUBLEWORD LOCATION     ** 60700020
**       ASSOCIATED WITH THE OCCURED ERROR.                          ** 60800020
*                                                                     * 60900020
*        THE WORK REGISTERS FOR THIS ROUTINE ARE REG 2 AND 3          * 61000020
*                                                                     * 61100020
*                                                                     * 61200020
*********************************************************************** 61300020
*                                                                     * 61400020
ADDR65   EQU   *                                                        61500020
         OI    REM2365,X80         SET 2365 INDICATION INTO REMEST      61600020
         MVC   REMCONF1(TWO),STGCONF    MOVE 2365 CONFIG. IN REMEST     61700020
         TM    L381,BIT01              * ANY ADDRESS CHECK              61800020
         BZ    L6FTADR                 * USE LEFT ADDRESS IF NO         61900020
         TM    L381,BIT1               * IS IT RIGHT ADDR CHECK         62000020
         BO    L6FTADR                 * IF YES,THEN USE LEFT ADDRESS   62100020
*                                                                     * 62200020
* USE THE RIGHT ADDRESS BITS IN LINE 8 OF MICROFICHE FRAME A1 TO GEN- * 62300020
* ERATE CPU ADDRESS OF ERROR LOCATION .                               * 62400020
*                                                                     * 62500020
R6GHTADR EQU   *                                                        62600020
         L     WKR2,ADDR378            * RIGHT ADDR LINE 7 IN REG       62700020
         B     S6IFT                   * GO PACK THE BITS               62800020
* USE THE LEFT ADDRESS BITS IN LINE 6 TO GENERATE CPU ADDRESS         * 62900020
*                                                                     * 63000020
L6FTADR  EQU   *                                                        63100020
         L     WKR2,ADDR374            * LEFT ADDR LINE 6 IN REG        63200020
*                                                                     * 63300020
S6IFT    XR    WKR3,WKR3               * CLEAR REGISTER                 63400020
         SRL   WKR2,THREE              * GET RID OF USELESS BITS        63500020
         SRDL  WKR2,FIVE               * STORAGE ADDR BIT 10-14 SAVED   63600020
         SRL   WKR2,TWO                * GET RID OF USELESS BITS        63700020
         SRDL  WKR2,TWO                * STG ADDR BIT 8,9 SAVED         63800020
         SRL   WKR2,TWO                * GET RID OF PB AND USELESS BIT  63900020
         SRDL  WKR2,TWO                * STG ADDR BIT 6,7 SAVED         64000020
         SRL   WKR2,TWO                * GET RID OF 2 ZERO BITS         64100020
         SRDL  WKR2,FIVE               * STG ADDR BIT 1-5 SAVED         64200020
         SRL   WKR2,FOUR               * GET RID OF PA AND OTHERS       64300020
         SRDL  WKR2,TWO                * SAVE BIFRAME AND BSM BITS      64400020
         XR    WKR2,WKR2               * CLEAR REGISTER                 64500020
         SLDL  WKR2,TWENTY             * SHIFT TO BIT 12 OF REG         64600020
*                                                                     * 64700020
* TEST FOR REVERSE BIFRAME AND REVERSE EV/ODD BSM FROM CONFIGURATION. * 64800020
*                                                                     * 64900020
         TM    L362,BIT1               * ANY REVERSE BIFRAME            65000020
         BZ    T6STBSM                 * IF NO GO TEST REVERSE BSM      65100020
         X     WKR2,REV12              * REVERSE BIFRAME BIT            65200020
T6STBSM  EQU   *                                                        65300020
         TM    L361,BIT2               * ANY REVERSE EVEN/ODD           65400020
         BZ    I6TERLV                 * TEST INTERLEAVE IF NO          65500020
         X     WKR2,REV13              * REVERSE BSM BIT                65600020
*                                                                     * 65700020
* TEST IF 4 WAY OR 2 WAY INTERLEAVE OR SERIAL ADDRESSING .            * 65800020
*                                                                     * 65900020
I6TERLV  EQU   *                                                        66000020
         ST    WKR2,TEMPSTO            * STORE UNADJUSTED ADDRESS       66100020
         ST    WKR2,ADDRESS            * STORE IN PERMANENT LOCATION    66200020
         TM    L361,BIT3               * IS IT SERIAL ADDRESSING        66300020
         BO    R6TURN                  * BRANCH IF SERIAL ADDRESSING    66400020
         TM    L361,BIT5               * IS IT 4 WAY INTERLEAVE         66500020
         BO    F6WAY                   * BR IF YES TO ADJUST BIT        66600020
*                                                                     * 66700020
*****          ADDRESSING IS TWO WAY INTERLEAVE                   ***** 66800020
*                                                                     * 66900020
T6WAY    EQU   *                                                        67000020
         NC    ADDRESS(FOUR),SWAP1     * ZERO BIT 13 AND 27             67100020
         TM    TEMPSTO1,BIT5           * IS CPU BIT 27 A 1 OR 0         67200020
         BZ    CHK13                   * TEST FOR BIT 13 IF 0           67300020
         OI    ADDRESS3,BIT3           * CPU ADDR BIT 27 SET TO A 1     67400020
CHK13    TM    TEMPSTO3,BIT3           * IS CPU BIT 13 A 0 OR 1         67500020
         BZ    R6TURN                  * ADDRESS ADJUSTED IF 0          67600020
         OI    ADDRESS1,BIT5           * CPU ADDR BIT 13 SET TO A 1     67700020
         B     R6TURN                  * EXIT                           67800020
*                                                                     * 67900020
*****          ADDRESSING IS FOUR WAY INTERLEAVE                  ***** 68000020
*                                                                     * 68100020
F6WAY    EQU   *                                                        68200020
         NC    ADDRESS(FOUR),SWAP2     * ZERO BIT 12,13,26,27           68300020
         TM    TEMPSTO1,BIT4           * IS CPU BIT 27 A 1              68400020
         BZ    CHK26                   * TEST BIT 26 IF NO              68500020
         OI    ADDRESS3,BIT3           * CPU ADDR BIT 27 IS SET TO 1    68600020
CHK26    TM    TEMPSTO1,BIT5           * IS CPU BIT 26 A 1              68700020
         BZ    CHK13A                  * TEST BIT 13 IF NO              68800020
         OI    ADDRESS3,BIT2           * CPU ADDR BIT 26 SET TO 1       68900020
CHK13A   TM    TEMPSTO3,BIT3           * IS CPU ADDR BIT 13 A 1         69000020
         BZ    CHK12                   * TEST FOR BIT 12 IF NO          69100020
         OI    ADDRESS1,BIT5           * CPU ADDR BIT 13 IS SET TO 1    69200020
CHK12    TM    TEMPSTO3,BIT2           * IS CPU ADDR BIT 12 A 1         69300020
         BZ    R6TURN                  * BRANCH IF NO                   69400020
         OI    ADDRESS1,BIT4           * CPU ADDR BIT 12 SET TO 1       69500020
R6TURN   EQU   *                                                        69600020
         L     WKR2,ADDRESS            GET FAILING ADDRESS              69700020
         BR    WKR8                    * RETURN                         69800020
*                                                                     * 69900020
*********************************************************************** 70000020
*                                                                     * 70100020
*****               2385 CPU ADDRESS GENERATION                   ***** 70200020
*                                                                     * 70300020
**   1.  CPU ADDRESS IS GENERATED FROM DATA IN MICROFICHE FRAME A1   ** 70400020
**       OF LOGOUT . SPECIFICALLY LINE 7 AND 9 .                     ** 70500020
*                                                                     * 70600020
**   2.  CPU ADDRESS GENERATED POINTS TO THE DOUBLEWORD LOCATION     ** 70700020
**       ASSOCIATED WITH THE OCCURED ERROR                           ** 70800020
*                                                                     * 70900020
**   3.  CPU ADDRESS GENERATED IS NOT RELIABLE FOR ADDRESS CHECK  .  ** 71000020
*                                                                     * 71100020
*********************************************************************** 71200020
*                                                                     * 71300020
ADDR85   EQU   *                                                        71400020
         OI    REM2385,X40         OTHERWISE IT IS 2385                 71500020
         MVC   REMCONF2(THREE),STGCONF  MOVE 2385 CONFIG. IN REMEST     71600020
         L     WKR2,ADDR374            * ADDR LINE 6 IN REG             71700020
         XR    WKR3,WKR3               * CLEAR REGISTER                 71800020
         SRL   WKR2,THREE              * CLEAR UNUSED BITS              71900020
         SRDL  WKR2,FIVE               * STG ADDR BIT 10-14 SAVED       72000020
         SRL   WKR2,TWO                * CLEAR                          72100020
         SRDL  WKR2,TWO                * STG ADDR BIT 8,9 SAVED         72200020
         SRL   WKR2,TWO                * CLEAR                          72300020
         SRDL  WKR2,TWO                * SAVED                          72400020
         SRL   WKR2,TWO                * CLEAR                          72500020
         SRDL  WKR2,FIVE               * STG ADDR BIT 1-5 SAVED         72600020
         SRL   WKR2,FOUR               * CLEAR UNWANTED BITS            72700020
         SRDL  WKR2,FOUR               * SAVED                          72800020
         SRL   WKR2,UNO                * REGISTER CLEARED               72900020
         SLDL  WKR2,TWENTWO            * STG ID AND ADDR BIT IN REG     73000020
         ST    WKR2,TEMPSTO            * TEMPORARY STORE                73100020
         N     WKR2,SWAP2              * CLEAR BIT 10-13,26,27          73200020
         ST    WKR2,ADDRESS            * STORE ADDRESS                  73300020
*                                                                     * 73400020
* CPU ADDRESS BITS 14 TO 25 ARE NOW STORED IN LOCATION 'ADDRESS' .    * 73500020
* TO GENERATE CPU ADDRESS BIT 12, 13, 26, 27 FROM LSU AND STG BITS    * 73600020
*                                                                     * 73700020
         TM    TEMPSTO1,BIT4           * IS CPU ADDR BIT 26 A 1         73800020
         BZ    CHK27                   * TEST BIT 27 IF NO              73900020
         OI    ADDRESS3,BIT2           * CPU ADDR BIT 26 SET TO 1       74000020
CHK27    TM    TEMPSTO1,BIT5           * IS CPU ADDR BIT 27 A 1         74100020
         BZ    CHK12A                  * TEST FOR BIT 12 IF NO          74200020
         OI    ADDRESS3,BIT3           * CPU ADDR BIT 27 SET TO 1       74300020
CHK12A   TM    TEMPSTO3,BIT2           * IS CPU ADDR BIT 12 A 1         74400020
         BZ    CHK13B                  * TEST FOR BIT 13 IF NO          74500020
         OI    ADDRESS1,BIT4           * CPU ADDR BIT 12 SET TO 1       74600020
CHK13B   TM    TEMPSTO3,BIT3           * IS CPU ADDR BIT 13 A 1         74700020
         BZ    T8STCSU                 * TEST BIT 10,11 IF NO           74800020
         OI    ADDRESS1,BIT5           * CPU ADDR BIT 13 SET TO 1       74900020
*                                                                     * 75000020
* TO GENERATE CPU ADDRESS BIT 10 AND 11 BASED ON THE CSU BITS .       * 75100020
*                                                                     * 75200020
T8STCSU  EQU   *                                                        75300020
         MVC   CONFIG(UNO),TEMPSTO1    * MVC STG BIT 8 TO 15            75400020
         MVC   CONFIG1(THREE),L361     * 3 BYTES OF 85 CONFIG MOVE IN   75500020
         NC    CONFIG(FOUR),SAVECSU    * ZERO ALL EXCEPT THE CSU BITS   75600020
         CLC   CONFIG(UNO),CONFIG1     * IS CSU FOR 1ST MEGABYTE        75700020
         BE    R6TURN                  * BIT 10,11 EQ 00 IF YES         75800020
         IC    WKR2,CONFIG             * TO ADJUST FOR NEXT COMPARE     75900020
         SLL   WKR2,TWO                * CSU BITS SHIFTED               76000020
         STC   WKR2,CONFIG             * CSU BITS READY FOR 2ND MEG     76100020
         CLC   CONFIG(UNO),CONFIG2     * IS CSW FOR 2ND MEGABYTE        76200020
         BE    S8COND                  * BIT 10,11 EQ 01 IF YES         76300020
         CLC   CONFIG(UNO),CONFIG3     * IS CSW FOR 3RD MEGABYTE        76400020
         BE    T8IRD                   * BIT 10,11 EQ 10 IF YES         76500020
* CSU IS NOT FOR 1ST OR 2ND OR 3RD MEGABYTE . MUST BE FOR 4TH THEN .  * 76600020
*                                                                     * 76700020
F8URTH   EQU   *                                                        76800020
         OI    ADDRESS1,BIT23          * SET BIT 10,11 TO '11'          76900020
         B     R6TURN                  * BRANCH TO EXIT                 77000020
*                                                                     * 77100020
* CSU IS FOR 3RD MEGABYTE . SET CPU ADDR BIT 10,11 TO '10' .          * 77200020
*                                                                     * 77300020
T8IRD    EQU   *                                                        77400020
         OI    ADDRESS1,BIT2           * SET BIT 10,11 TO '10'          77500020
         B     R6TURN                  * BRANCH TO EXIT                 77600020
*                                                                     * 77700020
* CSU IS FOR 2ND MEGABYTE. SET CPU ADDR BIT 10,11 TO '01' .           * 77800020
*                                                                     * 77900020
S8COND   EQU   *                                                        78000020
         OI    ADDRESS1,BIT3           * SET BIT 10,11 TO '01'          78100020
         B     R6TURN                  * BRANCH TO EXIT                 78200020
*                                                                     * 78300020
*                                                                     * 78400020
*                                                                     * 78500020
*                                                                     * 78600020
*********************************************************************** 78700020
*****                        EQUATES                              ***** 78800020
*********************************************************************** 78900020
*                                                                     * 79000020
BIT01    EQU   X'C0'               IMMEDIATE DATA                       79100020
BIT1     EQU   X'40'               IMMEDIATE DATA                       79200020
BIT2     EQU   X'20'               IMMEDIATE DATA                       79300020
BIT23    EQU   X'30'               IMMEDIATE DATA                       79400020
BIT3     EQU   X'10'               IMMEDIATE DATA                       79500020
BIT4     EQU   X'08'               IMMEDIATE DATA                       79600020
BIT5     EQU   X'04'               IMMEDIATE DATA                       79700020
*                                                                     * 79800020
*********************************************************************** 79900020
*****                    CONSTANTS AND WORKAREAS                  ***** 80000020
*********************************************************************** 80100020
*                                                                     * 80200020
         DS    0D                                                       80300020
WAITPSW  DC    X'0002000000000000'      WAIT STATE PSW                  80400020
TEMPSTO  DC    1F'0'                   * ADDRESS TEMPORARY STORE        80500020
CONFIG   DC    1F'0'                   * 2385 CONFIGURATION STO TEMP    80600020
ADDRESS  DC    1F'0'                   * FINAL ADDRESS STORE HERE       80700020
REV12    DC    X'00080000'             * TO REVERSE BIFRAME BIT         80800020
REV13    DC    X'00040000'             * TO REVERSE BSM BIT             80900020
SWAP2    DC    X'0003FFC0'             * TO ZERO BIT 12,13,26,27        81000020
SWAP1    DC    X'000BFFE0'             * TO ZERO BIT 13,27              81100020
TESTRT   DC    X'004408A0'             * TO TEST FOR RIGHT UNIT         81200020
SAVECSU  DC    X'3030C0C0'             * TO SAVE ONLY THE CSU BITS      81300020
MULTDIS  DC    X'00800000'        * TO ZERO ALL BUT MULT DIS BIT OF MCW 81400020
MODEBUF  DC    X'4F000000'        * TO KEEP BUF DIS AND MODE BITS MCW   81500020
MULTINS  DC    X'1C5C4CFC2C6C3C7C26276700'   TABLE OF MULTIPLY OP CODES 81600020
ONE      DC    H'1'                    * FOR ADDING TO HIR OR ECC COUNT 81700020
         SPACE 5                                                        81800020
***  MAINTENANCE  AREA  ***                                             81850021
MAINTID  DC    CL8'IGFMCH13'           CORE IDENTIFIER                  81860021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              81870021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 81880021
         EJECT                                                          81890021
RMSMSB   DSECT                                                          81900020
         RMSMSB    MOD=85                                               82000020
         EJECT                                                          82100020
MCHCOM   DSECT                                                          82170020
         MCHMAC                                                         82250020
         EJECT                                                          82260020
ASRCOM   DSECT                                                          82270020
         ASRMAC85                                                       82300020
BUFREP4  EQU   REBUFREP+4          LOCATION FOR SECTOR DELETE BITS      82400020
COMINTEL EQU   MCHINTEL                                                 82450020
RMSNXMOD EQU   MCHNXMOD                                                 82500020
MCIOPSW  EQU   MCHPSA+48  ADDR MCI OLD PSW IN COMMON AREA          IO   82550020
MCIOPSW1 EQU   MCIOPSW+1           ADDR 2ND BYTE MCI OLD PSW            82600020
MCIOPSW2 EQU   MCIOPSW+2           ADDR 3RD BYTE OF MCI OLD PSW         82700020
MCIOPSW3 EQU   MCIOPSW+3          ADDR 3RD BYTE OF MCIOLD PSW      IO   82800020
MCIOPSW4 EQU   MCIOPSW+4           ADDR 5TH BYTE MCI OLD PSW            82900020
CCHMCI   EQU   MCHPSA+115 ADDR MCI NEW PSW IN COMMON AREA          IO   83000020
L8C      EQU   RECPULOG+12         LOCATION OF ADDR OF RETRY INST       83100020
LB8      EQU   RECPULOG+56         START ADDR OF SECTOR ADDR REGS       83200020
STGCONF  EQU   RECPULOG+761        ADDR STG CONFIG IN COMMON AREA       83300020
SPFADRER EQU   RECPULOG+792        ADDR SPF ADDR CHECK BIT-COMMON AREA  83400020
SPFERROR EQU   RECPULOG+793        ADDR SPF KEY ERROR BITS-COMMON AREA  83500020
STGTYPE  EQU   RECPULOG+829        ADDR STG TYPE INDICATION-COMMON AREA 83600020
L3F4     EQU   RECPULOG+908        LOCATION OF CSAR BIT INDICATING WCS  83700020
WCSERROR EQU   RECPULOG+915        ADDR BYTE CONTAINING WCS ERROR BITS  83800020
MCWBIT8  EQU   RECPULOG+1041       ADDR REG MULT BIT IN MCW-COMMON AREA 83900020
HIMULTIP EQU   RECPULOG+1192       ADDR BYTE CONTAINING HSM ERROR BITS  84000020
HMULTIP1 EQU   RECPULOG+1193                                            84100020
STERROR  EQU   REMEST+9            PTR TO STG ERROR BIT IN REMEST       84200020
REMADR   EQU   REMEST+12           PTR TO STG ERROR ADDRESS IN REMEST   84300020
REM2365  EQU   REMEST+16           PTR TO 2365 STG BIT                  84400020
REM2385  EQU   REMEST+16           PTR TO 2385 STG BIT                  84500020
REMERTYP EQU   REMEST+17           *  DESCRIPTION OF THE BYTE  **       84600020
REMCONF1 EQU   REMEST+20           CONFIGURATION OF 2365                84700020
REMCONF2 EQU   REMEST+24           CONFIGURATION OF 2385                84800020
REMSPF   EQU   REMEST+28                                                84900020
L361     EQU   RECPULOG+761            * PT TO 4 WAY INTERLEAVE BYTE    85000020
L362     EQU   RECPULOG+762            * PT TO REVERSE BIFRAME BYTE     85100020
ADDR370  EQU   RECPULOG+776            * LEFT ADDRESS LINE 6 FOR 2365   85200020
ADDR374  EQU   RECPULOG+780            * ADDRESS FOR 2385               85300020
ADDR378  EQU   RECPULOG+784            * RIGHT ADDRESS LINE 7 FOR 2365  85400020
ADDR380  EQU   RECPULOG+792            * STG CHECK WORD IN LOGOUT       85500020
L381     EQU   RECPULOG+793            * PT TO ADDR CHECK INDICATOR     85600020
L3A9     EQU   RECPULOG+833        PTR TO BUF CHECK INDICATORS          85700020
L3AA     EQU   RECPULOG+834        PTR TO BUF CHECK INDICATORS          85800020
L3AB     EQU   RECPULOG+835        PTR TO BUF CHECK INDICATORS          85900020
L3AD     EQU   RECPULOG+837        PTR TO BUF CHECK INDICATORS          86000020
L3AE     EQU   RECPULOG+838        PTR TO BUF CHECK INDICATORS          86100020
L478     EQU   RECPULOG+1040                                            86200020
L480     EQU   RECPULOG+1048                                            86300020
L490     EQU   RECPULOG+1064       LOCATION OF RETRY IC VALID           86400020
L497     EQU RECPULOG+1071         VALID LOGOUT BYTE                    86500020
REPRIAN1 EQU   REPRIANL+1          PTR TO 2ND BYTE OF REPORT AREA       86700020
REPRIAN2 EQU   REPRIANL+2          PTR TO 3RD BYTE OF REPORT AREA       86800020
CONFIG1  EQU   CONFIG+1            2385 CONFIG BYTE                     86900020
CONFIG2  EQU   CONFIG+2            2385 CONFIG BYTE                     87000020
CONFIG3  EQU   CONFIG+3            2385 CONFIG BYTE                     87100020
ADDRESS1 EQU   ADDRESS+1           FAILING STG ADDRESS BYTE             87200020
ADDRESS3 EQU   ADDRESS+3           FAILING STG ADDRESS BYTE             87300020
TEMPSTO1 EQU   TEMPSTO+1           TEMPORARY STG ADDRESS BYTE           87400020
TEMPSTO3 EQU   TEMPSTO+3           TEMPORARY STG ADDRESS BYTE           87500020
RESMCW4  EQU   RESMCW+4            PTR TO 5TH BYTE MCW                  87600020
HIRCTN   EQU   RECPULOG+4                                               87700020
         END                                                            87800020
