         LCLA  &LEV,&REL                                                00150021
&LEV     SETA  21                                                       00200021
&REL     SETA  21                                                       00250021
&REL&LEV TITLE 'IGFMCH14 LEVEL &LEV MCH REFRESH/REPAIR VERIFICATION'    00260021
*********************************************************************** 00300020
*                                                                     * 00400020
*                                                                     * 00500020
*TITLE   IGFMCH14    REFRESH / REPAIR VERIFICATION                      00600020
*                                                                     * 00700020
*STATUS  CHANGE LEVEL 000                                             * 00800020
*                                                                     * 00900020
*FUNCTION  THIS MODULE PROVIDES THE INSTRUCTION RETRY CAPABILITIES    * 01000020
*   FOR RMS/85.                                                       * 01100020
*                                                                     * 01200020
*ENTRY POINT   IGFMCH14                                                 01300020
*                                                                     * 01400020
*ATTRIBUTES  TRANSIENT,SERIALLY REUSABLE, USES PRIVILEGED             * 01500020
*   INSTRUCTIONS, OPERATES IN SUPERVISOR MODE.                        * 01600020
*                                                                     * 01700020
*EXTERNAL REFERENCES NONE                                             * 01800020
*                                                                     * 01900020
*MACROS ASRMAC85                                                      * 02000020
*       MCHMAC                                                        * 02050020
*                                                                     * 02100020
*INPUT  THE FAILING ENVIRONMENT AS INDICATED BY PSA, GPR'S, FPR'S     * 02200020
*   AND LOGOUT                                                        * 02300020
*                                                                     * 02400020
*       A REFRESHED STORAGE AREA, OR REPAIRED SPF KEY                 * 02500020
*                                                                     * 02600020
*       INFORMATION IN THE RMS/85 COMMUNICATION AREA INDICATING       * 02700020
*   THE NEEDED SERVICE.                                               * 02800020
*                                                                     * 02900020
*OUTPUT  IF RECOVERY HAS BEEN SUCCESSFUL THE RESUME PSW IS SET, AND   * 03000020
*   THE MESSAGE IGF032I IS SCHEDULED. IF UNSUCCESSFULL THE APPROPRIATE* 03100020
*   FLAGS ARE SET FOR PDAR.                                           * 03200020
*                                                                     * 03300020
*OPERATION  UPON ENTRY THIS MODULE TESTS THE MACHINE CHECK OLD PSW    * 03400020
*   FOR AN UNSUCCESSFUL CODE TO VERIFY THAT RETRY HAD BEEN ATTEMPTED  * 03500020
*   BY THE HARDWARE FACILITIES OF THE MODEL 85.  FURTHER TESTS OF     * 03600020
*   THE SAVED LOGOUT ARE ALSO MADE TO INSURE THAT A RETRYABLE         * 03700020
*   SITUATION STILL EXISTS.  THE INSTRUCTION TO BE RETRIED IS         * 03800020
*   EXAMINED FOR PARTICULAR CASES THAT CANNOT BE RETRIED VIA THE      * 03900020
*   DIAGNOSE TRANSFER TO THE RETRY MICRO-PROGRAM IN HARDWARE.  SOME   * 04000020
*   CASES REQUIRE SIMULATION OF THE INSTRUCTION, OR DEMAND THAT       * 04100020
*   THE RESUME ENVIRONMENT MERELY BE ADJUSTED TO ALLOW THE            * 04200020
*   INSTRUCTION TO BE RE-EXECUTED WHEN THE INTERRUPTED PROGRAM        * 04300020
*   AGAIN RECEIVES CONTROL.                                           * 04400020
*           IF THE INSTRUCTION CANNOT BE RETRIED, OR IF RETRY HAS     * 04500020
*   BEEN UNSUCCESSFUL, THE PROPER FLAGS ARE SET AND PDAR IS           * 04600020
*   SCHEDULED FOR TERMINATION PROCEDURES.  IF RETRY HAS BEEN          * 04700020
*   SUCCESSFUL THIS MODULE PREPARES THE RESUME ENVIRONMENT,           * 04800020
*   REQUESTS THE MESSAGE IGF032I,AND SCHEDULES THE ERROR RECORDER.    * 04900020
*                                                                     * 05000020
         EJECT                                                          05100020
         SPACE                                                          05200020
*                                                                     * 05300020
*EXITS  NORMAL-TO RMS/85 NUCLEUS WITH IGFMCH17 AS SUCCESSOR WHENEVER    05400020
*   RECOVERY HAS BEEN SUCCESSFUL,AND WITH IGFMCHF1-F3 AS SUCCESSOR      05500020
*   WHENEVER RECOVERY WAS NOT SUCCESSFUL.                             * 05600020
*                                                                     * 05700020
*       ABNORMAL-TO SHUT ROUTINE IN THE RMS/85 NUCLEUS                * 05800020
*                                                                     * 05900020
*ERROR CONDITIONS  PROGRAM CHECKS OR UNEXPECTED MACHINE CHECKS CAUSE  * 06000020
*   THE SHUT ROUTINE IN THE RMS/85 NUCLEUS TO GAIN CONTROL.           * 06100020
*                                                                     * 06200020
*                                                                     * 06300020
*********************************************************************** 06400020
         EJECT                                                          06500020
IGFMCH14 CSECT                                                          06600020
K0       EQU   0                   DECIMAL VALUE                        06700020
K1       EQU   1                   DECIMAL VALUE                        06800020
K2       EQU   2                   DECIMAL VALUE                        06900020
K3       EQU   3                   DECIMAL VALUE                        07000020
K4       EQU   4                   DECIMAL VALUE                        07100020
K5       EQU   5                   DECIMAL VALUE                        07200020
K6       EQU   6                   DECIMAL VALUE                        07300020
K8       EQU   8                   DECIMAL VALUE                        07400020
K10      EQU   10                  DECIMAL VALUE                        07500020
K16      EQU   16                  DECIMAL VALUE                        07600020
K24      EQU   24                  DECIMAL VALUE                        07700020
K28      EQU   28                  DECIMAL VALUE                        07800020
K32      EQU   32                  DECIMAL VALUE                        07900020
K36      EQU   36                  DECIMAL VALUE                        08000020
K37      EQU   37                  DECIMAL VALUE                        08100020
K40      EQU   40                  DECIMAL VALUE                        08200020
K44      EQU   44                  DECIMAL VALUE                        08300020
K48      EQU   48                  DECIMAL VALUE                        08400020
K52      EQU   52                                                       08450020
K56      EQU   56                  DECIMAL VALUE              IH  45458 08460021
K60      EQU   60                  DECIMAL VALUE                        08500020
K64      EQU   64                  DECIMAL VALUE                        08600020
K72      EQU   72                  DECIMAL VALUE              IH  45458 08650021
K96      EQU   96                  DECIMAL VALUE                        08700020
K104     EQU   104                 DECIMAL VALUE                        08800020
K112     EQU   112                 DECIMAL VALUE                        08900020
K128     EQU   128                 DECIMAL VALUE                        09000020
X00      EQU   X'00'               HEXADECIMAL VALUE                    09100020
X01      EQU   X'01'               HEXADECIMAL VALUE                    09200020
X05      EQU   X'05'               HEXADECIMAL VALUE                    09300020
X08      EQU   X'08'               HEXADECIMAL VALUE                    09400020
X0C      EQU   X'0C'               HEXADECIMAL VALUE                    09500020
X0F      EQU   X'0F'               HEXADECIMAL VALUE                    09600020
X10      EQU   X'10'               HEXADECIMAL VALUE                    09700020
X20      EQU   X'20'               HEXADECIMAL VALUE                    09800020
X39      EQU   X'39'               HEXADECIMAL VALUE                    09900020
X3F      EQU   X'3F'               HEXADECIMAL VALUE                    10000020
X40      EQU   X'40'               HEXADECIMAL VALUE                    10100020
X7F      EQU   X'7F'               HEXADECIMAL VALUE                    10200020
X80      EQU   X'80'               HEXADECIMAL VALUE                    10300020
XB7      EQU   X'B7'               HEXADECIMAL VALUE                    10400020
XBF      EQU   X'BF'               HEXADECIMAL VALUE                    10500020
XC0      EQU   X'C0'               HEXADECIMAL VALUE                    10600020
XDF      EQU   X'DF'               HEXADECIMAL VALUE                    10700020
XF0      EQU   X'F0'               HEXADECIMAL VALUE                    10800020
XF1      EQU   X'F1'               HEXADECIMAL VALUE                    10900020
XF2      EQU   X'F2'               HEXADECIMAL VALUE                    11000020
XF4      EQU   X'F4'               HEXADECIMAL VALUE                    11100020
XFF      EQU   X'FF'               HEXADECIMAL VALUE                    11200020
ALL      EQU   X'FF'               BYTE WITH ALL BITS ON                11300020
         EJECT                                                          11400020
*     VARIOUS EQUATES                                                   11500020
FPR0     EQU   0                                                        11600020
FPR2     EQU   2                                                        11700020
FPR4     EQU   4                                                        11800020
FPR6     EQU   6                                                        11900020
MSG1LEN  EQU   8              LENGTH OF DATE IN MESSAGE             IO  12000020
PGMNEW   EQU   104                 LOCATION OF PGM NEW PSW              12100020
RF       EQU   X'40'               RETRY FAILED FLAG                    12200020
OPFETCH  EQU   X'20'               OP CODE PREVIOUSLY FETCHED FLAG      12300020
FETCHSUB EQU   X'10'               SUBJECT OP CODE FETCHED FLAG         12400020
NR       EQU   X'08'               NO RETRY FLAG                        12500020
SSM      EQU   X'80'               HEXADECIMAL VALUE                    12600020
LPSW     EQU   X'82'               HEXADECIMAL VALUE                    12700020
SVCNEW   EQU   96                  LOCATION OF SVC NEW PSW              12800020
SYSALTER EQU   X'80'               SYSTEM BEING ALTERED                 12900020
FAILED   EQU   X'40'               RETRY FAILED BIT FOR PDAR            13000020
SUCCESS  EQU   X'09'               SUCCESSFUL RETRY CODE                13100020
MCOLD    EQU   X'30'                                                    13200020
MCNEW    EQU   X'70'                                                    13300020
STATUS   EQU   X'88'               REAL STATUS LOG AREA                 13400020
LOWCORE  EQU   X'654'              ADDRESS OF SAVED BASE REG            13500020
LOWCORE1 EQU   X'658'              ADDRESS OF ENVIRONMENTAL PSW         13600020
LOWCORE2 EQU   X'660'              ADDRESS OF MCW FOR DIAGNOSE TRANSFER 13700020
PSA      EQU   0                                                        13800020
RITR     EQU   X'20'               RETRY INTERRUPT STATUS BIT           13900020
PRS      EQU   X'20'               PARTIAL RESULT STORED BIT            14000020
EX       EQU   X'44'                                                    14100020
REG0     EQU   0                   REGISTER 0                           14300020
WORK1    EQU   1                   WORK REG                             14500020
WORK2    EQU   2                   WORK REG                             14600020
WORK3    EQU   3                   WORK REG                             14700020
CTR      EQU   4                   LOOP CONTROL COUNT REG               14800020
ADDR     EQU   5                   ADDRESS OF DATA TO BE CONVERTED      14900020
TOADDR   EQU   6                   ADDRESS OF CONVERTED DATA            15000020
LINK     EQU   7                   LINK REG FOR CONVERT ROUTINE         15100020
ADBYTE   EQU   8                   REG FOR HOLDING ADDRESSES            15200020
MSGPTR   EQU   9                   PTR TO SLOT IN COMIBUF FOR MSG CODE  15300020
CVTREG   EQU   10                  BASE FOR CVT                         15400020
COMREG   EQU   11                    INDEPENDENT COMMON AREA BASE REG   15500020
BASEREG  EQU   12                  MODULE BASE REG                      15600020
DEPREG   EQU   13                      DEPENDENT COMMON AREA BASE REG   15650020
RETURN   EQU   14                  RETURN ADDRESS TO RMS/85 NUC         15700020
REG15    EQU   15                  REGISTER 15                          15800020
LEVEL    EQU   X'&LEV'                                                  15850021
NEXT51   EQU   X'02'     IGFMCH17-ERROR RECORDER ID                 IO  15900020
NEXT50   EQU   X'01'     IGFMCHF1-SYSTEM ANALYSIS ID                IO  15950021
         EJECT                                                          16000020
         USING *,BASEREG           MODULE ADDRESSABILITY                16100020
         USING MCHCOM,COMREG                                            16160020
         USING ASRCOM,DEPREG                                            16220020
         USING CVTAREA,CVTREG     CVT ADDRESSABILITY                    16300020
         USING    RMSMSB,ADBYTE        MSB BASE                         16350020
         LR    WORK1,BASEREG       SAVE GPR CONTENTS                    16400020
         LR    BASEREG,REG15       SET UP MODULE BASE FROM ENTRY POINT  16500020
         SPACE 3                                                        17300020
*   INITIALIZATION OF REGISTERS, MCW'S, PSW'S                         * 17400020
START    EQU   *                                                        17500020
         MVI   MCHEXLEV,LEVEL      MODULE LEVEL                     IO  17600020
         STM   WORK2,REG0,SAVEGPRS SAVE GPRS AT ENTRY                   17700020
         ST    WORK1,SAVEGPRS+K40  SAVE IN THE CORRECT SLOT             17800020
         L     DEPREG,MCHDPADR     SET DEPENDENT COMMON AREA BASE       17850020
         OI    RERETRY,X80         INDICATE RETRY MODULE ENTERED        17900020
         SPACE                                                          18000020
         LA    ADDR,MCIHANDL       GET ADDR OF MY MCI HANDLER           18100020
         ST    ADDR,MYMCNEW+K4     PUT ADDR INTO MY MC NEW PSW          18200020
         SPACE                                                          18300020
         LA    WORK1,ENABLED       SETUP ADDRESS FOR                    18400020
         ST    WORK1,ENABLE+K4     ENABLING PSW                         18500020
         SPACE                                                          18600020
         LA    ADDR,MCIHNDL2       GET ADDRESS OF 2ND LEVEL HANDLER     18700020
         ST    ADDR,AD2NDMCH       SAVE FOR LATER USE                   18800020
         ST    BASEREG,LOWCORE     SAVE MODULE BASE IN ZERO BASE AREA   18900020
         ST    COMREG,COMADSAV     SAVE COMMON AREA BASE REG            19000020
         MVC   SAVENEW(K8),MCNEW   SAVE MCNEWPSW AT ENTRY               19100020
         MVC   SAVPGM(K8),PGMNEW   SAVE PGM NEW PSW AT ENTRY            19200020
         L     ADBYTE,MCHMSB           ESTABLISH BASE                   19250020
         MVC   MCW1(K8),RESMCW     COPY SYSTEM MCW                      19300020
         DROP  ADBYTE                                                   19350020
         MVC   ENBLMCW(K8),MCW1    COPY SYSTEM MCW                      19400020
         OI    MCW1+K4,X05         FORCE HIR AND ECC TO COUNTER MODES   19500020
         OI    ENBLMCW+K2,X08      FORCE I/E DEFEATED                   19600020
         OI    ENBLMCW+K4,X40      FORCE BUFFER DISABLED                19700020
         MVC   DSBLMCW(K8),ENBLMCW COPY ALTERED MCW                     19800020
         OI    DSBLMCW+K4,X05      FORCE HIR AND ECC TO COUNTER MODES   19900020
         MVC   TRANSMCW(K5),ENBLMCW COPY ALTERED MCW PORTIONS NEEDED    20000020
         NI    TRANSMCW+K4,XF0     RECORDING MODE FORCED                20100020
         LA    ADDR,DIAGTRAN       ADDRESS OF DIAGNOSE TRANSFER         20200020
         ST    ADDR,ENVPSW+K4      INSTRUCTION INTO PSW                 20300020
         MVC   ENVPSW+K1(K1),REMCOPSW+K1     RESTORE PROGRAM KEY-RETRY  20400020
         NI    ENVPSW+K1,XF4       MAKE SURE KEY AND ENABLED FOR MCI    20500020
         MVC   ENVPSW+K4(K1),REMCOPSW+K4     RESTORE CC AND PGM MASK    20600020
         EJECT                                                          20700020
*   INTERROGATION OF SITUATION                                        * 20800020
         SPACE 2                                                        20900020
         TM    REMCOPSW+K3,X01     UNSUCCESSFULLY RETRIED ERROR         21000020
         BNO   NORETRY             NO  RETRY NOT POSSIBLE               21100020
         TM    STATLOG+K37,RITR    WAS ERROR DURING AN INTERRUPT        21200020
         BO    NORETRY             YES RETRY NOT POSSIBLE               21300020
         TM    RERETRY,OPFETCH     HAS OP CODE BEEN FETCHED             21400020
         BNO   FETCHOP             NO  GO FETCH OP CODE                 21500020
         SPACE                                                          21600020
TESTCODE EQU   *                                                        21700020
         CLI   OPCODE,EX           IS THIS AN EXECUTE INSTRUCTION       21800020
         BNE   CHEKPRIV            NO, CHECK FOR PRIVILEGED OPCODE      21900020
         SR    WORK1,WORK1         CLEAR REG                            22000020
         IC    WORK1,OPCODE+K2     GET BASE FOR EX INSTRUCTION SUBJECT  22100020
         SRL   WORK1,K4            CLEAR OUT LOW ORDER DISPLACEMENT     22200020
         SLL   WORK1,K2            AND COMPUTE DISP. INTO REGSGPR       22300020
         L     ADDR,REGSGPR(WORK1) GET BASE VALUE FOR SUBJECT OF EX     22400020
         NI    OPCODE+K2,X0F       CLEAR BASE LEAVING ONLU DISPLACEMENT 22500020
         AH    ADDR,OPCODE+K2      COMPUTE ADDRESS OF SUBJECT           22600020
         ST    ADDR,SUBJADR        SAVE THIS ADDRESS                    22700020
         L     CVTREG,MCHCVT            GET ADDRESS FOR CVT DSECT   IO  22800020
         C     ADDR,CVTMZ00        IS ADDRESS WITHIN VALID CORE         22900020
         BH    RETRY               NO  LET RETRY GIVE PROGRAM CHECK     23000020
         TM    SUBJADR+K3,X01      ON HALFWORD BOUNDARY                 23100020
         BO    RETRY               NO  LET RETRY GIVE PROGRAM CHECK     23200020
         SPACE                                                          23300020
SUBREDO  EQU   *                                                        23400020
         DC    X'8300'             DIAGNOSE TO DISABLE BUFFER           23500020
         DC    S(DSBLMCW)          AND TO DEFEAT I/E OVERLAP            23600020
         OI    SWITCH,X40          SET  SUBJECT OP CODE FETCH FLAG      23700020
         MVC   MCNEW(K8),MYMCNEW   POINT M.C. NEW PSW TO THIS MODULE    23800020
         IC    WORK1,K0(ADDR)      FETCH SUBJECT'S OPCODE               23900020
         MVC   MCNEW(K8),SAVENEW   RESTORE ORIGINAL MCNEWPSW            24000020
         NI    SWITCH,XBF          CLEAR SUBJECT OP CODE FETCH FLAG     24100020
         OI    RERETRY,FETCHSUB    INDICATE SUBJECT OP CODE FETCHED     24200020
         STC   WORK1,SUBJOP        SAVE OP CODE                         24300020
         CLI   SUBJOP,EX           IS THIS AN EXECUTE                   24400020
         BO    RETRY               YES LET RETRY GIVE PROGRAM CHECK     24500020
         EJECT                                                          24600020
CHEKPRIV EQU   *                                                        24700020
         TM    REMCOPSW+K1,X01     PROBLEM PROGRAM MODE WHEN ERROR      24800020
         BNO   TESTIO              NO                                   24900020
         LA    ADDR,SUBJOP         GET ADDRESS OF OP CODE               25000020
         LA    ADBYTE,PRIVTAB      GET ADDRESS OF PRIVILEGED OP TABLE   25100020
         LA    CTR,PRIVTABL        GET NUMBER OF ENTRIES                25200020
         BAL   LINK,TESTOP         SEE IF OPCODE IS PRIVILEGED          25300020
*   IF NOT FOUND RETURN IS HERE - IF FOUND ENTRY IS HERE PLUS FOUR      25400020
         B     RETRY               NOT FOUND  DO RETRY                  25500020
         SPACE 2                                                        25600020
*   SIMULATE PRIVILEGED OP PROGRAM CHECK                              * 25700020
         LA    CTR,K2              INITIALIZE LENGTH OF TWO             25800020
         TM    SUBJOP,XC0          TEST OP CODE FOR INSTRUCTION LENGTH  25900020
         BZ    ILC2                LENGTH IS 2 BYTES                    26000020
         BM    ILC4                LENGTH IS 4 BYTES                    26100020
         LA    CTR,K2(CTR)         LENGTH IS 6 BYTES - BUMP LENGTH TWO  26200020
         SPACE                                                          26300020
ILC4     EQU   *                                                        26400020
         LA    CTR,K2(CTR)         BUMP LENGTH BY TWO                   26500020
         SPACE                                                          26600020
ILC2     EQU   *                                                        26700020
         LR    WORK1,CTR           SAVE INSTRUCTION LENGTH              26800020
         A     CTR,ICVALUE         COMPUTE ADDRESS OF NEXT INSTRUCTION  26900020
         XC    SAVEOLD(K8),SAVEOLD INIT. TO BUILD PGM OLD PSW           27000020
         ST    CTR,SAVEOLD+K4      BUILD PROGRAM OLD PSW WITH ADDRESS   27100020
*                                  OF INTERRUPTED INSTRUCTION           27200020
         MVC   SAVEOLD+K4(K1),REMCOPSW+K4 GET CONDITION CODE, PGM MASK  27300020
         NI    SAVEOLD+K4,X3F      CLEAR ILC BITS                       27400020
         SLL   WORK1,K5            ILC TO H.O. BITS                     27500020
         EX    WORK1,ORILC         OR IN ILC                            27600020
         MVC   SAVEOLD(K2),REMCOPSW SYS. MASK AND STATUS INTO OLD PSW   27700020
         LA    WORK1,K2            GET PRIV. OP PGM CHECK CODE          27800020
         STH   WORK1,SAVEOLD+K2    CODE INTO BUILT PGM OLD PSW          27900020
         MVC   COMRSPSW(K8),COMPSA+K104 PGM NEW PSW IS RESUME POINT     28000020
         MVC   COMPSA+K40(K8),SAVEOLD SIMULATED PGM OLD PSW TO PSA      28100020
         DC    X'8300'             DIAGNOSE TO RETURN MCW TO STATE      28200020
         DC    S(MCW1)             UNDER WHICH RMS NORMALLY RUNS.       28300020
         NI    COMINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    28400020
         B     PREPMSG             GO TO PREPARE MESSAGE AND EXIT       28500020
         SPACE                                                          28600020
ORILC    OI    SAVEOLD+K4,X00      USE TO OR IN INSTRUCTION LENGTH CODE 28700020
         EJECT                                                          28800020
TESTIO   EQU   *                                                        28900020
         LA    ADDR,SUBJOP         GET ADDRESS OF OP CODE               29000020
         LA    ADBYTE,IOTAB        GET ADDRESS OF I/O OP TABLE          29100020
         LA    CTR,IOL             GET NUMBER OF ENTRIES                29200020
         BAL   LINK,TESTOP         SEE IF OPCODE IS AN I/O              29300020
*   IF NOT FOUND RETURN IS HERE - IF FOUND ENTRY IS HERE PLUS FOUR      29400020
         B     RETRY               NOT FOUND - DO RETRY                 29500020
         TM    STATLOG+K36,PRS     IS PARTIAL RESULT STORED TRIGGER ON  29600020
         BO    NORETRY             YES RETRY NOT POSSIBLE               29700020
         MVC   BLDPSW(K5),REMCOPSW GET PROGRAMS STATUS AT FAILURE       29800020
         MVC   BLDPSW+K5(K3),REPDARI+K1 SET PROGRAM INSTRUCTION ADDRESS 29900020
         MVC   COMRSPSW(K8),BLDPSW SET UP RESUME PSW FOR SELF RETRY     30000020
         NI    COMINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    30100020
         B     PREPMSG             GO TO PREPARE MESSAGE AND EXIT       30200020
         SPACE 2                                                        30300020
RETRY    EQU   *                                                        30400020
         OI    SWITCH,X20          INDICATE RETRY ATTEMPT BEGUN         30500020
         LD    FPR0,REGSFPR        RESTORE FPR0                         30600020
         LD    FPR2,REGSFPR+K8     RESTORE FPR2                         30700020
         LD    FPR4,REGSFPR+K16    RESTORE FPR4                         30800020
         LD    FPR6,REGSFPR+K24    RESTORE FPR6                         30900020
         MVC   LOWCORE2(K8),TRANSMCW MOVE MCW FOR DIAG. TRANSFER  TO    31000020
*                                  LOW CORE                             31100020
         MVC   LOWCORE1(K8),ENVPSW ENVIRONMENTAL PSW TO LOWCORE         31200020
         MVC   PSA(K128),COMPSA    RESTORE ORIGINAL PSWS                31300020
         MVC   PGMNEW(K8),SAVPGM   POINT PGM NEW TO SHUT RTN            31400020
         MVC   MCNEW(K8),MYMCNEW   POINT MCI TO ME                      31500020
         DC    X'8300'             DIAGNOSE TO GO TO HIR AND            31600020
         DC    S(ENBLMCW)          ECC RECORDING MODES.                 31700020
         MVC   STATUS(K40),STATLOG RETRY STATUS LOG TO LOWCORE          31800020
         LM    REG0,REG15,REGSGPR  RESTORE GPRS                         31900020
         LPSW  LOWCORE1            LOAD ENVIRONMENTAL PSW WHICH CAUSES  32000020
*                                  EXECUTION OF DIAGNOSE TRANSFER       32100020
*                                  TO RETYY MICROPROGRAM.               32200020
         EJECT                                                          32300020
NORETRY  EQU   *                                                        32400020
         OI    RERETRY,NR          INDICATE NO RETRY                    32500020
RETRYFAL EQU   *                                                        32600020
         TM    COMINTEL+K1,X01     HAS WRITABLE CONTROL BEEN LOADED IO  32700020
         BZ    SETFAIL             NO, PDAR HAS BEEN ENTERED            32800020
         OI    REPDAR1,X80         TERMINATION NECESSARY                32900020
         NI    REPDAR1,XDF         RESET RETRY POSSIBLE                 33000020
EXIT2    EQU   *                                                        33100020
         DC    X'8300'             DIAGNOSE TO RETURN MCW TO STATE      33200020
         DC    S(MCW1)             UNDER WHICH RMS NORMALLY RUNS.       33300020
         NI    COMINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    33400020
         MVI   MCHNXMOD,NEXT50     SUCCESSOR MODULE ID              IO  33500020
         LM    WORK2,REG0,SAVEGPRS RESTORE REGS AT ENTRY                33700020
         BR    RETURN              RETURN TO RMS/85 NUCLEUS             33800020
         SPACE 2                                                        33900020
SETFAIL  EQU   *                                                        34000020
         OI    REPDAR1,RF          SET RETRY FAILED FOR PDAR            34100020
         B     EXIT2               GO CLEAN UP AND EXIT TO TERMINATE    34200020
         SPACE 2                                                        34300020
FETCHOP  EQU   *                                                        34400020
         MVC   ICVALUE(K4),REPDARI GET COPY OF IC AT FAILURE            34500020
         L     ADDR,REPDARI        GET IC AT FAILURE                    34600020
         OI    COMINTEL,SYSALTER                                        34700020
         DC    X'8300'             DIAGNOSE TO DISABLE BUFFER           34800020
         DC    S(DSBLMCW)          AND TO DEFEAT I/E OVERLAP            34900020
         OI    SWITCH,X80          INDICATE OP CODE FETCH IN PROGRESS   35000020
         MVC   MCNEW(K8),MYMCNEW   POINT M.C. NEW PSW TO THIS MODULE    35100020
         MVC   OPCODE(K6),K0(ADDR) GET FAILING INSTRUCTION              35200020
         MVC   MCNEW(K8),SAVENEW   RESTORE ORIGINAL MCNEWPSW            35300020
         NI    SWITCH,X7F          CLEAR OP CODE FETCH IN PROGRESS      35400020
         MVC   SUBJOP(K1),OPCODE   OPCODE TO POSITION FOR SUBROUTINE    35500020
         OI    RERETRY,OPFETCH     INDICATE OP CODE FETCHED             35600020
         B     TESTCODE            GO TEST OP CODE                      35700020
         EJECT                                                          35800020
TESTOP   EQU   *                                                        35900020
         CLC   K0(K1,ADDR),K0(ADBYTE) CHECK FOR OP CODE MATCH           36000020
         BE    K4(LINK)            INSTRUCTION IN TABLE                 36100020
         BCT   CTR,TESTOP          CONTINUE UNTIL ALL CODES CHECKED     36200020
         BR    LINK                INSTRUCTION NOT IN TABLE             36300020
         SPACE                                                          36400020
CONVERT  EQU   *                                                        36500020
         LA    WORK2,XB7(WORK2)    BUMP TO PRINTABLE LETTER RANGE       36600020
         CH    WORK2,XC1               IS VALUE PRINTABLE LETTER        36700020
         BNL   STORE               YES                                  36800020
         LA    WORK2,X39(WORK2)    BUMP TO CONVERTED NUMBER             36900020
         SPACE                                                          37000020
STORE    EQU   *                                                        37100020
         STC   WORK2,K0(TOADDR)    CONVERTED DATA INTO MESSAGE          37200020
         LA    TOADDR,K1(TOADDR)   BUMP OUTPUT ADDRESS                  37300020
         BR    LINK                RETURN                               37400020
         SPACE 2                                                        37500020
PREPMSG  EQU   *                                                        37600020
         LA    CTR,K3              INITIALIZE CONVERT RTN. LOOP COUNT   37700020
         LA    ADDR,REPDARI+K1     GET ADDR OF ADDRESS TO BE CONVERTED  37800020
         LA    TOADDR,MSG1         GET ADDRESS OF POSITION IN MESSAGE   37900020
*                                  WHERE CONVERTED ADDRESS MUST GO.     38000020
NEXTBYTE EQU   *                                                        38100020
         SR    WORK2,WORK2         CLEAR REG                            38200020
         IC    WORK2,K0(ADDR)      GET BYTE TO BE CONVERTED             38300020
         SRDL  WORK2,K4            KEEP LEFT 4 BITS PASS OTHERS ON      38400020
         BAL   LINK,CONVERT        GO TO CONVERT FOR PRINT              38500020
         SRL   WORK3,K28           SHIFT TO LOW-ORDER 4 BITS            38600020
         LR    WORK2,WORK3         TRANSFER TO REG FOR SUBROUTINE       38700020
         BAL   LINK,CONVERT        GO TO CONVERT FOR PRINT              38800020
         LA    ADDR,K1(ADDR)       BUMP INPUT ADDRESS                   38900020
         BCT   CTR,NEXTBYTE        CONTINUE UNTIL 3 BYTES CONVERTED     39000020
         L     MSGPTR,MCHIPTR      GET I-MSG BUFFER POINTER         IO  39100020
         MVC   K0(MSG1LEN,MSGPTR),MSG1CODE REQUEST FOR IGF032I          39200020
         LA    MSGPTR,MSG1LEN(MSGPTR) INCR I-MSG BUFFER POINTER         39300020
         ST    MSGPTR,MCHIPTR      STORE UPDATE POINTER             IO  39400020
         DC    X'8300'             DIAGNOSE TO RETURN MCW TO STATE      39500020
         DC    S(MCW1)             UNDER WHICH RMS NORMALLY RUNS.       39600020
         NI    COMINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    39700020
         MVI   MCHNXMOD,NEXT51     SUCCESSOR MODULE ID              IO  39800020
         LM    WORK2,REG0,SAVEGPRS RESTORE REGS AT ENTRY                40000020
         BR    RETURN              RETURN TO RMS/85 NUCLEUS             40100020
         EJECT                                                          40200020
MCIHANDL EQU   *                                                        40300020
         ST    BASEREG,LOWCORE1+K4 SAVE REG 12                          40400020
         L     BASEREG,LOWCORE     GET SAVED MODULE BASE                40500020
         MVC   MCNEW+K4(K4),AD2NDMCH SECOND LEVEL HANDLER READY         40600020
         MVC   SAVEOLD(K8),MCOLD   SAVE MACHINE CHECK OLD PSW           40700020
         MVC   SAVESTAT(K48),STATUS SAVE STATUS LOG                     40800020
         LPSW  ENABLE              ENABLE FOR MACHINE CHECKS            40900020
         SPACE                                                          41000020
ENABLED  EQU   *                                                        41100020
         OI    SWITCH,X10          INDICATE ENABLE POINT REACHED        41200020
         DC    X'8300'             DIAGNOSE TO GO BACK TO               41300020
         DC    S(DSBLMCW)          CTR MODE AND BUFR DISABLED, ETC.     41400020
         MVC   MCNEW(K8),SAVENEW   RESTORE ORIGINAL MCNEWPSW            41500020
         ST    COMREG,LOWCORE1     SAVE GPR CONTENTS                    41600020
         L     COMREG,COMADSAV     RESTORE COMMON AREA DSECT REG        41700020
         ST    DEPREG,SAVREG13         SAVE ORIG REG 13                 41730020
         L     DEPREG,MCHDPADR     SET DEPENDENT COMMON AREA BASE       41760020
         MVC   SAVEPSA(K128),PSA   SAVE PSA AREA                        41800020
         TM    SWITCH,X20          WAS THIS A RETRY ATTEMPT             41900020
         BNO   FAIL2               NO                                   42000020
         CLC   SAVESTAT+K5(K3),STATLOG+K5 CORRECT INSTRUCTION RETRIED   42100020
         BNE   FAIL3               NO                                   42200020
         CLI   SAVEOLD+K3,SUCCESS  WAS RETRY SUCCESSFUL                 42300020
         BNE   FAIL1               NO                                   42400020
         MVC   SAVEPSA+K104(K16),COMPSA+K104  SAVE ORIG PGM AND MC NEW  42500020
         STM   REG0,REG15,MCISAVE  SAVE REGISTERS                       42600020
         MVC   MCISAVE+K44(K8),LOWCORE1 SAVE GPR TO SAVE AREA           42700020
         MVC   MCISAVE+K52,SAVREG13    REPLACED ORIG REG 13             42750020
         STD   FPR0,REGSFPR        SAVE FPR FOLLOWING EXECUTION         42800020
         STD   FPR2,REGSFPR+K8     SAVE FPR FOLLOWING EXECUTION         42900020
         STD   FPR4,REGSFPR+K16    SAVE FPR FOLLOWING EXECUTION         43000020
         STD   FPR6,REGSFPR+K24    SAVE FPR FOLLOWING EXECUTION         43100020
         MVC   REGSGPR(K64),MCISAVE SAVE GPRS FOLLOWING EXECUTION       43200020
*   GPRS OR FPRS MAY HAVE BEEN MODIFIED BY THE RETRIED INSTRUCTION    * 43300020
         CLC   SAVEOLD+K5(K3),PGMNEW+K5 HAS A PGM CHECK OCCURRED        43400020
         BNE   NOTPGMCK                 NO,BRANCH TO CHK SVC INT        43500020
         MVC   SAVEOLD(K8),COMPSA+K104  SET TO ORIGINAL PGM NEW         43600020
ALTERPGM MVC   SAVEPSA+K40(K2),REMCOPSW RESTORE PGM OLD MASK-AMWP       43700020
         B     ALTERPSA                 BRANCH TO ALTER PSA AREA        43800020
NOTPGMCK CLC   SAVEOLD+K5(K3),SVCNEW+K5 WAS AN SVC INTERRUPT TAKEN      43900020
         BNE   NOTSVCCK                 NO,BRANCH TO CHECK P/P MODE     44000020
ALTERSVC MVC   SAVEPSA+K32(K2),REMCOPSW RESTORE SVC OLD MASK-AMWP       44100020
         B     ALTERPSA                 BRANCH TO ALTER PSA AREA        44200020
NOTSVCCK TM    REMCOPSW+K1,X01          WAS PROGRAM IN P/P MODE         44300020
         BNO   CHEKMASK                 NO,BRANCH TO CHECK MASK         44400020
         OI    SAVEOLD+K1,X01           RESTORE P/P MODE                44500020
         B     MASKBACK                 BRANCH TO RESTORE MASK BITS     44600020
CHEKMASK CLI   SAVEOLD,X00         IS SYSTEM MASK ZERO                  44700020
         BNE   ALTERPSA                 NO,BRANCH TO ALTER PSA          44800020
         L     ADDR,REPDARI             LOAD ADDRESS OF RETRY IC        44900020
         CLI   K0(ADDR),SSM             IS IT A SSM INSTRUCTION         45000020
         BE    ALTERPSA                 YES,BRANCH TO ALTER PSA AREA    45100020
         CLI   K0(ADDR),LPSW            IS IT A LPSW INSTRUCTION        45200020
         BE    ALTERPSA                 YES,BRANCH TO ALTER PSA AREA    45300020
MASKBACK MVC   SAVEOLD(K1),REMCOPSW     RESTORE SYSTEM MASK BITS        45400020
ALTERPSA EQU   *                                                        45500020
         MVC   SAVEPSA+K48(K8),SAVEOLD  ALTER MC OLD PSW IN PSA AREA    45600020
         MVC   COMPSA(K48),SAVEPSA      SET UP RETURN         IH  45458 45700021
         MVC   COMPSA+K56(K72),SAVEPSA+K56  ENVIRONMENT       IH  45458 45750021
         MVC   COMRSPSW(K8),SAVEPSA+K48 SET RESUME PSW TO CONTINUE      45800020
         B     PREPMSG             GO TO PREPARE RECOVERED MSG          45900020
         EJECT                                                          46000020
FAIL1    EQU   *                                                        46100020
FAIL3    EQU   *                                                        46200020
         LA    LINK,RETRY          SETUP TO CONTINUE                    46300020
         SPACE                                                          46400020
CHEKCNT  EQU   *                                                        46500020
         LH    WORK1,RETRYCNT      GET RETRY COUNT                      46600020
         LA    WORK1,K1(WORK1)     BUMP BY ONE                          46700020
         STH   WORK1,RETRYCNT      STORE RETRY COUNT                    46800020
         CH    WORK1,RETRYMAX          HAS MAX. NO. BEEN REACHED        46900020
         BE    QUIT                YES                                  47000020
         BR    LINK                CONTINUE                             47100020
         SPACE                                                          47200020
QUIT     EQU   *                                                        47300020
         OI    RERETRY,RF          INDICATE RETRY FAILED                47400020
         B     RETRYFAL            CONTINUE                             47500020
         SPACE                                                          47600020
FAIL2    EQU   *                                                        47700020
         TM    SWITCH,X80              WAS OP CODE BEING FETCHED        47800020
         BNO   FAIL21              NO                                   47900020
         NI    SWITCH,ALL-X80      CLEAR FLAG                           48000020
         LA    LINK,FETCHOP        SETUP TO CONTINUE                    48100020
         B     CHEKCNT             GO CHECK RETRY COUNT                 48200020
         SPACE                                                          48300020
FAIL21   EQU   *                                                        48400020
         TM    SWITCH,X40              WAS SUBJECT OP CODE BEING FETCH  48500020
         BNO   QUIT           NO,PREPARE UNSUCCESSFUL EXIT          IO  48600020
         NI    SWITCH,ALL-X40      CLEAR FLAG                           48700020
         LA    LINK,SUBREDO        SETUP TO CONTINUE                    48800020
         B     CHEKCNT             GO CHECK RETRY COUNT                 48900020
         SPACE                                                          49000020
         SPACE                                                          49300020
MCIHNDL2 EQU   *                                                        49400020
         CLI   MCOLD+K3,X08            HAS ECC CORRECTED AN ERROR       49500020
         BE    ENABLED             YES   IGNORE IT                      49600020
         DC    X'8300'             DIAGNOSE TO GO BACK TO               49700020
         DC    S(DSBLMCW)          CTR MODE, BUFFER DISABLED, ETC       49800020
         MVC   MCNEW(K8),SAVENEW   RESTORE ORIGINAL MCNEWPSW            49900020
         L     COMREG,COMADSAV     RESTORE COMMON AREA DSECT REG        50000020
         L     DEPREG,MCHDPADR         SET DEPENDENT COMMON AREA BASE   50050020
         B     QUIT                PREPARE UNSUCCESSFUL EXIT            50100020
         EJECT                                                          50200020
*      CONSTANTS                                                        50300020
DIAGTRAN DC    X'8300'             DIAGNOSE TRANSFER TO                 50400020
         DC    S(LOWCORE2)         RETRY MICROPROGRAM.                  50500020
SAVEGPRS DS    16F                 GPR SAVE AREA                        50600020
MCW1     DS    1D                  COPY OF SYSTEM MCW                   50700020
MCW2     DS    1D                  COPY OF SYSTEM MCW                   50800020
MYMCNEW  DC    D'0'                MY FUTURE M.C. NEW PSW               50900020
ENVPSW   DC    X'0004000000000000' ENVIRONMENTAL PSW                    51000020
TRANSMCW DC    X'00000000000BC000' MCW TO TRANSFER TO RETRY MICROPROGM  51100020
OPCODE   DC    X'000000000000'     STG LOCATION FOR OP CODE             51200020
SAVEDISP DC    X'00000FFF'         BITS TO KEEP DISPLACEMENT ONLY       51300020
MSG1CODE DC    X'8806'             REQUEST FOR IGF032I  MSG         IO  51400020
MSG1     DC    C'AAAAAA'           SUCCESSFUL RECOVERY MESSAGE          51500020
SAVEPSA  DS    16D                 SAVE AREA FOR PSA AFTER RETRY        51600020
BLDPSW   DC    D'0'                RESUME PSW BUILD AREA                51700020
SAVENEW  DS    1D                  SAVE AREA FOR ORIGINAL MCNEWPSW      51800020
SAVPGM   DC    D'0'                SAVE AREA FOR PGM NEW PSW            51900020
DSBLMCW  DC    X'0300080045000000' MCW FOR DISABLING                    52000020
ENBLMCW  DC    X'0300080040000000' MCW FOR ENABLING                     52100020
SAVEOLD  DS    1D                  SAVE AREA FOR OLD MC PSW             52200020
SUBJADR  DC    F'0'                SUBJECT ADDRESS FOR EX INSTRUCTION   52300020
PRIVTAB  DC    X'08098082838485'   NON I/O PRIVILEGED INSTRUCTIONS      52400020
IOTAB    DC    X'9C9D9E9F'         I/O INSTRUCTIONS                     52500020
TABEND   EQU   *                                                        52600020
PRIVTABL EQU   TABEND-PRIVTAB      LENGTH OF TABLE OF PRIVILEGED OPS    52700020
ICVALUE  EQU   BLDPSW+K4                                                52800020
IOL      EQU   TABEND-IOTAB        LENGTH OF TABLE OF I/O INSTRUCTIONS  52900020
SWITCH   DC    X'00'               SWITCHES                             53000020
SAVESTAT DS    12F                 STATUS SAVE AREA                     53100020
MCISAVE  DS    16F                 SAVE AREA FOR REGS AFTER RETRY       53200020
MCPSWSAV DS    1D                       MACHINE CHECK NEW PSW SAVE AREA 53300020
RESUME   DS    1D                  STG. FOR RESUME PSW MANIPULATION     53400020
SAVE     DS    16F                 REGISTER SAVE AREA                   53500020
ENABLE   DC    X'0004000000000000' PSW TO ENABLE AFTER MCI HANDLING     53600020
AD2NDMCH DC    F'0'                ADDRESS OF 2ND MCI HANDLER           53700020
COMADSAV DC    F'0'                SAVE AREA FOR COMMON AREA BASE       53800020
SAVREG13 DC    F'0'                    REG13 SAVE AREA                  53850020
XC1      DC    X'00C1'             CONSTANT FOR CONVERT ROUTINE         53900020
RETRYCNT DC    H'0'                TWO BYTES FOR RETRY COUNT            54100020
RETRYMAX DC    H'10'               MAXIMUM RETRY COUNT                  54200020
SUBJOP   DC    X'00'               EX SUBJECT OP CODE                   54300020
         SPACE 3                                                        54350021
***  MAINTENANCE  AREA  ***                                             54400021
MAINTID  DC    CL8'IGFMCH14'           CORE IDENTIFIER                  54450021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              54500021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 54550021
         EJECT                                                          54700020
MCHCOM   DSECT                                                          54770020
         MCHMAC                                                         54850020
         EJECT                                                          54860020
ASRCOM   DSECT                                                          54870020
         ASRMAC85                                                       54900020
STATLOG  EQU   RECPULOG+K8         SAVED STATUS LOG AREA                55000020
COMINTEL EQU   MCHINTEL                                                 55010020
COMPSA   EQU   MCHPSA                                              IO   55020020
COMRSPSW EQU   REMCOPSW                                            IO   55030020
RMSMSB   DSECT                                                          55040020
         RMSMSB    MOD=85                                               55050020
         EJECT                                                          55100020
CVTAREA  DSECT                                                          55200020
         CVT                                                            55300020
         END                                                            55400020
