        LCLA &LEV,&REL                                                  00100021
&LEV     SETA  20                                                       00150021
&REL     SETA  21                                                       00160021
&REL&LEV TITLE 'IGFMCH16 LEVEL &LEV RMS-MCH BUFFER ANALYSIS'            00170021
*********************************************************************** 00200020
*                                                                     * 00300020
*TITLE  IGFMCH16   BUFFER CONTROL                                       00400020
*                                                                     * 00500020
*STATUS  CHANGE LEVEL 000                                             * 00600020
*                                                                     * 00700020
*FUNCTION  THE BUFFER CONTROL MODULE ANALYZES MACHINE ERRORS          * 00800020
*   ASSOCIATED WITH THE MODEL 85 HIGH SPEED BUFFER STORAGE UNIT       * 00900020
*   (C-40), AND EXERCISES THE FAILING PORTION OF THE HARDWARE TO      * 01000020
*   DETERMINE THE SEVERITY OF THE ERROR.  WITH THE ABILITY TO         * 01100020
*   DELETE SPECIFIC SECTORS OR TO DISABLE THE BUFFER ENTIRELY         * 01200020
*   THE STATUS OF THE BUFFER IS CONTROLLED TO PREVENT RE-OCCURRING    * 01300020
*   MACHINE CHECKS.                                                   * 01400020
*                                                                     * 01500020
*ENTRY POINT  IGFMCH16                                                  01600020
*                                                                     * 01700020
*ATTRIBUTES  TRANSIENT,SERIALLY REUSABLE, USES PRIVILEGED             * 01800020
*   INSTRUCTIONS, OPERATES IN SUPERVISOR MODE, MODEL DEPENDENT.       * 01900020
*                                                                     * 02000020
*EXTERNAL REFERENCES  NONE                                            * 02100020
*                                                                     * 02200020
*MACROS  ASRMAC85                                                     * 02300020
*        MCHMAC   INDEPENTENT SECTION                               IO  02350020
*                                                                     * 02400020
*INPUT  THE FAILING ENVIRONMENT AS DEPICTED BY THE LOGOUT SAVED IN    * 02500020
*   RECPULOG,THE PRELIMINARY ANALYSIS REPORT AREA REPRIANL, AND       * 02600020
*   THE MCW AND SECTOR STATUS AS SAVED IN RESMCW AND RESECT.          * 02700020
*                                                                     * 02800020
*OUTPUT  THE STATUS OF THE M85 HARDWARE, THE MCW AND SECTOR STATUS    * 02900020
*   FIELDS (RESMCW, RESECT), AND A MESSAGE TO THE OPERATOR IF A       * 03000020
*   SECTOR HAS BEEN DELETED OR THE BUFFER DISABLED.                   * 03100020
*                                                                     * 03200020
*OPERATION  THIS MODULE RECEIVES CONTROL FROM THE RMS/85 RESIDENT     * 03300020
*   NUCLEUS.  THE INDICATORS LOGGED AT THE TIME OF THE ERROR AND      * 03400020
*   THE STATUS OF THE BUFFER ARE ANALYZED TO DETERMINE THE TYPE OF    * 03500020
*   ERROR THAT OCCURRED.  THE FOLLOWING TABLE SUMMARIZES THE ERROR    * 03600020
*   TYPES AND THE ACTION TO BE TAKEN.                                 * 03700020
*                                                                     * 03800020
*       *******************************************************       * 03900020
*       *                                                     *       * 04000020
*       *   CHECK                CATEGORY      ACTION         *       * 04100020
*       *                                                     *       * 04200020
*       *******************************************************       * 04300020
*       *                                                     *       * 04400020
*       *                                                     *       * 04500020
*       *                                                     *       * 04600020
*       * SCU ADDRESS               B            N            *       * 04700020
*       *                                                     *       * 04800020
*       * BUFFER IN KEY             B            D            *       * 04900020
*       *                                                     *       * 05000020
*       * MULTIPLE COMPARE          B            D            *       * 05100020
*       *                                                     *       * 05200020
*       * BLOCK VALID               S            E            *       * 05300020
*       *                                                     *       * 05400020
*       * COMPARE                   S            E            *       * 05500020
*       *                                                     *       * 05600020
*       * SECTOR KEY                S            E            *       * 05700020
*       *                                                     *       * 05800020
*       * BUFFER ADDRESS BUS        B            D            *       * 05900020
*       *                                                     *       * 06000020
*       * BUFFER MARK               B            D            *       * 06100020
*       *                                                     *       * 06200020
*       * BUFFER DATA OUT BUS       S            E            *       * 06300020
*       *                                                     *       * 06400020
*       *                                                     *       * 06500020
*       *                                                     *       * 06600020
*       *******************************************************       * 06700020
*       *  CODE DEFINITIONS                                   *       * 06800020
*       *                                                     *       * 06900020
*       *   S = SECTOR ASSOCIATED ERROR                       *       * 07000020
*       *                                                     *       * 07100020
*       *   B = GENERAL BUFFER ERROR                          *       * 07200020
*       *                                                     *       * 07300020
*       *   N = NONE                                          *       * 07400020
*       *                                                     *       * 07500020
*       *   E = CIRCUITRY INVOLVED IS EXERCISED               *       * 07600020
*       *                                                     *       * 07700020
*       *   D = BUFFER IS DISABLED WHEN THE COUNT OF THE      *       * 07800020
*       *      CHECKS IN THIS CATEGORY REACH A CRITERIUM      *       * 07900020
*       *                                                     *       * 08000020
*       *                                                     *       * 08100020
*       *                                                     *       * 08200020
*       *                                                     *       * 08300020
*       *                                                     *       * 08400020
*       *******************************************************       * 08500020
*                                                                     * 08600020
*   WHENEVER AN EXERCISE SHOWS A SECTOR TO BE FAILING SOLIDLY,        * 08700020
*   THE SPECIFIC SECTOR IS DELETED FROM USE.  OTHERWISE, THE SECTOR   * 08800020
*   STATUS IS NOT CHANGED.                                            * 08900020
*                                                                     * 09000020
*EXITS NORMAL  TO MCHNUC WITH IGFMCH17 AS SUCCESSOR IF THE ORIGINAL     09100020
*   MCI WAS SOFT, OR WITH IGFMCHF1-F3 AS SUCCESSOR IF THE ORGINAL       09200020
*   MCI WAS HARD                                                        09300020
*                                                                     * 09400020
*       ABNORMAL  TO THE EMERGENCY HANDLER (SHUT) IN THE RMS/85 NUC.  * 09500020
*                                                                     * 09600020
*ERROR CONDITIONS  UNEXPECTED PROGRAM CHECKS OR COMPLEX MCI           * 09700020
*   SEQUENCES NOT EXPECTED.                                           * 09800020
*                                                                     * 09900020
*********************************************************************** 10000020
         SPACE 2                                                        10100020
         EJECT                                                          10200020
IGFMCH16 CSECT                                                          10300020
REG0     EQU   0                        GENERAL PURPOSE REGISTER ZERO   10400020
IDREG    EQU   1                                                        10500020
WORK     EQU   1                                                        10600020
CTR      EQU   2                        HOLDS A COUNT FOR A ROUTINE     10800020
KEY      EQU   2                                                        10900020
ADBYTE   EQU   3                                                        11000020
DATA     EQU   3                        HOLDS DATA FOR A ROUTINE        11100020
ADDR     EQU   4                        ADDRESS REG FOR ROUTINES        11200020
NUM      EQU   5                                                        11300020
ADREPORT EQU   6                       REPORT AREA ADDRESS              11400020
LINK     EQU   7                                                        11500020
LOG      EQU   8                        BASE FOR TESTING SAVED LOGOUT   11600020
SADR     EQU   9                        ADDR. OR DISPLACEMENT REG       11700020
MSBREG   EQU   10                      MSB BASE REG                     11850020
COMREG   EQU   11                    INDEPENDENT COMMON AREA BASE REG   11920020
BASEREG  EQU   12                       MODULE BASE REG                 12000020
DEPREG   EQU   13                      DEPENDENT COMMON AREA BASE REG   12100020
RETURN   EQU   14                       LINKING REG TO SUBROUTINES      12200020
BACK     EQU   15                       LINKING REG TO SUBROUTINES      12300020
CODE1    EQU   1                        BUFFER IN KEY ERROR CODE        12400020
CODE2    EQU   2                        BLOCK VALID ERROR CODE          12500020
CODE3    EQU   3                        SECTOR COMPARE ERROR CODE       12600020
CODE4    EQU   4                        MULTIPLE COMPARE ERROR CODE     12700020
CODE5    EQU   5                        SECTOR KEY ERROR CODE           12800020
CODE6    EQU   6                        MARK ERROR CODE                 12900020
CODE7    EQU   7                        BUFFER ADDRESS BUS ERROR CODE   13000020
CODE8    EQU   8                        BUFFER DATA BUS OUT ERROR CODE  13100020
BYTE1    EQU   9                                                        13200020
BYTE2    EQU   10                                                       13300020
BYTE3    EQU   13                                                       13400020
BYTE4    EQU   14                                                       13500020
BYTE5    EQU   7                                                        13600020
BYTE6    EQU   5                                                        13700020
BYTE7    EQU   6                                                        13800020
BYTE8    EQU   11                                                       13900020
         EJECT                                                          14000020
*                                       PROCESSING STATE IN PSW         14100020
FETCH3   EQU   25                       NUMBER OF FETCHES IN EXERCISE   14200020
MCNEWPSW EQU   112                      MACHINE CHECK NEW PSW           14300020
MCOLDPSW EQU   48                       MACHINE CHECK OLD PSW           14400020
K0       EQU   0                        DECIMAL VALUE 0                 14500020
K1       EQU   1                        DECIMAL VALUE 1                 14600020
K2       EQU   2                        DECIMAL VALUE 2                 14700020
K3       EQU   3                        DECIMAL VALUE 3                 14800020
K4       EQU   4                        DECIMAL VALUE 4                 14900020
K6       EQU   6                        DECIMAL VALUE 6                 15000020
K7       EQU   7                        DECIMAL VALUE 7                 15100020
K8       EQU   8                        DECIMAL VALUE 8                 15200020
K10      EQU   10                       DECIMAL VALUE 10                15300020
K11      EQU   11                       DECIMAL VALUE 11                15400020
K15      EQU   15                       DECIMAL VALUE 15                15500020
K16      EQU   16                       DECIMAL VALUE 16                15600020
K23      EQU   23                       DECIMAL VALUE 23                15700020
K24      EQU   24                       DECIMAL VALUE 24                15800020
K31      EQU   31                       DECIMAL VALUE 31                15900020
K40      EQU   40                       DECIMAL VALUE 40                16000020
K128     EQU   128                      DECIMAL VALUE 128               16100020
K256     EQU   256                      DECIMAL VALUE 256               16200020
K896     EQU   896                      DECIMAL VALUE 896               16300020
K1020    EQU   1020                     DECIMAL VALUE 1020              16400020
K1024    EQU   1024                     DECIMAL VALUE 1024              16500020
K2048    EQU   2048                     DECIMAL VALUE 2048              16600020
X00      EQU   X'00'                    HEXADECIMAL VALUE               16700020
X02      EQU   X'02'                    HEXADECIMAL VALUE               16800020
X04      EQU   X'04'                    HEXADECIMAL VALUE               16900020
X09      EQU   X'09'                    HEXADECIMAL VALUE               17000020
X0C      EQU   X'0C'                    HEXADECIMAL VALUE               17100020
X10      EQU   X'10'                    HEXADECIMAL VALUE               17200020
X20      EQU   X'20'                    HEXADECIMAL VALUE               17300020
X40      EQU   X'40'                    HEXADECIMAL VALUE               17400020
X45      EQU   X'45'                    HEXADECIMAL VALUE               17500020
X7F      EQU   X'7F'                    HEXADECIMAL VALUE               17600020
X80      EQU   X'80'                    HEXADECIMAL VALUE               17700020
XBB      EQU   X'BB'                    HEXADECIMAL VALUE               17800020
XBF      EQU   X'BF'                    HEXADECIMAL VALUE               17900020
XF0      EQU   X'F0'                    HEXADECIMAL VALUE               18000020
XFF      EQU   X'FF'                    HEXADECIMAL VALUE               18100020
X3A0     EQU   X'3A0'                   HEXADECIMAL VALUE               18200020
         EJECT                                                          18300020
STATCODE EQU   X'0A'          REQUEST CODE FOR 41I MSG              IO  18400020
NOTNEG   EQU   11                                                       18500020
DSBLFLAG EQU   X'80'                    BUFFER HAS BEEN DISABLED FLAG   18600020
DLTEFLAG EQU   X'40'                    SECTOR HAS BEEN DELETED FLAG    18700020
DSBLBUFR EQU   X'40'                    BIT IN MCW TO DISABLE BUFFER    18800020
ERRSTAT  EQU   X'20'                    INDICATOR FOR STATUS ERROR      18900020
QUIT1    EQU   X'01'                    QUIT SWITCH ONE                 19000020
QUIT2    EQU   X'02'                    QUIT SWITCH TWO                 19100020
BYPGATE  EQU   X'40'                                                    19200020
BUFRLOG  EQU   X'3A0'                   ADDRESS OF BUFR ERROR INDICATRS 19300020
LOWCORE  EQU   X'650'                   BASE REG SAVE AREA IN LOW CORE  19400020
LOWCORE1 EQU   X'658'                   LOW CORE ADDRESS                19500020
*                                       TO A PARTICULAR BUFFER ROUTINE. 19600020
*                                       TO A PARTICULAR BUFFER ROUTINE. 19700020
ALL      EQU   X'FF'                    BYTE WITH ALL BITS ON           19800020
SYSALTER EQU   X'80'                    INTERFACE BIT TO 'SHUT' RTN.    19900020
LEVEL    EQU   X'&LEV'                                                  19950021
NEXT50   EQU   X'01'          ID FOR IGFMCHF1(PDAR)                 IO  20000020
NEXT51   EQU   X'02'          ID FOR IGFMCH17(ERROR RECORDER)       IO  20050020
         EJECT                                                          20100020
*********************************************************************** 20200020
*                                                                     * 20300020
*        THE FOLLOWING ARE BIT POSITION DEFINITIONS FOR THE BUFFER    * 20400020
*    CHECKS.  THE ADDRESS FOR THE BYTE IN THE LOGOUT CONTAINING       * 20500020
*    THE CHECK INFORMATION IS DEFINED WITH ANOTHER EQUATE STATEMENT.  * 20600020
*                                                                     * 20700020
*********************************************************************** 20800020
BIKCHECK EQU   X'04'                    BUFFER IN KEY CHECK             20900020
MCCHECK  EQU   X'08'                    MULTIPLE SECTOR COMPARE CHECK   21000020
CCHECK   EQU   X'10'                    SECTOR COMPARE CHECK            21100020
BVCHECK  EQU   X'08'                    BLOCK VALID CHECK               21200020
SKCHECK  EQU   X'04'                    SECTOR KEY CHECK                21300020
BABCHECK EQU   X'80'                    BUFFER ADDRESS BUS CHECK        21400020
BMCHECK  EQU   X'80'                    BUFFER MARK CHECK               21500020
BDBOCHK1 EQU   X'3C'                    BDBO CHECK BITS IN LOGOUT       21600020
BDBOCHK2 EQU   X'F0'                    BDBO CHECK BITS IN LOGOUT       21700020
MSGLEN1  EQU   10                       LENGTH OF MSG1 AND CODES        21800020
*                                       BUS LATCH BITS 0,1,2,3          21900020
         EJECT                                                          22000020
         USING *,BASEREG                                                22100020
         USING   RMSMSB,MSBREG         MSB BASE                         22150020
         USING MCHCOM,COMREG                                            22200020
         USING ASRCOM,DEPREG                                            22250020
         LR    IDREG,BASEREG            SAVE CONTENTS OF GPR            22300020
         LR    BASEREG,BACK             SET UP MODULE BASE FROM ENTRY   22400020
         MVI   MCHEXLEV,LEVEL           MODULE CHANGE LEVEL         IO  23000020
         STM   CTR,REG0,SAVE            SAVE REGS AT ENTRY              23600020
         ST    IDREG,SAVE+K40           SAVED REG TO SAVE AREA          23700020
         L     MSBREG,MCHMSB           ESTABLISH BASE                   23750020
         TM    RESMCW+K4,X40           WAS BUFFER ORIGINALLY DISABLED   23800020
         BO    STATERR                  YES - GO SET STATUS ERROR       23900020
         MVC   NUCEMERG(K8),MCNEWPSW    SAVE MC NEW PSW OF NUCLEUS      24000020
         LA    WORK,MCHNDLR0            GET ADDRESS OF MCI HANDLER      24100020
         ST    WORK,BUFMCPSW+K4         PUT ADDRESS INTO NEW PSW AREA   24200020
         LA    WORK,MCHNDLR1            SET UP ENABLING PSW TO GO TO    24300020
         ST    WORK,ENABLPSW+K4         INSTRUCTION FOLLOWING LPSW      24400020
         LA    ADDR,MCHND2ND            GET ADDR OF 2ND MCI HANDLER     24500020
         ST    ADDR,AD2NDMCH            SAVE ADDRESS IN MY AREA         24600020
         MVC   DLTEMCW(K8),RESMCW       GET COPY OF SYSTEM MCW          24700020
         OI    DLTEMCW+K4,X45           SET BUFR DSBL, HIR,ECC CNT BITS 24800020
         MVC   EXITMCW(K8),DLTEMCW      COPY MCW                        24900020
         NI    EXITMCW+K4,XBF           CLEAR BUFFER DISABLED BIT       25000020
         OI    DLTEMCW+K2,X0C           DEFEAT I/E OVERLAP AND          25100020
*                                       DISABLE INTERVAL TIMER.         25200020
         MVC   ENBLMCW(K8),DLTEMCW      SAME COPY TO ENABLE MCW FIELD   25300020
         NI    ENBLMCW+K4,XBB           HIR CNT MODE, BUFR DSBL CLEARED 25400020
         MVC   DSBLMCW(K8),DLTEMCW      SET UP MCW IN DISABLE MCW FIELD 25500020
         MVC   ADDMCW(K8),DLTEMCW       SET UP MCW TO ADD ALL PAGES     25600020
         OI    ADDMCW+K3,X40            SET ADD ALL PAGES BIT           25700020
         LA    ADREPORT,REBUFREP        SET UP ADDRESS FOR REPORTING    25800020
         MVC   LOWCORE1(K8),DSBLMCW     DISABLE MCW TO ZERO BASE AREA   25900020
         ST    BASEREG,LOWCORE          MY BASE TO LOW CORE ALSO        26000020
         XC    ERRORCNT(K4),ERRORCNT    INIT. ERROR COUNTER             26100020
         LA    BACK,CHEKSAME            INITIALIZE BRANCH REG           26200020
         LA    LOG,RECPULOG-K128+K24+X3A0 GET ADDRESS OF QUADWORD WHICH 26300020
*                                       HAS THE BUFFER ERROR INDICATORS 26400020
*                                                                     * 26500020
*   NOTE - IN REAL LOGOUT IN LOW CORE, 3A0 IN HEX IS THE ADDRESS OF   * 26600020
*   QUADWORD HAVING THE INDICATORS.  RECPULOG CONTAINS IN ITS FIRST   * 26700020
*   BYTE THE BYTE OF DATA THAT WAS AT 128 DECIMAL (BEGINNING OF M85   * 26800020
*   DEPENDENT DATA).  ALSO THERE IS A 24 DECIMAL BYTE HOLE LEFT IN    * 26900020
*   THE RECPULOG AREA IN THE MIDDLE OF THE SAVED LOGOUT, SO THIS      * 27000020
*   QUADWORD IS 24 BYTES HIGHER THAN THE NATURAL DISPLACEMENT FROM    * 27100020
*   THE FIRST BYTE OF THE SAVED LOGOUT.                               * 27200020
*                                                                     * 27300020
         EJECT                                                          27400020
DETERM   EQU   *                                                        27500020
         TM    BYTE3(LOG),SKCHECK       SECTOR KEY CHECK                27600020
         BO    SECTRKEY                 YES                             27700020
         TM    BYTE3(LOG),CCHECK        COMPARE CHECK                   27800020
         BO    COMPARE                  YES                             27900020
         TM    BYTE1(LOG),BVCHECK       BLOCK VALID CHECK               28000020
         BO    BLKVALID                 YES                             28100020
         TM    BYTE2(LOG),BDBOCHK1      BDBO CHECK                      28200020
         BNZ   BDBO                     YES, BDBO CHECK INDICATED       28300020
         TM    BYTE8(LOG),BDBOCHK2      BDBO CHECK                      28400020
         BNZ   BDBO                     YES, BDBO CHECK INDICATED       28500020
         EJECT                                                          28600020
         TM    BYTE1(LOG),BIKCHECK      BUFFER IN KEY CHECK             28700020
         BO    BUFINKEY                 YES                             28800020
         TM    BYTE3(LOG),MCCHECK       MULTIPLE COMPARE CHECK          28900020
         BO    MULTCOMP                 YES                             29000020
         TM    BYTE4(LOG),BABCHECK      BUFFER ADDRESS BUS CHECK        29100020
         BO    BUFADBUS                 YES                             29200020
         TM    BYTE2(LOG),BMCHECK       BUFFER MARK CHECK               29300020
         BO    MARK                     YES                             29400020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       29500020
         B     EXIT                     PREPARE TO EXIT TO NUC          29600020
         SPACE 2                                                        29700020
BUFINKEY EQU   *                                                        29800020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       29900020
         MVI   REBUFREP,CODE1           MOVE ERROR TYPE TO REPORT AREA  30000020
         B     GENERAL                  GO TO GENERAL BUFR ERR RTN.     30100020
         SPACE                                                          30200020
MULTCOMP EQU   *                                                        30300020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       30400020
         MVI   REBUFREP,CODE4           MOVE ERROR TYPE TO REPORT AREA  30500020
         B     GENERAL                  GO TO GENERAL BUFR ERR RTN.     30600020
         SPACE                                                          30700020
BUFADBUS EQU   *                                                        30800020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       30900020
         MVI   REBUFREP,CODE7           MOVE ERROR TYPE TO REPORT AREA  31000020
         B     GENERAL                  GO TO GENERAL BUFR ERR RTN.     31100020
         SPACE                                                          31200020
MARK     EQU   *                                                        31300020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       31400020
         MVI   REBUFREP,CODE6           MOVE ERROR TYPE TO REPORT AREA  31500020
         EJECT                                                          31600020
*        SINCE IT IS NOT ONE OF THE ABOVE ERROR TYPES, IT FALLS INTO  * 31700020
*   NON-SECTOR ASSOCIATED ERROR CLASS.  ERRORS IN THIS CLASS CAN ONLY * 31800020
*   BE PREVENTED BY DISABLING THE BUFFER IN ENTIRETY.                 * 31900020
         SPACE 2                                                        32000020
GENERAL  EQU   *                                                        32100020
         LH    CTR,RECHKCNT             GET COUNT OF NUMBER OF MCI DUE  32200020
*                                       TO NON-SECTOR ASSOCIATED ERRORS 32300020
         LA    CTR,K1(CTR)              INCREMENT TO REFLECT THIS MCI   32400020
         STH   CTR,RECHKCNT             UPDATED COUNT TO COMMON AREA    32500020
         CH    CTR,BUFRCRIT             COMPARE THE NUMBER OF MCI TO    32600020
*                                       CRITERIUM VALUE FOR NON-SECTOR  32700020
*                                       ASSOCIATED CHECKS.              32800020
         BNH   EXIT                     NO COMPARE                      32900020
         OI    REBUFREP+K1,DSBLFLAG     TURN ON BUFFER DISABLE FLAG     33000020
         OI    RESMCW+K4,DSBLBUFR       TURN ON BIT TO DISABLE BUFFER   33100020
         XC    RECHKCNT(K2),RECHKCNT    CLR BUF ERR CNT                 33200020
         OI    COMINTEL,X02             SET STAT CHNGE                  33300020
         B     EXIT                     FINI                            33400020
***                                                                 *** 33500020
*        SINCE THE RMS NUCLEUS HAD ORIGINALLY DISABLED THE BUFFER     * 33600020
*   UPON DETECTING THIS WAS A BUFFER ERROR, THIS MODULE WILL NOW      * 33700020
*   ALLOW RMS TO CONTINUE WITH THE BUFFER DISABLED.                   * 33800020
***                                                                 *** 33900020
         EJECT                                                          34000020
*********************************************************************** 34100020
*                                                                     * 34200020
*              SECTOR KEY CHECK - THIS SECTION CAUSES DIFFERENT       * 34300020
*        KEY PATTERNS TO BE BROUGHT INTO THE FAILING SECTOR KEY       * 34400020
*        REG AND PARITY CHECKED DURING USE OF THE BUFFER.  ANY        * 34500020
*        FAILURES ARE REPORTED IN REBUFREP.                           * 34600020
*        NOTE - BECAUSE OF THE EXERCISING ROUTINES BEING BASED ON     * 34700020
*        BOUNDARIES OF 1024 AND 2048 BYTES, THIS SECTION MUST BE      * 34800020
*        WITHIN THE FIRST 1024 BYTES OF THE MODULE BASE REG           * 34900020
*                                                                     * 35000020
*********************************************************************** 35100020
SECTRKEY EQU   *                                                        35200020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       35300020
         MVI   REBUFREP,CODE5           MOVE ERROR TYPE TO REPORT AREA  35400020
         BAL   LINK,SECTSTAT            GO TO GET FAILING SECTOR NO.    35500020
         LR    ADBYTE,BASEREG           GET ADDRESS OF THIS MODULE      35600020
         SRL   ADBYTE,K11               ROUND ADDRESS TO                35700020
         SLL   ADBYTE,K11               2048 BYTE BOUNDARY              35800020
         ST    ADBYTE,SAVEADDR          SAVE ADDRESS                    35900020
         ISK   KEY,ADBYTE               GET KEY OF 2K BLOCK             36000020
         STC   KEY,SAVKEY1              SAVE KEY FOR LATER RESTORE      36100020
         LA    SADR,K2048(ADBYTE)       COMPUTE NEXT 2K BLOCK ADDRESS   36200020
         ISK   KEY,SADR                 GET KEY OF 2K BLOCK             36300020
         STC   KEY,SAVKEY2              SAVE KEY FOR LATER RESTORE      36400020
         LA    KEY,XF0                  GET KEY OF F FOR SSK INSTR      36500020
         LA    WORK,NSI1                SETUP PSW FOR CHANGING CURRENT  36600020
         ST    WORK,TESTPSW+K4           PSW KEY.                       36700020
         LA    WORK,NSI2                SETUP PSW WHICH RE-ESTABLISHES  36800020
         ST    WORK,PSWKEY0+K4           A CURRENT PSW KEY OF ZERO.     36900020
         LA    ADDR,I1                  GET ADDRESS OF TEST STREAM      37000020
         SRL   ADDR,K10                 ROUND ADDRESS TO                37100020
         SLL   ADDR,K10                 1024 BYTE BOUNDARY              37200020
         LA    BACK,REPORT05            SET UP REPORT RTN'S ADDRESS     37300020
         OI    COMINTEL,SYSALTER        SET 'SYSTEM ALTERED' FLAG       37400020
         MVC   MCNEWPSW(K8),BUFMCPSW    SETUP TO HANDLE MCI             37500020
MORPATRN EQU   *                                                        37600020
         STC   KEY,TESTPSW+K1           TEST KEY TO PSW                 37700020
         OI    TESTPSW+K1,X04           TURN ON BIT TO ALLOW MCI        37800020
         SSK   KEY,ADBYTE               CHANGE STORAGE KEY              37900020
         SSK   KEY,SADR                 CHANGE STORAGE KEY              38000020
         LPSW  TESTPSW                  CURRENT PSW TO MATCH STORAGE    38100020
         EJECT                                                          38200020
NSI1     EQU   *                                                        38300020
         DC    X'8300'                  DIAGNOSE TO ENABLE              38400020
         DC    S(ENBLMCW)               BUFFER AND GO INTO RECORDING    38500020
*                                                                     * 38600020
*              THE FOLLOWING INSTRUCTIONS CAUSE KEY EXERCISE BY       * 38700020
*        CAUSING FETCHES FOR THE INSTRUCTION STREAM AND OPERANDS.     * 38800020
*        SECTOR KEY PARITY CHECKING WILL OCCUR WHENEVER A SECTOR      * 38900020
*        COMPARE PROVES AFFIRMATIVE, I.E. AT LEAST ONE PREVIOUS       * 39000020
*        REFERENCE TO THE SAME 1K AREA WAS MADE CAUSING THAT SECTOR   * 39100020
*        TO BE ASSIGNED TO THAT 1K BLOCK.                             * 39200020
*                                                                     * 39300020
I1       EQU   *                                                        39400020
         CLC   K896(K256,ADDR),K896(ADDR) CAUSE SECTOR KEY CHECKING     39500020
         LPSW  PSWKEY0                  CURRENT PSW KEY BACK TO ZERO    39600020
NSI2     EQU   *                                                        39700020
MOREXER  EQU   *                                                        39800020
         SH    KEY,SIXTEEN              DECREMENT KEY PATTERN BY ONE    39900020
         BP    MORPATRN                 ALL KEY PATTERNS TESTED IF ZERO 40000020
         DC    X'8300'                  DIAGNOSE TO DISABLE BUFFER AND  40100020
         DC    S(LOWCORE1)              GO BACK TO COUNT MODES          40200020
         MVC   MCNEWPSW(K8),NUCEMERG    RESTORE MCNEWPSW OF RMS/NUC     40300020
         L     ADBYTE,SAVEADDR          GET SAVED ADDRESS               40400020
         LA    SADR,K2048(ADBYTE)       COMPUTE NEXT 2K BLOCK ADDRESS   40500020
         IC    KEY,SAVKEY1              GET SAVED KEY VALUE             40600020
         SSK   KEY,ADBYTE               RESTORE STORAGE KEY             40700020
         IC    KEY,SAVKEY2              GET SAVED KEY VALUE             40800020
         SSK   KEY,SADR                 RESTORE STORAGE KEY             40900020
         NI    COMINTEL,ALL-SYSALTER    CLEAR 'SYSTEM ALTERED' FLAG     41000020
ERRCHECK EQU   *                                                        41100020
         CLI   K8(ADREPORT),X00         ANY ENTRIES                     41200020
         BE    CLEAR                    NO - SECTOR IS OK               41300020
         B     DLTEEXIT                 SET DELETE AND GO TO EXIT       41400020
REPORT05 EQU   *                                                        41500020
         B     ERRCHECK                 GO TO TEST EXERCISE REPORT      41600020
         MVC   MCNEWPSW(K8),BUFMCPSW    SETUP TO HANDLE MCI             41700020
         CH    WORK,SAVNUMBR            WAS MCI ON SAME SECTOR          41800020
         BNE   MOREXER                  NO                              41900020
         STC   KEY,K8(ADREPORT)         REPORT FAILING KEY              42000020
         LA    ADREPORT,K1(ADREPORT)    INCREMENT PTR TO REPORT AREA    42100020
         B     MOREXER                  CONTINUE EXERCISING             42200020
         EJECT                                                          42300020
*********************************************************************** 42400020
*                                                                     * 42500020
*              BUFFER DATA BUS OUT CHECK - THIS SECTION FIRST CAUSES  * 42600020
*        THE BUFFER TO BE RESET SO THAT IF BAD PARITY IS NOW IN THE   * 42700020
*        BUFFER IT CANNOT BE REFERENCED.  A CHECK IS THEN MADE TO SEE * 42800020
*        IF THE BAD PARITY DETECTED CAME FROM THE BUFFER OR FROM      * 42900020
*        MAIN STORAGE.                                                * 43000020
*              IF THE CHECK WAS CAUSED BY DATA COMING FROM THE BUFFER * 43100020
*        A COUNT OF THE NUMBER OF CHECKS OF THIS TYPE IS INCREMENTED. * 43200020
*        IF THE COUNT EXCEEDS A CRITERIUM VALUE, THEN A SUFFICIENT    * 43300020
*        NUMBER OF CHECKS HAVE OCCURRED FOR PREVENTIVE ACTION TO BE   * 43400020
*        NECESSARY.  WHEN ACTION IS REQUIRED THE SECTOR CAUSING THE   * 43500020
*        CHECK IS DELETED.                                            * 43600020
*                                                                     * 43700020
*********************************************************************** 43800020
BDBO     EQU   *                                                        43900020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       44000020
         MVI   REBUFREP,CODE8           MOVE ERROR TYPE TO REPORT AREA  44100020
         TM    LOGBYTE5,BYPGATE         IS BUFFER BYPASS GATE ON        44200020
         BO    EXIT                     YES, ERROR FROM MAIN STORAGE    44300020
         LH    CTR,RECHKCNT+K2          GET COUNT OF NUMBER OF MCI DUE  44400020
         LA    CTR,K1(CTR)              INCREMENT TO REFLECT THIS MCI   44500020
         STH   CTR,RECHKCNT+K2          UPDATED COUNT TO COMMON AREA    44600020
         CH    CTR,BDBOCRIT             COMPARE THE NUMBER OF MCI TO    44700020
*                                       CRITERIUM VALUE FOR BDBO CHECKS 44800020
         BNL   EXIT                     CRITERIUM NOT MET, NO EXERCISE  44900020
         BAL   LINK,SECTSTAT            GO GET FAILING SECTOR SET UP    45000020
         LA    BACK,REPORT08            SET UP REPORT RTN'S ADDRESS     45100020
         LA    ADDR,INIT1               GET ADDRESS OF EXERCISE CODE    45200020
         SRL   ADDR,K10                 COMPUTE LOWER                   45300020
         SLL   ADDR,K10                 1K ADDRESS                      45400020
         LR    WORK,ADDR                SAVE ADDRESS                    45500020
         DC    X'8300'                  DIAG INSTR                      45600020
         DC    S(ENBLMCW)               BUFFER AND GO INTO RECORDING    45700020
INIT1    EQU   *                                                        45800020
         LA    NUM,K3                   GET NUMBER OF TIMES THRU LOOP   45900020
INIT2    EQU   *                                                        46000020
         LR    ADDR,WORK                RESTORE ADDRESS                 46100020
         LA   CTR,K4                    GET MVC LOOP COUNT              46200020
LOOP     EQU   *                                                        46300020
         CLC   K0(K256,ADDR),K0(ADDR)   REFERENCE 256 BYTES OF 1K BLOCK 46400020
         LA    ADDR,K256(ADDR)          BUMP ADDRESS                    46500020
         BCT   CTR,LOOP                 REFERENCE WHOLE 1K OF SECTOR    46600020
         BCT   NUM,INIT2                RE-REFERENCE SECTOR             46700020
         TM    SWITCH,X40              IS THIS FIRST/SECOND PASS        46800020
         BO    BOTHDONE                 2ND - BOTH PASSES FINISHED      46900020
         OI    SWITCH,X40               SET 2ND PASS SWITCH             47000020
         MVC   LOGSAVE(K8),K1020        FORCE INSTR. STREAM TO ASSIGN   47100020
*                                       TO OTHER SECTOR IF 24K/32K      47200020
         B     INIT1                    INITIALIZE FOR 2ND PASS         47300020
*                                                                     * 47400020
*   TWO PASSES WERE NEEDED IN CASE THERE WAS A 24K OR 32K SIZE BUFFER * 47500020
*                                                                     * 47600020
BOTHDONE EQU   *                                                        47700020
         DC    X'8300'                  DIAGNOSE TO DISABLE             47800020
         DC    S(DSBLMCW)               BUFFER AND GO TO CTR MODE       47900020
CLEAR    EQU   *                                                        48000020
         XC    SAVBIT(K4),SAVBIT        CLEAR FAILING SEC BIT FIELD     48100020
         B     TESTALL                  RESTORE SECTOR STATUS           48200020
REPORT08 EQU   *                                                        48300020
         B     EXIT                     GO TO TERMINATION               48400020
         XC    RECHKCNT+K2(K2),RECHKCNT+K2   CLR SECT ERR CNT           48500020
         B     DLTEEXIT                 SET DELETE AND GO TO EXIT       48600020
         EJECT                                                          48700020
*********************************************************************** 48800020
*                                                                     * 48900020
         SPACE                                                          49000020
SECTSTAT EQU   *                                                        49100020
         LA    ADDR,LOGBYTE7            GET LOGOUT DATA ADDRESS FOR RTN 49200020
         BAL   RETURN,GETNUMBR          GO GET FAILING SECTOR NUMBER    49300020
         STH   WORK,SAVNUMBR            SAVE SECTOR NUMBER              49400020
         BAL   RETURN,GETBIT            GO SETUP POSITIONED BIT         49500020
         ST    DATA,SAVBIT              SAVE POSITIONED BIT             49600020
         N     DATA,RESECT              COMPARE AGAINST SECTOR STATUS   49700020
*                                       LAST SET BY RMS.                49800020
         BNZ   STATERR                  ERROR-RMS HAD IT DELETED        49900020
         BAL   RETURN,GETSIZE           GO TO DETERMINE BUFFER SIZE     50000020
         CLC   SIZE(K1),SAVNUMBR+K1    IS FAILING SECTOR NUMBER VALID   50100020
         BL    STATERR                  NO, NUMBER EXCEEDS POSSIBILITY  50200020
         NI    SWITCH,X7F               CLEAR FLAG FOR ISOLATE RTN.     50300020
         OI    COMINTEL,SYSALTER        SET 'SYSTEM ALTERED' FLAG       50400020
         DC    X'8300'                  DIAGNOSE TO                     50500020
         DC    S(ADDMCW)                 ADD ALL SECTORS                50600020
         CLC   SAVNUMBR(K2),SIXTEEN     FAILING SECTOR NUMBER IN 1ST 16 50700020
         BL    FIRST16                  YES                             50800020
         MVC   FIELD+K2(K2),RESECT      GET THE SECTOR STATUS OF SECTOR 50900020
         L     DATA,FIELD               00-15 INTO REGISTER             51000020
         MVI   DLTEMCW+K3,X20           SET 00-15 DELETION BIT IN MCW   51100020
         BAL   RETURN,ISOLATE           GO TO DELETE ALL SECTORS IN     51200020
*                                        THE 1ST 16 EXCEPT ONE GOOD ONE 51300020
         SPACE                                                          51400020
         L     DATA,SAVBIT              GET FAILING SECTOR IN BIT POS.  51500020
         X     DATA,FOXES               INVERT BITS IN REGISTER         51600020
         MVI   DLTEMCW+K3,X10           SET 16-31 DELETION BIT IN MCW   51700020
         BAL   RETURN,ISOLATE           GO TO DELETE ALL SECTORS IN     51800020
*                                        THE LAST 16 EXCEPT FAILING ONE 51900020
         BR    LINK                     RETURN VIA LINK REG             52000020
         EJECT                                                          52100020
FIRST16  EQU   *                                                        52200020
         MVC   FIELD+K2(K2),RESECT+K2   GET SECT STAT OF SECTS          52300020
         L     DATA,FIELD               16-31 INTO REGISTER             52400020
         MVI   DLTEMCW+K3,X10           SET 16-31 DELETION BIT IN MCW   52500020
         BAL   RETURN,ISOLATE           GO TO DELETE ALL SECTORS IN     52600020
*                                        THE LAST 16 EXCEPT ONE GOODONE 52700020
         L     DATA,SAVBIT              GET FAILING SECTOR IN BIT POS.  52800020
         SRL   DATA,K16                 MOVE LOW ORDER HALF OF REG      52900020
         X     DATA,FOXES               INVERT BITS IN REGISTER         53000020
         MVI   DLTEMCW+K3,X20           SET 00-15 DELETION BIT IN MCW   53100020
         BAL   RETURN,ISOLATE           GO TO DELETE ALL SECTORS IN     53200020
*                                        THE 1ST 16 EXCEPT FAILING ONE  53300020
         BR    LINK                     RETURN VIA LINK REG             53400020
         SPACE                                                          53500020
GETSIZE  EQU   *                                                        53600020
         TM    LOGBYTE7,X40             IS BUFFER 32K                   53700020
         BO    SIZE32                   YES                             53800020
         TM    LOGBYTE7,X80             IS BUFFER 24K                   53900020
         BO    SIZE24                   YES                             54000020
         TM    LOGBYTE6,X04             IS BUFFER 16K                   54100020
         BNO   STATERR                  NO-ERROR-AT LEAST ONE MUST BE.  54200020
         MVI   SIZE,K15                 RECORD ACTUAL HIGHEST SECTOR    54300020
         BR    RETURN                   RETURN TO CALLER                54400020
SIZE32   EQU   *                                                        54500020
         MVI   SIZE,K31                 RECORD ACTUAL HIGHEST SECTOR    54600020
         BR    RETURN                   RETURN TO CALLER                54700020
SIZE24   EQU   *                                                        54800020
         MVI   SIZE,K23                 RECORD ACTUAL HIGHEST SECTOR    54900020
         BR    RETURN                   RETURN TO CALLER                55000020
         EJECT                                                          55100020
GETNUMBR EQU   *                                                        55200020
         SR    WORK,WORK                CLEAR FOR SECTOR NO. ASSEMBLY   55300020
         IC    WORK,K0(ADDR)            GET THE LOG BYTE CONTAINING 4   55400020
*                                        OF THE 5 BITS DEFINING NUMBER. 55500020
         SLL   WORK,K6                  POSITION THOSE 4 BITS TO LOW    55600020
*                                        ORDER BITS OF ADJACENT BYTE.   55700020
         IC    WORK,K1(ADDR)            GET THE LOG BYTE CONTAINING THE 55800020
*                                        OTHER BIT OF THE SECTOR NO.    55900020
         SRL   WORK,K7                  POSITION TO BITS 24-31 FOR USE  56000020
         N     WORK,CLEARBIT            CLEAR EXTRANEOUS BITS           56100020
         BR    RETURN                   RETURN TO CALLER                56200020
         SPACE                                                          56300020
GETBIT   EQU   *                                                        56400020
         L     DATA,HIGHBIT             GET WORD WITH ONLY H.O. BIT ON  56500020
         LTR   WORK,WORK                                                56600020
         BZ    GETBIT2                  DONE, NO SHIFTING NEEDED        56700020
GETBIT1  EQU   *                                                        56800020
         SRL   DATA,K1                  SHIFT BIT ONE POSITION RIGHT    56900020
         BCT   WORK,GETBIT1             SHIFT ACCORDING TO SECTOR NO.   57000020
GETBIT2  EQU   *                                                        57100020
         BR    RETURN                   RETURN TO CALLER                57200020
         SPACE 2                                                        57300020
         EJECT                                                          57400020
*********************************************************************** 57500020
*                                                                     * 57600020
*        THIS ROUTINE IS USED TO DELETE ANY NUMBER OF SECTORS OF      * 57700020
*   SIXTEEN IN THE HIGH-SPEED BUFFER.  THE DELETION MCW MUST BE SET   * 57800020
*   UP PREVIOUSLY TO ADDRESS THE CORRECT GROUP OF 16 SECTORS.  INPUT  * 57900020
*   IS THE GPR 'DATA' WHICH MUST CONTAIN THE STATUS OF THE SIXTEEN    * 58000020
*   SECTORS IN THE LOW ORDER 16 BITS.  THE RIGHT MOST BIT ON IN THE   * 58100020
*   GPR MEANS SECTOR NUMBER 15 MODULO 16 SHOULD BE DELETED.  ALSO     * 58200020
*   INPUT IS THE HIGH ORDER BIT OF A FLAG BYTE 'SWITCH'. IF OFF,      * 58300020
*   ONLY THE FIRST GOOD SECTOR ENCOUNTERED WILL NOT BE DELETED.  IF   * 58400020
*   ON, ALL GOOD SECTORS WILL BE EXEMPT FROM DELETION.                * 58500020
*                                                                     * 58600020
*********************************************************************** 58700020
         SPACE                                                          58800020
ISOLATE  EQU   *                                                        58900020
         LA    ADDR,ISOLATE1            SETUP LOOP BRANCH REG           59000020
         LA    CTR,K15                  INITIALIZE SECTOR NO. MODULO 16 59100020
         LA    REG0,K1       GET INSPECTION BIT AND SAVE                59200020
ISOLATE1 EQU   *                                                        59300020
         LR    WORK,REG0               GET INSPECTION BIT               59400020
         NR    WORK,DATA               IS THIS SECTOR A GOOD ONE        59500020
         SRL   DATA,K1                  SHIFT FOR NEXT INSPECTION       59600020
         BZ    ISOLATE4                 YES, LEAVE IT ACTIVE            59700020
ISOLATE2 EQU   *                                                        59800020
         NI    DLTEMCW+K3,XF0           CLEAR SECTOR NO. FIELD IN MCW   59900020
         EX    CTR,ORER                 SECTOR NO. MODULO 16 INTO MCW   60000020
         DC    X'8300'                  DIAGNOSE TO DELETE              60100020
         DC    S(DLTEMCW)                THE SPECIFIED SECTOR.          60200020
ISOLATE3 EQU   *                                                        60300020
         BCTR  CTR,K0                   SUBTRACT 1 FROM SECTOR NUMBER   60400020
         LTR   CTR,CTR                  IS IT NEGATIVE                  60500020
         BCR   NOTNEG,ADDR              IF NOT, CONTINUE VIA LOOP REG   60600020
         BR    RETURN                   IF NEGATIVE, DONE - RETURN      60700020
ISOLATE4 EQU   *                                                        60800020
         TM    SWITCH,X80              ALLOW OTHER GOOD SECTORS TOO     60900020
         BO    ISOLATE3                 SKIP LOOP BRANCH ADDRESS ALTER  61000020
         LA    ADDR,ISOLATE2            ALTER LOOP BRANCH ADDRESS TO    61100020
*                                        DELETE ALL SECTORS LEFT.       61200020
         B     ISOLATE3                 SKIP DELETE OF THIS ONE         61300020
ORER     OI    DLTEMCW+K3,K0            SECTOR NO. INTO DELETE MCW      61400020
         EJECT                                                          61500020
         EJECT                                                          61550020
*********************************************************************** 61600020
*                                                                     * 61700020
*   THE FOLLOWING REASONS CAUSE A STATUS ERROR TO BE INDICATED AND    * 61800020
* THE STATUS ERROR MESSAGE TO BE SCHEDULED -                          * 61900020
*                                                                     * 62000020
* (1) ENTRY TO THIS MODULE BUT THE 'RESMCW' FIELD INDICATES THAT THE  * 62100020
*    BUFFER HAD PREVIOUSLY BEEN DISABLED BY MCH.                      * 62200020
*                                                                     * 62300020
* (2) A SECTOR ASSOCIATED ERROR IS INDICATED IN A SECTOR WHICH        * 62400020
*    THE 'RESECT' FIELD INDICATES WAS PREVIOUSLY DELETED BY MCH.      * 62500020
*                                                                     * 62600020
* (3) THE NUMBER OF THE FAILING SECTOR INDICATED BY THE LOFOUT        * 62700020
*    EXCEEDS THAT POSSIBLE FOR THE SIZE OF BUFFER ON THIS MACHINE     * 62800020
*    AS INDICATED BY THE LOGOUT.                                      * 62900020
*                                                                     * 63000020
* (4) NONE OF THE BUFFER SIZE INDICATORS IN THE LOGOUT ARE ON         * 63100020
*                                                                     * 63200020
*********************************************************************** 63300020
STATERR  EQU   *                                                        63400020
         OI    REBUFREP+K1,ERRSTAT      INDICATE STATUS ERROR           63500020
         L     WORK,MCHIPTR             GET I-MSG BUFFER POINTER    IO  63600020
         MVI   K0(WORK),STATCODE        REQUEST MSG  IGF041I STAT ERR   63700020
         LA    WORK,K1(WORK)            UPDATE I-MSG BUFFER POINTER     63800020
         B     MODEXIT2                 GO TO EXIT                      63900020
         SPACE 5                                                        64000020
*********************************************************************** 64100020
*              COMPARE CHECK - THIS SECTION EXERCISES THE CIRCUITRY   * 64200020
*        ASSOCIATED WITH THE FAILING SECTOR AND DETERMINES THE        * 64300020
*        SEVERITY OF THE ERROR.  SINCE THE SAME PRINCIPLE IS USED     * 64400020
*        IN THE EXERCISE FOR BLOCK VALID CHECK, THAT ROUTINE IS       * 64500020
*        EXECUTED.                                                    * 64600020
COMPARE  EQU   *                                                        64700020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       64800020
         MVI   REBUFREP,CODE3           MOVE ERROR TYPE TO REPORT AREA  64900020
         B     BLKVAL                   EXECUTE EXERCISE ROUTINE        65000020
         EJECT                                                          65100020
*********************************************************************** 65200020
*                                                                     * 65300020
*              BLOCK VALID CHECK - THIS SECTION RECEIVES CONTROL      * 65400020
*        WHENEVER A BLOCK VALID CHECK OCCURRED IN THE BUFFER. THE     * 65500020
*        FAILING SECTOR WILL BE EXERCISED AND A DECISION MADE AS TO   * 65600020
*        THE SEVERITY OF THE ERROR.                                   * 65700020
*                                                                     * 65800020
*********************************************************************** 65900020
BLKVALID EQU   *                                                        66000020
         BALR  LINK,BACK                GO TO COMMON BRANCH POINT       66100020
         MVI   REBUFREP,CODE2           MOVE ERROR TYPE TO REPORT AREA  66200020
BLKVAL   EQU   *                                                        66300020
         BAL   LINK,SECTSTAT            GO PREPARE FOR SECTOR EXERCISE  66400020
         LA    CTR,FETCH3               GET FETCH COUNT FOR LOOP CNTRL  66500020
         STC   CTR,K3(ADREPORT)         REPORT THE TEST FETCH-COUNT     66600020
         LA    BACK,REPORT02            SET UP REPORT RTN'S ADDRESS     66700020
EXERCISE EQU   *                                                        66800020
         MVC   MCNEWPSW(K8),BUFMCPSW    SET UP TO HANDLE MCI            66900020
         DC    X'8300'                  DIAGNOSE TO ENABLE              67000020
         DC    S(ENBLMCW)               BUFFER AND GO INTO RECORDING    67100020
*                                                                     * 67200020
*              THE BUFFER WILL NOW BE ENABLED WITH ONLY ONE SECTOR    * 67300020
*        ACTIVE IF THE BUFFER IS 16K, OR ONLY TWO SECTORS IF THE      * 67400020
*        BUFFER IS 24K OR 32K.  THE FOLLOWING INSTRUCTIONS CAUSE      * 67500020
*        REPETITIVE SECTOR REASSIGNMENT.                              * 67600020
REASSIGN EQU   *                                                        67700020
         L     WORK,K0                  THESE LOADS ARE USED TO         67800020
         L     WORK,K1024               CAUSE SECTOR REASSIGNMENT       67900020
         L     WORK,K0                  TO THE INSTRUCTION STREAM,      68000020
         L     WORK,K1024               AND TO 2 OTHER 1K AREAS.        68100020
         BCT   CTR,REASSIGN             CONTINUE FOR SPECIFIED NUMBER   68200020
         DC    X'8300'                  DIAGNOSE TO DISABLE BUFFER AND  68300020
         DC    S(LOWCORE1)              GO BACK TO COUNT MODES          68400020
         MVC   MCNEWPSW(K8),NUCEMERG    RESTORE MCNEWPSW OF NUC'S       68500020
ERRTEST  EQU   *                                                        68600020
         CLI   REBUFREP+K4,X00          ANY ERRORS DURING EXERCISES     68700020
         BE    CLEAR                    NO                              68800020
         B     DLTEEXIT                 SET DELETE AND GO TO EXIT       68900020
REPORT02 EQU   *                                                        69000020
         B     ERRTEST                  GO TEST EXERCISE REPORT         69100020
         CH    WORK,SAVNUMBR            WAS MCI ON SAME SECTOR          69200020
         BNE   EXERCISE                 NO                              69300020
         IC    WORK,REBUFREP+K4         GET EXERCISE ERROR COUNT        69400020
         LA    WORK,K1(WORK)            INCREMENT ERROR COUNT           69500020
         STC   WORK,REBUFREP+K4         SAVE UPDATED COUNT              69600020
         B     EXERCISE                 CONTINUE TO EXERCISE            69700020
         EJECT                                                          69800020
*********************************************************************** 69900020
*              THIS SECTION HANDLES THE MACHINE CHECK INTERRUPTS      * 70000020
*        THAT OCCUR WHILE THIS MODULE IS EXERCISING THE BUFFER.       * 70100020
*        UNEXPECTED MCI ARE EITHER ROUTED TO THE RMS/85 NUCLEUS       * 70200020
*        EMERGENCY ROUTINE OR ARE RECEIVED THERE INITIALLY WHEN       * 70300020
*        THE MACHINE CHECK NEW PSW IS NOT POINTING HERE.              * 70400020
*              WHEN A MCI OCCURS, THIS ROUTINE DETERMINES WHAT        * 70500020
*        EXERCISING ROUTINE WAS EXECUTING AND CHECKS THE LOGOUT       * 70600020
*        FOR AN ASSOCIATED ERROR INDICATION.  IF THE ERROR IS NOT     * 70700020
*        ASSOCIATED WITH THE EXERCISING FUNCTION, IT IS TREATED       * 70800020
*        AS AN UNEXPECTED MCI AS DECRIBED PREVIOUSLY.  IF PERTINENT,  * 70900020
*        THE REPORT AREA - REBUFREP - IS UPDATED TO INCLUDE THIS      * 71000020
*        ERROR INFORMATION AND CONTROL IS RETURNED TO THE EXERCISING  * 71100020
*        ROUTINE.                                                     * 71200020
*********************************************************************** 71300020
MCHNDLR0 EQU   *                                                        71400020
         DC    X'8300'                  DIAGNOSE TO DISABLE BUFFER AND  71500020
         DC    S(LOWCORE1)              GO BACK TO COUNT MODES          71600020
         L     BASEREG,LOWCORE          RESTORE MODULE BASE REGISTER    71700020
         DC    X'8300'                  DIAGNOSE TO RESET THE LATCH     71800020
         DC    S(CPUBMCW)               SET BY BUF. DISABLE MODE, MCI   71900020
         MVC   MCNEWPSW+K4(K4),AD2NDMCH POINT MCI TO 2ND LEVEL HANDLER  72000020
         MVC   SAVCKPSW(K8),MCOLDPSW    SAVE MACHINE CHECK OLD PSW      72100020
         MVC   LOGSAVE(K16),BUFRLOG     SAVE NEEDED LOG INFORMATION     72200020
         LPSW  ENABLPSW                 ENABLE FOR MCI                  72300020
MCHNDLR1 EQU   *                                                        72400020
         MVC   MCNEWPSW(K8),NUCEMERG    ALLOW RMS/NUC TO HANDLE MCI     72500020
         LA    LOG,LOGSAVE              SET UP REG FOR LOGOUT TEST      72600020
         ST    BACK,SAVEBACK            SAVE GPR                        72700020
         LA    BACK,CHEKSAME+K2         SET UP FUTURE BRANCH REG TO NOT 72800020
*                                       RETURN TO THE LINKOR.           72900020
         B     DETERM                   GO DETERMINE ERROR TYPE         73000020
CHEKSAME EQU   *                                                        73100020
         BR    LINK                     IMMEDIATE RETURN TO LINKOR      73200020
*   IF RETURN IS HERE, THIS IS A SECOND ERROR CASE.                   * 73300020
         LA    ADDR,LOGSAVE+K6          SETUP ADDRESS FOR SUBROUTINE    73400020
         BAL   RETURN,GETNUMBR          GET FAILING SECTOR NUMBER       73500020
         L     BACK,SAVEBACK            RESTORE GPR                     73600020
         CLC   REBUFREP(K1),K1(LINK)    IS ERROR SAME AS ORIGINAL       73700020
         BNE   TESTCODE                 NO                              73800020
         B     K4(BACK)                 RETURN TO EXERCISE RTN.         73900020
*                                                                     * 74000020
*        CONTROL IS RETURNED TO THE SPECIFIC EXERCISING AREA FOR      * 74100020
*   REPORTING AND CONTINUATION/TERMINATION OF EXERCISES.  THE GPR     * 74200020
*   LABELED 'BACK' HAD PREVIOUSLY BEEN LOADED BY THE SPECIFIC RTN.    * 74300020
*                                                                     * 74400020
         EJECT                                                          74500020
MCHND2ND EQU   *                                                        74600020
         DC    X'8300'                  DIAGNOSE TO DISABLE BUFFER AND  74700020
         DC    S(LOWCORE1)              GO BACK TO COUNT MODES          74800020
         L     BASEREG,LOWCORE          RESTORE MODULE BASE REG         74900020
         MVC   MCNEWPSW(K8),NUCEMERG    LET NUCLEUS TAKE NEXT MCI       75000020
         LM    SADR,LOG,SAVEREGS        RESTORE TEMP. SAVED REGS        75100020
         BR    BACK                     RETURN TO EXERCISE RTN.         75200020
*   BACK HAD PREVIOUSLY BEEN SET UP BY THE SPECIFIC ROUTINE           * 75300020
         EJECT                                                          75400020
TESTCODE EQU   *                                                        75500020
         CLI   SAVCKPSW+K3,X09         WAS RETRY SUCCESSFUL             75600020
         BE    SUCCESS                  YES                             75700020
         OI    REBUFREP+K1,QUIT2        SET QUIT DUE TO HARD            75800020
         B     COMNQUIT                 GO TO COMMON RTN.               75900020
SUCCESS  EQU   *                                                        76000020
         L     WORK,ERRORCNT            GET COUNT OF UNRELATED ERRORS   76100020
         LA    WORK,K1(WORK)            INCREMENT BY ONE                76200020
         ST    WORK,ERRORCNT            STORE UPDATED COUNT             76300020
         C     WORK,ERRCRIT            HAS MAXIMUM BEEN REACHED         76400020
         BNH   K4(BACK)                 NO - RETURN TO EXERCISER        76500020
         OI    REBUFREP+K1,QUIT1        SET QUIT SWITCH NECESSARY       76600020
COMNQUIT EQU   *                                                        76700020
         SR    WORK,WORK                ZEROS INTO REG                  76800020
         ST    WORK,SAVBIT              CLEAR WORD INDICATING SECTOR    76900020
         OI    SWITCH,X20                                               77000020
         B     EXIT                     GO TO EXIT                      77100020
         EJECT                                                          77200020
DLTEEXIT EQU   *                                                        77300020
         OI    REBUFREP+K1,DLTEFLAG     SET SECTOR DELETE FLAG          77400020
         OI    COMINTEL,X02             INDICATE STATUS CHANGE          77500020
EXIT     EQU   *                                                        77600020
         L     WORK,MCHIPTR             GET I-MSG BUFFER PTR        IO  77700020
         TM    REBUFREP+K1,DSBLFLAG     HAS BUFFER BEEN DISABLED        77800020
         BO    DOMSG1                   YES,  SCHEDULE MESSAGE          77900020
         TM    REBUFREP+K1,DLTEFLAG    HAS A SECTOR BEEN DELETED        78000020
         BO    TESTALL                  YES, TEST FOR ALL BAD           78100020
         SPACE 2                                                        78200020
MODEXIT  EQU   *                                                        78300020
         DC    X'8300'                  FINAL DIAGNOSE TO CLEAR ANY     78400020
         DC    S(EXITMCW)               MCW BITS SET DURING EXERCISES.  78500020
MODEXIT2 EQU   *                                                        78600020
         ST    WORK,MCHIPTR             UPDATED I-MSG BUFFER PTR    IO  78700020
         TM    REPRIANL,X80             CHECK REPORT OF PRELIMINARY     78900020
*                                      ANALYSIS - IS MCI A SOFT ONE     79000020
         BO    SOFTCHEK                 YES ERROR RECORDER IS SUCCESSOR 79100020
         MVI   MCHNXMOD,NEXT50          SUCCESSOR ID PDAR           IO  79160020
         B     EXIT2                    GO RETURN TO NUCLEUS        IO  79220020
         SPACE 2                                                        79300020
SOFTCHEK EQU   *                                                        79400020
         MVI   MCHNXMOD,NEXT51          SUCCESSOR ID ERROR RECORDER IO  79500020
EXIT2    EQU   *                                                    IO  79600020
         LM    CTR,REG0,SAVE            RESTORE REGS                    79700020
         BR    RETURN                   RETURN CONTROL TO RMS NUCLEUS   79800020
         SPACE 2                                                        79900020
DOMSG1   EQU   *                                                        80000020
         MVC   MSG1TEXT(K1),REBUFREP    MOVE ERROR TYPE TO MESSAGE      80100020
         OI    MSG1TEXT,XF0             MAKE FIRST BYTE PRINTABLE       80200020
         MVC   K0(MSGLEN1,WORK),MSG1    MOVE DISABLE BUFFER MSG TO IBUF 80300020
BUMPADDR EQU   *                                                        80400020
         LA    WORK,MSGLEN1(WORK)       UPDATE I-MSG BUFFER POINTER     80500020
         B     MODEXIT                  PREPARE TO EXIT MODULE          80600020
         EJECT                                                          80700020
TESTALL  EQU   *                                                        80800020
         MVC   REBUFREP+K2(K1),SAVNUMBR+K1 REPORT NO. OF FAILING SECTOR 80900020
         OC    SAVBIT(K4),RESECT        GET UPDATED SECTOR STATUS VIA   81000020
*                                       COMBINING BOTH.                 81100020
         MVC   RESECT(K4),SAVBIT        UPDATE STATUS AREA TOO          81200020
         CLC   SAVBIT(K2),FOXES        ARE ALL 16 BAD                   81300020
         BE    ALLBAD                   YES                             81400020
         CLI   SIZE,K23                 TEST BUFFER SIZE                81500020
         BL    DELETE                   16K BUFFER - NOT ALL BAD        81600020
         BH    TST32                    32K BUFFER                      81700020
         CLI   SAVBIT+K2,XFF            ARE ALL 8 BAD                   81800020
         BNE   DELETE              NO,NOT ALL SECTORS ARE BAD       IO  81850020
ALLBAD   EQU   *                                                        81910020
         OI    RESMCW+K4,X40            SET DISABLE BIT IN SYS. MCW     81970020
         B     DOMSG1                   NOW SCHEDULE DISABLE MESSAGE    82030020
TST32    EQU   *                                                        82100020
         CLC   SAVBIT+K2(K2),FOXES      ARE ALL 16 BAD                  82200020
         BE    ALLBAD              ALL SECTORS ARE BAD              IO  82500020
         EJECT                                                          82800020
DELETE   EQU   *                                                        82900020
         DC    X'8300'                  DIAGNOSE TO                     83000020
         DC    S(ADDMCW)                ADD ALL SECTORS                 83100020
         OI    SWITCH,X80               SET PARAMETER FOR ISOLATE RTN.  83200020
         L     DATA,SAVBIT              GET SECTOR STATUS WORD          83300020
         SRL   DATA,K16                 MOVE TO LOW ORDER HALF OF REG   83400020
         MVI   DLTEMCW+K3,X20           SET 00-15 DELETION BIT IN MCW   83500020
         BAL   RETURN,ISOLATE           SET SECTORS 00-15 PER STATUS    83600020
         MVC   FIELD+K2(K2),SAVBIT+K2   GET SECTOR STATUS FOR 16-31     83700020
         L     DATA,FIELD               INTO PARAMETER REG              83800020
         MVI   DLTEMCW+K3,X10           SET 16-31 DELETION BIT IN MCW   83900020
         BAL   RETURN,ISOLATE           SET SECTORS 16-31 PER STATUS    84000020
*        FOR SOME PARTICULAR CASES, THIS ROUTINE IS ALSO USED         * 84100020
*   WHEN NO SECTOR DELETION HAS BEEN DETERMINED NECESSARY.            * 84200020
         TM    REBUFREP+K1,DLTEFLAG    HAS A SECTOR BEEN DELETED        84300020
         BNO   EXIT                     NO, USE NORMAL CODE FROM HERE   84400020
         MVC   MSG2TEXT(K1),REBUFREP    MOVE ERROR TYPE TO MESSAGE      84500020
         OI    MSG2TEXT,XF0             MAKE FIRST BYTE PRINTABLE       84600020
         LH    NUM,SAVNUMBR             GET FAILING SECTOR NUMBER       84700020
         SLL   NUM,K1                   MULTIPLY BY 2 FOR DISPLACEMENT  84800020
         LA    ADDR,CHARS(NUM)          GET ADDR OF 2 CHARACTER NUMBER  84900020
         MVC   MSG2TEXT+K6(K2),K0(ADDR) MOVE NUMBER INTO MESSAGE        85000020
         MVC   K0(MSGLEN1,WORK),MSG2    MOVE SECTOR DELETED MSG TO IBUF 85100020
         B     BUMPADDR                 CONTINUE AT COMMON POINT        85200020
         EJECT                                                          85300020
SAVE     DS    16F                      SAVE AREA FOR REGS AT ENTRY     85400020
FIELD    DC    F'0'                     WORD ON WORD BOUNDARY           85500020
SAVEBACK DC    F'0'                     REG SAVE AREA                   85600020
ERRORCNT DC    F'0'                     COUNT OF UNRELATED ERRORS       85700020
ERRCRIT  DC    F'10'                    MAX. ALLOWABLE UNRELATED ERRORS 85800020
SAVEREGS DC    D'0'                     TEMPORARY REGISTER SAVE AREA    85900020
ADDMCW   DC    X'0300004045000000'      MCW TO ADD ALL SECTORS YET STAY 86000020
*                                       IN HIR AND ECC COUNTER MODE,    86100020
*                                       AND LEAVE THE BUFFER DISABLED.  86200020
PSWKEY0  DC    X'0004000000000000'      PSW                             86300020
TESTPSW  DC    X'0004000000000000'       USAGE                          86400020
BUFMCPSW DC    D'0'                     NEW PSW FOR BUFR MCI HANDLER    86500020
DLTEMCW  DC    X'0300000045000000'      MCW TO DELETE SECTORS           86600020
DSBLMCW  DC    X'0300000045000000'      MCW TO DISABLE BUFFER           86700020
ENBLMCW  DC    X'0300000000000000'      MCW TO ENABLE BUFFER            86800020
CPUBMCW  DC    X'2400000000000000'      RESET LATCH SET BY MODE BIT,MCI 86900020
EXITMCW  DC    D'0'                     FINAL MCW ISSUED                87000020
SAVEADDR DC    F'0'                     ADDRESS OF 1ST 2048 BOUNDARY    87100020
CLEARBIT DC    X'0000001F'              CLEARS ALL BUT L.OL 5 BITS      87200020
ENABLPSW DC    D'0'                     PSW TO ENABLE AFTERMCI IN EXER. 87300020
NUCEMERG DC    D'0'                     SAVED MC NEW PSW OF NUC ERERG.  87400020
SAVBIT   DC    F'0'                     SAVED SECTOR BIT POSITION       87500020
AD2NDMCH DC    F'0'                     ADDRESS OF 2ND MCI HANDLER      87600020
SAVNUMBR DC    H'0'                     SAVED SECTOR NUMBER             87700020
SIZE     DC    H'0'                     2 BYTES OF ZEROS TO KEEP SIZE   87800020
HIGHBIT  DC    X'80000000'              WORD WITH HIGH ORDER BIT ON     87900020
SIXTEEN  DC    H'16'                    DECIMAL VALUE 16                88000020
BUFRCRIT DC    H'3'                     NON-SECTOR ASSOCIATED CRITERIUM 88100020
BDBOCRIT DC    H'3'                     BDBO CRITERIUM VALUE            88200020
SAVCKPSW DC    D'0'                     SAVED MC OLD PSW WHILE EXERCIS. 88300020
LOGSAVE  DC    2D'0'                    16 BYTE SAVE AREA FOR LOGOUT    88400020
FOXES    DC    X'FFFFFFFF'              WORD OF ALL ONES FOR SECT. NOS. 88500020
MSG1     DC    X'9108'             REQUEST IGF047I X BUFFER         IO  88600020
MSG1TEXT DC    C'X BUFFER'              MESSAGE 1 TEXT                  88700020
MSG2     DC    X'9008'             REQUEST IGF046I X SEC NN         IO  88800020
MSG2TEXT DC    C'X SEC NN'              MESSAGE 2 TEXT                  88900020
SAVKEY1  DC    X'00'                    SAVED SPF KEY                   89000020
SAVKEY2  DC    X'00'                    SAVED SPF KEY                   89100020
SWITCH   DC    X'00'                    CNTRL SW                        89200020
CHARS    DC    C'00010203040506070809101112131415161718192021222324' *  89300020
         DC    C'25262728293031'        *                               89400020
         SPACE 3                                                        89450021
***   MAINTENANCE  AREA  ***                                            89500021
MAINTID  DC    CL8'IGFMCH16'           CORE IDENTIFIER                  89550021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              89600021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 89650021
         EJECT                                                          89900020
MCHCOM   DSECT                                                          89960020
         MCHMAC                                                         90030020
COMINTEL EQU   MCHINTEL                                                 90060020
         EJECT                                                          90070020
ASRCOM   DSECT                                                          90080020
         ASRMAC85                                                       90100020
LOGBYTE1 EQU   RECPULOG-128+24+X'3A9'                                   90200020
LOGBYTE2 EQU   RECPULOG-128+24+X'3AA'                                   90300020
LOGBYTE3 EQU   RECPULOG-128+24+X'3AD'                                   90400020
LOGBYTE4 EQU   RECPULOG-128+24+X'3AE'                                   90500020
LOGBYTE5 EQU   RECPULOG-128+24+X'3A7'                                   90600020
LOGBYTE6 EQU   RECPULOG-128+24+X'3A5'                                   90700020
LOGBYTE7 EQU   RECPULOG-128+24+X'3A6'                                   90800020
LOGBYTE8 EQU   RECPULOG-128+24+X'3AB'                                   90900020
RMSMSB   DSECT                                                          90930020
         RMSMSB    MOD=85                                               90960020
         END                                                            91000020
