         LCLA  &LEV,&REL                                                00010021
&LEV     SETA  40                                                       00020000
&REL     SETA  21                                                       00030021
&REL&LEV TITLE 'IGFMCH17 LEVEL &LEV RMS-MCH 85 ERROR RECORDER'          00040021
*********************************************************************** 00160020
*                                                                     * 00240020
* MODULE  IGFMCH17 -- ERROR RECORDER                                    00320020
*                                                                     * 00400020
* FUNCTION/OPERATION                                                  * 00480020
*       THE ERROR RECORDER MODULE RECORDS THE CPU ERROR ENVIRONMENT   * 00560020
*   ON THE SYS1.LOGREC DATA SET FOR EVERY RMS RECOVERY ATTEMPT.       * 00640020
*   SUCCESSFUL OR UNSUCCESSFUL. (FOR THE MODEL 85 TWO RECORDS WILL BE * 00720020
*   WRITTEN). THE CHANNEL CHECK HANDLER OPTION(CCH) IS REQUIRED IN THE  00800020
*   SYSTEM AND IF A MCI OCCURS IN CCH, THIS MODULE WILL RECORD-CHANNEL  00880020
*   INBOARD RECORD ENTRY ON SYS1.LOGREC.                              * 00960020
*                                                                     * 01040020
*       THE RECORDS WILL CONTAIN DATA OF THE SAME CONTENT AND FORMAT  * 01120020
*   AS THAT NOW RECORDED BY SER0/1. (SEE FORMATS ON FOLLOWING PAGES.) * 01200020
*   IN ADDITION, THE CPU RECORD WILL CONTAIN MCH DETERMINED DATA.     * 01280021
*   THIS DATA INCLUDES THE RESULTS OF THE FOLLOWING RMS FUNCTIONS -   * 01360020
*                                                                     * 01440020
*      . PRELIMINARY ERROR ANALYSIS                                   * 01520020
*      . BUFFER CONTROL                                               * 01600020
*      . MAIN STORAGE ANALYSIS                                        * 01680020
*      . PROGRAM DAMAGE ASSESSMENT AND REPAIR (MFT/MVT)               * 01760020
*      . MACHINE STATUS CONTROL                                       * 01840020
*                                                                     * 01920020
*   THIS MODULE IS DIVIDED INTO SECTIONS                              * 02000020
*                                                                     * 02080020
*  SECTION 1-                                                         * 02160020
*       WHEN ERROR RECORDER GAINS CONTROL, IT READS THE HEADER RECORD * 02240020
*   FROM SYS1.LOGREC (R1) AND DETERMINES AVAILABLE RECORDING SPACE.   * 02320020
*   IF NO SPACE IS AVAILABLE, A MESSAGE (LOGREC FULL) IS SCHEDULED   *  02370020
*                                                                     * 02480020
*  SECTION 2-                                                         * 02560020
*       WHEN THE HEADER RECORD INFORMATION INDICATES THAT A RECORD    * 02640020
*   CAN BE WRITTEN, ERROR RECORDER COMPLETES THE RECORD AND WRITES IT.* 02720020
*   THE HEADER RECORD IS UPDATED AND REWRITTEN.                       * 02800020
*       FOR CPU RECORDS, THE FOLLOWING DATA IS ALREADY STORED WITHIN  * 02880020
*   THE RE BUILD AREA (SEE ASRMAC85 DSECT) -                          * 02960020
*                                                                     * 03040020
*  (1) RESULTS OF RMS MODULE EXECUTION                                * 03120020
*                                                                     * 03200020
*      . REBUFREP                                                     * 03280020
*      . RESTAT                                                       * 03360020
*      . REMEST                                                       * 03440020
*      . REPDAR (PARTIAL)                                             * 03520020
*      . RERETRY                                                      * 03600020
*      . REMCOPSW                                                     * 03680020
*      . RESECT                                                       * 03760020
*      . REPRIANL                                                     * 03840020
*      . RECHKCNT                                                     * 03920020
*                                                                     * 04000020
*  (2) SAVED BY THE RMS NUCLEUS                                       * 04080020
*                                                                     * 04160020
*      . RECPULOG                                                     * 04240020
*                                                                     * 04320020
*         FOR INBOARD RECORDS, CCH WILL COMPLETE THE RECORD FOR THE CCH 04400020
*    CHANNEL ERROR THAT HAS OCCURRED.  THE ADDRESS OF THE COMPLETED CCH 04480020
*    RECORD WILL BE PASSED IN REGISTER 13.  THE RECORD LENGTH IS    CCH 04560020
*    VARIABLE ,SO THE LENGTH IS PASSED IN 6(REGISTER13).            CCH 04640020
*       THE RETYPE FIELD IS SET BY RMS NUCLEUS TO I OR C, TO INDICATE * 04720020
*       RESPECTIVELY, THAT EITHER AN INBOARD OR A CPU RECORD ENTRY    * 04800020
*       IS TO BE RECORDED.                                            * 04880020
*       THE REMAINING FIELDS IN A CPU RECORD ARE DETERMINED           * 04960020
*       AND/OR LOADED BY ERROR RECORDER, THUS COMPLETING THE RECORD   * 05040020
*                                                                     * 05120020
*  ALL I/O OPERATIONS WILL BE HANDLED BY THE MCH NUCLEUS VIA A SPECIAL* 05200020
*   IOS INTERFACE. THERE ARE THREE WAYS TO ENTER THE MCH NUCLEUS FOR  * 05280020
*   DIFFERENT I/O REQUESTS                                            * 05360020
*                                                                     * 05440020
*********************************************************************** 05520020
         EJECT                                                          05600020
*                         HEADER  RECORD  AREA                        * 05680020
*     ***************************************************************** 05760021
*     *              *                                  *     HIGH    * 05840021
* +0  *  F F 0 0     *             LOW EXTENT           *    EXTENT   * 05920021
*     *              *               (CCHH)             *     (CC)    * 06000021
*     ***************************************************************** 06080021
*     * HIGH EXTENT  *       *       RECORD ENTRY AREA ADDRESS        * 06160021
* +8  *   (CONT.)    * SPARE *               (BBCCHHR)                * 06240021
*     *    (HH)      *       *                                        * 06320021
*     ***************************************************************** 06400021
*     *  REC. ENTRY  *  REMAINING     *  TOTAL BYTES    *  ADDRESS OF * 06480021
* +16 * AREA ADDR.   *   BYTES ON     *      ON         * LAST RECORD * 06560021
*     *   (CONT.)    *     TRACK      *    TRACK        * WRITTEN     * 06640021
*     ***************************************************************** 06720021
*     *           ADDRESS OF LAST RECORD         *   TRACKS    * EARLY* 06800021
* +24 *              WRITTEN  (CONT.)            *     PER     * WARN.* 06880021
*     *                                          *  CYLINDER   *  CNT.* 06960021
*     ***************************************************************** 07040021
*     * EARLY * DEV- *     EARLY WARNING                * EARLY*  CK  * 07120021
* +32 * WARN. *  ICE *                MESSAGE TRACK     * WARN.* BYTE * 07200021
*     * CNT.  * CODE *                                  * SWT. * (FF) * 07280021
*     ***************************************************************** 07360021
         EJECT                                                          07440020
*                      RMS CPU RECORD ENTRY AREA                      * 07520020
*                                                     ***************** 07530020
*                                                     *               * 07540020
*                                                  +0 *  KEY FIELD    * 07550021
*                                                     *               * 07560020
*     ***************************************************************** 07600020
*     *         RECORD        *  SYS. *  CPU  *  R.E. *               * 07680020
* +2  *          ENTRY        *  I.D. * MODEL *  TYPE * EREP INDICATOR* 07760021
*     *          LABEL        *       *  NO.  *       *     (NOTE)    * 07840021
*                                                                       07890021
*     ***************************************************************** 07920020
*     *                               *                               * 08000020
* +10 *             DATE              *             TIME              * 08080021
*     *                               *                               * 08160020
*     ***************************************************************** 08240020
*     *                                                               * 08320020
* +18 *                      PROGRAM  IDENTITY                        * 08400021
*     *                                                               * 08480020
*     ***************************************************************** 08560020
*     *                                                               * 08640020
* +26 *                  MACHINE  CHECK  OLD  PSW                     * 08720021
*     *                                                               * 08800020
*     ***************************************************************** 08880020
*     *                                                               * 08960020
* +34 *                                                               * 09040021
*     *                       CHANNEL/UNIT ADDRESSES OF               * 09120020
*     *                       ACTIVE I/O UNITS AT                     * 09200020
*     *                       THE TIME OF FAILURE                     * 09280020
*     *                            (16 BYTES)                         * 09360021
*     ***************************************************************** 09440021
*     *                                                               * 09520021
* +50 *                CHANNEL  TYPE  ASSIGNMENT                      * 09600021
*     *                                                               * 09680021
* --- ***************************************************************** 09760020
*     *                                                               * 09840020
* +58 *                      ENVIRONMENT CHECK DATA                   * 09920021
*     *                                                               * 10000020
*     ****************************************************************  10080020
*     *                                                               * 10160020
* +66 *                     REBUFREP - HIGH SPEED BUFFER              * 10240021
*     *                                                               * 10320020
*     ****************************************************************  10400020
*     *                                                               * 10480020
* +90 *                      MEMORY CHECK DATA                        * 10560021
*     *                      (13 DW OR 104 BYTES)                     * 10640021
*     ****************************************************************  10720020
         EJECT                                                          10740021
*     ***************************************************************** 10760021
*     *                                                               * 10800020
* +194*                      PROGRAM DAMAGE ASSESSMENT AND            * 10880021
*     *                        REPAIR DATA                            * 10960020
*     *                           (36 BYTES)                          * 10980021
*     *                               ********************************* 11000021
*     *                               *                               * 11020021
*     *                               *          SPARE                * 11040021
*     *                               *                               * 11060021
*     ****************************************************************  11120020
*     *                                                               * 11200020
* +234*                      INSTRUCTION RETRY DATA                   * 11280021
*     *                           (16 BYTES)                          * 11360021
* --- ****************************************************************  11440020
*     *                                                               * 11680020
* +250*                      SYSTEM STATUS AREA                       * 11760021
*     *                            (24 BYTES)                         * 11840021
*     ***************************************************************** 11920020
*     *                               *                               * 12000020
* +274*        SECTOR DELETION         *              SPARE           * 12080021
*     *                               *                               * 12160020
*     ***************************************************************** 12240020
*     *                                                               * 12320020
* +282*                             SPARE                             * 12400021
*     *                                                               * 12480021
*     ***************************************************************** 12560020
*     *                               *                               * 12640020
* +290*       COUNT OF BDBO CHECKS    *              SPARE            * 12720021
*     *                                            (68 BYTES)         * 12800021
*     ***************************************************************** 12880020
*     *                     CPU HARDWARE LOGOUT                       * 12960020
* +362*                           MODEL  85                           * 13040021
*     *                          (1480 BYTES)                         * 13120021
*     ***************************************************************** 13200020
*                                                                       13250021
*  NOTES                                                                13260021
*        EREP INDICATORS                                                13270021
*          BYTE 0                                                       13272021
*              BIT 0                                                    13276021
*              BIT 1 = INCOMPLETE RECORD                                13278021
*              BIT 2 = ILLEGAL CUA                                      13278421
*              BITS 3,4,5,6,7                                  CD 52708 13279226
*          BYTE 1                                                       13279321
*              BIT 0,1,2                                       CD 52708 13292726
*              BIT 3 = EXPANDED CHANNEL SUPPORT                CD 52708 13306426
*              BIT 6 = SECOND RECORD                                    13319800
*              BIT 7                                                    13333200
       EJECT                                                            13346600
*                     INBOARD  RECORD  ENTRY  AREA                    * 13360020
*     ***************************************************************** 13440020
*    DETAIL DESCRIPTION OF INBOARD RECORDS CAN BE FOUND IN CCH PUBS  *  14440020
*     ***************************************************************** 17280020
         EJECT                                                          17360020
IGFMCH17 CSECT                                                          17440020
         USING MCHCOM,COMREG                                            17500020
         USING ASRCOM,DEPREG                                            17560020
         USING TCVTNAM,CVTREG                                           17620020
*                                                                       17680020
*** REGISTER USAGE                                                      17760020
*                                                                       17840020
T0       EQU   0                                                        17920020
TWORK1   EQU   1                   WORK REG.                            18000020
TWORK2   EQU   2                   WORK REG.                            18080020
TWORK3   EQU   3                   WORK REG.                            18160020
TWORK4   EQU   4                   WORK REG.                            18240020
TWORK5   EQU   5                   WORK REG.                            18320020
TWORK6   EQU   6                   WORK REG.                            18400020
TWORK7   EQU   7                   WORK REG.                            18480020
TWORK8   EQU   8                   WORK REG.                            18560020
TCBREG   EQU   9              ADDRESS OF TCB                        IO  18640020
CVTREG   EQU   10                      CVT BASE REG                     18720020
COMREG   EQU   11                    INDEPENDENT COMMON AREA BASE REG   18800020
TBASEREG EQU   12                  BASE REG FOR THIS MODULE             18880020
DEPREG   EQU   13                      DEPENDENT COMMON AREA BASE REG   18980020
TLINK    EQU   15             MODULE LOADING FOR IO REQUESTS        IO  19120020
R14      EQU   14                  LINK REG BACK TO NUCLEUS             19280020
OBRBIT   EQU   299                 INDEX FOR LOGREC DCB                 19360020
         SPACE 2                                                        19520020
****           OFFSETS AND FLAGS                                        19600020
TSHPC    EQU   0                   SIX HOUR PSEUDO CLOCK                19680020
TT4PC    EQU   4                   24 HOUR PSEUDO CLOCK                 19760020
TLTPC    EQU   8                   LOCAL TIME PSEUDO CLOCK              19840020
         SPACE                                                          19920020
TUCBACT  EQU   6                   UCB BUSY BIT                         20000020
TUCBCUA  EQU   4                   UCB CHANNEL/UNIT ADDRESS             20080020
TACTTCB  EQU   4                   CURRENT TCB                          20160020
D8       EQU   8                                                        20240020
XRBPSW   EQU   17                  PSW WAIT BIT OFFSET FOR WAIT TCB     20320020
WAITBIT  EQU   X'02'               WAIT BIT                             20400020
TOPRBP   EQU   0                   TOP RB                               20480020
TRBSTAB  EQU   10                  RB STATUS AND ATTRIBUTE FIELD        20560020
TCBTIO   EQU   12                  TIOT ADDR                            20640020
TSIRB    EQU   X'80'               SIRB TYPE                            20720020
X80      EQU   X'80'                                                    20800020
TPRB     EQU   X'C0'               PRB CODE                             20880020
TRBTCB   EQU   X'80'               RBLNK POINTS TO TCB FLAG (IN RB)     20960020
TRBLNK   EQU   X'1C'               QUEING FIELD                         21040020
TMVT     EQU   X'10'               MVT IDENT. SET BY NIP.CVTDCB BYTE 1  21120020
MULTPROC EQU   X'10'               MULTIPROCESSING MASK              MP 21200020
TCDNAME  EQU   8                   RB CONTENTS DIRECTORY NAME,  FOR MVT 21360020
TRBCDE   EQU   12                  RB CONTENTS DIRECTORY ENTRY FOR MVT  21440020
TDCBF0   EQU   44                  DCB DEB ADDR                         21680020
TDEBF4   EQU   36                  DEB BBCCHHR                          21760020
LEVEL    EQU   X'&LEV'                  MODULE LEVEL                    21860021
NEXT5A   EQU   X'01'               FIRST SUCCESSOR PATH IN 17 ENTRY IO  22020020
T1       EQU   1                                                        22080020
T2       EQU   2                                                        22160020
T3       EQU   3                                                        22240020
T4       EQU   4                                                        22320020
T5       EQU   5                                                        22400020
T6       EQU   6                                                        22480020
T7       EQU   7                                                        22560020
T8       EQU   8                                                        22640020
T10      EQU   10                                                       22720020
T14      EQU   14                                                       22800020
T16      EQU   16                                                       22880020
T18      EQU   18                                                       22960020
T20      EQU   20                                                       23040020
T21      EQU   21                                                       23120020
T24      EQU   24                                                       23200020
T28      EQU   28                                                       23280020
T48      EQU   48                  DECIMAL CONSTANT           IH  45458 23330021
T68      EQU   68                                                       23360020
T69      EQU   69                                                       23440020
T72      EQU   72                                                       23520020
T80      EQU   80                                                       23600020
CI       EQU   C'I'                                                     23680020
CC       EQU   C'C'                                                     23760020
X02      EQU   X'02'                                                    23920020
X08      EQU   X'08'               IMMEDIATE DATA                       24000020
H1D      EQU   X'1D'               IMMEDIATE DATA                       24080020
H20      EQU   X'20'                                                    24160020
H70      EQU   X'70'                                                    24240020
H80      EQU   X'80'                                                    24320020
HC1      EQU   X'C1'                                                    24400020
HBF      EQU   X'BF'                                                    24720020
H23      EQU   X'23'                                                    24800020
H24      EQU   X'24'                                                    24880020
H7F      EQU   X'7F'                                                    25040020
H01      EQU   X'01'                                                    25120020
HEF      EQU   X'EF'                                                    25200020
HFF      EQU   X'FF'                                                    25280020
HF7      EQU   X'F7'                                                    25360020
D40      EQU   40                                                       25400020
         EJECT                                                          25440020
         USING IGFMCH17,TBASEREG    BASE REG FOR MODULE                 25520020
IGFMCH17 CSECT                                                          25600020
         LR    T0,TBASEREG         SAVE REG 12                          25680020
         LR    TBASEREG,TLINK      SET BASE REG FOR THIS MODULE         25880020
         SPACE 5                                                        26160020
*********************************************************************** 26240020
*                                                                     * 26320020
* SECTION 1 -  READING AND CHECKING HEADER RECORD                       26400020
*                                                                       26480020
*     THIS SECTION READS THE HEADER RECORD FROM THE SYS1.LOGREC DATA  * 26560020
*     SET.  THE TRACK AND CYLINDER IS UPDATED IF NECESSARY, AND IF    * 26640020
*     THE EXTENT IS FULL, EREP IS REQUESTED VIA A CONSOLE MESSAGE. THE* 26720020
*     HEADER RECORD IS THEN UPDATED TO REFLECT INFO FOR THE NEXT      * 26800020
*     RECORD ENTRY TO BE WRITTEN. ALL REQUIRED I/O OPERATIONS ARE     * 26880020
*     PERFORMED BY IOS THROUGH A MCH INTERFACE.                      *  26960020
*                                                                     * 27040020
*********************************************************************** 27120020
         SPACE 3                                                        27200020
         SPACE 2                                                        27280020
         MVI   MCHEXLEV,LEVEL           MODULE CHANGE LEVEL         IO  27380020
         STM   DEPREG,R14,TREGSAVE     SAVE REGS                        27480020
         MVC   XCPUL(T2),CPUL1     MOVE FIRST CPU RECORD LENGTH         27600020
TSTARTA  EQU   *                                                        27650020
         L     TCBREG,CVTTCBP      LOAD ADDRESS OF TCB POINTERS         27760020
         L     TCBREG,TACTTCB(TCBREG)   GET ADDR OF ACTIVE TCB -CURRENT 27840020
*                                                                       27920020
**** ROUTINE TO RESOLVE DATA ADDRESSES FOR CCWS - NO ADCONS CAN BE USED 28000020
         LA    TWORK5,TWRTCCW      GET ADDRESS OF WRITE CCW LIST        28200020
         ST    TWORK5,TICADDR      STORE AS TIC ADDR                    28400020
         MVC   WRTRETIC(T3),TICADDR1    MOVE TO RE WRITE TIC CCW        28600020
         SPACE                                                          29120020
         LA    TWORK3,TSRCHAD2     STORE ADDRESS OF                     29200020
         ST    TWORK3,WORKAREA            SEARCH ADDRESS IN             29280020
         MVC   THDRCCWA(T3),WORKARA1    SEARCH CCW                      29360020
         MVC   THDRCCWB(T3),WORKARA1    SEARCH CCW                      29440020
         MVC   TWRTCCWA(T3),WORKARA1    SEARCH CCW                      29520020
         MVC   TEOFCCW1(T3),WORKARA1    SEARCH CCW                      29600020
         SPACE                                                          29680020
         LA    TWORK3,THDRREC           STORE HEADER RECORD             29760020
         ST    TWORK3,WORKAREA            ADDRESS IN HDR READ           29840020
         MVC   RDHDR(T3),WORKARA1       AND WRITE CCW.                  29920020
         MVC   WRTHDR(T3),WORKARA1     WRITE CCW                        30000020
         SPACE                                                          30080020
         LA    TWORK3,TEOFREC           STORE EOF RECORD ADDRESS        30160020
         ST    TWORK3,WORKAREA            IN WRITE EOF CCW.             30240020
         MVC   EOFRECAD(T3),WORKARA1    MOVE IN CCW                     30320020
         SPACE 3                                                        30400020
         SPACE                                                          32400020
       SPACE 2                                                          32480020
*                                                                       32560020
*****       READ HEADER RECORD FROM SYS1.LOGREC.                        32640020
*                                                                       32720020
         SPACE 2                                                        32800020
RDHEAD   OI    RECTLIND,H40        SET INCOMPLETE RECORD INDICATOR      32880020
         LA    TWORK3,CTFLDID           STORE RE ADDRESS                32960020
         TM    RECTLND1,T2              SECOND RECORD                   33040020
         BZ    ERQ                 NO                                   33120020
         LA    TWORK3,CTFLDID6          SET TO DOUBLE WORD              33200020
         AH    TWORK3,CPUL1        ADD FIRST RECORD LENGTH              33280020
ERQ      ST    TWORK3,WORKAREA     IN WRITE RE CCW.                     33360020
         MVC   TWRTCCWB(T3),WORKARA1    PUT LENGTH IN CCW               33440020
*  GET ADDRESS OF SYS1.LOGREC FROM DEB                                  33520020
         L     TWORK2,CVTDCB       ADDRESS OF SYS1.LOGREC DCB AND       33600020
         ST    TWORK2,MCHIODCB     PUT DCB ADDR IN IOB FOR IO       IO  33640020
         L     TWORK6,TDCBF0(TWORK2)  ADDR OF DEB                       33680020
         MVC   TSRCHAD(T6),TDEBF4(TWORK6)    MOVE BBCCHH FROM DEB       33760020
         MVI   TSRCHAD6,T1         SET SEARCH ID FIELD TO ONE           33840020
         MVC   TDSADRSV(T8),TSRCHAD     SAVE SYS1.LOGREC ADDRESS        33920020
         MVC   MCHIOBS1(T7),TSRCHAD  PUT BBCCHHR INTO IOB-HEADER        33960020
*  COMPLETE CCWS FOR READ                                               34000020
         LA    TWORK3,THDRCCW      READ HEADER CCW LIST ADDRESS         34080020
         ST    TWORK3,TICADDR      STORE TIC ADDR AND                   34160020
         ST    TWORK3,MCHICCWS     PUT CHANNEL PROGRAM ADDR IN IOB  IO  34240020
         MVC   HDRDTIC(T3),TICADDR1     MOVE TO HDR READ TIC CCW        34320020
*  READ HEADER                                                          34400020
         LA    TWORK1,MCHIOB           IOB ADDRESS                      34420020
         L     TLINK,MCHEXCP           IOS INTERFACE ROUNTINE           34440020
         BALR  R14,TLINK                IOS INTERFACE TO READ HEAD  IO  34460020
         B     RIGHTIO1                 SUCCESSFUL IO               IO  34480020
         B     TERMNATE                 UNSUCCESSFUL IO             IO  34500020
RIGHTIO1 EQU   *                                                   IO   34520020
         CLI   TSFTYBYT,HFF        IS SAFETY BYTE IN HEADER CORRECT     34560020
         BNE   TERMNATE            BR -NO, INCORRECT - I/O OVERRUN      34640020
         SPACE 5                                                        34720020
*                                                                       34800020
*****    TEST HDR INFO TO DETERMINE IF TRK OR CYL SWITCH IS NECESSRY,OR 34880020
*        IF SYS1.LOGREC IS ALMOST FULL REQUIRING AN EREP RUN.           34960020
       SPACE 2                                                          35040020
* GET SYSRES DEVICE TYPE  (TO DETERMINE ACTUAL DEVICE TRACK CAPACITY)   35120020
* CHECK IF RECORD WILL FIT ON THIS TRACK                                35200020
         SR    TWORK4,TWORK4       CLEAR REG.                           35280020
         IC    TWORK4,DEVCODE          GET SYSRES DEVICE TYPE     21021 35360021
         CLI   RETYPE,CI           IS THIS AN INBOARD RECORDING         35440020
         BE    XINB                YES                                  35520020
         SLL   TWORK4,T2           TIME 4, 4 BYTE TABLE ENTRIES         35600020
         TM    RECTLND1,T2         SECOND RECORD                        35680020
         BZ    XFIRST              NO, FIRST RECORD                     35760020
         LA    TWORK4,T2(TWORK4)   SECOND RECORD USE SECOND ENTRY       35840020
XFIRST   LH    TWORK5,TCONRE84(TWORK4)  LOAD CPU REC. DECREMENT         35920020
         B     TSTBYREM            GO CHECK                             36000020
         SPACE                                                          36080020
XINB     SLL   TWORK4,T1           TIME 2, 2 BYTE TABLE ENTRIES         36160020
         LH    TWORK5,TCONIO82(TWORK4)       LOAD CCH RECORD DECREMENT  36240020
TSTBYREM LH    TWORK3,TBYTSREM          GET NO. OF BYTES REMAINING TRK  36320020
         SLR   TWORK3,TWORK5            SUBT CONSTANT FROM REMAING BYTS 36400020
         BO    TCHKLAST                 BR- RE WILL FIT ON THIS TRACK-  36480020
*                                      SO CHECK IF THIS IS LAST TRACK   36560020
         SPACE 2                                                        36640020
* CHECK IF END OF CYLINDER                                              36720020
TESTCYL  LH    TWORK3,TLASTTT4          GET LAST USED HEAD POSITION-HH  36800020
         LA    TWORK3,T1(TWORK3)        ADD ONE TO HEAD POSITION        36880020
         L     TWORK1,TLASTTT6     GET TRKS PER CYL               21021 36940021
         LA    TWORK1,T0(TWORK1)   CLEAR TOP BYTE                 21021 37000021
         SRL   TWORK1,X08          CLEAR LOW BYTE 2 MOVE RIGHT 1  21021 37060021
         CLR   TWORK1,TWORK3            COMPARE TRKS/CYL TO HEAD POSITN 37120020
         BL    TCYLEND       END OF CYLINDER                       IO   37200020
         SPACE 2                                                        37280020
         SPACE 2                                                        37360020
* IF NECESSARY, UPDATE HEAD POSITION TO SWITCH TRACKS                   37440020
TRKUPDT  STH   TWORK3,TLASTTT4          STORE NEXT HEAD POSITION IN HDR 37520020
         MVI   TLASTTT6,T0              SET RECORD ENTRY IO TO ZERO     37600020
         MVC   TBYTSREM(T2),TRKCAP      RESET BYTES REMAINING ON TRACK  37680020
         B     TSTBYREM                 TRY AGAIN                       37760020
         SPACE 2                                                        37840020
* IF NECESSARY, UPDATE CYLINDER POSITION                                37920020
TCYLEND  EQU   *                                                        37950020
         SR    TWORK3,TWORK3      CLEAR REG FOR ZERO HEAD          20.2 38040020
         LH    TWORK1,TLASTTT2          GET LAST USED CYLINDER POSITION 38080020
         LA    TWORK1,T1(TWORK1)        UPDATE CYLINDER POSITION -CC    38160020
         STH   TWORK1,TLASTTT2          STORE NEXT CYLINDER POS IN HDR  38240020
         B     TRKUPDT                  UPDATE HEADER                   38320020
         SPACE 2                                                        38400020
* CHECK RECORDING SPACE IN EXTENT FOR POSSIBLE EREP SCHEDULING          38480020
TCHKLAST STH   TWORK3,TBYTSREM          STORE NEW REMAINE BYTCNT IN HDR 38560020
         TM    SWITCHES,X80            HAS 90% MSG BEEN ISSUED    21021 38640021
         BO    TESTFULL                YES-GO TO TEST LOGREC FULL 21021 38720021
         CLC   EWMT(T4),TLASTTT2       EARLY WARN(90%)- NEW CCHH  21021 38800021
         BL    FUL90SET                SET  NEAR FULL MESSAGE     21021 38880021
**                                 USED ONLY IF WARN TRACK IS BYPASSED  38882021
         BH    TESTFULL            SKIP NEAR FULL MESSAGE         21021 38890021
         CLC   EWMC(T2),TBYTSREM       EARLY WARN CNT=REMAIN BYTE 21021 38930021
         BL    TSETWRT                 NO-SKIP NEAR FULL/FULL MSG 21021 38940021
***   SYS1.LOGREC IS NEAR FULL(90%)                                     38950021
FUL90SET EQU   *                                                  21021 38952021
         OI    MCHINT+T2,X08           SET 90% MESSAGE BIT        21021 38954021
         OI    SWITCHES,X80            SET 90% BIT IN LOGREC HDR  21021 38956021
         CLC   EWMT(T4),TLASTTT2       EARLY WARN(90%)- NEW CCHH  21021 38956421
         BL    TESTFULL            GO TO TEST FULL COND           21021 38956821
         B     TSETWRT                 GO WRITE RECORD            21021 38958021
TESTFULL EQU   *                                                  21021 38960021
         CLC   TUPLIMIT(T4),TLASTTT2   NEW CCHH = HIGH CCHH       21021 39040021
         BH    TSETWRT                 NO- WRITE RECORD           21021 39090021
***   SYS1.LOGREC IS FULL                                               39200021
         OI    MCHINT+T2,X80           LOGREC FULL MESSAGE BIT    21021 39280021
         OI    REFLAGS,T1               SET SYS1.LOGREC FULL INDICATOR  39440020
         B     END                      RETURN TO NUCLEUS               39520020
         SPACE 5                                                        39600020
*                                                                     * 39680020
****     COMPLETE  UPDATING  OF  HEADER                                 39760020
*                                                                       39840020
TSETWRT  BE    TSETWRTB                 BR EQ - HEAD SWITCHING NOT REQ. 39920020
         OI    TFLAGS,THDSWTCH          SET EOF HEAD SWITCH REQ. SWITCH 40000020
TSETWRTB EQU   *                                                    IO  40060020
         MVC   TSRCHAD(T7),TLASTTTR     GET SEARCH ID               IO  40120020
         MVC   MCHIOBS1(T7),TLASTTTR    PUT BBCCHHR IN IOB FOR REC  IO  40180020
         SR    TWORK5,TWORK5            CLEAR REG.                      40240020
         IC    TWORK5,TLASTTT6          LOAD IN OF LAST REC WRITTEN     40320020
         LA    TWORK5,T1(TWORK5)        ADD ONE TO ID FIELD             40400020
         STC   TWORK5,TLASTTT6          UPDATE LAST ID WRITTEN IN HDR   40480020
*                                                                       40560020
         OI    TFLAGS,THDROK            SET HEADER COMPLETE SWITCH      40640020
         EJECT                                                          40720020
*********************************************************************** 40800020
* SECTION 2 -  COMPLETION AND WRITING OF RECORD ENTRY                 * 40880020
*                                                                     * 40960020
*     THIS SECTION COMPLETES THE CPU RECORD FOR RMS.  THE          IO * 41060020
*     FOLLOWING FIELDS ARE LOADED -                                   * 41200020
*                                                                     * 41280020
*                  RELABEL  - ASR (RECORD ENTRY LABEL)                * 41360020
*                  REFORMT  - 0   (FORMAT TYPE)                       * 41440020
*                  REMODNUM - NN  (CPU MODEL NUMBER)                  * 41520020
*                  RETYPE   - C/I (TYPE OF RECORD - CPU OR INBOARD)   * 41600020
*                  REDATE   - DATE                                    * 41680020
*                  RETIME   - TIME                                    * 41760020
*                  REPROGID - PROGRAM ID                              * 41840020
*           REAIOU/REACTIO  - ACTIVE I/O UNITS                        * 41920020
*         RECHASSG/RECHASG  - CHANNEL CONFIG                          * 42000020
*                  REPDAR   - JOB AND STEP NAMES                      * 42080020
*                                                                     * 42160020
*     THE RECORD IS THEN WRITTEN VIA THE I/O ROUTINE (SECTION 3).     * 42240020
*                                                                     * 42320020
*********************************************************************** 42400020
         SPACE 3                                                        42480020
*                                                                       42560020
* MOVE KEY LENGTH, DATA LENGTH, RE KEY                                  42640020
         MVI   CTFLDKEY,T2              SET KEY LENGTH                  42720020
         SPACE                                                          42800020
*    DETERMINE DATA LENGTH                                              42880020
         LH    TWORK5,XCPUL        GET CPU RECORD LENGTH                42960020
         CLI   RETYPE,CI           IS THIS A INBOARD RECORD         CCH 43040020
         BE    INBOARD             BR YES -CCH COMPLETED THE RECORD CCH 43120020
RELENGTH STH   TWORK5,CTFLDDL      PUT RECORD LENGTH IN COUNT FIELD     43200020
         SPACE                                                          43280020
         MVC   REKEY(T2),TREKEY         MOVE IN RECORD KEY              43360020
*    COPY PDAR INFR TO RECORDING AREA    *****                          43370020
         MVC   REPDARV1(T20),REPDAR1                                    43380020
         MVC   REVDOPSW(T8),MCHPSA+T48                        IH  45458 43390021
         SPACE 2                                                        43440020
         TM    RECTLND1,T2              IS THIS SECOND RECORD           43520020
         BO    TRECMPLT            YES,                                 43600020
****   MOVE LABEL AND FORMAT INTO RECORD ENTRY                          43680020
*                                                                       43760020
         MVC   RELABEL(T4),TIDENTFY     ASR LABEL IS MCH                43840020
         MVC   REMODNUM(T1),CPUMOD      PUT CPU MODEL IN RECORD         43920020
          SPACE  3                                                      43930020
**  MOVE MACHINE STATUS BLOCK FROM SYSTEM TO RECORD ENTRY               43940020
         L     TWORK1,MCHMSB           GET MSB ADDRESS                  43950020
         MVC   RESTATV(D40),0(TWORK1)     MOVE TO RECORD ENTRY          43960020
         SPACE                                                          44000020
*                                                                       44080020
****  MOVE DATE FROM CVT INTO RECORD ENTRY                              44160020
*                                                                       44240020
         L     TWORK1,CVTDATE      GET DATE FROM CVT                    44320020
         ST    TWORK1,REDATE       STORE DATE IN RECORD ENTRY           44400020
*                                                                       44480020
         SPACE                                                          44560020
*                                                                       44640020
****  COMPUTE LOCAL TIME OF DAY FOR RECORD ENTRY                        44720020
*                                                                       44800020
         SR    TWORK1,TWORK1            CLEAR REG.                      44880020
         AL    TWORK1,CVTTPC            LOAD PTR TO PSEUDO-CLOCKS       44960020
         BNL   PROGID                  NO CLOCKE                   IO   45060020
         L     TWORK2,TSHPC(TWORK1) LOAD 6  HOUR PSEUDO CLOCK           45200020
         AL    TWORK2,TT4PC(TWORK1) ADD 24 HOUR  PSEUDO CLOCK           45280020
         L     TWORK3,T80               LOAD HARDWARE TIMER             45360020
         SRA   TWORK3,T1                HALVE- CONVERT TO 26 UL INCREM. 45440020
         SLR   TWORK2,TWORK3        SUBTRACT TIMER                      45520020
***       PTF FOR APAR 37153                                            45530020
         CL    TWORK2,TD24HRS          IS VALUE OVER 24 HOURS           45540020
         BL    NOT24                   NO, SKIP CORRECTION              45550020
         AL    TWORK2,TDADJ         YES,ADD  CORRECTION FACTER          45560020
NOT24    EQU   *                                                        45570020
***      END OF FIX FOR APAR 37153                                      45580020
         AL    TWORK2,TLTPC(TWORK1) ADD LOCAL TIME PSEUDO CLOCK         45600020
         BC    T3,TADJUST               BRANCH ON OVERFLOW              45680020
         CL    TWORK2,TD24HRS       CHECK FOR OVER 24 HOURS             45760020
         BM    TADJUSTA                 BRANCH IN NOT OVER 24 HOURS     45840020
TADJUST  AL    TWORK2,TDADJ         ADD 7+ HOURS CORRECTION FACTOR      45920020
TADJUSTA ST    TWORK2,RETIME            STORE TIME IN RECORD ENTRY      46000020
         SPACE 2                                                        46080020
         SPACE 2                                                        46160020
*                                                                       46240020
****  MOVE PROGRAM ID FROM RB (MFT) OR CONTENTS DIRECTORY ENTRY (MVT)   46320020
*                                                                       46400020
PROGID   EQU   *                                                   IO   46440020
         SR    TWORK2,TWORK2                                            46480020
         CLR   TWORK2,TCBREG       TEST TCBREG FOR ZERO ADDRESS         46560020
         BE    CHKTYPE                  BR ZERO - NO PROG IDENTITY      46640020
         L     TWORK1,TOPRBP(TCBREG) LOAD ADDR OF TOP RB                46720020
         TM    CVTDCB,TMVT         CHK MVT, NO-WAIT TCBS IN MFT         46800020
         BZ    TRBSRCH                  NO-WAIT                         46880020
         TM    XRBPSW(TWORK1),WAITBIT    IS THIS A WAIT TCB IN MVT SYS. 46960020
         BO    CHKTYPE                  BR YES - NO RB                  47040020
TRBSRCH  TM    TRBSTAB(TWORK1),TPRB     TEST RB FOR PRB TYPE            47120020
         BNE   TNOTPRB                  BR, NOT A PRB                   47200020
         LR    TWORK2,TWORK1       SAVE PRB ADDRESS                     47280020
TNOTPRB  TM    TRBSTAB1(TWORK1),TRBTCB  DOES LINK FLD POINT TO TCB      47360020
         BO    TRBEND                   BR YES - END OF RB LIST         47440020
         L     TWORK1,TRBLNK(TWORK1) LOAD NEXT RB ADDRESS               47520020
         B     TRBSRCH               CHECK NEXT RB FOR PRB TYPE         47600020
*                                                                       47680020
TRBEND   LTR   TWORK2,TWORK2       WAS PRB ADDRESS SAVED                47760020
         BZ    CHKTYPE                  BR - NO PRB - NO PROGRAM ID     47840020
         TM    CVTDCB,TMVT         IS SYSTEM MVT OR MFT                 47920020
         BO    TRBMVT              MVT-ID IN CDE                        48000020
         LM    TWORK3,TWORK4,T0(TWORK2) GET ID FROM RB FOR MFT          48080020
         STM   TWORK3,TWORK4,REPROGID   STORE ID IN RE                  48160020
         B     CHKTYPE                  GO CHECK TYPE                   48240020
TRBMVT   L     TWORK2,TRBCDE(TWORK2)    GET PTR TO CNTNTS DRECTRY ENTRY 48320020
         LM    TWORK3,TWORK4,TCDNAME(TWORK2)   GET ID FROM CDE          48400020
         STM   TWORK3,TWORK4,REPROGID          STORE ID IN RE           48480020
         SPACE 2                                                        48560020
CHKTYPE  EQU   *                                                        48640020
         CLI   COMPSAD,T1               DID MCI OCCUR IN CCH        CC  48720020
         BNE   TJOBSTP             BR NO                                48800020
         MVC   REPDAR(T8),CCHNAME       INDICATE CCH IN JOB NAME        48880020
         B     CPUCMPLT                 SKIP MCH MOVES                  48960020
         SPACE                                                          49040020
*                                                                       49120020
****  MOVE JOB AND STEP NAMES TO RECORD ENTRY                           49200020
*                                                                       49280020
TJOBSTP  LTR   TCBREG,TCBREG       TEST FOR ZERO ADDRESS                49360020
         BZ    CPUCMPLT            ZERO - SKIP MCH MOVES                49440020
         L     TWORK1,TCBTIO(TCBREG)    GET TIOT ADDR                   49520020
         LTR   TWORK1,TWORK1            TEST FOR ZERO ADDRESS           49600020
         BZ    CPUCMPLT                 BR - TIOT NOT IN                49680020
         LM    TWORK2,TWORK5,T0(TWORK1)      GET JOB AND STEP NAMES     49760020
         STM   TWORK2,TWORK5,REPDAR     STORE IN COMMON AREA  IH  45458 49840021
         STM   TWORK2,TWORK5,REPDARV   STORE IN RECORD ENTRY  IH  45458 49890021
CPUCMPLT LA    TWORK4,REAIOU            ADDR IN CPU RE FOR ACTIVE I/O   49920020
         B     TACTIO2                  MOVE ACTIVE I/O                 50000020
         SPACE 2                                                        50080020
****     WRITE INBOARD RECORD ON SYS1.LOGREC                       CCH  50160020
INBOARD  EQU  *                                                         50240020
         LA    TWORK5,TWRTCCW           GET WRITE CCW LIST ADDR     CCH 50320020
         ST    TWORK5,MCHICCWS    ST CHAN PROG ADDR IN IOB              50420020
         MVC   TWRTCCWB(T3),REGGPR13+T1 COUNT,KEY,DATA ADDR IN CCW  CCH 50560020
*                                       PASSED BY CCH               CCH 50640020
         L     TWORK5,REGGPR13          ADDR OF INBOARD RECORD      CCH 50720020
         MVC   0(T5,TWORK5),TLASTTT2   INSERT CCHHR FROM HEADER TO CCH  50800020
*                                COUNT FIELD IN RECORD             CCH  50880020
         MVI   T5(TWORK5),X02          SET KEY LENGTH IN RECORD    CCH  50960020
         LH    TWORK3,T6(TWORK5)   GET ACTUAL DATA LENGTH           CCH 51040020
         LA    TWORK3,T10(TWORK3)  ADD COUNT2KEY LENGTH             CCH 51120020
         STH   TWORK3,TCOUNT            COMPLETE LENGTH             CCH 51200020
         B     NOT2                     GO TO WRITE INBOARD         CCH 51280020
*                                                                       51360020
****  MOVE ACTIVE I/O UNIT ADDRESSES TO RECORD ENTRY                    51440020
*                                                                       51520020
TACTIO2  LA    TWORK3,T8                MAY I/O UNIT ADDRESSES TO MOVE  51680021
         L     TWORK2,CVTILK2      ADDR OF TWO-BYTE UCB ADDRESS LIST    51760020
*                                                                       51840020
TUCBTEST LH    TWORK1,T0(TWORK2)        GET UCB POINTER                 51920020
         LA    TWORK2,T2(TWORK2)        UPDATE UCB POINTER ADDRESS      52000020
         LTR   TWORK1,TWORK1       TEST FOR END OF UCB POINTER TABLE    52080020
         BM    TCHASGN                  BR- END, STORE CHANNEL ASSIGN.  52160020
         BZ    TUCBTEST                 BR IF DUMMY ZERO ADDRESS        52240020
         TM    TUCBACT(TWORK1),H80      TEST UCB FOR UNIT ACTIVE        52320020
         BZ    TUCBTEST                 BR - NOT ACTIVE, TRY NEXT UCB   52400020
         LH    TWORK1,TUCBCUA(TWORK1) GET CHANNEL/UNIT ADDRESS          52480020
         STH   TWORK1,T0(TWORK4)        STORE CUA IN RE AREA            52560020
         LA    TWORK4,T2(TWORK4)        UPDATE RE AREA ADDR             52640020
         BCT   TWORK3,TUCBTEST     BR, CHK NEXT UCB                     52720020
         SPACE 2                                                        52800020
*                                                                       52880020
****  MOVE SYSTEM CHANNEL CONFIGURATION TO RECORD ENTRY                 52960020
*                                                                       53040020
TCHASGN  L     TWORK4,COMCHASG     ADDR OF CONFIG FROM COMMUN AREA      53120020
         LM    TWORK3,TWORK4,T0(TWORK4)       GET CONFIG                53200021
         OI    RECTLIND+T1,T16         SET EREP INDICATOR      CD 52708 53250026
MRECMPLQ STM   TWORK3,TWORK4,RECHASSG-T4         STORE IN CPU RE ENTRY  53600021
         MVC   RERMSECC(D8),X80    MOVE ECC AND HIR COUNTERS TO RE      53680020
TRECMPLT EQU   *                                                        53760020
         NI    RECTLIND,HBF        TURN RE INCOMPLETE INDICATOR OFF TO  53840020
*                                    INDICATE RE COMPLETE.              53920020
         SPACE 2                                                        54000020
*                                                                       54080020
****       WRITE RECORD ON SYS1.LOGREC                                  54160020
*                                                                     * 54240020
         MVC   TCOUNT(T2),CTFLDDL       GET LENGTH FROM COUNT FIELD     54320020
         LA    TWORK5,TWRTCCW          GET CHANNEL PROG                 54420020
         ST    TWORK5,MCHICCWS    ST CHAN PROG ADDR IN IOB              54520020
         MVC   CTFLDID(T5),TLASTTT2     SET COUNT FIELD ID FOR RE       54640020
         TM    RECTLND1,T2              SECOND CPU RECORD               54720020
         BZ    NOT2                NO                                   54800020
         LA    TWORK3,CTFLDID6          SET TO DOUBLE WORD              54880020
         AH    TWORK3,CPUL1        ADD FIRST RECORD LENGTH              54960020
         MVC   T0(T18,TWORK3),CTFLDID   MOVE HEADER FOR SECOND RECORD   55040020
         OI    COMINTEL,H80             SET BIT- STOP RETURN TO SYSTEM  55120020
NOT2     EQU   *                                                        55140020
         L     TLINK,MCHEXCP           IOS INTERFACE ROUNTINE           55160020
         LA    TWORK1,MCHIOB           IOB ADDRESS                      55180020
         BALR  R14,TLINK                IOS INTERFACE TO WRITE REC  IO  55200020
         B     RIGHTIO2                 SUCCESSFUL IO               IO  55220020
         B     TERMNATE                 UNSUCCESSFUL IO             IO  55240020
RIGHTIO2 EQU   *                                                   IO   55260020
         EJECT                                                          55280020
*                                                                       55360020
****    WRITE  END OF FILE (EOF)                                        55440020
*                                                                       55520020
*  EOF MUST BE WRITTEN TO CONFORM TO MOVE/COPY UTILITY'S NEED  FOR A    55600020
*     IF THE RECORD WAS NOT WRITTEN ON THE LAST TRACK IN EXTENT, EOF    55680020
*  IS WRITTEN ON LAST TRACK. IF IT IS, EOF IS WRITTEN AS  NEXT RECORD.  55760020
*     WHEN EOF WON'T FIT, IT IS NOT WRITTEN -NO HARM,BECAUSE IT IS THE  55840020
*  END OF THE DATA SET.                                                 55920020
         SPACE 2                                                        56000020
         TM    TFLAGS,THDSWTCH          TEST IF HEAD SWITCHING REQUIRED 56080020
         BO    TSWITCH                  WRT EOF ON LAST TRACK           56160020
         MVC   TSRCHAD(T7),TLASTTTR     MOVE SEARCH ARGUMENT TO BUFFER  56240020
         B     TWRTEOF                  WRITE EOF AS NEXT RECORD        56320020
TSWITCH  MVC   TSRCHAD2(T4),TUPLIMIT    MOVE SEARCH ARGUMENT TO BUFFER  56400020
         MVI   TSRCHAD6,T0              SET ID FIELD TO ZERO            56480020
TWRTEOF  EQU   *                                                    IO  56560020
         MVC   TEOFREC(T4),TSRCHAD2     MOVE CCHH TO EOF RECORD     IO  56640020
         LA    TWORK5,TEOFCCW           GET ADDR OF WRITE EOF CCW LIST  56720020
         ST    TWORK5,TICADDR           STORE AS TIC ADDR               56800020
         MVC   EOFTIC(T3),TICADDR1      MOVE TO EOF WRITE TIC CCW       56880020
         ST    TWORK5,MCHICCWS          PUT EOF CHAN PROG IN IOB    IO  56890020
         MVC   MCHIOBS1(T7),TSRCHAD  PUT BBCCHHR INTO IOB-IOB           56900020
         LA    TWORK1,MCHIOB           IOB ADDRESS                      56910020
         L     TLINK,MCHEXCP           IOS INTERFACE ROUNTINE           56920020
         BALR  R14,TLINK                IOS INTERFACE TO WRITE EOF  IO  56930020
         B     RIGHTIO3                 SUCCESSFUL IO               IO  56940020
         B     TERMNATE                 UNSUCCESSFUL IO             IO  56950020
RIGHTIO3 EQU   *                                                   IO   56960020
         SPACE 2                                                        57040020
*                                                                       57120020
*** REWRITE UPDATED HEADER RECORD                                       57200020
*                                                                       57280020
         LA    TWORK5,THDRCCW1          GET ADDR OF WRITE HDR CCW LIST  57360020
         ST    TWORK5,TICADDR           STORE AS TIC ADDR               57440020
         MVC   HDRWRTIC(T3),TICADDR1    MOVE TO HDR WRITE TIC CCW       57520020
         ST    TWORK5,MCHICCWS          PUT CHAN PROG IN IOB -HEAD  IO  57600020
         MVC   TSRCHAD(T7),TDSADRSV     MOVE SEEK ADDRESS               57680020
         MVC   MCHIOBS1(T7),TSRCHAD  PUT BBCCHHR INTO IOB-HEADER        57700020
         LA    TWORK1,MCHIOB           IOB ADDRESS                      57720020
         L     TLINK,MCHEXCP           IOS INTERFACE ROUNTINE           57740020
         BALR  R14,TLINK                IOS INTERFACE TO WRITE HEAD IO  57760020
         B     RIGHTIO4                 SUCCESSFUL IO               IO  57780020
         B     TERMNATE                 UNSUCCESSFUL IO             IO  57800020
RIGHTIO4 EQU   *                                                        57820020
         OI    COMINTEL,H01        INDICATE RECORD ENTRY WRITTEN        57840020
         SPACE 2                                                        57920020
*                                                                       58000020
*** NORMAL END                                                          58080020
*      THIS IS THE NORMAL END EXIT FROM THIS MODULE.  IT IS USED WHEN A 58160020
*      CPU RECORD HAS BEEN WRITTEN SUCCESSFULLY, OR WHEN THE CPU RECORD 58240020
*      COULD NOT BE WRITTEN BECAUSE OF LACK OF RECORDING ROOM.  RETURN  58320020
*      IS MADE TO THE ASR NUCLEUS.                                      58400020
         SPACE                                                          58480020
END      EQU   *                                                        58560020
         CLI   RETYPE,CC                WAS THIS A CPU RECORDING        58640020
         BNE   TERMINB             BR NO                                58720020
         TM    REFLAGS,T1               IS SYS1.LOGREC FULL             58800020
         BO    RETRN               YES, RETURN TO NUC                   58880020
         TM    RECTLND1,T2              IS SECOND RECORD COMPLETE       58960020
         BO    CHKSOFT             YES                                  59040020
         CLC   CPUL2(T2),ONE            IS THERE A SECOND CPU RECORD    59120020
         BE    CHKSOFT             NO SECOND RECORD                     59200020
         OI    RECTLND1,T2              SET SECOND RECORD INDICATOR     59280020
         MVI   TFLAGS,T0                CLEAR INDICATOR                 59360020
         MVC   XCPUL(T2),CPUL2          MOVE SECOND CPU RECORD LENGTH   59440020
         B     TSTARTA             GO PUT OUT SECOND RECORD             59520020
       SPACE 5                                                          59530021
*  LOGREC DCB IS PERMANENT OPEN AFTER NIP AND IT IS PRIVATELY OWNED     59540021
*    BY (EREP,SER,OBR). AFTER THE  REGULAR DCB LENGTH,A 256 BYTE WORK   59550021
*   AREA IS ADDED IF MCH IS PRESENT.  IN THIS WORKAREA AT DISPLACEMENT  59560021
*    299(12B) FROM START OF DCB, A BIT IS USED FOR OBR-IN-PROGRESS(08), 59570021
*    WHICH IS SET AND CLEARED BY OBR.                                   59580021
CHKSOFT  EQU   *                                                        59600020
         TM    MCIOPSW3,X08        WAS IT A SOFT MCI                    59680020
         BO    DCBADR              YES,BRANCH TO GET DCB ADDRESS        59760020
         CLI   COMPSAD,T1               IF YES, DID MCI OCCUR IN CCH    59840020
         BE    TERMCCH             BR YES, TO TERMINATE, CANT RECOVER   59920020
DCBADR   EQU   *                                                        60000020
         L     TWORK1,CVTDCB       DCB FOR LOGREC DATA SET USED BY RMS  60080020
         LA    TWORK1,T0(TWORK1)   IS SYS1.LOGREC IN                    60160020
         TM    OBRBIT(TWORK1),X08                IN USE BY OBR          60240021
         BZ    RETRN                   NO- CONTINUE NORMALLY            60320021
         SPACE                                                          60400020
*  CHECK IF MCI IN OBR (IF CURRENT TCB IS OBR, THE SIRB WILL BE OFF     60480020
*                            THAT TCB.)                                 60560020
         LTR   TCBREG,TCBREG       TEST FOR ZERO ADDRESS                60640020
         BZ    NOTOBR              ZERO - NOT OBR                       60720020
         L     TWORK1,TOPRBP(TCBREG)  LOAD ADDR OF TOP RB               60800020
         TM    CVTDCB,TMVT         CHK MVT, NO WAIT TCB IN MFT          60880020
         BZ    SIRBSRCH                 CHECK SIRB TYPE                 60960020
         TM    XRBPSW(TWORK1),WAITBIT  IS THIS A WAIT TCB               61040020
         BO    NOTOBR                BR YES - NO RB  AND CURRENT NOTOBR 61120020
SIRBSRCH TM    TRBSTAB(TWORK1),TSIRB   TEST RB FOR SIRB TYPE            61200020
         BZ    NOTSIRB                 BR NO                            61280020
         TM    TRBSTAB(TWORK1),H70      INSURE RE IS SIRB               61360020
         BZ    OBRSIRB                 BR YES -CURRENT IS OBR           61440020
NOTSIRB  TM    TRBSTAB1(TWORK1),TRBTCB    DOES LINK FIELD PNT TO TCB    61520020
         BO    NOTOBR                   BR YES, END OF RB LIST, NOT OBR 61600020
         L     TWORK1,TRBLNK(TWORK1)    GET NEXT RB ADDR                61680020
         B     SIRBSRCH                 CHECK NEXT RB FOR SIRB TYPE     61760020
*                                                                       61840020
*  CURRENT IS OBR - MCI IN OBR - CHANGE ASR'S RESUME PSW TO EXIT RTN    61920020
OBRSIRB  EQU   *                                                        61970021
         MVC   REMCOPSW(T3),COMOBRX1    WHICH IS IN MCH NUCLEUS         62020021
         B     RETRN                    RETURN                          62080020
*                                                                       62160020
*  CURRENT IS NOT OBR (TASK SWITCH) - CHANGE SIRB PSW TO OBR EXIT RTN   62240020
*    IN THE ASR NUCLEUS.  THIS ROUTINE CAUSES OBR TO BE TERNINATED.     62320020
NOTOBR   EQU   *                                                        62370020
         L     TWORK1,MCHSIRB          GET SIRB ADDRESS                 62420020
         MVC   T21(T3,TWORK1),COMOBRX1  CHANGE PSW                      62480020
         SPACE                                                          62560020
         SPACE                                                          62720020
RETRN    EQU   *                                                        62770020
         LM    DEPREG,R14,TREGSAVE     RESTORE REGS                     62820020
         NI    COMINTEL,H7F        CLEAR-BIT FOR RETURN TO SYSTEM       62880020
         MVI   MCHNXMOD,NEXT5A          SUCCESSOR PATH NO TO 12     IO  62980020
         BR    R14                 RETURN TO NUC                        63120020
         SPACE 2                                                        63200020
*                                                                       63280020
*** ERROR TERMINATION                                                   63360020
*                                                                       63440020
*      THIS ERROR EXIT IS TAKEN BECAUSE OF-                             63520020
*        (1) I/O OVERRUN READING HEADRE RECORD                          63600020
*        (2) I/O ERROR IN SECTION 3 I/O ROUTINE, WHILE TRYING TO WRITE  63680020
*           CPU RECORD.                                                 63760020
*       (3) HARD MCI IN CCH (WAIT CODE = A0B).                          63840020
*       (4) CHANNEL INBOARD ERROR RECORDING (WAIT CODE = A0A).          63920020
*                                                                       64000020
*  THE WAIT  CODES ARE SET FOR ASR NUCLEUS, WHICH PUTS THE              64080020
*  MACHINE IN WAIT STATE.  THE I/O ERRORS RETURN TO ASR NUCLEUS,        64160020
*  NORMALLY, WHERE IF THE ERROR IS SEVERE, FURTHER ACTION IS TAKEN.     64240020
         SPACE 2                                                        64320020
TERMCCH  EQU   *                                                        64370020
         L     TWORK8,MCHIPTR           PRINT BUFFER ADDR           IO  64420020
         MVI   T0(TWORK8),H23      MOVE MESSAGE CODE INTO BUFFER        64480020
         B     WAITST              BRANCH TO SET FOR WAIT STATE         64560020
TERMNATE EQU   *                                                        64640020
         CLI   RETYPE,CI                IS THIS AN INBOARD RECORDING    64720020
         BE    TERMINB                  YES                             64800020
         TM    MCIOPSW3,X08        WAS IT A SOFT MCI                    64880020
         BO    PREP029             YES,BRANCH TO PREPARE IGF029I MSG    64960020
         CLI   COMPSAD,T1          MCI OCCUR IN CCH                     65040020
         BE    TERMCCH                  YES - CANNOT RECOVER            65120020
         B     PREP029                  GO PREPARE IGF029I MESSAGE      65200020
TERMINB  EQU   *                                                    IO  65250020
         L     TWORK8,MCHIPTR           PRINT BUFFER ADDRESS        IO  65300020
         MVI   T0(TWORK8),H24      MOVE MESSAGE CODE INTO BUFFER        65360020
WAITST   OI    COMINTEL,H40        SET WAIT CODE BIT                    65440020
         LA    TWORK8,T1(TWORK8)   STEP POINTER                         65520020
         ST    TWORK8,MCHIPTR           UPDATED PRINT BUFFER        IO  65600020
         B     RETRN               RETURN TO NUCLEUS                    65680020
         SPACE                                                          65760020
*              PREPARE 029 MESSSAGE                                     65840020
PREP029  EQU   *                                                        65920020
         L     TWORK8,MCHIPTR           PRINT BUFFER ADDRESS        IO  66000020
         MVC   T0(T2,TWORK8),H88        MOVE MESSAGE CODE AND LENGTH    66080020
         LA    TWORK8,T2(TWORK8)        STEP POINTER                    66160020
         CLC   ZEROS(T8),H40            IS CSW EQUAL TO ZEROS           66720020
         BE    NOCSW                    YES                             66800020
         LA    TWORK2,H40               ADDRESS OF CSW                  66880020
         LA    TWORK3,T0(TWORK8)                                        66960020
         LA    TWORK6,T8                8BYTES - CSW                    67040020
         BAL   TWORK7,EBCNVT            GO CONVERT CSW                  67120020
NOCSW    EQU   *                                                        67180020
         LA    TWORK8,T14(TWORK8)  FOR 29I MESSAGE            IE   2491 67240000
         ST    TWORK8,MCHIPTR           UPDATED PRINT BUFFER        IO  67300020
         B     RETRN                    RETURN TO NUCLEUS               67360020
         SPACE                                                          67440020
*                                                                     * 67520020
*              ROUTINE TO CONVERT HEX CHARS TO EBCDIC FOR PRINTING    * 67600020
*                                                                     * 67680020
*        INPUT  TWORK2 - ADDRESS OF FIELD TO BE CONVERTED             * 67760020
*               TWORK3 - ADDRESS OF FIRST OUTPUT EBCDIC BYTE          * 67840020
*               TWORK6 - COUNT OF BYTES IN FIELD TO BE CONVERTED      * 67920020
*               TWORK7 - LINK REG.                                    * 68000020
*                                                                     * 68080020
EBCNVT   EQU   *                                                        68160020
         SR    TWORK4,TWORK4            CLEAR WORK REG. (FOR HI ORDER)  68240020
         IC    TWORK4,T0(TWORK2)        GET CHARACTER                   68320020
         SRDL  TWORK4,T4                SAVE HI-ORDER BITS              68400020
         SRL   TWORK5,T28               SAVE LO-ORDER BITS              68480020
         IC    TWORK4,TABLE(TWORK4)     GET EBCDIC EQUIVALENT           68560020
         IC    TWORK5,TABLE(TWORK5)      CHARACTERS FROM TABLE          68640020
         STC   TWORK4,T0(TWORK3)        STORE CHARS.                    68720020
         STC   TWORK5,T1(TWORK3)         IN OUTPUT AREA                 68800020
         LA    TWORK2,T1(TWORK2)        UPDATE INPUT ADDRESS            68880020
         LA    TWORK3,T2(TWORK3)        UPDATE OUTPUT ADDRESS           68960020
         BCT   TWORK6,EBCNVT            CHECK NEXT BYTE                 69040020
         BR    TWORK7                   RETURN                          69120020
         SPACE                                                          69200020
TABLE    DC    C'0123456789ABCDEF'      HEX CHARS,F0,F1,F2,83,F4,ETC    69280020
         EJECT                                                          69360020
         EJECT                                                          75440020
*                                                                       75520020
***** CONSTANTS    **************************************************** 75600020
*                                                                       75680020
         SPACE 5                                                        75760020
TREKEY   DC    X'FF00'                  RECORD ENTRY KEY                75840020
TIDENTFY DC    C'MCH0'                  MCH LABEL                       75920020
CCHNAME  DC    C'MCI-CCH '              MACHINE CHECK IN CCH            76000020
         DS    0D                       ALIGNMENT                       76080020
***       PTF FOR APAR 37153                                            76120020
TD24HRS  DC    X'C5C10000'        24 HOUR PSEUDO CLOCK FACTOR           76160020
TDADJ    DC    X'3A3F0000'        PSEUDO-CLOCK CORRECTION FACTOR        76200020
***      END OF FIX FOR APAR 37153                                      76240020
         SPACE                                                          76320020
TSRCHAD  DC    XL8'0'                   SEARCH ADDRESS                  76400020
TSEEKADR DC    XL8'0'                   SEEK ADDRESS                    76480020
TDSADRSV DC    XL8'0'                   SAVE AREA FOR SYS1.LOGREC ADDR. 76560020
TSENSD   DC    XL8'0'                   SENSE DATA AREA                 76640020
TEOFREC  DC    XL4'0'              EOF RECORD                           76720020
         DC    X'FF000000'              ID OF EOF RECORD                76800020
TBUFR0   DC    F'0'                     R0 BUFFER                       76880020
WORKAREA DC    F'0'                     CCW DATA ADDRESS WORK AREA      76960020
TICADDR  DC    XL4'0'                   CCW START ADDRESS FOR TIC       77040020
         SPACE                                                          77120020
MESSAGE  DC    2D'0'                    MESSAGE WORK AREA               77200020
H09      EQU   X'09'                    MESSAGE CODE - IGF033I RUN EREP 77280020
H40      EQU   64                       PSA ADR. OF CSW                 77360020
H88      DC    X'8710'                  REQUEST FOR IGF029I MSG     IO  77440020
ZEROS    DC    D'0'                     ZEROS                           77520020
         EJECT                                                          77600020
*                                                                       77680020
****  CCW LISTS                                                         77760020
*                                                                       77840020
*     THE FOLLOWING CCWS  DIRECT ALL I/O DATA TRANSMISSION.  THE ADDR   77920020
*     FIELD   TSRCHAD IS  DYNAMICALLY                                   78000020
*     SET BY THE MODULE.  THE ADDRESSES OF THESE ADDR FIELDS            78080020
*     ARE STORED IN THE CCWS IN SECTION 1 OF THIS MODULE.               78160020
         SPACE 2                                                        78240020
         SPACE 5                                                        80480020
*  READ  HEADER  RECORD                                                 80560020
THDRCCW  DC    X'31'                    SEARCH ON ID EQUAL COMMAND      80640020
THDRCCWA DC    XL3'0'                   SEARCH ADDRESS                  80720020
         DC    X'40'                    COMMAND CHAIN                   80800020
         DC    XL2'0'                   NOT USED                        80880020
         DC    X'05'                    COUNT                           80960020
         SPACE                                                          81040020
         DC    X'08'                    TRANSFER IN CHANNEL COMMAND     81120020
HDRDTIC  DC    XL3'0'                   THDRCCC ADDRESS                 81200020
         DC    X'40'                    COMMAND CHAIN                   81280020
         DC    XL2'0'                   NOT USED                        81360020
         DC    X'01'                    COUNT                           81440020
         SPACE                                                          81520020
         DC    X'06'                    READ COMMAND TO READ HEADER REC 81600020
RDHDR    DC    XL3'0'                   HEADER RECORD AREA ADDRESS      81680020
         DC    X'00'                    NOT USED                        81760020
         DC    XL2'00'                  NOT USED                        81840020
         DC    X'28'         COUNT                                21021 81920021
         SPACE 5                                                        82000020
*  WRITE HEADER RECORD                                                  82080020
         SPACE 2                                                        82160020
THDRCCW1 DC    X'31'                    SEARCH ON ID EQUAL COMMAND      82240020
THDRCCWB DC    XL3'0'                   SEARCH ADDRESS                  82320020
         DC    X'40'                    COMMAND CHAIN                   82400020
         DC    XL2'0'                   NOT USED                        82480020
         DC    X'05'                    COUNT                           82560020
         SPACE                                                          82640020
         DC    X'08'                    TRANSFER IN CHANNEL COMMAND     82720020
HDRWRTIC DC    XL3'0'                   THDRCCW1 ADDRESS                82800020
         DC    X'40'                    COMMAND CHAIN                   82880020
         DC    XL2'0'                   NOT USED                        82960020
         DC    X'01'                    COUNT                           83040020
         SPACE                                                          83120020
         DC    X'05'                    WRITE COMMAND TO WRITE HEADER   83200020
WRTHDR   DC    XL3'0'                   HEADER RECORD AREA ADDRESS      83280020
         DC    X'00'                    NOT USED                        83360020
         DC    XL2'0'                   NOT USED                        83440020
         DC    X'28'         COUNT                                21021 83520021
         EJECT                                                          83600020
*  WRITE  RECORD  ENTRY                                                 83680020
         SPACE                                                          83760020
TWRTCCW  DC    X'31'                    SEARCH ON ID EQUAL COMMAND      83840020
TWRTCCWA DC    XL3'0'                   SEARCH ADDRESS                  83920020
         DC    X'40'                    COMMAND CHAIN                   84000020
         DC    XL2'0'                   NOT USED                        84080020
         DC    X'05'                    COUNT                           84160020
         SPACE                                                          84240020
         DC    X'08'                    TRANSFER IN CHANNEL COMMAND     84320020
WRTRETIC DC    XL3'0'                   TWRTCCW ADDRESS                 84400020
         DC    X'40'                    COMMAND CHAIN                   84480020
         DC    XL2'0'                   NOT USED                        84560020
         DC    X'01'                    COUNT                           84640020
         SPACE                                                          84720020
TWRTCCW1 DC    X'1D'                    WRITE COUNT, KEY, DATA COMMAND  84800020
TWRTCCWB DC    XL3'0'                   COUNT,KEY, DATA ADDRESS         84880020
         DC    X'2000'                  SILI BIT                        84960020
TCOUNT   DC    XL2'0'                   COUNT (8+ KEY LENGTH + DATA L.) 85040020
         SPACE 5                                                        85120020
*    WRITE  EOF                                                         85200020
         SPACE                                                          85280020
TEOFCCW  DC    X'31'                    SEARCH ON ID EQUAL COMMAND      85360020
TEOFCCW1 DC    XL3'0'                   SEARCH ADDRESS                  85440020
         DC    X'40'                    COMMAND CHAIN                   85520020
         DC    XL2'0'                   NOT USED                        85600020
         DC    X'05'                    COUNT                           85680020
         SPACE                                                          85760020
         DC    X'08'                    TRANSFER IN CHANNEL COMMAND     85840020
EOFTIC   DC    XL3'0'                   TEOFCCW ADDRESS                 85920020
         DC    X'40'                    COMMAND CHAIN                   86000020
         DC    XL2'0'                   NOT USED                        86080020
         DC    X'01'                    COUNT                           86160020
         SPACE                                                          86240020
         DC    X'1D'                    WRITE COUNT,KEY, DATA COMMAND   86320020
EOFRECAD DC    XL3'0'                   EOF RECORD AREA ADDRESS         86400020
         DC    X'00'                    NOT USED                        86480020
         DC    XL2'0'                   NOT USED                        86560020
         DC    X'08'                    COUNT                           86640020
         SPACE 5                                                        86720020
*                                                                       86800020
****  INTERNAL MODULE FLAGS                                             86880020
*                                                                       86960020
         SPACE 2                                                        87040020
TFLAGS   DC    X'00'                    FLAG AREA                       87120020
*        BIT 1---                                                       87200020
*        BIT 2---                                                       87280020
*        BIT 3---HEADER RECORD READ AND UPDATED SUCCESSFULLY            87360020
*        BIT 4---                                                       87440020
*        BIT 5---                                                       87520020
*        BIT 6---HEAD SWITCHING REQUIRED TO WRITE END OF FILE           87600020
THDSWTCH EQU   X'02'                    EOF HEAD SWITCHING REQUIRED     87680020
THDROK   EQU   X'10'                    HEADER RECORD READ AND UPDATED  87760020
         EJECT                                                          87840020
*                                                                       87920020
****  SYSRES DEVICE TYPE SUBTRACTION CONSTANT TABLE                     88000020
*                                                                       88080020
*        THESE CONSTANTS REPRESENT THE TOTAL BYTE REQUIREMENTS FOR      88160020
*        MODEL 85 RECORDS ON A TRACK (CPU OR I/O). THE CONSTANTS WERE   88240020
*        COMPUTED USING THE GIVEN TRACK CAPACITY FORMULA FOR EACH       88320020
*        DEVICE TYPE. THE KEY LENGTH IS TWO BYTES. THE MCH RECORD       88400020
*        LENGTHS ARE 1106 AND 762 BYTES. THE CCH IS 116 BYTES.          88480020
         SPACE                                                          88560020
*              DATA RECORD CONSTANTS                                    88640020
         DS    0H                       ALIGN TO HALF WORD              88720020
CPUMOD   DC    X'85'                    MODEL 85                        88800020
REFLAGS  DC    X'00'                    SWITCH                          88880020
CPUL1    DC    X'0452'                  REC. 1-1096 + 10(HDR) = 1106 B. 88960020
CPUL2    DC    X'02FA'                  REC. 2- 752 + 10      =  762 B. 89040020
XCPUL    DC    XL2'0'                   CPU RECORD WORK AREA            89120020
         SPACE                                                          89280020
*  MCH TABLE   CONSTANT                 DEC       UCB TYPE  * DEVICE    89360020
TCONRE85 DC    XL2'4D1'                 1233      X'01'     *  2311     89440020
         DC    XL2'368'                  872      X'01'     *  2311     89520020
         DC    XL2'504'                 1284      X'02'     *  2301     89600020
         DC    XL2'3AC'                  940      X'02'     *  2301     89680020
         DC    XL2'4DC'                 1244      X'03'     *  2303     89760020
         DC    XL2'384'                  900      X'03'     *  2303     89840020
         DC    XL2'4D1'                 1233      X'04'     *  2302     89920020
         DC    XL2'368'                  872      X'04'     *  2302     90000020
         DC    XL2'4E4'                 1252      X'05'     *  2321     90080020
         DC    XL2'37B'                  891      X'05'     *  2321     90160020
         DC    XL2'6CE'                1742      X'06'     * 2305I  202 90240020
         DC    XL2'576'                1398      X'06'     * 2305I  202 90320020
         DC    XL2'573'                1395      X'07'     * 2305II 202 90400020
         DC    XL2'427'                1051      X'07'     * 2305II 202 90480020
         DC    XL2'50D'                 1293      X'08'     *  2314     90560020
         DC    XL2'3A5'                  933      X'08'     *  2314     90640020
         DC    XL2'513'                1299      X'09'     *  3330  202 90660020
         DC    XL2'3BB'                 955      X'09'     *  3330  202 90680020
TCONRE84 EQU   TCONRE85-4                                               90720020
         SPACE                                                          90800020
*  I/O TABLE   CONSTANT                 DEC       UCB TYPE  * DEVICE    90880020
TCONIO85 DC    XL2'C3'                  195       X'01'     *  2311     90960020
         DC    XL2'126'                 294       X'02'     *  2301     91040020
         DC    XL2'FE'                  254       X'03'     *  2303     91120020
         DC    XL2'C3'                  195       X'04'     *  2302     91200020
         DC    XL2'DC'                  214       X'05'     *  2321     91280020
         DC    XL2'2F0'                 752      X'06'     * 2305I  202 91360020
         DC    XL2'195'                 405      X'07'     * 2305II 202 91440020
         DC    XL2'103'                 259       X'08'     *  2314     91520020
         DC    XL2'135'                 309      X'09'     *  3330  202 91560020
TCONIO82 EQU   TCONIO85-2                                               91600020
         SPACE 2                                                        91680020
TREGSAVE DC    D'0'                     REG. SAVE AREA                  91760020
ONE      DC    F'1'                     ONE                          MP 91840020
         EJECT                                                          92160020
*                                                                       92240020
****     HEADER RECORD FROM SYS1.LOGREC                                 92320020
*            WHICH IS THE FIRST RECORD ON SYS1.LOGREC AND THIS IS       92340021
*            THE WORKAREA FOR THE FOLLOWING DSECT.                      92360021
*                                                                       92400020
THDRREC  DC    10F'0'                   AREA FOR HEADER                 92480020
HDRKEY   EQU   THDRREC+0           HEADER KEY                     21021 92510021
LOWLIMIT EQU   THDRREC+2           LOW CCHH OF EXTENT             21021 92540021
TUPLIMIT EQU   THDRREC+6           HIGH CCHH OF EXTENT            21021 92570021
SPARE    EQU   THDRREC+7           SPARE BYTE                     21021 92600021
RESTAREA EQU   THDRREC+11          RE START AREA-BBCCHHR          21021 92630021
TBYTSREM EQU   THDRREC+18          BYTES REMAINING ON TRACK       21021 92660021
TRKCAP   EQU   THDRREC+20          TOTAL BYTES ON TRACK           21021 92690021
TLASTTTR EQU   THDRREC+22          LAST RE WRITTEN-BB             21021 92720021
TLASTTT2 EQU   THDRREC+24                          CC             21021 92750021
TLASTTT4 EQU   THDRREC+26                            HH           21021 92780021
TLASTTT6 EQU   THDRREC+28                          R              21021 92810021
TRKPERCY EQU   THDRREC+29          TRACKS PER CYLINDER            21021 92840021
EWMC     EQU   THDRREC+31          90 PERCENT TRACK COUNT         21021 92870021
DEVCODE  EQU   THDRREC+33          DEVICE CODE                    21021 92900021
EWMT     EQU   THDRREC+34          90 PERCENT TRACK-CCHH          21021 92930021
SWITCHES EQU   THDRREC+38          SWITCHES                       21021 92960021
*                                  BIT0=EARLY WARNING MSG IS SCH  21021 92990021
TSFTYBYT EQU   THDRREC+39          CHECK BYTE-'FF'                21021 93020021
         SPACE 5                                                        93050021
TSEEKAD1 EQU   TSEEKADR+1               SEEK ADR.                       93200020
WORKARA1 EQU   WORKAREA+1               ADR. DISPLACEMENT               93280020
TSRCHAD2 EQU   TSRCHAD+2                SEARCH ADR. DISP                93360020
TSRCHAD6 EQU   TSRCHAD+6                                                93440020
TICADDR1 EQU   TICADDR+1                                                93520020
TRBSTAB1 EQU   TRBSTAB+1                                                93920020
*********             MAINTENANCE  AREA     *************               94020021
MAINID   DC    CL8'IGFMCH17'           CORE IDENTIFIER                  94120021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              94220021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 94320021
         EJECT                                                          94480020
***      DSECTS                                                         94560020
*                                                                       94640020
TCVTNAM  DSECT                                                          94720020
         CVT                                                            94800020
         EJECT                                                          94880020
MCHCOM   DSECT                                                          94930020
         MCHMAC                                                         94980020
         EJECT                                                          95000020
ASRCOM   DSECT                                                          95020020
         ASRMAC85                                                       95040020
CTFLDID6 EQU   CTFLDID+6                                                95120020
MCIOPSW3 EQU   REMCOPSW+3                                               95200020
RECTLND1 EQU   RECTLIND+1                                               95280020
MCHICCW1 EQU   MCHICCWS+1                                               95320020
MCHIOBS1 EQU   MCHIOBSK+1                                               95360020
COMPSAD  EQU   MCHPSA+115                                               95400020
COMINTEL EQU   MCHINTEL                                                 95440020
REGGPR13 EQU   REGSGPR+52          REG FOR CCH INTERFACE            CCH 95520020
COMOBRX1 EQU   COMOBREX+1                                               95600020
         END                                                            95920020
