         LCLA  &LEV,&REL                                                00100021
&LEV     SETA  20                                                       00150021
&REL     SETA  21                                                       00160021
&REL&LEV TITLE 'IGFMCH19 LEVEL &LEV MCH 85 MAIN STORAGE ANALYSIS'       00170021
*********************************************************************** 00200020
*                                                                       00300020
* TITLE  IGFMCH19 -- MAIN STORAGE ANALYSIS                              00400020
*                                                                       00500020
*********************************************************************** 00600020
*                                                                       00700020
* STATUS CHANGE LEVEL              000                                * 00800020
*                                                                       00900020
* FUNCTION                                                            * 01000020
*     *  TO PROVIDE SUFFICIENT DATA CONCERNING STORAGE DATA FAILURE   * 01100020
*     *  TO ASSIST THE C.E. IN MINIMIZING STORAGE REPAIR TIME         * 01200020
*     *  TO ASSIST THE CUSTOMER IN E.C.C. COUNT MODE DECISION MAKING  * 01300020
*     *  TO ASSURE CONTINUED STORAGE RELIABILITY                      * 01400020
*                                                                       01500020
* OPERATION                                                           * 01600020
*********************************************************************** 01700020
*                     ***  INITIALIZATION  ***                        * 01800020
*********************************************************************** 01900020
*                                                                       02000020
*     *  SAVES RMS/85 NUCLEUS MACHINE CHECK NEW PSW                   * 02100020
*     *  IDENTIFY IF FAILURE IS SINGLE BIT OR MULTIPLE BIT            * 02200020
*     *  SELECT THE PROPER EXIT MODULE ADDRESS (PDAR OR EREP)         * 02300020
*     *  FOR MULTIPLE BIT STORAGE DATA ERROR, AN I MESSAGE WILL BE    * 02400020
*     OUTPUTED VIA THE RMS MESSAGE MODULE RUNNING UNDER THE COMMUNICA-* 02500020
*     TION TASK.                                                      * 02600020
*                                                                     * 02800020
*********************************************************************** 02900020
*                        ***  EXERCISE  ***                           * 03000020
*********************************************************************** 03100020
*                                                                       03200020
*        THE EXERCISE ROUTINE EXERCISES THE FAILING LOCATION IN       * 03300020
*        ORDER TO BE ABLE TO CALSSIFY THE STORAGE FAILURE AS          * 03400020
*        EITHER 'SOLID' OR 'INTERMITTENT'. DIFFERENT PATTERNS ARE     * 03500020
*        THEN USED TO EXERCISE THE FAILING ADDRESS BY STORING AND     * 03600020
*        LOADING THE PATTERNS (1'S AND 0'S) TO DETECT FOR MACHINE     * 03700020
*        CHECK OR PICKING AND DROPPING OF BITS. THE RESULTS ARE THEN  * 03800020
*        RECORDED IN THE REMEST TABLE                                 * 03900020
*                                                                       04000020
*********************************************************************** 04100020
*                     ***  ID GENERATION  ***                         * 04200020
*********************************************************************** 04300020
*                                                                       04400020
*        THE ID GENERATION ROUTINE IDENTIFIES THE PHYSICAL STORAGE    * 04500020
*        UNIT ( CONTAINING THE FAILURE ) AND RECORDS THIS INFORM-     * 04600020
*        ATION IN REMEST TABLE FOR THE PURPOSE OF ASSISTING THE       * 04700020
*        C.E. THE ROUTINE UTILIZES THE CONFIGURATION DATA (OF THE     * 04800020
*        PARTICULAR SYSTEM) AND THE FAILING ADDRESS IN ORDER TO       * 04900020
*        IDENTIFY THE STORAGE UNIT IN ERROR . MCK NEW PSW OF THE      * 05000020
*        NUCLEUS IS RESTORED BEFORE EXIT TO EITHER 'PDAR' OR 'EREP'   * 05100020
*        VIA THE RMS/85 NUCLEUS                                       * 05200020
*                                                                       05300020
* ENTRY POINT  IGFMCH19                                                 05400020
* INPUT                                                               * 05500020
*     *  MACHINE CHECK OLD PSW                                        * 05600020
*     *  LOGOUT                                                       * 05700020
*     *  COMMON AREA                                                  * 05800020
* OUTPUT                                                              * 05900020
*     *  REMEST TABLE DOUBLEWORD 0 , 1 , 2                            * 06000020
*     *  MESSAGE IGF045I - FOR MULTIPLE - BIT ERROR                   * 06200020
* EXIT                                                                * 06300020
*       NORMAL - IGFMCHF1-F3 FOR MULTIPLE-BIT FAILURE                   06400020
*                IGFMCH17   FOR E.C.C. SINGLE-BIT FAILURE               06500020
*        ABNORMAL - VIA MACHINE CHECK NEW PSW TO RMS/85 NUCLEUS       * 06600020
*                                                                       06700020
*********************************************************************** 06800020
* NOTE                                                                * 06900020
*********************************************************************** 07000020
*     *  RMS/85 NUCLEUS WILL CLEAR REMEST (WITH ZEROS) BEFORE         * 07100020
*        MAIN STORAGE ANALYSIS RECEIVES CONTROL                       * 07200020
*     *  PRELIMINARY ERROR ANALYSIS WILL PERFORM THE FOLLOWING        * 07300020
*        TASKS BEFORE CONTROL IS PASSED TO THIS MODULE                * 07400020
*        1.    SAVE FAILING ADDRESS INTO REMEST                       * 07500020
*        2.    SET SWITCH DENOTING E.C.C. OR MULTIPLE-BIT ERROR       * 07600020
*        3.    SET SWITCH DENOTING 2365 OR 2385 STORAGE UNIT          * 07700020
*        4.    SAVE CONFIGURATION BYTE(S) DATA INTO REMEST            * 07800020
*     *  WHEN THIS MODULE GETS CONTROL, MACHINE CHECK INTERRUPT IS    * 07900020
*        ENABLED ALREADY FOR THE SYSTEM                               * 08000020
*                                                                       08100020
*********************************************************************** 08200020
*                                                                       08300020
*********************************************************************** 08400020
         EJECT                                                          08500020
*********************************************************************** 08600020
*                                                                     * 08700020
******              REMEST TABLE FOR RMS/85                      ****** 08800020
*                                                                     * 08900020
*********************************************************************** 09000020
* BYTE * BIT * CONTENT *           INDICATION                         * 09100020
*********************************************************************** 09200020
* DOUBLEWORD 0 --- NOT USED IN THIS MODULE                            * 09300020
*********************************************************************** 09400020
* DOUBLEWORD 1 --- PRIMARY ERROR REPORT                               * 09500020
*********************************************************************** 09600020
*  0   *  0  *    1    * PRIMARY ERROR ENTRY                          * 09700020
*      *  1  *    1    * REPAIRABLE RECOVERABLE DATA ERROR            * 09800020
*      *  2  *    1    * REPAIRABLE RECOVERABLE SPF ERROR             * 09900020
*      *  3  *    1    * NONRECOVERABLE ERROR                         * 10000020
*      *  4  *    1    * NOT USED IN THIS MODULE                      * 10100020
*      * 5-7 *    1    * UNUSED                                       * 10200020
*********************************************************************** 10300020
*  1   *  0  *    1    * NOT USED IN THIS MODULE                      * 10400020
*      *  1  *    1    * SPF FAILURE                                  * 10500020
*      *  2  *    1    * UNUSED                                       * 10600020
*      *  3  *    1    * KEY MATCHING FAILURE                         * 10700020
*      *  4  *    1    * NOT USED IN THIS MODULE                      * 10800020
*      *  5  *    1    * DATA FAILURE                                 * 10900020
*      *  6  *    1    * NOT USED IN THIS MODULE                      * 11000020
*      *  7  *    1    * UNUSED                                       * 11100020
*********************************************************************** 11200020
*  2   *     *   ---   * NOT USED IN THIS MODULE                      * 11300020
*********************************************************************** 11400020
*  3   *     *    ---  * NOT USED IN THIS MODULE                      * 11500020
*********************************************************************** 11600020
* 4-7  *     *  ADDR   * ADDRESS OF ERROR LOCATION                    * 11700020
*********************************************************************** 11800020
* DOUBLEWORD 2 --- MAIN STORAGE FAILURE REPORT                        * 11900020
*********************************************************************** 12000020
*  0   *  0  *    1    * MAIN STORAGE IS 2365                         * 12100020
*      *  1  *    1    * MAIN STORAGE IS 2385                         * 12200020
*      *  2  *    1    * ECC SINGLE ERROR DURING EXERCISE             * 12300020
*      *  3  *    1    * MULT BIT ERROR DURING EXERCISE               * 12400020
*      *  4  *    1    * ADDRESS CHECK DURING EXERCISE                * 12500020
*      *  5  *    1    * SDBI CHECK DURING EXERCISE                   * 12600020
*      *  6  *    1    * MARK CHECK DURING EXERCISE                   * 12700020
*      *  7  *    1    * NON-STORAGE ERROR DURING EXERCISE            * 12800020
*********************************************************************** 12900020
*  1   *  0  *    1    * E.C.C. SINGLE-BIT STORAGE FAILURE            * 13000020
*      *  1  *    1    * MULTIPLE-BIT STORAGE FAILURE                 * 13100020
*      *  2  *    1    * SOLID STORAGE FAILURE                        * 13200020
*      *  3  *    1    * INTERMITTENT STORAGE FAILURE                 * 13300020
*      * 4-6 *    ---  * UNUSED                                       * 13400020
*      *  7  *    1    * ABNORMAL TERMINATION BY STORAGE ANALYSIS     * 13500020
*********************************************************************** 13600020
*  2   *  0  *    1    * FAILURE IN BIFRAME 0 (2365)                  * 13700020
*      *  1  *    1    * FAILURE IN BIFRAME 1 (2365)                  * 13800020
*      *  2  *    1    * FAILURE IN LEFT UNIT (2365)                  * 13900020
*      *  3  *    1    * FAILURE IN RIGHT UNIT (2365)                 * 14000020
*      *  4  *    1    * FAILURE IN ODD BOM (2365)                    * 14100020
*      *  5  *    1    * FAILURE IN EVEN BOM (2365)                   * 14200020
*      *  7  *    -    * UNUSED                                       * 14300020
*      *  6  *    1    * FAILURE IN OPPOSITE DBWORD DURING EXERCISE   * 14400020
*********************************************************************** 14500020
*  3   * 0-1 *   00    * CSU (CORE STORAGE UNIT) 0 (2385)             * 14600020
*      *     *   01    * CSU 1 (2385)                                 * 14700020
*      *     *   10    * CSU 2 (2385)                                 * 14800020
*      *     *   11    * CSU 3 (2385)                                 * 14900020
*      **************************************************************** 15000020
*      * 2-3 *   00    * LSU (LOGICAL STORAGE UNIT) 0 (2385)          * 15100020
*      *     *   01    * LSU 1 (2385)                                 * 15200020
*      *     *   10    * LSU 2 (2385)                                 * 15300020
*      *     *   11    * LSU 3 (2385)                                 * 15400020
*      **************************************************************** 15500020
*      *  4  *    1    * LEFT BSM (BASIC STORAGE MODULE) (2385)       * 15600020
*      *  5  *    1    * RIGHT BSM (2385)                             * 15700020
*      * 6-7 *    -    * UNUSED                                       * 15800020
*********************************************************************** 15900020
* 4-5  *     *   ---   * 2365 CONFIGURATION BYTE                      * 16000020
*********************************************************************** 16100020
* 6-7  *     *         * UNUSED                                       * 16200020
*********************************************************************** 16300020
* DOUBLEWORD 3 --- STORE PROTECT FAILURE REPORT                       * 16400020
************************************************$********************** 16500020
* 0-2  *               * 2385 CONFIGURATION BYTES                     * 16600020
************************************************$********************** 16700020
*  3   *     *    * UNUSED                                            * 16800020
************************************************$********************** 16900020
*  4   *  0  *    1    * INITIAL SP (STORE PROTECT) OUT-KEY CHECK     * 17000020
*      *  1  *    1    * INITIAL SP IN-KEY CHECK                      * 17100020
*      *  2  *    1    * INITIAL SP ADDRESS CHECK                     * 17200020
*      *  3  *    1    * OUT-KEY CHECK DURING SP EXERCISE             * 17300020
*      *  4  *    1    * IN-KEY CHECK DURING SP EXERCISE              * 17400020
*      *  5  *    1    * ADDRESS CHECK DURING SP EXERCISE             * 17500020
*      *  6  *    1    * NON-SP CHECK DURING SP EXERCISE              * 17600020
*      *  7  *    1    * KEY BIT CHANGED WHEN READ OUT                * 17700020
*********************************************************************** 17800020
* DOUBLEWORD 4 --- DATA IN FAILING DOUBLEWORD SAVED HERE              * 17900020
*********************************************************************** 18000020
* DOUBLEWORD 5 --- DATA IN FAILING 2ND DOUBLEWORD SAVED HERE          * 18100020
*********************************************************************** 18200020
* DOUBLEWORD 6-13 ---  UNUSED                                         * 18300020
*********************************************************************** 18400020
         EJECT                                                          18500020
*********************************************************************** 18600020
*                                                                     * 18700020
****              MAIN STORAGE ANALYSIS MODULE  IGFASR7D           **** 18800020
*                                                                     * 18900020
*********************************************************************** 19000020
*                                                                     * 19100020
*                                                                     * 19200020
IGFMCH19 CSECT                                                          19300020
         USING *,BASEREG                                                19400020
         USING CVTTAB,CVTREG                                            19500020
         USING COMMON,COMREG                                            19600020
         USING ASRCOM,DEPREG                                            19620020
         USING  RMSMSB,WKR5            MSB BASE                         19650020
         LR    BASEREG,ENTRYREG        * SET UP BASE FOR MODULE         19700020
*********************************************************************** 20900020
*                                                                     * 21000020
****                     INITIALIZATION    ROUTINE                 **** 21100020
*                                                                     * 21200020
*********************************************************************** 21300020
*                                                                       21400020
S2TART   EQU   *                                                        21500020
         L     CVTREG,MCHCVT            GET ADDRESS FOR CVT DSECT   IO  21600020
         MVC   ASRPSW(P8),MCKNPSW      * SAVE NUCLEUS MCK NEW PSW       21700020
         MVI   MCHEXLEV,LEVEL          MODULE LEVEL                     21800021
LEVEL    EQU   X'&LEV'                                                  21850021
         OI    REMEST+P8,BIT0          * SET PRIMARY ERROR BIT IN REMES 21900020
         XR    WKR4,WKR4               * CLEAR REGISTER                 22000020
         XR    WKR5,WKR5               * CLEAR REGISTER                 22100020
         XR    WKR7,WKR7               * CLEAR REGISTER                 22200020
         NI    LFRTSW,BIT4             * CLEAR BIT 0 AND 1 OF SWITCH    22300020
         TM    REMEST+P17,BIT0         * IS ERROR SINGLE BIT            22400020
         BZ    M2LTIPLE                * BR IF EROR IS MULTIPLE BIT     22500020
*                                                                       22600020
* STORAGE DATA ERROR IS ECC CORRECTED SINGLE BIT ERROR . ECC BIT      * 22700020
* ALREADY TURNED ON IN REMEST BY PRELIMINARY ANALYSIS .               * 22800020
*                                                                       22900020
         MVI   MCHNXMOD,NEXT51          SUCCESSOR PATH NO           IO  23100020
         LA    WKR2,S2VDBWD            * SET UP CORRECT BRANCH PT       23300020
         TM    RECPULOG+P31A,BIT3      * ANY LEFT CE DATA CHECK         23400020
         BNZ   S2TRTSW        NO,GO SET SW FOR RIGHT CHECK          IO  23600020
L2FTCE   EQU   *                       * LEFT DATA CHECK                23800020
         TM    RECPULOG+P31A,BIT4      * ANY RIGHT DATA CHECK ALSO      23900020
         BZ    S2TLFSW                 * SET SW FOR LEFT CHECK IF NO    24000020
         LA    WKR2,S2VQDWD                 * SET UP CORRECT BRANCH PT  24100020
         B     B2THDBWD                * SET SW FOR BOTH LEFT RIGHT     24200020
*                                                                       24300020
* STORAGE DATA ERROR IS MULTIPLE BIT ERROR . MULTIPLE BIT ALREADY TURN* 24400020
* ON IN REMEST BY THE ERROR PRELIMINARY ANALYSIS MODULE .             * 24500020
*                                                                       24600020
M2LTIPLE EQU   *                                                        24700020
         TM    REMCOPSW+P3,BIT47       * ANY SUCCESSFUL RETRY           24800020
         BO    S2TEREP                 * BR IF YES                      24900020
         MVI   MCHNXMOD,NEXT50          SUCCESSOR PATH NO           IO  25100020
E2XMULT  EQU   *                                                        25300020
         LA    WKR2,F2ADDR             * SET UP CHECKPOINT              25400020
         TM    RECPULOG+P31A,BIT5      * ANY LEFT UCE DATA CHECK        25500020
         BO    L2FTUCE                 * BR IF YES                      25600020
S2TRTSW  EQU   *                       * ERROR IN RIGHT DOUBLE WORD     25700020
         OI    LFRTSW,BIT1             * SWITCH SET FOR RIGHT CHECK     25800020
         OI    REMEST+P15,BIT4         * TURN ON BIT 28 OF ADDRESS      25900020
         LA    WKR4,R2MCHECK                * MCK RTN FOR RIGHT CHECK   26000020
         ST    WKR4,MCKPTR             * STORED FOR LATER USE           26100020
         B     T2STTRY                 * TEST FOR SUCCESSFUL RETRY      26200020
*                                                                     * 26300020
L2FTUCE  EQU   *                       * ERROR IN LEFT DOUBLE WORD      26400020
         TM    RECPULOG+P31B,BIT0      * ANY RIGHT UCE DATA CHECK ALSO  26500020
         BO    B2THDBWD                * BR IF YES                      26600020
S2TLFSW  EQU   *                       * ERROR IN LEFT DBWD ONLY        26700020
         OI    LFRTSW,BIT0             * SWITCH SET FOR LEFT CHECK      26800020
         LA    WKR4,L2MCHECK           * MCK RTN FOR LEFT CHECK         26900020
         ST    WKR4,MCKPTR             * STORED FOR LATER USE           27000020
T2STTRY  EQU   *                       *                                27100020
         TM    REMCOPSW+P3,BIT47       * ANY SUCCESSFUL RETRY           27200020
         BO    I2REPORT                * SKIP EXERCISE IF YES           27300020
         LA    WKR5,P8                 * SET UP ADDR INCREMENT          27400020
         BALR  WKR4,WKR2               * BRANCH ACCORDINGLY             27500020
         B     S2VDBWD                 * SAVE DOUBLEWORD DATA           27600020
*                                                                     * 27700020
B2THDBWD EQU   *                       * ERROR ON BOTH DOUBLE WORD      27800020
         OI    LFRTSW,BIT01            * LEFT RIGHT SW BOTH SET         27900020
         LA    WKR4,B2MCHECK           * MCK RTN FOR QUADWD CHK         28000020
         ST    WKR4,MCKPTR             *   STORED FOR LATER USE         28100020
         TM    REMCOPSW+P3,BIT47       * ANY SUCCESSFUL RETRY           28200020
         BO    I2REPORT                * SKIP EXERCISE IF YES           28300020
         LA    WKR5,P16                * SET UP ADDR INCREMENT          28400020
         BALR  WKR4,WKR2               * BRANCH ACCORDINGLY             28500020
         B     S2VQDWD                 * SAVE QUADWORD DATA             28600020
*                                                                     * 28700020
* ORIGINAL ERROR IS MULTIPLE BIT. SO SET BEGINNING AND ENDING FAILING * 28800020
* ADDRESS IN 'REPDARF1' AND 'REPDARF2' FOR PDAR .                     * 28900020
*                                                                     * 29000020
F2ADDR   EQU   *                                                        29100020
         L     ADDRREG,REMEST+P12      * GET BEGINNING FAILING ADDR     29200020
         ST    ADDRREG,REPDARF1        * STORE FOR PDAR INFORMATION     29300020
         AR    ADDRREG,WKR5            * ADD CORRECT INCREMENT          29400020
         ST    ADDRREG,REPDARF2        * END OF FAILING ADDR FOR PDAR   29500020
         BR    WKR4                    * RETURN                         29600020
*                                                                     * 29700020
* ALTHOUGH WE HAVE A MULTIPLE BIT ERROR, FOR SUCCESSFUL RETRY, THE    * 29800020
* NEXT MODULE TO BE CALLED WILL BE THE ERROR RECORDER .               * 29900020
*                                                                     * 30000020
S2TEREP  EQU   *                                                        30100020
         MVI   MCHNXMOD,NEXT51          SUCCESSOR PATH NO           IO  30300020
*                                                                       30500020
* IF WE GET AN UNCORRECTABLE DATA ERROR, THE BAD DATA WITH ITS BAD    * 30600020
* CHECK BITS ARE REGENERATED IN STORAGE . THEREFORE IF WE TRY TO      * 30700020
* FETCH THE DATA FROM THIS SAME DOUBLEWORD, WE WILL GET ANOTHER  'UE' * 30800020
* AGAIN. HOWEVER, THE BAD DATA WILL HAVE GOOD PARITY ON THE 'SDBO' .  * 30900020
* SO TO SAVE THE DATA (COULD BE BAD DATA) WE DISABLE MCI, FETCH THE   * 31000020
* DATA, THEN ENABLE MCI TO BLEED OFF THE PENDING MACHINE CHECK .      * 31100020
*                                                                     * 31200020
S2VDBWD  EQU   *                       * TO SAVE DATA IN DB WORD        31300020
         L     ADDRREG,REMEST+P12      * ERROR LOC ADDR IN REG          31400020
         LA    WKR4,D2ABLE2            * SET UP                         31500020
         ST    WKR4,DMCIPSW+P4         *       TO DISABLE MCK           31600020
         LA    WKR4,S2VDATA2           * SET UP                         31700020
         ST    WKR4,EMCIPSW+P4         *       TO ENABLE MCK            31800020
         LA    WKR4,S2KIPCK2           * TO BYPASS EXPECTED MCK         31900020
         ST    WKR4,MCKNIA             * SET UP TO IGNORE MCK           32000020
         LPSW  DMCIPSW                 * DISABLE MCI                    32100020
D2ABLE2  EQU   *                                                        32200020
         LM    WKR4,WKR5,P0(ADDRREG)   * FETCH DB WORD ERROR DATA       32300020
         LPSW  EMCIPSW                 * BLEED OFF PENDING MCI          32400020
S2VDATA2 EQU   *                                                        32500020
         MVC   MCKNPSW(P8),ASRPSW      * RESTORE NUCLEUS MCK NEW PSW    32600020
         STM   WKR4,WKR5,REMEST+P32    * SAVE DATA IN REMEST TABLE      32700020
         LA    WKR2,E2NDEXDB           * SET UP CHECKPOINT              32800020
         B     E2ERCISE                * GO AND EXERCISE STORAGE        32900020
*                                                                     * 33000020
*  STORAGE DATA CHECK ON BOTH DOUBLEWORD. HANDLE ACCORDINGLY .        * 33100020
*                                                                     * 33200020
S2VQDWD  EQU   *                       * TO SAVE DATA IN QUADWORD       33300020
         L     ADDRREG,REMEST+P12      * ERROR LOC ADDR IN REG          33400020
         LA    WKR4,D2ABLE4            * SET UP                         33500020
         ST    WKR4,DMCIPSW+P4         *       TO DISABLE MCK           33600020
         LA    WKR4,S2VDATA4           * SET UP                         33700020
         ST    WKR4,EMCIPSW+P4         *       TO ENABLE MCK            33800020
         LA    WKR4,S2KIPCK4           * TO BYPASS EXPECTED MCK         33900020
         ST    WKR4,MCKNIA             * SET UP TO IGNORE MCK           34000020
         LPSW  DMCIPSW                 * DISABLE MCI                    34100020
D2ABLE4  EQU   *                                                        34200020
         LM    WKR2,WKR5,P0(ADDRREG)   * FETCH QUADWORD ERROR DATA      34300020
         LPSW  EMCIPSW                 * BLEED OFF PENDING MCI          34400020
S2VDATA4 EQU   *                                                        34500020
         MVC   MCKNPSW(P8),ASRPSW      * RESTORE NUCLEUS MCK NEW PSW    34600020
         STM   WKR2,WKR5,REMEST+P32    * SAVE DATA IN REMEST TABLE      34700020
         L     WKR2,PATTERN3           * TO CLEAR BAD DATA              34800020
         LR    WKR3,WKR2               *  BY STORING A QUADWORD         34900020
         LR    WKR4,WKR2               *   OF 'F' INTO THE              35000020
         LR    WKR5,WKR2               *    ERROR LOCATION              35100020
         STM   WKR2,WKR5,P0(ADDRREG)   * BAD DATA CLEARED               35200020
         LA    WKR2,E2NDEX1            * SET UP CHECKPOINT              35300020
         B     E2ERCISE                * GO AND EXERCISE STORAGE        35400020
*                                                                       35500020
*********************************************************************** 35600020
*                                                                       35700020
*****    EXERCISE ROUTINE TO TEST FOR SOLID OR INTERMITTENT       ***** 35800020
*                                                                       35900020
*********************************************************************** 36000020
*                                                                       36100020
* SINCE RMS/85 RUNS IN 'COUNT MODE', WE HAVE TO CHANGE TO RECORDING   * 36200020
* MODE IN ORDER TO BE ABLE TO DETECT SINGLE BIT ERROR DURING EXERCISE.* 36300020
*                                                                     * 36400020
E2ERCISE EQU   *                                                        36500020
         L     WKR5,MCHMSB             ESTABLISH BASE                   36550020
         MVC   SAVEMCW(P8),RESMCW      * SAVE SYSTEM MACHINE STATUS     36600020
         DROP  WKR5                                                     36650020
         OI    SAVEMCW,BIT67           * MAKE SURE CPU SELECT BITS ON   36700020
         NI    SAVEMCW+P4,RECMODE      * HIR AND ECC IN RECORD MODE     36800020
D2AGNOS1 EQU   *                       *                                36900020
         DC    X'8300'                 * ISSUE DIAGNOSE TO SWITCH       37000020
         DC    S(SAVEMCW)              *    PGM TO RECORDING MODE       37100020
         L     WKR4,MCKPTR             * TO SET UP APPROPRIATE          37200020
         ST    WKR4,MCKNIA             *   IA FOR ANTICIPATED MCI       37300020
         OI    COMINTEL,BIT0           * SET WARNING INDICATOR          37400020
S2TLOOP  LA    WKR7,P16                * SET LOOP TO EXERCISE 4 PATTERN 37500020
         L     WKR4,PATTERN1           * SET UP PATTERN ONE             37600020
C2YCLE   EQU   *                                                        37900020
         LR    WKR5,WKR4               * PATTERN IN REG 5 TOO           38000020
         STM   WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY STORING 1 AND 0    38100020
         STM   WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY STORING 1 AND 0    38200020
         STM   WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY STORING 1 AND 0    38300020
         STM   WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY STORING 1 AND 0    38400020
         STM   WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY STORING 1 AND 0    38500020
*                                                                     * 38600020
         LM    WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY READING PATTERN    38700020
         LM    WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY READING PATTERN    38800020
         LM    WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY READING PATTERN    38900020
         LM    WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY READING PATTERN    39000020
         LM    WKR4,WKR5,P0(ADDRREG)   * EXERCISE BY READING PATTERN    39100020
*                                                                       39200020
         SH    WKR7,HFOUR              * DECREMENT BY FOUR TO INDEX     39300020
R2FER    B     R2FER+P4(WKR7)          * BRANCH TO CORRECT LOOP         39400020
         BCR   P15,WKR2                 * END OF ONE EXERCISE           39500020
         DC    X'0700'                 * 2 BYTES NO OP TO FILL SPACE    39600020
         B     C2YCLE4                 * EXERCISE WITH NEXT PATTERN     39700020
         B     C2YCLE3                 * EXERCISE WITH NEXT PATTERN     39800020
         B     C2YCLE2                 * EXERCISE WITH NEXT PATTERN     39900020
C2YCLE2  L     WKR4,PATTERN2           * SET UP NEXT PATTERN            40000020
         B     C2YCLE                  * CONTINUE EXERCISE              40100020
C2YCLE3  L     WKR4,PATTERN3           * SET UP NEXT PATTERN            40200020
         B     C2YCLE                  * CONTINUE EXERCISE              40300020
C2YCLE4  L     WKR4,PATTERN4           * SET UP NEXT PATTERN            40400020
         B     C2YCLE                  * CONTINUE EXERCISE              40500020
*                                                                     * 40600020
* FOR ERROR DUE TO ONE DOUBLEWORD, BRANCH HERE AFTER EXERCISE.        * 40700020
*                                                                     * 40800020
E2NDEXDB EQU   *                                                        40900020
         MVC   P0(P8,ADDRREG),REMEST+P32     * RESTORE DB WORD DATA     41000020
         B     N2CHECK                      *                           41100020
*                                                                     * 41200020
* FOR ERROR DUE TO BOTH DOUBLEWORD, CONTROL BRANCHES THER AFTER END   * 41300020
* OF EXERCISE FOR FIRST DOUBLEWORD. START EXERCISE FOR 2ND DOUBLEWORD * 41400020
*                                                                     * 41500020
E2NDEX1  EQU   *                                                        41600020
         LA    ADDRREG,P8(ADDRREG)     * INCREMENT BY DOUBLEWORD        41700020
         LA    WKR2,E2NDEX2            * CHECKPOINT FOR 2ND EXERCISE    41800020
         B     S2TLOOP                 * EXERCISE 2ND DOUBLEWORD        41900020
*                                                                     * 42000020
* EXERCISE FOR 2ND DOUBLEWORD COMPLETED. RESTORE ORIGINAL DATA.       * 42100020
*                                                                     * 42200020
E2NDEX2  EQU   *                                                        42300020
         SH    ADDRREG,HEIGHT          * DECREMENT TO PT TO QUADWORD    42400020
         MVC   P0(P16,ADDRREG),REMEST+P32    * RESTORE QDWD DATA        42500020
         B     N2CHECK                      *                           42600020
*                                                                       42700020
* PROGRAM CONTINUES HERE IF NO MCI OCCURS FROM THE ABOVE EXERCISE .   * 42800020
* THE STORAGE DATA FAILURE WILL BE CLASSIFIED AS INTERMITTENT ERROR   * 42900020
* RESTORE SYSTEM TO ITS ORIGINAL STATUS FIRST.                        * 43000020
*                                                                     * 43100020
N2CHECK  EQU   *                                                        43200020
         MVC   MCKNPSW(P8),ASRPSW      * RESTORE NUCLEUS MCK NEW PSW    43300020
         BAL   ICREG,C2NTMODE          * SWITCH BACK TO COUNT MODE      43400020
         NI    COMINTEL,ZBIT0          * CLEAR WARNING INDICATOR        43500020
N2TSOLID EQU   *                                                        43600020
         OI    REMEST+P8,BIT1          * SET 'REPAIRABLE ERROR' BIT     43700020
         OI    REMEST+P17,BIT3         * SET 'INTERMITTENT FAILURE' BIT 43800020
P2DARI   EQU   *                                                        43900020
         TM    REMEST+P17,BIT1         * WAS ORIGINAL ERROR MULT-BIT    44000020
         BZ    I2REPORT                * BR IF NO                       44100020
*                                                                     * 44200020
* SINCE ORIGINAL ERROR WAS A MULTIPLE BIT STORAGE ERROR, CONTROL WILL * 44300020
* GO TO PDAR LATER. SO SET THE 'INTERM STG DATA ERROR' AND 'STG DATA  * 44400020
* ERROR LOCATION CLEARED' BITS IN 'REPDAR2' FOR PDAR .                * 44500020
*                                                                     * 44600020
         OI    REPDAR2,BIT15           * TURN ON APPROPRIATE BITS       44700020
         TM    REPDAR1,BIT0            * IS TERMINATION BIT SET         44800020
         BO    I2REPORT                * BR IF YES. OTHERWISE           44900020
         OI    REPDAR1,BIT2            * ALSO SET RETRY POSSIBLE BIT    45000020
         B     I2REPORT                * GO AND IDENTIFY PHYSICAL UNIT  45100020
*                                                                       45200020
* THE STORAGE DATA FAILURE WILL BE CLASSIFIED AS SOLID ERROR .        * 45300020
*                                                                       45400020
S2LID    EQU   *                                                        45500020
         OI    REMEST+P8,BIT3          * SET 'NONREPAIRABLE ERROR' BIT  45600020
         OI    REMEST+P17,BIT2         * SET 'SOLID FAILURE' BIT        45700020
         BR    WKR4                    * BRANCH ACCORDINGLY             45800020
*                                                                       45900020
*********************************************************************** 46000020
*****    ANTICIPATED MACHINE CHECK INTERRUPT HANDLING ROUTINE     ***** 46100020
*********************************************************************** 46200020
*                                                                       46300020
S2KIPCK2 EQU   *                       * TO HANDLE MCI DURING SAVING    46400020
         BAL   ICREG,E2ABLE            * GO TO ENABLE FOR MCI           46500020
         B     S2VDATA2                *  OF DOUBLEWORD ERROR DATA      46600020
S2KIPCK4 EQU   *                       * TO HANDLE MCI DURING SAVING    46700020
         BAL   ICREG,E2ABLE            * GO TO ENABLE FOR MCI           46800020
         B     S2VDATA4                *  OF QUADWORD ERROR DATA        46900020
*                                                                     * 47000020
****     ENTRY POINT OF MCI FOR ERROR ON LEFT DOUBLEWORD ONLY      **** 47100020
*                                                                     * 47200020
L2MCHECK EQU   *                       *                                47300020
         MVC   MCKNPSW(P8),ASRPSW      * RESTORE NUCLEUS MCK NEW PSW    47400020
         BAL   ICREG,C2NTMODE          * SWITCH BACK TO COUNT MODE      47500020
         BAL   ICREG,E2ABLE            * GO TO ENABLE FOR MCI           47600020
         LA    WKR4,R2STORDB           * SET UP ENTRY POINT             47700020
         TM    SDBICHK,BIT02           * ANY RIGHT UCE OR SDBI CHECK    47800020
         BC    P7,S2TOTHER              * SET OPPOSITE BIT IF YES       47900020
         TM    DATACHK,BIT4            * ANY RIGHT CE CHECK             48000020
         BO    S2TOTHER                * SET OPPOSITE BIT IF YES        48100020
         TM    MARKCHK,BIT15           * ANY RIGHT ADR OF MARK CHECK    48200020
         BO    S2TOTHER                * BR IF YES                      48300020
         B     T2STECC                 * SHOULD DATA BE RESTORED        48400020
*                                                                     * 48500020
****     ENTRY POINT OF MCI FOR ERROR ON RIGHT DOUBLEWORD ONLY     **** 48600020
*                                                                     * 48700020
R2MCHECK EQU   *                       *                                48800020
         MVC   MCKNPSW(P8),ASRPSW      * RESTORE NUCLEUS MCK NEW PSW    48900020
         BAL   ICREG,C2NTMODE          * SWITCH BACK TO COUNT MODE      49000020
         BAL   ICREG,E2ABLE            * GO TO ENABLE FOR MCI           49100020
         LA    WKR4,R2STORDB           * SET UP ENTRY POINT             49200020
         TM    DATACHK,BIT35           * ANY LEFT CE OR UCE CHECK       49300020
         BC    P7,S2TOTHER              * SET OPPOSITE BIT IF YES       49400020
         TM    SDBICHK,BIT1            * ANY LEFT SDBI CHECK            49500020
         BO    S2TOTHER                * BR IF YES                      49600020
         TM    MARKCHK,BIT04           * ANY LEFT ADR OR MARK CHECK     49700020
         BC    P7,S2TOTHER              * SET OPPOSITE BIT IF YES       49800020
         B     T2STECC                 * SHOULD DATA BE RESTORED        49900020
*                                                                     * 50000020
S2TOTHER EQU   *                       *                                50100020
         OI    REMEST+P18,BIT6         * TURN ON 'OPPOSITE ALSO' SW     50200020
*                                                                     * 50300020
* EVEN THOUGH WE ENCOUNTERED MCK DURING EXERCISE,THE ORIGINAL DATA    * 50400020
* OF ERROR LOCATION SHOULD BE RESTORED IF ORIGINAL ERROR WAS ECC .    * 50500020
*                                                                     * 50600020
T2STECC  EQU   *                                                        50700020
         TM    REMEST+P17,BIT0         * WAS ORIGINAL ERROR ECC         50800020
         BZ    M2CHECK                 * BR TO COMMON RTN IF NO         50900020
         BR    WKR4                    * RESTORE SAVED DATA IF YES      51000020
R2STORDB EQU   *                                                        51100020
         MVC   P0(P8,ADDRREG),REMEST+P32     * RESTORE DB WORD DATA     51200020
         NI    COMINTEL,ZBIT0          * CLEAR WARNING INDICATOR        51300020
         B     M2CHECK                 * GO TO COMMON HANDLING RTN      51400020
R2STORQD EQU   *                                                        51500020
         MVC   P0(P16,ADDRREG),REMEST+P32    * RESTORE QDWD DATA        51600020
         NI    COMINTEL,ZBIT0          * CLEAR WARNING INDICATOR        51700020
         B     M2CHECK                 * GO TO COMMON HANDLING RTN      51800020
*                                                                     * 51900020
****     ENTRY POINT OF MCI FOR ERROR ON BOTH DOUBLEWORD           **** 52000020
*                                                                     * 52100020
B2MCHECK EQU   *                                                        52200020
         MVC   MCKNPSW(P8),ASRPSW      * RESTORE NUCLEUS MCK NEW PSW    52300020
         BAL   ICREG,C2NTMODE          * SWITCH BACK TO COUNT MODE      52400020
         BAL   ICREG,E2ABLE            * GO TO ENABLE FOR MCI           52500020
         SRL   ADDRREG,P4              * TO MAKE SURE ERROR ADDRESS     52600020
         SLL   ADDRREG,P4              *   IS ON QUADWORD BOUNDARY      52700020
         LA    WKR4,R2STORQD           * SET UP ENTRY POINT             52800020
         B     T2STECC                 * SHOULD DATA BE RESTORED        52900020
*                                                                     * 53000020
****     COMMON HANDLING ROUTINE ON OCCURANCE OF ANTICIPATED MCI   **** 53100020
*                                                                     * 53200020
M2CHECK  EQU   *                                                        53300020
         TM    MCKCODE,BIT3            * ANY UNCORRECTABLE DATA ERROR   53400020
         BO    S2LID1                  * IF YES,THEN ERROR IS SOLID     53500020
         TM    DATACHK,BIT34           * ANY ECC CORRECTED ERROR        53600020
         BC    P7,N2TSOLD1              * IF YES, ALSO CONSIDERED SOLID 53700020
*                                                                       53800020
* ANTICIPATED MACHINE CHECK OCCURED BUT IS NOT STORAGE DATA ERROR .   * 53900020
* CONTINUE TO ANALYZE WHAT TYPE OF CHECK OCCURED DURING EXERCISE .    * 54000020
*                                                                       54100020
         TM    SDBICHK,BIT12           * IS IT SDBI CHECK               54200020
         BNE   S2TSDBI                 * BRANCH IF YES                  54300020
         TM    ADRCHK,BIT01            * IS IT ADDRESS CHECK            54400020
         BNE   S2TADDR                 * BRANCH IF YES                  54500020
         TM    MARKCHK,BIT45           * IS IT MARK CHECK               54600020
         BNE   S2TMARK                 * BRANCH IF YES                  54700020
         OI    REMEST+P16,BIT7         * NON-STORAGE ERROR OCCURED      54800020
         B     E2ABLE1                 * CONTINUE                       54900020
*                                                                     * 55000020
S2TSDBI  OI    REMEST+P16,BIT5         * SDBI CHECK OCCURED             55100020
         B     E2ABLE1                 * CONTINUE                       55200020
S2TADDR  OI    REMEST+P16,BIT4         * ADDRESS CHECK OCCURED          55300020
         B     E2ABLE1                 * CONTINUE                       55400020
S2TMARK  OI    REMEST+P16,BIT6         * MARK CHECK OCCURED             55500020
         B     E2ABLE1                 * CONTINUE                       55600020
*                                                                     * 55700020
E2ABLE1  EQU   *                       *                                55800020
         B     N2TSOLID                * TAKE CARE FOR PDAR             55900020
*                                                                       56000020
S2LID1   EQU   *                                                        56100020
         OI    REMEST+P16,BIT3         * MULT BIT ERROR OCCURED         56200020
         LA    WKR4,I2REPORT           * SET UP EXIT POINTER            56300020
         TM    REMEST+P17,BIT1         * WAS ORIGINAL ERROR MULT-BIT    56400020
         BZ    S2LID                   * BR IF NO                       56500020
*                                                                     * 56600020
* ORIGINAL ERROR WAS MULTIPLE BIT, SO CONTROL WILL GO TO PDAR LATER . * 56700020
* SO SET 'TERMINATION NECESSARY', 'SOLID STORAGE DATA ERROR' AND      * 56800020
* CLEAR 'RETRY POSSIBLE' BIT IN 'REPDAR1' AND 'REPDAR2' FOR PDAR .    * 56900020
*                                                                     * 57000020
         OI    REPDAR1,BIT0            * SET TERMINATION BIT FOR PDAR   57100020
         NI    REPDAR1,ZBIT2           * CLEAR 'RETRY POSSIBLE' BIT     57200020
         OI    REPDAR2,BIT0            * SET 'SOLID STG ERROR' FOR PDAR 57300020
         B     S2LID                   * SET BITS FOR CE INFORMATION    57400020
*                                                                     * 57500020
N2TSOLD1 EQU   *                                                        57600020
         OI    REMEST+P16,BIT2         * ECC SINGLE BIT ERROR OCCURED   57700020
         LA    WKR4,P2DARI             * SET UP EXIT POINTER            57800020
         B     S2LID                   * CONSIDERD SOLID FAILURE        57900020
*                                                                     * 58000020
*                                                                     * 58100020
*********************************************************************** 58200020
* THE MCK NEW PSW IS DISABLED FOR MCI. SO WE HAVE TO LPSW TO ENABLE   * 58300020
* FOR MCI AFTER EACH MCK OCCURANCE .                                  * 58400020
*********************************************************************** 58500020
*                                                                     * 58600020
E2ABLE   EQU   *                                                        58700020
         ST    ICREG,EMCIPSW+P4        * TO ENABLE MCK FOR THE          58800020
         LPSW  EMCIPSW                 *    CURRENT PSW                 58900020
*                                                                     * 59000020
*********************************************************************** 59100020
**           RESTORE SYSTEM BACK TO ITS ORIGINAL STATUS              ** 59200020
*********************************************************************** 59300020
*                                                                     * 59400020
C2NTMODE EQU   *                       * SWITCH TO COUNT MODE           59500020
         OI    SAVEMCW+P4,BIT57        * HIR AND ECC ALL IN COUNTMODE   59600020
D2AGNOS2 EQU   *                       *                                59700020
         DC    X'8300'                 * DIAGNOSE TO SWITCH             59800020
         DC    S(SAVEMCW)              *    PGM BACK TO COUNT MODE      59900020
         BR    ICREG                   * RETURN TO CALLER               60000020
*                                                                     * 60100020
*********************************************************************** 60200020
*                                                                       60300020
*****                    ID  GENERATION ROUTINE                   ***** 60400020
*                                                                       60500020
*********************************************************************** 60600020
*                                                                       60700020
I2REPORT EQU   *                                                        60800020
         TM    REMEST+P16,BIT0         * IS THIS A 2365 STORAGE         60900020
         BZ    M2385                   * IF NO, THEN STORAGE IS 2385    61000020
*                                                                       61100020
* THE MIAN STORAGE USES 2365 STORAGE UNITS . DETERMINE IF STORAGE     * 61200020
* FAILURE IS IN LEFT OR RIGHT STORAGE UNIT .                          * 61300020
*                                                                       61400020
         TM    REMEST+P15,BIT4         * IS BIT 28 OF ERROR ADDR ON     61500020
         BZ    L2FTUNIT                * IF NO, THEN THIS IS LEFT UNIT  61600020
         OI    REMEST+P18,BIT3         * SET 'RIGHT UNIT' BIT           61700020
         B     T2STBF                  * NEXT DET BIFRAME NO.           61900020
* BIT 28 OF ADDRESS NOT ON COULD MEAN JUST LEFT DB WORD OR QUADWORD   * 62000020
*                                                                     * 62100020
L2FTUNIT EQU   *                                                        62200020
         TM    LFRTSW,BIT01            * IS ERROR A QUADWORD            62300020
         BO    L2FTRT                  * BR IF YES                      62400020
         OI    REMEST+P18,BIT2         * SET 'LEFT UNIT' BIT            62500020
         B     T2STBF                  * GO TEST BIFRAME                62700020
L2FTRT   EQU   *                                                        62800020
         OI    REMEST+P18,BIT23        * SET BOTH 'LEFT' AND 'RIGHT'    62900020
*                                                                       63100020
* DETERMINE IF FAILURE IS LOCATED IN BIFRAME 0 OR BIFRAME 1           * 63200020
*                                                                       63300020
T2STBF   TM    REMEST+P20,BIT5         * IS STORAGE 4 WAY INTERLEAVE    63400020
         BO    F2WAY                   * IF YES , BRANCH                63500020
*                                                                       63600020
* STORAGE IS NOT 4 WAY INTERLEAVE . TEST BIT 12 TO DET. BIFRAME       * 63700020
*                                                                       63800020
         TM    REMEST+P13,BIT4         * IS BIT 12 OF ADDR ON           63900020
         BZ    B2FRAME0                * IF NO, THEN THIS IS BIFRAME 0  64000020
         B     B2FRAME1                * IF YES, THEN THIS IS BIFRAME 1 64100020
*                                                                       64200020
* STORAGE IS 4 WAY INTERLEAVE . TEST BIT 27 OF ADDR TO DET. BIFRAME   * 64300020
*                                                                       64400020
F2WAY    TM    REMEST+P15,BIT3         * IS BIT 27 OF ADDR ON           64500020
         BO    B2FRAME1                * IF YES,THIS IS BIFRAME 1       64600020
B2FRAME0 EQU   *                                                        64700020
         TM    REMEST+P21,BIT1         * IS REVERSE BIFRAME REQ'D       64800020
         BO    S2TBIT1                 * BR IF YES                      64900020
S2TBIT0  OI    REMEST+P18,BIT0         * SET 'BIFRAME 0' BIT            65000020
         B     T2STBOM                 * TEST FOR ODD EVEN NEXT         65200020
B2FRAME1 EQU   *                                                        65300020
         TM    REMEST+P21,BIT1         * IS REVERSE BIFRAME REQ'D       65400020
         BO    S2TBIT0                 * IF YES, BR AND SET BIFRAME 1   65500020
S2TBIT1  OI    REMEST+P18,BIT1         * SET 'BIFRAME 1' BIT            65600020
*                                                                       65800020
* NOW DETERMINE IF FAILURE IS LOCATED IN ODD OR EVEN BOM              * 65900020
*                                                                       66000020
T2STBOM  EQU   *                                                        66100020
         TM    REMEST+P20,BIT4         * 2 WAY INTERLEAVE               66200020
         BO    T2WAY                   * BR IF YES                      66300020
         TM    REMEST+P20,BIT5         * 4 WAY INTERLEAVE               66400020
         BO    F2URWAY                 * BR IF YES                      66500020
         TM    REMEST+P13,BIT5         * IS BIT 13 OF ADDR ON           66600020
         BZ    E2ENBOM                 * IF NO, THIS MEANS EVEN BOM     66700020
         B     O2DBOM                  * OTHERWISE, ODD BOM             66800020
T2WAY    TM    REMEST+P15,BIT3         * IS BIT 27 OF ADDR ON           66900020
         BZ    E2ENBOM                 * IF NO, THIS MEANS EVEN BOM     67000020
         B     O2DBOM                  * OTHERWISE, ODD BOM             67100020
F2URWAY  TM    REMEST+P15,BIT2         * IS BIT 26 OF ADDR ON           67200020
         BZ    E2ENBOM                 * IF NO, THIS MEANS EVEN BOM     67300020
         B     O2DBOM                  * OTHERWISE, ODD BOM             67400020
O2DBOM   EQU   *                                                        67500020
         TM    REMEST+P20,BIT2         * IS REV E/O ADR BIT ON          67600020
         BO    S2TEVEN                 * SET 'EVEN BOM' IF BIT ON       67700020
S2TODD   OI    REMEST+P18,BIT4         * SET 'ODD BOM' IN REMEST        67800020
         B     F2NISH                  * GET READY TO EXIT              68000020
E2ENBOM  EQU   *                                                        68100020
         TM    REMEST+P20,BIT2         * IS REV E/O ADR BIT ON          68200020
         BO    S2TODD                  * SET 'ODD BOM' IF BIT ON        68300020
S2TEVEN  OI    REMEST+P18,BIT5         * SET 'EVEN BOM' IN REMEST       68400020
         B     F2NISH                  * GET READY TO EXIT              68600020
*                                                                       68700020
*        MAIN STORAGE USES 2385 STORAGE UNITS . DETERMINE WHICH  CSU  * 68800020
*        (CORE STORAGE UNIT) IS STORAGE FAILURE LOCATED .             * 68900020
*                                                                       69000020
M2385    EQU   *                                                        69100020
         XR    WKR4,WKR4               * CLEAR WORK REG                 69200020
         XR    WKR5,WKR5               * CLEAR WORK REG                 69300020
         TM    REMEST+P13,BIT23        * IS ADDR BIT 10 & 11 ON         69400020
         BO    M2GBYTE4                * MEGABYTE 4 IF BOTH BITS ON     69500020
         BZ    M2GBYTE1                * MEGABYTE 1 IF BOTH BIT OFF     69600020
         TM    REMEST+P13,BIT3         * IS ADDR BIT 11 ON              69700020
         BO    M2GBYTE2                * MEGABYTE 2 IF ON               69800020
         B     M2GBYTE3                * OTHERWISE, ADDR IN MEGABYTE 3  69900020
M2GBYTE1 MVC   TEMP(P1),REMEST+P24     * SAVE 2385 1ST MEG CONFIG       70000020
         B     S2VE23                  *                                70100020
M2GBYTE2 MVC   TEMP(P1),REMEST+P25     * SAVE 2385 2ND MEG CONFIG       70200020
         B     S2VE01                  *                                70300020
M2GBYTE3 MVC   TEMP(P1),REMEST+P26     * SAVE 2385 3RD MEG CONFIG       70400020
         B     S2VE01                  * TO SAVE BIT 0 AND 1            70500020
S2VE23   NI    TEMP,BIT23              * SAVE ONLY BIT 2 AND 3          70600020
         IC    WKR4,TEMP               *  TO SHIFT BIT WITHIN BYTE      70700020
         SLL   WKR4,P2                 * MOVE BIT 2,3 INTO BIT 0,1      70800020
         B     S2TCSU                  * TO SET THE CSU ID              70900020
M2GBYTE4 MVC   TEMP(P1),REMEST+P26     * SAVE 2385 4TH MEG CONFIG       71000020
         NI    TEMP,BIT45              * SAVE ONLY BIT 4 AND 5          71100020
         IC    WKR4,TEMP               * TO SHIFT BIT WITHIN BYTE       71200020
         SLL   WKR4,P4                 * MOVE BIT 4,5 TO 0,1            71300020
         B     S2TCSU                  * TO SET CSU BIT IN REMEST       71400020
S2VE01   NI    TEMP,BIT01              * SAVE ONLY BIT 0 AND 1          71500020
         IC    WKR4,TEMP               * TO SHIFT BIT WITHIN BYTE       71600020
S2TCSU   STC   WKR4,REMEST+P19         * CORRECT CSU BITS SET IN REMEST 71700020
*                                                                       72100020
* NOW SET THE PROPER LSU (LOGICAL STORAGE UNIT) BITS INTO REMEST      * 72200020
*                                                                       72300020
         MVC   TEMP(P1),REMEST+P15     * TO EXTRACT BIT 26,27 OF ADDR   72400020
         NI    TEMP,BIT23              * SAVE ONLY BIT 2,3 OF BYTE      72500020
         OC    REMEST+P19(P1),TEMP     * LSU BITS SET ON IN REMEST      72600020
*                                                                       73100020
* NOW TO DETERMINE IF ERROR IS LOCATED IN LEFT OR RIGHT BSM           * 73200020
*                                                                       73300020
         TM    REMEST+P15,BIT4         * IS BIT 28 OF ERROR ADDR ON     73400020
         BO    R2BSM                   * IF YES, THEN IN RIGHT BSM      73500020
*                                                                       73600020
* BIT 28 NOT ON COULD MEAN JUST LEFT BSM OR BOTH LEFT AND RIGHT BSM   * 73700020
*                                                                     * 73800020
         TM    LFRTSW,BIT01            * IS ERROR A QUADWORD            73900020
         BO    L2FRTBSM                * BR IF YES                      74000020
         OI    REMEST+P19,BIT4         * TURN ON 'LEFT BSM' BIT         74100020
         B     F2NISH                  * GET READY TO EXIT              74300020
*                                                                     * 74400020
L2FRTBSM EQU   *                                                        74500020
         OI    REMEST+P19,BIT45        * TURN ON BOTH BSM BITS          74600020
*                                                                     * 74800020
R2BSM    OI    REMEST+P19,BIT5         * TURN ON 'RIGHT BSM' BIT        74900020
*                                                                       75100020
* MAIN STORAGE ANALYSIS HAS FINISH ITS MAIN FUNCTIONS . NOW TO PRINT  * 75200020
* CONSOLE MESSAGE, RESTORE NUCLEUS MCK NEW PSW AND SCRAM .            * 75300020
*                                                                       75400020
F2NISH   EQU   *                                                        75500020
         TM    REMEST+P17,BIT0         * IS ERROR SINGLE BIT            75600020
         BO    R2TURN                  * IF YES,RETURN                  75700020
         L     WKR4,MCHIPTR             MESSAGE BUFFER ADDX         IO  75800020
         MVI   P0(WKR4),P15             ENTER MULT BIT CODE         IO  75900020
         LA    WKR4,P1(WKR4)            UPDATE BUFFER PTR           IO  76000020
         ST    WKR4,MCHIPTR             UPDATE MESSAGE BUFFER ADDR  IO  76100020
R2TURN   EQU   *                                                        76200020
         NI    COMINTEL,ZBIT0          * CLEAR WARNING INDICATOR        76300020
         NI    REMEST+P15,ZBIT4        * CLEAR BIT 28 OF ERROR ADDR     76400020
         BR    RETNREG                 * RETURN TO RMS/85 NUCLEUS       76500020
*********************************************************************** 78900020
*****               END OF MAIN STORAGE ANALYSIS MODULE           ***** 79000020
*********************************************************************** 79100020
*                                                                       79200020
*****    EQUATES UTILIZED TO MINIMIZED FUTURE PGM MODIFICATION    ***** 79300020
*****                         REGISTERS                           ***** 79400020
*                                                                       79500020
EXITREG  EQU   1                       * FIX. PT TO EXIT MODULE         79600020
WKR2     EQU   2                       * NF1X. WORK REG FOR EXERCISE    79700020
WKR3     EQU   3                       * NF1X. WORK REG FOR EXERCISE    79800020
WKR4     EQU   4                       * NFIX. GEN PURPOSE WORK REG     79900020
WKR5     EQU   5                       * NFIX. GEN PURPOSE WORK REG     80000020
CVTREG   EQU   6                       * FIX. PT TO CVTTAB              80100020
WKR7     EQU   7                       * NFIX. USED FOR BRANCH          80200020
ADDRREG  EQU   8                       * NFIX. CONTAIN FAILING ADDRESS  80300020
PRINTREG EQU   9                       * FIX. RTN REG FOR CALL PRINT    80400020
ICREG    EQU   10                      * NFIX. USED FOR ENABLING MCI    80500020
COMREG   EQU   11                      * FIX. BASE REG FOR COMMON AREA  80600020
BASEREG  EQU   12                      * FIX. BASE REG FOR MODULE       80700020
RETNREG  EQU   14                      * FIX. RETURN REG FOR MODULE     80800020
ENTRYREG EQU   15                      * FIX. CONTAIN MODULE ENTRY PT   80900020
DEPREG   EQU   13                      DEPENDENT COMMON AREA BASE REG   81000020
*                                                                       81200020
*                                                                     * 81300020
NEXT51   EQU   X'02'                    SUCCESSOR PATH-RECORDER     IO  81500020
NEXT50   EQU   X'01'                    SUCCESSOR PATH-PDAR         IO  81700020
*****                      MASKS AND FLAGS                        ***** 82100020
*                                                                       82200020
BIT0     EQU   X'80'                   * FOR TEST OR SET OF BIT 0       82300020
BIT1     EQU   X'40'                   * FOR TEST OR SET OF BIT 1       82400020
BIT2     EQU   X'20'                   * FOR TEST OR SET OF BIT 2       82500020
BIT3     EQU   X'10'                   * FOR TEST OR SET OF BIT 3       82600020
BIT4     EQU   X'08'                   * FOR TEST OR SET OF BIT 4       82700020
BIT5     EQU   X'04'                   * FOR TEST OR SET OF BIT 5       82800020
BIT6     EQU   X'02'                   * FOR TEST OR SET OF BIT 6       82900020
BIT7     EQU   X'01'                   * FOR TEST OR SET OF BIT 7       83000020
BIT01    EQU   X'C0'                   * FOR TEST OR SET OF BIT 0 AND 1 83100020
BIT02    EQU   X'A0'                   * FOR TEST OR SET OF BIT 0 AND 2 83200020
BIT04    EQU   X'88'                   * FOR TEST OR SET OF BIT 0 AND 4 83300020
BIT12    EQU   X'60'                   * FOR TEST OR SET OF BIT 1 AND 2 83400020
BIT15    EQU   X'44'                   * FOR TEST OR SET OF BIT 1 AND 5 83500020
BIT23    EQU   X'30'                   * FOR TEST OR SET OF BIT 2 AND 3 83600020
BIT34    EQU   X'18'                   * FOR TEST OR SET OF BIT 3 AND 4 83700020
BIT35    EQU   X'14'                   * FOR TEST OR SET OF BIT 3 AND 5 83800020
BIT45    EQU   X'0C'                   * FOR TEST OR SET OF BIT 4 AND 5 83900020
BIT47    EQU   X'09'                   * FOR TEST OR SET OF BIT 4 AND 7 84000020
BIT57    EQU   X'05'                   * FOR TEST OR SET OF BIT 5 AND 7 84100020
BIT67    EQU   X'03'                   * FOR TEST OR SET OF BIT 6 AND 7 84200020
ZBIT0    EQU   X'7F'                   * TO ZERO OUT BIT 0              84300020
ZBIT2    EQU   X'DF'                   * TO ZERO OUT BIT 2              84400020
ZBIT4    EQU   X'F7'                   * TO ZERO OUT BIT 4              84500020
RECMODE  EQU   X'F0'                   * TO ZERO BIT 4 TO 7             84600020
ADRCHK   EQU   X'381'                  * ADDR CHK INDICATOR IN LOGOUT   84800020
MARKCHK  EQU   X'381'                  * MARK CHK INDICATOR IN LOGOUT   84900020
DATACHK  EQU   X'382'                  * DATA CHK INDICATOR IN LOGOUT   85000020
SDBICHK  EQU   X'383'                  * SDBI CHK INDICATOR IN LOGOUT   85100020
MCKCODE  EQU   51                      * MCK INTERRUPT CODE             85200020
MCKNPSW  EQU   112                     * MCK NEW PSW                    85300020
MCKNIA   EQU   116                     * INSTR ADDR IN MCK NEW PSW      85400020
*                                                                       85500020
*****                           NUMERIC VALUE                     ***** 85600020
*                                                                       85700020
P0       EQU   0                       * CONSTANT EQUATE                85800020
P1       EQU   1                       * CONSTANT EQUATE                85900020
P2       EQU   2                       * CONSTANT EQUATE                86000020
P3       EQU   3                       * CONSTANT EQUATE                86100020
P4       EQU   4                       * CONSTANT EQUATE                86200020
P6       EQU   6                        * CONSTANT EQUATE               86300020
P7       EQU   7                        * CONSTANT EQUATE               86400020
P8       EQU   8                       * CONSTANT EQUATE                86500020
P9       EQU   9                       * CONSTANT EQUATE                86600020
P10      EQU   10                      * CONSTANT EQUATE                86700020
P11      EQU   11                      * CONSTANT EQUATE                86800020
P12      EQU   12                      * CONSTANT EQUATE                86900020
P13      EQU   13                      * CONSTANT EQUATE                87000020
P14      EQU   14                      * CONSTANT EQUATE                87100020
P15      EQU   15                      * CONSTANT EQUATE                87200020
P16      EQU   16                      * CONSTANT EQUATE                87300020
P17      EQU   17                      * CONSTANT EQUATE                87400020
P18      EQU   18                      * CONSTANT EQUATE                87500020
P19      EQU   19                      * CONSTANT EQUATE                87600020
P20      EQU   20                      * CONSTANT EQUATE                87700020
P21      EQU   21                      * CONSTANT EQUATE                87800020
P22      EQU   22                      * CONSTANT EQUATE                87900020
P24      EQU   24                      * CONSTANT EQUATE                88000020
P25      EQU   25                         * CONSTANT EQUATE             88100020
P26      EQU   26                      * CONSTANT EQUATE                88200020
P32      EQU   32                         * CONSTANT EQUATE             88300020
P31A     EQU   X'31A'                  * INDEX TO DATA CHK IN RECPULOG  88400020
P31B     EQU   X'31B'                  * INDEX TO DATA CHK IN RECPULOG  88500020
*                                                                     * 88600020
EQF0     EQU   X'F0'                   * EBCDIC FOR '0'                 88700020
EQF1     EQU   X'F1'                   * EBCDIC FOR '1'                 88800020
EQF2     EQU   X'F2'                   * EBCDIC FOR '2'                 88900020
EQF3     EQU   X'F3'                   * EBCDIC FOR '3'                 89000020
EQC2     EQU   X'C2'                   * EBCDIC FOR 'B'                 89100020
EQC5     EQU   X'C5'                   * EBCDIC FOR 'E'                 89200020
EQD3     EQU   X'D3'                   * EBCDIC FOR 'L'                 89300020
EQD6     EQU   X'D6'                   * EBCDIC FOR 'O'                 89400020
EQD9     EQU   X'D9'                   * EBCDIC FOR 'R'                 89500020
*                                                                       89600020
*********************************************************************** 89700020
*****                 CONSTANTS AND WORKAREAS                     ***** 89800020
*********************************************************************** 89900020
*                                                                       90000020
         CNOP  0,8                     * DOUBLEWORD BOUNDARY            90100020
ASRPSW   DC    XL8'0'                  * NUCLEUS MCK NEW PSW SAVED      90200020
DMCIPSW  DC    X'00000000'             * TEMPORARILY DISABLE MCI        90300020
         DC    XL4'0'                  *   TO SAVE ERROR DATA           90400020
EMCIPSW  DC    X'00040000'             * ENABLE MCI TO BLEED OFF MCI    90500020
         DC    XL4'0'                  *   CAUSED BY SAVING DATA        90600020
SAVEMCW  DC    XL8'0'                  * MCW SAVED AND CHANGED HERE     90700020
MCKPTR   DC    F'0'                    * POINT TO MCK RTN ACCORDINGLY   90800020
TEMP     DC    F'0'                    * 2385 CONFIG. BYTES STORAGE     90900020
PATTERN1 DC    X'AAAAAAAA'             * 1 AND 0 PATTERN FOR EXERCISE   91000020
PATTERN2 DC    X'55555555'             * 0 AND 1 PATTERN FOR EXERCISE   91100020
PATTERN3 DC    X'FFFFFFFF'             * ALL 1'S PATTERN FOR EXERCISE   91200020
PATTERN4 DC    X'00000000'             * ALL 0'S PATTERN FOR EXERCISE   91300020
HFOUR    DC    H'4'                    * DEFINED HALFWORD CONSTANT      91400020
HEIGHT   DC    H'8'                    * DEFINED HALFWORD CONSTANT      91500020
LFRTSW   DC    X'00'                   * LEFT-RIGHT TEST SWITCH         91600020
*********************************************************************** 92400020
***  MAINTENANCE  AREA  ***                                             92450021
MAINTID  DC    CL8'IGFMCH19'           CORE IDENTIFIER                  92460021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              92470021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 92490021
         EJECT                                                          92492021
*                                                                       92500020
*********************************************************************** 92600020
RMSMSB   DSECT                                                          92630020
         RMSMSB    MOD=85                                               92660020
         EJECT                                                          92680020
COMMON   DSECT                                                          92700020
         MCHMAC                                                         92730020
COMINTEL EQU   MCHINTEL                                                 92760020
         EJECT                                                          92770020
ASRCOM   DSECT                                                          92780020
         ASRMAC85                                                       92800020
CVTTAB   DSECT                                                          92900020
         CVT                                                            93000020
         END                                                            93100020
