         LCLA  &LEV,&REL                                                00012021
&LEV     SETA  20                                                       00014021
&REL     SETA  21                                                       00016021
&REL&LEV TITLE 'IGFMCH23  &LEV  REPAIR VERIFICATION'                    00018021
*********************************************************************** 00020020
*                                                                     * 00030020
*                                                                     * 00040020
*                                                                     * 00050020
* MODULE NAME -     IGFMCH23                                            00060020
*                                                                       00070020
* FUNCTION    -     THE PURPOSE OF THIS MODULE IS THE VERIFYING OF A    00080020
*                   REPAIRED SPF KEY OR REPAIRED MAIN STORAGE           00090020
*                                                                       00100020
* STATUS      -     CHANGE LEVEL 20  06/21/71                           00110021
*                                                                       00120020
* ATTRIBUTES  -     TRANSIENT                                           00130020
*                   SERIALLY REUSABLE                                   00140020
*                   OPERATES IN SUPERVISOR MODE                         00150020
*                                                                       00160020
* ENTRY POINT -     IGFMCH23                                            00170020
*                                                                       00180020
* OPERATION   -     SPF KEY ERROR                                       00190020
*                                                                       00200020
*                        ENTRY FROM PDAR SYSTEM ANALYSIS (IGFMCHF3).    00210020
*                        ANALYSIS DETERMINED THAT THE KEY WAS REPAIR-   00220020
*                        ABLE AND CORRECTED KEY. EFFECTIVENESS OF       00230020
*                        REPAIR IS TESTED BY SETTING UP ENVIRONMENT     00240020
*                        AND FETCHING FROM AFFECTED 2K BLOCK. IF A      00250020
*                        SUCCESSFUL REPAIR WAS ACCOMPLISHED CONTROL IS  00260020
*                        PASSED TO THE SOFT MACHINE CHECK HANDLER       00270020
*                        (IGFMCH20). IF REPAIR WAS UNSUCCESSFUL CONTROL 00280020
*                        IS PASSED TO PDAR (IGFMCHF1) FOR TERMINATION.  00290020
*                                                                       00300020
*                                                                       00310020
*                   MULTIPLE BIT STORAGE ERROR                          00320020
*                                                                       00330020
*                        ENTRY FROM PDAR SYSTEM ANALYSIS (IGFMCHF2).    00340020
*                        ANALYSIS DETERMINED THAT THE ERROR WAS         00350020
*                        CORRECTABLE AND THAT THE MODULE AFFECTED WAS   00360020
*                        CHECKSUMMED. NEW DATA WAS STORED. EFFECTIVE-   00370020
*                        NESS OF REPAIR IS TESTED BY SETTING UP THE     00380020
*                        TEST ENVIRONMENT AND FETCHING A QUADWORD       00390020
*                        CONTAINING THE ERROR LOCATION. IF THE REPAIR   00400020
*                        WAS SUCCESSFUL, CONTROL IS PASSED TO THE SOFT  00410020
*                        MACHINE CHECK HANDLER (IGFMCH20) FOR RECORDING 00420020
*                        AND EXIT. IF UNSUCCESSFUL REPAIR CONTROL IS    00430020
*                        PASSED TO PDAR (IGFMCHF1) FOR TERMINATION.     00440020
*                                                                       00450020
* EXITS       -     NORMAL                                              00460020
*                                                                       00470020
*                        VERIFICATION SUCCESSFUL - IGFMCH20 (SOFT MACH. 00480020
*                                                      CHECK HANDLER)   00490020
*                        VERIFICATION UNSUCCESSFUL - IGFMCHF1 (PDAR     00500020
*                                                      SYSTEM ANALYSIS) 00510020
         EJECT                                                          00520020
         SPACE                                                          00530020
*                   ABNORMAL                                            00540020
*                                                                       00550020
*                        IGFERR0 (SECONDARY ERROR HANDLER WITHIN THE    00560020
*                        MCH NUCLEUS (IGFMCHE0)).                       00570020
         SPACE                                                          00580020
*                                                                       00590020
* INPUT       -     MCHMAC      (MACHINE CHECK HANDLER INDEPENDENT      00600020
*                             COMMON AREA)                              00610020
*                                  REPDARF1                             00620020
*                                  REPDARF2                             00630020
*                                  REPDAR2                              00640020
*                                                                       00650020
*                   FAILING ENVIRONMENT                                 00660020
*                                  GPR'S                                00670020
*                                  FPR'S                                00680020
*                                  LOGOUT                               00690020
*                                  MACHINE CK OLD PSW                   00700020
*                                                                       00710020
*                   REPAIRED LOCATION OR KEY                            00720020
*                                                                       00730020
* OUTPUT      -     MCHMAC                                              00740020
*                                  REPDAR1                              00750020
*                                  REPDAR2                              00760020
*                                  MCHNXMOD (SUCCESSOR)                 00770020
*                                                                       00780020
* RESTRICTIONS-     MODEL DEPENDENT FOR IBM SYSTEM 360 MODEL 296        00790020
*                                                                     * 00800020
* NOTES:      MAINTENANCE SPACE                                         00801020
*             A DC OF 50 BYTES WITH THE LABEL                           00802020
*             *****MAINT*****                                           00803020
*                                                                     * 00810020
*                                                                     * 00820020
*********************************************************************** 00830020
         EJECT                                                        * 00840020
IGFMCH23 CSECT                                                          00850020
* E Q U A T E S  U S E D  I N   M O D U L E                           * 00860020
         SPACE 2                                                        00870020
LEVEL    EQU   X'&LEV'             MODULE LEVEL                         00872021
ADDR     EQU   2                   ADDR OF LOCATION TO BE CONVERTED     00880020
BASEREG  EQU   15                  * MODULE BASE REG                    00890020
COMREG   EQU   11                  * COMM AREA BASE REG                 00900020
CTR      EQU   1                   CONVERSION COUNTER                   00910020
FAILED   EQU   X'40'               * RETRY FAILED                       00920020
FAILOFF  EQU   X'BF'               * RETRY FAILED OFF                   00930020
INTSPF   EQU   X'10'               * INT SPF ERROR                      00940020
INTSTG   EQU   X'40'               * INT STG ERROR                      00950020
LINK     EQU   5                   LINK REG                             00960020
MCKNPSW  EQU   112                 * MCK NEW PSW ADDR                   00970020
OKOFF    EQU   X'F7'               * RETRY OK OFF                       00980020
PDAR     EQU   X'01'               * PDAR SCHEDULE                      00990020
RETURN   EQU   14                  * RETURN REG                         01000020
RSUCCESS EQU   X'08'               * SUCCESSFUL RETRY                   01010020
TERM     EQU   X'02'               * TERMINATOR SCHEDULE                01020020
TOADDR   EQU   3                   ADDRESS OF MESSAGE FIELD             01030020
N0       EQU   0                   * DEC 0                              01040020
N1       EQU   1                   * DEC 1                              01050020
N2       EQU   2                   * DEC 2                              01060020
N3       EQU   3                   * DEC 3                              01070020
N4       EQU   4                   * DEC 4                              01080020
N8       EQU   8                   * DEC 8                              01090020
N16      EQU   16                  * DEC 16                             01100020
N24      EQU   24                  * DEC 24                             01110020
N28      EQU   28                  * DEC 28                             01120020
N116     EQU   116                 * DEC 116                            01130020
REG0     EQU   0                   * GEN REG 0                          01140020
REG3     EQU   3                   * GEN REG 3                          01150020
REG4     EQU   4                   * GEN REG 4                          01160020
REG5     EQU   5                   * GEN REG 5                          01170020
REG6     EQU   6                   * GEN REG 6                          01180020
REG7     EQU   7                   * GEN REG 7                          01190020
REG8     EQU   8                   * GEN REG 8                          01200020
REG9     EQU   9                   * GEN REG 9                          01210020
REG15    EQU   15                  * GEN REG 15                         01220020
         SPACE  2                                                       01230020
X39      EQU   X'39'               CONSTANT FOR CONVERSION              01240020
X40      EQU   X'40'               SOFTWARE RECOVERY FLAG               01242020
XB7      EQU   X'B7'               CONSTANT FOR CONVERSION              01250020
         EJECT                                                          01260020
BEGIN    EQU   *                                                        01270020
         USING *,BASEREG           ESTABLISH ADDRESSABILITY             01280020
         USING COMDSECT,COMREG     EST. ADDR. FOR COMMON AREA           01290020
         STM   REG0,REG15,MCHMLSAV SAVE REGISTERS                       01300020
         MVI   MCHEXLEV,LEVEL      SAVE MODULE CHANGE LEVEL             01310021
         ST    COMREG,COMSAVE      SAVE COMMON AREA BASE                01320020
         MVC   MCKNSAVE(N8),MCKNPSW     SAVE MACHINE CHECK NEW PSW      01330020
         SPACE 2                                                        01340020
* DETERMINE TYPE OF ERROR WHICH CAUSED ENTRY                            01350020
STGTEST  EQU   *                                                        01360020
         TM    REPDAR2,INTSTG      STORAGE ERROR                        01370020
         BZ    SPFTEST             NO-TEST FOR SPF ERROR                01380020
         B     STGFIXCK            YES-CHECK STORAGE REPAIR             01390020
SPFTEST  EQU   *                                                        01400020
         TM    REPDAR2,INTSPF      SPF ERROR                            01410020
         BO    SPFFIXCK            YES-CHECK SPF REPAIR                 01420020
         B     BADEXIT2            NO-EXIT AS IF UNSECCESSFUL VERIFY    01430020
         SPACE 4                                                        01440020
STGFIXCK EQU   *                                                        01450020
         L     REG5,REPDARF1       GET START OF EFFECTED QUADWORD       01460020
         DC    X'8300'             DISABLE                              01470020
         DC    S(BDISABLE)         *      BUFFER                        01480020
         LA    REG3,BADEXIT1       RESET MACHINE CHECK NEW PSW          01490020
         ST    REG3,MCKNPSW+N4     *    TO POINT TO THIS ROUTINE        01500020
         LA    REG6,GOODEXT1       * INSTRUCTION ADDR FOR PSW           01510020
         ST    REG6,EXITPSW+N4     * STORE IT INTO PSW                  01520020
         SPACE 4                                                        01530020
* THE INSTRUCTION BELOW WILL CAUSE A FOUR WORD FETCH FROM MAIN STORAGE  01540020
* IF THE ERROR WAS REPAIRED THE NSI WILL BE EXECUTED                    01550020
* IF REPAIR WAS NOT GOOD A MACHINE CHECK WILL OCCUR CAUSING CONTROL     01560020
* TO PASS TO THIS MODULE AT THE LABEL BADEXIT1                          01570020
         SPACE 2                                                        01580020
REPTEST  EQU   *                                                        01590020
         CLC   N0(N16,REG5),N0(REG5)   CAUSE FETCH                      01600020
         SPACE 6                                                        01610020
* NO MACHINE CHECK OCCURRED REPAIR IS GOOD                              01620020
GOODEXIT EQU   *                                                        01630020
         LPSW  EXITPSW             * LOAD PSW TO RESET KEY              01640020
GOODEXT1 EQU   *                                                        01650020
         MVC   MCKNPSW(N8),MCKNSAVE     RESTORE MACHINE CK NEW PSW      01660020
         DC    X'8300'             ENABLE                               01670020
         DC    S(BENABLE)          *     BUFFER                         01680020
         NI    REPDAR1,FAILOFF     INSURE REPAIR FAILED IS OFF          01690020
         OI    REPDAR2,RSUCCESS    TURN ON REPAIR SUCCESSFUL            01700020
         OI    MCHDAMAG,X40        TURN ON SOFTWARE RECOVERY            01702020
         B     PREPMSG             PREPARE MESSAGE                      01710020
         SPACE 2                                                        01720020
GOODEXT2 EQU   *                                                        01730020
         MVI   MCHNXMOD,TERM       SCHEDULE TERMINATOR                  01740020
         L     REG7,MCHIPTR        * MSG BUF ADDR                       01750020
         MVC    N0(N8,REG7),RETRYMSG MOVE MSG INTO BUFFER               01760020
         LA    REG7,N8(REG7)       * UPDATE MSG BUFFER                  01770020
         ST    REG7,MCHIPTR        * UPDATE MSG BUFFER PTR              01780020
         LM    REG0,REG15,MCHMLSAV RESTORE REGISTERS                    01790020
         BR    RETURN              GO TO MOD SCHEDULER                  01800020
         EJECT                                                          01810020
* CODE BELOW BULIDS THE MESSAGE IGF032I FOR SUCCESSFUL RETRY            01820020
         SPACE 4                                                        01830020
PREPMSG  EQU   *                                                        01840020
         LA    CTR,N3              SET CYCLE COUNTER                    01850020
         LA    ADDR,REPDARI+N1     GET ADDR OF ADDRESS TO BE CONVERTED  01860020
         LA    TOADDR,MSGTEXT      GET ADDR OF TEXT FIELD OF MESSAGE    01870020
*                                  TO PUT CONVERTED ADDR IN             01880020
         SPACE  2                                                       01890020
NEXTBYTE EQU   *                                                        01900020
         SR    REG8,REG8           CLEAR WORK REG                       01910020
         IC    REG8,N0(ADDR)       GET BYTE TO BE CONVERTED             01920020
         SRDL  REG8,N4             KEEP LEFT 4 BITS PASS REST           01930020
         BAL   LINK,CONVERT        GO TO CONVERT FOR PRINT              01940020
         SRL   REG9,N28            SHIFT FOR LOW ORDER 4 BITS           01950020
         LR    REG8,REG9           TRANSFER FOR CONVERT                 01960020
         BAL   LINK,CONVERT        GO TO CONVERT FOR PRINT              01970020
         LA    ADDR,N1(ADDR)       UPDATE INPUT ADDRESS                 01980020
         BCT   CTR,NEXTBYTE        CONTINUE UNTIL 3 BYTES CONVERTED     01990020
         B     GOODEXT2            RETURN TO EXIT ROUTINE               02000020
         SPACE  2                                                       02010020
CONVERT  EQU   *                                                        02020020
         LA    REG8,XB7(REG8)      CONVERT TO PRINTABLE RANGE           02030020
         CH    REG8,XC1            IS IT A PRINTABLE LETTER             02040020
         BNL   STORE               YES - SAVE IT                        02050020
         LA    REG8,X39(REG8)      NO  - CONVERT TO PRINTABLE NR        02060020
         SPACE 2                                                        02070020
STORE    EQU   *                                                        02080020
         STC   REG8,N0(TOADDR)     PUT DATA IN MSG                      02090020
         LA    TOADDR,N1(TOADDR)   UPDATE MESSAGE POINTER               02100020
         BR    LINK                RETURN TO MESSAGE PROCESSOR          02110020
         EJECT                                                          02120020
SPFFIXCK EQU   *                                                        02130020
         L     REG5,REPDARF1       GET ADDR OF EFFECTED LOCATION        02140020
         IC    REG4,MCHRPSW+N1     GET STORAGE KEY FROM MCK OLD PSW     02150020
         SRL   REG4,N4             * INSURE AMWP                        02160020
         SLL   REG4,N2             *           CLEARED AND              02170020
         LA    REG4,N1(REG4)       * MACHINE CHECKS                     02180020
         SLL   REG4,N2             *              ARE ENABLED           02190020
         STC   REG4,MYMCKPSW+N1    SET KEY AND AMWP                     02200020
         LA    REG4,REPTEST        * SET ADDRESS OF                     02210020
         ST    REG4,MYMCKPSW+N4    * TEST INSTR IN PSW                  02220020
         DC    X'8300'             DISABLE                              02230020
         DC    S(BDISABLE)         *     BUFFER                         02240020
         LA    REG3,BADEXIT1       RESET MACHINE CHECK NEW PSW          02250020
         ST    REG3,MCKNPSW+N4     *    TO POINT TO THIS ROUTINE        02260020
         LA    REG6,GOODEXT1       * INSTRUCTION ADDR FOR PSW           02270020
         ST    REG6,EXITPSW+N4     * STORE IT INTO PSW                  02280020
         LPSW  MYMCKPSW            SET UP PSW TO TEST KEY AT            02290020
*                                  REPTEST                              02300020
         SPACE 4                                                        02310020
BADEXIT1 EQU   *                                                        02320020
BASEADJ  EQU   BADEXIT1-BEGIN                                           02330020
         L     BASEREG,N116        GET ADDRESS AT THIS LOCATION         02340020
         LA    REG4,BASEADJ        GET FACTOR TO ESTABLISH MODULE ADDR  02350020
         SR    BASEREG,REG4        ESTABLISH BASE                       02360020
         L     COMREG,COMSAVE      SET UP COMMON AREA BASE              02370020
         DC    X'8300'             * ENABLE                             02380020
         DC    S(BENABLE)          *      BUFFER                        02390020
BADEXIT2 EQU   *                                                        02400020
         NI    REPDAR2,OKOFF       TURN OFF REPAIR SUCCESSFUL           02410020
         OI    REPDAR1,FAILED      TURN ON REPAIR FAILED                02420020
         MVI   MCHNXMOD,PDAR       SCHEDULE PDAR                        02430020
         LM    REG0,REG15,MCHMLSAV RESTORE REGISTERS                    02440020
         BR    RETURN              GO TO MOD SCHEDULER                  02450020
         EJECT                                                          02460020
***                           C O N S T A N T S                     *** 02470020
***                        D O U B  L E  W O R D S                  *** 02480020
***                              F I R S T                          *** 02490020
         DS    0D                                                       02500020
MCKNSAVE DC    D'0'                SAVE FIELD FOR MCK NEW PSW           02510020
MYMCKPSW EQU   *                                                        02520020
         DC    F'0'                DISABLED MASK                        02530020
         DC    F'0'                ADDRESS FIELD                        02540020
EXITPSW  DC    X'00040000'         * FIRST HALF OF PSW                  02550020
         DC    F'0'                SECOND HALF OF PSW                   02560020
BDISABLE DC    X'0100D100'         * BUFFER DISABLE                     02570020
COMSAVE  DC    F'0'                * COMMON AREA BASE SAVE              02580020
BENABLE  DC    X'0200D100'         * BUFFER ENABLE                      02590020
XC1      DC    X'00C1'             CONSTANT FOR CONVERSION              02600020
RETRYMSG EQU   *                   * SUCCESSFUL RETRY MSG               02610020
         DC    X'8806'             * MESSAGE CODE AND LENGTH            02620020
MSGTEXT  EQU   *                                                        02630020
         DC    C'AAAAAA'           * MESSAGE TEXT FIELD                 02640020
MAINTID  DC    CL8'IGFMCH23'       MODULE NAME                          02642021
MAINT    DC    S(*)                                                     02644021
         DC    10CL4'&REL&LEV'     MAINT SPACE                          02646021
         EJECT                                                          02660020
COMDSECT DSECT                                                          02670020
         MCHMAC                                                         02680020
         END                                                            02690020
