         LCLA  &LEV,&REL                                                00060021
&REL     SETA  21                                                       00070021
&LEV     SETA  25                                                       00080021
&REL&LEV TITLE 'IGFMCH30-165 SOFT MACHINE CHECK HANDLER'                00090021
IGFMCH30 CSECT                                                          00100020
*                                                                       00150020
*                                                                       00200020
*   NAME       IGFMCH30 SOFT MACHINE CHECK HANDLER                      00250020
*                                                                       00300020
*  CHART ID    BA,BB,BC,BD,BE,BF                                        00350020
*                                                                       00400020
*        STATUS    LEVEL = 22  10/19/73                        @S66087P 00410021
*                                                                       00420020
*  FUNCTION    1. FORMATING MACHINE CHECK RECORD FOR THE SYS1.LOGREC    00450020
*                 DATA SET                                              00500020
*                                                                       00550020
*              2. AUTOMATIC MODE SWITCHING. WHEN THE SUM TOTAL OF SOFT  00600020
*                 ERRORS REACHES THE ESTABLISHED THRESHOLD ERROR VALUE, 00650020
*                 THE OPERATOR IS NOTIFIED THAT FURTHER ERROR REPORTS   00700020
*                 WILL NOT BE RECORDED                                  00750020
*                                                                       00800020
*              3. HIGH SPEED BUFFER DISABLE. WHEN THE GENERAL BUFFER    00850020
*                 ERROR COUNT EXCEEDS FOUR, THE BUFFER OPERATION WILL   00900020
*                 BE DISABLED                                           00950020
*                                                                       01000020
*              4. RECORD BUFFER MANAGEMENT : RECORD RETRIEVAL AND       01050020
*                 OVER LAY HANDLING                                     01100020
*                                                                       01150020
*              6. TERMINATES MACHINE CHECK HANDLER AND RESTORES THE     01200020
*                 SYSTEM STATUS                                         01250020
*                                                                       01300020
*  INPUT       LOGOUT - MODEL INDEPENDENT OR/AND MODEL DEPENDENT        01350020
*                       LOGOUT                                          01400020
*              EXTENDED INTERRUPT CODE                                  01450020
*              RMS COMMON AREA                                          01500020
*                                                                       01550020
*  OUTPUT      RECOVERY OR DAMAGE REPORT TO RMS RECORDER                01600020
*              MODE SWITCHING MESSAGE                                   01650020
*              MACHINE INTERRUPT CODE                                   01700020
*              HIGH SPEED BUFFER DELETE MESSAGE                         01750020
*                                                                       01800020
*  MACROS      CVT,MCHMAC,RMSMSB                                        01850020
*                                                                       01900020
*  NOTES       MAINTENANCE AREA OF 50 BYTES IS LOCATED AT LABEL MAINT   01950020
*                                                                       02000020
* THESE ARE EQUATES FOR REGISTERS                                       02050020
*                                                                       02100020
R0       EQU   0                   GEN REG 0                            02150020
RWORK0   EQU   0                                                        02200020
R1       EQU   1                                                        02250020
MSBBASE  EQU   1                   BASE FOR MACHINE STATUS BLOCK (MSB)  02300020
RCNTTCB  EQU   2                    POINTS TO CURRENT TCB               02350020
R2       EQU   2                                                        02400020
COUNT    EQU   3                                                        02450020
RRECNO   EQU   3                   CONTAINS BUFFER NUMBER               02500020
RWORK3   EQU   3                                                        02550020
RRB      EQU   3                   RB REGISTER                          02600020
R3       EQU   3                                                        02650020
RRECPTR  EQU   4                   POINTER TO CURRENT BUFFER            02700020
RECPTR   EQU   4                                                        02750020
RMSG     EQU   4              POINTS TO MESSAGE BUFFER                  02800020
R4       EQU   4                                                        02850020
RWORK5   EQU   5                                                        02900020
R5       EQU   5                                                        02950020
RWORK6   EQU   6                   WORK REGISTER                        03000020
R6       EQU   6                                                        03050020
RSECT    EQU   7              ERROR COUNTER REGISTER                    03100020
RWORK7   EQU   7                   WORK REGISTER                        03150020
R7       EQU   7                                                        03200020
RPRB     EQU   8                                                        03250020
R8       EQU   8                                                        03300020
R9       EQU   9                                                        03350020
RCOM     EQU   11                   BASE FOR COMMON AREA                03400020
RCVT     EQU   10             CVT BASE                                  03450020
R10      EQU   10                  GEN REG 10                           03500020
R11      EQU   11                                                       03550020
R13      EQU   13                                                       03600020
R14      EQU   14                  REG 14                               03650020
R15      EQU   15                  REG 15                               03700020
RBASE    EQU   15                   BASE FOR SMCIH                      03750020
*                                                                       03800020
* EQUATES FOR FLOATING POINT REGISTERS                                  03850020
*                                                                       03900020
FR0      EQU   0                   FLOATING REGISTER 0                  03950020
FR2      EQU   2                   FLOATING REGISTER 2                  04000020
FR4      EQU   4                   FLOATING REGISTER 4                  04050020
FR6      EQU   6                   FLOATING REGISTER 6                  04100020
*                                                                       04150020
*  THESE ARE EQUATES FOR AUTOMATIC MODE SWITCHING ROUTINE               04200020
*                                                                       04250020
INTPCODE EQU   0                   RELATIVE ADDR OF MCI CODE            04300020
*                                  IN INDEPENDENT LOGOUT AREA           04350020
EXTLG    EQU   0                   REL.START ADDR OF EXTENDED LOGOUT A. 04400020
ECC      EQU   X'40'               MASK TO TEST FOR ECC                 04450020
*                                                                       04500020
* MISCELLANEOUS EQUATES                                                 04550020
*                                                                       04600020
SRD      EQU   X'80'               FLAG FOR SHORT RECORD                04650020
SOFTMASK EQU   X'F7'               MASK TO DISABLE SOFT MCI             04700020
ECCMSG   EQU   X'0E'               MSG CODE FOR ECC CORRECTED           04750020
CPUMSG   EQU   X'12'               MSG CODE FOR CPU RETRY               04800020
QTMASK   EQU   X'7F'               MASK TO CLEAR FOR QUIET MODE         04850020
MSGCODE  EQU   X'18'               MESSAGE CODE FOR QUIET MODE          04900020
TIOCNJOB EQU   0                    TIOT + 0 CONTAINS JOB NAME          04950020
CNTTCB   EQU   4                    CVT POINTS TO CURRENT TCB ADDRESS   05000020
MVTMASK  EQU   X'10'                MASK TO TEST MVT SYSTEM             05050020
TCBRBP   EQU   0                    TCB + 0 POINTS TO RB                05100020
PRBMASK  EQU   X'C0'                MASK TO TEST PRB                    05150020
RBSTAB   EQU   10                   RB + 10 IS FLAG FIELD               05200020
RBSTAB1  EQU   RBSTAB+1            RB FIELD                             05250020
TCBTIO   EQU   12                   TCB + 12 POINTS TO TIOT             05300020
RBLINK   EQU   28                   RB + 28 POINTS TO NEXT RB OR TCB    05350020
RBTCBNXT EQU   X'80'                MASK TO TEXT RBLINK FIELD           05400020
RBCDE    EQU   12                   PRB+12 POINTS TO CDE                05450020
CDENM    EQU   8                    CDE+8 CONTAINS PGM NAME - MVT       05500020
TIOJOBID EQU   0                   DISPLACEMENT FOR JOB ID              05550020
TIOCSTEP EQU   8                   STEP ID DISPLACEMENT                 05600020
EXTLOGON EQU   X'40'               MASK TO TURN ON EXTENDED LOG         05650020
EXTLOGOF EQU   X'BF'               MASK TO TURN OFF EXTENDED LOG        05700020
OFF      EQU   8                                                        05750020
XRBNM    EQU   0                   PROGRAM NAME                         05800020
SETBLSEL EQU   X'0F'               BLOCK SELECT MASK                    05850020
CLRBLSEL EQU   X'F0'               BLOCK SELECT MASK                    05900020
CLRPRTNO EQU   X'00'               PARTITION NUMBER MASK                05950020
CLBYPSBT EQU   X'DF'               BYPASS SWITCH MASK                   06000020
STBYPSBT EQU   X'20'               BYPASS SWITCH MASK                   06050020
STDISBBT EQU   X'60'              DISABLE BIT MASK                      06100020
CLOCKERR EQU   X'02'               MASK TO CHECK IF MCI CAUSED BY CLOCK 06150020
*                                                                       06200020
** MASKS FOR BUFFER DELETION                                            06250020
*                                                                       06300020
XBF      EQU   X'BF'               MASK FOR BUFFER DELETION FLAG        06350020
*                                  RESET                                06400020
*                                                                       06450020
* THESE ARE EQUATES FOR THE ABBREVIATED RECORD                          06500020
*                                                                       06550020
KEY      EQU   0                   KEY                                  06600020
*   BYTE 0   BIT 0-7    X'10'      MCH RECORD                           06650020
*                                                                       06700020
OSRELNO  EQU   1                   OS - RELEASE LEVEL                   06750020
*   BYTE 1   BIT 0-2    000        OS                                   06800020
*                3-7    10011      RELEASE LEVEL                        06850020
RECSW    EQU   2                   RECORD SWITCH                        06900020
*                                                                       06950020
*   BYTE0   BIT 0=1                OPERATOR MESSAGE                     07000020
*               1=1                NS MACHINE                           07050020
*               2=1                EC MODE                              07100020
*               3-7                RESERVED                             07150020
*   BYTE 1   BIT 0=1               SHORT RECORD                         07200020
*               1=1                IMCOMPLETE                           07250020
*               2=1                MCH TERMINTE SYSTEM                  07300020
SPARE    EQU   4                                                        07350020
SERNO    EQU   6                   CPU SERIAL NUMBER                    07400020
DATE     EQU   8                   DATE                                 07450020
TIME     EQU   12                  TIME                                 07500020
CPUID    EQU   16                  CPUID                                07550020
PGMID    EQU   24                  PROGRAM ID                           07600020
JOBID    EQU   32                  JOB ID                               07650020
MCPSW    EQU   40                  MACHINE CHECK OLD PSW                07700020
MCICODE  EQU   48                  MACHINE CHECK INTERRUPTION CODE      07750020
DASMT    EQU   56                  RMS ASSESSMENT                       07800020
LOSTSUM  EQU   64                  RMS RECORD LOST SUMMARY              07850020
RECFLAG  EQU   70                  FLAG FOR RMS RECORDER                07900020
ACTIVE   EQU   X'80'               INDICATS THE ACTIVE RECORD. IT IS    07950020
*                                  SET BY SMCIH, RESET BY RECORDER      08000020
SHORT    EQU   X'40'               SHORT RECORD FLAG                    08050020
CLOBBER  EQU   X'10'               INDICATES THAT THE CORRELATED LOGOUT 08100020
*                                  IS OVERLAID                          08150020
KEYC     EQU   X'10'               KEY FOR MCH RECORD                   08200020
SWITCH   EQU   X'C0'               SWITCH SETTING                       08250020
*                                                                       08300020
*                                                                       08350020
* EQUATES FOR LOST SUMMARY                                              08400020
*                                                                       08450020
BUFDIS   EQU   X'20'               BUFFER DISABLED INDICATOR            08455000
HIRMODE  EQU   X'08'               HIR MODE INTERROGATION MASK          08460000
RECRDE   EQU   X'40'               ECC RECORD MODE INDICATOR            08465000
RECRDH   EQU   X'80'               HIR RECORD MODE INDICATOR            08470000
X7F      EQU   X'7F'               MASK TO TURN OFF QUIET MODE BIT      08475000
HEX40    EQU   X'40'               BUFFER ERROR INDICATOR               08480000
X0F      EQU   X'0F'               HEX EQUATE                           08485000
X1F      EQU   X'1F'               FLOATING POINT TCB BIT      IG 51236 08487021
XF0      EQU   X'F0'               HEX EQUATE                           08490000
XC0      EQU   X'C0'               HEX EQUATE                           08495000
ABNDCTR  EQU   64                  TASK ABEND COUNTER                   08500020
RECOVCTR EQU   65                  RECOVERY COUNTER                     08550020
SOFTCTR  EQU   66                  SOFT ERROR COUNTER                   08600020
DSOFT    EQU   56                  DISPLACEMENT FOR SOFT COUNTER FIELD  08650020
QUIET    EQU   X'80'               MASK FOR QUIET MODE                  08700020
SOFT     EQU   X'80'               MASK FOR SOFT ERROR                  08750020
CCHER    EQU   X'04'               MASK FOR CATASTROPHIC I/O ERROR      08800020
MS       EQU   X'80'                FLAG FOR MAIN STORAGE ERROR         08850020
PROC     EQU   X'08'               FLAG FOR PROCESSOR ERROR             08900020
DATA     EQU   X'20'               FLAG FOR DATA ERROR                  08950020
DSTORAGE EQU   57                  DISPLACEMENT FOR STORAGE ERROR       09000020
STG      EQU   X'80'               MASK TO TEST STORAGE ERROR           09050020
DRECV    EQU   56                  DISPLACEMENT FOR RECOVERY            09100020
RECV     EQU   X'40'               MASK TO TEST RECOVERY                09150020
WAITMASK EQU   X'02'               WAIT MASK                            09200020
RECLENG  EQU   71                  BUFFER LENGTH                        09250020
LONG     EQU   X'20'               MASK FOR RECORD - LONG               09300020
SYST     EQU   X'20'               RMS TERMINATION SYSTEM FLAG          09350020
EXTRDA   EQU   X'0C'               MASK FOR EXTERNAL DAMAGE             09400020
TSYS     EQU   X'08'               MASK TO TEST SYSTEM TERMINATION      09450020
WTOACTV  EQU   X'40'               WTO ACTIVE BIT                       09500020
X80      EQU   X'80'               IOS INTERFACE FLAG                   09550020
X30      EQU   X'30'               MODEL ID                             09600020
MCHE3    EQU   X'0B'               CODE FOR IGFMCHE3                    09650020
ERD      EQU   X'08'               SYSTEM TERMINATION MASK              09700020
CVTRMSD  EQU   224                 RMSMSB = CVT + 224                   09750020
BUF       EQU  X'19'          BUFFER CODE                               09760020
XFE      EQU   X'FE'               MASK TO TEST DISABLED PSW            09800020
X10P     EQU   X'10'               PROBLEM PGM.                         09810020
SHORTS   EQU   X'80'              FSHORT RECORD SWITCH                  09850020
LONGS    EQU   X'7F'               LONG RECORD SWITCH                   09900020
TERMS    EQU   X'20'               TERMINATION SWITCH                   09950020
BYPASLAT EQU   X'08'               BYPASS LATCH                         10000020
BARRYCHK EQU   X'1C'               BUFFER ARRAY CHECKS                  10050020
BCNTLCHK EQU   X'0C'               BUFFER CONTROL CHECKS                10100020
BDBOCHK1 EQU   X'3C'               BUFFER DATA BUS OUT CHECK            10150020
BDBOCHK2 EQU   X'F0'               BUFFER DATA BUS OUT CHECK            10200020
DISAMASK EQU   X'40'               MASK TO INDICATE DISABLED BUFFER     10250020
K0       EQU   0                                                        10300020
K1       EQU   1                                                        10350020
K2       EQU   2                  *                                     10360020
K3       EQU   3                                                        10400020
K6       EQU   6                                                        10450020
X0       EQU   0                                                        10500020
X1       EQU   1                   ONE                                  10550020
X2       EQU   2                   INTEGER                              10600020
X3       EQU   3                   ABSOLUT NUMBER                       10650020
X4       EQU   4                                                        10700020
X5       EQU   5                   FIVE                                 10750020
X6       EQU   6                   SIX                                  10800020
X8       EQU   8                                                        10850020
X10      EQU   10                                                       10900020
X12      EQU   12                                                       10950020
X16      EQU   16                                                       11000020
X20      EQU   20                  DECIMAL TWENTY                       11050020
X24      EQU   24                                                       11100020
X32      EQU   32                                                       11150020
X40      EQU   40                                                       11200020
X48      EQU   48                  MCI OLD PSW                          11250020
X49      EQU   49                                                       11300020
X53      EQU   53                  PSW                                  11350020
X64      EQU   64                                                       11400020
X72      EQU   72                                                       11450020
X128     EQU   128                                                      11500020
X120     EQU   120                 120                                  11550020
X152     EQU   152                 152                                  11600020
X192     EQU   192                                                      11650020
X248     EQU   248                 DECIMAL 248                          11700020
X272     EQU   272                 272                                  11750020
X328     EQU   328                 CTL REG 14 DISPLACEMENT FROM         11800020
*                                  INDEPENDENT LOGOUT                   11850020
X500     EQU   500                                                      11900020
X276     EQU   276                                                      11950020
X255     EQU   255                PARTITION NUMBER                      12000020
X7       EQU   7                  CONSTANT                              12050020
XEE      EQU   X'EE'               ADDR OF EXTENDED LOG LENGTH @S66087P 12053021
X1D      EQU   X'1D'               DISP TO TCB FLAG1           @S66087P 12056021
XFF      EQU   X'FF'              MASK TO TEST MCHSPARE                 12060021
D503     EQU   503                                                      12100020
D505     EQU   505                                                      12150020
D506     EQU   506                                                      12200020
D507     EQU   507                                                      12250020
D509     EQU   509                                                      12300020
LEVEL    EQU   X'&LEV'             MODULE LEVEL                         12310021
*                                                                       12350020
* SET REQUIRED BASE                                                     12400020
*                                                                       12450020
*                                                                       12500020
         USING *,RBASE             OUR BASE                             12550020
         USING CVTTAB,RCVT         ADDRESSABILITY FOR CVT               12600020
         USING MACLABEL,RCOM       COMMON AREA BASE                     12650020
         MVI   MCHEXLEV,LEVEL      MODULE LEVEL                         12700021
         MVI   MCHNXHIS,X30        INDICATE MOD ID                      12750020
         L     R9,MCHINLOG         INDEPENDENT LOG                      12800020
         L     RMSG,MCHIPTR        GET WTO BUFFER POINTER               12850020
         L     MSBBASE,MCHMSB      GET MACHINE STATUS BLOCK POINTER     12900020
         USING MSB553,MSBBASE      ESTAB ADDRESS FOR MACH STATUS BLOCK  12950020
         TM    MCHDAMAG+X1,CCHER   CATASTROPHIC I/O ERROR               13000020
         BO    EMRD                BRANCH IF YES                        13050020
         TM    MCHDAMAG,ERD        Q. TERMINATE SYSTEM                  13100020
         BO    BFRSTATS            BRANCH IF YES                        13150000
         TM    MCHDAMAG,SOFT       Q.SOFT ERROR                         13200020
         BZ    BFRSTATS            BRANCH IF NO                         13250000
*                                                                       13300020
AMS0     EQU   *                                                        13350020
         TM    INTPCODE+X2(R9),ECC      Q.WAS CORRECTED STORAGE ERROR   13400020
         BZ    AMS2                NO.CPU ERROR INDICATED               13450020
AMS1     EQU   *                                                        13500020
         OI    MCHDAMAG+X1,MS      SET MAIN STORAGE ERROR FLAG          13550020
         OI    MCHDAMAG+X2,DATA    SET DATA ERROR FLAG                  13600020
         MVI   X0(RMSG),ECCMSG     SET-UP FOR ECC CORRECTED MESSAGE     13650020
         B     AMS3                CONTINUE PROCESSING                  13700020
AMS2     EQU   *                                                        13750020
         TM    INTPCODE(R9),EXTRDA      Q.WAS EXTERNAL DAMAGE           13800020
         BC    X5,BFRSTATS         YES,BYPASS                           13850000
         OI    MCHDAMAG+X1,PROC    SET PROCESSOR ERROR FLAG             13900020
         MVI   X0(RMSG),CPUMSG     SET-UP CPU RETRY MESSAGE             13950020
AMS3     EQU   *                                                        14000020
         LA    RMSG,X1(RMSG)       UPDATE MESSAGE                       14050020
         NI    MCHINT+K3,X7F       CLEAR QUIET MODE INDICATOR           14100000
*                                                                       14150020
* AUTOMATIC MODE SWITCHING ROUTINE                                      14200020
*                                                                       14250020
         L     COUNT,MSBCOUNT      GET COUNT OF SOFT ERRORS             14300020
         LA    COUNT,X1(COUNT)     UPDATE ERROR COUNT BY ONE            14350020
         ST    COUNT,MSBCOUNT      SAVE ERROR COUNT IN MSB              14400020
         C     COUNT,MSBTHRLD      Q.HAS ERROR COUNT REACHED THE        14450020
*                                  ERROR THRESHOLD                      14500020
         BL    BFRSTATS            NO,BRANCH                            14550000
         NI    X272(R9),SOFTMASK   TURN RECOVERY BIT OFF                14600020
         OI    MCHINT+K3,X80       INDICATE QUIET MODE FOR RECORDER     14620000
         NI    MSBMODE,QTMASK      CHANGE TO QUIET MODE                 14650020
         MVI   X0(RMSG),MSGCODE    MOVE MSG CODE IN WTO BUFFER          15200020
         LA    RMSG,X1(RMSG)       UPDATE MESSAGE BUFFER                15250020
*                                                                       15252021
*** THIS ROUTINE TOTALS HIGH SPEED BUFFER ERRORS. THE BUFFER IS DISABL- 15255000
*   ED WHEN THE ERROR COUNT EXCEEDS FOUR ON M165.                       15260021
*                                                                       15265000
BFRSTATS EQU   *                                                        15270000
         TM    MCHSPARE,XFF        Q.IS THIS A MOD 168,165II IC S21122  15272021
         BNO   BFRSTAT1            NO,GO DO 165 BUFR CHECKS  IC S21122  15274021
         TM    INTPCODE(R9),X1     Q.WAS A BUFFER ERROR      IC S21122  15274421
         BZ    BUF1                NO,CONTINUE PROCESSING    IC S21122  15284421
         B     BUFRCHK1            YES,PROCESS BUFR ERROR    IC S21122  15287021
BFRSTAT1 EQU   *                                                        15287421
         L     R6,X276(R9)         SET-UP POINTER TO EXTENDED LOG-OUT   15288821
         TM    EXTLG+D505(R6),BCNTLCHK  Q.ANY BUFR ARRAY CHECK BITS SET 15295021
         BC    X5,BUFRCHK          YES,BRANCH TO INCREMENT COUNTER      15301221
         TM    EXTLG+D509(R6),BARRYCHK  Q.ANY BUFR ARRAY CHECK BITS SET 15307421
         BC    X5,BUFRCHK          YES,BRANCH TO INCREMENT COUNTER      15313621
         TM    EXTLG+D506(R6),BDBOCHK1  Q.ANY BUF DA BUS OUT CHK BITS   15319821
         BC    X5,BYPASCHK         YES,ALSO CHECK BYPASS LATCH BIT      15326021
         TM    EXTLG+D507(R6),BDBOCHK2  Q.ANY BUF DA BUS OUT CHK BITS   15332221
         BZ    BUF1                NO BUFFER ERRORS            @S66087P 15338421
BYPASCHK EQU   *                                                        15350821
         TM    EXTLG+D503(R6),BYPASLAT  Q.BYPASS LATCH BIT SET          15357021
         BO    BUF1                YES,NOT A BUFFER DATA BUS OUT ERROR  15363221
BUFRCHK  EQU   *                                                        15369421
         OI    MCHDAMAG+X1,HEX40   INDICATE BUFFER ERROR                15375621
         LH    COUNT,MSBBUFER      GET COUNT OF GENERAL BUFFER ERRORS   15381821
         LA    COUNT,X1(COUNT)     UPDATE ERROR COUNT BY ONE            15388021
         STH   COUNT,MSBBUFER      SAVE BUFFER ERROR COUNT IN MSB       15394221
         CH    COUNT,MSBBUFTH      Q.HAS ERROR COUNT EXCEEDED THE       15400421
*                                  BUFFER ERROR THRESHHOLD              15406621
         BL    BUF1                NO                                   15412821
         OI    MSBMODE,DISAMASK    INDICATE BUFFER IS DISABLEDIC S21122 15413221
         OI    MSB3,STDISBBT       INDICATE STATUS            IC S21122 15413621
BUFRCHK1 EQU   *                                                        15414821
         MVI   X0(RMSG),BUF        PUT MESSAGE INTO WTO BUFFER          15419021
         LA    RMSG,X1(RMSG)       UPDATE MESSAGE BUFFER POINTER        15425221
*                                                                       15443821
* THIS ROUTINE HANDLES BUFFER AVAILABLE CONDITION                       15450020
*                                                                       15500020
BUF1     EQU   *                                                        15550020
         ST    RMSG,MCHIPTR        UPDATE MSG BUFFER PTR                15555000
         TM    X272(R9),HIRMODE    DETERMINE HIR AND ECC MODE STATUS    15560000
         BZ    BUFTEST             HIR QUIET,ECC QUIET BY DEFAULT       15565000
         OI    MCHDAMAG+X4,XC0     INDICATE HIR RECORD, ECC RECORD      15570021
BUFTEST  EQU   *                                                        15580000
         TM    MSBMODE,DISAMASK    IS BUFFER DISABLED                   15585000
         BZ    BUFMGMT             NO                                   15590000
         OI    MCHDAMAG+X4,BUFDIS  INDICATE BUFFER IS DISABLED          15595000
BUFMGMT   EQU  *                                                        15600020
         NI    X272(R9),SOFTMASK   TURN RECOVERY BIT OFF                15650000
***   THIS CODE ALSO CORRECTS APAR 66528   ***                 @S66087P 15700021
         LH    R5,XEE              LOAD EXTENDED LOG LENGTH    @S66087P 15770021
         LR    R7,R5               SAVE LENGTH FOR MOVE        @S66087P 15840021
         L     R4,MSBPRI           LOAD ADDR OF PRIMARY LOGOUT @S66087P 15910021
         L     R6,MSBSEC           LOAD ADDR OF SECONDARY LOGOUT        15980021
         MVCL  R6,R4               MOVE PRIMARY TO SECONDARY   @S66087P 16050021
         LA    R6,RECLENG          GET SIZE OF ABREC                    16150020
         SR    R3,R3               CLEAR INITIALLY                      16200020
         LA    R5,MCHABREC         INIT TO FIRST ABREC                  16250020
         LR    RECPTR,R3           ZERO ALSO                            16300020
         IC    R3,MCHABRNO         GET NUMBER OF ABRECS                 16350020
TSTACTIV EQU   *                                                        16400020
         TM    RECFLAG(R5),ACTIVE  IS THIS ABREC AREA ACTIVE(USED)      16450020
         BNZ   BUFUSED             YES,DETERMINE IF I/O IN PROGRESS     16500020
         LR    RECPTR,R5           NO,SET PTR IN REG FOR LATER          16550020
BUFUSED  EQU   *                                                        16600020
         TM    RECFLAG(R5),LONG    IS A FULL MCH RECORD I/O IN PROGRESS 16650020
         BZ    NOLONGIO            NO,DO NOT SET EXCP CLOBBERED         16700020
         OI    RECFLAG(R5),CLOBBER SET EXCP OPERATION CLOBBERED         16750020
NOLONGIO EQU   *                                                        16800020
         OI    K3(R5),SHORTS       SET SHORT RECORD INDICATOR IN HEADER 16850020
         AR    R5,R6               COMPUTE ADDRESS OF NEXT ABREC        16900020
         BCT   R3,TSTACTIV         CONTINUE UNTIL ALL ARE CHECKED       16950020
         LTR   RECPTR,RECPTR       WAS AN UNUSED ABREC FOUND            17000020
         BZ    PURGEBUF            NO,GO PREPARE TO OVERLAY SHORT       17050020
         XC    LOSTSUM(K6,RECPTR),LOSTSUM(RECPTR) RESET LOST SUMMARY    17100020
         B     BUILDREC            GO FINISH BUILD OF RECORD            17150020
PURGEBUF EQU   *                                                        17200020
         LA    RECPTR,MCHABREC     INITIALIZE TO FIRST ABREC            17250020
         IC    R3,MCHABRNO         GET NUMBER OF ABRECS                 17300020
         LA    R5,PBPFOUND         SET-UP FOR LATER BRANCH              17350020
TSTSOFT  EQU   *                                                        17400020
         TM    DSOFT(RECPTR),SOFT  Q.EXISTING RECORD SHOWS SOFT MCI     17450020
         BO    PBPSOFT             YES                                  17500020
         AR    RECPTR,R6           COMPUTE ADDRESS OF NEXT ABREC        17550020
         BCT   R3,TSTSOFT          CONTINUE SEARCH                      17600020
         LA    RECPTR,MCHABREC     INITIALIZE TO FIRST ABREC            17650020
         IC    R3,MCHABRNO         GET NUMBER OF ABRECS                 17700020
TSTHDREC EQU   *                                                        17750020
         TM    DRECV(RECPTR),RECV  Q.EXISTING RECD SHOWS HARD RECOVERED 17800020
         BO    PBPRECOV            YES                                  17850020
         AR    RECPTR,R6           COMPUTE ADDRESS OF NEXT ABREC        17900020
         BCT   R3,TSTHDREC         CONTINUE SEARCH                      17950020
         SR    RECPTR,R6           GET LAST ABREC PTR                   17970000
         LA    R3,ABNDCTR(RECPTR)  SET PTR TO LAST LOST SUMMARY FIELD   18000020
         B     TESTSTG             GO TEST FOR STG/CPU ERROR            18050020
PBPSOFT  EQU   *                                                        18100020
         LA    R3,SOFTCTR(RECPTR)  SET PTR TO SOFTS IN LOST SUMMARY     18150020
TESTSTG  EQU   *                                                        18200020
         TM    DSTORAGE(RECPTR),STG   Q.STORAGE ERROR                   18250020
         BCR   OFF,R5              NO,CPU - BRANCH VIA PRESET ADDRESS   18300020
         LA    R3,K3(R3)           BUMP TO NEXT FIELD                   18350020
         BR    R5                  BRANCH VIA PRESET ADDRESS            18400020
PBPRECOV EQU   *                                                        18450020
         LA    R3,RECOVCTR(RECPTR)  SET PTR TO HARDS RECOVERY IN SUM.   18500020
         B     TESTSTG             CHECK FOR STG/CPU                    18550020
PBPFOUND EQU   *                                                        18600020
         IC    R5,K0(R3)           GET LOST INCIDENT COUNT              18650020
         LA    R5,K1(R5)           INCREMENT BY ONE                     18700020
         STC   R5,K0(R3)           SAVE UPDATED COUNT                   18750020
         TM    RECFLAG(RECPTR),LONG+SHORT  Q.IS ANY I/O IN PROGRESS     18800020
         BZ    BUILDREC            NO,CONTINUE                          18850020
         OI    RECFLAG(RECPTR),CLOBBER   SET EXCP OPERATION CLOBBERED   18900020
*                                                                       18950020
*** THIS IS THE MCH RECORD FORMAT ROUTINE                               19000020
*                                                                       19050020
*****  GENERATE OF THE RECORD HEADER; SOURCE,LEVEL,CPUID,RECORD TYPE    19100020
BUILDREC EQU   *                                                        19150020
         MVC   MCPSW(X8,RECPTR),MCHPSA+X48   MOVE MCH OPSW INTO RECORD  19200020
         MVC   DASMT(X8,RRECPTR),MCHDAMAG    MOVE DAM.ASSESS INTO RECRD 19250020
         MVC   MCHLSUM(X6),LOSTSUM(RECPTR)   MOVE LOST SUMMARY FIELD    19300020
*                                            INTO THE RECORD            19350020
          L    R8,BARRYCHK(R9)          LOAD IC IN REGISTER             19360020
          LA   R8,K0(R8)      CLEAR HIGH ORDER BYTE                     19370020
          L    R5,MCHREMCH    LOAD DAMAGE ASS. POINTER                  19380020
          MVC  K2(X6,R5),K0(R8)         MOVE FAILING INSTRUCTION        19390020
         OI    RECFLAG(RECPTR),ACTIVE   TURN-ON ACTIVE BUFFER FLAG      19400020
         ST    RECPTR,MCHLONG      SAVE POINTER TO LONG RECORD          19450020
         NI    K3(RECPTR),LONGS    CLEAR SHORT FORM OF RECORD SWITCH    19500020
         MVI   KEY(RECPTR),KEYC    MOVE MCH KEY INTO RECORD             19550020
         MVC   OSRELNO(K1,RECPTR),MCHRELNO  MOVE IN OS-RELEASE LEVEL    19600020
         MVI   RECSW(RECPTR),SWITCH     MOVE SWITCH INTO RECORD         19650020
         DC    X'B202'             USE DIAGNOSTIC INSTRUCTION TO GET    19700020
         DC    S(CTIME)              MODEL AND SERIAL NUMBER            19750020
         MVC   CPUID(X8,RRECPTR),CTIME  MOVE INTO THE RECORD            19800020
*                                                                       19850020
***  THIS ROUTINE GENERATES DATE AND TIME FOR THE RECORD                19900020
*                                                                       19950020
         TM    MCHDAM1,CLOCKERR    Q.MCH DUE TO THE CLOCK               20000020
         BO    NOSTORE             YES,DO NOT STORE CLOCK               20050020
         DC    X'B205'             NO,STORE CLOCK TO GET                20100020
         DC    S(CTIME)              DATE AND TIME                      20150020
         BC    K3,NOSTORE          STORE CLOCK DID NOT WORK             20200000
         MVC   DATE(X8,RRECPTR),CTIME   MOVE DATE,TIME INTO RECORD      20250020
         B     SKIPTIME            GO GENERATE JOB ID                   20300020
*                                                                       20350020
NOSTORE  EQU   *                                                        20400020
         XC    DATE(X8,RRECPTR),DATE(RRECPTR)     ZERO OUT DATE AND     20450020
*                                  TIME FIELD OF RECORD                 20500020
*                                                                       20550020
***  GENERATE JOB ID AND STEP ID                                        20600020
*                                                                       20650020
*                                                                       20700020
SKIPTIME EQU   *                                                        20750020
         XC    PGMID(X16,RECPTR),PGMID(RECPTR)  CLEAR JOB,PROG ID FIELD 20800020
         SR    RPRB,RPRB           CLEAR REG                            20850020
         L     RCNTTCB,X0(RCVT)    PTR FOR OLD AND NEW TCB              20900020
         L     RCNTTCB,CNTTCB(RCNTTCB)  ACTIVE TCB ADDRESS              20950020
         L     RRB,TCBRBP(RCNTTCB) CURRENT RB ADDR                      21000020
         CR    RRB,RCNTTCB         Q. DUMMY TCB                         21050020
         BE    RECMCI              BRANCH IF YES                        21100020
         ICM   R5,X7,TCBTIO+X1(RCNTTCB)  LOAD TIOT ADDR        @S66087P 21150021
         BZ    BYPASS              NO,THERE IS NO TIOT                  21250020
         MVC   JOBID(X8,RECPTR),TIOJOBID(R5)  MOVE JOB ID IN RECORD     21300020
*                                                                       21350020
*****  GENERATE PROGRAM ID                                              21400020
*                                                                       21450020
BYPASS   EQU   *                                                        21500020
         TM    X1D(RCNTTCB),XC0    TASK TERMINATING            @S66087P 21510021
         BNZ   RECMCI              YES  SKIP RB SEARCH         @S66087P 21520021
PRBTEST  TM    RBSTAB(RRB),PRBMASK Q. IS PRB                            21550020
         BNZ   MORERB              BRANCH IF NO                         21600020
         LR    RPRB,RRB            SAVE PRB ADDRESS IF YES              21650020
MORERB   EQU   *                                                        21700020
         TM    RBSTAB1(RRB),RBTCBNXT   Q.THIS RB POINTS TO TCB          21750020
         BO    RBEND               BRANCH IF YES                        21800020
         L     RRB,RBLINK(RRB)     GET NEXT RB ADDRESS                  21850020
         B     PRBTEST             GO TO TEST IF IT IS A PRB            21900020
RBEND    EQU   *                                                        21950020
         LTR   RPRB,RPRB           IS THERE A PRB                       22000020
         BZ    RECMCI              BRANCH IF NO PRB                     22050020
         TM    CVTDCB,MVTMASK      Q. IS MVT SYSTEM                     22100020
         BO    MVTPGMID            BRANCH IF YES                        22150020
         MVC   PGMID(X8,RRECPTR),XRBNM(RPRB)   MOVE PGM ID INTO RECORD  22200020
         B     RECMCI              BRANCH                               22250020
MVTPGMID EQU   *                                                        22300020
         L     RWORK3,RBCDE(RPRB)  GET CDE ADDRESS                      22350020
         MVC   PGMID(X8,RRECPTR),CDENM(RWORK3)  MOVE PGM ID INTO RECORD 22400020
RECMCI   EQU   *                                                        22450020
         MVC   MCICODE(X8,RRECPTR),INTPCODE(R9)                         22500020
         TM    MCHDAMAG,ERD        Q. EMERGENCY RECORD                  22550020
         BO    EMRD                BRANCH IF YES                        22600020
         SPACE                                                          22650020
*                                                                       22700020
* THIS ROUTINE WILL RESTART CHANNELS IF NEEDED.                         22750020
*                                                                       22800020
         TM    MCHINTEL+K1,X80     ANY MODULE LOADED                    22850020
         BZ    POST                BRANCH TO POST RTN INTERFACE IF NO   22900020
         ST    RCOM,R11SAVE        SAVE COMMON AREA BASE                22950020
         STM   R0,R15,MCHMLSAV     SAVE REGS                            23000020
         L     R15,MCHIOENT        LOAD ENTRY TO EXCP                   23100020
         CNOP  2,4                                                      23120000
         BALR  R14,R15             BRANCH TO IOS                        23150020
         USING *,R14               SET TEMP BASE                        23160000
         DC    X'80000000'         IOS INTERFACE WORD                   23170000
*                                  SET TO DEQUEUE MCH RQE         40762 23180000
         L     RCOM,R11SAVE        RESTORE MCH COMMON AREA BASE         23250020
         LM    R0,R15,MCHMLSAV     RESTORE ALL REGISTERS                23300020
         DROP  R14                 DROP TEMP BASE                       23350020
*                                                                       23400020
*** THIS ROUTINE INTERFACES WITH THE POST ROUTINE IN THE MCH NUCLEUS    23450020
*                                                                       23500020
POST     EQU   *                                                        23550020
         STM   R0,R15,MCHMLSAV     SAVE REGS                            23600020
         L     R3,MCHPSTAD         ADDRESS OF POST INTERFACE ROUTINE    23650020
         BALR  R2,R3               GO TO POST INTERFACE ROUTINE         23700020
*                                                                       23750020
*** THIS ROUTINE RESTORES SYSTEM STATUS AND TERMINATES THE MACHINE      23800020
*        CHECK HANDLER                                                  23850020
*                                                                       23900020
         LM    R0,R15,MCHMLSAV     RESTORE REGS                         23950020
         MVC   MCHPSA+X48(X8),MCHRPSW RESTORE PSW                       24000020
         TM    MCHPSA+X48,XFE      Q. WAS I/O DISABLED WHEN MCI         24050020
         BZ    RETPGM              YES,RETURNTO INTERRUPTED PROGRAM     24060000
         L     R2,MCHNEST          GET ADDRESS OF MCHNEST SWITCH  40412 24070000
         TM    K1(R2),XF0          WAS IOS IN CONTROL             40412 24080000
         BZ    RSYSTM              NO,RETURN TO SYSTEM,YES-TO IOS 40412 24090000
         TM    MCHDAMAG,XC0        ERROR  RECOVERED               40412 24100000
         BNZ   RETPGM              YES,IOS CAN GET CONTROL BACK   40412 24110000
         NI    K1(R2),X0F          TURN OFF IOSNEST SWITCH        40412 24120000
         B     RSYSTM              EXIT TO SYSTEM                 40412 24130000
RETPGM   EQU   *                                                        24140000
         LA    R8,X120(R9)         SET-UP POINTER                       24150020
         BAL   R2,PASUTPNT         BRANCH TO RESTORE                    24250020
         LM    R0,R15,X152(R9)     RESTORE REGS                         24350020
         LPSW  X48                 RETURN TO INTERRUPTED PROGRAM        24400020
*                                                                       24450020
*** THIS ROUTINE RETURNS CONTROL TO THE DISPATCHER FOR EVENTUAL RETURN  24500020
*     TO THE INTERRUPTED PROGRAM                                        24550020
*                                                                       24600020
RSYSTM   EQU   *                                                        24650020
         L     R2,CVTTCBP          TCB POINTER                          24700020
         LM    R6,R7,X0(R2)        NEW - OLD TCB                        24750020
         TM    CVTDCB,MVTMASK      Q. IS MVT SYSTEM ?                   24800020
         BO    NTMVT0              BRANCH IF YES                        24850020
         MVC   X48(X24,R7),X192(R9) RESTORE GPR 10-15 IN OLD TCB        24900020
         MVC   X72(X40,R7),X152(R9) RESTORE GPR 0-9 IN OLD TCB          24950020
         TM    X1F(R7),X8          DO FPRS EXIST IN THIS TCB   IG 51236 24960021
         BNO   NTO1                NO,DO NOT RESTORE THEM      IG 51236 24970021
NTO      EQU   *                                                        25000020
         LR    R8,R7               GET FLOATING REG                     25050020
         SH    R8,D32              SAVE AREA                            25100020
         MVC   X0(X32,R8),X120(R9) SAVE FLOATING REGS IN OLD TCB        25150020
NTO1     EQU   *                                               IG 51236 25160021
         L     R5,X0(R7)           GET ADDR OF RB IN OLD TCB            25200020
         MVC   X16(X8,R5),MCHRPSW  RESUME PSW IN RB                     25250020
         MVC   MCHPSA+X48(X8),DISPATCH  SET                             25300020
         MVC   MCHPSA+X53(X3),CVT0DS+X1 DISPATCHER ADDRESS              25350020
         LR    R8,R7               GET FLOATING REGISTER                25550020
         SH    R8,D32              SAVE AREA ADDRESS                    25600020
         BAL   R2,PASUTPNT         BRANCH AND LINK                      25700020
          TM   CVTDCB,MVTMASK Q. MVT SYSTEM                             25800020
          BO   NTCBMVT1       BRANCH IF YES                             25850020
          LM   R10,R9,X48(R7)          RESTORE REGS                     25860020
          LPSW X48  RETURN TO DISPATCHER                                25960020
NTCBMVT1  EQU  *                                                        25970020
          LM   R0,R15,X48(R7) RESTORE REGS                              25980020
         LPSW  X48                 RETURN TO DISPATCHER                 26010000
NTMVT0   EQU   *                                                        26050020
         MVC   X48(X64,R7),X152(R9) RESTORE REGS TO OLD TCB             26100020
         B     NTO                 BRANCH                               26200020
PASUTPNT EQU   *                                                        26250020
         MVC   CPUBBUF1(X8),MSBMCW MOVE MCW INTO DIAG.                  26350020
         NI    BUFLD3,XBF          CLEAR BIT 25                         26400020
         LD    FR0,X0(R8)          *                                    26450020
         LD    FR2,X8(R8)          * GET FLOATING REGISTERS             26500020
         LD    FR4,X16(R8)         * CONTESTS FROM                      26550020
         LD    FR6,X24(R8)         * TCB                                26600020
         LA    R3,DISABLE1         GET ADDRESS FOR LOAD PSW      42810  26610000
         ST    R3,DISABLE+X4       STORE ADDRESS IN PSW          42810  26620000
         DC    X'8300',S(CPUBBUF1)  ENABLE BUFFER                       26630000
         DC    X'8300',S(MSBMCW)   SET BUFFER DISABLING LATCH           26640000
         MVI   CPUBBUF1,X0         SET UP FOR RESET           IG  44412 26642000
         DC    X'8300',S(CPUBBUF1) RESET THE TEST LIGHT       IG  44412 26644000
         LPSW  DISABLE             DISABLE FOR MACHINE CHECKS     42810 26650000
DISABLE1 EQU   *                                                        26660000
         DC    X'B70F90D8'         RESTORE CONT REGISTERS               26700020
         MVC   X0(X128),MCHPSA    RESTORE PERMANENT STORAGE ASSIGNMENT  26770000
         BR    R2                RETURN                                 26850020
EMRD     EQU   *                                                        26900020
         MVI   MCHNXMOD,MCHE3      SET IGFMCHE3 AS SUCCESSOR            26950020
         OI    X3(RRECPTR),TERMS   SET TERMINATION SWITCH               27000020
         BR    R14                 RETURN TO NUCLEUS                    27050020
*                                                                       27100020
*                                                                       29250020
D32      DC    H'32'               CONSTANT                             29300021
R11SAVE  DC    F'0'                SAVE AREA                            29350021
         DS    0D                                                       29600020
CPUBBUF1 DC    X'0200000000000000'   DIAGNOSE MCW                       29650020
DISABLE  DC    D'0'                DISABLE PSW                          29700000
DISPATCH DC    X'0004FF0000000000' DISPATCHER RESUME PSW                29750020
BUFLD1   EQU   CPUBBUF1+1          DIAGNOSE FIELD                       29800020
BUFLD2   EQU   CPUBBUF1+2          DIAGNOSE FIELD                       29850020
BUFLD3   EQU   CPUBBUF1+3          DIAGNOSE FIELD                       29900020
*                                                                       30050020
*   THIS IS THE MACRO FOR THE 553 COMMON AREA                           30100020
*                                                                       30150020
MACLABEL DSECT                                                          30200020
         MCHMAC                                                         30250020
CTIME    EQU   MCHMLSAV+4         WORK AREA                             30300020
MCHDAM1  EQU   MCHDAMAG+1          DAMAGE FIELD                         30350020
CVTTAB   DSECT                                                          30400020
         CVT                                                            30450020
MSB553   DSECT                                                          30500020
         RMSMSB   MOD=53                                                30550020
MSB3     EQU   MSBMCW+3           MESSAGE BLOCK FIELD                   30600020
         END                                                            30650020
