         LCLA  &LEV,&REL                                                00060021
&LEV     SETA  20                                                       00070021
&REL     SETA  21                                                       00080021
&REL&LEV TITLE 'IGFMCH33 &LEV STORAGE ANALYSIS'                         00090021
IGFMCH33 CSECT                                                          00100020
         SPACE 3                                                        00150020
*********************************************************************** 00200020
*                                                                     * 00250020
*              IGFMCH33    MAIN STORAGE ANALYSIS                      * 00300020
*STATUS        CHANGE LEVEL 20   06/21/71                             * 00350021
*FUNCTION      THIS MODULE EXERCISES THE BAD  STORAGE ADDRESS SUPPLIED* 00400020
*              BY PEA TO DETIRMINE THE SEVERITY OF THE STORAGE ERROR. * 00450020
*              THE ERROR IS CLASSIFIED AS EITHER 'SOLID' OR           * 00500020
*              'INTERMITTENT'.THE ERROR IS SOLID IF BITS ARE DROPPED  * 00550020
*              OR A MACHINE CHECK OCCURS DURING THE EXERCISE(AT THE   * 00600020
*              ADDRESS BEING EXERCISED).THE RESULTS ARE THEN INDICATED* 00650020
*              IN REPDAR1,REPDAR2 AND MCHDAMAG FIELDS OF THE MCH      * 00700020
*              COMMUNICATION AREA.THE EXERCISING IS DONE VIA ST AND L * 00750020
*              OF AN ALL 1'S,ALL 0'S,1'S AND 0'S,AND 1'S  DATA*       * 00800020
*                                                                     * 00850020
*ENTRY POINT   IGFMCH33                                               * 00900020
*INPUT         REGISTER 10    CVT                                     * 00950020
*              REGISTER 11    POINTS TO MCH COMMON AREA               * 01000020
*              REGISTER 14    RETURN ADDRESS TO IGFMCHE0              * 01050020
*              REGISTER 15    ENTRY ADDRESS OF THE MODULE             * 01100020
*              CONTROL REGISTER 15 POINTER TO MACHINE EXTENDED LOGOUT * 01150020
*OUTPUT        MCHPDAR                                                * 01200020
*              BYTE 0                                                 * 01250020
*                 BIT 0 =1   TERMINATION NECESSARY                    * 01300020
*                 BIT 1 =1   RETRY NOT POSSIBLE                       * 01350020
*              BYTE 1                                                 * 01400020
*                 BIT 0 =1   SOLID STORAGE ERROR                      * 01450020
*                 BIT 1 =1   INTERMITTENT STORAGE ERROR               * 01500020
*              REPDARF1      FAILING LOCATION BEGINNING ADDRESS       * 01550020
*        REPDARF2            FAILING LOCATION ENDING ADDRESS          * 01600020
*              MCHDAMAG                                               * 01650020
*              BYTE 1                                                 * 01700020
*                 BIT 0 =1   MAIN STORAGE ERROR                       * 01750020
*              BYTE 2                                                 * 01800020
*                 BIT 0 =1   INTERMITTENT ERROR                       * 01850020
*                 BIT 1 =1   SOLID ERROR                              * 01900020
*                                                                     * 01950020
*              MESSAGE IGF05I WILL BE QUEUED  IN MESSAGE BUFFER       * 02000020
*EXIT/NORMAL   IGFMCHE0(MCH NUCLEUS)- NORMALLY WITH ANALYSIS DATA     * 02050020
*                                     AND PDAR SCHEDULES AS SUCCESSOR * 02100020
*EXIT/ERROR    IGIMCHE0(MCH NUCLEUS)- ABNORMAL VIA MACHINE CHECK NEW  * 02150020
*                                     PSW UPON OCCURANCE OF AN        * 02200020
*                                     UNEXPECTED INTERRUPT            * 02250020
*EXTERNAL REFERENCES     NONE                                         * 02300020
*TALBE/WORK AREA    THE FOLLOWING MCH COMMUNICATION AREAS ARE         * 02350020
*                   REFERENCED                                        * 02400020
*                      MCHMAC                                         * 02450020
*                      RMSMSB                                         * 02500020
*                                                                     * 02550020
*ATTRIBUTES    TRANSIENT                                              * 02600020
*              SERIALLY REUSABLE                                      * 02650020
*              OPERATES IN SUPERVISOR MODE                            * 02700020
*              MODEL DEPENDENT                                        * 02750020
*              SYSTEM INDEPENDENT                                     * 02800020
*                                                                     * 02850020
*NOTES         IN ORDER TO ALLOW FOR EXTENDED LOGOUTS DURING          * 02900020
*              EXERCISING  BIT 1 (MACHINE CHECK EXTENDED LOG-MCEL) OF * 02950020
*              CONTROL REGISTER 14 IS TURNED ON. AFER EXERCISING,     * 03000020
*              THE MCEL BIT IS RESET TO ZERO. THE FAILING STORAGE     * 03050020
*              INFORMATION IS OBTAINED AT                             * 03100020
*                    EXTENDED LOGOUT  444-BITS 4,5;  445-BIT 0        * 03150020
*              AND THE ADDRESS IS OBTAINED FROM EXTENDED LOGOUT+ 452  * 03200020
*                                                                     * 03250020
*                                                                     * 03300020
*           A MAINTENANCE SPACE OF 50 BYTES IS INCLUDED WITH LABEL OF   03310020
*           *****MAINT*****                                             03320020
*                                                                     * 03350020
******                                                            ***** 03400020
         SPACE 3                                                        03450020
********                                                       ******** 03500020
*                   REGISTER EQUATES                                  * 03550020
********                                                       ******** 03600020
R1       EQU   1                   GENERAL WORK REGISTER                03650020
R2       EQU   2                   GENERAL WORK REGISTER                03700020
R3       EQU   3                   GENERAL WORK REGISTER                03750020
R4       EQU   4                   GENERAL WORK REGISTER                03800020
R5       EQU   5                   GENERAL WORK REGISTER                03850020
R6       EQU   6                   GENERAL WORK REGISTER                03900020
R7       EQU   7                   BRANCH REGISTER                      03950020
R8       EQU   8                   GENERAL WORK REGISTER                04000020
R9       EQU   9                   GENERAL WORK REGISTER                04050020
R10      EQU   10                  WORK REG 10                          04100020
REGCOM   EQU   11                  BASE FOR COMMON AREA                 04150020
R14      EQU   14                  CONTROL REG 14                       04200020
REGRTN   EQU   14                  RETURN TO NUCLEUS REGISTER           04250020
REGBASE  EQU   15                  MODULE BASE REGISTER                 04300020
R15      EQU   15                  CONTROL REG 15                       04350020
         SPACE 3                                                        04400020
*****                                                            ****** 04450020
*                        EQUATES                                      * 04500020
*****                                                            ****** 04550020
X00      EQU   X'00'               INDICATES  MODULE LEVEL              04600020
X02      EQU   X'02'               TEST FSA VALIDITY                    04650020
X0F      EQU   X'0F'               MESSAGE CODE FOR BUFFER              04700020
X40      EQU   X'40'               HEXIDECIMAL EQUATES                  04750020
X70      EQU   X'70'               MCH NEW PSW LOCATION                 04800020
X74      EQU   X'74'               MCH NEW PSW ADDRESS                  04850020
X80      EQU   X'80'                                                    04900020
XBF      EQU   X'BF'               TURNS OFF MCEL BIT                   04950020
XDF      EQU   X'DF'               TURNS OFF RETRY POSSIBLE             05000020
PDAR     EQU   X'01'               SUCCESSOR CODE FOR PDAR              05050020
DATAERR  EQU   X'20'               FLAG FOR DATA ERROR IN MCHDAMAG      05100020
INTSTG   EQU   X'44'               FLAG FOR INTERMITTENT STORAGE ERROR  05150020
MSERROR  EQU   X'80'               MAIN STORAGE ERROR FLAG FOR MCHDAMAG 05200020
STORAGE  EQU   X'80'               TEST FOR OCCURANCE OF STORAGE ERROR  05250020
MCINTCOD EQU   232            MACHINE CODE INTERRUPT ADDRESS            05300020
D0       EQU   0              DISPLACEMENT                              05350020
D1       EQU   1              DISPLACEMENT                              05400020
D2       EQU   2                   DECIMAL EQUATE                       05450020
D3       EQU   3                   DECIMAL EQUATE                       05500020
D4       EQU   4              DISPLACEMENT                              05550020
D5       EQU   5              DISPLACEMENT                              05600020
D8       EQU   8              DISPLACEMENT                              05650020
D444     EQU   444            DISPLACEMENT INTO EXTENDED LOGOUT         05700020
LEVEL    EQU   X'&LEV'             MODULE LEVEL                         05710021
         EJECT                                                          05750020
         USING *,REGBASE           ADDRESSIBILITY                       05800020
         USING COMMACRO,REGCOM     COMMON AREA BASE REGISTER            05850020
         L     R2,MCHMSB           OBTAIN PTR TO THE MSB                05900020
         USING MSBMACRO,R2         DEPENDENT AREA BASE                  05950020
         MVI   MCHEXLEV,LEVEL      INDICATE MODULE LEVEL                06000021
         L     R9,MCHIPTR          OBTAIN MESSAGE BUFFER POINTER        06050020
         MVI   D0(R9),X0F          MOVE MESSAGE CODE INTO THE BUFFER    06100020
         LA    R9,D1(R9)           UPDATE MESSAGE BUFFER POINTER        06150020
         ST    R9,MCHIPTR          AND SAVE UPDATE                      06200020
         MVC   MCNEWPSW(D8),X70    SAVE MACHINE CHECK NEW PSW           06250020
         LA    R9,STINT1           SET UP PSW ADDRESS TO ENABLE         06300020
         ST    R9,MCENABLE+D4      FOR MACHINE CHECKS                   06350020
         OI    MCHDAMAG+D1,MSERROR SET MAIN STORAGE ERROR FLAG          06400020
         OI    MCHDAMAG+D2,DATAERR SET DATA ERROR FLAG IN DAMAG FIELD   06450020
         L     R9,REPDARF1         OBTAIN FAILING STORAGE ADDR AS       06500020
*                                  PREVIOUSLY STORED BY PEA             06550020
         SPACE 3                                                        06600020
******                                                           ****** 06650020
*              EXERCISE RTN  AND  NECESSARY                           * 06700020
*                       PREPARATION                                   * 06750020
******                                                           ****** 06800020
SETEXER  EQU   *                                                        06850020
         L     R4,PATTERN1         SET UP FIRST PATTERN                 06900020
         LA    R6,PATTERN1         SET UP INCREMENT POINTER REGISTER    06950020
         LA    R7,D4               INITIALIZE LOOP CTL FOR 4 PATTERNS   07000020
         STM   R10,R15,SAVEAREA    SAVE R10-R15 IN CASE OF INT          07050020
         DC    X'B6EE'             STORE CTRL REG 14                    07100020
         DC    S(ENABLES)          TO ENABLE EXTENDED LOGS              07150020
         OI    ENABLES,X40         ENABLE FOR EXTENDED LOGOUT           07200020
         DC    X'B7EE'             SET CTRL REG 14 TO                   07250020
         DC    S(ENABLES)          ENABLE FOR ENTENDED LOGS             07300020
         LA    R3,STINT            OBTAIN ADDR FOR POSSIBLE M.C. INT.   07350020
         ST    R3,X74              PUT THIS ADDR IN MCK NEW PSW         07400020
         DC    X'B7FF'             SET CTRL REG 15 TO                   07450020
         DC    S(MSBSEC)           2ND EXTENDED LOGOUT                  07500020
         LR    R5,R4               SET UP FOR STM                       07550020
         STM   R4,R5,D0(R9)        STORE AT BAD LOCATION                07600020
SETLOOP  EQU   *                                                        07650020
         LA    R3,D5               LOOP CONTROL EACH PATTERN -5 TIMES   07700020
EXERCISE EQU   *                                                        07750020
         ST    R4,D0(R9)           STORE AT BAD LOCATION                07800020
         ST    R4,D4(R9)           STORE AT BAD LOCATION                07850020
         BCT   R3,EXERCISE         LOOP FIVE TIMES                      07900020
         LA    R3,D5               SET UP LOOP CONTROL                  07950020
EXERCIS1 EQU   *                                                        08000020
         L     R4,D0(R9)           PICKUP BAD DATA                      08050020
         BCT   R3,EXERCIS1         LOOP FIVE TIMES                      08100020
         LA    R6,D4(R6)           SET REG 6 TO POINT TO NT  PATTERN    08150020
         L     R4,D0(R6)           LOADS REG 4 WITH NEXT EXERCISE PATT. 08200020
         BCT   R7,SETLOOP          LOOP CONTROL FOR NEXT PATTERN        08250020
         BAL   R7,RESTORE          B. TO RESTORE  CONTROL REGS,PSW      08300020
*****                                                            *****  08350020
*           INTERMITTENT  STORAGE ERROR  HAS OCCURED                  * 08400020
*****                                                            *****  08450020
         OI    REPDAR2,INTSTG      SET INTERMITTENT ERROR FLAG          08500020
         OI    MCHDAMAG+D2,X80     SET INTERMITTENT ERROR FLAG          08550020
NORMALRT EQU   *                                                        08600020
         MVI   MCHNXMOD,PDAR       SET PDAR AS SUCCESSOR                08650020
         SR    R9,R9               CLEAR REG WITH BAD ADDR              08700020
         BR    REGRTN              RETURN TO THE NUCLEUS                08750020
         SPACE 3                                                        08800020
****                                                               **** 08850020
*              SOLID  ERROR HAS OCCURED                               * 08900020
****                                                               **** 08950020
SOLID    EQU   *                                                        09000020
         OI    REPDAR2,STORAGE     SET  SOLID ERROR FLAG                09050020
         OI    MCHDAMAG+D2,X40      SET SOLID ERROR FLAG                09100020
         OI    REPDAR1,X80         SET  TERMINATION NECESSARY           09150020
         NI    REPDAR1,XDF         SET RETRY NOT POSSIBLE               09200020
         SR    R5,R5               ZERO REGISTERS WITH                  09250020
         SR    R8,R8                  BAD ADDRESSES                     09300020
         B     NORMALRT            B.TO SCHEDULE PDAR AND RETURN TO NUC 09350020
         SPACE 3                                                        09400020
***                                                                 *** 09450020
*                  RESTORE  MACHINE CHECK NEW AND  CR 15,14           * 09500020
***                                                                 *** 09550020
RESTORE  EQU   *                                                        09600020
         NI    ENABLES,XBF         TURN OFF MCEL BIT                    09650020
         DC    X'B7EE'             RESTORE CONTROL                      09700020
         DC    S(ENABLES)          REGISTER 14                          09750020
         DC    X'B7FF'             RESTORE                              09800020
         DC    S(MSBPRI)           CONTROL REG 15                       09850020
         MVC   X70(D8),MCNEWPSW    RESTORE MACHINE CHECK NEW PSW        09900020
         BR    R7                  RETURN TO MAIN LINE                  09950020
         SPACE 3                                                        10000020
****                                                                *** 10050020
*          INTERRUPTION ANALYSIS  ROUTINE                             * 10100020
****                                                                *** 10150020
STINT    EQU   *                                                        10200020
         USING *,R3                TEMPORARY BASE                       10250020
         L     R3,X74              ESTABLISHED                          10300020
         LM    R10,R15,SAVEAREA    RESTORE REGISTERS                    10350020
         DROP  R3                  DROP TEMPORARY BASE                  10400020
         BAL   R7,RESTORE          BRANCH TO RESTORE PSW AND CONTROL 15 10450020
         LPSW  MCENABLE            ENABLE FOR MACHINE CHECKS            10500020
STINT1   EQU   *                                                        10550020
         TM    MCINTCOD+D2,STORAGE Q. IS GENERATE ERROR A STORAGE ERROR 10600020
         BZ    UNEXINT             IF NOT THIS IS AN UNEXPECTED ERROR   10650020
         TM    MCINTCOD+D3,X02     Q. IS FAILING STORAGE ADDR VALID     10700020
         BZ    UNEXINT             IF NOT THIS IS AN UNEXPECTED ERROR   10750020
STINT2   EQU   *                                                        10800020
         L     R3,MSBPRI           PICK UP POINTER TO ORIGINAL EX LGOUT 10850020
         LA    R3,D444(R3)         UPDATE PTR TO STORAGE DATA           10900020
         LM    R3,R5,D0(R3)        OBTAIN VITAL STORAGE DATA LOG 1      10950020
         L     R6,MSBSEC           PICK UP POINTER TO NEW EX LOGOUT     11000020
         LA    R6,D444(R6)         UPDATE PTR TO STORAGE DATA           11050020
         LM    R6,R8,D0(R6)        OBTAIN VITAL STG DATA FOR LOG 2      11100020
         N     R3,MASK             ZERO OUT UNNEEDED DATA               11150020
         N     R6,MASK             ZERO OUT UNNEEDED DATA               11200020
         CR    R3,R6               ARE STORAGE IDS EQUAL                11250020
         BNE   UNEXINT             NO UNANTICAPATED STORAGE ERROR       11300020
         CR    R5,R8               DID ERROR OCCUR AT SAME LOCATION     11350020
         BE    SOLID               YES-SOLID ERROR  NO  UNEPTD ERROR    11400020
         SPACE 2                                                        11450020
*****                                                             ***** 11500020
*                   UNEXPECTED ERROR CONDITION                        * 11550020
*****                                                             ***** 11600020
UNEXINT  EQU   *                                                        11650020
         SR    R9,R9               ZERO REG WITH FAILING STG ADDR       11700020
         SR    R5,R5               ZERO REG WITH BAD ADDR               11750020
         SR    R8,R8               ZERO REG WITH BAD ADDR               11800020
         LPSW  X70                 RETURN TO NUCLEUS ERROR RTN          11850020
         SPACE 2                                                        11900020
*****                                                             ***** 11950020
*              GENERAL WORKING STORAGE                                * 12000020
*****                                                             ***** 12050020
         DS    0D                  DOUBLE WORD ALIGNMENT                12100020
MCENABLE DC    X'00040000'         PSW WHICH ENABLES FOR                12150020
         DC    F'0'                MACHINE CHECK                        12200020
MCNEWPSW DS    2F                  SAVE AREA FOR MACHINE CHECK NEW PSW  12250020
PATTERN1 DC    X'FFFFFFFF'         ALL 1'S PATTERN                      12300020
PATTERN2 DC    X'00000000'          ALL 0'S PATTERN                     12350020
PATTERN3 DC    X'AAAAAAAA'         1'S AND 0'S PATTERN                  12400020
PATTERN4 DC    X'55555555'         0'S AND 1'S PATTERN                  12450020
SAVEAREA DS    6F                  SAVE AREA FOR REGISTERS 10-15        12500020
MASK     DC    X'0C800000'         MASK FOR OBTAIN STORAGE IDS          12550020
ENABLES  DC    F'0'                STORAGE FOR CONTROL REG 14           12600020
MAINTID  DC    CL8'IGFMCH33'       MODULE NAME                          12602021
MAINT    DC    S(*)                                                     12604021
         DC    10CL4'&REL&LEV'     MAINTANANCE SPACE                    12606021
COMMACRO DSECT                                                          12650020
         MCHMAC                                                         12700020
MSBMACRO DSECT                                                          12750020
         RMSMSB MOD=53                                                  12800020
         END                                                            12850020
