         LCLA  &LEV,&REL                                                00060021
&LEV     SETA  20                                                       00070021
&REL     SETA  21                                                       00080021
&REL&LEV TITLE 'IGFMCH35   REFRESH/REPAIR VERIFICATION 1'               00090021
IGFMCH35 CSECT                                                          00100020
*********************************************************************** 00150020
*                                                                       00200020
*                                                                       00250020
* TITLE - IGFMCH35     REFRESH/REPAIR VERIFICATION - PART I             00300020
*                                                                       00350020
* STATUS - CHANGE LEVEL=20       06/21/71                               00400021
*                                                                       00450020
* FUNCTION/OPERATION - THIS MODULE, ALONG WITH IGFMCH36, PROVIDES THE   00500020
*                      INSTRUCTION RETRY CAPABILITIES FOR RMS/165.      00550020
*                      THE INSTRUCTION TO BE RETRIED IS EXAMINED FOR    00600020
*                      PARTICULAR CASES THAT CANNOT BE RETRIED VIA THE  00650020
*                      DIAGNOSE TRANSFER TO THE RETRY MICRO-PROGRAM IN  00700020
*                      HARDWARE. SOME CASES REQUIRE SIMULATION OF THE   00750020
*                      INSTRUCTION, OR DEMAND THAT THE RESUME ENVIRON-  00800020
*                      MENT MERELY BE ADJUSTED TO ALLOW THE INSTRUCTION 00850020
*                      TO BE RE-EXECUTED WHEN THE INTERRUPTED PROGRAM   00900020
*                      AGAIN RECEIVES CONTROL. IF THE INSTRUCTION       00950020
*                      CANNOT BE RETRIED, THE PROPER FLAGS ARE SET AND  01000020
*                      PDAR IS SCHEDULED FOR TERMINATION PROCEDURES.    01050020
*                                                                       01100020
* ENTRY POINT - IGFMCH35                                                01150020
*                                                                       01200020
* INPUT - A REFRESHED STORAGE AREA, OR REPAIRED SPF KEY                 01250020
*         MODEL INDEPENDENT LOGOUT                                      01300020
*         MCH COMMON AREA                                               01350020
*                                                                       01400020
* OUTPUT - IF RETRY IS NOT POSSIBLE, THE APPROPRIATE FLAGS ARE SET FOR  01450020
*          PDAR TO SCHEDULE TERMINATION.                                01500020
*                                                                       01550020
* EXITS - NORMAL - VIA IGFMCHE0 TO IGFMCHF1 WHEN RETRY IS NOT POSSIBLE  01600020
*                  OR TO IGFMCH36 TO PERFORM RETRY.                     01650020
*                                                                       01700020
*         ERROR - TO THE SHUT ROUTINE LOCATED WITHIN IGFMCHE0.          01750020
*                                                                       01800020
* TABLES/WORK AREAS - MCH COMMON AREA, INDEPENDENT LOGOUT               01850020
*                                                                       01900020
* ATTRIBUTES - TRANSIENT, SERIALLY REUSABLE, OPERATES IN SUPERVISOR     01950020
*              STATE, MODEL DEPENDENT.                                  02000020
*                                                                       02050020
*     NOTES   MAINTENANCE AREA OF 50 BYTES IS LOCATED AT LABEL MAINT    02060020
*********************************************************************** 02100020
R0       EQU   0                   REGISTER                             02150020
R1       EQU   1                   REGISTER                             02200020
R2       EQU   2                   REGISTER                             02250020
R3       EQU   3                   REGISTER                             02300020
R4       EQU   4                   REGISTER                             02350020
R5       EQU   5                   REGISTER                             02400020
R6       EQU   6                   REGISTER                             02450020
R7       EQU   7                   REGISTER                             02500020
R8       EQU   8                   REGISTER                             02550020
R9       EQU   9                   REGISTER                             02600020
R10      EQU   10                  REGISTER                             02650020
R11      EQU   11                  REGISTER                             02700020
R12      EQU   12                  REGISTER                             02750020
R13      EQU   13                  REGISTER                             02800020
R14      EQU   14                  REGISTER                             02850020
R15      EQU   15                  REGISTER                             02900020
CTR      EQU   4                   LOOP CONTROL COUNT REG               02950020
ADDR     EQU   5                   REGISTER                             03000020
LINK     EQU   7                   LINK REG FOR CONVERT ROUTINE         03050020
ADBYTE   EQU   8                   REG FOR HOLDING ADDRESSES            03100020
CVTREG   EQU   10                  BASE FOR CVT                         03150020
COMREG   EQU   11                  COMMON AREA DSECT REG                03200020
K0       EQU   0                   DECIMAL CONSTANT                     03250020
K1       EQU   1                   DECIMAL CONSTANT                     03300020
K2       EQU   2                   DECIMAL CONSTANT                     03350020
K3       EQU   3                   DECIMAL CONSTANT                     03400020
K4       EQU   4                   DECIMAL CONSTANT                     03450020
K5       EQU   5                   DECIMAL CONSTANT                     03500020
K6       EQU   6                   DECIMAL CONSTANT                     03550020
K8       EQU   8                   DECIMAL CONSTANT                     03600020
K28      EQU   28                  DECIMAL CONSTANT                     03650020
K40      EQU   40                  DECIMAL CONSTANT                     03700020
K60      EQU   60                  DECIMAL CONSTANT                     03750020
K104     EQU   104                 DECIMAL CONSTANT                     03800020
K152     EQU   152                 DECIMAL CONSTANT                     03850020
X00      EQU   X'00'               HEXADECIMAL CONSTANT                 03900020
X01      EQU   X'01'               HEXADECIMAL CONSTANT                 03950020
X02      EQU   X'02'               HEXADECIMAL CONSTANT                 04000020
X03      EQU   X'03'               HEXADECIMAL CONSTANT                 04050020
X08      EQU   X'08'               HEXADECIMAL CONSTANT                 04100020
X0F      EQU   X'0F'               HEXADECIMAL CONSTANT                 04150020
X20      EQU   X'20'               HEXADECIMAL CONSTANT                 04200020
X10      EQU   X'10'               HEXADECIMAL CONSTANT                 04250020
X39      EQU   X'39'               HEXADECIMAL CONSTANT                 04300020
X3F      EQU   X'3F'               HEXADECIMAL CONSTANT                 04350020
X40      EQU   X'40'               HEXADECIMAL CONSTANT                 04400020
X74      EQU   X'74'               HEXADECIMAL CONSTANT                 04450020
X7F      EQU   X'7F'               HEXADECIMAL CONSTANT                 04500020
X80      EQU   X'80'               HEXADECIMAL CONSTANT                 04550020
XB7      EQU   X'B7'               HEXADECIMAL CONSTANT                 04600020
XBF      EQU   X'BF'               HEXADECIMAL CONSTANT                 04650020
XC0      EQU   X'C0'               HEXADECIMAL CONSTANT                 04700020
XDF      EQU   X'DF'               HEXADECIMAL CONSTANT                 04750020
XF7      EQU   X'F7'               HEXADECIMAL CONSTANT                 04800020
MCNEW    EQU   X'70'               MACHINE CHECK NEW PSW ADDRESS        04850020
PGMNEW   EQU   104                 LOCATION OF PGM NEW PSW              04900020
GPRSAVE  EQU   X'180'              LOCATION OF GPR SAVE                 04950020
RF       EQU   X'40'               RETRY FAILED FLAG                    05050020
FPR6     EQU   6                   FLOATING POINT REG                   05100020
FPR4     EQU   4                   FLOATING POINT REG                   05150020
FPR2     EQU   2                   FLOATING POINT REG                   05200020
FPR0     EQU   0                   FLOATING POINT REG                   05250020
SYSALTER EQU   X'80'               SYSTEM BEING ALTERED                 05300020
ALL      EQU   X'FF'               BYTE WITH ALL BITS ON                05350020
MSG1LEN  EQU   8                   LENGTH OF DATA IN IGF040IMSG         05400020
MSGPTR   EQU   9                   PTR TO SLOT IN MCHIBUF FOR MSG CODE  05450020
TOADDR   EQU   6                   ADDRESS OF CONVERTED DATA            05500020
OPFETCH  EQU   X'20'               OO CODE PREVIOUSLY FETCHED FLAG      05550020
FETCHSUB EQU   X'10'               SUBJECT OP CODE FETCHED FLAG         05600020
EX       EQU   X'44'               EXECUTE OP CODE                      05650020
LEVEL    EQU   X'&LEV'             MODULE LEVEL                         05660021
*                                                                       05700020
         USING COMAREA,COMREG      COMMON AREA ADDRESSABILITY           05750020
         USING CVTAREA,CVTREG      CVT ADDRESSABILITY                   05800020
         USING *,R15                                                    05850020
         MVI   MCHEXLEV,LEVEL      INDICATE MODULE CHANGE LEVEL         05900020
         STM   R0,R15,SAVEGPRS     SAVE GPRS AT ENTRY                   05950020
         LA    ADDR,MCIHANDL       GET ADDR OF MY MCI HANDLER           06000020
         ST    ADDR,MYMCNEW+K4     PUT ADDR INTO MY MC NEW PSW          06050020
         LA    ADDR,ENABLED        GET ADDR OF ENABLE POINT             06100020
         ST    ADDR,ENABLE+K4      PUT ADDR INTO ENABLE PSW             06150020
         MVC   SAVENEW(K8),MCNEW   SAVE MCNEWPSW AT ENTRY               06200020
         L     R6,MCHMSB           GET PTR TO MSB                       06250020
         USING MSBSECT,R6                                               06300020
         DC    X'B6EE'             STORE                                06350020
         DC    S(CNTRLWRD)           CONTROL REG 14                     06400020
         TM    RERETRY,OPFETCH     HAS OP CODE BEEN FETCHED             06450020
         BNO   FETCHOP             NO                                   06500020
TESTCODE EQU   *                                                        06550020
         CLI   OPCODE,EX           IS THIS AN EXECUTE INSTRUCTION       06600020
         BNE   CHEKPRIV            NO,CHECK FOR PRIVELEGED OPCODE       06650020
         SR    R1,R1               CLEAR REG                            06700020
         IC    R1,OPCODE+K2        GET BASE FOR EX INSTRUCTION SUBJECT  06750020
         SRL   R1,K4               CLEAR OUT LOW ORDER DISPLACEMENT     06800020
         SLL   R1,K2               AND COMPUTE DISP. INTO GPR SAVE      06850020
         L     ADDR,MCHINLOG       GET ADDRESS OF INDEPENDENT LOG       06900020
         L     ADDR,K152(R1,ADDR)  GET BASE VALUE FOR SUBJECT OF EX     06950020
         NI    OPCODE+K2,X0F       CLEAR BASE LEAVING ONLY DISPLACEMENT 07000020
         AH    ADDR,OPCODE+K2      COMPUTE ADDRESS OF SUBJECT           07050020
         ST    ADDR,SUBJADR        SAVE THIS ADDRESS                    07100020
         C     ADDR,CVTMZ00        IS ADDRESS WITHIN VALID CORE         07150020
         BH    RETRY               NO,LET RETRY GIVE PROGRAM CHECK      07200020
         TM    SUBJADR+K3,X01      ON HALFWORD BOUNDARY                 07250020
         BO    RETRY               NO,LET RETRY GIVE PROGRAM CHECK      07300020
SUBREDO  EQU   *                                                        07350020
         DC    X'8300'             DIAGNOSE TO DEFEAT                   07400020
         DC    S(DSBLMCW)          I/E OVERLAP                          07450020
         OI    SWITCH,X40          SET SUBJECT OP CODE FETCH FLAG       07500020
         MVC   MCNEW(K8),MYMCNEW   POINT M.C. NEW PSW TO THIS MODULE    07550020
         IC    R1,K0(ADDR)         FETCH SUBJECTS OPCODE                07600020
         MVC   MCNEW(K8),SAVENEW   RESTORE ORIGINAL MCNEWPSW            07650020
         NI    SWITCH,XBF          CLEAR SUBJECT OP CODE FETCH FLAG     07700020
         OI    RERETRY,FETCHSUB    INDICATE SUBJECT OP CODE FETCHED     07750020
         STC   R1,SUBJOP           SAVE OP CODE                         07800020
         CLI   SUBJOP,EX           IS THIS AN EXECUTE                   07850020
         BE    RETRY               YES,LET RETRY GIVE PROGRAM CHECK     07900020
CHEKPRIV EQU   *                                                        07950020
         TM    MCHRPSW+K1,X01      PROBLEM PROGRAM MODE WHEN ERROR      08000020
         BNO   TESTIO              NO                                   08050020
         LA    ADDR,SUBJOP         GET ADDRESS OF OP CODE               08100020
         LA    ADBYTE,PRIVTAB      GET ADDRESS OF PRIVILEGED OP TABLE   08150020
         LA    CTR,PRIVTABL        GET NUMBER OF ENTRIES                08200020
         BAL   LINK,TESTOP         SEE IF OP CODE IS PRIVILEGED         08250020
*   IF NOT FOUND RETURN IS HERE - IF FOUND ENTRY IS HERE PLUS FOUR      08300020
         B     RETRY               NOT FOUND DO RETRY                   08350020
*   SIMULATE PRIVILEGED OP PROGRAM CHECK                                08400020
         LA    CTR,K2              INITIALIZE LENGTH OF TWO             08450020
         TM    SUBJOP,XC0          TEST OP CODE FOR INSTRUCTION LENGTH  08500020
         BZ    ILC2                LENGTH IS 2 BYTES                    08550020
         BM    ILC4                LENGTH IS 4 BYTES                    08600020
         LA    CTR,K2(CTR)         LENGTH IS 6 BYTES - BUMP LENGTH TWO  08650020
         SPACE                                                          08700020
ILC4     EQU   *                                                        08750020
         LA    CTR,K2(CTR)         BUMP LENGTH BY TWO                   08800020
         SPACE                                                          08850020
ILC2     EQU   *                                                        08900020
         LR    R1,CTR              SAVE INSTRUCTION LENGTH              08950020
         A     CTR,ICVALUE         COMPUTE ADDRESS OF NEXT INSTRUCTION  09000020
         XC    SAVEOLD(K8),SAVEOLD INIT. TO BUILD PGM OLD PSW           09050020
         ST    CTR,SAVEOLD+K4      BUILD PROGRAM OLD PSW WITH ADDRESS   09100020
*                                  OF INTERRUPTED INSTRUCTION           09150020
         MVC   SAVEOLD+K4(K1),MCHRPSW+K4 GET CONDITION CODE, PGM MASK   09200020
         NI    SAVEOLD+K4,X3F      CLEAR ILC BITS                       09250020
         SLL   R1,K5               ILC TO H.O. BITS                     09300020
         EX    R1,ORILC            OR IN ILC                            09350020
         MVC   SAVEOLD(K2),MCHRPSW SYS. MASK AND STATUS INTO OLD PSW    09400020
         LA    R1,K2               GET PRIV. OP PGM CHECK CODE          09450020
         STH   R1,SAVEOLD+K2       CODE INTO BUILT PGM OLD PSW          09500020
         MVC   MCHRPSW(K8),MCHPSA+K104  PGM NEW PSW IS RESUME POINT     09550020
         MVC   MCHPSA+K40(K8),SAVEOLD SIMULATED PGM OLD PSW TO PSA      09600020
         DC    X'8300'             DIAGNOSE TO RETURN MCW TO STATE      09650020
         DC    S(MCW1)             UNDER WHICH RMS NORMALLY RUNS.       09700020
         NI    MCHINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    09750020
         B     PREPMSG             GO TO PREPARE MESSAGE AND EXIT       09800020
         SPACE                                                          09850020
ORILC    OI    SAVEOLD+K4,X00      USE TO OR IN INSTRUCTION LENGTH CODE 09900020
TESTIO   EQU   *                                                        09950020
         LA    ADDR,SUBJOP         GET ADDRESS OF OP CODE               10000020
         LA    ADBYTE,IOTAB        GET ADDRESS OF I/O OP TABLE          10050020
         LA    CTR,IOL             GET NUMBER OF ENTRIES                10100020
         BAL   LINK,TESTOP         SEE IF OPCDOE IS AN I/O              10150020
*   IF NOT FOUND RETURN IS HERE - IF FOUND ENTRY IS HERE PLUS FOUR      10200020
         B     RETRY               NOT FOUND - DO RETRY                 10250020
         L     R1,MCHINLOG         GET ADDRESS OF MCIC                  10300020
         TM    K60(R1),X20         IS PARTIAL RESULT STORED TRIGGER ON  10350020
         BO    RETRYFAL            YES                                  10400020
         MVC   BLDPSW(K5),MCHRPSW  GET PROGRAMS STATUS AT FAILURE       10450020
         MVC   BLDPSW+K5(K3),REPDARI+K1 SET PROGRAM INSTRUCTION ADDRESS 10500020
         MVC   MCHRPSW(K8),BLDPSW  SET UP RESUME PSW FOR SELF RETRY     10550020
         NI    MCHINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    10600020
         B     PREPMSG             GO TO PREPARE MESSAGE AND EXIT       10650020
         SPACE 2                                                        10700020
RETRY    EQU   *                                                        10750020
         MVI   MCHNXMOD,X02        SCHEDULE RETRY AS SUCCESSOR          10800020
         LM    R0,R15,SAVEGPRS     RESTORE REGS AT ENTRY                10850020
         BR    R14                 RETURN TO NUCLEUS                    10900020
RETRYFAL EQU   *                                                        10950020
         OI    REPDAR1,XC0         SET RETRY FAILED - TERM NECESSARY    11000020
         NI    REPDAR1,XDF         RESET RETRY POSSIBLE                 11050020
EXIT2    EQU   *                                                        11100020
         DC    X'8300'             DIAGNOSE TO RETURN MCW TO STATE      11150020
         DC    S(MCW1)             UNDER WHICH MCH NORMALLY RUNS.       11200020
         NI    MCHINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    11250020
         MVI   MCHNXMOD,X01        SET PDAR AS SUCCESSOR                11300020
         LM    R0,R15,SAVEGPRS     RESTORE REGS AT ENTRY                11350020
         BR    R14                 RETURN TO NUCLEUS                    11400020
         SPACE 3                                                        11450020
         SPACE 2                                                        11500020
FETCHOP  EQU   *                                                        11550020
         MVC   ICVALUE(K4),REPDARI GET COPY OF IC AT FAILURE            11600020
         L     ADDR,REPDARI        GET IC AT FAILURE                    11650020
         OI    MCHINTEL,SYSALTER   TURN ON SYSTEM BEING ALTERED FLAG    11700020
         DC    X'8300'             DIAGNOSE TO DISABLE BUFFER           11750020
         DC    S(DSBLMCW)          AND TO DEFEAT I/E OVERLAP            11800020
         OI    SWITCH,X80          INDICATE OP CODE FETCH IN PROGRESS   11850020
         MVC   MCNEW(K8),MYMCNEW   POINT M.C. NEW PSW TO THIS MODULE    11900020
         MVC   OPCODE(K6),K0(ADDR) GET FAILING INSTRUCTION              11950020
         MVC   MCNEW(K8),SAVENEW   RESTORE ORIGINAL MCNEWPSW            12000020
         NI    SWITCH,X7F          CLEAR OP CODE FETCH IN PROGRESS      12050020
         MVC   SUBJOP(K1),OPCODE   OPCODE TO POSITION FOR SUBROUTINE    12100020
         OI    RERETRY,OPFETCH     INDICATE OP CODE FETCHED             12150020
         B     TESTCODE            GO TEST OP CODE                      12200020
TESTOP   EQU   *                                                        12250020
         CLC   K0(K1,ADDR),K0(ADBYTE) CHECK FOR OP CODE MATCH           12300020
         BE    K4(LINK)            INSTRUCTION IN TABLE                 12350020
         BCT   CTR,TESTOP          CONTINUE UNTIL ALL CODES CHECKED     12400020
         BR    LINK                INSTRUCTION NOT IN TABLE             12450020
         SPACE                                                          12500020
CONVERT  EQU   *                                                        12550020
         LA    R2,XB7(R2)          BUMP TO PRINTABLE LETTER RANGE       12600020
         CH    R2,XC1              IS VALUE PRINTABLE LETTER            12650020
         BNL   STORE               YES                                  12700020
         LA    R2,X39(R2)          BUMP TO CONVERTED NUMBER             12750020
         SPACE                                                          12800020
STORE    EQU   *                                                        12850020
         STC   R2,K0(TOADDR)       CONVERTED DATA INTO MESSAGE          12900020
         LA    TOADDR,K1(TOADDR)   BUMP OUTPUT ADDRESS                  12950020
         BR    LINK                RETURN                               13000020
         SPACE 2                                                        13050020
PREPMSG  EQU   *                                                        13100020
         LA    CTR,K3              INITIALIZE CONVERT RTN. LOOP COUNT   13150020
         LA    ADDR,REPDARI+K1     GET ADDR OF ADDRESS TO BE CONVERTED  13200020
         LA    TOADDR,MSG1         GET ADDRESS OF POSITION IN MESSAGE   13250020
*                                  WHERE CONVERTED ADDRESS MUST GO.     13300020
NEXTBYTE EQU   *                                                        13350020
         SR    R2,R2               CLEAR REG                            13400020
         IC    R2,K0(ADDR)         GET BYTE TO BE CONVERTED             13450020
         SRDL  R2,K4               KEEP LEFT 4 BITS PASS OTHERS ON      13500020
         BAL   LINK,CONVERT        GO TO CONVERT FOR PRINT              13550020
         SRL   R3,K28              SHIFT TO LOW-ORDER 4 BITS            13600020
         LR    R2,R3               TRANSFER TO REG FOR SUBROUTINE       13650020
         BAL   LINK,CONVERT        GO TO CONVERT FOR PRINT              13700020
         LA    ADDR,K1(ADDR)       BUMP INPUT ADDRESS                   13750020
         BCT   CTR,NEXTBYTE        CONTINUE UNTIL 3 BYTES CONVERTED     13800020
         L     MSGPTR,MCHIPTR      GET I-MSG BUFFER POINTER             13850020
         MVC   K0(MSG1LEN,MSGPTR),MSG1CODE REQUEST FOR IGF032I          13900020
         LA    MSGPTR,MSG1LEN(MSGPTR) INCR I-MSG BUFFER POINTER         13950020
         ST    MSGPTR,MCHIPTR      STORE UPDATED POINTER                14000020
         DC    X'8300'             DIAGNOSE TO RETURN MCW TO STATE      14050020
         DC    S(MCW1)             UNDER WHICH RMS NORMALLY RUNS.       14100020
         NI    MCHINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    14150020
         MVI   MCHNXMOD,X03        SET TERM AS SUCCESSOR                14200020
         OI    MCHDAMAG,X40        SET SOFTWARE RECOVERY BIT            14250020
         LM    R0,R15,SAVEGPRS     RESTORE REGS AT ENTRY                14300020
         BR    R14                 RETURN TO NUCLEUS                    14350020
MCIHANDL EQU   *                                                        14400020
         L     R15,X74             GET ROUTINES ADDRESS                 14450020
         LA    R5,NBASEADJ         GET FACTOR TO ESTABLISH BASE REG     14500020
         SR    R15,R5              ESTABLISH BASE REG                   14550020
         USING IGFMCH35,R15                                             14600020
         LM    R10,R15,SAVEGPRS+K40 RESTORE MODULES REGS                14650020
         NI    CNTRLWRD,XF7        TURN OFF BIT ALLOWING SOFT ERRORS    14700020
         DC    X'B7EE'             DISABLE                              14750020
         DC    S(CNTRLWRD)           SOFT ERRORS                        14800020
         MVC   MCNEW(K8),SAVENEW   RESTORE ORIGINAL MCNEWPSW            14850020
         LPSW  ENABLE              ENABLE FOR MACHINE CHECKS            14900020
         SPACE                                                          14950020
ENABLED  EQU   *                                                        15000020
         OI    SWITCH,X10          INDICATE ENABLE POINT REACHED        15050020
FAIL2    EQU   *                                                        15100020
         TM    SWITCH,X80          WAS OP CODE BEING FETCHED            15150020
         BNO   FAIL21              NO                                   15200020
         NI    SWITCH,ALL-X80      CLEAR FLAG                           15250020
         LA    LINK,FETCHOP        SETUP TO CONTINUE                    15300020
         B     CHEKCNT             GO CHECK RETRY COUNT                 15350020
         SPACE                                                          15400020
FAIL21   EQU   *                                                        15450020
         TM    SWITCH,X40          WAS SUBJECT OP CODE BEING FETCHED    15500020
         BNO   FAIL22              NO                                   15550020
         NI    SWITCH,ALL-X40      CLEAR FLAG                           15600020
         LA    LINK,SUBREDO        SETUP TO CONTINUE                    15650020
         B     CHEKCNT             GO CHECK RETRY COUNT                 15700020
         SPACE                                                          15750020
FAIL22   EQU   *                                                        15800020
         B     QUIT                PREPARE UNSUCCESSFUL EXIT            15850020
CHEKCNT  EQU   *                                                        15900020
         LH    R1,RETRYCNT         GET RETRY COUNT                      15950020
         LA    R1,K1(R1)           BUMP BY ONE                          16000020
         STH   R1,RETRYCNT         STORE RETRY COUNT                    16050020
         CH    R1,RETRYMAX         HAS MAX. NO. BEEN REACHED            16100020
         BE    QUIT                YES                                  16150020
         BR    LINK                CONTINUE                             16200020
         SPACE                                                          16250020
QUIT     EQU   *                                                        16300020
         OI    RERETRY,RF          INDICATE RETRY FAILED                16350020
         B     RETRYFAL            CONTINUE                             16400020
         SPACE                                                          16450020
*      CONSTANTS                                                        16500020
SAVEGPRS DS    16F                 GPR SAVE AREA                        16550020
SAVEOLD  DS    1D                  SAVE AREA FOR OLD MC PSW             16600020
MCW1     DC    X'0300000000000000' COPY OF SYSTEM MCW                   16650020
MYMCNEW  DC    D'0'                MY FUTURE M.C. NEW PSW               16700020
ENABLE   DC    X'0004000000000000' PSW TO ENABLE AFTER MCI HANDLING     16750020
BLDPSW   DC    D'0'                RESUME PSW BUILD AREA                16800020
SAVENEW  DS    1D                  SAVE AREA FOR ORIGINAL MCNEWPSW      16850020
DSBLMCW  DC    X'0300080000000000' MCW FOR DISABLING                    16900020
CNTRLWRD DC    F'0'                LOCATION TO SAVE CONTROL REG 14      16950020
SUBJADR  DC    F'0'                SUBJECT ADDRESS FOR EX INSTRUCTION   17000020
XC1      DC    X'00C1'             CONSTANT FOR CONVERT ROUTINE         17050020
OPCODE   DC    X'000000000000'     STG LOCATION FOR OP CODE             17100020
MSG1CODE DC    X'8806'             MSG CODE AND LENGTH OF PLUGGABLE DTA 17150020
MSG1     DC    C'AAAAAA'           SUCCESSFUL RECOVERY MESSAGE          17200020
PRIVTAB  DC    X'08098082838485B2B6B7' NON I/O PRIVELEGED INSTRUCTIONS  17250020
IOTAB    DC    X'9C9D9E9F'         I/O INSTRUCTIONS                     17300020
TABEND   EQU   *                                                        17350020
PRIVTABL EQU   TABEND-PRIVTAB      LENGTH OF TABLE OF PRIVILEGED OPS    17400020
ICVALUE  EQU   BLDPSW+K4                                                17450020
NBASEADJ EQU   MCIHANDL-IGFMCH35                                        17500020
IOL      EQU   TABEND-IOTAB        LENGTH OF TABLE OF I/O INSTRUCTIONS  17550020
RERETRY  DC    X'00'               RETRY INFORMATION BYTE               17600020
SWITCH   DC    X'00'               SWITCHES                             17650020
RETRYCNT DC    H'0'                TWO BYTES FOR RETRY COUNT            17700020
RETRYMAX DC    H'10'               MAXIMUM RETRY COUNT                  17750020
SUBJOP   DC    X'00'               EX SUBJECT OP CODE                   17800020
MAINTID  DC    CL8'IGFMCH35'                                            17810021
MAINT    DC    S(*)                                                     17820021
         DC    10CL4'&REL&LEV'     MAINT SPACE                          17830021
COMAREA  DSECT                                                          17900020
         MCHMAC                                                         17950020
MSBSECT  DSECT                                                          18000020
         RMSMSB  MOD=53                                                 18050020
CVTAREA  DSECT                                                          18100020
         CVT                                                            18150020
         END                                                            18200020
