         LCLA  &LEV,&REL                                                00060021
&LEV     SETA  20                                                       00070021
&REL     SETA  21                                                       00080021
&REL&LEV TITLE 'IGFMCH36  &LEV REFRESH/REPAIR VERIFICATION  2'          00090021
IGFMCH36  CSECT                                                         00100020
*********************************************************************** 00150020
*                                                                       00200020
*                                                                       00250020
* TITLE - IGFMCH36    REFRESH/REPAIR VERIFICATION - PART II             00300020
*                                                                       00350020
* STATUS - CHANGE LEVEL=20       06/21/71                               00400021
*                                                                       00450020
* FUNCTION/OPERATION - THIS MODULE, ALONG WITH IGFMCH35, PROVIDES THE   00500020
*                      INSTRUCTION RETRY CAPABILITIES FOR RMS/165.      00550020
*                      THIS MODULE SETS UP THE REQUIRED ENVIRONMENT     00600020
*                      AND ACTUALLY PERFORMS A RETRY OF THE FAILING     00650020
*                      INSTRUCTION BY MEANS OF A DIAGNOSE TRANSFER INTO 00700020
*                      THE RETRY MICROPROGRAM.                          00750020
*                      IF RETRY IS UNSUCCESSFUL, THE PROPER FLAGS ARE   00800020
*                      SET AND PDAR IS SCHEDULED FOR TERMINATION        00850020
*                      PROCEDURES. IF RETRY IS SUCCESSFUL, THIS MODULE  00900020
*                      PREPARES THE RESUME ENVIRONMENT, REQUESTS THE    00950020
*                      MESSAGE IGF032I, AND SCHEDULES THE SMCH-         01000020
*                      TERMINATOR.                                      01050020
*                                                                       01100020
* ENTRY POINT - IGFMCH36                                                01150020
*                                                                       01200020
* INPUT - THE FAILING ENVIRONMENT AS INDICATED BY PSA, GPR'S, FPR'S,    01250020
*         AND THE MODEL INDEPENDENT LOGOUT.                             01300020
*         A REFRESHED STORAGE AREA, OR REPAIRED SPF KEY                 01350020
*         MCH COMMON AREA                                               01400020
*                                                                       01450020
* OUTPUT - IF RECOVERY HAS BEEN SUCCESSFUL, THE RESUME PSW IS SET, AND  01500020
*          THE MESSAGE IGF032I IS SCHEDULED. IF RETRY IS UNSUCCESSFUL,  01550020
*          THE APPROPRIATE FLAGS ARE SET FOR PDAR.                      01600020
*                                                                       01650020
* EXITS - NORMAL - VIA IGFMCHE0 TO IGFMCHF1 IF RETRY HAS FAILED, OR TO  01700020
*                  IGFMCH30 IF RETRY HAS BEEN SUCCESSFUL.               01750020
*                                                                       01800020
*         ERROR - TO THE SHUT ROUTINE LOCATED WITHIN IGFMCHE0.          01850020
*                                                                       01900020
* TABLES/WORK AREAS - MCH COMMON AREA, INDEPENDENT LOGOUT               01950020
*                                                                       02000020
* ATTRIBUTES - TRANSIENT, SERIALLY REUSABLE, OPERATES IN SUPERVISOR     02050020
*              STATE, MODEL DEPENDENT.                                  02100020
*                                                                       02150020
*     NOTES  MAINTENANCE AREA OF 50 BYTES IS LOCATED AT LABEL MAINT     02160020
*********************************************************************** 02200020
R0       EQU   0                   REGISTER                             02250020
R1       EQU   1                   REGISTER                             02300020
R2       EQU   2                   REGISTER                             02350020
R3       EQU   3                   REGISTER                             02400020
R4       EQU   4                   REGISTER                             02450020
R5       EQU   5                   REGISTER                             02500020
R6       EQU   6                   REGISTER                             02550020
R7       EQU   7                   REGISTER                             02600020
R8       EQU   8                   REGISTER                             02650020
R9       EQU   9                   REGISTER                             02700020
R10      EQU   10                  REGISTER                             02750020
R11      EQU   11                  REGISTER                             02800020
R12      EQU   12                  REGISTER                             02850020
R13      EQU   13                  REGISTER                             02900020
R14      EQU   14                  REGISTER                             02950020
R15      EQU   15                  REGISTER                             03000020
CTR      EQU   4                   LOOP CONTROL COUNT REG               03050020
ADDR     EQU   5                   REGISTER                             03100020
LINK     EQU   7                   LINK REG FOR CONVERT ROUTINE         03150020
ADBYTE   EQU   8                   REG FOR HOLDING ADDRESSES            03200020
CVTREG   EQU   10                  BASE FOR CVT                         03250020
COMREG   EQU   11                  COMMON AREA DSECT REG                03300020
K0       EQU   0                   DECIMAL CONSTANT                     03350020
K1       EQU   1                   DECIMAL CONSTANT                     03400020
K2       EQU   2                   DECIMAL CONSTANT                     03450020
K3       EQU   3                   DECIMAL CONSTANT                     03500020
K4       EQU   4                   DECIMAL CONSTANT                     03550020
K5       EQU   5                   DECIMAL CONSTANT                     03600020
K8       EQU   8                   DECIMAL CONSTANT                     03650020
K16      EQU   16                  DECIMAL CONSTANT                     03700020
K24      EQU   24                  DECIMAL CONSTANT                     03750020
K28      EQU   28                  DECIMAL CONSTANT                     03800020
K32      EQU   32                  DECIMAL CONSTANT                     03850020
K40      EQU   40                  DECIMAL CONSTANT                     03900020
K48      EQU   48                  DECIMAL CONSTANT                     03950020
K64      EQU   64                  DECIMAL CONSTANT                     04000020
K104     EQU   104                 DECIMAL CONSTANT                     04050020
K120     EQU   120                 DECIMAL CONSTANT                     04100020
K128     EQU   128                 DECIMAL CONSTANT                     04150020
K136     EQU   136                 DECIMAL CONSTANT                     04200020
K144     EQU   144                 DECIMAL CONSTANT                     04250020
K152     EQU   152                 DECIMAL CONSTANT                     04300020
X00      EQU   X'00'               HEXADECIMAL CONSTANT                 04350020
X01      EQU   X'01'               HEXADECIMAL CONSTANT                 04400020
X02      EQU   X'02'               HEXADECIMAL CONSTANT                 04450020
X04      EQU   X'04'               HEXADECIMAL CONSTANT                 04500020
X08      EQU   X'08'               HEXADECIMAL CONSTANT                 04550020
X10      EQU   X'10'               HEXADECIMAL CONSTANT                 04600020
X20      EQU   X'20'               HEXADECIMAL CONSTANT                 04650020
X39      EQU   X'39'               HEXADECIMAL CONSTANT                 04700020
X74      EQU   X'74'               HEXADECIMAL CONSTANT                 04750020
X80      EQU   X'80'               HEXADECIMAL CONSTANT                 04800020
XB7      EQU   X'B7'               HEXADECIMAL CONSTANT                 04850020
XC0      EQU   X'C0'                                                    04900020
XDF      EQU   X'DF'               HEXADECIMAL CONSTANT                 04950020
XF4      EQU   X'F4'               HEXADECIMAL CONSTANT                 05000020
XF7      EQU   X'F7'               HEXADECIMAL CONSTANT                 05050020
STATLOG  EQU   X'18'               SAVED STATUS LOG AREA                05100020
STATUS   EQU   X'100'              REAL STATUS LOG AREA                 05150020
LOWCORE1 EQU   X'E8'               ADDRESS OF ENVIRONMENTAL PSW         05200020
LOWCORE2 EQU   X'F0'               ADDRESS OF MCW FOR DIAGNOSE TRANSFER 05250020
PSA      EQU   0                   LOCATION OF PSA AREA                 05300020
SVCNEW   EQU   96                  LOCATION OF SVC NEW PSW              05350020
LPSW     EQU   X'82'               HEXADECIMAL VALUE                    05400020
SSM      EQU   X'80'               HEXADECIMAL VALUE                    05450020
MCOLD    EQU   X'30'               ADDRESS OF MC OLD PSW                05500020
MCNEW    EQU   X'70'               MACHINE CHECK NEW PSW ADDRESS        05550020
PGMNEW   EQU   104                 LOCATION OF PGM NEW PSW              05600020
GPRSAVE  EQU   X'180'              LOCATION OF GPR SAVE                 05650020
LEVEL    EQU   X'&LEV'             MODULE CHANGE LEVEL                  05700021
RF       EQU   X'40'               RETRY FAILED FLAG                    05750020
FPR6     EQU   6                   FLOATING POINT REG                   05800020
FPR4     EQU   4                   FLOATING POINT REG                   05850020
FPR2     EQU   2                   FLOATING POINT REG                   05900020
FPR0     EQU   0                   FLOATING POINT REG                   05950020
SYSALTER EQU   X'80'               SYSTEM BEING ALTERED                 06000020
ALL      EQU   X'FF'               BYTE WITH ALL BITS ON                06050020
MSG1LEN  EQU   8                   LENGTH OF DATA IN IGF040IMSG         06100020
MSGPTR   EQU   9                   PTR TO SLOT IN MCHIBUF FOR MSG CODE  06150020
TOADDR   EQU   6                   ADDRESS OF CONVERTED DATA            06200020
         USING COMAREA,COMREG      COMMON AREA ADDRESSABILITY           06250020
         USING CVTAREA,CVTREG      CVT ADDRESSABILITY                   06300020
         USING *,R15                                                    06350020
         MVI   MCHEXLEV,LEVEL      INDICATE MODULE CHANGE LEVEL         06400020
         STM   R0,R15,SAVEGPRS     SAVE GPRS AT ENTRY                   06450020
         LA    ADDR,MCIHANDL       GET ADDR OF MY MCI HANDLER           06500020
         ST    ADDR,MYMCNEW+K4     PUT ADDR INTO MY MC NEW PSW          06550020
         LA    R1,ENABLED          SET UP ADDRESS FOR                   06600020
         ST    R1,ENABLE+K4        ENABLING PSW                         06650020
         MVC   SAVENEW(K8),MCNEW   SAVE MCNEWPSW AT ENTRY               06700020
         MVC   SAVPGM(K8),PGMNEW   SAVE PGM NEW PSW                     06750020
         L     R6,MCHMSB           GET PTR TO MSB                       06800020
         USING MSBSECT,R6                                               06850020
         DC    X'B6EE'             STORE                                06900020
         DC    S(CNTRLWRD)           CONTROL REG 14                     06950020
         LA    ADDR,DIAGTRAN       ADDRESS OF DIAGNOSE TRANSFER         07000020
         ST    ADDR,ENVPSW+K4      INSTRUCTION INTO PSW                 07050020
         MVC   ENVPSW+K1(K1),MCHRPSW+K1 RESTORE PROGRAM KEY-RETRY       07100020
         NI    ENVPSW+K1,XF4       MAKE SURE KEY AND ENABLED FOR MCI    07150020
         MVC   ENVPSW+K4(K1),MCHRPSW+K4 RESTORE CC AND PROGRAM MASK     07200020
RETRY    EQU   *                                                        07250020
         OI    SWITCH,X20          INDICATE RETRY ATTEMPT BEGUN         07300020
         L     ADDR,MCHINLOG       GET ADDRESS OF INDEPENDENT LOG       07350020
         LD    FPR0,K120(ADDR)     RESTORE FPR 0                        07400020
         LD    FPR2,K128(ADDR)     RESTORE FPR 2                        07450020
         LD    FPR4,K136(ADDR)     RESTORE FPR 4                        07500020
         LD    FPR6,K144(ADDR)     RESTORE FPR 6                        07550020
         MVC   LOWCORE2(K8),TRANSMCW MOVE MCW FOR DIAGNOSE TRANSFER TO  07600020
*                                  LOW CORE                             07650020
         MVC   LOWCORE1(K8),ENVPSW ENVIRONMENTAL PSW TO LOW CORE        07700020
         MVC   PSA(K128),MCHPSA    RESTORE ORIGINAL PSWS                07750020
         MVC   MCNEW(K8),MYMCNEW   POINT MCI TO ME                      07800020
         MVC   PGMNEW(K8),SAVPGM   POINT PGM NEW TO SHUT RTN            07850020
         OI    CNTRLWRD,X08        SET BIT TO ALLOW SOFT ERRORS         07900020
         DC    X'B7EE'             ENABLE                               07950020
         DC    S(CNTRLWRD)           SOFT ERRORS                        08000020
         MVC   STATUS(K40),K24(ADDR) RETRY STATUS LOG TO LOW CORE       08050020
         LM    R0,R15,K152(ADDR)   RESTORE GPRS                         08100020
         LPSW  LOWCORE1            LOAD ENVIRONMENTAL PSW WHICH CAUSES  08150020
*                                  EXECUTION OF DIAGNOSE TRANSFER       08200020
*                                  TO RETRY MICROPROGRAM.               08250020
RETRYFAL EQU   *                                                        08300020
         OI    REPDAR1,XC0         TERM NECESSARY AND RETRY FAILED      08350020
         NI    REPDAR1,XDF         RESET RETRY POSSIBLE                 08400020
EXIT2    EQU   *                                                        08450020
         DC    X'8300'             DIAGNOSE TO RETURN MCW TO STATE      08500020
         DC    S(MCW1)             UNDER WHICH MCH NORMALLY RUNS.       08550020
         NI    MCHINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    08600020
         MVI   MCHNXMOD,X01        SET PDAR AS SUCCESSOR                08650020
         LM    R0,R15,SAVEGPRS     RESTORE REGS AT ENTRY                08700020
         BR    R14                 RETURN TO NUCLEUS                    08750020
         SPACE 3                                                        08800020
         SPACE                                                          08850020
CONVERT  EQU   *                                                        08900020
         LA    R2,XB7(R2)          BUMP TO PRINTABLE LETTER RANGE       08950020
         CH    R2,XC1              IS VALUE PRINTABLE LETTER            09000020
         BNL   STORE               YES                                  09050020
         LA    R2,X39(R2)          BUMP TO CONVERTED NUMBER             09100020
         SPACE                                                          09150020
STORE    EQU   *                                                        09200020
         STC   R2,K0(TOADDR)       CONVERTED DATA INTO MESSAGE          09250020
         LA    TOADDR,K1(TOADDR)   BUMP OUTPUT ADDRESS                  09300020
         BR    LINK                RETURN                               09350020
         SPACE 2                                                        09400020
PREPMSG  EQU   *                                                        09450020
         LA    CTR,K3              INITIALIZE CONVERT RTN. LOOP COUNT   09500020
         LA    ADDR,REPDARI+K1     GET ADDR OF ADDRESS TO BE CONVERTED  09550020
         LA    TOADDR,MSG1         GET ADDRESS OF POSITION IN MESSAGE   09600020
*                                  WHERE CONVERTED ADDRESS MUST GO.     09650020
NEXTBYTE EQU   *                                                        09700020
         SR    R2,R2               CLEAR REG                            09750020
         IC    R2,K0(ADDR)         GET BYTE TO BE CONVERTED             09800020
         SRDL  R2,K4               KEEP LEFT 4 BITS PASS OTHERS ON      09850020
         BAL   LINK,CONVERT        GO TO CONVERT FOR PRINT              09900020
         SRL   R3,K28              SHIFT TO LOW-ORDER 4 BITS            09950020
         LR    R2,R3               TRANSFER TO REG FOR SUBROUTINE       10000020
         BAL   LINK,CONVERT        GO TO CONVERT FOR PRINT              10050020
         LA    ADDR,K1(ADDR)       BUMP INPUT ADDRESS                   10100020
         BCT   CTR,NEXTBYTE        CONTINUE UNTIL 3 BYTES CONVERTED     10150020
         L     MSGPTR,MCHIPTR      GET I-MSG BUFFER POINTER             10200020
         MVC   K0(MSG1LEN,MSGPTR),MSG1CODE REQUEST FOR IGF032I          10250020
         LA    MSGPTR,MSG1LEN(MSGPTR) INCR I-MSG BUFFER POINTER         10300020
         ST    MSGPTR,MCHIPTR      STORE UPDATED POINTER                10350020
         DC    X'8300'             DIAGNOSE TO RETURN MCW TO STATE      10400020
         DC    S(MCW1)             UNDER WHICH RMS NORMALLY RUNS.       10450020
         NI    MCHINTEL,ALL-SYSALTER CLEAR SYSTEM BEING ALTERED FLAG    10500020
         MVI   MCHNXMOD,X02        SET TERM AS SUCCESSOR                10550020
         OI    MCHDAMAG,RF         SET SOFTWARE RECOVERY BIT            10600020
         OI    MCHDAMAG+K3,X80     SET RETRY BIT                        10650020
         LM    R0,R15,SAVEGPRS     RESTORE REGS AT ENTRY                10700020
         BR    R14                 RETURN TO NUCLEUS                    10750020
MCIHANDL EQU   *                                                        10800020
         L     R15,X74             GET ROUTINES ADDRESS                 10850020
         LA    R5,NBASEADJ         GET FACTOR TO ESTABLISH BASE REG     10900020
         SR    R15,R5              ESTABLISH BASE REG                   10950020
         USING IGFMCH36,R15                                             11000020
         LM    R10,R15,SAVEGPRS+K40 RESTORE MODULES REGS                11050020
         MVC   SAVEOLD(K8),MCOLD   SAVE MACHINE CHECK OLD PSW           11100020
         MVC   SAVESTAT(K40),STATUS SAVE STATUS LOG                     11150020
         NI    CNTRLWRD,XF7        TURN OFF BIT ALLOWING SOFT ERRORS    11200020
         DC    X'B7EE'             DISABLE                              11250020
         DC    S(CNTRLWRD)           SOFT ERRORS                        11300020
         MVC   MCNEW(K8),SAVENEW   RESTORE ORIGINAL MCNEWPSW            11350020
         LPSW  ENABLE              ENABLE FOR MACHINE CHECKS            11400020
         SPACE                                                          11450020
ENABLED  EQU   *                                                        11500020
         OI    SWITCH,X10          INDICATE ENABLE POINT REACHED        11550020
         MVC   SAVEPSA(K128),PSA   SAVE PSA AREA                        11600020
         TM    SWITCH,X20          WAS THIS A RETRY ATTEMPT             11650020
         BNO   QUIT                NO                                   11700020
         L     ADDR,MCHINLOG       GET ADDRESS OF INDEPENDENT LOG       11750020
         CLC   SAVESTAT+K5(K3),STATLOG+K5(ADDR)  CORRECT INSTRUCTION    11800020
         BNE   FAIL3               NO                                   11850020
         CLI   LOWCORE1,X20        WAS RETRY SUCCESSFUL                 11900020
         BNE   FAIL1               NO                                   11950020
         MVC   SAVEPSA+K104(K16),MCHPSA+K104  SAVE ORIG PGM AND MC NEW  12000020
         STD   FPR0,K120(ADDR)     SAVE FPR FOLLOWING EXECUTION         12050020
         STD   FPR2,K128(ADDR)     SAVE FPR FOLLOWING EXECUTION         12100020
         STD   FPR4,K136(ADDR)     SAVE FPR FOLLOWING EXECUTION         12150020
         STD   FPR6,K144(ADDR)     SAVE FPR FOLLOWING EXECUTION         12200020
         MVC   K152(K64,ADDR),GPRSAVE SAVE GPRS FOLLOWING EXECUTION     12250020
*   GPRS OR FPRS MAY HAVE BEEN MODIFIED BY THE RETRIED INSTRUCTION    * 12300020
         CLC   SAVEOLD+K5(K3),PGMNEW+K5 HAS A PGM CHECK OCCURRED        12350020
         BNE   NOTPGMCK            NO,BRANCH TO CHK SVC INT             12400020
         MVC   SAVEOLD(K8),MCHPSA+K104  SET TO ORIGINAL PGM NEW         12450020
ALTERPGM MVC   SAVEPSA+K40(K2),MCHRPSW RESTORE PGM OLD MASK-AMWP        12500020
         B     ALTERPSA            BRANCH TO ALTER PSA AREA             12550020
NOTPGMCK CLC   SAVEOLD+K5(K3),SVCNEW+K5 WAS AN SVC INTERRUPT TAKEN      12600020
         BNE   NOTSVCCK            NO,BRANCH TO CHECK P/P MODE          12650020
ALTERSVC MVC   SAVEPSA+K32(K2),MCHRPSW RESTORE SVC OLD MASK-AMWP        12700020
         B     ALTERPSA            BRANCH TO ALTER PSA AREA             12750020
NOTSVCCK TM    MCHRPSW+K1,X01      WAS PROGRAM IN P/P MODE              12800020
         BNO   CHEKMASK            NO,BRANCH TO CHECK MASK              12850020
         OI    SAVEOLD+K1,X01      RESTORE P/P MODE                     12900020
         B     MASKBACK            BRANCH TO RESTORE MASK BITS          12950020
CHEKMASK CLI   SAVEOLD,X00         IS SYSTEM MASK ZERO                  13000020
         BNE   ALTERPSA            NO,BRANCH TO ALTER PSA               13050020
         L     ADDR,REPDARI        LOAD ADDRESS OF RETRY IC             13100020
         CLI   K0(ADDR),SSM        IS IT A SSM INSTRUCTION              13150020
         BE    ALTERPSA            YES,BRANCH TO ALTER PSA AREA         13200020
         CLI   K0(ADDR),LPSW       IS IT A LPSW INSTRUCTION             13250020
         BE    ALTERPSA            YES,BRANCH TO ALTER PSA AREA         13300020
MASKBACK MVC   SAVEOLD(K1),MCHRPSW RESTORE SYSTEM MASK BITS             13350020
ALTERPSA EQU   *                                                        13400020
         MVC   SAVEPSA+K48(K8),SAVEOLD  ALTER MC OLD PSW IN PSA AREA    13450020
         MVC   MCHPSA(K128),SAVEPSA     SET UP RETURN ENVIRONMENT       13500020
         MVC   MCHRPSW(K8),SAVEPSA+K48  SET RESUME PSW TO CONTINUE      13550020
         B     PREPMSG             GO TO PREPARE RECOVERED MSG          13600020
FAIL1    EQU   *                                                        13650020
FAIL3    EQU   *                                                        13700020
         LA    LINK,RETRY          SETUP TO CONTINUE                    13750020
         SPACE                                                          13800020
CHEKCNT  EQU   *                                                        13850020
         LH    R1,RETRYCNT         GET RETRY COUNT                      13900020
         LA    R1,K1(R1)           BUMP BY ONE                          13950020
         STH   R1,RETRYCNT         STORE RETRY COUNT                    14000020
         CH    R1,RETRYMAX         HAS MAX. NO. BEEN REACHED            14050020
         BE    QUIT                YES                                  14100020
         BR    LINK                CONTINUE                             14150020
         SPACE                                                          14200020
QUIT     EQU   *                                                        14250020
         OI    RERETRY,RF          INDICATE RETRY FAILED                14300020
         B     RETRYFAL            CONTINUE                             14350020
         SPACE                                                          14400020
         SPACE                                                          14450020
*      CONSTANTS                                                        14500020
DIAGTRAN DC    X'8300'             DIAGNOSE TRANSFER TO                 14550020
         DC    S(LOWCORE2)         RETRY MICOPROGRAM.                   14600020
MYMCNEW  DC    D'0'                MY FUTURE M.C. NEW PSW               14650020
MCW1     DC    X'0300000000000000' COPY OF SYSTEM MCW                   14700020
ENVPSW   DC    X'0004000000000000' ENVIRONMENTAL PSW                    14750020
TRANSMCW DC    X'03000800000BC000' MCW TO TRANSFER TO RETRY MICROPROGM  14800020
SAVEPSA  DS    16D                 SAVE AREA FOR PSA AFTER RETRY        14850020
SAVENEW  DS    1D                  SAVE AREA FOR ORIGINAL MCNEWPSW      14900020
DSBLMCW  DC    X'0300080000000000' MCW FOR DISABLING                    14950020
SAVEOLD  DS    1D                  SAVE AREA FOR OLD MC PSW             15000020
SAVPGM   DC    D'0'                SAVE AREA FOR PGM NEW PSW            15050020
ENABLE   DC    X'0004000000000000' PSW TO ENABLE AFTER MCI HANDLING     15100020
SAVEGPRS DS    16F                 GPR SAVE AREA                        15150020
SAVESTAT DS    10F                 STATUS SAVE AREA                     15200020
CNTRLWRD DC    F'0'                LOCATION TO SAVE CONTROL REG 14      15250020
MSG1CODE DC    X'8806'             MSG CODE AND LENGTH OF PLUGGABLE DTA 15300020
MSG1     DC    C'AAAAAA'           SUCCESSFUL RECOVERY MESSAGE          15350020
RERETRY  DC    X'00'               RETRY INFORMATION BYTE               15400020
SWITCH   DC    X'00'               SWITCHES                             15450020
XC1      DC    X'00C1'             CONSTANT FOR CONVERT ROUTINE         15500020
RETRYCNT DC    H'0'                TWO BYTES FOR RETRY COUNT            15550020
RETRYMAX DC    H'10'               MAXIMUM RETRY COUNT                  15600020
MAINTID  DC    CL8'IGFMCH36'       MODULE NAME                          15602021
MAINT    DC    S(*)                                                     15604021
         DC    10CL4'&REL&LEV'     MAINT SPACE                          15606021
NBASEADJ EQU   MCIHANDL-IGFMCH36                                        15650020
COMAREA  DSECT                                                          15700020
         MCHMAC                                                         15750020
MSBSECT  DSECT                                                          15800020
         RMSMSB  MOD=53                                                 15850020
CVTAREA  DSECT                                                          15900020
         CVT                                                            15950020
         END                                                            16000020
