         LCLA  &LEV,&REL                                                00004021
&LEV     SETA  23                                                       00008021
&REL     SETA  21                                                       00012021
&REL&LEV TITLE 'IGFMCH40 LEVEL &LEV SOFT MACHINE CHECK HANDLER FOR 145' 00016021
IGFMCH40 CSECT                                                          00020020
*********************************************************************** 00030020
*                                                                       00040020
*  NAME        IGFMCH40  SOFT MACHINE CHECK HANDLER                     00050020
*                                  STATUS LEVEL = 23 10/19/73           00060021
*    STATUS - LEVEL=22      4/03/72                                     00062021
*                                                                       00064020
*  FUNCTION    1. FORMATING MACHINE CHECK RECORD FOR THE SYS1.LOGREC    00070020
*                 DATA SET                                              00080020
*                                                                       00090020
*              2. PROCESS THE AUTOMATIC MODE SWITCHING ROUTINE          00100020
*                                                                       00110020
*              3. RECORD BUFFER MANAGEMENT                              00120020
*                                                                       00130020
*              4. TERMINATES MACHINE CHECK HANDLER AND RESTORES THE     00140020
*                 SYSTEM STATUS                                         00150020
*                                                                       00160020
*  ATTRIBUTES - NONRESIDENT IN MCH TRANSIENT AREA,SUPERVISOR STATE      00162020
*                                                                       00164020
*  ENTRY POINTS- IGFMCH40 ENTERED FROM IGFMCHE0                         00166020
*                                                                       00168020
*  EXITS -     ON SYSTEM TERMINATION TO MODULE SCHEDULER TO SCHEDULE    00168420
*              IGFMCHE3                                                 00168820
*              OTHERWISE CONTROL IS RETURNED TO THE SYSTEM              00169220
*              CONTROL IS RETURNED TO INTERRUPTED PROGRAM IF I/O        00169320
*              WAS DISABLED AT TIME OF INTERRUPT                        00169420
*              CONTROL IS RETURNED TO DISPATCHER IF I/O NOT DISABLED    00169520
*                                                                       00169620
*  INPUT       LOGOUT - MODEL INDEPENDENT OR/AND MODEL DEPENDENT        00170020
*                       LOGOUT                                          00180020
*              MACHINE INTERRUPT CODE                                   00190020
*              MCH COMMON AREA                                          00200020
*                                                                       00210020
*  OUTPUT      RECOVERY OR DAMAGE REPORT TO MCH RECORDER                00220020
*              MODE SWITCHING MESSAGE                                   00230020
*              ECC SUCCESSFUL MESSAGE                                   00240020
*              HIR SUCCESSFUL MESSAGE                                   00250020
*                                                                       00250420
*  OPERATION - UPON GETTING CONTROL THIS MODULE WILL CHECK WHETHER      00252020
*              THE ERROR WAS A SOFT ERROR.  IF IT WAS IT DETERMINES     00256020
*              WHETHER IT WAS AN ECC CORRECTED OR AN HIR CORRECTED      00258420
*              CONDITION AND INDICATES TYPE OF ERROR IN DAMAGE          00258820
*              ASSESSEMENT FIELD AND CORRECT MESSAGE.  IT THEN          00259220
*              SETS UP THE RECORD BY RECORD BUFFERING ROUTINE.          00259620
*              WHEN THE RECORD HAS BEEN SET UP CONTROL IS GIVEN TO POST 00267120
*              ROUTINE WHO WILL POST RMS ECB IN UCM.  SMCH WILL DETER-  00269120
*              MINE IF MCK INTERRUPTION OCCURED IN A PROGRAM WITH A     00269220
*              DISABLED PSW.  IF SO STATUS IS RESTORED AND CONTROL      00269520
*              RETURNED TO INTERRUPTED PROGRAM AT POINT OF INTERRUP-    00269920
*              TION.  IF NOT CONTROL IS RETURNED TO DISPATCHER          00270020
*              WHO WILL DISPATCH NEXT READY TASK.                       00270420
*              IF THE SMCH WAS ENTERED ON A SYSTEM DOWN CASE, THE       00270820
*              RECORD IS BUFFERED AND IGFMCHE3 IS SCHEDULED AND         00270920
*              CONTROL IS RETURNED TO NUCLEUS TO LOAD THIS MODULE.      00271020
*                                                                       00275020
*  NOTES -     A 50 BYTE MAINTENANCE AREA HAS BEEN ADDED WITH LABEL -   00277020
*              *****MAINT*****                                          00279020
*                                                                       00282520
********************************************************************    00290020
         EJECT                                                          00320020
********************************************************************    00327520
* THESE ARE EQUATES FOR REGISTER                                        00335020
*                                                                       00342520
R0       EQU   0                   *                                    00350020
R1       EQU   1                   *                                    00357021
RCNTTCB  EQU   2                   *                                    00365020
R2       EQU   2                   *                                    00372520
RWORK3   EQU   3                   *                                    00380020
RRB      EQU   3                   *                                    00387520
R3       EQU   3                   *                                    00395020
RECPTR   EQU   4                   *                                    00402520
RMSG     EQU   4                   *                                    00410020
R5       EQU   5                   *                                    00420020
R6       EQU   6                   *                                    00430020
R7       EQU   7                   *                                    00440020
RPRB     EQU   8                   *                                    00450020
R8       EQU   8                   *                                    00460020
R9       EQU   9                   *                                    00470020
CVTREG   EQU   10                  CVT POINTER                          00480020
R10      EQU   10                  *                                    00490020
COMBASE  EQU   11                  POINTER TO MCHMAC                    00500020
R14      EQU   14                  *                                    00510020
R15      EQU   15                  *                                    00520020
BASEREG  EQU   15                  BASE REGISTER FOR THIS MODULE        00530020
*                                                                       00540020
* EQUATES FOR FLOATING POINT REGISTERS                                  00550020
*                                                                       00560020
FR0      EQU   0                   FLOATING REGISTER 0                  00570020
FR2      EQU   2                   FLOATING REGISTER 2                  00580020
FR4      EQU   4                   FLOATING REGISTER 4                  00590020
FR6      EQU   6                   FLOATING REGISTER 6                  00600020
*                                                                       00610020
*********************************************************************** 00620020
         EJECT                                                          00630020
*********************************************************************** 00640020
*                                                                       00650020
*  THESE ARE EQUATES FOR AUTOMATIC MODE SWITCHING ROUTINE               00660020
*                                                                       00670020
INTPCODE EQU   0                   RELATIVE ADDR OF MCI CODE            00680020
*                                  IN INDEPENDENT LOG                   00690020
ECC      EQU   X'40'               MASK TO TEST ECC                     00700020
INRECVR  EQU   X'20'               INTERNAL RECOVERY BIT IN MCICODE     00710020
*                                                                       00720020
REGION   EQU   255                 REGION CODE IN FIXED LOG             00730020
THRESHLD EQU   X'04'               INDICATES THRESHOLD MODE             00740020
INTERMIT EQU   X'02'               INDICATES INTERMITTENT ERROR         00750020
CONTROL  EQU   X'01'               CONTROL STORAGE ERROR BIT IN REGION  00760020
*                                                                       00770020
* MISCELLANEOUS EQUATES                                                 00780020
*                                                                       00790020
X1D      EQU   X'1D'               DISP TO TCB FLAG FIELD      @S66087P 00795021
X1F      EQU   X'1F'               FLOATING POINT TCB BIT      IG 51236 00800021
ECCMSG   EQU   X'0E'               MSG CODE FOR ECC SUCCESSFUL          00810020
CPUMSG   EQU   X'12'               MSG CODE FOR HIR SUCCESSFUL          00820020
QUIET    EQU   X'18'               CODE FOR QUIET MODE MESSAGE          00830020
CONTQUI  EQU   X'20'               INDICATES CONTROL STORAGE IN QUIET   00840021
         SPACE 2                                                        00860020
CNTTCB   EQU   4                   CVT POINTS TO CURRENT TCB ADDRESS    00870020
MVTMASK  EQU   X'10'               MASK TO TEST FOR MVT SYSTEM          00880020
TCBRBP   EQU   0                   TCB + 0 POINTS TO RB                 00890020
TCBTIO   EQU   12                  TCB + 12 POINTS TO TIOT              00900020
TCBGRS   EQU   48                  GENERAL PURPOSE REGISTER SAVE AREA   00910020
XRBNM    EQU   0                   PRB + 0 = PGM NAME IN MFT            00920020
PRBMASK  EQU   X'C0'               MASK TO TEST FOR PRB                 00930020
RBSTAB   EQU   10                  RB + 10 IS FLAG FIELD                00940020
RBCDE    EQU   12                  PRB+12 POINTS TO CDE                 00950020
RBOPSW   EQU   16                  SAVE AREA FOR OLD PSW                00960020
RBLINK   EQU   28                  RB + 28 POINTS TO NEXT RB OR TCB     00970020
RBTCBNXT EQU   X'80'               MASK TO TEST RBLINK FIELD            00980020
CDENM    EQU   8                   CDE+8 CONTAINS PGM NAME - MVT        00990020
TIOJOBID EQU   0                   DISPLACEMENT FOR JOB ID              01000020
MCKOPSW  EQU   48                  MACHINE CHECK OLD PSW                01020020
EXTLOGON EQU   X'40'               MASK TO TURN EXTENDED LOG ON         01030020
EXTLOGOF EQU   X'BF'               MASK TO TURN EXTENDED LOG OFF        01040020
OFF      EQU   8                                                        01050020
LEVEL    EQU   X'&LEV'             MODULE LEVEL                         01080021
SMCHID   EQU   X'40'               MODULE ID                            01118820
*                                                                       01127520
*********************************************************************   01136220
         EJECT                                                          01144920
*********************************************************************   01153620
*********     F  O  R  M  A  T    O  F    A  B  R  E  C     *********   01162320
*                                                                       01179720
*             ******************************************                01188420
*             *          *   OS    *                   *                01197120
*  + 0        *   KEY    * RELEASE *  S W I T C H E S  *                01205820
*             *          * NUMBER  *                   *                01214520
*             ******************************************                01223220
*  + 4        *                S P A R E               *                01240620
*             ******************************************                01258020
*             *                                        *                01266720
*  + 8        *              D   A   T   E             *                01275420
*             *                                        *                01284120
*             ******************************************                01292820
*             *                                        *                01301520
*  + 12       *              T   I   M   E             *                01310220
*             *                                        *                01318920
*             ******************************************                01327620
*             *                                        *                01336320
*  + 16       *                C P U I D               *                01345020
*             *                                        *                01353720
*             ******************************************                01362420
*             *                                        *                01371120
*  + 24       *          P R O G R A M    I D          *                01379820
*             *                                        *                01388520
*             ******************************************                01397220
*             *                                        *                01405920
*  + 32       *              J O B    I D              *                01414620
*             *                                        *                01423320
*             ******************************************                01432020
*             *              M A C H I N E             *                01440720
*   + 40      *                C H E C K               *                01449420
*             *             O L D    P S W             *                01458120
*             ******************************************                01466820
*             *              M A C H I N E             *                01475520
*   + 48      *                C H E C K               *                01484220
*             *       I N T E R R U P T    C O D E     *                01492920
*             ******************************************                01501620
*             *               D A M A G E              *                01510320
*   + 56      *           A S S E S S M E N T          *                01519020
*             *                 D A T A                *                01527720
*             ******************************************                01536420
*             *   LOST   *   LOST  *   LOST  *   LOST  *                01545120
*   + 64      * CPU-ABND * CPU-RECV* CPU-SOFT* ECC-ABND*                01553820
*             *    CTR   *    CTR  *    CTR  *    CTR  *                01562520
*             ******************************************                01571220
*             *   LOST   *   LOST  *         *                          01579920
*   + 68      * ECC-RECV * ECC-SOFT*   FLAG  *                          01588620
*             *    CTR   *    CTR  *         *                          01597320
*             ********************************                          01606020
*                                                                       01614720
* THESE ARE EQUATES FOR THE ABBREVIATED RECORD                          01623420
*                                                                       01632120
KEY      EQU   0                   KEY                                  01640820
*   BYTE 0   BIT 0-7    X'10'      MCH RECORD                           01649520
*                                                                       01658220
OSRELNO  EQU   1                   OS RELEASE NUMBER                    01666920
*   BYTE 1   BIT 0-2    000        OS                                   01675620
*                3-7               RELEASE LEVEL                        01684320
RECSW    EQU   2                   RECORD SWITCH                        01693020
*                                                                       01701720
*   BYTE 0   BIT 0 = 1             OPERATOR MESSAGE                     01710420
*                1 = 1             NS MACHINE                           01719120
*                2 = 1             EC MODE                              01727820
*                3-7               RESERVED                             01736520
*   BYTE 1   BIT 0 = 1             SHORT RECORD                         01745220
*                1 = 1             IMCOMPLETE                           01753920
*                2 = 1             MCH TERMINTE SYSTEM                  01762620
SPARE    EQU   4                   RESERVED                             01771320
DATE     EQU   8                   DATE                                 01780020
TIME     EQU   12                  TIME                                 01790020
CPUID    EQU   16                  CPU ID                               01791020
PGMID    EQU   24                  PROGRAM ID                           01800020
JOBID    EQU   32                  JOB ID                               01810020
MCPSW    EQU   40                  MACHINE CHECK OLD PSW                01820020
MCICODE  EQU   48                  MACHINE CHECK INTERRUPTION CODE      01830020
DASMT    EQU   56                  MCH DAMAGE ASSESSMENT FIELD          01840020
LOSTSUM  EQU   64                  MCH LOST RECORD SUMMARY              01850020
RECFLAG  EQU   70                  FLAG FOR RMS RECORDER                01860020
RECLENG  EQU   71                  BUFFER LENGTH                        01870020
ACTIVE   EQU   X'80'               INDICATES AN ACTIVE RECORD. IT IS    01880020
*                                  SET BY SMCIH, RESET BY RECORDER      01890020
SHORT    EQU   X'40'               SHORT RECORD SET BY MCH RECORDER     01900020
LONG     EQU   X'20'               LONG RECORD SET BY MCH RECORDER      01910020
CLOBBER  EQU   X'10'               INDICATES THAT THE CORRELATED LOGOUT 01920020
*                                  IS OVERLAID                          01930020
*                                                                       01940020
KEYC     EQU   X'10'               MCH KEY ID                           01950020
SWITCH   EQU   X'40'               RECORD SWITCH                        01960020
*                                                                       01970020
* EQUATES FOR LOST SUMMARY                                              01980020
*                                                                       01990020
ABNDCTR  EQU   64                  TASK ABEND COUNTER                   02000020
RECOVCTR EQU   65                  TASK RECOVERY COUNTER                02010020
SOFTCTR  EQU   66                  SOFT ERROR COUNTER                   02020020
*                                  COUNTER                              02030020
* EQUATES FOR DAMAGE ASSESSMENT FIELD                                   02040020
*                                                                       02050020
* BYTE 0 OF DAMAGE ASSESSMENT FIELD - SUMMARY                           02060020
DSOFT    EQU   56                  DISPLACEMENT FOR SOFT COUNTER        02070020
*                                  FIELD                                02080020
DRECV    EQU   56                  DISPLACEMENT FOR RECOVERY            02090020
SOFT     EQU   X'80'               MASK FOR SOFT ERROR                  02100020
RECV     EQU   X'40'               MASK TO TEST RECOVERY                02110020
TERMIN   EQU   X'08'               SYSTEM TERMINATION MASK              02130020
* BYTE 1 OF DAMAGE ASSESSMENT FIELD - AREA DATA                         02140020
DSTORAGE EQU   57                  DISPLACEMENT FOR STORAGE ERROR       02150020
MAINSTOR EQU   X'80'               MAIN STORAGE ERROR                   02160020
STG      EQU   X'80'               MASK TO TEST STORAGE ERROR           02170020
CNTLSTOR EQU   X'20'               INDICATES CONTROL STORAGE ERROR      02180020
PROC     EQU   X'08'               INDICATES PROCESSOR ERROR            02190020
CCHER    EQU   X'04'               MASK FOR CATASTROPH I/O EROR         02200020
CLOCKERR EQU   X'02'               MASK IN MCHDAMAG FOR MACHINE         02201020
SOFTMASK EQU   X'F7'               MASK TO DISABLE SOFT MCI             02205021
* BYTE 2 OF DAMAGE ASSESSMENT FIELD - ERROR TYPE DATA                   02210020
DATA     EQU   X'20'               DATA ERROR                           02220020
*                                  CHECK DUE TO CLOCK                   02222020
         SPACE 3                                                        02230020
EMERECDR EQU   X'0B'               CODE FOR IGFMCHE3                    02240020
SHORTS   EQU   X'80'               SHORT RECORD SWITCH                  02250020
LONGS    EQU   X'7F'               LONG RECORD SWITCH                   02260020
TERMS    EQU   X'20'               TERMINATION SWITCH                   02270020
K0       EQU   0                   * 0                                  02280020
K1       EQU   1                   * 1                                  02290020
K2       EQU   2                   * 2                                  02300020
K3       EQU   3                   * 3                                  02310020
K4       EQU   4                   * 4                                  02310521
K5       EQU   5                   * 5                                  02311020
K6       EQU   6                   * 6                                  02320020
K8       EQU   8                   * 8                                  02321020
K16      EQU   16                  * 16                                 02440020
K24      EQU   24                  * 24                                 02451020
K32      EQU   32                  * 32                                 02461020
K40      EQU   40                  * 40                                 02471020
K48      EQU   48                  * 48                                 02481020
K53      EQU   53                  * 53                                 02491020
K64      EQU   64                  * 64                                 02501020
K72      EQU   72                  * 72                                 02510120
K128     EQU   128                 * 128                                02540020
K120     EQU   120                 * 120                                02561020
K152     EQU   152                 * 152                                02571020
K192     EQU   192                 * 192                                02581020
K272     EQU   272                 * 272                                02591020
X10      EQU   X'10'               * X'10'                              02591420
X80      EQU   X'80'               * 80                                 02592020
X60      EQU   X'60'               *                                    02593021
X40      EQU   X'40'               *                                    02594021
X08      EQU   X'08'               *                                    02595021
XF0      EQU   X'F0'               *                                    02596021
XC0      EQU   X'C0'               *                                    02597021
X0F      EQU   X'0F'               *                                    02598021
XFE      EQU   X'FE'               MASK TO TEST DISABLED PSW            02600020
         EJECT                                                          02610020
*                                                                       02620020
* SET REQUIRED BASE                                                     02630020
*                                                                       02640020
         USING *,BASEREG           SET BASE FOR SMCH                    02650020
         USING CVTSECT,CVTREG      ADDRESSABILITY FOR CVT               02660020
         USING MCHCOMMN,COMBASE    COMMON AREA BASE                     02670020
         USING MODMSB,R1           BASE FOR MSB                   21196 02675021
         MVI   MCHEXLEV,LEVEL      MODULE LEVEL INDICATOR               02680021
         L     R1,MCHMSB           POINTER TO MSB IN CVT          21021 02685021
         MVI   MCHNXHIS,SMCHID     MOVE IN MODULE ID                    02690020
         L     R9,MCHINLOG         INDEPENDENT LOG                      02700020
         L     RMSG,MCHIPTR        GET TO NEXT ENTRY IN MCHIBUF         02710020
         LA    R7,MCHWORK          GET ENDING ADDR OF MCHIBUF           02712020
         CR    RMSG,R7             IS BUFFER FULL                       02714020
         BL    HORS                CONTINUE PROCESSING IF NOT FULL      02716020
* MCHIBUF IS FULL SO MUST RESET POINTER TO BEGINNING OF BUFFER AREA     02718020
* AND TURN ON MCHIBUF CLOBBER FLAG IN BYTE 2 OF MCHINT                  02718120
         LA    RMSG,MCHIBUF        RESET PTR TO BEG. OF MCHIBUF         02718420
         OI    MCHINT+K2,X10       TURN ON MSG BUFFER CLOBBER FLAG      02718820
HORS     EQU   *                                                        02720020
         TM    MCHDAMAG+K1,CCHER   I O ERROR                            02730020
         BO    SYSDOWNY            BRANCH IF YES                        02740020
         TM    MCHDAMAG,TERMIN     Q. TERMINATE SYSTEM                  02750020
         BO    BUFMGMT             BRANCH IF YES                        02760020
         TM    MCHDAMAG,SOFT       Q. SOFT ERROR                        02770020
         BZ    BUFMGMT             BRANCH IF NO                         02780020
*  SOFT ERROR                                                           02790020
         TM    INTPCODE(R9),INRECVR SUCESSFUL HARDWARE RECOVERY         02800020
         BZ    BUFMGMT             NO                                   02810020
         TM    INTPCODE+K2(R9),ECC Q. ECC ERROR                         02820020
         BO    ECCERROR            YES ECC ERROR                        02830020
HIROK    EQU   *                                                        02840020
         MVI   K0(RMSG),CPUMSG     SET UP HIR CORRECTED MESSAGE         02850020
         TM    REGION,CONTROL      DID ERROR OCCUR IN CONTROL STORAGE   02852020
         BO    CHECKTHR            YES GO CHECK THRESHOLD EXCEEDED      02854020
         OI    MCHDAMAG+K1,PROC    INDICATE PROCESSING DAMAGE           02860020
UPDTIBUF EQU   *                                                        02870020
         LA    RMSG,K1(RMSG)       UPDATE MESSAGE                       02880020
         ST    RMSG,MCHIPTR        UPDATE MCHIPTR TO REFLECT MSG        02890020
         EJECT                                                          02900020
*                                                                       02910020
* THIS ROUTINE HANDLES BUFFER AVAILABLE CONDITION                       02920020
*                                                                       02930020
BUFMGMT  EQU   *                                                        02940020
         TM    MSBNODSW,X80        IS MAIN IN RECORD MODE         21196 02940821
         BZ    NXTEST1             NO - CHECK FOR OTHERS          21196 02941621
         OI    MCHDAMAG+K4,X40     SET MAIN STORAGE RECORD        21196 02942421
NXTEST1  TM    MSBNODSW,X60        IS CONTROL IN RECORD OR QUIET  21196 02943221
         BNZ   NXTEST2             YES                            21196 02944021
         OI    MCHDAMAG+K4,X08     SET CONTROL IN THRESHOLD MODE  21196 02944821
         B     TURNOFF             CONTINUE                       21196 02945621
NXTEST2  TM    MSBNODSW,X40        IS CONTROL IN RECORD MODE      21196 02946421
         BZ    TURNOFF             CONTINUE                       21196 02947221
         OI    MCHDAMAG+K4,X10     INDICATE CONTROL IN RECORD     21196 02948021
TURNOFF  NI    K272(R9),SOFTMASK   TURN OFF RECOVERY BIT                02948821
         LA    R6,RECLENG          GET SIZE OF ABREC                    02950020
         SR    R3,R3               CLEAR INITIALLY                      02960020
         LA    R5,MCHABREC         INIT TO FIRST ABREC                  02970020
         LR    RECPTR,R3           ZERO ALSO                            02980020
         IC    R3,MCHABRNO         GET NUMBER OF ABRECS                 02990020
TSTACTIV EQU   *                                                        03000020
         TM    RECFLAG(R5),ACTIVE  IS THIS ABREC AREA ACTIVE(USED)      03010020
         BNZ   BUFUSED             YES, DETERMINE IF I/O IN PROGRESS    03020020
         LR    RECPTR,R5           NO, SET PTR IN REG FOR LATER         03030020
         SPACE                                                          03040020
BUFUSED  EQU   *                                                        03050020
         TM    RECFLAG(R5),LONG    IS A FULL MCH RECORD I/O IN PROG.    03060020
         BZ    NOLONGIO            NO, DO NOT SET EXCP CLOBBERED        03070020
         OI    RECFLAG(R5),CLOBBER SET EXCP OPERATION CLOBBERED         03080020
         SPACE                                                          03090020
NOLONGIO EQU   *                                                        03100020
         OI    K3(R5),SHORTS       SET SHORT FORM OF RECORD FLAG        03110020
         AR    R5,R6               COMPUTE ADDRESS OF NEXT ABREC        03120020
         BCT   R3,TSTACTIV         CONTINUE UNTIL ALL ARE CHECKED       03130020
         LTR   RECPTR,RECPTR       WAS AN UNUSED ABREC FOUND            03140020
         BZ    PURGEBUF            NO, GO PREPARE TO OVERLAY SHORT      03150020
         XC    LOSTSUM(K6,RECPTR),LOSTSUM(RECPTR) RESET LOST SUMMARY    03160020
         B     BUILDREC            GO FINISH BUILD OF RECORD            03170020
         SPACE                                                          03180020
PURGEBUF EQU   *                                                        03190020
         LA    RECPTR,MCHABREC     INIT. TO FIRST ABREC                 03200020
         IC    R3,MCHABRNO         GET NUMBER OF ABREC S                03210020
         LA    R5,PBPFOUND         SET UP FOR LATER BR                  03220020
         SPACE                                                          03230020
TSTSOFT  EQU   *                                                        03240020
         TM    DSOFT(RECPTR),SOFT  EXISTING REC. SHOW SOFT MCI          03250020
         BO    PBPSOFT             YES                                  03260020
         AR    RECPTR,R6           COMPUTE ADDRESS OF NEXT ABREC        03270020
         BCT   R3,TSTSOFT          CONTINUE SEARCH                      03280020
         LA    RECPTR,MCHABREC     INIT. TO FIRST ABREC                 03290020
         IC    R3,MCHABRNO         GET NUMBER OF ABREC S                03300020
         SPACE                                                          03310020
TSTHDREC EQU   *                                                        03320020
         TM    DRECV(RECPTR),RECV  EXISTING REC. SHOW HARD RECOVERED    03330020
         BO    PBPRECOV            YES                                  03340020
         AR    RECPTR,R6           COMPUTE ADDRESS OF NEXT ABREC        03350020
         BCT   R3,TSTHDREC         CONTINUE SEARCH                      03360020
         SR    RECPTR,R6           GET LAST ABREC POINTER               03365021
         LA    R3,ABNDCTR(RECPTR)  SET PTR TO LAST LOST SUM. FIELD      03370020
         B     TESTSTG             GO TEST FOR STG/CPU ERROR            03380020
         SPACE                                                          03390020
PBPSOFT  EQU   *                                                        03400020
         LA    R3,SOFTCTR(RECPTR)  SET PTR TO SOFTS IN LOST SUM.        03410020
         SPACE                                                          03420020
TESTSTG  EQU   *                                                        03430020
         TM    DSTORAGE(RECPTR),STG STORAGE ERROR                       03440020
         BCR   OFF,R5              NO, CPU - BR VIA PRESET ADDR         03450020
         LA    R3,K3(R3)           BUMP TO NEXT FIELD                   03460020
         BR    R5                  BR VIA PRESET ADDR                   03470020
         SPACE                                                          03480020
PBPRECOV EQU   *                                                        03490020
         LA    R3,RECOVCTR(RECPTR) SET PTR TO HARDS RECOVERED IN SUM.   03500020
         B     TESTSTG             CHECK FOR STG/CPU                    03510020
         SPACE                                                          03520020
PBPFOUND EQU   *                                                        03530020
         IC    R5,K0(R3)           GET LOST INCIDENT COUNT              03540020
         LA    R5,K1(R5)           INCREMENT BY ONE                     03550020
         STC   R5,K0(R3)           SAVE UPDATED COUNT                   03560020
         TM    RECFLAG(RECPTR),LONG+SHORT IS ANY I/O IN PROGRESS        03570020
         BZ    BUILDREC            NO                                   03580020
         OI    RECFLAG(RECPTR),CLOBBER SET EXCP OPERATION CLOBBERED     03590020
         EJECT                                                          03600020
*                                                                       03610020
* THIS IS MCH RECORD FORMATE ROUTINE                                    03620020
*                                                                       03630020
*  GENERATS THE RECORD HEADER                                           03640020
*                                                                       03650020
BUILDREC EQU   *                                                        03660020
RECFRMT  EQU   *                                                        03670020
         OI    RECFLAG(RECPTR),ACTIVE    INDICATE ACTIVE BUFFER         03680020
         ST    RECPTR,MCHLONG      SAVE PTR TO LONG RECORD              03690020
         NI    K3(RECPTR),LONGS    SET LONG SWITCH IN HDR               03700020
         MVC   MCHLSUM(K6),LOSTSUM(RECPTR) MOVE LOST SUMMARY INTO       03710020
*                                  DAMAGE ASSESMENT FIELD               03720020
         MVC   MCPSW(K8,RECPTR),MCHPSA+K48 MOVE MCK OLD PSW INTO RECORD 03730020
         MVC   DASMT(K8,RECPTR),MCHDAMAG MOVE DAMAGE ASSESMENT          03740020
*                                  INTO THE RECORD                      03750020
         MVI   KEY(RECPTR),KEYC    MOVE KEY INTO THE RECORD             03760020
         MVI   RECSW(RECPTR),SWITCH  MOVE SWITCH INTO RECORD            03770020
         MVC   OSRELNO(K1,RECPTR),MCHRELNO MOVE IN OS RELEASE NO.       03780020
         DC    X'B202'             USE DIAGNOSTIC INSTRUCTION TO GET    03790020
         DC    S(CTIME)            MODEL AND SERIAL NO                  03800020
         MVC   CPUID(K8,RECPTR),CTIME MOVE INTO THE RECORD              03810020
*                                                                       03830020
***  THIS ROUTINE GENERATES DATE AND TIME FOR THE RECORD                03840020
*                                                                       03850020
         TM    MCHDAMAG+K1,CLOCKERR HAS THERE BEEN A MACHINE CHECK DUE  03860020
*                                  TO CLOCK                             03861020
         BO    NOSTORE             YES, DO NOT STORE CLOCK              03870020
         DC    X'B205'             NO,STORE CLOCK TO GET                03880020
         DC    S(CTIME)            DATE AND TIME                        03890020
         BC    K3,NOSTORE          STORE CLOCK DIDN'T WORK              03900021
         MVC   DATE(K8,RECPTR),CTIME MOVE DATE AND TIME INTO RECORD     03910020
         B     SKIPTIME            GO GENERATE JOB ID                   03920020
NOSTORE  EQU   *                                                        03930020
         XC    DATE(K8,RECPTR),DATE(RECPTR) CLEAR DATE AND TIME         03940020
*                                  FIELD OF RECORD                      03950020
*                                                                       04030020
***  GENERATE JOB ID                                                    04040020
*                                                                       04050020
*                                                                       04060020
SKIPTIME EQU   *                                                        04070020
         XC    PGMID(K16,RECPTR),PGMID(RECPTR) CLEAR JOB AND PROG ID    04080020
         SR    RPRB,RPRB           CLEAR REG                            04090020
         L     RCNTTCB,CVTTCBP     PTR FOR OLD AND NEW TCB              04100020
         L     RCNTTCB,CNTTCB(RCNTTCB)  ACTIVE TCB ADDRESS              04110020
         L     RRB,TCBRBP(RCNTTCB) CURRENT RB ADDR                      04120020
         CR    RRB,RCNTTCB         Q. DUMMY TCB                         04130020
         BE    RECMCI              BRANCH IF YES                        04140020
         L     R5,TCBTIO(RCNTTCB)   TIOT ADDRESS                        04150020
         LTR   R5,R5               Q. TIOT VALID                        04160020
         BZ    BYPASS              NO THERE IS NO TIOT                  04170020
         MVC   JOBID(K8,RECPTR),TIOJOBID(R5) MOVE JOB ID IN RECORD      04180020
*                                                                       04190020
*****  GENERATE PROGRAM ID                                              04200020
BYPASS   EQU   *                                                        04210020
         TM    X1D(RCNTTCB),XC0    TASK TERMINATING            @S66087P 04213021
         BNZ   RECMCI              YES SKIP RB SEARCH          @S66087P 04216021
PRBTEST  TM    RBSTAB(RRB),PRBMASK Q. IS PRB                            04220020
         BNZ   MORERB              BRANCH IF NO                         04230020
         LR    RPRB,RRB            SAVE PRB ADDRESS IF YES              04240020
MORERB   EQU   *                                                        04250020
         TM    RBSTAB+K1(RRB),RBTCBNXT  IS THIS RB POINTING TO TCB      04260020
         BO    RBEND               BRANCH IF YES                        04270020
         L     RRB,RBLINK(RRB)     GET NEXT RB ADDRESS                  04280020
         B     PRBTEST             GO TO TEST IF IT IS A PRB            04290020
RBEND    EQU   *                                                        04300020
         LTR   RPRB,RPRB           IS THERE A PRB                       04310020
         BZ    RECMCI              BRANCH IF NO PRB                     04320020
         TM    CVTDCB,MVTMASK      Q. IS MVT SYSTEM                     04330020
         BO    MVTPGMID            BRANCH IF YES                        04340020
         MVC   PGMID(K8,RECPTR),XRBNM(RPRB) MOVE PGM ID IN RECORD       04350020
         B     RECMCI              BRANCH                               04360020
MVTPGMID EQU   *                                                        04370020
         L     RWORK3,RBCDE(RPRB)  GET CDE ADDRESS                      04380020
         MVC   PGMID(K8,RECPTR),CDENM(RWORK3) MOVE PGM ID IN RECORD     04390020
RECMCI   EQU   *                                                        04400020
         MVC   MCICODE(K8,RECPTR),INTPCODE(R9) MOVE MCICODE INTO RECORD 04410020
         TM    MCHDAMAG,TERMIN     TERMINATION OF SYSTEM NEEDED         04420020
         BO    SYSDOWN             BRANCH IF YES                        04430020
*                                                                       04440020
* THIS ROUTINE WILL RESTART CHANNELS IF NEEDED.                         04450020
*                                                                       04460020
         TM    MCHINTEL+K1,X80     ANY MODULE LOADED                    04470020
         BZ    POST                BRANCH TO POST TRN INTERFACE IF NO   04480020
         ST    COMBASE,R11SAVE     SAVE COMMON AREA BASE                04500020
         STM   R0,R15,MCHMLSAV     SAVE REGS                            04510020
         L     R15,MCHIOENT        LOAD ENTRY TO EXCP                   04520020
         CNOP  K2,K4               PUT INSTRUCTION ON HALF WORD   40762 04525021
         BALR  R14,R15             BRANCH TO IOS                        04530021
         USING *,R14                SET UP TEMP BASE                    04532000
         DC    X'80000000'                                        40762 04535000
         L     COMBASE,R11SAVE     RESTORE MCH COMMON AREA BASE         04550020
         LM    R0,R15,MCHMLSAV     RESTORE ALL REGS                     04560020
         DROP  R14                 DROP TEMP BASE                       04570020
*                                                                       04580020
*  THIS ROUTINE INTERFACES WITH POST ROUTINE                            04590020
*                                                                       04600020
POST     EQU   *                                                        04610020
         STM   R0,R15,MCHMLSAV     SAVE REGS                            04620020
         L     R3,MCHPSTAD         ADDR OF POST INTERFACE ROUTINE       04630020
         BALR  R2,R3               GO TO POST INTERFACE ROUTINE         04640020
*                                                                       04650020
*****    THIS ROUTINE RESTORE SYSTEM STATUS AND TERMINATES MACHINE      04660020
*        CHECK HANDLER                                                  04670020
*                                                                       04680020
TRMNT0   EQU   *                                                        04690020
EXIT     EQU   *                                                        04700020
         LM    R0,R15,MCHMLSAV     RESTORE REGS                         04710020
         TM    MCHPSA+K48,XFE      Q. WAS I/O DISABLED WHEN MCI         04720020
         BZ    RETPGM              YES - RETURN TO INTERRUPTED PROGRAM  04722021
         L     R2,MCHNEST          GET ADDRESS OF MCHNEST SWITCH  40412 04724021
         TM    K1(R2),XF0          WAS IOS IN CONTROL             40412 04726021
         BZ    RSYSTM              N0 - RETURN TO SYSTEM, YES - TO IOS  04728021
         TM    MCHDAMAG,XC0        ERROR RECOVERED                40412 04730021
         BNZ   RETPGM              YES - IOS CAN GET CONTROL BACK 40412 04732021
         NI    K1(R2),X0F          TURN OFF IOS NEST SWITCH       40412 04734021
         B     RSYSTM              EXIT TO THE SYSTEM             40412 04736021
RETPGM   EQU   *                                                        04738021
         LA    R8,K120(R9)         SET UP POINTER IN FIXED LOG          04740020
         BAL   R2,RESTORE          BRANCH AND LINK                      04750020
         LM    R0,R15,K152(R9)     RESTORE REGS FROM FIXED LOGOUT       04760020
         LPSW  MCKOPSW             RETURN TO INTERRUPTED PGM            04770020
*                                                                       04780020
* THIS ROUTINE RETURNS CONTROL TO DISPATCHER                            04790020
*                                                                       04800020
RSYSTM   EQU   *                                                        04810020
         L     R2,CVTTCBP          TCB POINTER                          04820020
         LM    R6,R7,K0(R2)        NEW - OLD TCB                        04830020
         TM    CVTDCB,MVTMASK      IS MVT SYSTEM                        04840020
         BO    MVTSYS              BRANCH IF YES                        04850020
MFTSYS   MVC   TCBGRS(K24,R7),K192(R9) RESTORE GPR 10-15 IN OLD TCB     04860020
         MVC   K72(K40,R7),K152(R9) RESTORE GPR 0-9 IN OLD TCB          04870020
         TM    X1F(R7),X08         DO FPRS EXIST IN THIS TCB   IG 51236 04872021
         BNO   NTO1                NO,DO NOT RESTORE THEM      IG 51236 04874021
NTO      EQU   *                                                        04880020
         LR    R8,R7               GET FLOATING REG                     04890020
         SH    R8,D32              SAVE AREA                            04900020
         MVC   K0(K32,R8),K120(R9) SAVE FLOATING REGS IN OLD TCB        04910020
NTO1     EQU   *                                               IG 51236 04912021
         L     R5,TCBRBP(R7)       GET ADDR OF RB IN OLD TCB            04920020
         MVC   RBOPSW(K8,R5),MCHRPSW  RESUME PSW IN RB                  04930020
         MVC   MCHPSA+K48(K5),DISPATCH SET UP                           04940020
         MVC   MCHPSA+K53(K3),CVT0DS+K1 DISPATCHER ADDRESS              04950020
* GET HIGHEST PRIORITY READY TCB SET UP                                 04990020
         BAL   R2,RESTORE          BRANCH AND LINK                      05020020
         TM    CVTDCB,MVTMASK      IS MVT SYSTEM                        05030020
         BO    MVTSYS1             BRANCH IF YES                        05040020
         LM    R10,R9,TCBGRS(R7)   RESTORE REGS FOR MFT                 05060020
         LPSW  MCKOPSW             RETURN TO DISPATCHER                 05070020
MVTSYS1  EQU   *                                                        05080020
         LM    R0,R15,TCBGRS(R7)   RESTORE REGS                         05090020
         LPSW  MCKOPSW             RETURN TO DISPATCHER                 05100020
MVTSYS   EQU   *                                                        05110020
         MVC   TCBGRS(K64,R7),K152(R9) RESTORE REGS TO OLD TCB          05120020
         B     NTO                 BRANCH                               05130020
RESTORE  EQU   *                                                        05140020
         TM    X1F(R7),X08         DO FPRS EXIST ON THE MACHINE   50272 05140421
         BNO   RESTORE1            NO,DO NOT LOAD THEM         IG 50272 05141221
         LR    R8,R7               GET FLOATING REG            IG 50272 05142021
         SH    R8,D32              SAVE AREA                   IG 50272 05144021
         LD    FR0,K0(R8)          * RESTORE                            05150020
         LD    FR2,K8(R8)          * FLOATING                           05160020
         LD    FR4,K16(R8)         * POINT                              05170020
         LD    FR6,K24(R8)         * REGISTERS                          05180020
RESTORE1 EQU   *                                               IG 50272 05182021
         LA    R3,DISABLE1         GET ADDRESS FOR LPSW           42810 05190021
         ST    R3,DISABLE+K4       STORE IN PSW                   42810 05200021
         LPSW  DISABLE             DISABLE FOR MACHINE CHECKS     42810 05210021
DISABLE1 DC    X'B70F90D8'         RESTORE CONTROL REGISTERS      42810 05220021
         MVC   K0(K128),MCHPSA     RESTORE PERMANENT STORAGE ASSIGNMENT 05232020
         BR    R2                  RETURN                               05240020
SYSDOWN  EQU   *                                                        05250020
         OI    K3(RECPTR),TERMS    SET TERMINATION SWITCH               05260020
SYSDOWNY EQU   *                                                        05262020
         MVI   MCHNXMOD,EMERECDR   SET IGFMCHE3 AS SUCCESSOR            05270020
         BR    R14                 RETURN TO NUCLEUS                    05280020
         EJECT                                                          05290020
*  ECC CORRECTED ERROR OCCURRED.  THIS ROUTINE WILL CHECK FOR MESSAGE   05300020
*  FOR CONTROL STORAGE IN QUIET MODE NEEDED                             05310020
ECCERROR EQU  *                                                         05320020
         OI    MCHDAMAG+K2,DATA    INDICATE DATA ERROR                  05330020
         MVI   K0(RMSG),ECCMSG     SET UP ECC CORRECTED MESSAGE         05360020
         OI    MCHDAMAG+K1,MAINSTOR INDICATE MAIN STORAGE ERROR         05410020
         B     UPDTIBUF            GO UPDATE PTR TO IBUFF               05450020
CHECKTHR EQU   *                                                        05460020
         OI    MCHDAMAG+K1,CNTLSTOR INDICATE CONTROL STORAGE ERROR      05470020
         TM    REGION,THRESHLD     HAS THRESHOLD BEEN REACHED           05480021
         BZ    UPDTIBUF            NO UPDATE PTR TO IBUFF               05490020
         LA    RMSG,K1(RMSG)       UPDATE TO REFLECT HIR SUCCESSFUL     05540020
         MVI   K0(RMSG),QUIET      SET UP QUIET MODE MSG                05570020
         OI    MSBNODSW,CONTQUI    INDICATE CONTROL IN QUIET MODE 21196 05575021
         B     UPDTIBUF            GO UPDATE PTR TO IBUFF               05580020
         EJECT                                                          05590020
         DS    0D                                                       05600020
R11SAVE  DC    F'0'                SAVE AREA FOR REG 11                 05610020
D32      DC    H'32'               CONSTANT                             05620020
DISPATCH DC    X'0004FF0000'       FIRST FIVE BYTE OF DISPATCHER PSW    05630020
         DS    0D                                                       05635021
DISABLE  DC    XL8'0'                                                   05640021
MAINTID  DC    CL8'IGFMCH40'       CORE IDENTIFIER                      05645021
MAINT    DC    S(*)                MODULE DISPLACEMENT                  05650021
         DC    10CL4'&REL&LEV'     ADDITIONAL SPACE                     05655021
*                                                                       05660020
*   THIS IS THE MACRO FOR MCH COMMOM AREA                               05670020
*                                                                       05680020
MCHCOMMN DSECT                                                          05690020
         MCHMAC                                                         05700020
CTIME    EQU   MCHMLSAV+4          WORKAREA                             05710020
CVTSECT  DSECT                                                          05720020
         CVT                                                            05730020
MODMSB   DSECT                                                          05733021
         RMSMSB  MOD=45                                                 05736021
         END                                                            05740020
