         LCLA  &LEV,&REL                                                00072021
&LEV     SETA  22                                                       00074021
&REL     SETA  21                                                       00080021
&REL&LEV TITLE 'IGFMCH41 LEVEL &LEV PROGRAM ERROR ANALYSIS (PEA) FOR   C00086021
               MODELS 135,145'                                          00092021
IGFMCH41 CSECT                                                          00100020
*********************************************************************** 00150020
*                                                                     * 00200020
*   TITLE-     IGFMCH41  PROGRAM ERROR ANALYSIS ROUTINE               * 00250020
*                                                                     * 00300020
*   STATUS-    CHANGE LEVEL 00  -  2/08/71                            * 00350020
*                                                                     * 00400020
*   FUNCTION-  ANALYZE THE TYPE OF INSTRUCTION PROCESSING DAMAGE AND  * 00450020
*              DETERMINE THE TYPE OF RECOVERY STRATEGY FOR    IC 21055* 00480021
*                    MCH/135,145                              IC 21055* 00510021
*                                                                     * 00550020
*   ENTRY POINT- IGFMCH41                                             * 00600020
*                                                                     * 00650020
*   INPUT-     REGISTER 11 POINTS TO MCH COMMON AREA                  * 00700020
*              REGISTER 14 CONTAINS THE RETURN ADDRESS                * 00750020
*              REGISTER 15 CONTAINS PROGRAM ENTRY ADDRESS             * 00800020
*              MACHINE CHECK INTERRUPT CODE AND FAILING STORAGE       * 00850020
*                      ADDRESS FROM MODEL INDEPENDENT LOGOUT AREA     * 00900020
*                                                                     * 00950020
*   OUTPUT-    INSTRUCTION PROCESSING DAMAGE-                         * 01000020
*                 SWITCHES ARE SET IN MCHPDAR TO INDICATE THE TYPE    * 01050020
*                       OF ERROR, SEVERITY OF IT, AND TERMINATE THE   * 01100020
*                       AFFECTED AREA                                 * 01150020
*                       MCHPDAR-                                      * 01200020
*                          BYTE 0-                                    * 01250020
*                           BIT 0 = 1   TERMINATION NECESSARY         * 01300020
*                          BYTE 1-                                    * 01350020
*                           BIT 0 = 1   SOLID STORAGE ERROR           * 01400020
*                           BIT 1 = 1   INTERMITTENT STORAGE ERROR    * 01450020
*                           BIT 2 = 1   SOLID SPF ERROR               * 01500020
*                           BIT 3 = 1   INTERMITTENT SPF ERROR        * 01550020
*                           BIT 5 = 1   STORAGE LOCATION CLEARED      * 01560020
*                          BYTES 8 - 11- BEGINNING ADDRESS OF         * 01600020
*                                        AFFECTED AREA                * 01650020
*                          BYTES 12 - 15- END ADDRESS OF AFFECTED     * 01700020
*                                         AREA                        * 01750020
*                 AT THE ADDRESS POINTED TO BY MCHIPTR, INSERT A      * 01800020
*                       X'0F' TO INDICATE TO MESSAGE WRITER(IGFMCHE1) * 01850020
*                       TO WRITE MESSAGE 'IGF045I MULTIPLE BIT        * 01900020
*                       ERROR', THEN UPDATE THE POINTER BY ONE(1).    * 01950020
*                 SET MCHNXMOD TO X'01' TO CALL IGFMCHF1(PDAR) AS     * 02000020
*                       THE SUCCESSOR MODULE                          * 02050020
*              INVALID FAILING STORAGE ADRESSS, SYSTEM MASK, PSW      * 02100020
*               AMWP, OR CONTROL REGISTERS-                           * 02150020
*                 TURN ON BIT 4, BYTE 0 OF MCHDAMAG TO SET SYSTEM     * 02200020
*                       TERMINATION NECESSARY                         * 02250020
*                 SET MCHNXMOD TO X'02' TO CALL THE SOFT      IC 21055* 02280021
*                       MACHINE CHECK HANDLER AS THE SUCESSOR IC 21055* 02310021
*                       MODULE                                IC 21055* 02340021
*                                                                     * 02400020
*   EXTERNAL REFERENCES- NONE                                         * 02450020
*                                                                     * 02500020
*   EXITS-     SOFT MCH -INVALID FAILING STORAGE ADDRESS,     IC 21055* 02550021
*                        SYSTEM MASK,PSW AMWP,OR CONTROL REGS IC 21055* 02600021
*              IGFMCHF1 - STORAGE ERROR, STORAGE PROTECT FAILURE,     * 02650020
*                         OR RETRY FAILED                             * 02700020
*              NUCLEUS  - UNEXPECTED MACHINE CHECK OCCURRED           * 02750020
*                                                                     * 02800020
*   TABLES/WORKAREAS- MCHMAC - MODEL INDEPENDENT COMMON AREA          * 02850020
*                     INDEPENDENT LOGOUT AREA                         * 02900020
*                                                                     * 02950020
*   ATTRIBUTES- TRANSIENT                                             * 03000020
*               SERIALLY REUSABLE                                     * 03050020
*               OPERATES IN SUPERVISOR MODE                           * 03100020
*               MODELS 135,145 DEPENDENT                      IC 21055* 03150021
*                                                                     * 03200020
*   NOTES-      THIS PROGRAM CONTAINS A 50 BYTE MAINTENANCE AREA      * 03210020
*                  CALLED 'MAINT'                                     * 03220020
*                                                                     * 03250020
*********************************************************************** 03300020
         EJECT                                                          03350020
*********************************************************************** 03400020
*                                                                     * 03450020
*        EQUATES                                                      * 03500020
*                                                                     * 03550020
*********************************************************************** 03600020
         SPACE                                                          03650020
R0       EQU   0                   WORK REGISTER                        03700020
SCNDBASE EQU   2                   SECONDARY BASE REGISTER              03750020
R2       EQU   2                   WORK REGISTER                        03800020
R3       EQU   3                   WORK REGISTER                        03850020
R4       EQU   4                   WORK REGISTER                        03900020
R5       EQU   5                   WORK REGISTER                        03950020
R6       EQU   6                   WORK REGISTER                        04000020
R7       EQU   7                   WORK REGISTER                        04050020
R8       EQU   8                   WORK REGISTER                        04100020
R9       EQU   9                   WORK REGISTER                        04150020
R10      EQU   10                  WORK REGISTER                        04200020
COMBASE  EQU   11                  COMMUNICATIONS AREA BASE REGISTER    04250020
R14      EQU   14                  RETURN REGISTER                      04300020
BASEREG  EQU   15                  TRANSIENT BASE REGISTER              04350020
X00      EQU   X'00'               HEX CONSTANT                         04400020
X01      EQU   X'01'               HEX CONSTANT                         04450020
X02      EQU   X'02'               HEX CONSTANT                         04500020
X03      EQU   X'03'               HEX CONSTANT                         04550020
X04      EQU   X'04'               HEX CONSTANT                         04600020
X08      EQU   X'08'               HEX CONSTANT                         04650020
X10      EQU   X'10'               HEX CONSTANT                         04700020
X20      EQU   X'20'               HEX CONSTANT                         04702021
N1       EQU   1                   DECIMAL CONSTANT           IC  21961 04710021
N2       EQU   2                   DECIMAL CONSTANT           IC  21961 04720021
D2048    EQU   2048                DECIMAL CONSTANT                     04750020
MCHOPSW  EQU   48                  LOCATION OF MACHINE CHECK OLD PSW    04800020
MCHNPSW  EQU   112                 LOCATION OF MACHINE CHECK NEW PSW    04850020
MCIC     EQU   232                 MACHINE CHECK INTERRUPT CODE ADDRESS 04900020
SOFTMCI  EQU   X'20'               SOFT MCI INDICATOR                   04950020
IPD      EQU   X'40'               INSTRUCTION PROCESSING DAMAGE IND.   05000020
SPF      EQU   X'20'               SPF ERROR INDICATOR                  05050020
SE       EQU   X'80'               STORAGE ERROR INDICATOR              05100020
MS       EQU   X'04'               SYSTEM MASK AND KEY VALID INDICATOR  05150020
WP       EQU   X'08'               VALID PSW AMWP INDICATOR             05200020
FA       EQU   X'80'               FAILING STORAGE ADDRESS VALID IND.   05250020
CR       EQU   X'04'               CONTROL REGISTERS VALID INDICATOR    05300020
SOLID    EQU   X'40'               SOLID ERROR INDICATOR      IC  21961 05310021
INTER    EQU   X'80'               INTERMITTENT ERROR IND     IC  21961 05320021
SPFINT   EQU   X'84'               SPF INTERMITTENT ERROR IND IC  21961 05330021
SPFSLD   EQU   X'44'               SPF SOLID ERROR IND        IC  21961 05340021
INTSE    EQU   X'44'               INTERMITTENT STORAGE ERROR INDICATOR 05350020
SLDSE    EQU   X'80'               SOLID STORAGE ERROR INDICATOR        05400020
INTSPF   EQU   X'10'               INTERMITTENT SPF ERROR INDICATOR     05450020
SLDSPF   EQU   X'20'               SOLID SPF ERROR INDICATOR            05500020
TERM     EQU   X'80'               TERMINATION NECESSARY INDICATOR      05550020
TERMSYS  EQU   X'08'               SYSTEM TERMINATION NECESSARY IND.    05600020
IGFMCHF1 EQU   X'01'               IGFMCHF1 MODULE ID                   05650020
SOFTMCH  EQU   X'02'               SOFT MCH MODULE ID         IC  21961 05700021
IGF045I  EQU   X'0F'               MULTIPLE BIT ERROR MESSAGE ID        05750020
LEVEL    EQU   X'&LEV'             MODULE LEVEL                         05800021
         EJECT                                                          05850020
*********************************************************************** 05900020
*                                                                     * 05950020
*        THIS SECTION OF CODE PERFORMS GENERAL INITIALIZATION         * 06000020
*                                                                     * 06050020
*********************************************************************** 06100020
         SPACE                                                          06150020
         USING IGFMCH41,BASEREG    ESTABLISH PROGRAM BASE REGISTER      06200020
         USING MCHCOMMN,COMBASE    ESTABLISH COMMUNICATIONS BASE REG    06250020
         MVI   MCHEXLEV,LEVEL      INDICATE MODULE LEVEL                06300021
         MVC   PSWSAVE(X08),MCHNPSW SAVE MACHINE CHECK NEW PSW IC 21961 06310021
         L     R3,MCHINLOG         GET ADDR OF INDEPENDENT LOGOUT AREA  06350020
         TM    X02(R3),WP+MS       VALID PSW AMWP AND SYSTEM MASK       06400020
         BNO   SMCHEXIT            NO, GO PUT SYSTEM DOWN               06450020
         TM    X03(R3),CR          YES, CONTROL REGISTERS VALID         06500020
         BZ    SMCHEXIT            NO, GO PUT SYSTEM DOWN               06550020
         L     R4,X10(R3)          YES, GET ADDRESS OF FAILING LOCATION 06600020
         STM   R10,BASEREG,REGSAVE SAVE IMPORTANT REGISTERS             06700020
         LA    R5,CHKSOFT          GET ADDR OF EXPECTED MCI ENTRY POINT 06750020
         ST    R5,EXPERPSW+X04     PUT IT IN EXPECTED ERROR PSW         06800020
         LA    R5,SLDENTRY         GET ADDR OF EXPECTED MCI ENTRY POINT 06850020
         ST    R5,MCHNPSW+X04      PUT IT IN MACHINE CHECK NEW PSW      06900020
         EJECT                                                          06950020
*********************************************************************** 07000020
*                                                                     * 07050020
*        THIS ROUTINE DETERMINES IF THE STORAGE ERROR IS SOLID        * 07100020
*              OR INTERMITTENT                                        * 07150020
*                                                                     * 07200020
*********************************************************************** 07250020
         SPACE                                                          07300020
         TM    X02(R3),SE          STORAGE ERROR                        07350020
         BZ    NOSTRERR            NO, CHECK FOR SPF ERROR              07400020
         OI    MCHDAMAG+N1,SE      INDICATE STORAGE ERROR     IC  21961 07420021
         OI    MCHDAMAG+N2,X20     INDICATE DATA ERROR                  07430021
         TM    X03(R3),FA          YES, FAILING STORAGE ADDRESS VAILID  07450020
         BZ    SMCHEXIT            NO, GO PUT THE SYSTEM DOWN           07500020
         L     R5,MCHIPTR          YES, GET POINTER TO MESSAGE BUFFER   07550020
         MVI   X00(R5),IGF045I     INDICATE TO WRITE IGF045I MESSAGE    07600020
         LA    R5,X01(R5)          INCREMENT THE POINTER BY ONE(1)      07650020
         ST    R5,MCHIPTR          PUT THE NEW POINTER BACK             07700020
         N     R4,DBLEWORD         ROUND OFF ADDRESS TO DOUBLE WORD     07750020
         ST    R4,REPDARF1         SET UP BEGINNING ADDRESS FOR PDAR    07800020
         LA    R5,X08(R4)          COMPUTE END ADDRESS                  07850020
         ST    R5,REPDARF2         SET UP END ADDRESS FOR PDAR          07900020
         LA    R2,(TEST4+L'TEST4-TEST1)/L'TEST1 GET NUMBER OF BIT TESTS 07950020
         LA    R9,TEST1            GET ADDRESS OF THE FIRST BIT TEST    08000020
TESTSE   MVC   X00(L'TEST1,R4),X00(R9) THE FOLLOWING CODE VALIDATES THE 08050020
         LM    R7,R8,X00(R4)        FAILING STORAGE LOCATION BY MOVING  08100020
         C     R7,X00(R9)           ALL POSSIBLE BIT COMBINATIONS INTO  08150020
         BNE   SLDSERR              THAT LOCATION, THEN FETCHING THEM   08200020
         C     R8,X04(R9)           AND CHECKING THE RESULT. IF THE     08250020
         BNE   SLDSERR              RESULTANT PATTERNS DO NOT MATCH, OR 08300020
         LA    R9,L'TEST1(R9)       A SECOND MACHINE CHECK OCCURS, THE  08350020
         BCT   R2,TESTSE            STORAGE ERROR IS CONSIDERED SOLID,  08400020
*                                   OTHERWISE IT IS INTERMITTENT.       08450020
         OI    REPDAR2,INTSE       INDICATE INTERMITTENT STORAGE ERROR  08500020
         OI    MCHDAMAG+N2,INTER   IND.INTERMITTENT STOR ERR  IC  21961 08520021
         B     PDAREXIT            EXIT TO PDAR                         08550020
         EJECT                                                          08600020
*********************************************************************** 08650020
*                                                                     * 08700020
*        THIS ROUTINE DETERMINES IF THE SPF ERROR IS SOLID            * 08750020
*              OR INTERMITTENT                                        * 08800020
*                                                                     * 08850020
*********************************************************************** 08900020
         SPACE                                                          08950020
NOSTRERR TM    X02(R3),SPF         SPF ERROR                            09000020
         BZ    NOSPFERR            NO, INDICATE RETRY FAILED            09050020
         TM    X03(R3),FA          YES, FAILING STORAGE VALID           09100020
         BZ    SMCHEXIT            NO, GO PUT SYSTEM DOWN               09150020
         N     R4,F2048            YES, ROUND ADDRESS TO 2048 BOUNDARY  09200020
         ST    R4,REPDARF1         SET UP BEGINNING ADDRESS FOR PDAR    09250020
         LA    R5,D2048(R4)        COMPUTE END ADDRESS                  09300020
         ST    R5,REPDARF2         SET UP END ADDRESS FOR PDAR          09350020
         SR    R6,R6               ZERO WORK REGISTER                   09400020
         SR    R7,R7               ZERO WORK REGISTER                   09450020
         LA    R8,X10              GET NUMBER OF TIMES TO LOOP          09500020
SPFLOOP  SSK   R6,R4               THIS SECTION OF CODE DETERMINES      09550020
         ISK   R7,R4                IF THE SPF ERROR IS INTERMITTENT    09600020
         CR    R6,R7                OR SOLID BY TESTING ALL POSSIBLE    09650020
         BNE   SLDSPFER             BIT COMBINATIONS AND CHECKING THE   09700020
         LA    R6,X10(R6)           FINAL RESULTS, OR BY RECEIVING A    09750020
         BCT   R8,SPFLOOP           SECOND MACHINE CHECK INTERRUPTION.  09800020
         SR    R6,R6               GET ZERO PROTECT KEY                 09850020
         SSK   R6,R4               SET STORAGE PROTECT KEY TO ZERO      09900020
         OI    REPDAR2,INTSPF      INDICATE INTERMITTENT SPF ERROR      09950020
         OI    MCHDAMAG+N2,SPFINT  IND.INTERMITTENT SPF ERROR IC  21961 09970021
         B     PDAREXIT            EXIT TO PDAR                         10000020
         EJECT                                                          10050020
*********************************************************************** 10100020
*                                                                     * 10150020
*        THIS ROUTINE INDICATES RETRY FAILED AND EXITS TO PDAR        * 10200020
*                                                                     * 10250020
*********************************************************************** 10300020
         SPACE                                                          10350020
NOSPFERR EQU   *                   INDICATE RETRY FAILED                10400020
PDAREXIT OI    REPDAR1,TERM        INDICATE TERMINATION NECESSARY       10450020
         MVI   MCHNXMOD,IGFMCHF1   INDICATE MODULE SUCCESSOR            10500020
COMMEXIT MVC   MCHNPSW(X08),PSWSAVE RESTORE MACHINE CHECK NEW PSW       10550020
         BR    R14                 RETURN TO CALLER                     10600020
         SPACE 3                                                        10650020
*********************************************************************** 10700020
*                                                                     * 10750020
*        ROUTINE TO EXIT TO SMCH IN THE EVENT OF INVALID DATA         * 10800020
*                                                                     * 10850020
*********************************************************************** 10900020
         SPACE                                                          10950020
SMCHEXIT OI    MCHDAMAG,TERMSYS    SET SYSTEM TERMINATION NECESSARY     11000020
         MVI   MCHNXMOD,SOFTMCH    INDICATE MODULE SUCCESSOR  IC  21961 11050021
         B     COMMEXIT            RETURN TO CALLER                     11100020
         EJECT                                                          11150020
*********************************************************************** 11200020
*                                                                     * 11250020
*        ROUTINE TO HANDLE SECOND MACHINE CHECK IN THE EVENT OF A     * 11300020
*              SOLID MCI                                              * 11350020
*                                                                     * 11400020
*********************************************************************** 11450020
         SPACE                                                          11500020
         USING SLDENTRY,SCNDBASE                                        11550020
SLDENTRY LM    R0,BASEREG,X00      CLEAR POSSIBLE BAD PARITY IN GPRS    11600020
         L     SCNDBASE,MCHNPSW+X04 REESTABLISH ADDRESSABILITY          11650020
         LM    R10,BASEREG,REGSAVE RELOAD IMPORTANT REGISTERS           11700020
         DROP  SCNDBASE                                                 11750020
         LPSW  EXPERPSW            ENABLE MACHINE CHECKS AGAIN          11800020
CHKSOFT  TM    MCIC,SOFTMCI        SOFT MACHINE CHECK                   11850020
         BZ    CHKHARD             NO, GO CHECK FOR TYPE OF HARD MCI    11900020
         LPSW  MCHOPSW             YES, IGNORE SOFT MCI                 11950020
CHKHARD  TM    MCIC,IPD            INSTRUCTION PROCESSING DAMAGE        12000020
         BZ    UNEXPERR            NO, UNEXPECTED ERROR OCCURRED        12050020
         L     R3,MCHINLOG         YES, GET ADDRESS OF OLD MCIC         12100020
         CLC   MCIC(X04),X00(R3)   INTERRUPT CODES MATCH                12150020
         BNE   UNEXPERR            NO, UNEXPECTED ERROR OCCURRED        12200020
         L     R4,MCIC+X10         YES, GET FAILING STORAGE ADDRESS     12250020
         TM    X02(R3),SE          STORAGE ERROR                        12300020
         BZ    CHKSPF              NO, CHECK FOR SPF ERROR              12350020
         N     R4,DBLEWORD         YES, ROUND OFF ADDR TO DOUBLE WORD   12400020
         C     R4,REPDARF1         FAILING STORAGE ADDRESSES THE SAME   12450020
         BNE   UNEXPERR            NO, INDICATE UNEXPECTED ERROR        12500020
SLDSERR  OI    REPDAR2,SLDSE       YES, INDICATE SOLID STORAGE ERROR    12550020
         OI    MCHDAMAG+N2,SOLID   INDICATE SOLID STOR ERROR  IC  21961 12570021
         B     PDAREXIT            EXIT TO PDAR                         12600020
CHKSPF   TM    X02(R3),SPF         SPF ERROR                            12650020
         BZ    UNEXPERR            NO, UNEXPECTED ERROR OCCURRED        12700020
         N     R4,F2048            YES, ROUND ADDRESS TO 2048 BOUNDARY  12750020
         C     R4,REPDARF1         FAILING STORAGE ADDRESSES THE SAME   12800020
         BNE   UNEXPERR            NO, INDICATE UNEXPECTED ERROR        12850020
SLDSPFER OI    REPDAR2,SLDSPF      YES, INDICATE SOLID SPF ERROR        12900020
         OI    MCHDAMAG+N2,SPFSLD  INDICATE SOLID SPF ERROR   IC  21961 12920021
         B     PDAREXIT            EXIT TO PDAR                         12950020
UNEXPERR MVC   MCHNPSW(X08),PSWSAVE RESTORE MACHINE CHECK NEW PSW       13000020
         LPSW  MCHNPSW             EXIT TO NUCLEUS SHUT ROUTINE         13050020
         EJECT                                                          13100020
*********************************************************************** 13150020
*                                                                     * 13200020
*        SAVE AREAS, WORK AREAS, CONSTANTS AND DSECT(S)               * 13250020
*                                                                     * 13300020
*********************************************************************** 13350020
         SPACE                                                          13400020
         DS    0D                                                       13450020
REGSAVE  DC    6F'0'               IMPORTANT REGISTERS SAVE AREA        13500020
TEST1    DC    X'5555555555555555' TEST PATTERN DBLE WD OF B'01010101'  13600020
TEST2    DC    X'AAAAAAAAAAAAAAAA' TEST PATTERN DBLE WD OF B'10101010'  13650020
TEST3    DC    X'FFFFFFFFFFFFFFFF' TEST PATTERN DBLE WD OF B'11111111'  13660020
TEST4    DC    XL8'0'              TEST PATTERN DBLE WD OF B'00000000'  13700020
EXPERPSW DC    X'00040000'         ENABLE MACHINE CHECK INTERRUPTIONS   13750020
         DS    A(CHKSOFT)           AGAIN RESUME PSW                    13800020
DBLEWORD DC    XL4'FFFFF8'         CONSTANT TO ROUND OFF ADDRESS        13850020
F2048    DC    XL4'FFF800'         CONSTANT TO ROUND OFF ADDRESS        13900020
PSWSAVE  DC    D'0'                SAVE AREA FOR MACHINE CHECK NEW PSW  13950020
MAINTID  DC    CL8'IGFMCH41'       CORE IDENTIFIER                      14000021
MAINT    DC    S(*)                MODULE DISPLACEMENT                  14010021
         DC    10CL4'&REL&LEV'     ADDITIONAL SPACE                     14020021
MCHCOMMN DSECT                                                          14050020
         MCHMAC                                                         14100020
         END                                                            14150020
