         LCLA  &LEV,&REL                                                00020000
&LEV SETA 24                                                            00050021
&REL     SETA  21                                                       00060000
&REL&LEV TITLE 'IGFMCH50 LEVEL &LEV SOFT MACHINE CHECK HANDLER FOR 135' 00080000
IGFMCH50 CSECT                                                          00200000
*********************************************************************** 00300000
*                                                                       00400000
*  NAME        IGFMCH50  SOFT MACHINE CHECK HANDLER                   * 00500000
*                                                                       00600000
* STATUS LEVEL = 24 10/19/73                                            00700021
*                                                                       00800000
*  FUNCTION    1. FORMATING MACHINE CHECK RECORD FOR THE SYS1.LOGREC    00900000
*                 DATA SET                                              01000000
*                                                                       01100000
*              2. PROCESS THE AUTOMATIC MODE SWITCHING ROUTINE          01200000
*                                                                       01300000
*              3. RECORD BUFFER MANAGEMENT                              01400000
*                                                                       01500000
*              4. TERMINATES MACHINE CHECK HANDLER AND RESTORES THE     01600000
*                 SYSTEM STATUS                                         01700000
*                                                                       01800000
*  ATTRIBUTES - NONRESIDENT IN MCH TRANSIENT AREA,SUPERVISOR STATE      01900000
*                                                                       02000000
*  ENTRY POINTS- IGFMCH50 ENTERED FROM IGFMCHE0                       * 02100000
*                                                                       02200000
*  EXITS -     ON SYSTEM TERMINATION TO MODULE SCHEDULER TO SCHEDULE    02300000
*              IGFMCHE3                                                 02400000
*              OTHERWISE CONTROL IS RETURNED TO THE SYSTEM              02500000
*              CONTROL IS RETURNED TO INTERRUPTED PROGRAM IF I/O        02600000
*              WAS DISABLED AT TIME OF INTERRUPT                        02700000
*              CONTROL IS RETURNED TO DISPATCHER IF I/O NOT DISABLED    02800000
*                                                                       02900000
*  INPUT       LOGOUT - MODEL INDEPENDENT OR/AND MODEL DEPENDENT        03000000
*                       LOGOUT                                          03100000
*              MACHINE INTERRUPT CODE                                   03200000
*              MCH COMMON AREA                                          03300000
*                                                                       03400000
*  OUTPUT      RECOVERY OR DAMAGE REPORT TO MCH RECORDER                03500000
*              MODE SWITCHING MESSAGE                                   03600000
*                                                                       03700000
*  OPERATION - UPON GETTING CONTROL THIS MODULE WILL CHECK WHETHER      03800000
*              THE ERROR WAS A SOFT ERROR.  IF IT WAS IT DETERMINES     03900000
*              WHETHER IT WAS AN ECC CORRECTED OR AN HIR CORRECTED      04000000
*              CONDITION AND INDICATES TYPE OF ERROR IN DAMAGE          04100000
*              ASSESSEMENT FIELD AND CORRECT MESSAGE.  IT THEN          04200000
*              SETS UP THE RECORD BY RECORD BUFFERING ROUTINE.          04300000
*              WHEN THE RECORD HAS BEEN SET UP CONTROL IS GIVEN TO POST 04400000
*              ROUTINE WHO WILL POST RMS ECB IN UCM.  SMCH WILL DETER-  04500000
*              MINE IF MCK INTERRUPTION OCCURED IN A PROGRAM WITH A     04600000
*              DISABLED PSW.  IF SO STATUS IS RESTORED AND CONTROL      04700000
*              RETURNED TO INTERRUPTED PROGRAM AT POINT OF INTERRUP-    04800000
*              TION.  IF NOT CONTROL IS RETURNED TO DISPATCHER          04900000
*              WHO WILL DISPATCH NEXT READY TASK.                       05000000
*              IF THE SMCH WAS ENTERED ON A SYSTEM DOWN CASE, THE       05100000
*              RECORD IS BUFFERED AND IGFMCHE3 IS SCHEDULED AND         05200000
*              CONTROL IS RETURNED TO NUCLEUS TO LOAD THIS MODULE.      05300000
*                                                                       05400000
*  NOTES -     A 50 BYTE MAINTENANCE AREA HAS BEEN ADDED WITH LABEL -   05500000
*              *****MAINT*****                                          05600000
*                                                                       05700000
********************************************************************    05800000
********************************************************************    05900000
* THESE ARE EQUATES FOR REGISTER                                        06000000
*                                                                       06100000
R0       EQU   0                   *                                    06200000
MSBBASE  EQU   1                   BASE FOR MACHINE STATUS BLOCK (MSB)  06300000
RCNTTCB  EQU   2                   *                                    06400000
R2       EQU   2                   *                                    06500000
COUNT    EQU   3                   HIR ERROR COUNTER                    06600000
RWORK3   EQU   3                   *                                    06700000
RRB      EQU   3                   *                                    06800000
R3       EQU   3                   *                                    06900000
RECPTR   EQU   4                   *                                    07000000
RMSG     EQU   4                   *                                    07100000
R5       EQU   5                   *                                    07200000
R6       EQU   6                   *                                    07300000
R7       EQU   7                   *                                    07400000
RPRB     EQU   8                   *                                    07500000
R8       EQU   8                   *                                    07600000
R9       EQU   9                   *                                    07700000
CVTREG   EQU   10                  CVT POINTER                          07800000
R10      EQU   10                  *                                    07900000
COMBASE  EQU   11                  POINTER TO MCHMAC                    08000000
R14      EQU   14                  *                                    08100000
R15      EQU   15                  *                                    08200000
BASEREG  EQU   15                  BASE REGISTER FOR THIS MODULE        08300000
*                                                                       08400000
* EQUATES FOR FLOATING POINT REGISTERS                                  08500000
*                                                                       08600000
FR0      EQU   0                   FLOATING REGISTER 0                  08700000
FR2      EQU   2                   FLOATING REGISTER 2                  08800000
FR4      EQU   4                   FLOATING REGISTER 4                  08900000
FR6      EQU   6                   FLOATING REGISTER 6                  09000000
*                                                                       09100000
*********************************************************************** 09200000
*********************************************************************** 09300000
*                                                                       09400000
*  THESE ARE EQUATES FOR AUTOMATIC MODE SWITCHING ROUTINE               09500000
*                                                                       09600000
INTPCODE EQU   0                   RELATIVE ADDR OF MCI CODE            09700000
*                                  IN INDEPENDENT LOG                   09800000
ECC      EQU   X'40'               MASK TO TEST ECC                     09900000
INRECVR  EQU   X'20'               INTERNAL RECOVERY BIT IN MCICODE     10000000
* MISCELLANEOUS EQUATES                                                 10100000
*                                                                       10200000
CPUMSG   EQU   X'12'               MESG CODE FOR HIR SUCCESS  IC  21961 10210021
ECCMSG   EQU   X'0E'               MESG CODE FOR ECC SUCCESS  IC  21961 10220021
MAINSTOR EQU   X'80'               MAIN STORAGE ERROR         IC  21961 10230021
CONTSTOR EQU   X'20'               CONTROL STORAGE ERROR      IC  21961 10240021
CPULGOUT EQU   257                 BYTE IN FIXED LOGOUT AREA  IC  21961 10250021
ECCQT    EQU   X'17'               CODE FOR ECC QUIET MESSAGE           10300000
ECCHIRQT EQU   X'16'               CODE FOR ECC,HIR QUIET MESSAGE       10400000
CNTTCB   EQU   4                   CVT POINTS TO CURRENT TCB ADDRESS    10500000
MVTMASK  EQU   X'10'               MASK TO TEST FOR MVT SYSTEM          10600000
MNSTOR   EQU   X'01'               MASK TO CHECK MAIN STOR ACSIC  21961 10650021
TCBRBP   EQU   0                   TCB + 0 POINTS TO RB                 10700000
TCBTIO   EQU   12                  TCB + 12 POINTS TO TIOT              10800000
TCBGRS   EQU   48                  GENERAL PURPOSE REGISTER SAVE AREA   10900000
XRBNM    EQU   0                   PRB + 0 = PGM NAME IN MFT            11000000
PRBMASK  EQU   X'C0'               MASK TO TEST FOR PRB                 11100000
RBSTAB   EQU   10                  RB + 10 IS FLAG FIELD                11200000
RBCDE    EQU   12                  PRB+12 POINTS TO CDE                 11300000
RBOPSW   EQU   16                  SAVE AREA FOR OLD PSW                11400000
RBLINK   EQU   28                  RB + 28 POINTS TO NEXT RB OR TCB     11500000
RBTCBNXT EQU   X'80'               MASK TO TEST RBLINK FIELD            11600000
CDENM    EQU   8                   CDE+8 CONTAINS PGM NAME - MVT        11700000
TIOJOBID EQU   0                   DISPLACEMENT FOR JOB ID              11800000
MCKOPSW  EQU   48                  MACHINE CHECK OLD PSW                11900000
EXTLOGON EQU   X'40'               MASK TO TURN EXTENDED LOG ON         12000000
EXTLOGOF EQU   X'BF'               MASK TO TURN EXTENDED LOG OFF        12100000
XF0      EQU   X'F0'               TO SET SIGN FIELD TO ZONE  IC  40412 12120021
XC0      EQU   X'C0'               HEX EQUATE                 IC  40412 12140021
X0F      EQU   X'0F'               HEX EQUATE                 IC  40412 12160021
X1F      EQU   X'1F'               FLOATING POINT TCB BIT     IG  51236 12170021
X08      EQU   X'08'               HEX EQUATE                 IG  51236 12172021
X1D      EQU   X'1D'               DISP TO TCB FLAG FIELD      @S66087P 12176021
X7F      EQU   X'7F'               HEX EQUATE                 IC  21116 12180021
OFF      EQU   8                                                        12200000
LEVEL    EQU   X'&LEV'             MODULE LEVEL                         12300000
SMCHID   EQU   X'50'               MODULE ID                            12400000
*                                                                       12500000
*********************************************************************   12600000
         EJECT                                                          12700000
*********************************************************************   12800000
*********     F  O  R  M  A  T    O  F    A  B  R  E  C     *********   12900000
*                                                                       13000000
*             ******************************************                13100000
*             *          *   OS    *                   *                13200000
*  + 0        *   KEY    * RELEASE *  S W I T C H E S  *                13300000
*             *          * NUMBER  *                   *                13400000
*             ******************************************                13500000
*  + 4        *                S P A R E               *                13600000
*             ******************************************                13700000
*             *                                        *                13800000
*  + 8        *              D   A   T   E             *                13900000
*             *                                        *                14000000
*             ******************************************                14100000
*             *                                        *                14200000
*  + 12       *              T   I   M   E             *                14300000
*             *                                        *                14400000
*             ******************************************                14500000
*             *                                        *                14600000
*  + 16       *                C P U I D               *                14700000
*             *                                        *                14800000
*             ******************************************                14900000
*             *                                        *                15000000
*  + 24       *          P R O G R A M    I D          *                15100000
*             *                                        *                15200000
*             ******************************************                15300000
*             *                                        *                15400000
*  + 32       *              J O B    I D              *                15500000
*             *                                        *                15600000
*             ******************************************                15700000
*             *              M A C H I N E             *                15800000
*   + 40      *                C H E C K               *                15900000
*             *             O L D    P S W             *                16000000
*             ******************************************                16100000
*             *              M A C H I N E             *                16200000
*   + 48      *                C H E C K               *                16300000
*             *       I N T E R R U P T    C O D E     *                16400000
*             ******************************************                16500000
*             *               D A M A G E              *                16600000
*   + 56      *           A S S E S S M E N T          *                16700000
*             *                 D A T A                *                16800000
*             ******************************************                16900000
*             *   LOST   *   LOST  *   LOST  *   LOST  *                17000000
*   + 64      * CPU-ABND * CPU-RECV* CPU-SOFT* ECC-ABND*                17100000
*             *    CTR   *    CTR  *    CTR  *    CTR  *                17200000
*             ******************************************                17300000
*             *   LOST   *   LOST  *         *                          17400000
*   + 68      * ECC-RECV * ECC-SOFT*   FLAG  *                          17500000
*             *    CTR   *    CTR  *         *                          17600000
*             ********************************                          17700000
*                                                                       17800000
         EJECT                                                          17900000
* THESE ARE EQUATES FOR THE ABBREVIATED RECORD                          18000000
*                                                                       18100000
KEY      EQU   0                   KEY                                  18200000
*   BYTE 0   BIT 0-7    X'10'      MCH RECORD                           18300000
*                                                                       18400000
OSRELNO  EQU   1                   OS RELEASE NUMBER                    18500000
*   BYTE 1   BIT 0-2    000        OS                                   18600000
*                3-7               RELEASE LEVEL                        18700000
RECSW    EQU   2                   RECORD SWITCH                        18800000
*                                                                       18900000
*   BYTE 0   BIT 0 = 1             OPERATOR MESSAGE                     19000000
*                1 = 1             NS MACHINE                           19100000
*                2 = 1             EC MODE                              19200000
*                3-7               RESERVED                             19300000
*   BYTE 1   BIT 0 = 1             SHORT RECORD                         19400000
*                1 = 1             IMCOMPLETE                           19500000
*                2 = 1             MCH TERMINTE SYSTEM                  19600000
SPARE    EQU   4                   RESERVED                             19700000
DATE     EQU   8                   DATE                                 19800000
TIME     EQU   12                  TIME                                 19900000
CPUID    EQU   16                  CPU ID                               20000000
PGMID    EQU   24                  PROGRAM ID                           20100000
JOBID    EQU   32                  JOB ID                               20200000
MCPSW    EQU   40                  MACHINE CHECK OLD PSW                20300000
MCICODE  EQU   48                  MACHINE CHECK INTERRUPTION CODE      20400000
DASMT    EQU   56                  MCH DAMAGE ASSESSMENT FIELD          20500000
LOSTSUM  EQU   64                  MCH LOST RECORD SUMMARY              20600000
RECFLAG  EQU   70                  FLAG FOR RMS RECORDER                20700000
RECLENG  EQU   71                  BUFFER LENGTH                        20800000
ACTIVE   EQU   X'80'               INDICATES AN ACTIVE RECORD. IT IS    20900000
*                                  SET BY SMCIH, RESET BY RECORDER      21000000
SHORT    EQU   X'40'               SHORT RECORD SET BY MCH RECORDER     21100000
LONG     EQU   X'20'               LONG RECORD SET BY MCH RECORDER      21200000
CLOBBER  EQU   X'10'               INDICATES THAT THE CORRELATED LOGOUT 21300000
*                                  IS OVERLAID                          21400000
*                                                                       21500000
KEYC     EQU   X'10'               MCH KEY ID                           21600000
SWITCH   EQU   X'40'               RECORD SWITCH                        21700000
*                                                                       21800000
* EQUATES FOR LOST SUMMARY                                              21900000
*                                                                       22000000
ABNDCTR  EQU   64                  TASK ABEND COUNTER                   22100000
RECOVCTR EQU   65                  TASK RECOVERY COUNTER                22200000
SOFTCTR  EQU   66                  SOFT ERROR COUNTER                   22300000
*                                  COUNTER                              22400000
* EQUATES FOR DAMAGE ASSESSMENT FIELD                                   22500000
*                                                                       22600000
* BYTE 0 OF DAMAGE ASSESSMENT FIELD - SUMMARY                           22700000
DSOFT    EQU   56                  DISPLACEMENT FOR SOFT COUNTER        22800000
*                                  FIELD                                22900000
DRECV    EQU   56                  DISPLACEMENT FOR RECOVERY            23000000
SOFT     EQU   X'80'               MASK FOR SOFT ERROR                  23100000
RECV     EQU   X'40'               MASK TO TEST RECOVERY                23200000
TERMIN   EQU   X'08'               SYSTEM TERMINATION MASK              23300000
* BYTE 1 OF DAMAGE ASSESSMENT FIELD - AREA DATA                         23400000
DSTORAGE EQU   57                  DISPLACEMENT FOR STORAGE ERROR       23500000
STG      EQU   X'80'               MASK TO TEST STORAGE ERROR           23600000
PROC     EQU   X'08'               INDICATES PROCESSOR ERROR            23700000
CCHER    EQU   X'04'               MASK FOR CATASTROPH I/O EROR         23800000
CLOCKERR EQU   X'02'               MASK IN MCHDAMAG FOR MACHINE         23900000
* BYTE 2 OF DAMAGE ASSESSMENT FIELD - ERROR TYPE DATA                   24000000
DATA     EQU   X'20'               DATA ERROR                           24100000
*                                  CHECK DUE TO CLOCK                   24200000
EMERECDR EQU   X'0B'               CODE FOR IGFMCHE3                    24300000
SHORTS   EQU   X'80'               SHORT RECORD SWITCH                  24400000
LONGS    EQU   X'7F'               LONG RECORD SWITCH                   24500000
TERMS    EQU   X'20'               TERMINATION SWITCH                   24600000
K0       EQU   0                   * 0                                  24700000
K1       EQU   1                   * 1                                  24800000
K2       EQU   2                   * 2                                  24900000
K3       EQU   3                   * 3                                  25000000
K4       EQU   4                   * 4                                  25050000
K5       EQU   5                   * 5                                  25100000
K6       EQU   6                   * 6                                  25200000
K8       EQU   8                   * 8                                  25300000
K16      EQU   16                  * 16                                 25400000
K24      EQU   24                  * 24                                 25500000
K32      EQU   32                  * 32                                 25600000
K40      EQU   40                  * 40                                 25700000
K48      EQU   48                  * 48                                 25800000
K53      EQU   53                  * 53                                 25900000
K64      EQU   64                  * 64                                 26000000
K72      EQU   72                  * 72                                 26100000
K128     EQU   128                 * 128                                26200000
K120     EQU   120                 * 120                                26300000
K152     EQU   152                 * 152                                26400000
K192     EQU   192                 * 192                                26500000
K272     EQU   272                 LOCATION OF CONTROL REG 14           26600000
X10      EQU   X'10'               * X'10'                              26700000
X80      EQU   X'80'               * 80                                 26800000
XFE      EQU   X'FE'               MASK TO TEST DISABLED PSW            26900000
XFF      EQU   X'FF'               HEX VALUE                            27000000
RECRDE   EQU   X'40'               ECC RECORD MODE INDICATOR            27100000
RECRDHE  EQU   X'C0'               HIR,ECC RECORD MODE INDICATOR        27200000
SOFTMASK EQU   X'F7'               MASK TO DISABLE SOFT MCI             27300000
MODESTAT EQU   X'C0'               MODE INTERROGATION MASK        21021 27350000
         EJECT                                                          27400000
*                                                                       27500000
* SET REQUIRED BASE                                                     27600000
*                                                                       27700000
         USING *,BASEREG           SET BASE FOR SMCH                    27800000
         USING CVTSECT,CVTREG      ADDRESSABILITY FOR CVT               27900000
         USING MCHCOMMN,COMBASE    COMMON AREA BASE                     28000000
         L     MSBBASE,MCHMSB      GET MACHINE STATUS BLOCK POINTER     28100000
         USING MSB553,MSBBASE      ESTAB ADDRESS FOR MACH STATUS BLOCK  28200000
         MVI   MCHEXLEV,LEVEL      MOVE IN MODULE LEVEL                 28300000
         MVI   MCHNXHIS,SMCHID     MOVE IN MODULE ID                    28400000
         L     R9,MCHINLOG         INDEPENDENT LOG                      28500000
         L     RMSG,MCHIPTR        GET TO NEXT ENTRY IN MCHIBUF         28600000
         LA    R7,MCHWORK          GET ENDING ADDR OF MCHIBUF           28700000
         CR    RMSG,R7             IS BUFFER FULL                       28800000
         BL    HORS                CONTINUE PROCESSING IF NOT FULL      28900000
* MCHIBUF IS FULL SO MUST RESET POINTER TO BEGINNING OF BUFFER AREA     29000000
* AND TURN ON MCHIBUF CLOBBER FLAG IN BYTE 2 OF MCHINT                  29100000
         LA    RMSG,MCHIBUF        RESET PTR TO BEG. OF MCHIBUF         29200000
         OI    MCHINT+K2,X10       TURN ON MSG BUFFER CLOBBER FLAG      29300000
HORS     EQU   *                                                        29400000
         TM    MCHDAMAG+K1,CCHER   I O ERROR                            29500000
         BO    SYSDOWNY            BRANCH IF YES                        29600000
         TM    MCHDAMAG,TERMIN     Q. TERMINATE SYSTEM                  29700000
         BO    BUFMGMT             BRANCH IF YES                        29800000
         TM    MCHDAMAG,SOFT       Q. SOFT ERROR                        29900000
         BZ    BUFMGMT             BRANCH IF NO                         30000000
*  SOFT ERROR                                                           30100000
         TM    INTPCODE(R9),INRECVR SUCESSFUL HARDWARE RECOVERY         30200000
         BZ    BUFMGMT             NO                                   30300000
         NI    MCHINT+K3,X7F       CLEAR QUIET MODE INDICATOR IC  21116 30350021
         TM    INTPCODE+K2(R9),ECC Q. ECC ERROR                         30400000
         BO    ECCERROR            YES ECC ERROR                        30500000
*  HIR ERROR OCCURRED                                                   30600000
         OI    MCHDAMAG+K1,PROC    INDICATE PROCESSING DAM    IC  21961 30620021
         MVI   K0(RMSG),CPUMSG     SET HIR SUCCESSFUL CODE    IC  21961 30640021
         TM    CPULGOUT,MNSTOR     Q.IS DAMAGE IN MAIN STORAGEIC  21961 30660021
         BZ    CONTDAM             NO,ITS CONTROL STORAGE     IC  21961 30680021
         OI    MCHDAMAG+K1,MAINSTOR  INDICATE MAIN STOR DAM   IC  21961 30700021
         B     THRSCNT             CONTINUE                   IC  21961 30720021
CONTDAM  OI    MCHDAMAG+K1,CONTSTOR  INDICATE CONT STOR DAM   IC  21961 30740021
THRSCNT  L     COUNT,MSBCOUNT      GET COUNT OF HIR ERRORS    IC  21961 30760021
         LA    COUNT,K1(COUNT)     UPDATE ERROR COUNT BY ONE            30800000
         ST    COUNT,MSBCOUNT      SAVE ERROR COUNT IN MSB              30900000
         C     COUNT,MSBTHRLD      HAS ERROR COUNT REACHED THRESHOLD    31000000
         BL    UPDTIBUF            NO,BRANCH                  IC  21961 31100021
         NI    K272(R9),SOFTMASK   DISABLE FOR SOFT MCI                 31200000
         OI    MCHINT+K3,X80       IND QUIET MODE FOR RECORDER    RECDR 31250000
         NI    MSBMODE,XFF-RECRDHE SET HIR,ECC QUIET INDICATORS IN MSB  31300000
         LA    RMSG,K1(RMSG)       UPDATE BUFFER POINTER      IC  21961 31400021
         MVI   K0(RMSG),ECCHIRQT   MOVE MSG CODE INTO WTO BUFFER        31500000
         B     UPDTIBUF            OUTPUT MESSAGE             IC  21961 31540021
*  ECC ERROR OCCURRED                                                   31700000
ECCERROR EQU   *                                                        31800000
         DC    X'83000F32'         PUT ECC IN QUIET MODE                31900000
         OI    MCHDAMAG+K2,DATA    INDICATE DATA ERROR                  32000000
         NI    MSBMODE,XFF-RECRDE  SET ECC QUIET INDICATOR IN MSB       32100000
         MVI   K0(RMSG),ECCQT      MOVE MSG CODEINTO WTO BUFFER         32200000
         LA    RMSG,K1(RMSG)       UPDATE BUFFER POINTER      IC  21961 32230021
         MVI   K0(RMSG),ECCMSG     SET ECC SUCCESSFUL CODE    IC  21961 32260021
UPDTIBUF EQU   *                                                        32300000
         LA    RMSG,K1(RMSG)       UPDATE MESSAGE                       32400000
         ST    RMSG,MCHIPTR        UPDATE MCHIPTR TO REFLECT MSG        32500000
*                                                                       32600000
* THIS ROUTINE HANDLES BUFFER AVAILABLE CONDITION                       32700000
*                                                                       32800000
BUFMGMT  EQU   *                                                        32900000
         TM    MSBMODE,MODESTAT    DETERMINE MODE STATUS      IC  21961 32910021
         BO    HRER                HIR RECORD,ECC RECORD      IC  21961 32920021
         BZ    TURNOFF             HIR QUIET,ECC QUIET        IC  21961 32930021
         OI    MCHDAMAG+K4,X80     IND HIR RECORD,ECC QUIET   IC  21961 32940021
         B     TURNOFF             CONTINUE                   IC  21961 32950021
HRER     OI    MCHDAMAG+K4,RECRDHE IND HIR RECORD,ECC RECORD  IC  21961 32960021
TURNOFF  NI    K272(R9),SOFTMASK   CLEAR FOR SOFT MCI         IC  21961 32970021
         LA    R6,RECLENG          GET SIZE OF ABREC                    33000000
         SR    R3,R3               CLEAR INITIALLY                      33100000
         LA    R5,MCHABREC         INIT TO FIRST ABREC                  33200000
         LR    RECPTR,R3           ZERO ALSO                            33300000
         IC    R3,MCHABRNO         GET NUMBER OF ABRECS                 33400000
TSTACTIV EQU   *                                                        33500000
         TM    RECFLAG(R5),ACTIVE  IS THIS ABREC AREA ACTIVE(USED)      33600000
         BNZ   BUFUSED             YES, DETERMINE IF I/O IN PROGRESS    33700000
         LR    RECPTR,R5           NO, SET PTR IN REG FOR LATER         33800000
         SPACE                                                          33900000
BUFUSED  EQU   *                                                        34000000
         TM    RECFLAG(R5),LONG    IS A FULL MCH RECORD I/O IN PROG.    34100000
         BZ    NOLONGIO            NO, DO NOT SET EXCP CLOBBERED        34200000
         OI    RECFLAG(R5),CLOBBER SET EXCP OPERATION CLOBBERED         34300000
         SPACE                                                          34400000
NOLONGIO EQU   *                                                        34500000
         OI    K3(R5),SHORTS       SET SHORT FORM OF RECORD FLAG        34600000
         AR    R5,R6               COMPUTE ADDRESS OF NEXT ABREC        34700000
         BCT   R3,TSTACTIV         CONTINUE UNTIL ALL ARE CHECKED       34800000
         LTR   RECPTR,RECPTR       WAS AN UNUSED ABREC FOUND            34900000
         BZ    PURGEBUF            NO, GO PREPARE TO OVERLAY SHORT      35000000
         XC    LOSTSUM(K6,RECPTR),LOSTSUM(RECPTR) RESET LOST SUMMARY    35100000
         B     BUILDREC            GO FINISH BUILD OF RECORD            35200000
         SPACE                                                          35300000
PURGEBUF EQU   *                                                        35400000
         LA    RECPTR,MCHABREC     INIT. TO FIRST ABREC                 35500000
         IC    R3,MCHABRNO         GET NUMBER OF ABREC S                35600000
         LA    R5,PBPFOUND         SET UP FOR LATER BR                  35700000
         SPACE                                                          35800000
TSTSOFT  EQU   *                                                        35900000
         TM    DSOFT(RECPTR),SOFT  EXISTING REC. SHOW SOFT MCI          36000000
         BO    PBPSOFT             YES                                  36100000
         AR    RECPTR,R6           COMPUTE ADDRESS OF NEXT ABREC        36200000
         BCT   R3,TSTSOFT          CONTINUE SEARCH                      36300000
         LA    RECPTR,MCHABREC     INIT. TO FIRST ABREC                 36400000
         IC    R3,MCHABRNO         GET NUMBER OF ABREC S                36500000
         SPACE                                                          36600000
TSTHDREC EQU   *                                                        36700000
         TM    DRECV(RECPTR),RECV  EXISTING REC. SHOW HARD RECOVERED    36800000
         BO    PBPRECOV            YES                                  36900000
         AR    RECPTR,R6           COMPUTE ADDRESS OF NEXT ABREC        37000000
         BCT   R3,TSTHDREC         CONTINUE SEARCH                      37100000
         SR    RECPTR,R6           GET LAST ABREC POINTER         21961 37150000
         LA    R3,ABNDCTR(RECPTR)  SET PTR TO LAST LOST SUM. FIELD      37200000
         B     TESTSTG             GO TEST FOR STG/CPU ERROR            37300000
         SPACE                                                          37400000
PBPSOFT  EQU   *                                                        37500000
         LA    R3,SOFTCTR(RECPTR)  SET PTR TO SOFTS IN LOST SUM.        37600000
         SPACE                                                          37700000
TESTSTG  EQU   *                                                        37800000
         TM    DSTORAGE(RECPTR),STG STORAGE ERROR                       37900000
         BCR   OFF,R5              NO, CPU - BR VIA PRESET ADDR         38000000
         LA    R3,K3(R3)           BUMP TO NEXT FIELD                   38100000
         BR    R5                  BR VIA PRESET ADDR                   38200000
         SPACE                                                          38300000
PBPRECOV EQU   *                                                        38400000
         LA    R3,RECOVCTR(RECPTR) SET PTR TO HARDS RECOVERED IN SUM.   38500000
         B     TESTSTG             CHECK FOR STG/CPU                    38600000
         SPACE                                                          38700000
PBPFOUND EQU   *                                                        38800000
         IC    R5,K0(R3)           GET LOST INCIDENT COUNT              38900000
         LA    R5,K1(R5)           INCREMENT BY ONE                     39000000
         STC   R5,K0(R3)           SAVE UPDATED COUNT                   39100000
         TM    RECFLAG(RECPTR),LONG+SHORT IS ANY I/O IN PROGRESS        39200000
         BZ    BUILDREC            NO                                   39300000
         OI    RECFLAG(RECPTR),CLOBBER SET EXCP OPERATION CLOBBERED     39400000
*                                                                       39500000
* THIS IS MCH RECORD FORMATE ROUTINE                                    39600000
*                                                                       39700000
*  GENERATS THE RECORD HEADER                                           39800000
*                                                                       39900000
BUILDREC EQU   *                                                        40000000
RECFRMT  EQU   *                                                        40100000
         OI    RECFLAG(RECPTR),ACTIVE    INDICATE ACTIVE BUFFER         40200000
         ST    RECPTR,MCHLONG      SAVE PTR TO LONG RECORD              40300000
         NI    K3(RECPTR),LONGS    SET LONG SWITCH IN HDR               40400000
         MVC   MCHLSUM(K6),LOSTSUM(RECPTR) MOVE LOST SUMMARY INTO       40500000
*                                  DAMAGE ASSESMENT FIELD               40600000
         MVC   MCPSW(K8,RECPTR),MCHPSA+K48 MOVE MCK OLD PSW INTO RECORD 40700000
         MVC   DASMT(K8,RECPTR),MCHDAMAG MOVE DAMAGE ASSESMENT          40800000
*                                  INTO THE RECORD                      40900000
         MVI   KEY(RECPTR),KEYC    MOVE KEY INTO THE RECORD             41000000
         MVI   RECSW(RECPTR),SWITCH  MOVE SWITCH INTO RECORD            41100000
         MVC   OSRELNO(K1,RECPTR),MCHRELNO MOVE IN OS RELEASE NO.       41200000
         DC    X'B202'             USE DIAGNOSTIC INSTRUCTION TO GET    41300000
         DC    S(CTIME)            MODEL AND SERIAL NO                  41400000
         MVC   CPUID(K8,RECPTR),CTIME MOVE INTO THE RECORD              41500000
*                                                                       41600000
***  THIS ROUTINE GENERATES DATE AND TIME FOR THE RECORD                41700000
*                                                                       41800000
         TM    MCHDAMAG+K1,CLOCKERR HAS THERE BEEN A MACHINE CHECK DUE  41900000
*                                  TO CLOCK                             42000000
         BO    NOSTORE             YES, DO NOT STORE CLOCK              42100000
         DC    X'B205'             NO,STORE CLOCK TO GET                42200000
         DC    S(CTIME)            DATE AND TIME                        42300000
         BC    K3,NOSTORE          STORE CLOCK DID NOT WORK       21961 42400000
         MVC   DATE(K8,RECPTR),CTIME MOVE DATE AND TIME INTO RECORD     42500000
         B     SKIPTIME            GO GENERATE JOB ID                   42600000
NOSTORE  EQU   *                                                        42700000
         XC    DATE(K8,RECPTR),DATE(RECPTR) CLEAR DATE AND TIME         42800000
*                                  FIELD OF RECORD                      42900000
*                                                                       43000000
***  GENERATE JOB ID                                                    43100000
*                                                                       43200000
*                                                                       43300000
SKIPTIME EQU   *                                                        43400000
         XC    PGMID(K16,RECPTR),PGMID(RECPTR) CLEAR JOB AND PROG ID    43500000
         SR    RPRB,RPRB           CLEAR REG                            43600000
         L     RCNTTCB,CVTTCBP     PTR FOR OLD AND NEW TCB              43700000
         L     RCNTTCB,CNTTCB(RCNTTCB)  ACTIVE TCB ADDRESS              43800000
         L     RRB,TCBRBP(RCNTTCB) CURRENT RB ADDR                      43900000
         CR    RRB,RCNTTCB         Q. DUMMY TCB                         44000000
         BE    RECMCI              BRANCH IF YES                        44100000
         L     R5,TCBTIO(RCNTTCB)   TIOT ADDRESS                        44200000
         LTR   R5,R5               Q. TIOT VALID                        44300000
         BZ    BYPASS              NO THERE IS NO TIOT                  44400000
         MVC   JOBID(K8,RECPTR),TIOJOBID(R5) MOVE JOB ID IN RECORD      44500000
*                                                                       44600000
*****  GENERATE PROGRAM ID                                              44700000
BYPASS   EQU   *                                                        44800000
         TM    X1D(RCNTTCB),XC0    TASK TERMINATING            @S66087P 44830021
         BNZ   RECMCI              YES SKIP RB SEARCH          @S66087P 44860021
PRBTEST  TM    RBSTAB(RRB),PRBMASK Q. IS PRB                            44900000
         BNZ   MORERB              BRANCH IF NO                         45000000
         LR    RPRB,RRB            SAVE PRB ADDRESS IF YES              45100000
MORERB   EQU   *                                                        45200000
         TM    RBSTAB+K1(RRB),RBTCBNXT  IS THIS RB POINTING TO TCB      45300000
         BO    RBEND               BRANCH IF YES                        45400000
         L     RRB,RBLINK(RRB)     GET NEXT RB ADDRESS                  45500000
         B     PRBTEST             GO TO TEST IF IT IS A PRB            45600000
RBEND    EQU   *                                                        45700000
         LTR   RPRB,RPRB           IS THERE A PRB                       45800000
         BZ    RECMCI              BRANCH IF NO PRB                     45900000
         TM    CVTDCB,MVTMASK      Q. IS MVT SYSTEM                     46000000
         BO    MVTPGMID            BRANCH IF YES                        46100000
         MVC   PGMID(K8,RECPTR),XRBNM(RPRB) MOVE PGM ID IN RECORD       46200000
         B     RECMCI              BRANCH                               46300000
MVTPGMID EQU   *                                                        46400000
         L     RWORK3,RBCDE(RPRB)  GET CDE ADDRESS                      46500000
         MVC   PGMID(K8,RECPTR),CDENM(RWORK3) MOVE PGM ID IN RECORD     46600000
RECMCI   EQU   *                                                        46700000
         MVC   MCICODE(K8,RECPTR),INTPCODE(R9) MOVE MCICODE INTO RECORD 46800000
         TM    MCHDAMAG,TERMIN     TERMINATION OF SYSTEM NEEDED         46900000
         BO    SYSDOWN             BRANCH IF YES                        47000000
*                                                                       47100000
* THIS ROUTINE WILL RESTART CHANNELS IF NEEDED.                         47200000
*                                                                       47300000
         TM    MCHINTEL+K1,X80     ANY MODULE LOADED                    47400000
         BZ    POST                BRANCH TO POST TRN INTERFACE IF NO   47500000
         ST    COMBASE,R11SAVE     SAVE COMMON AREA BASE                47700000
         STM   R0,R15,MCHMLSAV     SAVE REGS                            47800000
         L     R15,MCHIOENT        LOAD ENTRY TO EXCP                   47900000
         CNOP  K2,K4               PUT INSTRUCT ON HALF WORD  IC  40762 47950021
         BALR  R14,R15             BRANCH TO IOS                        48000000
         USING *,R14               SET TEMP BASE                        48100000
         DC    X'80000000'         INTERFACE WORD FOR IOS,REQUESTS IOS  48130021
*                                  TO DEQUEUE MCH RQE         IC  40762 48160021
         L     COMBASE,R11SAVE     RESTORE MCH COMMON AREA BASE         48200000
         LM    R0,R15,MCHMLSAV     RESTORE ALL REGS                     48300000
         DROP  R14                 DROP TEMP BASE                       48400000
*                                                                       48500000
*  THIS ROUTINE INTERFACES WITH POST ROUTINE                            48600000
*                                                                       48700000
POST     EQU   *                                                        48800000
         STM   R0,R15,MCHMLSAV     SAVE REGS                            48900000
         L     R3,MCHPSTAD         ADDR OF POST INTERFACE ROUTINE       49000000
         BALR  R2,R3               GO TO POST INTERFACE ROUTINE         49100000
*                                                                       49200000
*****    THIS ROUTINE RESTORE SYSTEM STATUS AND TERMINATES MACHINE      49300000
*        CHECK HANDLER                                                  49400000
*                                                                       49500000
EXIT     EQU   *                                                        49600000
         LM    R0,R15,MCHMLSAV     RESTORE REGS                         49700000
         TM    MCHPSA+K48,XFE      Q. WAS I/O DISABLED WHEN MCI         49800000
         BZ    RETPGM              YES,RETRN TO INTRUPTD PRGM IC  40412 49820021
         L     R2,MCHNEST          GET ADDR OF MCHNEST SWITCH IC  40412 49840021
         TM    K1(R2),XF0          Q.WAS IOS IN CONTROL       IC  40412 49860021
         BZ    RSYSTM              NO,SYS RETRN-YES,IOS RETRN IC  40412 49880021
         TM    MCHDAMAG,XC0        Q.ERROR RECOVERED          IC  40412 49900021
         BNZ   RETPGM              YES,IOS CAN GET CNTRL BACK IC  40412 49920021
         NI    K1(R2),X0F          TURN OFF IOS NEST SWITCH   IC  40412 49940021
         B     RSYSTM              EXIT TO THE SYSTEM         IC  40412 49960021
RETPGM   EQU   *                   PROGRAM RETURN ENTRY       IC  40412 49980021
         LA    R8,K120(R9)         SET UP POINTER IN FIXED LOG          50000000
         BAL   R2,RESTORE          BRANCH AND LINK                      50100000
         LM    R0,R15,K152(R9)     RESTORE REGS FROM FIXED LOGOUT       50200000
         LPSW  MCKOPSW             RETURN TO INTERRUPTED PGM            50300000
*                                                                       50400000
* THIS ROUTINE RETURNS CONTROL TO DISPATCHER                            50500000
*                                                                       50600000
RSYSTM   EQU   *                                                        50700000
         L     R2,CVTTCBP          TCB POINTER                          50800000
         LM    R6,R7,K0(R2)        NEW - OLD TCB                        50900000
MFTSYS   MVC   TCBGRS(K24,R7),K192(R9) RESTORE GPR 10-15 IN OLD TCB     51200000
         MVC   K72(K40,R7),K152(R9) RESTORE GPR 0-9 IN OLD TCB          51300000
         TM    X1F(R7),X08         DO FPRS EXIST IN THIS TCB  IG  51236 51350021
         BNO   NTO1                DO NOT RESTORE THEM        IG  51236 51360021
NTO      EQU   *                                                        51400000
         LR    R8,R7               GET FLOATING REG                     51500000
         SH    R8,D32              SAVE AREA                            51600000
         MVC   K0(K32,R8),K120(R9) SAVE FLOATING REGS IN OLD TCB        51700000
NTO1     EQU   *                                              IG  51236 51750021
         L     R5,TCBRBP(R7)       GET ADDR OF RB IN OLD TCB            51800000
         MVC   RBOPSW(K8,R5),MCHRPSW  RESUME PSW IN RB                  51900000
         MVC   MCHPSA+K48(K5),DISPATCH SET UP                           52000000
         MVC   MCHPSA+K53(K3),CVT0DS+K1 DISPATCHER ADDRESS              52100000
* GET HIGHEST PRIORITY READY TCB SET UP                                 52500000
         BAL   R2,RESTORE          BRANCH AND LINK                      52800000
         LM    R10,R9,TCBGRS(R7)   RESTORE REGS FOR MFT                 53100000
         LPSW  MCKOPSW             RETURN TO DISPATCHER                 53200000
MVTSYS1  EQU   *                                                        53300000
         LM    R0,R15,TCBGRS(R7)   RESTORE REGS                         53400000
         LPSW  MCKOPSW             RETURN TO DISPATCHER                 53500000
RESTORE  EQU   *                                                        53900000
         TM    X1F(R7),X08         DO FPRS EXIST ON THIS MACHINE 51236  53910021
         BNO   RESTORE1            NO,DO NOT RESTORE THEM     IG  51236 53920021
         LR    R8,R7               GET FLOATING REG           IG  50272 53950021
         SH    R8,D32              SAVE AREA                  IG  50272 53960021
         LD    FR0,K0(R8)          * RESTORE                            54000000
         LD    FR2,K8(R8)          * FLOATING                           54100000
         LD    FR4,K16(R8)         * POINT                              54200000
         LD    FR6,K24(R8)         * REGISTERS                          54300000
RESTORE1 EQU   *                                              IG  51236 54350021
         LA    R3,DISABLE1         GET ADDRESS FOR LPSW           42810 54420000
         ST    R3,DISABLE+K4       STORE ADDRESS IN PSW           42810 54440000
         LPSW  DISABLE             DISABLE FOR MACHINE CHECKS     42810 54460000
DISABLE1 EQU   *                                                  42810 54480000
         DC    X'B70F90D8'         RESTORE CONTROL REGISTERS            54500000
         MVC   K0(K128),MCHPSA     RESTORE PERMANENT STORAGE ASSIGNMENT 54800000
         BR    R2                  RETURN                               54900000
SYSDOWN  EQU   *                                                        55000000
         OI    K3(RECPTR),TERMS    SET TERMINATION SWITCH               55100000
SYSDOWNY EQU   *                                                        55200000
         MVI   MCHNXMOD,EMERECDR   SET IGFMCHE3 AS SUCCESSOR            55300000
         BR    R14                 RETURN TO NUCLEUS                    55400000
         DS    0D                                                       55500000
DISABLE  DC    D'0'                DISABLE PSW                    42810 55550000
R11SAVE  DC    F'0'                SAVE AREA FOR REG 11                 55600000
D32      DC    H'32'               CONSTANT                             55700000
DISPATCH DC    X'0004FF0000'       FIRST FIVE BYTE OF DISPATCHER PSW    55800000
MAINTID  DC    CL8'IGFMCH50'       CORE IDENTIFICATION                  55850000
MAINT    DC    S(*)                MODULE DISPLACEMENT                  55900000
         DC    15CL4'&REL&LEV'     ADDITIONAL SPACE                     55950000
         EJECT                                                          56000000
*                                                                       56100000
*   THIS IS THE MACRO FOR MCH COMMOM AREA                               56200000
*                                                                       56300000
MCHCOMMN DSECT                                                          56400000
         MCHMAC                                                         56500000
CTIME    EQU   MCHMLSAV+4          WORKAREA                             56600000
         EJECT                                                          56700000
CVTSECT  DSECT                                                          56800000
         CVT                                                            56900000
         EJECT                                                          57000000
MSB553   DSECT                                                          57100000
         RMSMSB MOD=53                                                  57200000
         END                                                            57300000
