         LCLA  &LEV,&REL                                                22860021
&LEV     SETA  50                                                       22870021
&REL     SETA  21                                                       22880021
&REL&LEV TITLE 'IGFMCHE0 LEVEL &LEV MCH NUCLEUS'                        22890021
IGFMCHE0 CSECT                                                          22900020
         ENTRY IGFN0000                                                 22950020
         ENTRY IGFPOST1,IGFPOST2                                        23000020
* MODULE NAME...                                                        23050020
*       IGFMCHE0                                                        23100020
*                                                                       23150020
* STATUS -                                                              23160020
*         LEVEL FOR 20.1-IGFMCHE0 - 01      3/15/71                     23170021
*         LEVEL FOR 370 -IGFMCHE0 - 20      8/03/71                     23180021
*         LEVEL FOR 21.7-IGFMCHE0 - 40      3/14/73                     23190021
*            LEVEL FOR 21.8 - IGFMCHE0 - 50    3/1/74          @S68598P 23195021
*                                                                       23200020
* FUNCTIONS...                                                          23250020
*       THE MCH NUCLEUS SERVES AS THE CONTROL PROGRAM FOR THE TOTAL     23300020
*       MCH OPERATION. ITS MAJOR FUNCTIONS ARE..                        23350020
*       1. TO RECEIVE CONTROL VIA MACHINE CHECK NEW PSW                 23400020
*       2. TO DETERMINE THE VALIDITY OF HARDWARE INPUT                  23450020
*       3. TO DETERMINE TYPE OF ENTRY--NORMAL MCI,MCI IN CCH,MCI IN IOS 23500020
*       4. TO DETERMINE WHETHER ERROR IS HARD OR SOFT                   23550020
*       5. TO SAVE INITIAL CPU OR IO ENVIRONMENT UPON ENTRY             23600020
*       6. TO PERFORM GENERAL INITIALIZATION FOR MCH                    23650020
*       7. TO LOAD THE MCH MODULES AND REFRESH MODULES VIA THE MODULE   23700020
*          LOADER CLOSED SUBROUTINE                                     23750020
*       8. TO HANDLE UNEXPECTED INTERRUPTS DURING MCH PROCESSING VIA    23800020
*          ERROR ON ERROR HANDLER (ENTRY POINT IGFERR0)                 23850020
*       9. TO RECOGNIZE AND IGNORE MONITOR CALL INTERRUPTS IN RMS  GTF  23870000
*                                                                       23900020
*                                                                       23950020
* ATTRIBUTES...                                                         24000020
*       PERMANENTLY RESIDENT,SERIALLY REUSABLE,OPERATES IN SUPERVISOR   24050020
*       MODE AND USES PRIVILEGED INSTRUCTIONS                           24100020
*                                                                       24150020
*                                                                       24200020
* ENTRY POINTS...                                                       24250020
*       IGFN000--ENTERED VIA MCK NEW PSW. THE ADDRESS OF THIS LABEL IS  24300020
*                CONTAINED IN THE MCK NEW PSW                           24350020
*                                                                       24400020
*       IGFERR0--ENTERED VIA MCK NEW PSW WHEN A HARD ERROR OCCURS       24450020
*                DURING MCH PROCESSING. THE ADDRESS OF THIS LABEL IS    24500020
*                PLACED IN THE MCK NEW PSW AT THE START OF MCH PROC.    24550020
*                                                                       24600020
*                                                                       24650020
* EXITS...                                                              24700020
*       THE MCH NUCLEUS HAS THE FOLLOWING EXITS...                      24750020
*       EXIT TO DISABLED WAIT STATE...                                  24800020
*       1. WHEN AN ERROR OCCURS IN CRITICAL IOS CODE REPEATEDLY         24850020
*       2. WHEN A HARD ERROR OCCURS DURING HARD ERROR PROCESSING AND    24900020
*          THE FIRST ERROR WAS A SYSTEM TASK AND THE SECOND ERROR       24950020
*          OCCURRED IN IOS                                              25000020
*       3. SAME AS 2 BUT THE SECOND ERROR OCCURED SOMEWHERE OTHER THAN  25050020
*          IOS OR MCH CODE                                              25100020
*       EXIT TO SYSTEM...                                               25150020
*       1. WHEN  HARD ERROR OCCURS DURING THE PROCESSING OF A HARD      25200020
*          ERROR (ALL CASES NOT OUTLINED ABOVE)                         25250020
*       2. WHEN IO RETRIES HAVE FAILED DURING MODULE LOADING            25300020
*       3. WHEN MCH WAS NOT SUCCESSFULLY INITIALIZED BY NIP             25350020
*       4. WHEN THE ERROR CAUSING THE MCI WAS IN CRITICAL IOS CODE      25400020
*       EXIT TO LOADED MODULES...                                       25450020
*          AFTER EACH MCH MODULE IS SUCCESSFULLY LOADED,MCH NUCLEUS     25500020
*          GIVES CONTROL TO THAT MODULE AT THE BEGINNING OF             25550020
*          THAT MODULE                                                  25600020
*                                                                       25650020
*                                                                       25700020
* INPUT...                                                              25750020
*       THE INPUT TO MCH IS CLASSIFIED BY THE FOLLOWING                 25800020
*       CATEGORIES...                                                   25850020
*       1. ENVIRONMENT--HARDWARE GENERATED...                           25900020
*         A.  GENERAL PURPOSE REGISTERS                                 25950020
*         B.  FLOATING POINT REGISTERS                                  26000020
*         C.  CONTENTS OF LOW CORE LOCATIONS (0-128 DECIMAL)            26050020
*       2. STATUS--HARDWARE GENERATED...                                26100020
*         A.  INSTRUCTION RETRY COUNTER                                 26150020
*         B.  ERROR CORRECTION CODE COUNTER                             26200020
*         C.  MODEL DEPENDENT STATUS LOGOUT                             26250020
*         D.  MODEL INDEPENDENT INTERRUPT STATUS (BEGINS AT LOC 128 D)  26300020
*       3. SOFTWARE GENERATED...                                        26350020
*             THIS INPUT CONSISTS OF ANY PARAMETERS OR STATUS GENERATED 26400020
*             BY AN MCH MODULE AND USED AND INTERROGATED BY THE NUCLEUS 26450020
*             TO MAKE LOGICAL DECISIONS ABOUT FURTHER MCH OPERATION.    26500020
*             THE SOFTWARE GENERATED INPUT IS AS FOLLOWS...             26550020
*                                                                       26600020
*             A.  TTR'S OF TRANS MODULES AND LOGOUT LOCATION            26650020
*                SUPPLIED BY NIP                                        26700020
*             B. SUCCESSOR MODULE'S TTR IS SUPPLIED BY EACH             26750020
*                LOADED MODULE AT ITS COMPLETION                        26800020
*                                                                       26850020
*                                                                       26900020
* OUTPUT...                                                             26950020
*       TO ALL MCH MODULES...                                           27000020
*       1. BASE REG IN GPR15--ENTRY POINT ADDRESS                       27050020
*       2. RETURN ADDRESS TO NUCLEUS IN GPR14                           27100020
*       3. SAVE AREA ADDRESS IN GPR13                                   27150020
*       4. NUCLEUS BASE IN GPR12                                        27200020
*       5. COMMON AREA ADDRESS IN GPR11                                 27250020
*                                                                       27300020
*       TO MCH MODULE LOADER SUBROUTINE...                              27350020
*       1. RETURN ADDRESS IN GPR14                                      27400020
*       2. TTR OF MODULE TO BE LOADED-IN COMMON AREA                    27450020
*       3. LIBRARY TYPE FLAG-IN COMMON AREA                             27500020
*                                                                       27550020
*                                                                       27600020
*                                                                       27650020
*                                                                       27700020
* ERROR CONDITIONS...                                                   27750020
*       REFER TO EXITS                                                  27800020
*                                                                       27850020
*                                                                       27900020
* TABLES AND WORK AREAS...                                              27950020
*       MCH COMMUNICATIONS AREA                                         28000020
*       HARDWARE LOGOUT AREA                                            28050020
*                                                                       28100020
*                                                                       28150020
* RESTRICTIONS/CONVENTIONS...                                           28200020
*       1. MCH PGM AND ITS CORE MAY NOT BE USED BY OS/360 OR ANY        28250020
*          PROBLEM PROGRAM                                              28300020
*       2. MCH SUPPORTS                                                 28350020
*         A.  MFT                                                       28400020
*         B.  MVT                                                       28450020
*                                                                       28500020
*  NOTES     MAINTENANCE AREA OF 50 BYTES IS LOCATED AT LABEL MAINT     28510020
         EJECT                                                          28550020
*                                                                       28600020
*****     EQUATES USED BY THE MCH NUCLEUS     *****                     28650020
*                                                                       28700020
LEVEL    EQU   X'&LEV'             MODULE LEVEL                         28710021
K8       EQU   8                   DECIMAL CONSTANT                     28750020
K56      EQU   56                  DECIMAL CONSTANT                     28800020
K40      EQU   40                  DECIMAL CONSTANT                     28850020
K256     EQU   256                 DECIMAL CONSTANT                     28900020
R0       EQU   0                   REGISTER                             28950020
R1       EQU   1                   REGISTER                             29000020
R2       EQU   2                   REGISTER                             29050020
R4       EQU   4                   REGISTER                             29100020
R5       EQU   5                   REGISTER                             29150020
R7       EQU   7                   REGISTER                             29200020
R14      EQU   14                  REGISTER                             29250020
R15      EQU   15                  REGISTER                             29300020
REG0     EQU   0                   REGISTER                             29350020
REG1     EQU   1                   REGISTER                             29400020
REG2     EQU   2                   REGISTER                             29450020
REG3     EQU   3                   REGISTER                             29500020
REG4     EQU   4                   REGISTER                             29550020
REG5     EQU   5                   REGISTER                             29600020
R6       EQU   6                   REGISTER                             29650020
REG6     EQU   6                   REGISTER                             29700020
REG7     EQU   7                   REGISTER                             29750020
REG8     EQU   8                   REGISTER                             29800020
REG9     EQU   9                   REGISTER                             29850020
REG10    EQU   10                  REGISTER                             29900020
REG11    EQU   11                  REGISTER                             29950020
REG12    EQU   12                  REGISTER                             30000020
REG13    EQU   13                  REGISTER                             30050020
REG14    EQU   14                  REGISTER                             30100020
REG15    EQU   15                  REGISTER                             30150020
WKR2     EQU   2                   REGISTER 2                           30154000
WKR3     EQU   3                   REGISTER 3                           30158000
X1       EQU   1                   HEXADECIMAL CONSTANT                 30162000
X2       EQU   2                   HEXADECIMAL CONSTANT                 30166000
X3       EQU   3                   HEXADECIMAL CONSTANT                 30170000
X4       EQU   4                   HEXADECIMAL CONSTANT                 30174000
X5       EQU   5                   HEXADECIMAL CONSTANT                 30178000
PGMOPSW  EQU   X'28'                                                    30182000
PCMONCAL EQU   X'AF'               MONITOR CALL AF                GTF   30186000
XC0      EQU  X'C0'                                                     30190000
PCBRANCH EQU   X'47'               BRANCH OP CODE                 GTF   30194000
ACTPOST  EQU   X'40'               INDICATES POST RTN IN PROCESS        30200020
ADDR1    EQU   10                  REGISTER FOR POST                    30250020
ADDR2    EQU   11                  REGISTER FOR POST                    30300020
CS       EQU   C'S'                CHARACTER S FOR WAIT MESSAGE         30350020
CVTBASE  EQU   10                  CVT BASE REGISTER                    30400020
COMBASE  EQU   11                  COMMON AREA BASE REG                 30450020
EQUAL    EQU   8                   CONSTANT FOR BC INSTR                30500020
IONPSW   EQU   X'78'               IO NEW PSW ADDRESS                   30550020
NCAW     EQU   72                  ABSOLUTE ADDR OF CAW                 30600020
NCNTLREG EQU   448                 ABSOLUTE ADDR OF CR SAVE             30650020
NUCBASE  EQU   12                  IGFMCHE0 BASE REGISTER               30700020
MCKNPSW  EQU   112                 ABSOLUTE ADDR OF MCK NEW PSW         30750020
MCKOPSW  EQU   48                  ABSOLUTE ADDR OF MCK OLD PSW         30800020
NMCIC    EQU   232                 ABS ADDR OF MACH CHK INT CODE        30850020
NPGMNPSW EQU   104                 ABSOLUTE ADDR OF PGM CHK NEW PSW     30900020
NINREGSV EQU   152                 ABSOLUTE ADDR OF GPR'S IN IND LOG    30950020
NREGINCD EQU   252                 ABSOLUTE ADDR OF REGION CODE         31000020
OPGMPSW  EQU   X'28'               ABSOLUTE ADDR OF PGM CHK OLD PSW     31050020
READREC  EQU   X'06'               CCW COMMAND CODE                     31100020
SRCHID   EQU   X'31'               CCW SEARCH ID                        31150020
TIC      EQU   X'08'               TIC COMMAND CODE                     31200020
TIMER    EQU   80                  ABSOLUTE ADDR OF HARDWARE TIMER      31250020
UCBRGG   EQU   2                   UCB BASE REGISTER                    31300020
SOFT     EQU   X'A0'               MASK TO TEST SOFT ERROR              31350020
UCBBSY   EQU   X'80'               UCB BUSY FLAG                        31400020
ACTIVE   EQU   X'10'               CONSOLE ACTIVE FLAG         @S64611P 31420021
HARDCY   EQU   X'40'               CONSOLE HARDCOPY            @S64611P 31440021
SYSLOG   EQU   X'02'               CONSOLE IS SYSLOG           @S64611P 31460021
XF       EQU   15                ICM MASK                      @S64611P 31480021
         EJECT                                                          31500020
*****     DECIMAL NUMBER EQUATES     *****                              31550020
K1       EQU   1                   DECIMAL CONSTANT                     31600020
K48      EQU   48                  DECIMAL CONSTANT                     31650020
N0       EQU   0                   DECIMAL CONSTANT                     31700020
N1       EQU   1                   DECIMAL CONSTANT                     31750020
N2       EQU   2                   DECIMAL CONSTANT                     31800020
N3       EQU   3                   DECIMAL CONSTANT                     31850020
N4       EQU   4                   DECIMAL CONSTANT                     31900020
N5       EQU   5                   DECIMAL CONSTANT                     31950020
N6       EQU   6                   DECIMAL CONSTANT                     32000020
N7       EQU   7                   DECIMAL CONSTANT                     32050020
N8       EQU   8                   DECIMAL CONSTANT                     32100020
N9       EQU   9                   DECIMAL CONSTANT                     32150020
N10      EQU   10                  DECIMAL CONSTANT                     32200020
N11      EQU   11                  DECIMAL CONSTANT                     32250020
N12      EQU   12                  DECIMAL CONSTANT                     32300020
N13      EQU   13                  DECIMAL CONSTANT               20302 32310020
N16      EQU   16                  DECIMAL CONSTANT                     32350020
N19      EQU   19                  DECIMAL CONSTANT                     32400020
N20      EQU   20                  DECIMAL CONSTANT                     32450020
N21      EQU   21                  DECIMAL CONSTANT                     32500020
N22      EQU   22                  DECIMAL CONSTANT               20302 32510020
N23      EQU   23                  DECIMAL CONSTANT                     32550020
N24      EQU   24                  DECIMAL CONSTANT                     32600020
N25      EQU   25                  DECIMAL CONSTANT                     32650020
N28      EQU   28                  DECIMAL CONSTANT                     32700020
N30      EQU   30                  DECIMAL CONSTANT                     32750020
N32      EQU   32                  DECIMAL CONSTANT                     32800020
N33      EQU   33                  DECIMAL CONSTANT                     32850020
N50      EQU   50                  DECIMAL CONSTANT                     32900020
N56      EQU   56                  DECIMAL CONSTANT                     32950020
N108     EQU   108                 DECIMAL CONSTANT                     33000020
N115     EQU   115                 DECIMAL CONSTANT                     33050020
N128     EQU   128                 DECIMAL CONSTANT                     33100020
N144     EQU   144                 DECIMAL CONSTANT                     33150020
N148     EQU   148                 DECIMAL CONSTANT                     33200020
N232     EQU   232                 DECIMAL CONSTANT                     33250020
N256     EQU   256                 DECIMAL CONSTANT                     33300020
N272      EQU   272              DECIMAL CONSTANT                   PWF 33320021
N488     EQU   488                 DECIMAL CONSTANT                     33350020
N1024    EQU   1024                DECIMAL CONSTANT                     33400020
PCUNEQ   EQU   7                   NOT EQUAL (AFTER COMPARE)            33420000
         EJECT                                                          33450020
*****     HEXADECIMAL EQUATES     *****                                 33500020
X00      EQU   X'00'               HEXADECIMAL CONSTANT                 33550020
X01      EQU   X'01'               HEXADECIMAL CONSTANT                 33600020
X02      EQU   X'02'               HEXADECIMAL CONSTANT                 33650020
X03      EQU   X'03'               HEXADECIMAL CONSTANT                 33700020
X04      EQU   X'04'               HEXADECIMAL CONSTANT                 33750020
X05      EQU   X'05'               HEXADECIMAL CONSTANT                 33800020
X08      EQU   X'08'               HEXADECIMAL CONSTANT                 33850020
X0B      EQU   X'0B'               HEXADECIMAL CONSTANT                 33900020
X0E      EQU   X'0E'               HEXADECIMAL CONSTANT                 33950020
X0F      EQU   X'0F'               HEXADECIMAL CONSTANT                 34000020
X10      EQU   X'10'               HEXADECIMAL CONSTANT                 34050020
X13      EQU   X'13'               HEXADECIMAL CONSTANT                 34100020
X14      EQU   X'14'               HEXADECIMAL CONSTANT                 34150020
X18      EQU   X'18'               HEXADECIMAL CONSTANT                 34200020
X1F      EQU   X'1F'               HEXADECIMAL CONSTANT                 34250020
X20      EQU   X'20'               HEXADECIMAL CONSTANT                 34300020
X21      EQU   X'21'               HEXADECIMAL CONSTANT                 34350020
X38      EQU   X'38'               HEXIDECIMAL CONSTANT       IC  55625 34352021
X40      EQU   X'40'               HEXADECIMAL CONSTANT                 34400020
X41      EQU   X'41'               HEXADECIMAL CONSTANT                 34450020
X44      EQU   X'44'               HEXADECIMAL CONSTANT                 34500020
X5C      EQU   X'5C'               HEXADECIMAL CONSTANT                 34550020
X60      EQU   X'60'               HEXADECIMAL CONSTANT                 34600020
X70      EQU   X'70'               HEXADECIMAL CONSTANT                 34620021
X7F      EQU   X'7F'               HEXADECIMAL CONSTANT                 34700020
X80      EQU   X'80'               HEXADECIMAL CONSTANT                 34750020
X90      EQU   X'90'               HEXADECIMAL CONSTANT                 34800020
XA0      EQU   X'A0'               HEXADECIMAL CONSTANT                 34850020
XDF      EQU   X'DF'               HEXADECIMAL CONSTANT           40762 34860021
XE0      EQU   X'E0'               HEXADECIMAL CONSTANT                 34900021
XF0      EQU   X'F0'               HEXADECIMAL CONSTANT                 34950020
XFD      EQU   X'FD'               HEXADECIMAL CONSTANT                 35000020
XFE      EQU   X'FE'               HEXADECIMAL CONSTANT                 35050020
XFF      EQU   X'FF'               HEXADECIMAL CONSTANT                 35100020
X319     EQU   X'319'              HEXADECIMAL CONSTANT                 35150020
X800     EQU   X'800'              HEXADECIMAL CONSTANT                 35200020
XA02     EQU   X'A02'              HEXADECIMAL CONSTANT                 35250020
XC04     EQU   X'C04'              HEXADECIMAL CONSTANT                 35300020
         EJECT                                                          35350020
*****     DECIMAL EQUATES FOR RELOCATOR     *****                       35400020
K0       EQU   0                   DECIMAL CONSTANT                     35450020
K16      EQU   16                  DECIMAL CONSTANT                     35500020
K19      EQU   19                  DECIMAL CONSTANT                     35550020
K2       EQU   2                   DECIMAL CONSTANT                     35600020
K24      EQU   24                  DECIMAL CONSTANT                     35650020
K28      EQU   28                  DECIMAL CONSTANT                     35700020
K3       EQU   3                   DECIMAL CONSTANT                     35750020
K32      EQU   32                  DECIMAL CONSTANT                     35800020
K35      EQU   35                  DECIMAL CONSTANT                     35850020
K38      EQU   38                  DECIMAL CONSTANT                     35900020
K39      EQU   39                  DECIMAL CONSTANT                     35950020
K4       EQU   4                   DECIMAL CONSTANT                     36000020
K5       EQU   5                   DECIMAL CONSTANT                     36050020
K44      EQU   44                  DECIMAL CONSTANT                     36100020
K36      EQU   36                  DECIMAL CONSTANT                     36150020
K68      EQU   68                  DECIMAL CONSTANT                     36200020
         EJECT                                                          36250020
***   RELOCATOR--USED TO RELOCATE NUCLEUS AT NIP TIME                   36300020
         USING *,R15                                                    36350020
         L     R6,LIMITS           GET ADDRESS OF START OF CODE         36400020
         SR    R6,R0               COMPUTE DIFFERENCE                   36450020
         LA    R2,IGFIORTN         ***********************************  36500020
         SR    R2,R6               *                                    36550020
         ST    R2,K24(R1)          *                                    36600020
         LA    R2,IGFLOAD          *                                    36650020
         SR    R2,R6               *                                    36700020
         ST    R2,K28(R1)          *                                    36750020
         LA    R2,IGFPOST1         *                                    36800020
         SR    R2,R6               *                                    36850020
         ST    R2,K32(R1)          *                                    36900020
         LA    R2,NCOMADDR         *                                    36950020
         SR    R2,R6               * THIS CODE SETS UP THE              37000020
         ST    R2,K40(R1)          * RELOCATION TABLE FOR ALL           37050020
         LA    R2,NMODBASE         * THE ADCONS IN THE MCH NUCLEUS      37100020
         SR    R2,R6               *                                    37150020
         ST    R2,K36(R1)          *                                    37200020
         LA    R2,IGFCINT          *                                    37250020
         SR    R2,R6               *                                    37300020
         ST    R2,K48(R1)          *                                    37350020
         LA    R2,PARMLIST-K4      *                                    37400020
         SR    R2,R6               *                                    37450020
         ST    R2,K56(R1)          *                                    37500020
         LA    R2,IGFPOST2         *                                    37550020
         SR    R2,R6               *                                    37600020
         ST    R2,K68(R1)          ***********************************  37650020
         EJECT                                                          37700020
         LR    R1,R0               COPY REG                             37750020
         LA    R7,LIST             GET PTR TO LIST OD PTRS FOR UPDATING 37800020
UPDAT    EQU   *                                                        37850020
         CLI   K0(R7),XFF          IS THIS END OF THE TABLE             37900020
         BE     QUIT               YES                                  37950020
         L     R4,K0(R7)           GET PTR TO ADCON                     38000020
         L     R2,K0(R4)           GET ACTUAL ADDRESS                   38050020
         SR    R2,R6               ADJUST FOR RELOCATION                38100020
         ST    R2,K0(R4)           SOTRE BACK UPDATED VALUE             38150020
         LA    R7,K4(R7)           BUMP TO NEXT ADCON                   38200020
         B     UPDAT               CONTINUE                             38250020
QUIT     EQU   *                                                        38300020
         LM    R4,R5,LIMITS        GET PTRS TO BEGINNING AND            38350020
*                                  ENDING OF CODE TO BE RELOCATED.      38400020
*  ASSUME GPR0 CONTAINS A PTR TO THE SPOT IN THE OS NUCLEUS WHERE    *  38450020
* NIP WANTS THIS RELOCATOR TO PUT  THE MCH NUCLEUS CODE.             *  38500020
         SR    R5,R4               COMPUTE SIZE                         38550020
         LR    R7,R0               COPY REG                             38600020
         AR    R0,R5               COMPUTE NEW BOUND OF OS NUC          38650020
         SRL   R5,K8               DIVIDE BY 256                        38700020
         LA    R5,K1(R5)           ADD ONE FOR ANY REMAINING CODE       38750020
RELOCATE EQU   *                                                        38800020
         MVC   K0(K256,R7),K0(R4)  RELOCATE 256 BYTES OF PROG.          38850020
         LA    R4,K256(R4)         BUMP TO NEXT BLOCK                   38900020
         LA    R7,K256(R7)         BUMP TO NEXT BLOCK                   38950020
         BCT   R5,RELOCATE         CONTINUE UNTIL ALL RELOCATED         39000020
         BR    R14                 RETURN TO NIP                        39050020
         EJECT                                                          39100020
*****  ADCON TABLE FOR RELOCATABLE ADDRS IN NUCLEUS  *****              39150020
LIMITS   DC    A(IGFSTART)         ADCON FOR RELOCATION                 39200020
         DC    V(ICFEND)           END OF ICFBDE00                  PWF 39250021
LIST     DC    A(IECISPSW+4)       ADCON FOR RELOCATION                 39300020
         DC    A(IECISDIS+4)       ADCON FOR RELOCATION                 39350020
         DC    A(APNTBL)           ADCON FOR RELOCATION                 39400020
         DC    A(APNTBL+4)         ADCON FOR RELOCATION                 39450020
         DC    A(APNTBL+8)         ADCON FOR RELOCATION                 39500020
         DC    A(APNTBL+12)        ADCON FOR RELOCATION                 39550020
         DC    A(APNTBL+16)        ADCON FOR RELOCATION                 39600020
         DC    A(CCWLOAD+8)        ADCON FOR RELOCATION                 39650020
         DC    A(ENBLPSW+4)        ADCON FOR RELOCATION                 39700020
         DC    A(NUNEXPSW+4)       ADCON FOR RELOCATION                 39750020
         DC    A(NXITENAB+4)       ADCON FOR RELOCATION                 39800020
         DC    A(NPCKPSW+4)        ADCON FOR RELOCATION           GTF   39820000
         DC    A(ICFBDEP)          ADCON FOR RELOCATION             PWF 39830021
         DC    X'FF'               END OF TABLE                         39850020
         DS    0D                                                       39900020
         EJECT                                                          39950020
IGFSTART EQU   *                                                        40000020
IGFN0000 EQU   *                                                        40050020
         USING *,NUCBASE                                                40100020
         USING NCOMAREA,COMBASE                                         40150020
         USING CVTDSECT,CVTBASE                                         40200020
         LM    REG14,REG12,N0       RESTORE GPR PARITY                  40250020
         L     NUCBASE,MCKNPSW+N4  SET GPR 12 AS MCH NUC BASE           40300020
         L     COMBASE,NCOMADDR    SET GPR 11 AS COMM AREA BASE         40350020
         DC    X'B7EE'             * DISABLE                            40400020
         DC    S(DISABLE)          * SOFT MCI                           40450020
         L     REG2,MCHINLOG       GET ADDRESS OF LOGOUT LOCATIONS      40500020
         L     REG10,X10           GET CVT START ADDR                   40550020
         MVC   N0(N256,REG2),N232  * MOVE FIXED LOGOUT *                40600020
         MVC   N256(N24,REG2),N488 *   TO SAVE AREA     *               40650020
         MVC   MCHRPSW(N8),MCKOPSW SAVE MACHINE CK OLD PSW              40700020
         MVC   MCHMLSAV(N16),NPGMNPSW    SAVE PGM + MCI NEW PSW         40750020
         MVC   MCKNPSW(N8),NUNEXPSW SET UNEX ERROR ADDR IN MCK NEW PSW  40800020
         MVC   NPGMNPSW(N8),NPCKPSW  SET PROG. CHK PTR             GTF  40850000
         LPSW  ENBLPSW             ENABLE FOR HARD ERRORS               40900020
         SPACE 4                                                        40950020
***************          CHANNEL ERROR ENTRY            *************** 41000020
NCHERTST EQU   *                                                        41050020
NENVSAVE EQU   *                                                        41100020
         MVC   MCHPSA(N128),N0     SAVE PERM STORAGE ALLOCATION         41150020
         MVC   MCHPSA+NPGMNPSW(N16),MCHMLSAV  RESTORE DGM + MCI NEW PSW 41200020
         XC    MCHDAMAG(X40),MCHDAMAG   CLEAR WORK FIELDS               41250020
         XC    MCHINTEL(N2),MCHINTEL    CLEAR FIELDS                    41350020
         MVI   MCHNXHIS,XE0        SET NUCLEUS ID IN HIST TABLE         41400020
         MVI   MCHEXLEV,LEVEL      CURRENT NUC CHANGE LEVEL TO HIST TAB 41450021
         MVC   REPDARI+N1(N3),MCHRPSW+N5 STORE IC FOR PDAR              41500020
         LA    REG4,NCCHCK         GET ADDRESS OF CCH CHECK             41550020
         CLI   MCHPSA+N115,X0F     CHAN CHECK BRANCH TO MCH RECORD OK   41600020
         BE    NCLRECOK            YES  RECORD CHANNEL RECORD           41650020
         EJECT                                                          41700020
************** ANALYSIS OF MACHINE CHECK INTERRUPT      *************** 41750020
         SPACE 2                                                        41800020
         L     REG13,N0            RESTORE GPR PARITY                   41850020
         TM    NMCIC+N1,X80        Q. WARNING INDICATED IN MCIC     PWF 41860021
         BO    WARNING             YES, BRANCH-MCIC IS VALID        PWF 41870021
         TM    NMCIC,XFD           VALID INTERRUPT CODE                 41900020
         BC    N5,ANALYSIS         YES                                  41950020
MITERM   OI    MCHDAMAG+N3,X04     SET INVALID MCIC FLAG                42000020
         B     NERCALL1            GO TO TERMINATE SYSTEM               42050020
WARNING  EQU   *                                                    PWF 42053021
         L     REG15,ICFBDEP       GET ADDR OF ICFBDE00             PWF 42056021
         SR    REG0,REG0           INDICATE ENTRY FROM MCH MAINLINE PWF 42059021
         BALR  REG14,REG15         GO TO ICFBDE00 TO ANAL. WARNING  PWF 42062021
         LTR   REG15,REG15         Q. WARNINGS TO BE DISABLED       PWF 42065021
         BNZ   ENDWARN             NO, BRANCH                       PWF 42068021
         L     REG15,MCHINLOG      GET ADDR OF SAVED LOGOUT         PWF 42071021
         NI    N272(REG15),XFE     DISABLE WARNINGS IN SAVED        PWF 42074021
*                                  COPY OF CONTROL REG 14           PWF 42077021
         B     ENDWARN             BRANCH AROUND VCON               PWF 42080021
         DS    0F                                                   PWF 42083021
ICFBDEP  DC    V(ICFBDE00)         ENTRY POINT IN ICFBDE00          PWF 42086021
ENDWARN  EQU   *                                                    PWF 42089021
ANALYSIS TM    NMCIC,X80           SYSTEM DAMAGE                        42100020
         BZ    NOSYSDAM            NO                                   42150020
         TM    MCHLOGIC,X80        MOD DEP ANALYSIS AVAILABLE           42200020
         BZ    NSYSDAM             NO,MODEL INDEPENDENT SYSTEM TERM     42250020
         MVI   MCHNXMOD,N1         SET SYSTEM DAMAGE MODULE SUCCESSOR   42300020
         BR    REG4                CHECK FOR MCI IN CCH                 42350020
         SPACE 2                                                        42400020
NOSYSDAM TM    NMCIC,X40           INSTRUCTION PROCESSING DAMAGE        42450020
         BZ    NOIPD               NO                                   42500020
         TM    NMCIC+N1,X02        BACKUP BIT ON                        42550020
         BO    NOIPD               YES                                  42600020
         TM    MCHLOGIC,X40        MOD DEP PROCESSING DAM AVAIL         42650020
         BZ    SETTERM             NO                                   42700020
         MVI   MCHNXMOD,N2         SET PROCESSING DAM MOD SUCCESSOR     42750020
         BR    REG4                CHECK FOR MCI IN CCH                 42800020
         SPACE                                                          42850020
SETTERM  OI    REPDAR1,X80         SET TERMINATION NECCESSARY           42900020
         SPACE                                                          42950020
NOIPD    LA    REG1,XC04           LOAD VALIDITY BITS -LHPSW,CR'S       43000020
         LR    REG2,REG1           SAVE IN REG2                         43050020
         N     REG1,NMCIC          AND WITH INTERRUPT CODE              43100020
         XR    REG1,REG2           ALL BITS ON                          43150020
         BNZ   SYSDOWN             NO                                   43200020
         LA    REG1,X319           GET REST OF VALIDITY BITS            43250020
         LR    REG2,REG1           SAVE IN REG2                         43300020
         N     REG1,NMCIC          AND WITH INTERRUPT CODE              43350020
         XR    REG1,REG2           ALL BITS ON                          43400020
         BNZ   SETCRIT             NO,SET CRITICAL FIELDS INVALID       43450020
         SPACE 2                                                        43500020
TSTSOFT  TM    NMCIC,X40           SOFT ERROR                           43550020
         BZ    TESTEXT             YES                                  43600020
         SPACE 2                                                        43650020
TESTSE   TM    NMCIC+N2,X80        MULTIPLE ECC ERROR                   43700020
         BZ    TESTKE              NO                                   43750020
         TM    MCHLOGIC,X10        MOD DEP STORAGE ANALYSIS AVAILABLE   43800020
         BZ    SETTERM2            NO                                   43850020
         MVI   MCHNXMOD,N4         SCHEDULE STORAGE ANALYSIS AS SUCC    43900020
         BR    REG4                CHECK FOR MCI IN CCH                 43950020
         EJECT                                                          44000020
SETTERM2 OI    REPDAR1,X80         SET TERMINATION NECESSARY            44050020
         SPACE 2                                                        44100020
TESTEXT  TM    NCNTLREG+N56,X02    EXTERNAL MASK CHECK                  44150020
         BZ    TESTAC              EXTERNAL MASKED BYPASS CHECKING      44200020
         TM    NMCIC,X04           EXTERNAL DAMAGE                      44250020
         BZ    TSTTODC             NO                                   44300020
         TM    MCHLOGIC,X02        MOD DEP EXTERNAL DAMAGE ANAL AVAIL   44350020
         BZ    TSTTODC             NO                                   44400020
         MVI   MCHNXMOD,N7         SCHED EXT DAM ANALYSIS AS SUCC       44450020
         BR    REG4                CHECK FOR MCI IN CCH                 44500020
         SPACE 2                                                        44550020
TSTTODC  TM    NMCIC,X08           TIME OF DAY CLOCK DAMAGE             44600020
         BO    NCLCKREP            YES CONTINUE PROCESSING              44650020
         SPACE 2                                                        44700020
TSTTIME  TM    NMCIC,X10           TIMER DAMAGE                         44750020
         BO    NTIMEREP            YES ATTEMPT REPAIR                   44800020
         SPACE 2                                                        44850020
TESTAC   TM    NCNTLREG+N56,X04    CONFIGURATION MASK CHECK             44900020
         BZ    SYSREC              ERRORS MASKED CHECK FOR SYS RECOVERY 44950020
         TM    NMCIC,X01           CONFIGURATION ERROR (BUFFER DELETE)  45000020
         BZ    SYSREC              NO,CHECK FOR SYSTEM RECOVERY         45050020
         TM    MCHLOGIC+N1,X20     MOD DEP AUTO CONFIG ANAL AVAIL       45100020
         BZ    SYSREC              NO,CHECK FOR SYSTEM RECOVERY         45150020
         MVI   MCHNXMOD,N8         SCHED MOD DEP AUTO CONFIG AS SUCC    45200020
         BR    REG4                CHECK FOR MCI IN CCH                 45250020
         SPACE 2                                                        45300020
SYSREC   TM    REPDAR1,X80         TERMINATION NECESSARY                45350020
         BO    NGETPDAR            YES,SCHEDULE PDAR AS SUCCESSOR       45400020
         B     NGETSMCH            CALL SMCH                            45450020
         SPACE 2                                                        45500020
         SPACE 2                                                        45550020
TESTKE   TM    NMCIC+N2,X20        STORAGE KEY ERROR                    45600020
         BZ    TESTBOTH            NO                                   45650020
         TM    MCHLOGIC,X08        MOD DEP STG PROTECT ANALYSIS AVAIL   45700020
         BZ    SETTERM2            NO                                   45750020
         MVI   MCHNXMOD,N5         SCHED MOD DEP STG PROTECT AS SUCC    45800020
         BR    REG4                CHECK FOR MCI IN CCH                 45850020
         EJECT                                                          45900020
TESTBOTH TM    MCHLOGIC,X04        MOD DEP STG AND PROT ANAL AVAIL      45950020
         BZ    SETTERM2            NO                                   46000020
         MVI   MCHNXMOD,N6         SCHED MOD DEP STG AND PROT ANAL      46050020
         BR    REG4                CHECK FOR MCI IN CCH                 46100020
         SPACE 2                                                        46150020
SYSDOWN  OI    MCHDAMAG,X08        SET SYSTEM TERMINATION NECESSARY     46200020
         SPACE 2                                                        46250020
SETCRIT  OI    REPDAR1,X80         SET CRITICAL FIELDS INVALID          46300020
         TM    NMCIC+N3,X02        LOGOUT VALID                         46350020
         BZ    SETTERM1            NO                                   46400020
         TM    MCHLOGIC,X20        MOD DEP RECONSTRUCT AVAILABLE        46450020
         BZ    SETTERM1            NO                                   46500020
         MVI   MCHNXMOD,N3         SCHED MOD DEP RECONSTRUCT AS SUCC    46550020
         BR    REG4                CHECK FOR MCI IN CCH                 46600020
*                                                                       46650020
         SPACE 2                                                        46700020
SETTERM1 TM    MCHDAMAG,X08        SYSTEM TERMINATION                   46750020
         BO    NERCALL1            YES                                  46800020
         B     TSTSOFT             GO TEST FOR SOFT ERROR         20302 46900020
         EJECT                                                          47000020
******** CCH TO MCH CHANNEL RECORD IS BUILT                    ******** 47050020
*  THIS ROUTINE RECEIVES THE CCH PARAMETERS AND SETS UP AN ENTRY TO   * 47100020
*  THE EMERGENCY RECORDER TO PUT THE CHANNEL RECORD ON SYS1.LOGREC    * 47150020
*  ROUTINE THEN SCHEDULES A SYSTEM WAIT EXIT                          * 47200020
         SPACE 2                                                        47250020
NCLRECOK EQU   *                                                        47300020
         ST    REG13,MCHWORK       SAVE ADDR OF CHANNEL RECORD          47350020
         LH    REG6,N6(REG13)      GET LENGTH FOR RECORD                47400020
         LA    REG6,N10(REG6)      ADJUST FOR COUNT/KEY                 47450020
         STH   REG6,MCHWORK+K4     SAVE CHANNEL RECORD LENGTH           47500020
         OI    MCHINT+N1,X80       SET CHNL RECORD FLAG FOR RECORDER    47550020
         OI    MCHDAMAG+N1,X04     SET CHNL ERROR IN DAMAGE ASSESSMENT  47600020
         B     NERCALL             CALL S/A RECORDER                    47650020
         EJECT                                                          47700020
******** S Y S T E M  D A M A G E  F O U N D                   ******** 47750020
NSYSDAM  EQU   *                                                        47800020
         SPACE 2                                                        47850020
******** EMERGENCY RECORDER CALL ROUTINE                         ****** 47900020
         OI    MCHDAMAG+N1,X08     SET PROCESSING DAMAGE FLAG           47950020
         OI    MCHDAMAG+N3,X01     SET SYSTEM DAMAGE FLAG               48000020
NERCALL  EQU   *                                                        48050020
NERCALL1 EQU   *                                                        48100020
         OI    MCHDAMAG,X08        SET TERM IN DAMAGE ASSESSMENT        48150020
         MVI   MCHNXMOD,N10        SET SUCCESSOR AS TERMINATOR          48200020
         BR    REG4                CHECK FOR MCI IN CCH                 48250020
         SPACE 4                                                        48300020
         EJECT                                                          48350020
********  S O F T  M A C H I N E  C H E C K  H A N D L E R  C A L L *** 48400020
NGETSMCH EQU   *                                                        48450020
         MVC   MCHHISTY(HISTLEN),MCHHISTY+N2 ADJUST HISTORY TABLE       48500020
         TM    MCHDAMAG,X40        SOFTWARE RECOVERY                    48550020
         BO    GETSMCH             YES                                  48600020
         OI    MCHDAMAG,X80        SET SOFT FLAG                        48650020
GETSMCH  EQU   *                                                        48700020
         L     REG15,NMODBASE      GET XIENT AREA BASE                  48750020
         BR    REG15               CALL SMCH                            48800020
         SPACE 2                                                        48850020
*****  T I M E  OF  D A Y  C L O C K  D A M A G E   R O U T I N E  **** 48900020
NCLCKREP EQU   *                                                        48950020
         MVI   MCHINTEL,X20        SET MESSAGE FLAG                     49000020
         MVI   MCHDAMAG+N1,X02     SET TOD DAMAGE                       49050020
         MVC   MCHIBUF(N23),NTODTXT-N2  PUT MSG IN BUFFER               49100020
         LA    REG6,MCHIBUF        GET WTO BUFFER ADDRESS               49150020
         LA    REG5,N23            GET MESSAGE BUFFER UPDATE VALUE      49200020
         BAL   REG2,NMSGEND        SET UP MESSAGE                       49250020
         B     NERCALL             EXIT TO TERMINATOR                   49300020
         SPACE 4                                                        49350020
********            T I M E R    R E P A I R                   ******** 49400020
NTIMEREP EQU   *                                                        49450020
         SR    REG6,REG6           CLEAR REGISTER TO STORE ZEROES       49500020
         ST    REG6,TIMER          STORE ZEROES IN CLOCK TO CORR PARITY 49550020
         L     REG6,MCHIPTR        GET WTO BUFFER ADDRESS               49600020
         LA    REG5,N1             GET MESSAGE BUFFER UPDATE VALUE      49650020
         MVI   N0(REG6),X14        SET MESSAGE CODE                     49700020
         BAL   REG2,NMSGEND        SET UP MESSAGE                       49750020
         OI    MCHDAMAG,X40        SET SOFTWARE RECOVERED FLAG          49800020
         B     TESTAC              EXIT MCH                             49850020
         SPACE 2                                                        49900020
*****     MCH MESSAGE UPDATE ROUTINE     *****                          49950020
NMSGEND  AR    REG6,REG5           UPDATE BUFFER POINTER                50000020
         ST    REG6,MCHIPTR        RESET BUFFER POINTER                 50050020
         BR    REG2                RETURN                               50100020
         SPACE 2                                                        50150020
***            CALL  PDAR  AS  SUCCESSOR                            *** 50200020
NGETPDAR EQU   *                                                        50250020
         MVI   MCHNXMOD,N9         SET PDAR AS SUCCESSOR                50300020
         EJECT                                                          50350020
*********************************************************************** 50400020
*********************************************************************** 50450020
HISTLEN  EQU   26                  2 LESS THAN LENGTH OF MCHHISTY       50500020
*****     CHECK FOR CCH ENTRY     *****                                 50550020
NCCHCK   EQU   *                                                        50600020
         TM    MCHDAMAG+N3,X02     MCI CCH MSG SCHED                    50650020
         BO    NMODSCED            YES SCHEDULE NEXT MODULE             50700020
         CLI   MCHPSA+N115,X01     MCI IN CCH                           50750020
         BNE   NMODSCED            NO SCHDEULE NEXT MODULE              50800020
         OI    MCHDAMAG+N3,X02     SET MCI-CCH FLAG                     50850020
         B     NERCALL             EXIT TO TERMINATION                  50900020
         SPACE 2                                                        50950021
*  THIS CODE MAY BE ENTERED FROM SHUT AFTER MCH HAS TIMED OUT           50960021
*  ATTEMPTING TO LOAD A MODULE.  IN THIS CASE A X40 WILL BE SET IN      50970021
*  MCHIOSWD TO TELL IOS TO CLEAR THE UCB STATUS                         50980021
         SPACE 2                                                        50990021
NMODSCED EQU   *                                                        51000020
         OI    MCHINTEL+N1,X80     SET MODULE LOAD BIT                  51050020
         LA    REG4,IGFERR0        GET S/A CONSOLE MESSAGE ADDR         51100020
         ST    REG4,MCHSHUT        SAVE ADDRESS FOR RECORDER            51150020
         MVC   MCHDISPL(N1),MCH1STDS  GET DISPLACEMENT                  51200020
NMODSKD1 EQU   *                                                        51230021
         MVC   MCHHISTY(HISTLEN),MCHHISTY+K2 ADJUST HISTORY TABLE       51300020
         SR    REG1,REG1           CLEAR REG                            51350020
         IC    REG1,MCHDISPL       GET DISPLACEMENT INTO SUCCESSOR LIST 51400020
         L     REG2,MCHNXIDS       * GET                                51450020
         AR    REG2,REG1           * ADDRESS OF                         51500020
         BCTR  REG2,N0             * SUCCESSOR LIST                     51550020
         IC    REG1,MCHNXMOD       GET FUNCTIONAL SUCCESSOR PATH NO.    51600020
         AR    REG2,REG1           GET ADDRESS OF DESIRED SUCCESSOR ID  51650020
         MVC   MCHNXHIS(K1),K0(REG2) SAVE MODULE ID                     51700020
         L     REG1,MCHTTRS        GET POINTER TO MODULE TTR TABLE      51750020
NMODCHEK EQU   *                                                        51800020
         CLC   N0(N1,REG1),N0(REG2) SEARCH TABLE FOR THIS MODULES ID    51850020
         BE    NIDFOUND            ID WAS FOUND                         51900020
         LA    REG1,K5(REG1)       INCREMENT TO NEXT ENTRY IN TTR TABLE 51950020
         B     NMODCHEK            CONTINUE SEARCH                      52000020
NIDFOUND EQU   *                                                        52050020
         MVC   MCHDISPL(N1),N1(REG1) SAVE THIS NEXT MODULE'S DIS-       52100020
*                                  PLACEMENT INTO SUCCESSOR LIST.       52150020
         MVI   MCHEXLEV,XFF        INIT TO X'FF' UNTIL OVERLAID         52200020
         LA    REG14,NMODSKD8      SET RETURN REG                       52250020
         MVC   MCHTTRIN(K3),K2(REG1) TTR TO INPUT FIELD FOR CONVERT     52300020
         LA    REG2,MCHIOBSK+N3    GET ADDRESS OF IOB SEEK FIELD        52350020
         ST    REG2,CCWLOAD        AND SET IT INTO CCW FOR SEARCH       52400020
         MVI   CCWLOAD,SRCHID      RESTORE OP CODE OF CCW               52450020
         MVC   CCWRD+N1(N3),NMODBASE+N1                                 52500020
         LA    REG2,CCWLOAD        SET IOB PTR TO CHANNEL               52550020
         ST    REG2,MCHIOB+K16     PROGRAM TO LOAD TRANSIENT MODULE     52600020
         L     REG1,CVTSVDCB       GET SVCLIB DCB ADDRESS               52650020
         L     REG1,K44(REG1)      GET SVCLIB DEB ADDR                  52700020
         LA    REG15,IGFLOAD       GET ADDRESS OF LOADER SUBROUTINE     52750020
         SPACE 2                                                        52760021
** AT THIS POINT, CONTROL GOES TO THE MODULE LOADER ROUTINE          ** 52800020
         SPACE 2                                                        52810021
         BR    REG15               GO TO ROUTINE                        52850020
         EJECT                                                          52900020
** AT THIS LOCATION CONTROL IS RETURNED FROM THE LOADER IF GOOD LOAD    52950020
         SPACE 2                                                        52960021
NMODSKD8 EQU   *                                                        53000020
         B     NMODSKD9            MODULE LOADED - PREPARE TO EXECU     53050020
         SPACE 2                                                        53100020
** AT THIS POINT CONTROL IS RETURNED IF THE LOAD WAS BAD                53150020
         SPACE 2                                                        53160021
NIOMSG   EQU  *                                                         53200020
         TM    MCHINTEL,X20        WAIT STATE MESSAGE IN BUFFER   40762 53203000
         BO    NSAWRITE            YES, DO NOT OVERLAY WITH NEW MESSAGE 53206000
         L     REG2,MCHUCB         GET UCB ADDR OF BAD I/0        20302 53210020
         MVC   NIOTXT+N19(N3),N13(REG2) MOVE IN CUA FROM UCB      20302 53220020
         MVC   MCHIBUF(N24),NIOTXT-N2 SET MESSAGE IN BUFFER       20302 53250020
         MVI   WRITECCW+N7,N22     MSG LENGTH FOR THIS MSG        20302 53260020
         OI    MCHDAMAG,X08        SET TERMINATE FLAG                   53300020
         OI    MCHDAMAG+N3,X03     SET I/O ERROR FLAG                   53350020
         B     NSAWRITE            SEND MESSAGE AND WAIT                53400020
NMODSKD9 EQU   *                                                        53450020
         LA    REG14,NMODSKD1      SET RETURN REG FOR MODULE            53500020
         LA    REG2,MCHEXLEV       SUBSYS LEVEL NR ADDR           20021 53550020
         LA    REG3,MCHNXMOD       SUBSYS FUNCT SUCC PATH NR ADDR 20021 53600020
         L     REG9,MCHSUBP        SUBSYS COMMON AREA PTR         20021 53650020
         L     REG15,NMODBASE      SET UP XIENT AREA BASE               53700020
         BR    REG15               GO TO XIENT MODULE                   53750020
         EJECT                                                          53800020
*                                                                       53850020
*                                                                       53900020
*                                                                       53950020
BEGINCC  EQU   6                                                        54000020
BEGINHH  EQU   8                                                        54050020
NMEXT    EQU   16                                                       54100020
NMTRK    EQU   14                                                       54150020
IGFLOAD  EQU   *                                                        54200020
MODLDREP EQU   *                                                        54250020
         STM   REG0,REG15,MCHMLSAV SAVE REGISTERS                       54300020
         LR    REG12,REG15            * ESTABLISH                       54350020
         LA    REG4,IGFLOAD-NUCLABLE  * MODULE                          54400020
         SR    REG12,REG4             * BASE                            54450020
         MVC   MCHIODCB+N1(N3),N25(REG1)                                54500020
         L     REG2,K32(REG1)      GET UCB ADDRESS                      54550020
         LA    REG2,K0(REG2)       CLEAR HI-ORDER BYTE                  54600020
         SR    REG4,REG4           CLEAR WORK REG                       54650020
         IC    REG4,K19(REG2)      GET DASD DEVICE TYPE FROM UCB        54700020
         L     REG2,CVTZDTAB       GET DEV CHAR TABLE ADDR              54750020
         IC    REG4,N0(REG4,REG2)  * GET NUMBER OF TRACKS               54800020
         LH    REG4,N2(REG4,REG2)  * PER CYLINDER                       54850020
*  *    ASSUME TTR IS IN 'MCHTTRIN' AND IS LEFT JUSTIFIED          *  * 54900020
         LH    REG3,MCHTTRIN       GET TT FROM INPUT FIELD              54950020
         SR    REG2,REG2           CLEAR FOR DIVIDE                     55000020
         N     REG3,NMASKHI2       CLEAR HI-ORDER 2 BYTES               55050020
         LR    REG5,REG3           GET TT                               55100020
         SR    REG6,REG6           CLEAR REG                            55150020
         IC    REG6,NMEXT(REG1)    GET NUMBER OF EXTENT ENTRIES         55200020
         SR    REG7,REG7           INIT EXTENT NO. TO ZERO              55250020
         LA    REG1,N32(REG1)      PTR. TO EXTENT FIELD                 55260020
NSRCHXTN SH    REG5,NMTRK(REG1)    DECREMENT TT BY SIZE OF EXTENT       55300020
         BM    NXTNFND             XTNT FOUND IF REG CONTENTS NEGATIVE  55350020
         SH    REG3,NMTRK(REG1)    COMPUTE REL TRK ADDR TO NEXT EXTENT  55360020
         LA    REG1,K16(REG1)      INCREMENT TO CHECK NEXT EXTENT       55400020
         LA    REG7,N1(REG7)       BUMP TO NEXT EXTENT NO.              55450020
         BCT   REG6,NSRCHXTN       CONTINUE SEARCH FOR PROPER EXTENT    55500020
         OI    MCHDAMAG,X08        SET TERMINATE FLAG                   55550020
         B     NSAOPMSG            NOT FOUND-TERMINATE SYSTEM           55600020
NXTNFND  EQU   *                                                        55650020
         STC   REG7,MCHIOBSK       SET XTNT NO. IN SEEK FIELD           55700020
         MVC   MCHUCB+N1(N3),N1(REG1) COPY UCB ADDR FOR ENABLE RTN      55750020
         DR    REG2,REG4           COMPUTE NO. OF CYLS AND TRACKS FROM  55800020
*                                  BEGINNING OF THIS EXTENT             55850020
         AH    REG3,BEGINCC(REG1)  ADD CC AND HH DISPLACEMENTS TO       55900020
         AH    REG2,BEGINHH(REG1)  THE ABSOLUTE CC AND HH               55950020
         CR    REG2,REG4           IS HH NOW GREATER THAN TRKS PER CYL  56000020
         BL    NTTRC1              YES                                  56050020
         SR    REG2,REG4           SUBTRACT NO. OF TRACKS PER CYLINDER  56100020
         LA    REG3,K1(REG3)       BUMP CYLINDER COUNT                  56150020
NTTRC1   EQU   *                                                        56200020
         STH   REG3,MCHIOB+K36     STORE CC INTO IOB                    56250020
         STH   REG2,MCHIOB+K38     STORE HH INTO IOB                    56300020
         MVC   MCHIOB+K35(K4),MCHIOB+K36 SLIDE CCHH TO CORRECT IOB SPOT 56350020
         MVC   MCHIOB+K39(K1),MCHTTRIN+K2 MOVE R INTO IOB ALSO          56400020
         LA    REG15,MLDRIOGO      GET ADDR OF IO ROUTINE               56450020
         LM    REG0,REG14,MCHMLSAV RESTORE REGISTERS                    56500020
         LA    REG1,MCHIOB         SET FOR ENTRY TO PSEUDO EXCP         56550020
         BR    REG15               GO TO IO ROUTINE                     56600020
         EJECT                                                          56650020
********                                                         ****** 56700020
*                                                                       56750020
* TITLE...MCH RESIDENT MODULE LOADER                                    56800020
*                                                                       56850020
* FUNCTION...TO LOAD THE MCH TRANSIENT MODULES VIA AN INTERFACE WITH    56900020
*            IOS...THIS METHOD OF USING SYSTEM FACILITIES PROVIDES A    56950020
*            GREATER DEGREE OF DEVICE INDEPENDENCE AND THE FULL USE     57000020
*            OF I/O ERROR RECOVERY PROCEDURES...                        57050020
*                                                                       57100020
* ENTRY POINT...MODLDREP                                                57150020
*                                                                       57200020
* ATTRIBUTES...SERIALLY REUSEABLE,RESIDENT,OPERATES IN SUPERVISOR MODE, 57250020
*            MODEL AND SYSTEM INDEPENDENT...                            57300020
*                                                                       57350020
* INPUT TO MODULE LOADER...........FILLED IN BY MODULE SCHEDULER        57400020
*              MCHSTEXT.....ADDR FOR DEB STARTING EXTENT                57450020
*              MCHENEXT.....ADDR FOR DEB ENDING EXTENT                  57500020
*              MCHMBBCH.....MBBCCHHR FOR IOB SEEK FIELD                 57550020
*                                                                       57600020
* INPUT TO IOS......                                                    57650020
*              REG1.....IOB ADDR.                                       57700020
*              REG10....ENTRY ADDR TO IOS                               57750020
*              REG14....MCH ADDRESSABILITY RTN...IOS RETURNS HERE       57800020
*              MCHIOSWD...IOS INTERFACE WORD                            57810021
*                BYTE 0                                                 57815021
*                  BIT 0 EQUAL 0 - NORNAL ENTRANCE FROM MCH             57820021
*                  BIT 0 EQUAL 1 - DEQUEUE MCH RQE                      57830021
*                  BIT 1 EQUAL 0 - NORMAL STATE                         57840021
*                  BIT 1 EQUAL 1 - CLEAR BUSY AND POST INDICATORS IN    57842021
*                                  UCB                                  57850021
*                  BIT 2 EQUAL 1 - INTERNAL MCH INDICATOR FOR RECURSION 57860021
*                BYTE 1                                                 57863021
*                  BIT 0 EQUAL 1 - INDICATES MCH/IOS TIMEOUT EXIT       57866021
*                                                                       57870021
*                                                                       57880021
*                                                                       57900020
* DEPENDENT REQUIREMENT.....MCH NIP MODULE MUST RESOLVE THE FOLLOWING.. 57950021
*                   MCH..ADCONS    IOS...ENTRY POINTS                   58000020
*                      IGFCINT        IECINT                            58050020
*                      IGFIOENT       IECRMS                            58100020
*                                                                       58150020
* EXITS....NORMAL..TO CALLER WITH A SUCCESSFUL LOAD CODE                58200020
*          ERROR...TO CALLER WITH AN UNSUCCESSFUL LOAD CODE             58250020
*                                                                       58300020
*                                                                       58350020
********                                                         ****** 58400020
*                                                                       58450020
*                                                                       58500020
*                                                                       58550020
         EJECT                                                          58600020
*                                                                       58650020
*                                                                       58700020
IGFIORTN EQU   *                                                        58750020
MLDRIOGO EQU   *                                                        58800020
         STM   REG0,REG15,MCHMLSAV SAVE REGISTERS                       58850020
         LR    REG12,REG15         ESTABLISH                            58900020
         LA    REG4,MLDRIOGO-NUCLABLE        MODULE                     58950020
         SR    REG12,REG4                           BASE                59000020
         ST    REG1,IOBSVAD        SAVE IOB ADDR                        59050020
         L     REG4,N20(REG1)      GET DCB ADDRESS                      59100020
         L     REG4,K44(REG4)      GET DEB ADDR                         59150020
         LA    REG4,N0(REG4)       CLEAR HIGH ORDER BYTE                59160020
         C     REG4,DEBSVAD        IS DEB ADDR EQUAL TO OLD DEB         59170020
         BE    NEXT                YES                                  59180020
         MVC   NDEBSAVE(N4),N28(REG4) SAVE CURRENT APN PTR.             59182020
         ST    REG4,DEBSVAD        SAV DEB ADDR FOR I/O REINSTATE       59184020
NEXT     EQU   *                                                        59190020
         MVC   PSWSAV(N4),IONPSW+N4     SAVE IONPSW ADDR                59250020
         LA    REG2,MCHECB         GET ADDRESS OF ECB                   59300020
         ST    REG2,MCHIOB+N4      SET ECB ADDRESS INTO IOB             59350020
         LA    REG4,MCHFLIH        LOAD MCH INT/HANDLER ADDR            59400020
         ST    REG4,IONPSW+N4      STORE MCH ADDR AT IONPSW ADDR FIELD  59450020
         MVI   MCHECB,X80          ESTABLISH PSEUDO WAIT STATE          59500020
         L     REG4,DEBSVAD        LOAD DEB PTR                         59600020
         LA    REG2,APNTBL         PUT MCH APN PTR                      59700020
         ST    REG2,N28(REG4)      IN DEB                               59750020
         MVC   N28(N1,REG4),NDEBSAVE RESTORE HI-ORDER BYTE              59800020
         L     R15,MCHIOENT        IOS INTERFACE ADDRESS                59850020
         CNOP  2,4                                                      59870000
         BALR  REG14,REG15         GO IOS/RETURN MCH                    59900020
MCHADABL EQU   *                                                        59910000
MCHIOSWD DC    F'0'                IOS INTERFACE WORD             40762 59920000
*                                                                       59950020
*                                                                       60000020
         EJECT                                                          60050020
*                                                                       60100020
NUCLABLE EQU   IGFN0000                                                 60200020
         LR    REG12,REG14              * ESTABLISH                     60250020
         LA    REG4,MCHADABL-NUCLABLE   * MODULE                        60300020
         SR    REG12,REG4               * BASE                          60350020
         L     REG11,NCOMADDR      SET ADDRESSABILITY FOR COMM AREA     60400020
*                                                                       60450020
         EJECT                                                          60500020
MCHENABL EQU   *                                                        60550020
         L     REG2,MCHUCB         GET ADDRESS OF UCB                   60600020
         IOSGEN SELSSM,UCBRGG,(REG6,REG7,REG8,REG9),0,AUTH=IGFMCHE0     60650020
*                                                                       60700020
         EJECT                                                          60702021
         LA    REG1,XFF            SET UP FOR TIME OUT LOOP       40762 60710000
         SLL   REG1,N12            SET REG 1 TO 1 MILLION         40762 60720000
MCHIOTST TM    MCHECB,X80          TEST FOR MCH I/O COMPLETE            60800020
         BZ    MCHDABLE            FALL OUT OF BIT SPIN           40762 60820000
         BCT   REG1,MCHIOTST       CONTINUE THE BIT SPIN          40762 60840000
         OI    MCHIOSWD+N1,X80     SET I/O TIMEOUT INDICATOR  IC  21961 60850021
         OI    MCHIOSWD,X20        SET TIMEOUT RECURSION INDICATOR40762 60870021
*                                                                       60900020
         EJECT                                                          60950020
MCHDABLE EQU   *                                                        61000020
         IOSGEN SELSSM,,,1,AUTH=IGFMCHE0                                61050020
*                                                                       61100020
         MVC   IONPSW+N4(N4),PSWSAV RESTORE IONPSW ADDRESS              61200020
         L     REG1,DEBSVAD        LOAD DEB ADDR                        61250020
         MVC   N28(N4,REG1),NDEBSAVE   RESTORE CURRENT POINTER TO THE   61300020
*                                      APPENDAGE TABLE                  61350020
         TM    MCHIOSWD,X20        HAS A TIMEOUT OCCURRED         40762 61355021
         BNO   NOTYET              NO,CHECK FOR SUCCESSFUL I/O    40762 61360021
         NI    MCHIOSWD,XDF        TURN OFF TIMEOUT INDICATOR     40762 61362021
         L     REG10,MCHCVT        PICK UP CVT POINTER            40762 61365021
         TM    MCHIOSWD,X40        IS THIS THE SECOND TIMEOUT     40762 61370021
         BO    NIOMSG              YES,GO PUT THE SYSTEM DOWN     40762 61375000
         B     NEXIT2              GO TERMINATE  THE SYSTEM       40762 61385021
NOTYET   EQU   *                                                        61390000
         MVI   MCHIOSWD,X00        CLEAR IOS INTERFACE BYTE   IC  21961 61395021
         CLI   MCHECB,X7F          TEST FOR SUCCESSFUL COMPLETION       61400020
         LM    REG0,REG15,MCHMLSAV RESTORE REGISTERS                    61450020
         BCR   EQUAL,REG14         NORMAL SUCCESSFUL RETURN             61500020
         B     N4(REG14)           ERROR RETURN                         61550020
*                                                                       61600020
*                                                                       61650020
*                                                                       61700020
*                                                                       61750020
*        FIRST LEVEL INTERRUPT HANDLER                                  61800020
MCHFLIH  EQU   *                                                        61850020
         USING *,REG6                                                   61900020
         L     REG6,IONPSW+N4      ESTABLISH ADDR.                      61950020
         L     REG6,IGFCINT        LOAD IOS ENTRY ADDR                  62000020
         BR    REG6                BRANCH TO IOS                        62050020
         DROP  REG6                                                     62100020
*                                                                       62150020
*                                                                       62200020
ENDEXT   EQU   *                                                        62250020
         USING *,REG15                                                  62300020
         SR    REG11,REG11         SET REG11 TO 0 INDEX                 62350020
         BAL   REG15,APNTEST       GO TO APPENDAGE TEST ROUTINE         62400020
         BR    REG14               RTN TO IOS                           62450020
*                                                                       62500020
SIOAPN   EQU   *                                                        62550020
         USING *,REG15                                                  62600020
         LA    REG11,N4            SET REG 11 TO FOUR INDEX             62650020
         BAL   REG15,APNTEST       GO TO APPENDAGE TEST ROUTINE         62700020
         BR    REG14               RTN TO IOS                           62750020
*                                                                       62800020
PCIAPN   EQU   *                                                        62850020
         USING *,REG15                                                  62900020
         LA    REG11,N8            SET REG 10 T0 8 INDEX                62950020
         BAL   REG15,APNTEST       GO TO APPENDAGE TEST ROUTINE         63000020
         BR    REG14               RTN TO IOS                           63050020
*                                                                       63100020
*                                                                       63150020
*                                                                       63200020
*        ABNORMAL END APPENDAGE ROUTINE                                 63250020
*                                                                       63300020
*        ECB=7F RETURN TO IOS AT OFFSET 0--FIRST ERROR ENTRY            63350020
*        ECB=41 RETURN TO IOS AT OFFSET 12--PERM.ERROR                  63400020
*                                                                       63450020
AENDAP   EQU   *                                                        63500020
         USING *,REG15                                                  63550020
         LA    REG11,N16           SET REG11 TO 16 INDEX                63600020
         BAL   REG15,APNTEST       GO TO APPENDAGE TEST ROUTINE         63650020
         USING *,REG15                                                  63700020
         L     REG11,NCOMADDR      SET BASE FOR COMMON AREA             63750020
         CLI   MCHIOECB,X7F        CHECK FIRST ENTRY                    63800020
         BCR   EQUAL,REG14         RTN TO IOS OFFSET 0                  63850020
         CLI   MCHIOECB,X44        DEVICE END ERROR                     63900020
         BE    N8(REG14)           RTN TO IOS OFFSET 8                  63950020
         MVI   MCHECB,X41          INSERT ERROR CODE                    64000020
         B     N12(REG14)          RTN TO IOS OFFSET 12                 64050020
*                                                                       64100020
*        NORMAL END APPENDAGE ROUTINE                                   64150020
*                                                                       64200020
NENDAP   EQU   *                                                        64250020
         USING *,REG15                                                  64300020
         LA    REG11,N12           SET REG11 TO 12 INDEX                64350020
         BAL   REG15,APNTEST       GO TO APPENDAGE TEST ROUTINE         64400020
         USING *,REG15                                                  64450020
         L     REG11,NCOMADDR      SET ADDRESSABILITY FOR COMM AREA     64500020
         CLI   MCHIOB,X04          CHECK EXCEPTION BIT IN IOB           64550020
         BE    EXCPERR             AN ERROR HAS OCCURED                 64600020
         MVI   MCHECB,X7F          INSERT SUCCESSFUL LOAD CODE          64650020
         B     N12(REG14)          RTN TO IOS OFFSET 12                 64700020
EXCPERR  MVI   MCHECB,X41          MOVE IN ERROR CODE                   64750020
         XI    MCHIOB,X04          TURN OFF IOB EXECPTION BIT           64800020
         B     N12(REG14)          RTN TO IOS OFFSET 12                 64850020
         DROP  REG15                                                    64900020
*                                                                       64950020
APNTBL   DC    A(ENDEXT)           END/EXTENT APPEN                     65000020
         DC    A(SIOAPN)           SIO APPEN                            65050020
         DC    A(PCIAPN)           PCI APPEN                            65100020
         DC    A(NENDAP)           NORMAL END APPEN                     65150020
         DC    A(AENDAP)           ABNORMAL END APPEN                   65200020
*                                                                       65250020
APNTEST  EQU   *                                                        65300020
         BALR  REG10,N0            SET UP BASE REG                      65350020
         USING *,REG10                                                  65400020
         C     REG2,IOBSVAD        COMPARE MCH IOB TO IOB EXECUTING     65450020
         BCR   EQUAL,REG15         BRANCH TO APPENDAGE                  65500020
         SPM   REG14               SET PROGRAM MASK                     65550020
         L     REG15,NDEBSAVE      LOAD APPENDAGE TABLE PTR             65600020
         L     REG15,N0(REG11,REG15) LOAD APPENDAGE ADDRESS             65650020
         BR    REG15               BRANCH TO APPENDAGE                  65700020
         DROP  REG10                                                    65750020
*                                                                       65800020
*        CONSTANTS                                                      65850020
*                                                                       65900020
NDEBSAVE DS    F                   SAVE AREA FOR APPEND. TABLE ADDRESS  65950020
IGFCINT  DC    A(0)                IOS ENTRY POINT  (IECINT)            66000020
PSWSAV   DC    F'0'                PSW SAVE,FIRST WORD                  66050020
MCHECB   DC    F'0'                ECB FOR MCH MOD LOADING              66100020
DEBSVAD  DC    F'0'                SAVE AREA FOR I/O DEB ADDR           66150020
IOBSVAD  DC    F'0'                IOB ADDRESS                          66200020
*        CHANNEL PROGRAM                                                66250020
*                                                                       66300020
CCWLOAD  CCW   SRCHID,N0,X60,N5                                         66350020
         CCW   TIC,CCWLOAD,X60,N1  TIC TO SEARCH                        66400020
CCWRD    CCW   READREC,NMODBASE,X20,N1024  READ MCH RECORD              66450020
* CONSTANTS FOR RELATIVE TO ABSOLUTE TRACK CONVERSION                 * 66500020
*                                                                     * 66550020
         DS    0F                                                       66550900
         EJECT                                                          66551321
PROGCHEK EQU   *                                                   GTF  66551800
PCBASADJ EQU   PROGCHEK-IGFN0000                                        66552700
         SPACE 2                                                        66553121
*              (PROG. CHECK FOR MONITOR CALL IS TREATED AS NO-OP) GTF   66553600
*                                                                 * GTF 66554500
* THIS ROUTINE INTERCEPTS PGM CHK NEW PSW                         * GTF 66555400
*  1- TO DETERMINE IF A MONITOR CALL.                             * GTF 66556300
*  2- TO ALLOW PROCESSING TO CONTINUE AT NSI IF IT IS.            * GTF 66557200
*  3- TO PROCEED TO UNUSUAL PGM INTERRUPT HANDLER IF IT IS NOT    * GTF 66558100
* THE LOGOUT AREA IS USED AS A SAVE AREA IN CASE RETURN IS TO NSI. GTF  66559000
*                                                                 * GTF 66559900
         SPACE 2                                                        66560321
         STM   REG9,REG12,LOGOUT   FREE SOME WORK REGS             GTF  66560800
LOGOUT   EQU   X'180'              SAVE AREA FOR WORK REGS        P1086 66561700
         L     REG12,N108          GET ROUTINES ADDRESS           GTF   66562600
         LA    WKR9,PCBASADJ    GET FACTOR TO ESTABLISH NUCBASE  GTF    66563500
         SR    REG12,REG9          ESTABLISH NUCBASE              GTF   66564400
         USING IGFN0000,REG12                                     GTF   66565300
         MVC   NPGMNPSW(N8),NUNEXPSW  SEND PGM CHKS TO SHUT        GTF  66566200
         LA    WKR9,MCEXIT         SET EXIT TO ORIGINAL HANDLER   GTF   66567100
WKR9     EQU   9                                                   GTF  66568000
         CLI   PGMOPSW+X03,X01     OPERATION EXCEPTION?          GTF    66568900
         BE    MCNOP               YES - TEST FURTHER            GTF    66569800
         TM    PGMOPSW+X03,X'40'   MONITOR INTERRUPT?            GTF    66570700
         BCR   8,WKR9              NO NOT MON. CALL              GTF    66571600
MCNOP    TM    PGMOPSW+X04,XC0     IS INSTR LNG SIX OR ZERO?      GTF   66572500
         BCR   N9,WKR9             ALSO PGM CHK IF IMPRECISE      GTF   66573400
         TM    PGMOPSW+X04,X40     INSTR LNG TWO?                 GTF   66574300
         BCR   X01,WKR9            ELIMINATE TWO-BYTE INSTR       GTF   66575200
*                                  (BOTH AF & 44 4-BYTE INSTR)    GTF   66576100
         L     WKRA,PGMOPSW+X04    2ND HALF OF OLD PSW IS NSI     GTF   66577000
         SH    WKRA,PCK4           BACK UP TO INSPECT OP CODE     GTF   66577900
WKRA     EQU   10                                                  GTF  66578800
         CLI   X4(WKRA),PCBRANCH   INSTR. AFTER PCK IS BRANCH?     GTF  66579700
         BCR   PCUNEQ,WKR9         IF NOT, GO PROG. CHK            GTF  66580600
         TM    X5(WKRA),XF0        WILL IT BE NO-OP?               GTF  66581500
         BCR   X5,WKR9             YES, IF BITS 8-11 ARE ZERO      GTF  66582400
         CLI   N0(WKRA),PCMONCAL   POTENTIAL MONITOR CALL ?        GTF  66583300
         BE    PCGONSI             YES- GO TO NEXT SEQ.            GTF  66584200
* TEST THE CONTEXT: 44-00-0-PTR, 47-00-0-DDD ONLY GOOD COMBINATION GTF  66585100
         SPACE 2                                                        66585521
         CLC   N0(X2,WKRA),PCEXEC  NO- IS IT THE EXECUTE?          GTF  66586000
         BCR   PCUNEQ,WKR9         NOT EXECUTE, NO MONITOR CALL    GTF  66586900
         TM    X2(WKRA),XF0        BASE MUST BE ZERO FOR CMT       GTF  66587800
         BCR   X5,WKR9             NON ZERO, BAD CMT               GTF  66588700
         LH    WKRA,X2(WKRA)       GET CLASS MASK TABLE PTR        GTF  66589600
         CLC   N0(X2,WKRA),PCKAF00 2ND HALF WD INDICATE CMT?       GTF  66590500
         BCR   PCUNEQ,WKR9         NO- NOT A MONITOR CALL          GTF  66591400
         SPACE 2                                                        66591821
* GOOD MONITOR CALL ASSUMED AT THIS TIME; TREATED AS NO-OP.        GTF  66592300
         SPACE 2                                                        66592721
PCGONSI  MVC   NPGMNPSW(N8),NPCKPSW SEND PGM CHKS TO PROGCHEK      GTF  66593200
         LM    REG9,REG12,LOGOUT   RESTORE WORK REGS               GTF  66594100
         LPSW PGMOPSW              RETURN TO NSI (WHICH IS NO-OP)  GTF  66595000
         SPACE 2                                                        66595421
*  THIS POINT IS REACHED WHEN NO MONITOR CALL EXISTS               GTF  66595900
         EJECT                                                          66596800
         DS    0F                                                       66650020
IGFERR0  EQU   *                                                        66700020
NSECERR  EQU   *                                                        66750020
NBASEADJ EQU   NSECERR-IGFN0000                                         66800020
         SPACE 2                                                        66810021
********  U N E X P E C T E D  E R R O R  H A N D L E R         ******* 66850020
*                                                                     * 66900020
* THIS ROUTINE IS ENTERED WHENEVER...                                 * 66950020
*       1. AN UNEXPECTED HARD MCI OCCURS IN MCH CODE.                 * 67000020
*            A.IF THE ORIGINAL ERROR WAS SOFT AND THE NEW ERROR IS    * 67050020
*              HARD (OTHER THAN SYSTEM DAMAGE OR PROGRAM DAMAGE WITH  * 67100020
*              INVALID FIELDS) THE ERROR IS RECORDED AND THE PROCESS- * 67150020
*              ING PROGRAM IS RETURNED TO                             * 67200020
*                                                                     * 67250020
*            B.IF THE SECOND ERROR IS SYSTEM DAMAGE OR PROGRAM DAMAGE * 67300020
*              WITH INVALID FIELDS AN ATTEMPT TO WRITE A RECORD IS    * 67350020
*              MADE AND A WAIT STATE IS ENTERED                       * 67400020
*                                                                     * 67450020
*            C.IF THE SECOND ERROR IS SOFT AND THE ORIGINAL ERROR WAS * 67500020
*              SOFT BOTH ARE HANDLED                                  * 67550020
*                                                                     * 67600020
*            D.IF THE ORIGINAL ERROR IS HARD RECOVERED IT IS HANDLED  * 67650020
*              AS IN 1.A.                                             * 67700020
*                                                                     * 67750020
*            E.IF THE ORIGINAL ERROR IS HARD NOT RECOVERED IT IS      * 67800020
*              HANDLED AS IN 1.B.                                     * 67850020
*       2. A PROGRAM CHECK OCCURS IN MCH CODE                         * 67900020
*              THIS CASE IS HANDLED AS IN 1.A. AND 1.B.               * 67950020
*                                                                     * 68000020
*********************************************************************** 68050020
         EJECT                                                          68100020
         LM    REG14,REG13,N0      RESTORE GPR PARITY                   68110020
         L     REG12,MCKNPSW+4     GET ROUTINES ADDRESS            GTF  68150000
         LA    WKR2,NBASEADJ       GET FACTOR TO ESTABLISH NUCBASE      68190000
         SR    REG12,WKR2          ESTABLISH NUCBASE                    68230000
         USING IGFN0000,NUCBASE                                         68300020
         USING NCOMAREA,COMBASE                                         68350020
         USING CVTDSECT,CVTBASE                                         68400020
MCEXIT   EQU   *                                                  GTF   68420000
         L     COMBASE,NCOMADDR    SET GPR 11 AS COMM AREA BASE         68450020
         L     CVTBASE,X10         GET CVT START ADDRESS                68500020
         OI    NPGMNPSW+N1,X02     SET PGM WAIT BIT                     68550020
         LA    REG13,XA02          WAIT CODE                            68600020
         ST    REG13,NPGMNPSW+N4   PUT IN PGM PSW                       68650020
         OI    MCKNPSW+N1,X02      SET MCI WAIT BIT                     68700020
         ST    REG13,MCKNPSW+N4    PUT CODE IN MCI PSW                  68750020
         LPSW  NXITENAB            ENABLE HARD MCI                      68800020
NERR0    EQU   *                                                        68850020
*              UNCONDITIONALLY ENTER ICFBDE00 TO ANALYZE WARNINGS   PWF 68850721
         L     REG15,ICFBDEP       GET ADDR OF ICFBDE00             PWF 68851621
         LA    REG0,N4             INDICATE ENTRY FROM MCHSHUT      PWF 68852521
         BALR  REG14,REG15         PERFORM WARNING ANALYSIS         PWF 68853421
         LTR   REG15,REG15         Q. WARNING TO BE DISABLED        PWF 68854321
*        BNZ   ENDWARN2            NO, BRANCH                       PWF 68855221
         L     REG15,MCHINLOG      GET ADDR OF SAVED LOGOUT         PWF 68856121
         NI    N272(REG15),XFE     DISABLE WARNING IN SAVED         PWF 68857021
*                                  COPY OF CONTROL REG 14           PWF 68857921
ENDWARN2 EQU   *                                                    PWF 68858821
         TM    MCHINTEL,X01        RECORDER SUCESSFUL                   68860020
         BO    NSAOPMSG            YES                                  68870020
         TM    MCHPSA+N115,X0F   CATASTROPHIC CHANNEL ERROR    @SA70516 68900021
         BNZ   NIOMSG              YES,FAILURE TO LOAD                  68950020
         TM    MCHINTEL,X20        EMERGENCY EXIT                       69000020
         BO    NSAWRITE            YES                                  69050020
         TM    MCHINTEL,X04        TERMINATOR SCHEDULED                 69100020
         BO    NSAOPMSG            YES-TERMINATE SYSTEM                 69150020
         TM    MCHINTEL,X80        SYSTEM RETURN POSSIBLE               69200020
         BO    NEXIT3              NO                                   69250020
NPGMCHK  EQU   *                                                        69600020
NEXIT1   EQU   *                                                        69650020
         SPACE 2                                                        69660021
* TESTS BELOW ARE CHECK FOR HARD UNRECOVERED ERROR                      69700020
         SPACE 2                                                        69710021
         TM    MCHDAMAG,X80        HARDWARE RECOVERY                    69720000
         BO    NEXIT5              YES                                  69740000
NEXIT2   EQU   *                   ENTER HERE AFTER FIRST TIME OUT40762 69752021
         TM    MCHDAMAG,X70        RECOVERED SYSTEM                     69760000
         BM    NEXIT4              YES                                  69800020
NEXIT3   EQU   *                                                        69900020
         OI    MCHDAMAG,X08        SYSTEM TERMINATION EMERG RECORD      69950020
NEXIT4   EQU   *                                                        70000020
         OI    MCHIOSWD,X40        SET BIT FOR IOS                40762 70010021
NEXIT5   EQU   *                   TO CLEAR UCB STATUS            40762 70020021
         OI    MCHINTEL,X04        TERMINATOR ENTERED                   70050020
         MVI   MCHNXMOD,N10        SCHEDULE TERMINATOR                  70100020
         MVC   NPGMNPSW(N8),NPCKPSW SEND PGM CHKS TO PROGCHEK      GTF  70150000
         MVC   MCKNPSW(N8),NUNEXPSW     RESTORE MCI PSW                 70200020
         B     NMODSCED            CALL TERMINATOR                      70250020
         EJECT                                                          70650020
NSAOPMSG EQU   *                                                        70700020
         TM    MCHINTEL,X20        RECORD IN BUFFER                     70750020
         BO    NSAWRITE            YES                                  70800020
         XC    MCHIBUF(N30),MCHIBUF     CLEAR BUFFER                    70850020
NUNEXMSG EQU   *                                                        70900020
         MVC   MCHIBUF(N23),NUNEXTXT-N2 SET UP MSG                      70950020
NSAWRITE EQU   *                                                        71000020
         TM    MCHINTEL,X01        RECORD OUT                           71050020
         BO    NWRITE2             YES                                  71100020
         MVI   MCHIBUF+N11,CS      SET S MESSAGE                        71150020
NWRITE2  EQU   *                                                        71200020
         SR    REG7,REG7           CLEAR WORK REGISTER         @S64611P 71250021
         SR    REG8,REG8           CLEAR WORK REGISTER         @S64611P 71280021
         SR    REG2,REG2           CLEAR WORK REGISTER         @S64611P 71310021
         L     REG6,CVTCUCB        GET UCM POINTER             @S64611P 71340021
         SH    REG6,FOUR           GET POINTER TO MCS PREFIX   @S64611P 71370021
         USING UCMPRFX,REG6                                    @S64611P 71400021
         ICM   REG6,N7,N1(REG6)    GET MCS PREFIX & TEST       @S64611P 71430021
         BZ    NOCONSL             NO,WAIT STATE ONLY          @S64611P 71460021
         USING UCMLIST,REG3                                    @S64611P 71490021
         L     REG3,UCMMCENT       GET ADDR MST CONSL UCM ENTRY         71520021
         LA    REG2,K32            GET LOOP CONSTANT           @S64611P 71550021
FINDCON  EQU   *                                               @S64611P 71580021
         LTR   REG3,REG3           TEST FOR CONSL AVAILABLE    @S64611P 71610021
         BZ    CHKHDCPY            NO,GO CHECK FOR HARDCOPY CONS        71640021
         ICM   REG4,XF,UCMCOMPC    TEST FOR COMPOSITE CONSL    @S64611P 71670021
         BZ    CHKACT              NO,CHECK FOR ACTIVE CONSL   @S64611P 71700021
         LR    REG3,REG4           IF YES,GET OUTPUT UCM ENTRY ADDR     71730021
CHKACT   EQU   *                                               @S64611P 71760021
         TM    UCMATR,ACTIVE       Q.IS THIS CONSOLE ACTIVE    @S64611P 71790021
         BO    CHKGRAPH            YES,TEST FOR GRAPHIC CONS   @S64611P 71820021
         L     REG3,UCMALTEN       NOT ACTIVE-GET ALT CONSL ADDR        71850021
         BCT   REG2,FINDCON        DECREMENT & LOOK AGAIN      @S64611P 71880021
         B     CHKHDCPY            WHEN CTR=0'CHECK FOR HARD   @S64611P 71910021
*                                  COPY CONSOLE AVAILABLE      @S64611P 71940021
CHKGRAPH EQU   *                                               @S64611P 71970021
         L     REG7,UCMUCB         GET ADDR OF UCB OF CONSOLE  @S64611P 72000021
         ICM   REG2,N7,UCMXB+N1    TEST FOR GRAPHIC CONSOLE VIA         72030021
*                                  ADDRESS IN UCM DCM          @S64611P 72060021
         BZ    READYWRT            NOT GRAPHICS-WRITE TO CONSL @S64611P 72090021
* CONSOLE IS A GRAPHICS DEVICE                                 @S64611P 72120021
GRAPHICS EQU   *                                               @S64611P 72150021
         SR    REG1,REG1           CLEAR REGISTER              @S64611P 72180021
         L     REG1,UCMXB          GET DCM ADDRESS             @S64611P 72210021
         SR    REG3,REG3           CLEAR REGISTER              @S64611P 72240021
         IC    REG3,X14(REG1)      GET WRITE CCW COUNT         @S64611P 72270021
         L     REG1,X14(REG1)      GET ADDR OF CCW STRING FOR WRITE     72300021
 BCTR REG3,N0 DECR. NO. OF CCWS BY 1                           @S64611P 72330021
         SLL   REG3,N3             MULTIPLY BY 8 TO GET        @S64611P 72360021
         AR    REG3,REG1             TO LOCATION OF CCW        @S64611P 72390021
         BAL   REG4,MSGWRITE       GO WRITE TO GRAPHIC CONSOLE @S64611P 72420021
CHKHDCPY EQU   *                                               @S64611P 72450021
         TM    UCMSFLGS,HARDCY     Q.HARD COPY REQUIRED        @S64611P 72480021
         BZ    NOCONSL             NO,BYPASS MESSAGE WRITE     @S64611P 72510021
         TM    UCMSFLGS,SYSLOG     HARD COPY = SYSLOG (DASD)   @S64611P 72540021
         BO   NOCONSL             YES,BYPASS MESSAGE WRITE     @S64611P 72570021
         L     REG3,UCMHCUCM       GET HARDCOPY UCM ENTRY      @S64611P 72600021
         TM    UCMATR,ACTIVE       Q.IS HARDCOPY DEVICE ACTIVE @S64611P 72630021
         BZ    NOCONSL             NO,BYPASS MESSAGE WRITE     @S64611P 72660021
         L     REG7,UCMUCB         GET ADDR OF UCB FOR CONSL   @S64611P 72690021
READYWRT EQU   *                                               @S64611P 72720021
         USING UCBSECT,REG7                                    @S64611P 72750021
         CLI   UCBTBYT3,UCB3UREC   Q.IS THE CONSOLE UNIT       @S64611P 72780021
*                                    RECORD EQUIPMENT          @S64611P 72810021
         BNE   NOCONSL             NO,BYPASS WRITE             @S64611P 72840021
         LA    REG1,CCW2740        GET CCW ADDRESS             @S64611P 72870021
         LA    REG3,WRITECCW       GET ADDR FOR WRITE ALGORITHM         72900021
         BAL   REG4,MSGWRITE       GO WRITE MESSAGE            @S64611P 72930021
NOCONSL  EQU   *                                               @S64611P 72960021
         TM    MCHDAMAG+N1,X04     CATASTROPHIC I/O ERROR     IC  56022 73460021
         BZ    ENTRWAIT            BRANCH IF NO               IC  56022 73470021
         MVI   MCKNPSW+N3,X0F      IND.CAT.CHAN.ERR.FOR SEREP IC  56022 73472021
ENTRWAIT MVC   NWAITPSW+N7(N1),MCHIBUF+N1    WAIT STATE CODE  IC  56022 73500021
         LPSW  NWAITPSW            ENTER WAIT STATE                     73550021
         SPACE 2                                                        73600020
*                                                              @S64611P 73650021
* REG 1 CONTAINS BEGINNING ADDRESS OF CCW STRING               @S64611P 73670021
* REG 3 CONTAINS ADDRESS OF THE RMS CCW WRITE ADDRESS          @S64611P 73690021
* REG 7 CONTAINS UCB ADDRESS                                   @S64611P 73710021
*                                                              @S64611P 73730021
MSGWRITE EQU   *                                               @S64611P 73750021
         LA    REG2,MCHIBUF+N2     GET ADDRESS OF MESSAGE      @S64611P 73770021
         USING UCBSECT,REG7                                    @S64611P 73790021
         LH    REG7,UCBCHA         GET CUA                     @S64611P 73810021
         DROP  REG7                                            @S64611P 73830021
         STCM  REG1,N7,NCAW+1      SET CCW ADDR IN CAW         @S64611P 73850021
         MVI   NCAW,N0             INSURE PROTECT KEY OF ZERO  @S64611P 73870021
         STCM  REG2,N7,N1(REG3)    PUT MSG ADDR IN CCW         @S64611P 73890021
         MVI   N7(REG3),N22        SET MSG LENGTH IN CCW       @S64611P 73910021
         L     REG5,NLCNT          SET TIO LOOP COUNT          @S64611P 73930021
WRITE3   EQU   *                                                        74050020
         TIO   N0(REG7)            TEST I/O                             74100020
         BC    N2,NBUSY            BUSY-LOOP                            74150020
         BC    N9,WRITE4           OK TRY SIO                           74200020
         TM    X44,X38             CUE,BUSY,OR CE             IC  55625 74250021
         BC    N7,NBUSY            BRANCH IF ANY ON            @S68598P 74300021
WRITE4   EQU   *                                                        74350020
         SIO   N0(REG7)            START I/O FOR WRITE                  74400020
         BR    REG4                RETURN                               74450020
         SPACE 2                                                        74500020
NBUSY    EQU   *                                                        74550020
         BCT   REG5,WRITE3         LOOP TILL ZERO                       74600020
         B     WRITE4              TRY SIO                              74650020
         EJECT                                                          74700020
         DS    0D                  ALIGN PSW ON 2 WORD BOUNDARY         74750020
ENBLPSW  EQU   *                                                        74800020
         DC    X'0004000000'       ENABLE FOR HARD MCI                  74850020
         DC    AL3(NCHERTST)       ADDRESS FIELD OF PSW                 74900020
NUNEXPSW EQU   *                                                        74950020
         DC    XL5'0'              DISABLE PSW SECOND EP                75000020
         DC    AL3(NSECERR)        ADDRESS FIELD OF PSW                 75050020
NPCKPSW  DC    XL5'0004000000'     ENABLED PROG. CHK. PSW          GTF  75060000
         DC    AL3(PROGCHEK)       ADDRESS FIELD OF PSW            GTF  75070000
NXITENAB DC    XL5'0004000000'     ENABLE MCI PSW                       75100020
         DC    AL3(NERR0)          ADDRESS FIELD OF PSW                 75150020
NWAITPSW DC    XL4'00020000'       WAIT PSW                             75200020
         DC    XL4'00000A00'       DUMMY WAIT STATE CODE                75250020
CCW2740  EQU   *                                                        75300020
         CCW   X0B,N0,X60,N2                                            75310020
WRITECCW EQU   *                                                  20302 75312020
         CCW   N9,*,X20,N21                                             75320020
NLCNT    DC    XL4'000A0000'       LOOP TIO COUNT                       75350020
         DC    X'0A14'             WAIT STATE CODE                      75400020
NUNEXTXT DC    C'*IGF015W   UNEX ERR  '   UNEXPECTED ERROR MESSAGE      75450020
         DC    X'0A04'             WAIT STATE CODE                      75500020
NIOTXT   DC    C'*IGF006W   I/O ERR '    I/O ERROR MESSAGE        20302 75550020
         DC    X'0A16'             WAIT STATE CODE                      75600020
NTODTXT  DC    C'*IGF050W   TOD ERROR ' TOD ERROR MESSAGE               75650020
         EJECT                                                          75700020
*                                                                       75750020
**  MCH POST ROUTINE                                                    75800020
*                                                                       75850020
         DS    0H                                                       75900020
IGFPOST1 EQU   *                                                        75950020
         STM   ADDR1,ADDR2,SAV6    SAVE CALLERS REGS                    76000020
         USING IGFN0000,12                                              76050020
         TM    FLAGBYTE,ACTPOST    IS THIS RTN ALREADY IN PROCESS       76100020
         BO    SKIPPOST            YES                                  76150020
         TM    MCHPSA+K48,XFE      WAS I/O DISABLED WHEN MCI            76200020
         BNZ   MCHPOST1            NO                                   76250020
         OI    FLAGBYTE,ACTPOST    INDICATE  BUSY                       76300020
         L     ADDR1,ADDRS         GET ADDRESS OF NOP IN DISPATCHER     76350020
         MVC   SAVENOP1(K1),K1(ADDR1) SAVE I2 FIELD OF NOP              76400020
         MVI   K1(ADDR1),XF0       MAKE NOP AN UNCONDITIONAL BRANCH     76450020
         LM    ADDR1,ADDR2,SAV6    RESTORE REGS                         76500020
SKIPPOST EQU   *                                                        76550020
         BR    REG2                EXIT                                 76600020
MCHPOST1 EQU   *                                                        76650020
         STM   REG10,REG15,SAV6    SAVE REGS                            76700020
         DROP  12                                                       76750020
         BALR  REG15,N0            ESTABLISH ADDR                       76800020
         USING *,REG15                                                  76850020
         LM    REG10,REG12,PARMLIST GET PARAMETER LIST FOR POST         76900020
         L     REG15,ADPOST        GET ENTRY POINT TO POST              76950020
         BALR  REG14,REG15         LINK TO POST RTN.                    77000020
         DROP  REG15                                                    77050020
         USING *,REG14                                                  77100020
         LM    REG10,REG15,SAV6    RESTORE REGS                         77150020
         BR    REG2                RETURN TO CALLER                     77200020
         DROP  REG14                                                    77250020
*  ENTRY VIA GPR 15 FROM OS SUPERVISOR                                  77300020
IGFPOST2 EQU   *                                                        77350020
         USING *,REG15                                                  77400020
         STM   REG9,REG14,SAV6     SAVE REGS                            77450020
         L     ADDR1,ADDRS         GET ADDRESS OF NOP IN DISPATCHER     77500020
         MVC   K1(K1,ADDR1),SAVENOP1 RESTORE I2 FIELD OF NOP            77550020
         LM    REG10,REG12,PARMLIST GET PARAMETER LIST FOR POST         77600020
         L     REG15,ADPOST        GET ENTRY POINT TO POST RTN          77650020
         BALR  REG14,REG15         LINK TO POST                         77700020
         DROP  15                                                       77750020
         USING *,14                                                     77800020
         NI    FLAGBYTE,XFF-ACTPOST CLEAR BUSY FLAG                     77850020
         L     REG10,X10           GET POINTER TO CVT                   77858000
         L     REG15,CVT0DS        GET ADDRESS OF PT. IN DISP  IG 51213 77900021
         LM    REG9,REG14,SAV6     RESTORE REGS                         77950020
         BR    REG15               GIVE CONTROL BACK TO DISPATCHER      78000020
ADDRS    DC    A(0)                NOP IN BEGINNING OF DISPATCHER       78050020
PARMLIST EQU   *                                                        78100020
         DC    F'0'                ADDR OF ERROR RECORDER INTFACE WD    78150020
         DC    F'0'                ADDRESS OF MCH ECB                   78200020
         DC    A(0)                ADDRESS OF COM. TASK TCB             78250020
ADPOST   DC    A(0)                ADDRESS OF ENTRY TO POST ROUTINE     78300020
SAV6     DS    6F                  SAVE AREA                            78350020
SAVENOP1 DC    X'00'               ONE BYTE SAVE AREA                   78400020
FLAGBYTE DC    X'00'               POST ROUTINE FLAGS                   78450020
FOUR     DC    H'4'                CONSTANT FOR S/A WRITE      @S64611P 78470021
*                                                                       78500020
         DS    0F                                                       78550020
DISABLE  DC    X'82400000'         SOFT MASK-NO LOGS                    78600020
NMASKHI2 DC    X'0000FFFF'         *                                    78650020
NCOMADDR DS    F                   PTR TO MODEL IND. COMMON AREA        78700020
NMODBASE DS    F                   PTR TO TRANSIENT AREA                78750020
PCK4     DC    H'4'                                               GTF   78760000
PCKAF00  DC    X'AF00'             CLASS MASK TABLE ENTRY         GTF   78770000
PCEXEC   DC    X'4400'             EXECUTE IS FOLLOWED BY ZEROES  GTF   78780000
MAINTID  DC    CL8'IGFMCHE0'                                            78790021
MAINT    DC    S(*)                                                     78792021
         DC    10CL4'&REL&LEV'   MAINT SPACE                            78794021
*                                                                       78850020
         DS    0D                  SET TO DOUBLE WORD BOUNDARY          78900020
IGFEND   EQU   *                                                        78950020
IGFSIZE  EQU   IGFEND-IGFSTART     SIZE OF REAL MCH NUC.                79000020
         EJECT                                                          79050020
NCOMAREA DSECT                                                          79100020
         MCHMAC                                                         79150020
         EJECT                                                          79200020
CVTDSECT DSECT                                                          79250020
         CVT                                                            79300020
         EJECT                                                          79350020
MSBSECT  DSECT                                                          79400020
*****  THIS CODE IS A DUMMY FOR THE MSB                                 79450020
DUMMY    EQU   *                                                        79500020
MSBMSCON EQU   DUMMY+40                                                 79550020
MSBHDCPY EQU   DUMMY+44                                                 79600020
         EJECT                                                          79650020
UCMSECT  DSECT                                                          79700020
         IEECUCM                                                        79750020
         EJECT                                                          79800020
UCBSECT  DSECT                                                          79850020
         IEFUCBOB                                                       79900020
         END                                                            79950020
