         TITLE '          IGFMCHE1    MCH CONSOLE WRITE ROUTINE'        00012020
*********************************************************************** 00014020
*  STATUS  -                                                          * 00016020
*  RELEASE 21 CODE ADDED 05/24/71 - IGFMCHE1                          * 00016221
*            LEVEL FOR 20.2-IGFMCHE1 - 01      2/24/71                * 00016420
*            LEVEL FOR 370 -IGFMCHE1 - 01      3/10/71                * 00016820
*                                                                     * 00018020
*  FUNCTION  -                                                        * 00018420
*        THIS MODULE WILL OUTPUT BY ISSUING SVC 35 ANY MESSAGES       * 00018820
*        REQUIRED BY IGFMCHE2 AND THOSE MESSAGES QUEUED BY MCH        * 00019220
*        ROUTINES IN MCHIBUF                                          * 00019620
*                                                                     * 00019720
*  ENTRY POINTS -                                                     * 00019820
*        IGFMCHE1-ENTERED VIA XCTL FROM IGFMCHE2(IGCR107B)            * 00019920
*                                                                     * 00020020
*  INPUT - UPON ENTRY REGISTER 0 CONTAINS THE ADDRESS OF MCHINT WHICH * 00030020
*        IS IN MCH COMMON AREA.                                       * 00040020
*                                                                     * 00050020
*  OUTPUT- MESSAGES ARE QUEUED UP AND OUTPUTTED BY ISSUING SVC 35'S   * 00060020
*                                                                     * 00062020
*  EXTERNAL REFERENCES-                                               * 00064020
*        CVT - CVTCUCB,CVTTCBP                                        * 00066020
*        MCH COMMON AREA - STARTING AT MCHINT                         * 00068020
*        EXTENTED SVRB                                                * 00068420
*        UCM - UCMMODE                                                * 00068820
*                                                                     * 00069220
*  EXIT POINTS-                                                       * 00069620
*        NORMAL-                                                      * 00069720
*          FOR NONMCS IN SYSTEM - XCTL TO IEECVCTR(ROUTER ROUTINE)    * 00069820
*          FOR MCS IN SYSTEM - RETURN VIA REGISTER 14                 * 00069920
*        ERROR-NONE                                                   * 00070020
*                                                                     * 00080020
*  TABLES/WORK AREAS.... INFORMATION MESSAGE TABLE, AND MCHWORK       * 00090020
*                                                                     * 00100020
*   ATTRIBUTES-                                                       * 00110020
*        NONRESIDENT,REENTRANT,SUPERVISOR STATE                       * 00112020
*                                                                     * 00114020
*   NOTES.  MAINTENANCE AREA OF 50 BYTES IS LOCATED AT LABEL MAINT    * 00116020
*                                                                     * 00118020
*********************************************************************** 00118420
         EJECT                                                          00118820
*********************************************************************** 00119220
*  MCHINT IS AN INTERFACE WORD IN MCH COMMON AREA FOR COMMUNICATION   * 00119620
*  PURPOSES BETWEEN MCH, ERR0R RECORDER AND WTO ROUTINES.             * 00119720
*BYTE 0 OF MCHINT                                                     * 00119820
*        BIT 0- 0 ERROR RECORDER FUNCTION NOT NEEDED                  * 00119920
*        BIT 0- 1 INVOKE ERROR RECORDER                               * 00120020
*        BIT 1- 0 WTO FUNCTION NOT NEEDED                             * 00122020
*        BIT 1- 1 INVOKE WTO FUNCTION                                 * 00122420
*        BIT 2-7  RESERVED                                            * 00122820
*BYTE 1                                                               * 00123220
*        BIT 0 - CCH RECORD-FOR EMERGENCY RECORDER ONLY               * 00125220
*        BIT 1 - NO ROOM FOR A LONG RECORD ON SYS1.LOGREC             * 00127220
*BYTE 2  OF MCHINT                                                    * 00129220
*        BIT 0 - LOGREC FULL MSG TO BE OUTPUTTED                      * 00129620
*        BIT 1 - I/O ERROR MSG TO BE OUTPUTTED                        * 00129720
*        BIT 2 - DISK FORMAT ERROR MSG TO BE OUTPUTTED                * 00129820
*               BIT 3 - MCHIBUF CLOBBERED FLAG                        * 00130221
*               BIT 4 - LOGREC NEAR FULL MSG TO BE OUTPUTTED          * 00130621
*               BIT 5-7 - RESERVED                                    * 00131021
* BYTE 3 - RESERVED                                                   * 00131421
*********************************************************************** 00131821
         EJECT                                                          00132420
IGFMCHE1 CSECT                                                          00132820
         SPACE                                                          00133220
***************************   E Q U A T E S   ************************* 00135220
REG0     EQU   0                   PARAMETER REGISTER                   00137220
REG1     EQU   1                                                        00139220
RMSBASE  EQU   2                   BASE FOR MCHINT                      00139620
MSGPTR   EQU   4                   PTR TO MCHIBUF                       00139720
R5       EQU   5                   MESSAGE TABLE                        00139820
R6       EQU   6                   WORK REG                             00139920
R7       EQU   7                                                        00140020
WORK1    EQU   8                                                        00142020
R8       EQU   8                                                        00142420
CVTREG   EQU   9                   CVT REG.                             00142820
UCMREG   EQU   10                  UCM REGISTER                         00143220
BASE     EQU   12                  BASE REG FOR MODULE                  00145220
R14      EQU   14                  RETURN REGISTER FOR MCS ONLY         00147220
R15      EQU   15                  ADDR OF EXTENDED SVRB                00149220
         SPACE                                                          00149620
K0       EQU   0                   DECIMAL VALUE OF 0                   00149720
K2       EQU   2                   DECIMAL VALUE OF 2                   00149820
K3       EQU   3                   DECIMAL VALUE OF 3                   00149920
K4       EQU   4                   DECIMAL VALUE OF 4                   00150020
K5       EQU   5                   DECIMAL VALUE OF 5                   00152020
K6       EQU   6                   DECIMAL EQUATE                       00152120
K8       EQU   8                   DECIMAL VALUE OF 8                   00152420
K10      EQU   10                  DECIMAL EQUATE                       00152520
K13      EQU   13                  DECIMAL VALUE OF 13                  00152820
K7       EQU   7                   DECIMAL VALUE OF 7                   00152921
K9       EQU   9                   DECIMAL VALUE OF 9                   00153021
K96      EQU   96                  DECIMAL VALUE OF 96                  00153220
         SPACE                                                          00155220
FULL     EQU   X'80'               LOGREC FULL INDICATOR                00157220
POINT    EQU   X'4B'               PRINTABLE PERIOD                     00158221
FULLOFF  EQU   X'7F'                                                    00159220
CLOBBER  EQU   X'10'               MSG I BUFFER CLOBBER FLAG            00159620
X0       EQU   0                                                        00159720
X1       EQU   1                                                        00159820
X3       EQU   3                                                        00159920
X4       EQU   4                                                        00160020
X5       EQU   5                                                        00162020
X6       EQU   6                                                        00162420
X00      EQU   X'00'               CLEAR FLAG BYTE                      00162820
X10      EQU   X'10'               FLAG                                 00163220
X19      EQU   X'19'               BUFFER MESSAGE CODE         @S66681P 00163621
XC1      EQU   X'C1'               CHARACTER A                 @S66681P 00164021
X20      EQU   X'20'               MASK OF 20                           00164420
X40      EQU   X'40'               MASK OF 40                           00166420
X80      EQU   X'80'               MASK FOR DYNAMIC MESSAGE             00166820
XC5      EQU   X'C5'               E CHARACTER                          00166920
X08      EQU   X'08'               *                                    00167021
XFF      EQU   X'FF'               MASK OF FF                           00167220
**********************************************************************  00169900
         EJECT                                                          00171100
**********************************************************************  00172300
         BALR  BASE,K0             SET UP BASE REGISTER                 00173500
         USING *,BASE                                                   00174700
         USING MCHAREA,RMSBASE                                          00175900
         USING SVRBXSA,R15                                              00177100
         USING CVTSECT,CVTREG                                           00178300
         USING UCM,UCMREG                                               00179500
         L     CVTREG,CVTPTR       ADDR OF CVT                          00180700
         LR    RMSBASE,REG0        GET ADDRESS OF MCHINT FROM PARAMETER 00181900
*                                  REGISTER                             00183100
         LA    RMSBASE,K0(RMSBASE) CLEAR POST CODE IN HIGH ORDER BYTE   00184300
         ST    R14,R14SAVE         SAVE REGISTER 14 FOR MCS RETURN ONLY 00185500
         TM    MCHINT,X40          TEST FOR WTO FUNCTION NEEDED         00186700
         BZ    XCTLEXIT            NOT NEEDED - EXIT                    00187900
         LA    MSGPTR,MCHIBUF      ADDRESS OF BEGINNING OF MESSAGE BUF  00189100
         SPACE                                                          00190300
BEGIN    EQU   *                                                        00191500
         MVC   WTOBUFF(WTOLEN),WTOCODE MOVE WTO CODE INTO MCHWORK AREA  00192700
CHECKLOG EQU   *                                                        00193900
         TM    MSGFLAG,FULL        TEST FOR LOGREC FULL FLAG            00195100
         BO    LOGFULL             YES-GO QUEUE MESSAGE                 00196300
         TM    MSGFLAG,X40         TEST FOR I/O ERROR FLAG              00197500
         BO    IOERROR             GO TO OUTPUTI/O ERROR MSG            00198700
         TM    MSGFLAG,X20         TEST FOR DISK FORMAT ERROR           00199900
         BO    DISKERR             DISK FORMAT ERR MSG TO BE OUTPUTTED  00201100
        SPACE                                                           00201721
         TM    MSGFLAG,X08         TEST FOR LOGREC NEAR FULL            00202321
         BO    NEARFULL            GO OUTPUT MESSAGE                    00202921
         SPACE                                                          00203600
CHECKWTO EQU   *                                                        00204000
         C     MSGPTR,MCHIPTR      IS THERE AN ENTRY IN MSG BUFFER      00204700
         BE    EXIT1               NO GO TO EXIT                        00205900
         CLI   X0(MSGPTR),X19      TEST FOR BUFFER DISABLE FLAG         00206321
         BE    BUFDISAB            GO TO PROCESS MESSAGE       @S66681P 00206721
         LA    R7,WTOTBEND         ADDR OF END OF TABLE                 00207100
         SR    R6,R6               CLEAR WORK REG                       00208300
         SPACE                                                          00209500
LOOPMSG  LA    R5,WTOMGTAB         BEG OF TABLE OF MESSAGES             00210700
WTOMSG   CLC   X0(X1,R5),X0(MSGPTR) IS THIS THE ENTRY CORRESPONDING     00211900
*                                  TO THE SPECIFIED MESSAGE             00213100
         BE    MOVEMSG             YES                                  00214300
         IC    R6,X1(R5)           LOAD LENGTH OF TABLE ENTRY           00215500
         AR    R5,R6               UPDATE TABLE PTR                     00216700
         CR    R5,R7               IS THIS END OF TABLE                 00217900
         BNE   WTOMSG              TEST NEXT ENTRY                      00219100
         B     EXIT1               END OF TABLE-EXIT                    00220300
         SPACE                                                          00221500
MOVEMSG  EQU   *                                                        00222700
         MVI   DESCODE+K3,X00      CLEAR 10 ROUTING CODE          M0746 00223900
         MVI   DESCODE+K2,X40      REINTIALIZE 2 ROUTING CODE  @S66681P 00224521
         MVC   MSGNO(X4),K2(R5)    MOVE 4 CHARACTER MSG NO TO TEXT      00225100
         TM    X0(MSGPTR),X80      IS THIS DYNAMIC MESSAGE              00226300
         BZ    WTODATA             NO-GO SET UP FOR PREFORMATED MSG     00227500
*SET UP FOR BUILDING WTO FOR A DYNAMIC MESSAGE                          00228700
         LA    R8,K2(MSGPTR)       LOAD ADDR OF DATA IN I-BUFFER        00229900
         IC    R6,X1(MSGPTR)       LOAD LENGTH TO BE MOVED              00231100
         AR    MSGPTR,R6           UPDATE MSG BUFFER                    00232300
         LA    MSGPTR,K2(MSGPTR)   PTR TO NEXT ENTRY                    00233500
         BCTR  R6,X0               DECREMENT BY 1 FOR EX INSTRUCTION    00234700
         SPACE                                                          00235900
EXMOVE   EX    R6,WTOLOAD          MOVE DATA INTO TEXT                  00237100
         TM    MSGFLAG,CLOBBER     MSG BUFFER BEEN CLOBBERED            00238300
         BZ    CONTINUE            CONTINUE                             00239500
         NI    MSGFLAG,XFF-CLOBBER CLEAR CLOBBER MSG FLAG               00240700
         LA    MSGPTR,MCHIBUF      ADDRESS OF BEGINNING OF MESSAGE BUF  00241900
         B     CHECKWTO            START SCANNING MGS BUFFER AGAIN      00243100
         SPACE                                                          00244300
CONTINUE EQU   *                                                        00245500
* UPON REACHING THIS POINT, REG 6 HAS LENTH OF DATA -1                  00246700
         LA    R6,K13(R6)          GET TOTAL LENGTH OF WTO SO IT CAN    00247900
         LA    R5,WTOBUFF          ADDRESS OF WTO CODE                  00249921
         CLI   K10(R5),XC1         Q.IS TYPE A MESSAGE         @S66681P 00250821
         BE    SETDESCA            YES,CONTINUE                @S66681P 00251721
         CLI   K10(R5),XC5         I OR E TYPE MESSAGE            M0746 00252700
         BE    SETDESCD            E MESSAGE-DESC CODE IS 3       M0746 00253900
         MVI   DESCODE,X10         I MESSAGE-DESC CODE IS 4       M0746 00255100
ISSUEWTO EQU   *                                                  M0746 00256300
         AR    R5,R6               GET END OF WTO MESSAGE               00257500
         TIME  DEC                 ISSUE TIME MACRO                     00257721
         ST    REG0,TIME           PUT TIME INTO MESSAGE                00257921
         UNPK  X3(K7,R5),TIME(K4)  CHANGE TO PRINTABLE                  00258121
         MVC   K2(K4,R5),X3(R5)    MOVE TO INSERT PERIOD                00258321
         MVI   X6(R5),POINT        INSERT PERIOD                        00258521
         MVC   X1(K2,R5),K2(R5)    MOVE FOR ANOTHER PERIOD              00258721
         MVI   X3(R5),POINT        INSERT PERIOD                        00258921
         MVC   K9(K4,R5),DESCODE   MOVE DECS. AND ROUTER CODES          00259121
         LA    R6,K9(R6)           ADD TIME STAMP TO LENGTH             00259321
         STH   R6,WTOBUFF          PUT LENGTH INTO MESSAGE              00259521
*   NOW ISSUE WTO FOR THE MESSAGE                                       00259721
         LA    REG1,WTOBUFF        RESTORE REG 1 TO ISSUE WTO           00259921
         WTO   MF=(E,(1))          ISSUE WTO                            00261100
         B     BEGIN               RETURN TO BEGINNING                  00262300
         SPACE                                                          00263500
SETDESCD EQU   *                                                  M0746 00264720
         MVI   DESCODE,X20         SET DESC CODE OF 3 FOR E MSG   M0746 00265100
         B     ISSUEWTO            GO ISSUE WTO                   M0746 00265520
SETDESCA EQU *                                                 @S66681P 00265621
         MVI   DESCODE,X40         SET DESC CODE OF 2 FOR MESSAGE A     00265721
         B     ISSUEWTO            GO ISSUE WTO                @S66681P 00265821
         SPACE 3                                                        00265920
WTODATA  LA    R8,X6(R5)           LOAD ADDR OF DATA IN MSG TABLE       00314720
         IC    R6,X1(R5)           LOAD LENGTH OF TABLE ENTRY           00364720
         SH    R6,SEVEN            COMPUTE LENGTH OF DATA TO BE MOVED   00414720
         LA    MSGPTR,X1(MSGPTR)   UPDATE I BUFFER PTRO TO NEXT         00464720
         B     EXMOVE              GO TO MOVE IN TEXT                   00514720
BUFDISAB EQU *                                                 @S66681P 00522721
         MVI   DESCODE+K2,X80      ROUTING CODE IS 1,10 FOR MASTER      00530721
         MVI   DESCODE+K3,X40      CONSOLE ACTION,MAINTENANCE  @S66681P 00538721
         LA    R5,BUFMSG           ADDR OF MESSAGE             @S66681P 00546721
         B     SETUP               GO PREPARE FOR MESSAGE OUTPUT        00554721
         SPACE                                                          00564720
LOGFULL  EQU   *                                                        00614720
         NI    MSGFLAG,XFF-FULL    TURN OFF LOGREC FULL FLAG            00664720
         LA    R5,LOGMSG           ADDR OF LOGREC FULL MSG NO           00714720
         B     SETUP               GO AND SET UP MSG FOR OUTPUTTING     00764720
IOERROR  EQU   *                                                        00814720
         MVI   DESCODE+K3,X40      SYSTEM ERROR-ROUT CODE IS 2,10 M0746 00824700
         NI    MSGFLAG,XFF-X40     TURN OFF I/O ERROR MSG FLAG          00864720
         LA    R5,IOMSG            GET ADDR OF MSG                      00914720
         B     SETUP               GO AND SET UP MSG FOR OUTPUTTING     00964720
NEARFULL EQU   *                                                        00972721
         NI    MSGFLAG,XFF-X08     TURN OFF FLAG                        00980721
         LA    R5,NEARMSG          GET MSG TEXT ADDRESS                 00988721
         MVI   DESCODE+K2,X80      SET ROUTING CODE OF 1 FOR MSG        00996721
         B     SETUP               GO SETUP MESSAGE                     01004721
DISKERR  EQU   *                                                        01014720
         MVI   DESCODE+K3,X40      SYSTEM ERROR-ROUT CODE IS 2,10 M0746 01024700
         NI    MSGFLAG,XFF-X20     TURN OFF DISK FORMAT ERRMSG FLAG     01064720
         LA    R5,DISKMSG          GET ADDR OF MSG                      01114720
SETUP    EQU   *                                                        01164720
         MVC   MSGNO(X4),K0(R5)    MOVE 4 CHARACTER MSG NO TO TEXT      01214720
         SR    R6,R6               CLEAR REG                            01264720
         IC    R6,K4(R5)           GET LENGTH OF MSG-1                  01314720
MOVE     EX    R6,SPECWTO          GO MOVE DATA INTO TEXT               01364720
         B     CONTINUE            GO ISSUE WTO                         01414720
SPECWTO  MVC   DATA(X0),K5(R5)     MOVE DATA INTO WTO TEXT              01464720
         SPACE                                                          01514720
EXIT1    EQU   *                                                        01564720
         LA    R8,MCHIBUF          GET START ADDRESS OF MSG BUFFER      01614720
         ST    R8,MCHIPTR          TO REINITIALIZE PTR TO MSG BUFFER    01664720
XCTLEXIT EQU   *                                                        01714720
         L     UCMREG,CVTCUCB      GET ADDDRESS OF UCM                  01764720
         TM    UCMMODE,UCMMCS      MCS IN THE SYSTEM                    01814720
         BO    MCSEXIT             YES-DO SPECIAL EXIT FOR MCS          01864720
         L     R15,CVTTCBP         LOAD PTR TO NEW/OLD TCB PTRS         01914720
         L     R15,K4(R15)         LOAD OLD(CURRENT) TCB PTR            01964720
         L     R15,K0(R15)         LOAD PTR TO CURRENT RB (SVRB)        02014720
         LA    R15,K96(R15)        PTR TO EXTENDED SAVE AREA IN SVRB    02064720
         LR    REG1,R15            LOAD PTR TO CXSA INTO PROCESSOR'S    02114720
*                                  PARAMETER LIST                       02164720
         LA    WORK1,K8(R15)                                            02214720
         ST    WORK1,CSANPTR       *+8 FOR XCTL IN CXSA                 02264720
         XC    CSADCBP(K4),CSADCBP ZERO DCB POINTER IN CXSA             02314720
         MVC   CSANAME(K8),EXTNAME MOVE NAME OF ROUTER MODULE INTO      02364720
*                                  XCTL PARAMETER LIST IN XSA           02414720
         XCTL  SF=(E,(15))         *EXIT                                02464720
MCSEXIT  EQU   *                                                        02514720
* THIS CODE IS FOR A RETURN TO WAIT ROUTINE (IEECMQWR(MVT) OR IEECMAWR  02564720
* (MFT)) FOR MCS IN THE SYSTEM                                          02614720
         L     R14,R14SAVE         RESTORE RETURN ADDRESS               02664720
         BR    R14                 GO TO ROUTER PORTION OF WAIT ROUTINE 02714720
EXTNAME  DC    CL8'IGC0007B'       NAME OF ROUTER MODULE                02764720
         EJECT                                                          02814720
*********************************************************************** 02864720
*                  INFORMATION MESSAGE (IGFXXXX) TABLE                * 02914720
*        THIS TABLE HAS TWO TYPES OF ENTRIES, ONE FOR PREFORMATED     * 02964720
*        MESSAGES AND THE OTHER FOR DYNAMIC MESSAGES. THESE ARE       * 03014720
*        ILLUSTRATED BELOW.                                           * 03064720
*                                                                     * 03114720
*        PREFORMATED MESSAGES IN MESSAGE TABLE                        * 03164720
*              * CODE * LEN. * MSG. NO. * PREFORMATED DATA   *        * 03214720
*              ***********************************************        * 03264720
*              *- 1B -*- 1B -*--- 4B ---*------- LEN-6 ------*        * 03314720
*        DYNAMIC MESSAGES IN MESSAGE TABLE                            * 03364720
*              * CODE * LEN. * MSG. NO. *                             * 03414720
*              **************************                             * 03464720
*              *- 1B -*- 1B -*--- 4B ---*                             * 03514720
*                                                                     * 03564720
*              LEN.=6                                                 * 03614720
*********************************************************************** 03664720
*                         MCHIBUF                                     * 03714720
*        MCHIBUF ALSO HAS TWO TYPES OF ENTRIES, ONE FOR PREFORMATED   * 03764720
*        MESSAGES AND THE OTHER FOR DYNAMIC MESSAGES.  THESE ARE      * 03814720
*        ILLUSTRATED BELOW.                                           * 03864720
*        PREFORMATED MESSAGES IN MCHIBUF                              * 03914720
*              * CODE *                                               * 03964720
*              ********                                               * 04014720
*              *- 1B -*                                               * 04064720
*         DYNAMIC  MESSAGES IN MCHIBUF                                * 04114720
*              * CODE * LEN. * DATA   *                               * 04164720
*              ************************                               * 04214720
*              *- 1B -*- 1B -*- LEN. -*                               * 04264720
*              WHERE LEN = LENGTH OF ACTUAL DATA                      * 04314720
*********************************************************************** 04364720
         SPACE                                                          04414720
WTOMGTAB EQU   *                                                        04464720
         DC    X'010E'             ENTRY IGF015I UNEX ERR               04514720
         DC    C'015IUNEX ERR'           CODE=01,LENGTH=0E,PREFORMATED  04564720
         DC    X'020B'             ENTRY IGF020I ABEND                  04614720
         DC    C'020IABEND'              CODE=02,LENGTH=0B,PREFORMATED  04664720
         DC    X'050E'             ENTRY IGF023I BLDL DLT               04714720
         DC    C'023IBLDL DLT'           CODE=05,LENGTH=0E,PREFORMATED  04764720
         DC    X'8606'             ENTRY IGF024I                        04814720
         DC    C'024I'                  CODE=86,LENGTH=06,DYNAMIC       04864720
         DC    X'8706'             ENTRY IGF029I                        04914720
         DC    C'029I'                   CODE=87,LEN=06,DYNAMIC         04964720
         DC    X'8806'             ENTRY IGF032I                        05014720
         DC    C'032I'                   CODE=88,LEN=06,DYNAMIC         05064720
         DC    X'090E'             ENTRY IGF033E RUN EREP               05114720
         DC    C'033ERUN EREP'           CODE=09,LEN=0E,PREFORMATED     05164720
         DC    X'0A0E'             ENTRY IGF041I STAT ERR               05214720
         DC    C'041ISTAT ERR'           CODE=0A,LEN=0E,PREFORMATED     05264720
         DC    X'0B0D'             ENTRY IGF042I HSM-ERR                05314720
         DC    C'042IHSM-ERR'            CODE=0B,LEN=0D,PREFORMATED     05364720
         DC    X'0C0D'             ENTRY IGF043I HIR CNT                05414720
         DC    C'043IHIR CNT'            CODE=0C,LEN=0D,PREFORMATED     05464720
         DC    X'0D0D'             ENTRY IGF043I ECC CNT                05514720
         DC    C'043IECC CNT'            CODE=0D,LEN=0D,PREFORMATED     05564720
         DC    X'0E14'             ENTRY IGF044I ECC CORRECTED          05614720
         DC    C'044IECC SUCCESSFUL'     CODE=0E,LEN=14,PREFORMATED     05664720
         DC    X'0F18'             ENTRY IGF045I MULTIPLE BIT ERROR     05714720
         DC    C'045IMULTIPLE BIT ERROR' CODE=0F,LEN=18,PREFORMATED     05764720
         DC    X'9006'             ENTRY IGF046I                        05814720
         DC    C'046I'                   CODE=90,LEN=06,DYNAMIC         05864720
         DC    X'9106'             ENTRY IGF047I                        05914720
         DC    C'047I'                   CODE=91,LEN=06,DYNAMIC         05964720
         DC    X'1214'             ENTRY IGF048I HIR CORRECTED          06014720
         DC    C'048IHIR SUCCESSFUL'     CODE=12,LENGTH=14,PREFORMATED  06064720
         DC    X'140F'             ENTRY IGF051I HRT ERROR              06114720
         DC    C'051IHRT ERROR'          CODE=14,LEN=0F,PREFORMATED     06164720
         DC    X'9506'             ENTRY IGF052I                        06214720
         DC    C'052I'                   CODE=95,LEN=06,DYNAMIC         06264720
         DC    X'1618'             ENTRY IGF055I QUIET MODE ECC,HIR     06314720
         DC    C'055IQUIET MODE ECC,HIR' CODE=16,LEN=18,PREFORMATED     06364720
         DC    X'1714'             ENTRY IGF055I QUIET MODE ECC         06414720
         DC    C'055IQUIET MODE ECC'     CODE=17,LEN=14,PREFORMATED     06464720
         DC    X'1810'             ENTRY IGF055I QUIET MODE             06514720
         DC    C'055IQUIET MODE'         CODE=18,LEN=10,PREFORMATED     06564720
         DC    X'9A06'             ENTRY IGF059I 2880 CHAN MSG          06674720
         DC    C'059I'                   CODE=9A,LENG=06,DYNAMIC        06684720
         DC    X'A006'             ENTRY IGF040I SUBSYSTEM MESSAGE      06714720
         DC    C'040I'                   CODE=20,LENG=06,DYNAMIC        06764720
         DC    X'1B12'             ENTRY IGF063I SVC BLDL DLT           06774721
         DC    C'063ISVC BLDL DLT'       CODE=1B,LEN=12,PREFORMATED     06784721
WTOTBEND EQU   *                                                        06814720
         SPACE                                                          06864720
LOGMSG   DC    C'054E'              IGF054E MESSAGE                     06914720
         DC    X'0F'               LENGTH OF MESSAGE -1                 06964720
         DC    C'SYS1.LOGREC FULL' MESSAGE FOR LOGREC FULL              07014720
         SPACE                                                          07064720
IOMSG    DC    C'056I'              IGF056I MESSAGE                     07114720
         DC    X'12'               LENGTH OF MESSAGE -1                 07164720
         DC    C'I/O ERR IN RECORDER' MESSAGE                           07214720
         SPACE                                                          07264720
DISKMSG  DC    C'057E'              IGF057E MESSAGE                     07314720
         DC    X'10'               LENGTH OF MESSAGE -1                 07364720
         DC    C'DISK FORMAT ERROR' MESSAGE                             07414720
NEARMSG  EQU   *                                                        07424721
         DC    C'060E'             IGF060E SYS1.LOGREC NEAR FULL MSG    07434721
         DC    X'14'               LENGTH OF MSG -1                     07444721
         DC    C'SYS1.LOGREC NEAR FULL' MESSAGE TEXT                    07454721
BUFMSG   DC    C'058A'             IGF058A MESSAGE             @S66681P 07456721
         DC    X'0E'               LENGTH OF MESSAGE -1        @S66681P 07458721
         DC    C'BUFFER DISABLED'  MESSAGE                     @S66681P 07460721
         SPACE                                                          07464720
         DS    0F                  GET ON FULL WORD BOUNDARY            07514720
WTOLOAD  MVC   DATA(X0),K0(R8)     MOVE DATA INTO WTO TEXT              07564720
WTOCODE  WTO   'IGF                                     ',MF=L,        *07594721
               ROUTCDE=(2),DESC=(3)                                     07624721
         SPACE                                                          07664720
*************************   C O N S T A N T S   *********************** 07714720
ENDWTO   DS    0H                  GET ON HALF WORD BOUNDARY            07764720
SEVEN    DC    X'0007'             CONSTANT OF SEVEN                    07814720
WTOLEN   EQU   ENDWTO-WTOCODE      LENGTH OF WTO MESSAGE                07864720
MAINT    DC    XL50'0'                  MAINTENANCE SPACE               07914720
         EJECT                                                          07964720
CVTSECT  DSECT                                                          08014720
         CVT   SYS=MVT OR VMS                                           08064720
         EJECT                                                          08114720
UCM      DSECT                                                          08164720
         IEECUCM                                                        08214720
         EJECT                                                          08264720
SVRBXSA  DSECT                                                          08314720
         IEECVMUG CXSA                                                  08364720
         EJECT                                                          08414720
* COMMON AREA LOCATIONS USED BY ERROR RECORDED AND WRITE TO OPERATOR    08464720
* ROUTINES                                                              08514720
MCHAREA  DSECT                                                          08564720
MCHINT   DS    F                   INTERFACE WORD                       08614720
MCHIPTR  DS    F                   POINTER TO MESSAGE BUFFER            08664720
MCHIBUF  DS    25F                 MESSAGE BUFFER                       08714720
MCHWORK  DS    30F                 WORK AREA                            08814720
MCHLONG  DS    F                   POINTER TO LONG ABREC                08824720
MCHBUILD DS    F                   MCH RECORD BUILD AREA PTR            08834720
MCHINLOG DS    F                   POINTER TO INDEPENDENT LOG           08864720
MCHREMCH DS    F                   POINTER TO DAMAGE ASSESSMENT DATA    08914720
MCHENQ   DS    F                   SAVE AREA FOR ENQUEING               08934721
MCHABRNO DS    CL1                 NUMBER OF ABREC BUFFERS              08964720
MCHABREC EQU   *                   ABREC BUFFERS                        09014720
         SPACE                                                          09064720
MSGFLAG  EQU   MCHINT+2            BYTE IN MCHINT FOR MESSAGE FLAGS     09114720
R14SAVE  EQU   MCHWORK             SAVE AREA FOR RETURN ADDR FOR MCS    09116720
WTOBUFF  EQU   MCHWORK+6           AREA FOR MESSAGE BUILD               09124720
MSGNO    EQU   MCHWORK+13          AREA FOR MESSAGE NUMBER              09164720
DATA     EQU   MCHWORK+18          AREA FOR MESSAGE TEXT                09214720
DESCODE  EQU   MCHWORK+50          WTO DESCRIPTER AND ROUTER CODES      09244721
TIME     EQU   MCHWORK+116         AREA TO STORE TIME                   09274721
         END                                                            09314720
