         TITLE '         IGFMCHE2    MCH ERROR RECORDER MODULE'         00050020
IGFMCHE2 CSECT                                                          00100020
         SPACE                                                          00150020
*********************************************************************** 00200020
*  TITLE- IGFMCHE2  RECORDER                                          * 00210020
*  STATUS -                                                           * 00250020
*  RELEASE 21 CODE ADDED 02/24/70 - IGFMCHE2                          * 00255021
*          LEVEL FOR 20.3-IGFMCHE2 - 00      2/05/71                  * 00260020
*          LEVEL FOR 370 -IGFMCHE2 - 01      2/03/71                  * 00270020
*          LEVEL FOR 21.7-IGFMCHE2 - 03      2/14/73         IC  60509* 00280021
*  FUNCTION/OPERATION-                                                * 00300020
*        THIS MODULE WILL RECORD ABBREVIATED RECORDS(ABREC) OR A TOTAL* 00350020
*        RECORD(ABREC,INDEPENDENT LOG,EXTENDED LOG,AND MCH DATA) ON   * 00400020
*        SYS1.LOGREC.                                                 * 00450020
*        1. AN ACTIVE ABREC BUFFER IS FOUND AND A FLAG IS SET TO      * 00500020
*        INDICATE THE TYPE OF THE RECORD.                             * 00550020
*        2. THE HEADER RECORD IS READ FROM SYS1.LOGREC AND THIS       * 00600020
*        ROUTINE DETERMINES IF ENOUGH SPACE IS LEFT ON DATA SET       * 00650020
*        ACCORDING TO I/O DEVICE TYPE FOR THE RECORD.                 * 00700020
*        3. IF THERE IS ENOUGH SPACE LEFT ON DATA SET, THE RECORD     * 00750020
*        WRITTEN. THEN EOF IS WRITTEN.                                * 00800020
*        IF ENOUGH SPACE IS NOT LEFT ON THE DATA SET A FLAG IS SET TO * 00850020
*        INDICATE TO IGFMCHE1(WTORTN) THAT A MESSAGE MUST BE OUTPUTTED* 00900020
*        TO THE EFFECT THAT SYS1.LOGREC IS FULL. CONTROL IS           * 00950020
*        PASSED TO IGFMCHE1 WHEN NEITHER A SHORT OR A LONG RECORD     * 01000020
*        WILL FIT ON THE DATA SET.                                    * 01050020
*        4. THE UPDATED HEADER IS WRITTEN BACK ON SYS1.LOGREC.        * 01100020
*        THIS ROUTINE WILL CONTINUE PROCESSING UNTIL ALL ACTIVE       * 01150020
*        BUFFERS HAVE BEEN PROCESSED.                                 * 01200020
*        THIS RECORDING MODULE CHECKS FOR A LONG RECORD THAT HAS BEEN * 01250020
*        CLOBBERED WHILE THE RECORDING MODULE IS PROCESSING THE       * 01300020
*        RECORD.  IF THIS OCCURS, THE FLAGS IN ABREC ARE CLEARED AND  * 01350020
*        CONTROL IS RETURNED TO BEGINNING OF THE MODULE.              * 01400020
*  ENTRY POINTS                                                       * 01450020
*        IGFMCHE2-ENTERED VIA XCTL FROM COMMUNICATIONS TASK ROUTER    * 01500020
*  INPUT - UPON ENTRY REGISTER 0 CONTAINS THE POST CODE OF UCMRECB(RMS* 01550020
*        ECB).THE POST CODE CONTAINS IN THE THREE LOW ORDER BYTES THE * 01600020
*        ADDRESS OF MCHINT WHICH IS THE WORK AREA FOR THIS MODULE.    * 01650020
*  OUTPUT-                                                            * 01700020
*        RECORDS ARE WRITTEN OUT ON SYS1.LOGREC.                      * 01750020
*        REGISTER 0 CONTAINS ADDRESS OF MCHINT FOR SECOND LOAD        * 01800020
*  EXTERNAL REFERENCES-                                               * 01850020
*        MCHINT WHICH IS PART OF MCH COMMON AREA                      * 01900020
*        EXTENDED SAVE AREA FOR SVRB.                                 * 01950020
*        CVT - CVTDCB,CVTTCBP                                         * 02000020
*  EXIT POINTS-                                                       * 02050020
*        NORMAL-XCTL TO IGFMCHE1 WHICH OUTPUTS MESSAGES               * 02100020
*        ERROR-XCTL TO IGFMCHE1 WITH A FLAG SET TO INDICATE MESSAGE   * 02150020
*        TO BE OUTPUTTED.                                             * 02200020
*        ERROR CONDITIONS-                                            * 02250020
*        1.AN I/O ERROR                                               * 02300020
*        2.HEADER RECORD ON SYS1.LOGREC NOT FORMATED CORRECTLY        * 02350020
*        3.ATTEMPT TO ACCESS INFORMATION NOT IN EXTENT                * 02400020
*  TABLES/WORK AREAS-                                                 * 02450020
*        MCHWORK                                                      * 02500020
*  ATTRIBUTES-                                                        * 02550020
*        NONRESIDENT,REENTRANT,SUPERVISOR STATE                       * 02600020
*  NOTES-                                                             * 02650020
*        MAINTENANCE SPACE                                            * 02660020
*        A DC OF 50 BYTES WITH THE LABEL                              * 02670020
*        *****MAINT*****                                              * 02680020
*                                                                     * 02700020
*********************************************************************** 02750020
         EJECT                                                          02800020
*********************************************************************** 02850020
*BYTE 0 OF MCHINT                                                     * 02900020
*        BIT 0- 0 ERROR RECORDER FUNCTION NOT NEEDED                  * 02950020
*        BIT 0- 1 INVOKE ERROR RECORDER                               * 03000020
*        BIT 1- 0 WTO FUNCTION NOT NEEDED                             * 03050020
*        BIT 1- 1 INVOKE WTO FUNCTION                                 * 03100020
*        BIT 2-7  RESERVED                                            * 03150020
*BYTE 1 OF MCHINT -                                                   * 03200020
*        BIT 0-1 CCH RECORD(FOR EMERGENCY RECORDER ONLY)              * 03250020
*        BIT 1-1 NO ROOM FLAG FOR A LONG RECORD                       * 03300020
*        BIT 2-7 RESERVED                                             * 03350020
*BYTE 2  OF MCHINT                                                    * 03400020
*        BIT 0 - LOGREC FULL MSG TO BE OUTPUTTED                      * 03450020
*        BIT 1 - I/O ERROR MSG TO BE OUTPUTTED                        * 03500020
*        BIT 2 - DISK FORMAT ERROR MSG TO BE OUTPUTTED                * 03550020
*        BIT 3 - MCHIBUF CLOBBERED FLAG                               * 03570021
*        BIT 4 - SYS1.LOGREC NEAR FULL MESSAGE TO BE OUTPUTTED        * 03590021
*        BIT 5-7 RESERVED                                             * 03610021
*BYTE 3 OF MCHINT - RESERVED                                          * 03650020
*********************************************************************** 03700020
         EJECT                                                          03750020
*                             ABREC FORMAT                            * 03800020
         SPACE 3                                                        03850020
*********************************************************************** 03900020
*       *                                                             * 03950020
* +0    *                     HEADER                                  * 04000020
*       *                                                             * 04050020
*       *                                                             * 04100020
*       *                                                             * 04150020
*       *************************************************************** 04200020
*       *                                                             * 04250020
* +24   *                     PROG ID                                 * 04300020
*       *                                                             * 04350020
*       *************************************************************** 04400020
*       *                                                             * 04450020
* +32   *                     JOB  ID                                 * 04500020
*       *                                                             * 04550020
*       *************************************************************** 04600020
*       *                                                             * 04650020
* +40   *                     MCOPSW                                  * 04700020
*       *                                                             * 04750020
*       *************************************************************** 04800020
*       *                                                             * 04850020
* +48   *                     MCIC                                    * 04900020
*       *                                                             * 04950020
*       *************************************************************** 05000020
*       *                                                             * 05050020
* +56   *                     MCH INDEPENDENT SUMMARY                 * 05100020
*       *                     PURGED RECORD COUNTERS                  * 05150020
*       *                                                             * 05200020
*       *************************************************************** 05250020
*       *              *                                                05300020
* +70   *    FLAG      *                                                05350020
*       *              *                                                05400020
************************                                                05450020
         SPACE 3                                                        05500020
*********************************************************************** 05550020
*        FLAG                                                         * 05600020
*        BIT 0 ACTIVE BUFFER                                          * 05650020
*        BIT 1 SHORT ABREC                                            * 05700020
*        BIT 2 LONG ABREC(INCLUDES ABREC,INDEPENDENT LOG,EXTENDED LOG,* 05750020
*              AND MCH DATA),                                         * 05800020
*        BIT 3 CLOBBER                                                * 05850020
*        BITS 4-7 RESERVED                                            * 05900020
*********************************************************************** 05950020
         EJECT                                                          06000020
*                                                                     * 06030021
*     S Y S 1 . L O G R E C   H E A D E R   R E C O R D   A R E A     * 06060021
*                                                                     * 06090021
*                                                                     * 06120021
*       *************************************************************** 06150021
*       *               *                               *             * 06180021
*  +0   *   F F F F     *          LOW EXTENT           *    EXTENT   * 06210021
*       *               *            (CCHH)             *     (CC)    * 06240021
*       *************************************************************** 06270021
*       * HIGH EXTENT   *       *      RECORD ENTRY AREA ADDRESS      * 06300021
*  +8   *   (CONT.)     * SPARE *             (BBCCHHR)               * 06330021
*       *     (HH)      *       *                                     * 06360021
*       *************************************************************** 06390021
*       *  REC. ENTRY   *  REMAINING     *  TOTAL BYTES *  ADDRESS OF * 06420021
*  +16  *  AREA ADDR.   *   BYTES ON     *      ON      *  LAST RECORD* 06450021
*       *    (CONT.)    *    TRACK       *    TRACK     *   WRITTEN   * 06480021
*       *************************************************************** 06510021
*       *           ADDRESS OF LAST RECORD       *    TRACKS   * EARLY* 06540021
*  +24  *                WRITTEN (CONT.)         *      PER    * WARN * 06570021
*       *                                        *   CYLINDER  * COUNT* 06600021
*       *************************************************************** 06630021
*       * EARLY * DEV- *     EARLY WARNING              * EARLY*  CK. * 06660021
*  +32  * WARN. *  ICE *               MESSAGE TRACK    * WARN.* BYTE * 06690021
*       * COUNT * CODE *                                *SWITCH* (FF) * 06720021
*       *************************************************************** 06750021
         EJECT                                                          07030020
*********************************************************************** 07080020
******************* R E G I S T E R   U S A G E *********************** 07130020
REG0     EQU   0                   PARAMETER REGISTER                   07180020
         SPACE                                                          07230020
REG1     EQU   1                   PARAMETER REGISTER                   07280020
WORK1    EQU   2                   GENERAL WORK REG                     07330020
WORK2    EQU   3                   WORK REG FOR LENGTH OF RECORD        07380020
WORK3    EQU   4                   WORK REG FOR DETERMINING TRK,ECT     07430020
WORK4    EQU   5                   WORK REG FOR DETERMINING TRK,ECT     07480020
WORK5    EQU   6                   WORK REGISTER                  51713 07490021
CVTREG   EQU   7                   ADDRESS OF CVT                       07530020
RMSBASE  EQU   8                   BASE FOR MCHINT AREA                 07580020
R9       EQU   9                   BASE FOR RECORD BUILD AREA           07630020
WORKB    EQU   11                  ADDRESS OF ACTIVE BUFFER             07680020
BASEREG  EQU   12                  BASE REG FOR THIS MODULE             07730020
R14      EQU   14                  RETURN ADDRESS FOR MCS SYSTEMS ONLY  07780020
R15      EQU   15                  ADDRESS OF SVRB                      07830020
         SPACE                                                          07880020
*************************** E Q U A T E S ***************************** 07930020
K0       EQU   0                   DECIMAL VALUE OF 0                   07980020
K1       EQU   1                   DECIMAL VALUE OF 1                   08030020
K2       EQU   2                   DECIMAL VALUE OF 2                   08080020
K3       EQU   3                   DECIMAL VALUE OF 3                   08130020
K4       EQU   4                   DECIMAL VALUE OF 4                   08180020
K5       EQU   5                   DECIMAL VALUE OF 5                   08230020
K6       EQU   6                   DECIMAL VALUE OF 6                   08280020
K7       EQU   7                   DECIMAL VALUE OF 7                   08330020
K8       EQU   8                   DECIMAL VLUE OF 8                    08380020
K10      EQU   10                  DECIMAL VALUE OF 10                  08430020
K11      EQU   11                  DECIMAL VALUE OF 11                  08480020
K12      EQU   12                  DECIMAL CONSTANT                     08486021
K16      EQU   16                  DECIMAL CONSTANT                     08492021
K17      EQU   17                  *                                    08500021
K20      EQU   20                  DECIMAL CONSTANT                     08510021
K22      EQU   22                  DECIMAL VALUE OF 22                  08530020
K25      EQU   25                  *                                    08550021
K24      EQU   24                  DECIMAL CONSTANT                     08560021
K32      EQU   32                  DECIMAL CONSTANT                     08570021
K36      EQU   36                  DECIMAL VALUE OF 36                  08580020
K40      EQU   40                  DECIMAL VALUE OF 40                  08630020
K44      EQU   44                  DECIMAL VALUE OF 44                  08680020
K48      EQU   48                                                       08730020
K60      EQU   60                                                       08780020
K61      EQU   61                  *                                    08800021
K81      EQU   81                  DECIMAL VALUE OF 81                  08830020
K101     EQU   101                 *                                    08850021
K96      EQU   96                  DISPLACEMENT OF EXTENDED SAVE AREA   08880020
K146     EQU   146                 DECIMAL VALUE OF 146                 08930020
K193     EQU   193                 DECIMAL VALUE OF 193                 08980020
K198     EQU   198                 DECIMAL VALUE OF 198       IC  60509 09000021
K289     EQU   289                 DECIMAL VALUE OF 289                 09030020
K299     EQU   299                 *                                    09050021
K347     EQU   347                 DECIMAL VALUE                  20201 09080020
K2137    EQU   2137                DECIMAL VALUE OF 2137                09130020
K2148    EQU   2148                DECIMAL VALUE OF 2148                09180020
K63      EQU   63                  DECIMAL EQUATE OF 63        @S64160P 09190021
K108     EQU   108                 DECIMAL EQUATE OF 108       @S64160P 09200021
K236     EQU   236                 DECIMAL EQUATE OF 236       @S64160P 09210021
X01      EQU   X'01'               MASK FOR EXTENDED DCB                09230020
X02      EQU   X'02'               MASK OF 2 FOR KEY LENGTH             09280020
X05      EQU   X'05'               CODE FOR WRITE HEADER                09330020
X06      EQU   X'06'               CODE FOR READ HEADER                 09380020
X07      EQU   X'07'               MASK                                 09430020
X08      EQU   X'08'               CODE FOR TIC                         09480020
X09      EQU   X'09'               MASK                                 09530020
X1D      EQU   X'1D'               CODE FOR WRITE COUNT,KEY,DATA        09580020
X20      EQU   X'20'                                                    09630020
X28      EQU   X'28'               LENGTH OF HEADER RECORD        21021 09680021
X31      EQU   X'31'               CODE FOR SEARCH ON ID EQUAL          09730020
X40      EQU   X'40'               MASK OF X'40'                        09780020
X42      EQU   X'42'               FLAG 1 FIELD EQU                     09830020
COMCHAIN EQU   X'40'               COMMAND CHAINING BIT ON              09880020
SHORTCNT EQU   78                  COUNT FOR SHORT RECORD               09980020
LNGLEN   EQU   48                  TOTAL LENGTH OF ABREC FOR LONG       10030020
SHRLEN   EQU   70                  TOTAL LENGTH OF ABREC                10080020
INDL     EQU   280                 LENGTH OF IND LOG                    10130020
AREA     EQU   114                 LENGTH OF MCHWORK TO BE CLEARED      10230020
ABCT     EQU   70                  LENGTH OF SHORT REC(DATA LEN)  21021 10290021
ABCTL    EQU   48                  LENGTH OF LONG REC(DATA LEN)   21021 10350021
LONGCNT  EQU   56                  LENGTH OF LONG RECORD                10430020
         SPACE                                                          10480020
FLAG1    EQU   70                  PTR TO FLAG                          10530020
TOTAL    EQU   71                  LENGTH OF TOTAL RECORD               10580020
OFF      EQU   X'00'               ALL BITS OFF                         10630020
CLOBBER  EQU   X'10'               CLOBBERED ABREC BIT                  10680020
EXCPLONG EQU   X'20'               EXCP LONG ABREC BIT                  10730020
EXCPSHRT EQU   X'40'               EXCP SHORT ABREC BIT                 10780020
ACTIVE   EQU   X'80'               ACTIVE ABREC BIT                     10830020
         SPACE                                                          10880020
X80      EQU   X'80'                                                    10930020
X90      EQU   X'90'               LOCATION OF LOG AREA                 10980020
NOLONG   EQU   X'BF'               NO ROOM FOR LONG FLAG-OFF            11030020
LONGON   EQU   X'40'               NO ROOM FOR LONG RECORD FLAG         11080020
FULL     EQU   X'80'               MASK FOR LOGREC FULL                 11130020
EXTENTNG EQU   X'42'               NOT IN EXTENT COMPLETION CODE IN ECB 11180020
INTCEPT  EQU   X'44'               INTERCEPT CODE IN ECB                11230020
NORMAL   EQU   X'7F'               NORMAL COMPLETION CODE IN ECB        11280020
XF7      EQU   X'F7'                                                    11330020
XEF      EQU   X'EF'                                                    11380020
CLOBOFF  EQU   X'EF'               MASK TO TURN OFF CLOBBER BIT         11430020
XFF      EQU   X'FF'               MASK OF FF                           11480020
HDSWITCH EQU   X'80'               HEAD SWITCH                          11530020
EXCP     EQU   0                   EXECUTE CHANNEL PROGRAM CALL         11580020
*********************************************************************** 11630020
         EJECT                                                          11680020
         BALR  BASEREG,K0          SET UP BASE REGISTER                 11730020
         USING *,BASEREG                                                11780020
         USING CVTSECT,CVTREG                                           11830020
         USING MCHAREA,RMSBASE                                          11880020
         USING SVRBXSA,R15                                              11930020
         USING BUILDARA,R9                                              11980020
ORIGIN   L     CVTREG,CVTPTR       LOAD CVT POINTER                     12030020
         LR    RMSBASE,REG0        GET ADDRESS OF MCHINT FROM PARAMETER 12080020
*                                  REGISTER                             12130020
         LA    RMSBASE,K0(RMSBASE) CLEAR POST CODE IN HIGH ORDER BYTE   12180020
         ST    R14,R14SAVE         SAVE AREA FOR RETURN ADDR FOR MCS    12230020
         TM    MCHINT,X80          TEST FOR ERROR RECORDER NEEDED       12280020
         BZ    EXIT2               NO GO EXIT                  IG P1095 12330021
         NI    NOROOM,NOLONG       TURN FLAG FOR NO ROOM LONG OFF       12380020
         BAL   WORK1,COMENDEQ      GO TO COMMON BUILD OF ENQ   MACRO    12390021
         ENQ   MF=(E,(1))          ISSUE ENQ TO GET CONTROL OF LOGREC   12400021
         SPACE 3                                                        12430020
*********************************************************************** 12480020
*           THIS ROUTINE SEARCHES FOR AN ACTIVE BUFFER(ABREC)         * 12530020
*           WHEN AN ACTIVE BUFFER IS FOUND THIS ROUTINE WILL THEN     * 12580020
*           DETERMINE WHETHER IT IS A SHORT OR LONG RECORD.           * 12630020
*********************************************************************** 12680020
         SPACE                                                          12730020
ACTCHECK EQU   *                                                        12780020
         SR    WORK1,WORK1         CLEAR REGISTER                       12830020
         IC    WORK1,MCHABRNO      LOAD NUMBER OF RECORD BUFFERS        12880020
         LA    WORKB,MCHABREC      ADDRESS OF FIRST RECORD BUFFER       12930020
         SPACE                                                          12980020
TEST1    TM    FLAG1(WORKB),ACTIVE TEST FOR ACTIVE BUFFER               13030020
         BO    TEST2               YES-ACTIVE                           13080020
TRYSHRT  EQU   *                                                        13130020
         LA    WORKB,TOTAL(WORKB)  ADDRESS OF NEXT RECORD BUFFER        13180020
         BCT   WORK1,TEST1         SUBTRACT 1 FROM NO OF RECORD BUFFERS 13230020
         B     EXITRTN             IF NO=0 GO TO EXIT                   13280020
TEST2    CL    WORKB,MCHLONG       TEST FOR A LONG RECORD               13330020
         BNE   SETSHORT            NO GO SET SHORT EXCP FLAG            13380020
         OI    FLAG1(WORKB),EXCPLONG SET LONG RECORD FLAG               13430020
         TM    FLAG1(WORKB),CLOBBER LONG RECORD CLOBBERED               13480020
         BO    RESET               YES BRANCH TO RESET                  13530020
         TM    NOROOM,LONGON       TEST FOR NO ROOM FOR LONG RECORD     13580020
         BO    TRYSHRT             TEST NEXT BUFFER                     13630020
         B     BEGIN               CONTINUE PROCESSING                  13680020
SETSHORT OI    FLAG1(WORKB),EXCPSHRT SET SHORT RECORD FLAG              13730020
         NI    FLAG1(WORKB),CLOBOFF TURN CLOBBER OFF FOR SHORT RECORD   13780020
BEGIN    EQU   *                                                        13830020
NEXT     EQU   *                                                        13880020
         SPACE 3                                                        13930020
*********************************************************************** 13980020
*          THIS CODE WILL START TO BUILD THE CCWS FOR READ OF HEADER  * 14030020
*          DYNAMICALLY IN MCHWORK AREA OF MCH COMMON AREA.  THE       * 14080020
*          CCWS ARE BUILT DYNAMICALLY SINCE THIS MODULE IS BROUGHT IN * 14130020
*          A TRANSIENT AREA.                                          * 14180020
*********************************************************************** 14230020
         SPACE                                                          14280020
         XC    HDRREC(AREA),HDRREC CLEAR MCHWORK AREA                   14330020
         L     R9,MCHBUILD         GET ADDRESS OF RECORD BUILD AREA     14380020
         MVI   EXCPIOB,X42         SET FLAG 1 FIELD IN IOB              14430020
         MVI   SRCHFLAG,COMCHAIN   SET COMMAND CHAINING                 14480020
         MVI   TICFLAG,COMCHAIN    SET COMMAND CHAINING                 14530020
         MVI   SRCHCNT,X05         SET COUNT FOR SEARCH IS 5            14580020
         MVI   TICCNT,X01          SET COUNT FOR TIC IS 1               14630020
         LA    WORK1,SEARCH        ADDR OF FIRST CCW ON CHAIN           14680020
         ST    WORK1,IOBCCW        RESOLVE ADDR OF CCW LIST IN IOB      14730020
         ST    WORK1,TIC           STORE ADDRESS IN TIC CCW             14780020
         MVI   TIC,X08             CODE FOR TIC                         14830020
         SPACE 3                                                        14880020
*********************************************************************** 14930020
*          THIS ROUTINE COMPLETES THE BUILDING OF CCWS AND IOB, AND   * 14980020
*          THEN READS IN THE HEADER RECORD FROM SYS1.LOGREC.          * 15030020
*********************************************************************** 15080020
         SPACE                                                          15130020
         L     WORK1,CVTDCB        DCB ADDRESS FOR LOGREC               15180020
         ST    WORK1,IOBDCB        STORE DCB ADDRESS IN IOB             15230020
         L     WORK1,K44(WORK1)    ADDRESS OF DEB                       15280020
         MVC   SEEKADR(K6),K36(WORK1) MOVE BBCCHH FROM DEB TO SEEK      15330020
         MVI   SEEKADR+K6,K1       SET SEARCH FIELD TO ID OF ONE        15380020
         LA    WORK1,EXCPECB       ECB ADDRESS                          15430020
         ST    WORK1,IOBECB        STORE ECB ADDRESS IN IOB             15480020
         BAL   WORK1,COMBUILD      GO TO COMMON BUILD FOR HEADER REC    15530020
         MVI   GENCCW,X06          SET CODE FOR READING OF LOGREC HDR   15580020
         BAL   WORK1,EXCPCALL      BRANCH TO EXCP TO GET HEADER RECORD  15630020
         CLI   SFTBYTS,XFF         COMPARE SAFETY BYTES IN HEADER       15680020
         BC    K8,NEXT1            CONTINUE PROCESSING            51713 15730021
         B     ERROR1              HDR RECORD FORMAT ERROR        51713 15740021
         SPACE 3                                                        15780020
*********************************************************************** 15830020
*          THIS ROUTINE FILLS IN THE CCWS FOR A LONG RECORD.          * 15880020
*********************************************************************** 15930020
NEXT1    EQU   *                                                  51713 15940021
         SPACE                                                          15980020
         MVC   EXCPSEEK+K7(K1),LASTTTR+K6 SET ID IN IOB SEEK FIELD      16030020
         TM    FLAG1(WORKB),EXCPSHRT IS IT A SHORT RECORD               16080020
         BO    SHORTREC            YES-GO COMPUTE LENGTH                16130020
         L     WORK4,MCHINLOG      ADDRESS OF INDEPENDENT LOG           16180020
         LH    WORK2,K6(WORK4)     LENGTH OF EXTENDED LOG               16230020
         LA    WORK2,INDL(WORK2)   ADD LENGTH OF IND LOG                16280020
         AR    WORK4,WORK2         GET LOCATION OF DAMAGE ASSES BUFFER  16330020
         L     WORK1,MCHREMCH      ADDRESS OF DAMAGE ASSESSMENT FIELD   16380020
         LH    WORK3,K0(WORK1)     LENGTH OF DAMAGE ASS. DATA           16430020
         AR    WORK2,WORK3         TOTAL LENGTH MINUS 10                16480020
         BCTR  WORK3,K0            DECREMENT MOVE FOR EX MOVE           16530020
         EX    WORK3,MOVEDA        GO MOVE DAMAGE ASSESS. FIELD INTO    16580020
*                                  RECORD FROM MCHCOMMON AREA           16630020
         LR    WORK3,WORK2         SAVE COUNT                           16680020
         LA    WORK3,LONGCNT(WORK3) GET TOTAL LENGTH OF RECORD          16730020
         STH   WORK3,COUNT         SET COUNT IN CCW FOR WRITING OF      16780020
*                                  RECORD                               16830020
         LA    WORK2,ABCTL(WORK2)  GET LENGTH OF RECORD USED FOR DETER- 16880020
*                                  MINING SPACE NEEDED ON DIRECT ACCESS 16930020
         LA    R9,K22(R9)          UPDATE ADDRESS OF BUILD AREA FOR     16980020
*                                  LONG RECORD                          17030020
         MVC   ABRECCUR(LNGLEN),K0(WORKB) MOVE IN ABREC TO BUFFER       17080020
         EJECT                                                          17130020
*********************************************************************** 17160021
*                                                                     * 17190021
*  THIS ROUTINE WILL FIND THE SPACE NEEDED FOR THE RECORD ACCORDING   * 17220021
*       TO THE PARTICULAR DEVICE THAT SYS1.LOGREC RESIDES ON  -       * 17250021
*        2311,2301,2303,2305 MODELS I AND II,2314, AND 3330.          * 17280021
*                                                                     * 17310021
*********************************************************************** 17340021
*  DEVICE *DEVICE  *  FORMULA FOR SPACE FOR   *  FORMULA FOR SPACE FOR* 17370021
*         * TYPE   *     RECORD WITH KEY      *    RECORD WITHOUT KEY * 17400021
*********************************************************************** 17430021
*   2311      01   *   81 + 537(KL+DL)/512    *   61 + 537(DL)/512    * 17460021
*   2301      02   *  186 + KL + DL           *  133 + DL             * 17490021
*   2303      03   *  146 + KL + DL           *  108 + DL             * 17520021
*   2305(1)   06   *  634 + 2 + KL + DL       *  432 + 2 + DL         * 17550021
*   2305(2)   07   *  289 + KL + DL           *  198 + DL    IC  60509* 17580021
*   2314      08   *  146 + 2137(KL+DL)/2048  *  101 + 2137(DL)/2048  * 17610021
*   3330      09   *  193 + KL + DL           *  135 + DL             * 17640021
*   WHERE     KL = KEY LENGTH                                         * 17670021
*             DL = DATA LENGTH                                        * 17700021
*********************************************************************** 17730021
         SPACE                                                          17930020
* UPON ENTRY TO THIS ROUTINE WORK2 HAS NUMBER OF BYTES OF RECORD MINUS* 17980020
* 10                                                                    18030020
SPACE    EQU   *                                                        18080020
         STH   WORK2,CTFLDDL       SET DATA LENGTH FIELD FOR RECORD     18130020
         SR    WORK1,WORK1         CLEAR REGISTER                       18230020
         IC    WORK1,DEVICE        GET DEVICE TYPE FROM LOGREC HEADER   18280020
         SLL   WORK1,K1            SHIFT DEVICE TYPE OVER               18330020
         LH    WORK1,BRTABLE-K2(WORK1) GET INDEX VALUE IN WORK1         18380020
         B     ORIGIN(WORK1)       GO TO RTN FOR THE DEVICE TYPE        18430020
T2314    EQU   *                                                        18480020
         LA    WORK3,K101          ADDITION FACTOR FOR 2314       21021 18530021
         LA    WORK4,K2137         MULTIPLYING FACTOR FOR 2314          18580020
         SPACE                                                          18630020
COMMULT  EQU   *                                                        18680020
         MR    WORK1,WORK4         MULT TOTAL LENGTH BY FACTOR          18730020
         SRL   WORK2,K11           DIVIDE BY 2048                       18780020
         AR    WORK2,WORK3         ADD VALUE CONSTANT TO RESULT         18830020
         B     TSTBYREM            GO TO TEST NO OF BYTES LEFT          18880020
T2311    EQU   *                                                        18930020
         LA    WORK3,K61           ADDITION FACTOR FOR 2311       21021 18980021
         LA    WORK4,K2148         MULTIPLYING FACTOR FOR 2311          19030020
         B     COMMULT             BRANCH TO ROUTINE TO MUTL            19080020
T2305A   EQU   *                                                  21021 19140021
         LA    WORK2,K236(WORK2)   2305I FORMULA IS DL+434     @S64160P 19200021
T2305C   EQU   *                                               @S64160P 19220021
         LA    WORK2,K63(WORK2)    2305II FORMULA IS DL+198    @S64160P 19240021
T3330    EQU   *                        21021                           19260021
         LA    WORK2,K2(WORK2)     3330 FORMULA IS DL+135         21021 19320021
T2301    EQU   *                                                  21021 19380021
         LA    WORK2,K25(WORK2)    2301 FORMULA IS DL+133         21021 19440021
T2303    EQU   *                                                  21021 19500021
         LA    WORK2,K108(WORK2)   2303 FORMULA IS DL+108      @S64160P 19560021
         SPACE 3                                                        19780020
*********************************************************************   19830020
*          THIS ROUTINE DETERMINES IF ENOUGH BYTES REMAIN ON TRACK  *   19880020
*********************************************************************   19930020
         SPACE                                                          19980020
TSTBYREM LH    WORK3,BYTSREM       NO OF BYTES REMAINING ON TRACK       20030020
         SLR   WORK3,WORK2         SUB LENGTH OF ERROR RECORD FROM      20080020
*                                  REMAINING BYTES                      20130020
         BO    TCHKLAST            BR IF RECORD WILL FIT ON TRACK       20180020
         CLC   UPLIMIT(K4),LASTTTR+K2 COMPARE CCHH WITH EXTENT          20230020
         BE    FULOGREC            LOGREC IS FULL WHEN EQUAL TO EXTENT  20280020
         SPACE 3                                                        20330020
*********************************************************************   20380020
*         CHECK IF END OF CYLINDER                                  *   20430020
*********************************************************************   20480020
         SPACE                                                          20530020
TESTCYL  LH    WORK3,LASTTTR+K4    LOAD LAST USED HEAD POSITION         20580020
         LA    WORK3,K1(WORK3)     ADD ONE TO HEAD POSITION             20630020
         XR    WORK4,WORK4         CLEAR REG                            20680020
         ICM   WORK4,K3,TRKSPER    GET R TRACKS/CYLINDER AND CNT  21021 20710021
*                                  IN REGISTER                    21021 20740021
         CLR   WORK4,WORK3         COMPARE HD CT TO TRACK/CYLINDER      20780020
         BL    TCYLEND             BR LOW FOR END OF CYLINDER IC  21961 20830021
         SPACE 3                                                        20880020
*********************************************************************   20930020
*        IF NECESSARY, UPDATE HEAD POSITION TO SWITCH TRACKS        *   20980020
*********************************************************************   21030020
         SPACE                                                          21080020
TRKUPDT  STH   WORK3,LASTTTR+K4    STORE NEXT HEAD POSITION IN HDR      21130020
         MVI   EXCPSEEK+K7,K0      SET ID IN IOB SEEK FIELD TO 0        21180020
         MVI   LASTTTR+K6,K0       SET RECORD ENTRY ID TO ZERO          21230020
         MVC   BYTSREM(K2),TRKCAP  SET REMAINING BYTE ON TRK TO MAX     21280020
         B     TSTBYREM            TRY AGAIN                            21330020
         SPACE 3                                                        21380020
*********************************************************************   21430020
*        THIS CODE SETS UP FOR A SHORT RECORD.                      *   21480020
*********************************************************************   21530020
         SPACE                                                          21580020
SHORTREC EQU   *                                                        21630020
         MVI   COUNTA,SHORTCNT     COUNT FOR SHORT RECORD               21680020
         MVC   ABRECCUR(SHRLEN),K0(WORKB) MOVE IN ACTIVE ABREC TO BUFF  21730020
         LA    WORK2,ABCT          GET LEN OF REC USED TO DETER-  21021 21760021
*                                  MINE SPACE NEEDED              21021 21790021
         B     SPACE               GO FIND SPACE ON DEVICE              21830020
         SPACE 3                                                        21880020
*********************************************************************   21930020
*        IF NECESSARY, UPDATE CYLINDER POSITION                     *   21980020
*********************************************************************   22030020
         SPACE                                                          22080020
TCYLEND  EQU   *                                                  20201 22090020
         XR    WORK3,WORK3         CLEAR REGISTER FOR ZERO HEAD   20201 22130020
         LH    WORK4,LASTTTR+K2    LOAD LAST USED CYLINDER POSITION     22180020
         LA    WORK4,K1(WORK4)     ADD ONE TO CYLINDER COUNT            22230020
         STH   WORK4,LASTTTR+K2    STORE UPDATED CYLINDER COUNT         22280020
         B     TRKUPDT             UPDATE HEADER                        22330020
         SPACE 3                                                        22380020
*********************************************************************   22430020
*        CHECK RECORDING SPACE IN EXTENT                            *   22480020
*********************************************************************   22530020
         SPACE                                                          22580020
TCHKLAST STH   WORK3,BYTSREM       STORE REMAINING BYTE COUNT           22630020
         TM    WARNSW,X80          IF NEAR FULL MSG HAS BEEN  IC  21961 22630721
*                                  SCHEDULED,DONT SCHEDULE    IC  21961 22631421
         BO    TSET                THE MESSAGE AGAIN          IC  21961 22632121
         CLC   WARNTRK(K4),LASTTTR+K2 COMPARE LAST USED WITH WARN 21021 22633021
*                                  CCHH                           21021 22636021
         BL    SETWARN             LOGREC FULL MSG IS REQ     IC  21961 22639021
         BH    TSET                LOGREC FULL MSG NOT REQD   IC  21961 22642021
         CLC   WARNCNT(K2),BYTSREM CHECK BYTES REMAINING          21021 22645021
         BL    TSET                NO LOGREC FULL MSG NEEDED      21021 22648021
SETWARN  EQU   *                                                        22654021
         OI    MCHINT+K2,X08       INDICATE LOGREC NEAR FULL MSG  21021 22660021
*                                  TO BE OUTPUTTED BY IGFMCHE1    21021 22663021
         OI    WARNSW,X80          INDICATE NEAR FULL MSG SCHDULED21021 22666021
TSET     XR    WORK4,WORK4         CLEAR REGISTER                       22680020
         IC    WORK4,LASTTTR+K6    LOAD ID OF LAST REC WRITTEN          22730020
         LA    WORK4,K1(WORK4)     ADD ONE TO FIELD COUNT               22780020
         STC   WORK4,LASTTTR+K6    UPDATE LAST ID WRITTEN IN HDR        22830020
         SPACE 3                                                        22880020
*********************************************************************** 22930020
*        ROUTINE TO WRITE RECORD ON SYS1.LOGREC                       * 22980020
*********************************************************************** 23030020
         SPACE                                                          23080020
         SPACE 2                                                        23130020
READY    EQU   *                                                        23180020
         ST    R9,GENCCW           SET ADDR OF RECORD BUFFER            23230020
         MVI   GENCCW,X1D          SET CODE FOR WRITE TO LOGREC         23280020
         MVI   CTFLDKEY,OFF        SET KEY LENGTH TO ZERO         21021 23330021
         MVC   CTFLDID(K5),LASTTTR+K2 SET UP COUNT FIELD ID FOR RECORD  23380020
         LA    WORK1,EXCPSEEK+K3   RESOLVE SEEK ADDR                    23430020
         ST    WORK1,SEARCH        SET SEARCH ADDR IN CCW               23480020
         MVI   SEARCH,X31          SET SEARCH CODE IN CCW               23530020
         MVC   EXCPSEEK+K1(K6),LASTTTR PLACE SEEK ADDR FOLLOWING IOB    23580020
         TM    FLAG1(WORKB),CLOBBER CLOBBER BIT ON                      23630020
         BO    RESET               YES-RESET BITS                       23680020
         BAL   WORK1,EXCPCALL      BRANCH TO EXCP TO WRITE RECORD ON    23730020
*                                  SYS1.LOGREC                          23780020
         TM    FLAG1(WORKB),CLOBBER CLOBBER BIT ON                      23830020
         BO    RESET               YES-RESET BITS                       23880020
         MVI   FLAG1(WORKB),OFF    CLEAR ALL BITS                       23930020
         SPACE 3                                                        23980020
**********************************************************************  24030020
*        ROUTINE TO SETUP AND WRITE AN END OF FILE                   *  24080020
*                                                                    *  24130020
* END OF FILE IS ALWAYS WRITTEN AS THE VERY LAST RECORD ON THE DATA  *  24180020
* SET UNLESS IS THE LAST RECORD AND THEN IT IS WRITTEN RIGHT AFTER   *  24230020
* THE RECORD.                                                        *  24280020
**********************************************************************  24330020
         SPACE                                                          24380020
         CLC   UPLIMIT(K4),LASTTTR+K2 COMPARE CCHH WITH EXTENT          24430020
         BNE   SWITCH              BR-HEAD SWITCHING REQUIRED           24480020
         MVC   EXCPSEEK+K1(K7),LASTTTR MOVE SEEK ADDR TO IOB            24530020
         MVI   CTFLDID+K4,XFF      SET EOF ID                           24580020
         B     WRTEOF              WRITE EOF AS NEXT RECORD             24630020
SWITCH   XC    EXCPSEEK+K3(K5),EXCPSEEK+K3 CLEAR SEEK ADDR              24680020
         MVC   EXCPSEEK+K3(K4),UPLIMIT MOVE SEEK ADDR TO IOB            24730020
         MVI   CTFLDID+K4,X01      SET EOF ID                           24780020
WRTEOF   MVC   CTFLDID(K4),EXCPSEEK+K3 MOVE CCHH TO EOF RECORD          24830020
         XC    CTFLDKEY(K3),CTFLDKEY CLEAR RECORD COUNT FIELD           24880020
         MVI   COUNT,OFF           CLEAR 1ST BYTE OF COUNT FILED        24930020
         MVI   COUNTA,X08          SET COUNT FIELD FOR EOF WRITE        24980020
         BAL   WORK1,EXCPCALL      BRANCH TO EXCP TO WRITE EOF RECORD   25030020
         SPACE 3                                                        25080020
*********************************************************************** 25130020
*        ROUTINE TO WRITE HEADER RECORD BACK                          * 25180020
*********************************************************************** 25230020
         SPACE                                                          25280020
         BAL   WORK1,COMBUILD      GO TO COMMON BUILD FOR HEADER REC    25350021
         MVI   GENCCW,X05          SET CODE TO WRITE LOGREC HEADER      25380020
         BAL   WORK1,EXCPCALL      TO EXCP TO WRITE EOF REC   IC  58508 25380421
         B     ACTCHECK            BRANCH TO BEGINNING                  25480020
         SPACE 2                                                        25530020
RESET    EQU   *                                                        25580020
         NI    FLAG1(WORKB),ACTIVE LEAVE ONLY ACTIVE BIT ON             25630020
         B     ACTCHECK            CHECK FOR MORE ACTIVE BUFFERS        25680020
         SPACE 3                                                        25730020
**********************************************************************  25780020
*ROUTINE TO BUILD COMMON PARTS OF THE CCWS FOR READING AND WRITING OF   25830020
*THE HEADER RECORD                                                      25880020
**********************************************************************  25930020
         SPACE                                                          25980020
COMBUILD EQU   *                                                        26030020
         MVI   COUNTA,X28          SET COUNT OF HEADER RECORD     21021 26040021
         LA    WORK2,HDRREC        RESOLVE ADDRESS                      26050020
         ST    WORK2,GENCCW        SET ADDRESS OF CCW                   26060020
         LA    WORK2,SEEKADR+K2    RESOLVE                              26070020
         ST    WORK2,SEARCH        SEEK ADDRESS IN CCW                  26080020
         MVI   SEARCH,X31          SET CODE FOR SEARCH                  26130020
         MVC   EXCPSEEK+K1(K7),SEEKADR PLACE SEEK ADR FOLLOWING IOB     26180020
         BR    WORK1               GO TO CALLER-EITHER READ OR WRITE    26230020
*                                  HEADER                               26280020
*                                                              @S64160P 26284021
* THIS ROUTINE WILL BUILD ENQ/DEQ MACRO EXPANSION IN MCHWORK AREA       26288021
*                                                              @S64160P 26292021
COMENDEQ EQU   *                                               @S64160P 26296021
         MVC   MCHWORK+K12(ENQLEN),ENQCODE MOVE ENQ/DEQ INTO BUFFER     26300021
         LA    WORK2,MCHWORK+K24   PICK UP ADDR OF QNAME       @S64160P 26304021
         ST    WORK2,MCHWORK+K16   RESOLVE IN EXPANSION        @S64160P 26308021
         LA    WORK2,MCHWORK+K32   PICK UP ADDR OF RNAME       @S64160P 26312021
         ST    WORK2,MCHWORK+K20   RESOLVE IN EXPANSION        @S64160P 26316021
         LA    REG1,MCHWORK+K12    POINT REG1 TO BUFFER        @S64160P 26320021
         BR    WORK1                                           @S64160P 26324021
         SPACE 3                                                        26330020
EXCPCALL EQU   *                                                        26380020
         XC    EXCPECB(K4),EXCPECB CLEAR ECB                            26430020
         LA    REG1,EXCPIOB        ADDRESS OF IOB                       26480020
         SVC   EXCP                SUPERVISOR CALL TO EXCP              26530020
         WAIT  1,ECB=EXCPECB                                            26580020
         CLI   EXCPECB,INTCEPT     COMPARE COMPLETION CODE IN ECB       26630020
         BE    EXCPCALL            BRANCH TO EXCP AGAIN                 26680020
         CLI   EXCPECB,NORMAL      COMPARE COMPLETION CODE IN ECB       26730020
         BCR   K8,WORK1            BRANCH IF COMPLETED OK               26780020
ERROR2   OI    MSGFLAG,X40         TURN ON FLAG TO INDICATE I/O ERROR   26830020
         B     EXITRTN             GO TO WTO MODULE TO OUTPUT MSG       26880020
         SPACE 2                                                        26930020
ERROR1   OI    MSGFLAG,X20         TURN ON FLAG TO INDICATE HDR RECORD  26980020
*                                  FORMAT ERROR                         27030020
         B     EXITRTN             GO TO WTO MODULE TO OUTPUT MSG       27080020
         SPACE 2                                                        27130020
FULOGREC EQU   *                   LOGREC IS FULL                       27180020
         OI    MSGFLAG,FULL        TURN ON FLAG TO INDICATE LOGREC FULL 27230020
         TM    FLAG1(WORKB),EXCPSHRT IF SHORT REC-THEN GO TO IGFMCHE1   27280020
*                                  TO OUTPUT MESSAGE                    27330020
*                                  IF LONG REC-GO SEE IF SHORT WILL FIT 27380020
         SPACE                                                          27580020
         BO    EXITRTN             GO TO OUTPUT MESSAGE        @S64160P 27590021
         OI    NOROOM,LONGON       TURN ON NO LONG ROOM FLAG   @S64160P 27600021
         B     ACTCHECK            CHECK FOR FIT OF SHORT RECORD        27610021
EXITRTN  EQU   *                                                        27630020
         BAL   WORK1,COMENDEQ      GO TO COMMON BUILD OF ENQ MACRO      27640021
         DEQ   MF=(E,(1))          ISSUE DEQ TO REL CONT OF LOGREC      27650021
         L     R14,R14SAVE         RESTORE MCS RETURN ADDRESS           27682021
         TM    MCHINT+K3,X80       IS SYSTEM IN QUIET MODE              27685021
         BO    EXIT2               YES                                  27690021
         DC    X'B6EE'                                                  27695021
         DC    S(MCHWORK)          STORE CTR 14                         27700021
         OI    MCHWORK,X08         ENABLE SOFT ERRORS                   27705021
         DC    X'B7EE'                                                  27710021
         DC    S(MCHWORK)          LOAD CTR 14                          27715021
EXIT2    EQU   *                                                        27724021
         L     R15,CVTTCBP         LOAD PTR TO NEW-OLD TCB PTRS         27730020
         L     R15,K4(R15)         LOAD OLD(CURRENT) TCB PTR            27780020
         L     R15,K0(R15)         LOAD PTR TO CURRENT RB(SVRB)         27830020
         LA    R15,K96(R15)        PTR TO EXTENDED SAVE AREA IN SVRB    27880020
         LR    REG0,RMSBASE        PARAMETER REG FOR ADDRESS OF MCHINT  27930020
         LA    WORK1,K8(R15)                                            27980020
         ST    WORK1,CSANPTR       *+8 FOR XCTL IN CXSA                 28030020
         XC    CSADCBP(K4),CSADCBP ZERO DCB POINTER IN CXSA             28080020
         MVC   CSANAME(K8),EXTNAME MOVE NAME OF ROUTER MODULE INTO      28130020
*                                  XCTL PARAMETER LIST IN XSA           28180020
         XCTL  SF=(E,(15))         *EXIT                                28230020
EXTNAME  DC    CL8'IGCR207B'       NAME OF WTO ROUTINE                  28280020
         EJECT                                                          28330020
* THE FOLLOWING IS THE BRANCH TABLE FOR DEVICE TYPE FORMULA DETERMINA-  28380020
* TION.                                                                 28430020
BRTABLE  DC    AL2(T2311-ORIGIN)   ENTRY FOR 2311                       28480020
         DC    AL2(T2301-ORIGIN)   ENTRY FOR 2301                       28530020
         DC    AL2(T2303-ORIGIN)   ENTRY FOR 2303                       28580020
         DC    AL2(ERROR1-ORIGIN)  ENTRY FOR ERROR DEVICE TYPE          28630020
         DC    AL2(ERROR1-ORIGIN)  ENTRY FOR ERROR DEVICE TYPE          28680020
         DC    AL2(T2305A-ORIGIN)  ENTRY FOR 2305A                      28730020
         DC    AL2(T2305C-ORIGIN)  ENTRY FOR 2305C                      28780020
         DC    AL2(T2314-ORIGIN)   ENTRY FOR 2314                       28830020
         DC    AL2(T3330-ORIGIN)   ENTRY FOR 3330                       28880020
ENQCODE  ENQ   (LOGREC,RECORDER,E,8,SYSTEM),RET=HAVE,MF=L         42815 28888021
LOGREC   DC    CL8'LOGREC'         QNAME FOR ENQUE/DEQUE          42815 28896021
RECORDER DC    CL8'RECORDER'       RMANE FOR ENQUE/DEQUE          42815 28904021
ENQEND   DS    0H                                                       28912021
ENQLEN   EQU   ENQEND-ENQCODE      LENGTH OF ENQUE FIELD          42815 28920021
         SPACE 5                                                        28930020
MAINT    DC    XL50'0'             MAINTENANCE SPACE                    28980020
         SPACE 3                                                        29030020
MOVEDA   MVC   K0(K0,WORK4),K0(WORK1) MVC TO MOVE DAM.ASESS.FIELD TO    29080020
*                                  BUFFER                               29130020
         SPACE 3                                                        29180020
         EJECT                                                          29230020
* MCH COMMON AREA LOCATIONS USED BY ERROR RECORDER AND WRITE TO         29280020
* OPERATOR ROUTINES                                                     29330020
MCHAREA  DSECT                                                          29380020
MCHINT   DS    F                   INTERFACE WORD                       29430020
         SPACE                                                          29480020
NOROOM   EQU   MCHINT+1            FLAG FOR NO ROOM FOR LONG RECORD     29530020
MSGFLAG  EQU   MCHINT+2            BYTE IN MCHINT FOR MESSAGE FLAGS     29580020
         SPACE                                                          29630020
MCHIPTR  DS    F                   POINTER TO NEXT AVAILABLE LOCATION   29680020
*                                  IN MESSAGE BUFFER                    29730020
MCHIBUF  DS    25F                 MESSAGE BUFFER                       29780020
         SPACE                                                          29830020
MCHWORK  DS    30F                 WORK AREA FOR RECORDER AND WTO RTNS  29880020
R14SAVE  EQU   MCHWORK             SAVE AREA FOR RETURN ADDR IN MCS SYS 29930020
CCHADDR  EQU   MCHWORK             ADDR OF CCH RECORD FOR IGFMCHE3      29980020
CCHLEN   EQU   MCHWORK+4           LENGTH OF CCH RECORD FOR IGFMCHE3    30030020
         SPACE 2                                                        30080020
HDRREC   EQU   MCHWORK+4           AREA FOR SYSL.LOGREC HEADER    21021 30120021
LOWLIMIT EQU   HDRREC+2            STARTING CCHH OF EXTENT        21021 30160021
UPLIMIT  EQU   HDRREC+6            ENDING CCHH OF EXTENT          21021 30200021
SPARE    EQU   HDRREC+10           SPARE BYTE                     21021 30240021
RESTART  EQU   HDRREC+11           BBCCHHR OF REC. AREA START     21021 30280021
BYTSREM  EQU   HDRREC+18           REMAINING BYTES ON TRACK       21021 30320021
TRKCAP   EQU   HDRREC+20           TOTAL TRACK CAPACITY           21021 30360021
LASTTTR  EQU   HDRREC+22           LAST BBCCHHR USED FOR REC      21021 30400021
TRKSPERA EQU   HDRREC+28           TRKSPER NOT ON HALF WD BDRY    21021 30440021
TRKSPER  EQU   HDRREC+29           NUMBER OF TRACKS PER CYLINDER  21021 30480021
WARNCNT  EQU   HDRREC+31           90 PERCENT TRACK COUNT         21021 30520021
DEVICE   EQU   HDRREC+33           DEVICE TYPE CODE               21021 30560021
WARNTRK  EQU   HDRREC+34           90 PERCENT TRACK-CCHH          21021 30600021
WARNSW   EQU   HDRREC+38           BIT 0 IS TURNED ON WHEN WARN   21021 30640021
*                                  MESSAGE IS ISSUED              21021 30680021
SFTBYTS  EQU   HDRREC+39           SAFETY BYTE TO DETECT OVERRUN  21021 30720021
         SPACE 2                                                        30880020
*CCWS FOR RECORDERS                                                     30930020
SEARCH   EQU   MCHWORK+44          SEARCH CCW                           30980020
SRCHADR  EQU   MCHWORK+45          ADDRESS PORTION OF SEARCH CCW        31030020
SRCHFLAG EQU   MCHWORK+48          FLAG FIELD FOR SEARCH CCW            31080020
SRCHCNT  EQU   MCHWORK+51          COUNT FIELD FOR SEARCH               31130020
         SPACE                                                          31180020
TIC      EQU   MCHWORK+52          TIC CCW                              31230020
TICFLAG  EQU   MCHWORK+56          FLAG FIELD FOR TIC CCW               31280020
TICCNT   EQU   MCHWORK+59          COUNT FIELD FOR TIC                  31330020
         SPACE                                                          31380020
GENCCW   EQU   MCHWORK+60          CCW FOR READ HDR,WRITE HDR AND DATA  31430020
CCWADR   EQU   MCHWORK+61          ADDRESS PORTION OF GENERAL CCW       31480020
FLAG     EQU   MCHWORK+64          FLAG FIELD FOR CCW                   31530020
COUNT    EQU   MCHWORK+66          COUNT FIELD FOR CCW                  31580020
COUNTA   EQU   MCHWORK+67          COUNT FIELD(1 BYTE FOR RD,WRT HDR)   31630020
         SPACE                                                          31680020
EXCPIOB  EQU   MCHWORK+68          IOB FOR EXCP FOR IGFMCHE2            31730020
IOBECB   EQU   EXCPIOB+4           ECB POINTER                          31780020
IOBCCW   EQU   EXCPIOB+16          CCW ADDRESS                          31830020
IOBDCB   EQU   EXCPIOB+20          DCB POINTER                          31880020
EXCPSEEK EQU   EXCPIOB+32          SEEK&ADDR FOR EXCP                   31930020
EXCPECB  EQU   EXCPIOB+40          ECB FOR EXCP                         31980020
SEEKADR  EQU   EXCPIOB+44          BBCCHHR USED FOR READ/WRITE HEADER   32030020
         SPACE                                                          32080020
TFLAG    EQU   MCHWORK+119         SWITCH FOR EOF WRITE                 32130020
         SPACE 2                                                        32180020
MCHLONG  DS    F                   POINTER TO LONG ABREC                32230020
MCHBUILD DS    F                   POINTER TO RECORD BUILD AREA         32280020
MCHINLOG DS    F                   POINTER TO INDEPENDENT LOG           32330020
MCHREMCH DS    F                   POINTER TO DAMAGE ASSESSMENT DATA    32380020
MCHENQ   DS    F                   SAVE AREA FOR ENQUING                32400021
MCHABRNO DS    CL1                 NUMBER OF ABREC BUFFERS              32430020
MCHABREC EQU   *                   ABREC BUFFERS                        32480020
         EJECT                                                          32530020
* THIS DSECT REPRESENTS THE ACTUAL AREA FROM WHICH THE RECORD WILL BE * 32580020
* WRITTEN.MCHBUILD IS A POINTER TO THIS AREA. THE RECORDER WILL BUILD * 32630020
* DYNAMICALLY THE CTFIELD PORTION OF RECORD AND WILL MOVE THE         * 32680020
* ACTIVE ABREC AND DAMAGE ASSESSMENT FIELD INTO RECORD BUILD AREA.    * 32730020
* THE INDEPENDENT LOG IS MOVED INTO THIS AREA BY MCH NUCLEUS AND HARD-* 32780020
* WARE LOGS THE DEPENDENT LOG IN THIS AREA. BOTH DAMAGE ASSESSMENT AND* 32830020
* DEPENDENT LOG ARE VARIABLE IN SIZE ACCORDING TO MODEL.              * 32880020
         SPACE                                                          32930020
* RECORD BUILD AREA BUFFER                                              32980020
         SPACE 3                                                        33030020
*                                                                     * 33080020
* SHORT RECORD - 78 BYTES LONG                                        * 33130020
         SPACE                                                          33180020
*        *                            *                               * 33230020
* CTFIELD*          ABREC             * NOT RECORDED FOR SHORT RECORD * 33280020
* 8 BYTES*        70  BYTES           *                               * 33330020
*        *                            *                               * 33380020
*                                                                     * 33430020
         SPACE 3                                                        33480020
*                                                                     * 33530020
* LONG RECORD - VARIABLE LENGTH                                       * 33580020
         SPACE                                                          33630020
*               *         *           *           *         *         * 33680020
* NOT   USED    * CTFIELD *   ABREC   *  IND LOG  * DEP LOG *DAM.ASESS* 33730020
*   22 BYTES    * 8 BYTES *  48 BYTES *  280 BYTE * VARIABLE* VARIABLE* 33780020
*               *         *           *           *  LENGTH *  LENGTH * 33830020
*               *         *           *           *         *         * 33880020
*                                                                     * 33930020
         SPACE 3                                                        33980020
BUILDARA DSECT                                                          34030020
CTFIELD  DS    CL5                 RECORD ENTRY COUNT FIELD             34080020
CTFLDID  EQU   CTFIELD             COUNT FIELD ID-CCHAR                 34130020
CTFLDKEY DS    CL1                 KEY LENGTH                           34180020
CTFLDDL  DS    CL2                 DATA LENGTH                          34230020
ABRECCUR DS    CL70                AREA FOR ACTIVE ABREC TO CONTAIN     34280020
*                                  WHILE IN PROCESS OF WRITING RECORD   34330020
*                                  ON SYS1.LOGREC                       34380020
INDLOG   DS    CL6                 PTED TO BY MCHINLOG                  34430020
         DS    CL2                 LENGTH OF DEPENDENT LOG              34480020
         DS    CL272               REST OF INDEPENT LOG                 34530020
DEPLOG   EQU   *                   DEPENDENT LOG IF ANY                 34580020
DAMASESS DS    CL2                 LENGTH OF DAMAGE ASSESSMENT FIELD    34630020
DAMASFLD EQU   *                   DAMAGE ASSESSMENT FIELD              34680020
         SPACE                                                          34730020
         EJECT                                                          34780020
         SPACE 3                                                        34830020
CVTSECT  DSECT                                                          34880020
         CVT   SYS=MVT OR VMS                                           34930020
         SPACE 3                                                        34980020
SVRBXSA  DSECT                                                          35030020
         IEECVMUG CXSA                                                  35080020
         END                                                            35130020
