         TITLE '         IGFMCHE3     RMS EMERGENCY RECORDER MODULE'    35219920
*********************************************************************** 35269920
*  TITLE-IGFMCHE3--EMERGENCY RECORDER                                 * 35279920
*  RELEASE 21 CODE ADDED 05/24/70 - IGFMCHE3                            35299921
*  STATUS -                                                           * 35319920
*         LEVEL FOR 20.3-IGFMCHE3 - 00      2/05/71                   * 35329920
*         LEVEL FOR 370 -IGFMCHE3 - 02      2/03/71                   * 35339920
*         LEVEL FOR 21.7-IGFMCHE3 - 03      2/15/73          IC  60509* 35349921
*  FUNCTION                                                           * 35369920
*        THIS MODULE WILL RECORD AN CHANNEL CHECK RECORD(IF ANY),     * 35419920
*        ABREVIATED RECORDS(ABREC) OR THE TOTAL RECORD                * 35469920
*        (ABREC,INDEPENDENT LOG,EXTENDED LOG,AND MCH DATA) ON         * 35519920
*        SYS1.LOGREC.                                                 * 35569920
*        1.THIS MODULE FIRST CHECKS FOR A CCH RECORD TO BE RECORDED-  * 35619920
*        IF THERE IS ANY.   IF THERE IS NO CCH RECORD OR IF           * 35669920
*        IT HAS ALREADY BEEN RECORDED AN ACTIVE BUFFER IS FOUND       * 35719920
*        AND A FLAG IS SET TO INDICATE THE TYPE OF RECORD             * 35769920
*        2. THE HEADER RECORD IS READ FROM SYS1.LOGREC AND THIS       * 35819920
*        ROUTINE DETERMINES IF ENOUGH SPACE IS LEFT ON DATA SET       * 35869920
*        ACCORDING TO I/O DEVICE TYPE FOR THE RECORD.                 * 35919920
*        3. IF THERE IS ENOUGH SPACE LEFT ON DATA SET, THE RECORD     * 35969920
*        WRITTEN. THEN EOF IS WRITTEN.                                * 36019920
*        IF ENOUGH SPACE IS NOT LEFT ON THE DATA SET A FLAG IS SET TO * 36069920
*        INDICATE TO SHUT THAT THE RECORD HAS NOT BEEN OUTPUTTED.     * 36119920
*        CONTROL IS RETURNED TO SHUT WHEN THERE IS NO MORE ROOM ON    * 36169920
*        THE DATA SET.                                                * 36219920
*        4. THE UPDATED HEADER IS WRITTEN BACK ON SYS1.LOGREC.        * 36269920
*        THIS ROUTINE WILL CONTINUE PROCESSING UNTIL ALL ACTIVE       * 36319920
*        BUFFERS HAVE BEEN PROCESSED.                                 * 36369920
*  ENTRY POINTS                                                       * 36419920
*        IGFMCHE3- ENTERED FROM SHUT                                  * 36469920
*  INPUT -                                                            * 36519920
*        REG 10 - CVT POINTER                                         * 36569920
*        REG 11 - ADDRESS OF MCH COMMON AREA                          * 36619920
*        REG 12 - ENTRY POINT OF NUCLEUS                              * 36669920
*        REG 15 - BASE FOR TRANSIENT AREA                             * 36719920
*  OUTPUT-                                                            * 36769920
*        RECORDS ARE WRITTEN OUT ON SYS1.LOGREC.                      * 36819920
*        BYTE 0,BIT 4 IN MCHINTEL IS TURNED ON WHEN RECORDER IS       * 36869920
*        SUCCESSFUL.                                                  * 36919920
*  EXTERNAL REFERENCES-                                               * 36969920
*        MCH COMMON AREA                                              * 37019920
*        CVT - CVTDCB                                                 * 37069920
*  EXIT POINTS-                                                       * 37119920
*        NORMAL-BRANCH TO SHUT VIA ADDRESS IN MCHSHUT                 * 37169920
*        ERROR- BRANCH TO SHUT VIA ADDRESS IN MCHSHUT                 * 37219920
*        ERROR CONDITIONS-                                            * 37269920
*        1.AN I/O ERROR                                               * 37319920
*        2.HEADER RECORD ON SYS1.LOGREC NOT FORMATED CORRECTLY        * 37369920
*        3.ATTEMPT TO ACCESS INFORMATION NOT IN EXTENT                * 37419920
*        SHUT DETERMINES IF RECORDER WAS SUCESSFUL BY BIT IN MCHINTEL * 37469920
*  TABLES/WORK AREAS-                                                 * 37519920
*        MCHWORK-                                                     * 37569920
*  ATTRIBUTES-                                                        * 37619920
*        NONRESIDENT,REENTRANT,SUPERVISOR STATE                       * 37669920
*                                                                     * 37679920
*  NOTES                                                              * 37719920
*        MAINTENANCE SPACE                                            * 37729920
*        A DC OF 50 BYTES WITH THE LABEL                              * 37739920
*        *****MAINT*****                                              * 37749920
*                                                                     * 37769920
*                                                                     * 37819920
*********************************************************************** 37869920
         EJECT                                                          37919920
*********************************************************************** 37969920
*BYTE 0 OF MCHINT                                                     * 38019920
*        BIT 0- 0 ERROR RECORDER FUNCTION NOT NEEDED                  * 38069920
*        BIT 0- 1 INVOKE ERROR RECORDER                               * 38119920
*        BIT 1- 0 WTO FUNCTION NOT NEEDED                             * 38169920
*        BIT 1- 1 INVOKE WTO FUNCTION                                 * 38219920
*        BIT 2-7  RESERVED                                            * 38269920
*BYTE 1 OF MCHINT -                                                   * 38319920
*        BIT 0-1 CCH RECORD(FOR EMERGENCY RECORDER ONLY)              * 38369920
*        BIT 1-1 NO ROOM FLAG FOR A LONG RECORD                       * 38419920
*        BIT 2-7 RESERVED                                             * 38469920
*BYTE 2  OF MCHINT                                                    * 38519920
*        BIT 0 - LOGREC FULL MSG TO BE OUTPUTTED                      * 38569920
*        BIT 1 - I/O ERROR MSG TO BE OUTPUTTED                        * 38619920
*        BIT 2 - DISK FORMAT ERROR MSG TO BE OUTPUTTED                * 38669920
*        BIT 3 - MCHIBUF CLOBBERED FLAG                               * 38689921
*        BIT 4 - SYS1.LOGREC NEAR FULL MESSAGE TO BE OUTPUTTED        * 38709921
*        BIT 5-7 RESERVED                                             * 38729921
*BYTE 3 OF MCHINT - RESERVED                                          * 38769920
*********************************************************************** 38819920
         EJECT                                                          38869920
*********************************************************************** 38919920
*                             ABREC FORMAT                            * 38969920
*********************************************************************** 39019920
*       *                                                             * 39069920
* +0    *                     HEADER                                  * 39119920
*       *                                                             * 39169920
*       *                                                             * 39219920
*       *                                                             * 39269920
*       *************************************************************** 39319920
*       *                                                             * 39369920
* +24   *                     PROG ID                                 * 39419920
*       *                                                             * 39469920
*       *************************************************************** 39519920
*       *                                                             * 39569920
* +32   *                     JOB  ID                                 * 39619920
*       *                                                             * 39669920
*       *************************************************************** 39719920
*       *                                                             * 39769920
* +40   *                     MCOPSW                                  * 39819920
*       *                                                             * 39869920
*       *************************************************************** 39919920
*       *                                                             * 39969920
* +48   *                     MCIC                                    * 40019920
*       *                                                             * 40069920
*       *************************************************************** 40119920
*       *                                                             * 40169920
* +56   *                     RMS INDEPENDENT SUMMARY                 * 40219920
*       *                     PURGED RECORD COUNTERS                  * 40269920
*       *                                                             * 40319920
*       *************************************************************** 40369920
*       *              *                                                40419920
* +70   *    FLAG      *                                                40469920
*       *              *                                                40519920
************************                                                40569920
         SPACE 3                                                        40619920
*********************************************************************** 40669920
*        FLAG                                                         * 40719920
*        BIT 0 ACTIVE BUFFER                                          * 40769920
*        BIT 1 SHORT ABREC                                            * 40819920
*        BIT 2 LONG ABREC(INCLUDES ABREC,INDEPENDENT LOG,EXTENDED LOG,* 40869920
*              AND MCH DATA),                                         * 40919920
*        BIT 3 CLOBBER                                                * 40969920
*        BITS 4-7 RESERVED                                            * 41019920
*********************************************************************** 41069920
         EJECT                                                          41119920
*                                                                     * 41159921
*     S Y S 1 . L O G R E C   H E A D E R   R E C O R D   A R E A     * 41199921
*                                                                     * 41239921
*                                                                     * 41279921
*       *************************************************************** 41319921
*       *               *                               *             * 41359921
*  +0   *   F F F F     *          LOW EXTENT           *    EXTENT   * 41399921
*       *               *            (CCHH)             *     (CC)    * 41439921
*       *************************************************************** 41479921
*       * HIGH EXTENT   *       *      RECORD ENTRY AREA ADDRESS      * 41519921
*  +8   *   (CONT.)     * SPARE *             (BBCCHHR)               * 41559921
*       *     (HH)      *       *                                     * 41599921
*       *************************************************************** 41639921
*       *  REC. ENTRY   *  REMAINING     *  TOTAL BYTES *  ADDRESS OF * 41679921
*  +16  *  AREA ADDR.   *   BYTES ON     *      ON      *  LAST RECORD* 41719921
*       *    (CONT.)    *    TRACK       *    TRACK     *   WRITTEN   * 41759921
*       *************************************************************** 41799921
*       *           ADDRESS OF LAST RECORD       *    TRACKS   * EARLY* 41839921
*  +24  *                WRITTEN (CONT.)         *      PER    * WARN * 41879921
*       *                                        *   CYLINDER  * COUNT* 41919921
*       *************************************************************** 41959921
*       * EARLY * DEV- *     EARLY WARNING              * EARLY*  CK. * 41999921
*  +32  * WARN. *  ICE *               MESSAGE TRACK    * WARN.* BYTE * 42039921
*       * COUNT * CODE *                                *SWITCH* (FF) * 42079921
*       *************************************************************** 42119921
         EJECT                                                          42269920
*********************************************************************** 42319920
* MCHINT-INTERFACE WORD                                               * 42369920
*********************************************************************** 42419920
*BYTE 0                                                               * 42469920
*        BIT 0- 0 ERROR RECORDER FUNCTION NOT NEEDED                  * 42519920
*        BIT 0- 1 INVOKE ERROR RECORDER                               * 42569920
*        BIT 1- 0 WTO FUNCTION NOT NEEDED                             * 42619920
*        BIT 1- 1 INVOKE WTO FUNCTION                                 * 42669920
*        BIT 2-7  RESERVED                                            * 42719920
*BYTE 1                                                               * 42769920
*        BIT 0-0 NO CHANNEL CHECK RECORD                              * 42819920
*              1 CHANNEL CHECK RECORD FOR EMERGENCY RECORDER TO OUTPUT* 42869920
*        BIT 1-1 NO ROOM FLAG ON SYS1.LOGREC FOR LONG RECORD          * 42919920
*BYTE 2                                                               * 42969920
*        BIT 0-1 LOGREC FULL MESSAGE TO BE OUTPUTTED                  * 43019920
*        BIT 1-1 I/O ERROR MESSAGE TO BE OUTPUTTED                    * 43069920
*        BIT 2-1 DISK FORMAT ERROR MESSAGE TO BE OUTPUTTED            * 43119920
*        BIT 3-7 RESERVED                                             * 43169920
*BYTE 3  RESERVED                                                     * 43219920
*********************************************************************** 43269920
         EJECT                                                          43319920
IGFMCHE3 CSECT                                                          43369920
         SPACE 2                                                        43419920
******************* R E G I S T E R   U S A G E *********************** 43469920
RECODE   EQU   0                   REGISTER FOR RETURN CODE             43519920
REG0     EQU   0                   W                                    43569920
REG1     EQU   1                   O                                    43619920
WORK1    EQU   2                   R                                    43669920
WORK2    EQU   3                   K                                    43719920
WORK3    EQU   4                                                        43769920
WORK4    EQU   5                   R                                    43819920
CURBUF   EQU   6                   PTR TO ABREC                         43869920
REG6     EQU   6                   E                                    43919920
IOREG    EQU   7                                                        43969920
REG7     EQU   7                   G                                    44019920
REG8     EQU   8                   S                                    44069920
R9       EQU   9                   BASE FOR RECORD BUILD AREA           44119920
CVTREG   EQU   10                  ADDRESS OF CVT                       44169920
COMBASE  EQU   11                  ADDRESS OF MCH COMMON AREA           44219920
NUCBASE  EQU   12                  ENTRY POINT OF NUCLEUS               44269920
SAVEARE  EQU   13                  ADDRESS OF SAVEAREA                  44319920
RETURN   EQU   14                  RETURN ADDRESS                       44369920
TRANBASE EQU   15                  BASE FOR TRANSIENT AREA              44419920
         SPACE 2                                                        44469920
*************************** E Q U A T E S ***************************** 44519920
K0       EQU   0                   DECIMAL VALUE OF 0                   44569920
K1       EQU   1                   DECIMAL VALUE OF 1                   44619920
K2       EQU   2                   DECIMAL VALUE OF 2                   44669920
K3       EQU   3                   DECIMAL VALUE OF 3                   44719920
K4       EQU   4                   DECIMAL VALUE OF 4                   44769920
K5       EQU   5                   DECIMAL VALUE OF 5                   44819920
K6       EQU   6                   DECIMAL VALUE OF 6                   44869920
K7       EQU   7                   DECIMAL VALUE OF 7                   44919920
K8       EQU   8                   DECIMAL VLUE OF 8                    44969920
K10      EQU   10                  DECIMAL VALUE OF 10                  45019920
K11      EQU   11                  DECIMAL VALUE OF 11                  45069920
K12      EQU   12                  DISPLACEMENT OF 12                   45119920
K17      EQU   17                  *                                    45139921
K20      EQU   20                  DECIMAL VALUE OF 20                  45169920
K21      EQU   21                  DECIMAL VALUE                        45179920
K22      EQU   22                  DECIMAL VALUE OF 22                  45219920
K23      EQU   23                  DECIMAL VALUE OF 23                  45269920
K25      EQU   25                  *                                    45289921
K28      EQU   28                  DECIMAL VALUE OF 28                  45319920
K33      EQU   33                  DISPLACEMENT TO UCB ADDRESS IN DEB   45369920
K36      EQU   36                  DECIMAL VALUE OF 36                  45419920
K40      EQU   40                  DECIMAL VALUE OF 40                  45469920
K44      EQU   44                  DECIMAL VALUE OF 44                  45519920
K60      EQU   60                  DECIMAL VLAUE OF 60                  45569920
K61      EQU   61                  *                                    45589921
K81      EQU   81                  DECIMAL VALUE OF 81                  45619920
K82      EQU   82                  DECIMAL VALUE                  20302 45629920
K96      EQU   96                  DECIMAL VALUE OF 96                  45669920
K101     EQU   101                 *                                    45689921
K146     EQU   146                 DECIMAL VALUE OF 146                 45719920
K178     EQU   178                 DECIMAL VALUE                        45729920
K193     EQU   193                 DECIMAL VALUE OF 193                 45769920
K198     EQU   198                 DECIMAL VALUE OF 198       IC  60509 45779921
K299     EQU   299                 *                                    45789921
K289     EQU   289                 DECIMAL VALUE OF 289                 45819920
K347     EQU   347                 DECIMAL VALUE OF 347           20302 45869920
K634     EQU   634                 DECIMAL VALUE OF 634                 45919920
K2137    EQU   2137                DECIMAL VALUE OF 2137                45969920
K2148    EQU   2148                DECIMAL VALUE OF 2148                46019920
K63      EQU   63                  DECIMAL VALUE OF 63         @S60509P 46029921
K108     EQU   108                 DECIMAL VALUE OF 108        @S60509P 46039921
K236     EQU   236                 DECIMAL VALUE OF 236        @S60509P 46049921
X01      EQU   X'01'               MASK FOR EXTENDED DCB                46069920
X02      EQU   X'02'               MASK OF 2 FOR KEY LENGTH             46119920
X04      EQU   X'04'                                                    46169920
X07      EQU   X'07'                                                    46219920
X09      EQU   X'09'                                                    46269920
X20      EQU   X'20'                                                    46319920
X42      EQU   X'42'               FLAG 1 FIELD IN IOB                  46369920
X90      EQU   X'90'               LACATION OF LOG AREA                 46419920
XFF      EQU   X'FF'               MASK OF FF                           46469920
         SPACE                                                          46519920
X05      EQU   X'05'               CODE FOR WRITE HEADER                46569920
X06      EQU   X'06'               CODE FOR READ HEADER                 46619920
X08      EQU   X'08'               CODE FOR TIC                         46669920
X1D      EQU   X'1D'               CODE FOR WRITE COUNT,KEY,DATA        46719920
X28      EQU   X'28'               LENGTH OF HEADER RECORD        21021 46769921
X31      EQU   X'31'               CODE FOR SEARCH ON ID EQUAL          46819920
COMCHAIN EQU   X'40'               COMMAND CHAINING BIT ON              46869920
DATCHAIN EQU   X'80'               DATA CHAINING BIT ON                 46919920
         SPACE                                                          46969920
SHORTCNT EQU   78                  COUNT FOR SHORT RECORD               47019920
LONGCNT  EQU   56                  LENGTH OF LONG RECORD                47069920
LNGLEN   EQU   48                  TOTAL LENGTH OF ABREC FOR LONG       47119920
SHRLEN   EQU   70                  TOTAL LENGTH OF ABREC                47169920
ABCT     EQU   70                  LENGTH OF SHORT RECORD(DATA LENGTH)  47219921
ABCTL    EQU   48                  LENGTH OF LONG RECORD(DATA LENGTH)   47269921
ABRECL   EQU   48                  LENGTH OF ABREC FOR LONG RECORD      47319920
FLAG1    EQU   70                  PTR TO FLAG                          47369920
TOTAL    EQU   71                  LENGTH OF TOTAL RECORD               47419920
INDL     EQU   280                 LENGTH OF INDEPENDENT LOG            47469920
AREA     EQU   114                 LENGTH OF MCHWORK TO BE CLEARED      47519920
         SPACE                                                          47569920
OFF      EQU   X'00'               ALL BITS OFF                         47619920
ACTIVE   EQU   X'80'               ACTIVE ABREC BIT                     47669920
LONG     EQU   X'20'               LONG RECORD BIT                      47719920
SHORT    EQU   X'40'               SHORT RECORD BIT                     47769920
         SPACE                                                          47819920
NOCCH    EQU   X'7F'               CCH RECORD FLAG OFF                  47869920
CCH      EQU   X'80'               CCH RECORD FLAG                      47919920
LONGON   EQU   X'40'               NO ROOM FOR LONG RECORD ON LOGREC    47969920
NOLONG   EQU   X'BF'               NOROOM FOR LONG RECORD FLAG OFF      48019920
FULL     EQU   X'80'               MASK FOR LOGREC FULL                 48069920
HDSWITCH EQU   X'80'               HEAD SWITCH                          48119920
*********************************************************************** 48169920
         EJECT                                                          48219920
*********************************************************************** 48269920
         USING *,TRANBASE                                               48319920
         USING CVTSECT,CVTREG                                           48369920
         USING MCHCOMON,COMBASE                                         48419920
         USING BUILDARA,R9                                              48469920
ORIGIN   EQU   *                                                        48519920
         MVI   MCHEXLEV,K3         CHANGE LEVEL OF MODULE     IC  60509 48569921
CCHREC   EQU   *                                                        48619920
         TM    CCHFLAG,CCH         TEST FOR CCH RECORD                  48669920
         BNO   ACTCHECK            NO GO SETUP MCH RECORD         21021 48689921
         LH    REG8,CCHLEN         SAVE LENGTH OF CCH RECORD      21021 48709921
         B     BUILDCCW            FOR LATER                      21021 48729921
         SPACE                                                          48769920
*********************************************************************** 48819920
* THIS ROUTINE WILL TEST FOR ACTIVE BUFFERS AND IF THERE ARE ANY IT   * 48869920
* WILL SET THE FLAG FOR THE PARTICULAR TYPE OF RECORD                 * 48919920
*********************************************************************** 48969920
ACTCHECK EQU   *                                                        49019920
         SR    WORK1,WORK1         CLEAR REGISTER                       49069920
         IC    WORK1,MCHABRNO      LOAD NUMBER OF RECORD BUFFERS        49119920
         LA    CURBUF,MCHABREC     ADDRESS OF FIRST RECORD BUFFER       49169920
         SPACE                                                          49219920
TEST1    TM    FLAG1(CURBUF),ACTIVE TEST FOR ACTIVE BUFFER              49269920
         BO    TEST2               YES-ACTIVE                           49319920
TRYSHRT  EQU   *                                                        49369920
         LA    CURBUF,TOTAL(CURBUF) ADDRESS OF NEXT RECORD BUFFER       49419920
         BCT   WORK1,TEST1         SUBTRACT 1 FROM NO OF RECORD BUFFERS 49469920
         B     EXITRTN             IF NO=0 GO TO EXIT                   49519920
TEST2    CL    CURBUF,MCHLONG      TEST FOR A LONG RECORD               49569920
         BNE   SETSHORT            NO GO SET SHORT EXCP FLAG            49619920
         OI    FLAG1(CURBUF),LONG  SET LONG RECORD FLAG                 49669920
         TM    NOROOM,LONGON       TEST FOR NO ROOM FOR LONG RECORD     49719920
         BO    TRYSHRT             TEST NEXT BUFFER                     49769920
         B     BUILDCCW            GO BUILD CCWS                        49819920
SETSHORT OI    FLAG1(CURBUF),SHORT SET SHORT RECORD FLAG                49869920
         SPACE 3                                                        49919920
*********************************************************************** 49969920
* THIS ROUTINE SETS UP THE IOB AND THE COMMON PARTS OF THE CCWS IN    * 50019920
* MCHWORK AREA                                                        * 50069920
*********************************************************************** 50119920
BUILDCCW EQU   *                                                        50169920
         XC    HDRREC(AREA),HDRREC CLEAR MCHWORK AREA                   50219920
         L     R9,MCHBUILD         GET ADDRESS OF RECORD BUILD AREA     50269920
         MVI   SRCHFLAG,COMCHAIN   SET COMMAND CHAINING                 50319920
         MVI   TICFLAG,COMCHAIN    SET COMMAND CHAINING                 50369920
         MVI   SRCHCNT,X05         SET COUNT FOR SEARCH IS 5            50419920
         MVI   TICCNT,X01          SET COUNT FOR TIC IS 1               50469920
         LA    WORK1,SEARCH        ADDR OF FIRST CCW ON CHAIN           50519920
         ST    WORK1,MCHICCWS      ADDR OF CCW LIST                     50569920
         ST    WORK1,TIC           STORE ADDRESS IN TIC CCW             50619920
         MVI   TIC,X08             CODE FOR TIC                         50669920
         L     WORK1,CVTDCB        DCB ADDRESS FOR LOGREC               50719920
         ST    WORK1,MCHIODCB      SAVE DCB ADDRESS IN IOB              50769920
         SPACE 3                                                        50819920
*********************************************************************** 50869920
* THIS ROUTINE COMPLETES THE CCWS FOR READING OF HEADER RECORD        * 50919920
*********************************************************************** 50969920
         L     WORK1,K44(WORK1)    ADDRESS OF DEB                       51019920
         MVC   SEEKADR(K6),K36(WORK1) MOVE BBCCHH FROM DEB TO SEEK      51069920
         MVI   SEEKADR+K6,K1       SET SEARCH FIELD TO ID OF ONE        51119920
         MVI   MCHIOBSK,OFF        CLEAR M-EXTENT NO FOR LOGREC         51169920
         BAL   WORK2,COMHDRED      GO FIX CCWS FOR HEADER READ          51219920
         MVI   GENCCW,X06          SET CODE FOR READING OF LOGREC HDR   51269920
         BAL   IOREG,IORTN         GO TO RTN TO DO I/O                  51319920
         CLI   SFTBYTS,XFF         COMPARE SAFETY BYTES IN HEADER       51369920
         BC    K7,EXIT1            HDR RECORD FORMAT ERROR-EXIT         51419920
         SPACE 3                                                        51469920
READY    EQU   *                                                        51519920
         TM    CCHFLAG,CCH         TEST FOR CCH RECORD                  51569920
         BO    CCHLENG             YES GO FIND CCH LENGTH               51619920
         TM    FLAG1(CURBUF),SHORT TEST FOR SHORT RECORD                51669920
         BO    SHORTREC            YES-GO COMPUTE LENGTH                51719920
         SPACE                                                          51769920
         SPACE                                                          51819920
*********************************************************************** 51869920
* THIS ROUTINE FILLS IN THE PARTS OF THE CCW'S UNIQUE FOR WRITING THE * 51919920
* LONG RECORD                                                         * 51969920
*********************************************************************** 52019920
         L     WORK4,MCHINLOG      ADDRESS OF INDEPENDENT LOG           52069920
         LH    WORK2,K6(WORK4)     LENGTH OF EXTENDED LOG               52119920
         LA    WORK2,INDL(WORK2)   ADD LENGTH OF IND LOG                52169920
         AR    WORK4,WORK2         GET PTR TO DAMAGE ASSES BUFFER       52219920
         L     WORK1,MCHREMCH      PTR TO DAMAGE ASSESSMENT FIELD       52269920
         LH    WORK3,K0(WORK1)     GET LENGTH OF DAMAGE ASSESSMENT DATA 52319920
         AR    WORK2,WORK3         TOTAL LENGTH OF LONG MINUS 10        52369920
         BCTR  WORK3,K0            DECREMENT MOVE FOR EX MOVE           52419920
         EX    WORK3,MOVEDA        GO MOVE DAMAGE ASSESS. FIELD INTO    52469920
*                                  RECORD FROM MCHCOMMON AREA           52519920
         LR    WORK3,WORK2         SAVE COUNT                           52569920
         LA    WORK3,LONGCNT(WORK3) GET TOTAL LENGTH OF RECORD          52619920
         STH   WORK3,COUNT         SET COUNT IN CCW FOR WRITING OF      52669920
*                                  RECORD                               52719920
         LA    WORK2,ABCTL(WORK2)  GET LENGTH OF RECORD USED FOR DETER- 52769920
*                                  MINING SPACE NEEDED ON DIRECT ACCESS 52819920
         LA    R9,K22(R9)          UPDATE ADDRESS OF BUILD AREA FOR     52869920
*                                  LONG RECORD                          52919920
         MVC   ABRECCUR(LNGLEN),K0(CURBUF) MOVE ABREC TO BUFFER         52969920
         SPACE 2                                                        53019920
*********************************************************************** 53069920
* THIS ROUTINE FILLS IN THE PARTS OF THE CCW'S COMMON TO THE WRITING  * 53119920
* OF LONG AND SHORT RECORDS                                           * 53169920
*********************************************************************** 53219920
COMMON   EQU   *                                                        53269920
         ST    R9,GENCCW           SET ADDR OF RECORD BUFFER            53319920
         MVI   CTFLDKEY,OFF        SET KEY LENGTH TO ZERO         21021 53369921
         STH   WORK2,CTFLDDL       SET DATA LENGTH FIELD FOR RECORD     53419920
         SPACE 3                                                        53519920
*********************************************************************** 53569920
* THIS ROUTINE FILLS IN THE PARTS OF THE CCW'S COMMON TO THE WRITING  * 53619920
* OF LONG,SHORT AND CCH RECORDS                                       * 53669920
*********************************************************************** 53719920
COMALL   EQU   *                                                        53769920
         LA    WORK1,MCHIOBSK+K3   RESOLVE SEEK ADR                     53819920
         ST    WORK1,SEARCH        SET SEARCH ADDR IN CCW               53869920
         MVI   SEARCH,X31          SET SEARCH CODE IN CCW               53919920
         MVI   GENCCW,X1D          SET CODE FOR WRITE TO LOGREC         53969920
         MVC   MCHIOBSK+K7(K1),LASTTTR+K6 SET ID IN IOB SEEK FIELD      54019920
         EJECT                                                          54069920
*********************************************************************** 54099921
*                                                                     * 54129921
*  THIS ROUTINE WILL FIND THE SPACE NEEDED FOR THE RECORD ACCORDING   * 54159921
*       TO THE PARTICULAR DEVICE THAT SYS1.LOGREC RESIDES ON  -       * 54189921
*        2311,2301,2303,2305 MODELS I AND II,2314, AND 3330.          * 54219921
*                                                                     * 54249921
*********************************************************************** 54279921
*  DEVICE *DEVICE  *  FORMULA FOR SPACE FOR   *  FORMULA FOR SPACE FOR* 54309921
*         * TYPE   *     RECORD WITH KEY      *    RECORD WITHOUT KEY * 54339921
*********************************************************************** 54369921
*   2311      01   *   81 + 537(KL+DL)/512    *   61 + 537(DL)/512    * 54399921
*   2301      02   *  186 + KL + DL           *  133 + DL             * 54429921
*   2303      03   *  146 + KL + DL           *  108 + DL             * 54459921
*   2305(1)   06   *  634 + 2 + KL + DL       *  432 + 2 + DL         * 54489921
*   2305(2)   07   *  289 + KL + DL           *  198 + DL    IC  60509* 54519921
*   2314      08   *  146 + 2137(KL+DL)/2048  *  101 + 2137(DL)/2048  * 54549921
*   3330      09   *  193 + KL + DL           *  135 + DL             * 54579921
*   WHERE     KL = KEY LENGTH                                         * 54609921
*             DL = DATA LENGTH                                        * 54639921
*********************************************************************** 54669921
* UPON ENTRY TO THIS ROUTINE WORK2 HAS NUMBER OF BYTES OF RECORD MINUS* 54819920
* 10                                                                    54869920
SPACE    EQU   *                                                        54919920
         SR    WORK1,WORK1         CLEAR REGISTER                       54969920
         IC    WORK1,DEVICE        GET DEVICE TYPE FOR LOGREC HEADER    55019920
         SLL   WORK1,K1            SHIFT DEVICE TYPE OVER               55069920
         LH    WORK1,BRTABLE-K2(WORK1) GET PTR TO DEVICE TABLE ENTRY    55119920
         B     ORIGIN(WORK1)       GO TO APPROPIATE DEVICE ROUTINE      55169920
T2314    EQU   *                                                        55219920
         LA    WORK3,K101          ADDITION FACTOR FOR 2314       21021 55269921
         LA    WORK4,K2137         MULTIPLYING FACTOR FOR 2314          55319920
         SPACE                                                          55369920
COMMULT  EQU   *                                                        55419920
         MR    WORK1,WORK4         MULT TOTAL LENGTH BY FACTOR          55469920
         SRL   WORK2,K11           DIVIDE BY 2048                       55519920
         AR    WORK2,WORK3         ADD VALUE CONSTANT TO RESULT         55569920
         B     TSTBYREM            GO TO TEST NO OF BYTES LEFT          55619920
T2311    EQU   *                                                        55669920
         LA    WORK3,K61           ADDITION FACTOR FOR 2311       21021 55719921
         LA    WORK4,K2148         MULTIPLYING FACTOR FOR 2311          55769920
         B     COMMULT             BRANCH TO ROUTINE TO MULTIPLY        55819920
T2305A   EQU   *                                                  21021 55869921
         LA    WORK2,K236(WORK2)   2305I FORMULA IS DL+434     @S60509P 55919921
T2305C   EQU   *                                               @S60509P 55929921
         LA    WORK2,K63(WORK2)    2305II FORMULA IS DL+198    @S60509P 55939921
T3330    EQU   *                        21021                           55969921
         LA    WORK2,K2(WORK2)     3330 FORMULA IS DL+135         21021 56019921
T2301    EQU   *                                                  21021 56069921
         LA    WORK2,K25(WORK2)    2301 FORMULA IS DL+133         21021 56119921
T2303    EQU   *                                                  21021 56169921
         LA    WORK2,K108(WORK2)   2303 FORMULA IS DL+108      @S60509P 56219921
         EJECT                                                          56419920
*********************************************************************** 56469920
*****    ROUTINE TO DETERMINE IF ENOUGH BYTES REMAINING ON TRACK   **** 56519920
*********************************************************************** 56569920
*    AT THIS POINT WORK2 CONTAINS THE AMOUNT OF SPACE REQUIRED BY THE * 56619920
*    PARTICULAR DEVICE FOR THE RECORD WHICH IS TO BE WRITTEN          * 56669920
*********************************************************************** 56719920
TSTBYREM LH    WORK3,BYTSREM       NO OF BYTES REMAINING ON TRACK       56769920
         SLR   WORK3,WORK2         SUB LENGTH OF ERROR RECORD FROM      56819920
*                                  REM BYTES                            56869920
         BO    TCHKLAST            BR IF RECORD WILL FIT ON TRACK       56919920
         CLC   UPLIMIT(K4),LASTTTR+K2 COMPARE CCHH WITH EXTENT          56969920
         BE    FULOGREC            LOGREC IS FULL WHEN EQUAL TO EXTENT  57019920
         SPACE 3                                                        57069920
*********************************************************************** 57119920
*               CHECK IF END OF CYLINDER                              * 57169920
*********************************************************************** 57219920
TESTCYL  LH    WORK3,LASTTTR+K4    LOAD LAST USED HEAD POSITION         57269920
         LA    WORK3,K1(WORK3)     ADD ONE TO HEAD POSITION             57319920
         XR    WORK4,WORK4         CLEAR REG                            57369920
         ICM   WORK4,K3,TRKSPER    GET R TRACKS/CYLINDER AND CNT  21021 57419921
         CLR   WORK4,WORK3         COMPARE HD CT TO TRACK/CYLINDER      57469920
         BNH   TCYLEND             BR EQ/LOW- END OF CYLINDER           57519920
         SPACE 3                                                        57569920
*********************************************************************** 57619920
*         IF NECESSARY, UPDATE HEAD POSITION TO SWITCH TRACKS         * 57669920
*********************************************************************** 57719920
TRKUPDT  STH   WORK3,LASTTTR+K4    STORE NEXT HEAD POSITION IN HDR      57769920
         MVI   MCHIOBSK+K7,K0      SET ID IN IOB SEEK FIELD TO 0        57819920
         MVI   LASTTTR+K6,K0       SET RECORD ENTRY ID TO ZERO          57869920
         MVC   BYTSREM(K2),TRKCAP  SET REMAINING BYTE ON TRK TO MAX     57919920
         B     TSTBYREM            TRY AGAIN                            57969920
         SPACE 3                                                        58019920
*********************************************************************** 58069920
* THIS ROUTINE FILLS IN THE PARTS OF THE CCW'S UNIQUE FOR WRITING THE * 58119920
* CHANNEL CHECK RECORD                                                * 58169920
*********************************************************************** 58219920
CCHLENG  EQU   *                                                        58269920
         STH   REG8,COUNT          SET COUNT FOR CCH RECORD       21021 58319921
         MVC   CCWADR(K3),CCHADDR+K1 SET ADDR OF CCH RECORD             58369920
         LR    WORK2,REG8          GET LENGTH FOR FIND SPACE RTN  21021 58419921
         B     COMALL              GO TO RTN WHICH ALL 3 RECORDS USE    58469920
         SPACE 2                                                        58519920
* THIS ROUTINE WILL FILL IN CCHHR IN COUNT FIELD OF CCH RECORD          58569920
CCHSETUP EQU *                                                          58619920
         L     WORK1,CCHADDR       GET ADDR OF CCH RECORD               58669920
         MVC   K0(K5,WORK1),LASTTTR+K2 SET UP COUNT FIELD FOR CCH REC   58719920
         B     ALLSET              ALL SET FOR I/ O                     58769920
         SPACE 2                                                        58819920
*********************************************************************** 58869920
* THIS ROUTINE FILLS IN THE PARTS OF THE CCW'S UNIQUE FOR WRITING THE * 58919920
* SHORT RECORD                                                        * 58969920
*********************************************************************** 59019920
SHORTREC EQU   *                                                        59069920
         MVI   COUNTA,SHORTCNT     COUNT FOR SHORT RECORD               59119920
         MVC   ABRECCUR(SHRLEN),K0(CURBUF) MOVE ABREC TO BUFFER         59169920
         LA    WORK2,ABCT          GET LEN OF REC USED TO DETER-  21021 59199921
*                                  MINE SPACE NEEDED ON DEVICE    21021 59229921
         B     COMMON              GO TO RTN TO FILL IN COMMON PARTS OF 59269920
*                                  CCWS                                 59319920
         SPACE 3                                                        59369920
*********************************************************************** 59419920
*               IF NECESSARY, UPDATE CYLINDER POSITION                * 59469920
*********************************************************************** 59519920
TCYLEND  EQU   *                                                  20201 59529920
         XR    WORK3,WORK3         CLEAR REGISTER FOR ZERO HEAD   20201 59569920
         LH    WORK4,LASTTTR+K2    LOAD LAST USED CYLINDER POSITION     59619920
         LA    WORK4,K1(WORK4)     ADD ONE TO CYLINDER COUNT            59669920
         STH   WORK4,LASTTTR+K2    STORE UPDATED CYLINDER COUNT         59719920
         B     TRKUPDT             UPDATE HEADER                        59769920
*********************************************************************** 59819920
*               CHECK RECORDING SPACE IN EXTENT                       * 59869920
*********************************************************************** 59919920
TCHKLAST STH   WORK3,BYTSREM       STORE REMAINING BYTE COUNT           59969920
TSET     XR    WORK4,WORK4         CLEAR REGISTER                       60019920
         IC    WORK4,LASTTTR+K6    LOAD ID OF LAST REC WRITTEN          60069920
         LA    WORK4,K1(WORK4)     ADD ONE TO FIELD COUNT               60119920
         STC   WORK4,LASTTTR+K6    UPDATE LAST ID WRITTEN IN HDR        60169920
         SPACE 3                                                        60219920
*********************************************************************** 60269920
*                                                                     * 60319920
*                ROUTINE TO WRITE RECORD ON SYS1.LOGREC               * 60369920
*                                                                     * 60419920
*********************************************************************** 60469920
         TM    CCHFLAG,CCH         CCH RECORD BEING PROCESSED           60519920
         BO    CCHSETUP            YES SET UP COUNT FIELD ID FOR CCH    60569920
         MVC   CTFLDID(K5),LASTTTR+K2 SET UP COUNT FIELD ID WITH        60619920
*                                  UPDATED CCHHR                        60669920
ALLSET   EQU   *                                                        60719920
         MVC   MCHIOBSK+K1(K6),LASTTTR FILL IN IOB SEEK FIELD WITH LAST 60769920
*                                   USED POSITION                       60819920
         BAL   IOREG,IORTN         GO TO RTN TO DO I/O                  60869920
         SPACE 3                                                        60919920
*********************************************************************** 60969920
*                                                                     * 61019920
*                ROUTINE TO SETUP AND WRITE AN END OF FILE            * 61069920
*                                                                     * 61119920
* END OF FILE IS ALWAYS WRITTEN AS VERY LAST RECORD ON DATA SET       * 61169920
* UNLESS IT IS THE LAST RECORD AND THEN IT IS WRITTEN RIGHT AFTER     * 61219920
* THE RECORD                                                          * 61269920
*********************************************************************** 61319920
         TM    CCHFLAG,CCH         TEST FOR CCH RECORD                  61369920
         BO    CCHEOF              YES - WRITE EOF FOR CCH RECORD       61419920
         LA    WORK1,CTFLDID       GET ADDRESS OF CTFIELD               61469920
EOFWRITE EQU       *                                                    61519920
* REGISTER WORK1 CONTAINS THE ADDRESS OF CTFIELD FOR EITHER RECORD      61569920
* AT THIS POINT                                                         61619920
         CLC   UPLIMIT(K4),LASTTTR+K2 COMPARE CCHH WITH EXTENT          61669920
         BNE   SWITCHY             BR-HEAD SWITCHING REQUIRED           61719920
         MVC   MCHIOBSK+K1(K7),LASTTTR MOVE SEEK ADDR TO IOB            61769920
         MVI   K4(WORK1),XFF       SET EOF ID                           61819920
         B     WRTEOF              WRITE EOF AS NEXT RECORD             61869920
CCHEOF   EQU   *                                                        61919920
         L     WORK1,CCHADDR       GET ADDR OF CCH RECORD               61969920
         B     EOFWRITE            GO WRITE EOF                         62019920
SWITCHY  XC    MCHIOBSK+K3(K5),MCHIOBSK+K3 CLEAR SEEK ADDR              62069920
         MVC   MCHIOBSK+K3(K4),UPLIMIT MOVE SEEK ADDR TO IOB            62119920
         MVI   K4(WORK1),X01       SET EOF ID                           62169920
WRTEOF   MVC   K0(K4,WORK1),MCHIOBSK+K3 MOVE CCHH TO EOF RECORD         62219920
         XC    K5(K3,WORK1),K5(WORK1) CLEAR RECORD COUNT FIELD          62269920
         MVI   COUNT,OFF           CLEAR 1ST BYTE OF COUNT FILED        62319920
         MVI   COUNTA,X08          SET COUNT FIELD FOR EOF WRITE        62369920
         BAL   IOREG,IORTN         GO TO RTN TO DO I/O                  62419920
         SPACE 3                                                        62469920
*********************************************************************** 62519920
*                                                                     * 62569920
*                ROUTINE TO WRITE HEADER RECORD BACK                  * 62619920
*                                                                     * 62669920
*********************************************************************** 62719920
         BAL   WORK2,COMHDRED      GO FIX CCWS FOR HEADER WRITE         62769920
         MVI   GENCCW,X05          SET CODE TO WRITE LOGREC HEADER      62819920
         BAL   IOREG,IORTN         GO TO RTN TO DO I/O                  62869920
         TM    CCHFLAG,CCH         TEST FOR CCH RECORD                  62919920
         BO    CLEARCCH            NO-CLEAR CCH FLAGS                   62969920
CLEAR    NI    FLAG1(CURBUF),OFF   CLEAR ALL BITS                       63019920
         B     ACTCHECK            BRANCH TO BEGINNING                  63069920
*  ROUTINE TO SET COMMON PARTS OF CCWS FOR READING OR WRITING OF        63119920
*  SYS1.LOGREC HEADER RECORD                                            63169920
         SPACE 3                                                        63219920
COMHDRED EQU   *                                                        63269920
         MVI   COUNTA,X28          SET COUNT OF HEADER RECORD     21021 63319921
         LA    WORK1,HDRREC        SET ADDR OF HEADER RECORD BUFFER     63369920
         ST    WORK1,GENCCW        SET ADDR OF RECORD                   63419920
         LA    WORK1,SEEKADR+K2    RESOLVE SEEK ADDR                    63469920
         ST    WORK1,SEARCH        SET SEEK ADDR IN SEARCH CCW          63519920
         MVI   SEARCH,X31          SET SEARCH CODE IN CCW               63569920
         MVC   MCHIOBSK+K1(K7),SEEKADR PLACE SEEK ADDR FOLLOWING IOB    63619920
         BR    WORK2               RETURN TO CALLER                     63669920
         SPACE 3                                                        63719920
FULOGREC EQU   *                                                        63769920
         TM    CCHFLAG,CCH         TEST FOR CCH RECORD                  63819920
         BO    CLEARCCH            YES-GO CLEAR FLAGS                   63869920
         TM    FLAG1(CURBUF),SHORT TEST FOR SHORT RECORD                63919920
         BO    EXIT1               YES-EXIT                             63969920
         OI    NOROOM,LONGON       TURN ON FLAG FOR NO ROOM FOR LONG    64019920
         B     ACTCHECK            CHECK FOR MORE ACTIVE BUFFERS        64069920
CLEARCCH EQU   *                                                        64119920
         NI    CCHFLAG,NOCCH       TURN OFF CCH RECORD FLAG             64169920
         B     ACTCHECK            TEST FOR MORE ACTIVE BUFFERS         64219920
         SPACE 3                                                        64269920
*********************************************************************** 64319920
* THE RETURN CODE IS SET IN MCHINTEL INDICATING TO SHUT THAT THE      * 64369920
* EMERGENCY RECORDER WAS SUCESSFUL.                                   * 64419920
*********************************************************************** 64469920
EXITRTN  EQU   *                                                        64519920
         OI    MCHINTEL,X01        RECORDER SUCESSFUL                   64569920
         SPACE 3                                                        64619920
* EXIT ROUTINE TO GET ADDRESS OF SHUT IN REGISTER 14 AND BRANCH TO IT.  64669920
EXIT1    EQU   *                                                        64719920
         TM    MCHINTEL,X20        WAIT STATE MSG ALREADY SET UP        64769920
         BO    EXIT2               YES-RETURN TO SHUT                   64819920
         SR    WORK3,WORK3         CLEAR REGISTER                 20302 64829920
         TM    MCHDAMAG+K3,X02     MCI-CCH ERROR                  20302 64839920
         BO    MCICCH              GO SET UP FOR MCI IN CCH MSG   20302 64849920
         TM    MCHDAMAG+K3,X01     SYSTEM DAMAGE                        64969920
         BO    SUPVMSG             YES-GO SET UP WAIT STATE MESSAGE     65019920
         TM    MCHDAMAG+K1,X04     CCH PUTTING SYSTEM DOWN              65069920
         BZ    EXIT2               NO-NO WAIT STATE MSGS TO BE SET UP   65119920
CCHWSMSG EQU   *                                                  20302 65129920
         LA    WORK1,CHANWSC       GET ADDRESS OF WSCODE AND MSG  20302 65139920
         L     WORK2,CCHADDR       GET ADDRESS OF CCH RECORD      20302 65149920
         IC    WORK3,K82(WORK2)    GET CHAN NO FROM CCH RECORD    20302 65159920
CNVTCHAN EQU   *                                                  20302 65161920
         IC    WORK3,CHARS(WORK3)  GET PRINTABLE CHARACTER        20302 65163920
         STC   WORK3,K22(WORK1)    STORE CHAN NO IN MESSAGE       20302 65165920
WSMSGSET EQU   *                                                        65219920
         MVC   MCHIBUF(K23),K0(WORK1) MOVE IN MESSAGE INTO BUFFER       65269920
         LA    WORK1,MCHIBUF+K23   FIND ENDING ADDRESS OF MESSAGE       65319920
         ST    WORK1,MCHIPTR       UPDATE MCHIPTR TO REFLECT MESSAGE    65369920
         OI    MCHINTEL,X20        INDICATE WAIT STATE MSG SET UP       65419920
EXIT2    EQU   *                                                        65469920
         L     RETURN,MCHSHUT      GET RETURN PT ADDR OF SHUT           65519920
         BR    RETURN              RETURN TO SHUT                       65569920
         SPACE 3                                                        65619920
MCICCH   LA    WORK1,CCHWSC        GET ADDRESS OF WSCODE AND MSG  20302 65669920
         L     WORK2,MCHINLOG      GET ADDR OF IND. LOG           20302 65719920
         IC    WORK3,K178(WORK2)   GET CHANNEL NUMBER FROM REG6   20302 65729920
*                                  IN IND. LOG SAVE AREA          20302 65739920
         B     CNVTCHAN            GO CONVERT CHAN NO TO PRINTBLE 20302 65749920
*                                  CHARACTER                      20302 65759920
SUPVMSG  EQU   *                                                        65819920
         LA    WORK1,SUPVWSC       GET ADDRESS OF WSCODE AND MESSAGE    65869920
         B     WSMSGSET            GO PUT MSG IN BUFFER                 65919920
         EJECT                                                          65969920
*********************************************************************** 66019920
* THIS ROUTINE HANDLES THE I/O FOR THIS MODULE. IT USES THE 10S INTER-* 66069920
* FACE WITH IOS BY-                                                   * 66119920
*         - SETTING UP THE ADDRESS OF IOB IN REGISTER 1               * 66169920
*         - SETTING UP RETURN POINT ADDRESS IN REGISTER 14            * 66219920
*         - BRANCHING TO ENTRY POINT MLDRIOGO                         * 66269920
*********************************************************************** 66319920
IORTN    EQU   *                                                        66369920
         L     WORK1,CVTDCB        DCB ADDRESS FOR SYS1.LOGREC          66419920
         L     WORK3,K44(WORK1)    ADDRESS OF DEB OF SYS1.LOGREC        66469920
         MVC   MCHUCB+K1(K3),K33(WORK3) COPY UCB ADDRESS                66519920
         LA    REG1,MCHIOB         ADDRESS OF IOB                       66569920
         LA    RETURN,IODONE       RETURN POINT ADDRESS                 66619920
         STM   REG0,TRANBASE,MCHMLSAV SAVE REGISTERS                    66669920
         L     TRANBASE,MCHEXCP    GET ADDRESS OF IOS INTERFACE RTN FOR 66719920
*                                  ADDRESSABILITY                       66769920
         B     K4(TRANBASE)        GO TO SPECIAL ENTRY TO IOS INTERFACE 66819920
*                                  RTN FOR EMERGENCY RECORDER           66869920
IODONE   EQU   *                                                        66919920
         BR    IOREG               RETURN TO CALLER                     66969920
         NOPR  WORK1               FILLER OF TWO BYTES                  67019920
*IOS INTERFACE ROUTINE RETURNS CONTROL HERE IF I/O WAS UNSUCESSFUL.     67069920
NOGOOD   EQU   *                                                        67119920
         B     EXIT1                GO TO EXIT RTN-I/O NO GOOD          67169920
         SPACE 2                                                        67219920
         EJECT                                                          67269920
SUPVWSC  DC    X'0A05'             WAIT STATE CODE AND MSG FOR          67319920
SUPVTXT  DC    C'*IGF002W   SUPVR MC  ' SYSTEM DAMAGE                   67369920
CCHWSC   DC    X'0A0B'             WAIT STATE CODE AND MSG FOR          67419920
CCHTXT   DC    C'*IGF012W   MCI-CCH   ' MCI IN CCH                      67469920
CHANWSC  DC    X'0A0A'             WAIT STATE CODE AND MSG FOR          67519920
CHANTXT  DC    C'*IGF013W   CHAN ERR  ' CCH PUTTING SYSTEM DOWN         67569920
CHARS    DC    C'0123456789ABCDEF' TABLE OF PRINTABLE CHARACTERS  20302 67579920
         SPACE 3                                                        67619920
         DS    0H                  ALIGN ON HALF WORD BOUNDARY          67669920
BRTABLE  DC    AL2(T2311-ORIGIN)   ENTRY FOR 2311                       67719920
         DC    AL2(T2301-ORIGIN)   ENTRY FOR 2301                       67769920
         DC    AL2(T2303-ORIGIN)   ENTRY FOR 2303                       67819920
         DC    AL2(EXIT1-ORIGIN)   ENTRY FOR ERROR DEVICE TYPE          67869920
         DC    AL2(EXIT1-ORIGIN)   ENTRY FOR ERROR DEVICE TYPE          67919920
         DC    AL2(T2305A-ORIGIN)  ENTRY FOR 2305A                      67969920
         DC    AL2(T2305C-ORIGIN)  ENTRY FOR 2305C                      68019920
         DC    AL2(T2314-ORIGIN)   ENTRY FOR 2314                       68069920
         DC    AL2(T3330-ORIGIN)   ENTRY FOR 3330                       68119920
         SPACE 3                                                        68169920
MAINT    DC    XL50'0'             MAINTENANCE SPACE                    68219920
         SPACE 3                                                        68269920
MOVEDA   MVC   K0(K0,WORK4),K0(WORK1) MVC TO MOVE DAM.ASESS.FIELD TO    68319920
*                                  BUFFER                               68369920
         EJECT                                                          68419920
         SPACE                                                          68469920
         DS    0D                                                       68519920
MCHCOMON DSECT                                                          68569920
         MCHMAC                                                         68619920
* MCH COMMON AREA LOCATIONS USED BY ERROR RECORDER AND WRITE TO         68669920
* OPERATOR ROUTINES                                                     68719920
         SPACE                                                          68769920
NOROOM   EQU   MCHINT+1            FLAG FOR NO ROOM FOR LONG RECORD     68819920
CCHFLAG  EQU   MCHINT+K1           CCH RECORD FLAG                      68869920
MSGFLAG  EQU   MCHINT+2            BYTE IN MCHINT FOR MESSAGE FLAGS     68919920
         SPACE                                                          68969920
         SPACE                                                          69019920
R14SAVE  EQU   MCHWORK             SAVE AREA FOR RETURN ADDR IN MCS SYS 69069920
CCHADDR  EQU   MCHWORK             ADDR OF CCH RECORD FOR IGFMCHE3      69119920
CCHLEN   EQU   MCHWORK+4           LENGTH OF CCH RECORD FOR IGFMCHE3    69169920
         SPACE 2                                                        69219920
HDRREC   EQU   MCHWORK+4           AREA FOR SYSL.LOGREC HEADER    21021 69259921
LOWLIMIT EQU   HDRREC+2            STARTING CCHH OF EXTENT        21021 69299921
UPLIMIT  EQU   HDRREC+6            ENDING CCHH OF EXTENT          21021 69339921
SPARE EQU      HDRREC+10           SPARE BYTE                     21021 69379921
RESTART  EQU   HDRREC+11           BBCCHHR OF REC. AREA START     21021 69419921
BYTSREM  EQU   HDRREC+18           REMAINING BYTES ON TRACK       21021 69459921
TRKCAP   EQU   HDRREC+20           TOTAL TRACK CAPACITY           21021 69499921
LASTTTR  EQU   HDRREC+22           LAST BBCCHHR USED FOR REC      21021 69539921
TRKSPERA EQU   HDRREC+28           TRKS/CYLIN NOT ON HALF WD BDRY 21021 69579921
TRKSPER  EQU   HDRREC+29           NUMBER OF TRACKS PER CYLINDER  21021 69619921
WARNCNT  EQU   HDRREC+31           90 PERCENT TRACK COUNT         21021 69659921
DEVICE   EQU   HDRREC+33           DEVICE TYPE CODE               21021 69699921
WARNTRK  EQU   HDRREC+34           90 PERCENT TRACK-CCHH          21021 69739921
WARNSW   EQU   HDRREC+38           BIT 0 IS TURNED ON WHEN WARN   21021 69779921
*                                  MESSAGE IS ISSUED              21021 69819921
SFTBYTS  EQU   HDRREC+39           SAFETY BYTE TO DETECT OVERRUN  21021 69859921
         SPACE 2                                                        70019920
*CCWS FOR RECORDERS                                                     70069920
SEARCH   EQU   MCHWORK+44          SEARCH CCW                           70119920
SRCHADR  EQU   MCHWORK+45          ADDRESS PORTION OF SEARCH CCW        70169920
SRCHFLAG EQU   MCHWORK+48          FLAG FIELD FOR SEARCH CCW            70219920
SRCHCNT  EQU   MCHWORK+51          COUNT FIELD FOR SEARCH               70269920
         SPACE                                                          70319920
TIC      EQU   MCHWORK+52          TIC CCW                              70369920
TICFLAG  EQU   MCHWORK+56          FLAG FIELD FOR TIC CCW               70419920
TICCNT   EQU   MCHWORK+59          COUNT FIELD FOR TIC                  70469920
         SPACE                                                          70519920
GENCCW   EQU   MCHWORK+60          CCW FOR READ HDR,WRITE HDR AND DATA  70569920
CCWADR   EQU   MCHWORK+61          ADDRESS PORTION OF GENERAL CCW       70619920
FLAG     EQU   MCHWORK+64          FLAG FIELD FOR CCW                   70669920
COUNT    EQU   MCHWORK+66          COUNT FIELD FOR CCW                  70719920
COUNTA   EQU   MCHWORK+67          COUNT FIELD(1 BYTE FOR RD,WRT HDR)   70769920
         SPACE                                                          70819920
EXCPIOB  EQU   MCHWORK+68          IOB FOR EXCP FOR IGFMCHE2            70869920
IOBECB   EQU   EXCPIOB+4           ECB POINTER                          70919920
IOBCCW   EQU   EXCPIOB+16          CCW ADDRESS                          70969920
IOBDCB   EQU   EXCPIOB+20          DCB POINTER                          71019920
EXCPSEEK EQU   EXCPIOB+32          SEEK&ADDR FOR EXCP                   71069920
EXCPECB  EQU   EXCPIOB+40          ECB FOR EXCP                         71119920
SEEKADR  EQU   EXCPIOB+44          BBCCHHR USED FOR READ/WRITE HEADER   71169920
         SPACE                                                          71219920
TFLAG    EQU   MCHWORK+119         SWITCH FOR EOF WRITE                 71269920
         SPACE 2                                                        71319920
         EJECT                                                          71369920
* THIS DSECT REPRESENTS THE ACTUAL AREA FROM WHICH THE RECORD WILL BE * 71419920
* WRITTEN.MCHBUILD IS A POINTER TO THIS AREA. THE RECORDER WILL BUILD * 71469920
* DYNAMICALLY THE CTFIELD PORTION OF RECORD AND WILL MOVE THE         * 71519920
* ACTIVE ABREC AND DAMAGE ASSESSMENT FIELD INTO RECORD BUILD AREA.    * 71569920
* THE INDEPENDENT LOG IS MOVED INTO THIS AREA BY MCH NUCLEUS AND HARD-* 71619920
* WARE LOGS THE DEPENDENT LOG IN THIS AREA. BOTH DAMAGE ASSESSMENT AND* 71669920
* DEPENDENT LOG ARE VARIABLE IN SIZE ACCORDING TO MODEL.              * 71719920
         SPACE                                                          71769920
* RECORD BUILD AREA BUFFER                                              71819920
         SPACE 3                                                        71869920
*                                                                     * 71919920
* SHORT RECORD - 78 BYTES LONG                                        * 71969920
         SPACE                                                          72019920
*        *                            *                               * 72069920
* CTFIELD*          ABREC             * NOT RECORDED FOR SHORT RECORD * 72119920
* 8 BYTES*        70  BYTES           *                               * 72169920
*        *                            *                               * 72219920
*                                                                     * 72269920
         SPACE 3                                                        72319920
*                                                                     * 72369920
* LONG RECORD - VARIABLE LENGTH                                       * 72419920
         SPACE                                                          72469920
*               *         *           *           *         *         * 72519920
* NOT   USED    * CTFIELD *   ABREC   *  IND LOG  * DEP LOG* DAM.ASESS* 72569920
*   22 BYTES    * 8 BYTES *  48 BYTES * 280 BYTE  *VARIABLE*  VARIABLE* 72619920
*               *         *           *           * LENGTH  *  LENGTH * 72669920
*               *         *           *           *         *         * 72719920
*                                                                     * 72769920
         SPACE 3                                                        72819920
BUILDARA DSECT                                                          72869920
CTFIELD  DS    CL5                 RECORD ENTRY COUNT FIELD             72919920
CTFLDID  EQU   CTFIELD             COUNT FIELD ID-CCHAR                 72969920
CTFLDKEY DS    CL1                 KEY LENGTH                           73019920
CTFLDDL  DS    CL2                 DATA LENGTH                          73069920
ABRECCUR DS    CL70                AREA FOR ACTIVE ABREC TO CONTAIN     73119920
*                                  WHILE IN PROCESS OF WRITING RECORD   73169920
*                                  ON SYS1.LOGREC                       73219920
INDLOG   DS    CL6                 PTED TO BY MCHINLOG                  73269920
         DS    CL2                 LENGTH OF DEPENDENT LOG              73319920
         DS    CL272               REST OF INDEPENT LOG                 73369920
DEPLOG   EQU   *                   DEPENDENT LOG IF ANY                 73419920
DAMASESS DS    CL2                 LENGTH OF DAMAGE ASSESSMENT FIELD    73469920
DAMASFLD EQU   *                   DAMAGE ASSESSMENT FIELD              73519920
         EJECT                                                          73569920
CVTSECT  DSECT                                                          73619920
         CVT   SYS=MVT                                                  73669920
         END                                                            73719920
