         LCLA  &REL,&LEV                                                00010021
&LEV     SETA  22                                                       00012000
&REL     SETA  21                                                       00014021
&REL&LEV TITLE 'IGFMCHF4 LEVEL &LEV MCH 85 P P REFRESH LOADER'          00016021
*TITLE   IGFMCHF4   P P REFRESH LOADER                                  00020020
*                                                                     * 00030020
*FUNCTION/OPERATION      THE FUNCTION OF THE PDAR REFRESH LOADER IS   * 00040020
*    TO RESTORE A SPECIFIED AREA OF MAIN STORAGE TO ITS ORIGINAL      * 00050020
*    CONTENTS BEFORE A MACHINE MALFUNCTION CAUSED IT TO BE CHANGED OR * 00060020
*    DAMAGED.                                                         * 00070020
*                                                                     * 00080020
*    THIS MODULE   IS COMPRISED OF THE FOLLOWING ROUTINES -           * 00090020
*       (1) PROGRAM INITIALIZATION/ TERMINATION - BRANCHES TO INIT RTN* 00100020
*              AND CONTAINS LOGIC TO TERMINATE THIS MODULE AND CALL   * 00110020
*              NEXT.                                                  * 00120020
*       (2) REFRESH ROUTINE - LOADS MODULE TEXT AND PROCESSES RLD REC-* 00130020
*              ORDS. ALSO CONTAINS LOGIC FOR SCATTER LOADING.         * 00140020
*       (3) I/O ROUTINE - PASSES CONTROL TO MOD LOADER FOR I O REQ.     00150020
*       (4) CONVERT ROUTINE - CONVERTS TTR TO MBBCCHHR.               * 00160020
*       (5) CONTROL INITIALIZATION (INIT) - DETERMINES WHERE MODULE IS* 00170020
*       (6) SEARCH  ROUTINE - SCANS DIRECTORY FOR LOCATION OF MODULE  * 00180020
*              WHEN ONLY ITS NAMES IS PASSED.                         * 00190020
*                                                                       00200020
*     PROGRAM OPERATION - DETERMINE IF MVT OR MFT SYSTEM                00210020
*                         FIND MODULE LOCATION AND DETERMINE            00220020
*                          IF P P IS REFRESHABLE                        00230020
*       IF REFRESHABLE, THE DIRECTORY FOR THE PARTITIONED DATA    *     00240020
*    SET IS SEARCHED FOR THE RECORD ASSOCIATED WITH THE NAME. THIS    * 00250020
*    RECORD CONTAINS THE TTR FOR THE MODULE, WHICH IS THEN CONVERTED  * 00260020
*    TO ABSOLUTE TRACK AND THE MODULE IS LOADED.                      * 00270020
*                                                                     * 00280020
*                                                                     * 00290020
*                                                                     * 00300020
*ENTRY POINT   IGFMCHF4 FROM RMS NUCLEUS                                00310020
*                                                                     * 00320020
*INPUT  MCHMAC COMMUNICATION AREA--- REPDAR.                            00330020
*                                                                     * 00340020
*OUTPUT  MCHMAC COMMUNICATION AREA----MCHNXMOD AND REPDAR             * 00350020
*                                                                     * 00360020
         SPACE                                                          00370020
*EXITS   REFRESH REPAIR VERIFICATION                                    00380020
*        PDAR TERM                                                      00390020
*                                                                     * 00400020
         EJECT                                                          00410020
IGFMCHF4 CSECT                                                          00420020
         USING IGFMCHF4,BASEREG    BASE ADDRESSABILITY FOR MODULE       00430020
         USING MCHMAC,MACBASE      BASE FOR ASRMAC DSECT                00440020
         USING CVTMAC,CVTREG                                            00450020
         USING IHADEB,DEBREG                                            00460020
         USING IHADCB,DCBREG                                            00470020
*********************************************************************** 00480020
*              GPR EQUATES                                            * 00490020
*********************************************************************** 00500020
         SPACE 2                                                        00510020
*                                                                       00520020
*NAME          GPR                  FUNCTION OF REGISTER                00530020
*                                                                       00540020
W0       EQU   0                    WORK                                00550020
W1       EQU   1                    WORK                                00560020
W2       EQU   2                    WORK                                00570020
CUAREG   EQU   2                   CUA FOR I/O ROUTINE                  00580020
W3       EQU   3                    WORK                                00590020
W4       EQU   4                    WORK                                00600020
CNTREG   EQU   4                   MAX RETRY COUNT FOR SIO              00610020
W5       EQU   5                    WORK                                00620020
LINK2      EQU 5             I/O ROUTINE LINK REG             IE  45459 00630000
W6       EQU   6                    WORK                                00640020
W7       EQU   7                    WORK                                00650020
W8       EQU   8                    WORK                                00660020
W9       EQU   9                                                        00670020
DCBREG   EQU   9                   ADDRESS OF DATA CONTROL BLOCK        00680020
DEBREG   EQU   10                  DEB ADDR FOR LIB OF MODULE TO BE REF 00690020
MACBASE  EQU   11                  DSECT BASE FOR COMMON AREA           00700020
BASEREG  EQU   12                  MODULE BASE REG                      00710020
CVTREG   EQU   13                  ADDRESS OF CVT                       00720020
LINKREG  EQU   14                  INTERNAL LINKAGE REGISTER            00730020
RETRNREG EQU   14                  ADDRESS FOR RETURN                   00740020
W15      EQU   15                  GPR15                                00750020
         EJECT                                                          00760020
*********************************************************************** 00770020
RP       EQU   X'20'                                                    00780020
RF       EQU   X'40'                                                    00790020
REPAIR   EQU   X'08'                                                    00800020
WAITFAIL EQU   X'02'                                                    00810020
MSGCODE3 EQU   X'10'                                                    00820020
CSW      EQU   68                                                       00830020
CSW1     EQU   69                                                       00840020
CAW      EQU   72                                                       00850020
K0       EQU   0                   DECIMAL VALUE                        00860020
K1       EQU   1                   DECIMAL VALUE                        00870020
K2       EQU   2                   DECIMAL VALUE                        00880020
K3       EQU   3                   DECIMAL VALUE                        00890020
K4       EQU   4                   DECIMAL VALUE                        00900020
K5       EQU   5                   DECIMAL VALUE                        00910020
K6       EQU   6                   DECIMAL VALUE                        00920020
K7       EQU   7                   DECIMAL VALUE                        00930020
K8       EQU   8                   DECIMAL VALUE                        00940020
K9       EQU   9                   DECIMAL VALUE                        00950020
K10      EQU   10                  DECIMAL VALUE                        00960020
K11      EQU   11                  DECIMAL VALUE                        00970020
K12      EQU   12                  DECIMAL VALUE                        00980020
K13      EQU   13                  DECIMAL VALUE                        00990020
K14      EQU   14                  DECIMAL VALUE                        01000020
K15      EQU   15                  DECIMAL VALUE                        01010020
K16      EQU   16                  DECIMAL VALUE                        01020020
K17      EQU   17                  DECIMAL VALUE                        01030020
K18      EQU   18                  DECIMAL VALUE                        01040020
K19      EQU   19                  DECIMAL VALUE                        01050020
K20      EQU   20                  DECIMAL VALUE                        01060020
K28      EQU   28                  DECIMAL VALUE                        01070020
K32      EQU   32                  DECIMAL VALUE                        01080020
K39      EQU   39                  DECIMAL VALUE                        01090020
K40      EQU   40                  DECIMAL VALUE                        01100020
K43      EQU   43                  DECIMAL VALUE                        01110020
K44      EQU   44                  DECIMAL VALUE                        01120020
K124     EQU   124                  VALUE                               01130020
K24      EQU   24                  VALUE                                01140020
K21      EQU   21                   VALUE                               01150020
K1020    EQU   1020                DECIMAL VALUE                        01160020
X01      EQU   X'01'                                                    01170020
X02      EQU   X'02'                                                    01180020
X04      EQU   X'04'                                                    01190020
X28      EQU   X'28'                HEX                                 01200020
X7F      EQU   X'7F'                  HEX                               01210020
X05      EQU   X'05'                                                    01220020
X06      EQU   X'06'                                                    01230020
X08      EQU   X'08'               HEXADECIMAL VALUE                    01240020
X09      EQU   X'09'               HEXADECIMAL VALUE                    01250020
X0A      EQU   X'0A'               HEXADECIMAL VALUE                    01260020
X0D      EQU   X'0D'               HEXADECIMAL VALUE                    01270020
X0E      EQU   X'0E'                                                    01280020
X0F      EQU   X'0F'               HEXADECIMAL VALUE                    01290020
X10      EQU   X'10'                                                    01300020
X16      EQU   X'16'               HEXADECIMAL VALUE                    01310020
X1F      EQU   X'1F'               HEXADECIMAL VALUE                    01320020
X20      EQU   X'20'               HEXADECIMAL VALUE                    01330020
X40      EQU   X'40'                                                    01340020
X44      EQU   X'44'               HEXADECIMAL VALUE                    01350020
X60      EQU   X'60'               HEXADECIMAL VALUE                    01360020
X69      EQU   X'69'                                                    01370020
X80      EQU   X'80'               HEXADECIMAL VALUE                    01380020
XBF      EQU   X'BF'                                                    01390020
XE0      EQU   X'E0'               HEXADECIMAL VALUE                    01400020
XEE      EQU   X'EE'                                                    01410020
XF7      EQU   X'F7'                                                    01420020
XFC      EQU   X'FC'                                                    01430020
XFF      EQU   X'FF'                                                    01440020
X168     EQU   X'168'              HEXADECIMAL VALUE                    01450020
*        PROGRAM INITIALIZATION / TERMINATION                         * 01460020
*********************************************************************** 01470020
         SPACE 2                                                        01480020
START    EQU   *                                                        01490020
         LR    W1,BASEREG          SAVE CONTENTS OF REG                 01500020
         LR    BASEREG,W15         SET UP MY BASE                       01510020
         ST    W1,SAVE             SAVE CONTENTS IN REG SAVE AREA       01520020
         STM   CVTREG,RETRNREG,SAVE+K4 GPRS  SAVED                      01530020
         L     CVTREG,MCHCVT       GET CVT ADDRESS FOR ADDRESSABILITY   01540020
         MVI   MCHEXLEV,LEVEL                                           01550021
LEVEL    EQU   X'&LEV'                 MODULE LEVEL                     01552021
         SPACE                                                          01560020
*  INITIALIZATION IN BACK. MAY BE OVERLAID IF SCATTER LOAD IMPLEMENTED. 01570020
         B     INIT                GO TO INITIALIZATION CODE            01580020
         SPACE 2                                                        01590020
* TERMINATION                                                           01600020
*      THE PROPER CODES TO CALL EITHER IRE OR PDER TERMINATION ARE SET  01610020
*      AND THE MODULE IS CALLED.                                        01620020
         SPACE 2                                                        01630020
* NORMAL RETURN                                                         01640020
RETURN   EQU   *                                                        01650020
         OI    PDARTAB+K8,X01      SET REFRESH SUCCESSFUL               01660020
         OI    MCHDAMAG+K3,X10     SET REFRESH FLAG                     01670020
         OI    REPDAR2,REPAIR      SET SUCCESSFUL REPAIR                01680020
         TM    REPDAR1,RP              IS RETRY POSSIBLE                01690020
         BZ    EXIT                NO, SCHEDULE PDAR TERMINATOR & EXIT  01700020
         MVI   MCHNXMOD,K1          SUCCESSOR IS REFRESH REPAIR         01710020
         B     EXIT2                EXIT                                01720020
* THERE HAS BEEN AN ERROR AND THE MODULE WAS NOT REFRESHED.             01730020
NOREFRSH EQU   *                                                        01740020
         OI    REPDAR1,RF          SET REPAIR/RETRY FAILED              01750020
         OI    REPDAR6,MSGCODE3    TASK ABEND MESSAGE REQUIRED          01760020
EXIT     EQU   *                                                        01770020
         L     W4,REPDARF1          ADDR OF ERROR LOCATION              01780020
         STM   W2,W5,K0(W4)         CLEAR STORAGE LOCATION              01790020
         MVI   MCHNXMOD,K1          SUCCESSOR IS PDAR TERM              01800020
EXIT2    EQU   *                                                        01810020
         LM    BASEREG,RETRNREG,SAVE RESTORE REGS                       01820020
         BR    RETRNREG            RETURN TO NUCLEUS                    01830020
         EJECT                                                          01840020
*********************************************************************** 01850020
*        REFRESH ROUTINE                                                01860020
*              THE REFRESH ROUTINE WILL LOAD A PROGRAM MODULE INTO    * 01870020
*        THE SPECIFIED LOCATION(S) IN MAIN STORAGE AS INDICATED BY    * 01880020
*        THE ADDRESS FIELD OF THE PDAR REFRESH TABLE, OR THE EXTENT   * 01890020
*        LIST IF THE MODULE WAS LOADED IN THE SCATTER LOAD FORMAT.    * 01900020
*********************************************************************** 01910020
         SPACE                                                          01920020
REFRMOD  EQU   *                                                        01930020
         SPACE                                                          01940020
* CONVERT THE TTR                                                       01950020
*   ENTERED BY INITIALIZATION ROUTINE, SCATTER ROUTINE, AND  SEARCH     01960020
*      ROUTINE WHEN TTR MUST BE CONVERTED.                              01970020
CNVTTR   EQU   *                                                        01980020
         LM    W0,W1,LISTZ         GET TTR FOR FIRST TEXT               01990020
         SLDL  W0,K16              TTR IN REG. ZERO                     02000020
         IC    W0,LISTCN                GET CONCATENATION NUMBER        02010020
         LA    W2,MEXTENT               ADDRESS FOR ABS TRK ADDR        02020020
         BAL   LINKREG,TTRCNVT          CONVERT TTRN                    02030020
* GET RELOCATION ORIGIN (WHERE IN STG MODULE IS TO BE LOADED) FOR CCWS  02040020
         L     W8,RPTR                                                  02050020
         TM    LISTATR2,X40        DOGS ASSIGNED ORIGIN OF 1ST TXT = O  02060020
         BO    SETCCW              YES                                  02070020
         L     W2,LISTORIG         ORIG OF FIRST TEXT                   02080020
         SRL   W2,K8                                                    02090020
         AR    W8,W2               ADD RELOC TO ORIGIN                  02100020
         SPACE 2                                                        02110020
*  INITIALIZATION BRANCHES HERE WHEN ABSOLUTE TRACK ADDRESS IS GIVEN.   02120020
*   IF SO, W8 IS ALREADY LOADED.                                        02130020
SETCCW   EQU   *                                                        02140020
         ST    W8,READTXT          RELOC  ORIG  TO CHAN PROG            02150020
         MVI   READTXT,X06         RESTORE OP                           02160020
         MVC   READTXT+K6(K2),LISTCNT COUNT OF 1ST TXT TO C P           02170020
         MVC   NEXTCNT(K5),SRCHADDR   MOVE CCHHR FOR I/O EXTENT CHECK   02180020
         TM    LISTATR1,X01        TEST ONE TXT,NO RLD'S                02190020
         BZ    RDTXT               BRANCH IF MULTI RECS                 02200020
         NI    READTXT+K4,XBF      TURN CC OFF                          02210020
         MVI   FLAGS+K3,XFF        SET LAST INDICATOR                   02220020
* READ TEXT AND NEXT COUNT                                              02230020
RDTXT    EQU   *                                                        02240020
         LA    W1,READTXT          SET TIC ADDRESS TO READ TEXT         02250020
         ST    W1,TICADDR                                               02260020
         BAL   LINK2,IOROUTNE         READ TEXT               IE  45459 02270000
         CLI   FLAGS+K3,XFF        LAST INDICATOR ON                    02280020
         BE    RETURN              NO RLDS TO PROCESS                   02290020
         CLI   RLDBUF,X04          HAS THE LAST RLD BEEN PROCESSED YET  02300020
         BE    RETURN              YES RETURN TO ASRNUC AND IRE         02310020
* READ RLD AND NEXT COUNT                                               02320020
         LA    W1,READRLD          SET TIC ADDRESS TO READ RLD          02330020
         ST    W1,TICADDR                                               02340020
         MVC   SRCHADDR(K5),NEXTCNT  CCHHR                              02350020
         BAL   LINK2,IOROUTNE         READ RLD                IE  45459 02360000
         EJECT                                                          02370020
*              BUFFER TABLE PROCESSING                                  02380020
* THE FIRST BYTE OF THE RLD INDICATES IF RLD INFO IS PRESENT OR IF THE  02390020
*  LAST TEXT RECORD FOR THE MODULE IS NEXT.  THE RLD ALSO CONTAINS THE  02400020
*  NEXT READ CCW THAT IS USED.                                          02410020
TSTRLD   EQU   *                                                        02420020
         TM    RLDBUF,X02          TEST RLD'S                           02430020
         BZ    FTPCI01              BRANCH NO RLDS                      02440020
         B     FT017                TO RELOCATION                       02450020
FTPCI01  EQU   *                                                        02460020
         TM    RLDBUF,X01          TEST BUF FOR CONTROL                 02470020
         BZ    FTPCI05              BRANCH RLD ONLY                     02480020
         TM    FLAGS+K1,XFF        TEST FOR SCATTER                     02490020
         BNO   FTPCI021            BRANCH NOT SCATTER                   02500020
         LA    W4,RLDBUF+K16       COMPUTE LOCATION OF ID FOR           02510020
         AH    W4,RLDBUF+K6        NEXT RELOC FACTOR                    02520020
         LH    W4,K0(W4)           LOAD TXT ID                          02530020
         LA    W4,K4(W4,W4)        2 X ID PLUS 4                        02540020
         A     W4,TRANS             PLUS TBL ADDRESS                    02550020
         LH    W4,K0(W4)           LOAD TR TABLE VALUE                  02560020
         SLL   W4,K2                                                    02570020
         A     W4,SCAT              ADR OF RELOC FACTOR                 02580020
         MVC   RPTR(K4),K0(W4)                                          02590020
FTPCI021 EQU   *                                                        02600020
         LM    W4,W5,RLDBUF+K8     LOAD NEXT TXT CCW                    02610020
         A     W4,RPTR              RELOC TEXT CCW                      02620020
         STM   W4,W5,READTXT            STORE NEW READ TEXT CCW         02630020
FTPCI05  EQU   *                                                        02640020
         TM    RLDBUF,X04          TEST FOR END OF RLDS                 02650020
         BZ    FTPCI051             NO                                  02660020
         CLI   RLDBUF,X0E          LAST RLD                             02670020
         BE    RETURN              YES                                  02680020
         NI    READTXT+K4,XBF      CLEAR CC BIT                         02690020
         MVI   RLDBUF,X04          SET RLD LAST INDICATOR AND READ TXT  02700020
FTPCI051 EQU   *                                                        02710020
         MVC   SRCHADDR(K5),NEXTCNT  CCHHR OF NEXT TXT RECORD           02720020
         B     RDTXT               GO READ TEXT                         02730020
         EJECT                                                          02740020
*              INITIALIZATION FOR SCATTER                               02750020
         SPACE 2                                                        02760020
SCATRLD  EQU   *                                                        02770020
FT006    EQU   *                                                        02780020
         MVC   BDWD(K4),LISTADDR+K39 NO. OF BYTES IN TR/SC LIST         02790020
         LH    W1,BDWD              SCAT SIZE                           02800020
         LH    W2,BDWD+K2          TR TABLE SIZE                        02810020
         LA    W1,K4(W1,W2)        SC + TR SIZE                         02820020
         LA    W3,TRANSBUF          ADDR OF TRANSLATE BUFFER            02830020
         ST    W3,TRANS             PTR TO TRANSLATE LIST               02840020
         LA    W4,K4(W3,W2)        ADDR OF SCATTER LIST                 02850020
         ST    W4,SCAT                                                  02860020
         LR    W3,W1                SC + TR SIZE                        02870020
         LM    W0,W1,LISTADDR+K20  TTR FOR SCATT LIST                   02880020
         SLDL  W0,K16              ADJUST TTR                           02890020
         IC    W0,LISTCN                GET C.N.                        02900020
         LA    W2,MEXTENT               ADDRESS FOR ABS TRK ADDR        02910020
         ST    W3,SAVE+K12         SAVE CONTENTS OF REG                 02920020
         BAL   LINKREG,TTRCNVT          CONVERT TTR                     02930020
         L     W3,SAVE+K12         RESTORE REG                          02940020
         A     W3,TRANS             END OF TR&SC LST-4                  02950020
FT00601  EQU   *                                                        02960020
         LA    W1,K1020                                                 02970020
         SR    W3,W1                CALC SIZE OF SC/TR REC              02980020
         C     W3,TRANS             REC = OR GR THAN 1024               02990020
         BE    FT00602              EQUAL                               03000020
         BH    SCTERR               HIGH, SCATTER ERROR                 03010020
         AR    W3,W1                LOW, ADD BACK                       03020020
         S     W3,TRANS             GET SIZE AGAIN                      03030020
         STH   W3,READTXT+K6       STORE SIZE LESS THAN 1024            03040020
FT00602  EQU   *                                                        03050020
         MVC   READTXT+K1(K3),TRANS+K1 LIST ADDR TO CHANNEL PROGRAM     03060020
         LA    W1,READTXT                                               03070020
         ST    W1,TICADDR                                               03080020
         BAL   LINK2,IOROUTNE        READ LIST                IE  45459 03090000
FT006023 EQU   *                                                        03100020
         L     W1,TRANS             ADDR OF T/S LIST                    03110020
         TM    K0(W1),K16          TEST FOR T/S TYPE RECORD             03120020
         BO    FT00603              BRANCH REC OK                       03130020
SCTERR   EQU   *                                                        03140020
         B     NOREFRSH            GO TO SET ERROR FLAGS                03150020
FT00603  EQU   *                                                        03160020
         L     W2,BDWD              GET SIZE OS T/S LIST                03170020
         SRL   W2,K18              NO. OF ENTRIES IN SCATT LIST         03180020
         BCTR  W2,K0                    STP ONE                         03190020
         L     W8,PDARTAB+K8       GET EXTENT LIST ADDR                 03200020
         CH    W2,K6(W8)           COMPARE WITH EXTENT LIST             03210020
         BNE   SCTERR              GO TO SET ERROR FLAGS                03220020
         L     W1,SCAT              ADDR OF SCATTER LIST                03230020
         LA    W3,K4(W8)           INIT EXT LIST POINTER                03240020
FT00604  EQU   *                                                        03250020
         LA    W1,K4(W1)           INDEX SCATTER LIST POINTER           03260020
         LA    W3,K4(W3)           EXTENT LIST POINTER                  03270020
         NI    K0(W1),XFC          CLEAR 3 L. O. BITS OF ORIG           03280020
         BCT   W2,FT00605           BRANCH END                          03290020
         L     W2,LISTADDR+K28     TOTAL LENGTH OF PROGRAM              03300020
         SRL   W2,K8               POSITION IN LOW ORDER 24 BITS        03310020
         S     W2,K0(W1)           SUB LAST ORIG                        03320020
         CH    W2,K2(W3)           COMPARE LAST LENGTH                  03330020
         BNE   SCTERR                   ERROR                           03340020
         B     INITRL              GO TO INITIALIZE RL                  03350020
         SPACE 2                                                        03360020
*   IS THAT ALL                                                         03370020
FT00605  EQU   *                                                        03380020
         L     W4,K4(W1)           NEXT ORIGIN                          03390020
         S     W4,K0(W1)           COMPUTE LENGTH                       03400020
         CH    W4,K2(W3)           COMPARE WITH EXTENT LIST ENTRY       03410020
         BE    FT00604              EQUAL, OK                           03420020
         B     SCTERR               NOT, SCATTER ERROR                  03430020
INITRL   EQU   *                                                        03440020
         LA    W3,K4(W3)           GET LAST ENTRY + 4                   03450020
         L     W4,K4(W8)           NO. OF ENTRIES IN EXTENT LIST        03460020
         L     W2,SCAT              ADDR OF SCATTER LIST                03470020
FT00606  EQU   *                                                        03480020
         LA    W2,K4(W2)           INDEX SCATTER LIST POINTER           03490020
         L     W1,K0(W3)           CORE ALLOC ADDRESS                   03500020
         S     W1,K0(W2)           ADD ORIG ADJUST                      03510020
         ST    W1,K0(W2)           STORE RELOCATION FACTOR              03520020
         BCT   W4,FT00607           CHECK FOR END                       03530020
         SR    W3,W3                END                                 03540020
         IC    W3,LISTADDR+K43     LEFT HALF FIRST TEXT ID              03550020
         SLL   W3,K8               SHIFT LEFT ONE BYTE                  03560020
         IC    W3,LISTADDR+K44     RIGHT HALF ID                        03570020
         BAL   LINKREG,TBLLKUP     TO TABLE LOOP UP                     03580020
         MVC   RPTR(K4),K0(W3)     SAVE RELOCATION FACTOR               03590020
         MVI   FLAGS+K1,XFF        PROGRAM BEING SCATTERED              03600020
         B     CNVTTR                   CONV TTR                        03610020
FT00607  EQU   *                                                        03620020
         LA    W3,K4(W3)           INCREMENT BY FOUR                    03630020
         B     FT00606             CONTINUE BY GETTING RELOC. FACTOR    03640020
         EJECT                                                          03650020
*                    RELOCATION ROUTINE                                 03660020
         SPACE 2                                                        03670020
FT017    EQU   *                                                        03680020
         LA    W1,RLDBUF+K16       SET POINTER TO FIRST RPFA            03690020
         LR    W0,W1                                                    03700020
         AH    W0,RLDBUF+K6        TOTAL SIZE OF BUFFER                 03710020
FT018    EQU   *                                                        03720020
         TM    FLAGS+K1,XFF            IS PROGRAM BEING SCATTER LOADED  03730020
         BZ    FT020                BRANCH NOT SCATTER                  03740020
FT019    EQU   *                                                        03750020
         LH    W3,K0(W1)           R PTR                                03760020
         BAL   LINKREG,TBLLKUP          TO GET RELOC FACTOR             03770020
         MVC   RPTR(K4),K0(W3)     R PTR STORED                         03780020
         LH    W3,K2(W1)           P PTR                                03790020
         BAL   LINKREG,TBLLKUP          TO GET RELOC FACTOR             03800020
         MVC   PPTR(K4),K0(W3)     TO GET RELOCATION FACTOR             03810020
         B     FT021               GO TO SET PTR                        03820020
FT020    EQU   *                                                        03830020
         MVC   PPTR(K4),RPTR                                            03840020
FT021    EQU   *                                                        03850020
         LA    W1,K4(W1)           SET POINTER TO FA                    03860020
         TM    K0(W1),XE0              IS RELOCATION REQUIRED           03870020
         BNZ   FT024               NO                                   03880020
         L     W2,K0(W1)           GET ADDRESS OF LOAD CONST.           03890020
         A     W2,PPTR              RELOC ADDR OF LOAD CONST            03900020
FT02102  EQU   *                                                        03910020
         SR    W4,W4                NOT FULL WORD BOUNDARY              03920020
         ST    W4,BDWD              CLEAR BOUNDARY WORD                 03930020
         NI    K0(W1),X0F          CLEAR UNWANTED FLAGS                 03940020
         IC    W4,K0(W1)           COUNT INTO REG                       03950020
         SRL   W4,K2               MULTIPLY BY FOUR                     03960020
         LA    W3,BDWD+K3          SET ADDRESS OF BDWD                  03970020
         SR    W3,W4                SET BD WD TO BYTES                  03980020
         EX    W4,FT025             MOVE ADCON TO BOUND WORD            03990020
         L     W5,BDWD              LOAD FROM BOUND WORD                04000020
         TM    K0(W1),X02                                               04010020
         BZ    FT022               BRANCH TO ADD                        04020020
         S     W5,RPTR              SUB RELOC FACTOR                    04030020
         B     FT023               GO TO STORE INTO BDWD                04040020
FT022    EQU   *                                                        04050020
         A     W5,RPTR              ADD RELOC FACTOR                    04060020
FT023    EQU   *                                                        04070020
         ST    W5,BDWD              RET TO BOUND WORD                   04080020
         EX    W4,FT026             RET RELOC ADCON                     04090020
FT024    EQU   *                                                        04100020
         LR    W3,W1                SAVE POINTER                        04110020
         LA    W1,K4(W1)           ADD 4 TO COUNT                       04120020
         CR    W1,W0                DOES PTR=END                        04130020
         BZ    FTPCI01             YES, RETURN FROM RELOCATION ROUTINE  04140020
         TM    K0(W3),X01          TEST TERM FLAG                       04150020
         BO    FT021+K4            SAME REP POINTERS                    04160020
         B     FT018                NEW R&P POINTERS                    04170020
FT025    EQU   *                                                        04180020
         MVC   K0(K1,W3),K0(W2)                                         04190020
FT026    EQU   *                                                        04200020
         MVC   K0(K1,W2),K0(W3)                                         04210020
         SPACE 2                                                        04220020
TBLLKUP  EQU   *                                                        04230020
         LA    W3,K4(W3,W3)        2 TIMES ID +4 = TR TBL VALUE         04240020
         A     W3,TRANS             INDEX PLUS TRANS TBL VALUE          04250020
         LH    W3,K0(W3)                                                04260020
         SLL   W3,K2               SCATTER INDEX VALUE                  04270020
         A     W3,SCAT              PLUS SCAT LIST ADDR                 04280020
         BR    LINKREG             RETURN TO CALLER                     04290020
         EJECT                                                          04300020
*********************************************************************** 04310020
*        I/O ROUTINE                                                  * 04320020
*********************************************************************** 04330020
         SPACE 2                                                        04340020
IOROUTNE EQU   *                                                        04350020
         SR    W3,W3                CLEAR REG                           04360020
         IC    W3,MEXTENT           GET CURRENT EXTENT NUMBER           04370020
         SLL   W3,K4               FORM INDEX TO CURRENT EXTENT         04380020
         LA    W3,DEBDVMOD(W3)       ADDR OF CURRENT EXT IN DEB         04390020
*  W3 POINTS TO CURRENT DEB EXTENT                                      04400020
         SPACE 2                                                        04410020
* END OF EXTENT ROUTINE                                                 04420020
*    THIS CODE CHECKS THE CCHHR (NEXTCNT) TO ASCERTAIN THAT IT IS NOT   04430020
*    OUT OF THE EXTENT LIMITS SPECIFIED IN THE DEB. WHEN THE EXTENT IS  04440020
*    EXCEEDED, THE NEXT EXTENT IS OBTAINED AND CCHHR (NEXTCNT) IS       04450020
*    UPDATED.                                                           04460020
         SPACE                                                          04470020
CHKEXTNT EQU   *                                                        04480020
         CLC   NEXTCNT(K4),K6(W3)  TEST IF UNDER START LIMIT            04490020
         BL    OUTEXTNT            BR - LOWER THAN LOW ADDRESS          04500020
         CLC   NEXTCNT(K4),K10(W3) TEST IF OVER END LIMIT               04510020
         BNH   STARTIO             BR EXTENT OK - NOT HIER END LIMIT    04520020
         SPACE                                                          04530020
* NEXTCNT HIGHER THAN END LIMIT, NEXT EXTENT NECESSARY                  04540020
OUTEXTNT EQU   *                    ROUTINE TO UPDATE EXTENT            04550020
         SR    W3,W3               CLEAR REG                            04560020
         IC    W3,MEXTENT           GET CURRENT EXTENT NUMBER (0 TO N)  04570020
         LA    W3,K1(W3)           INCREASE IT BY ONE FOR NEXT EXTENT   04580020
         SR    W1,W1                CLEAR REG                           04590020
         IC    W1,DEBNMEXT          GET NO. EXTENTS IN THIS DEB (N+1)   04600020
         CR    W3,W1                WAS CURRENT LAST EXTENT IN DEB      04610020
         BNE   NEXTEXT               NO, USE NEXT                       04620020
         B     NOREFRSH              ERROR CANT REFRESH                 04630020
         SPACE                                                          04640020
NEXTEXT  EQU  *                     UPDATE EXTENT AND SEEK ADDR         04650020
         STC   W3,MEXTENT           STORE NEW EXTENT NUMBER             04660020
         SLL   W3,K4                   FORM INDEX TO NEW EXTENT         04670020
         LA    W3,DEBDVMOD(W3)        GET ADDR OF NEW EXTENT            04680020
         MVC   SEEKADDR(K6),K4(W3) GET STARTING BBCCHH                  04690020
         MVI   RECORD,X01          SET R TO ONE                         04700020
         MVC   NEXTCNT(K4),SRCHADDR UPDATE NEW SEARCH ADDRESS           04710020
         B     CHKEXTNT                  LOOK AGAIN                     04720020
         SPACE                                                          04730020
* INITIATE I/O OPERATION                                                04740020
STARTIO  EQU   *                                                        04750020
         MVC   TIC+K1(K3),TICADDR+K1 MOVE CCW START ADDR          IKES  04752020
*                                  IN TIC CCW                     IKES  04754020
         LA    W3,SRCHIDEQ          ADDR OF CHANNEL PGM                 04760020
         ST    W3,MCHICCWS         STORE INTO RMS IOB                   04770020
         ST    DCBREG,MCHIODCB     ADDR OF DCB INTO RMSIOB              04780020
         MVI   MCHIODCB,X0F                                             04790020
         MVC   MCHIOBSK(K8),MEXTENT MOVE MBBCCHHR TO SEEK FIELD         04800020
         LA    W1,MCHIOB           ADDR OF MCH IOB                      04810020
         L     W15,MCHEXCP         ENTRY POINT ADDR                     04820020
         BALR  LINKREG,W15         EXIT TO MODULE LOADER                04830020
* RETURN HERE IF I O WAS SUCESSFUL                                      04840020
         BR  LINK2                 RETURN TO CALLER           IE  45459 04850000
         DC  X'0700'                2-BYTE  FILLER            IE  45459 04852000
* RETURN HERE IF I O WAS NOT SUCESSFUL                                  04860020
         B     NOREFRSH            NOT REFRESHABLE EXIT                 04870020
         EJECT                                                          04880020
*********************************************************************** 04890020
*        CONVERT ROUTINE                                              * 04900020
*        THIS ROUTINE CONVERTS A RELATIVE DIRECT ACCESS ADDRESS AND   * 04910020
*        CONCATENATION NUMBER, TTRN, INTO ITS ABSOLUTE EQUIVALENT,    * 04920020
*        MBBCCHHR.                                                    * 04930020
* REGISTER USAGE                                                        04940020
*        WO = CONTAINS TTRN, WHERE N IS CONCATENATION FACTOR            04950020
*        W2 = ADDRESS OF MEXTENT FOR RESULTING MBBCCHHR                 04960020
*        W1 = ADDRESS FOR DEB EXTENT                                  * 04970020
         SPACE                                                          04980020
* FOR EACH EXTENT, THE AMOUNT TT IS REDUCED BY THE NUMBER OF TRACKS IN  04990020
* THE EXTENT. THE PROPER EXTENT IS REACHED WHEN BALANCE IS NEGATIVE.    05000020
* ( A TTRN OF ZERO YIELDS ADDRESS IN 1ST EXTENT (EXTENT 0).)            05010020
*********************************************************************** 05020020
         SPACE                                                          05030020
TTRCNVT  EQU   *                    TTRN TO MBBCCHHR CONVERT ROUTINE    05040020
         SR    W3,W3                                                    05050020
         IC    W3,DEBNMEXT          NUMBER OF EXTENTS                   05060020
         LR    W4,W3                USE FOR LIMIT                       05070020
         LA    W7,XFF              MASK                                 05080020
         NR    W7,W0                CONCATENATION NUMBER (N)            05090020
         BZ    CNVTA                IS N ZERO                           05100020
         LR    W6,W3                NUMBER OF EXTENTS                   05110020
         SLL   W6,K4               TIMES 16                             05120020
         AR    W6,W7                ADD N                               05130020
         IC    W7,DEBDVMOD-K1(W6)  FIRST M OF DATA SET N                05140020
         SR    W4,W7                ADJUST LIMIT                        05150020
         SLL   W7,K4               TIMES 16                             05160020
CNVTA    EQU   *                                                        05170020
         LA    W1,K32(DEBREG)      GET DEB EXTENT ADDR                  05180020
* W1  POINTS TO DEB EXTENT                                              05190020
         AR    W1,W7                 REG-W7 CONTAINS 0 OR OFFSET TO EXT 05200020
         SRL   W0,K8               REMOVE N                             05210020
         STC   W0,K7(W2)           SAVE R                               05220020
         SRL   W0,K8               GET TT                               05230020
CNVTB    EQU   *                                                        05240020
         SH    W0,K14(W1)          DECREASE BY TRACKS IN EXTENT         05250020
         BM    CNVTC                BR IF LESS THAN 0. IT IS PROPER EXT 05260020
         LA    W1,K16(W1)          OR GO TO NEXT EXTENT                 05270020
         BCT   W4,CNVTB             Q. STILL WITHIN DEB                 05280020
         B     NOREFRSH             SET REFRESH NOT POSSIBLE            05290020
CNVTC    EQU   *                                                        05300020
         SR    W3,W4                DEVELOP M                           05310020
         AH    W0,K14(W1)          ADD BACK OVERDRAW                    05320020
         STC   W3,K0(W2)           STORE M                              05330020
         MVC   K1(K6,W2),K4(W1)    GET BBCCHH FROM EXTENT               05340020
         BCR   K8,LINKREG          BR IF RESULT W0 IS 0.  ELSE DIVIDE   05350020
*              PICKUP LOCATION OF APPROPRIATE DEVICE CONSTANTS          05360020
*   NECESSARY PCIKUP LOCATION OF APPROPRIATE DEVICE CONSTANTS.          05370020
         L     W5,K0(W1)           UCB ADDRESS                          05380020
         IC    W5,K19(W5)          GET DEVICE TYPE CODE                 05390020
         LA    W6,K15              MASK                                 05400020
         NR    W5,W6                LEAVE 4 L.O. BITS                   05410020
         L     W6,CVTZDTAB         GET DEVICE TABLE ATTRIBUTES ADDRESS  05420020
         IC    W5,K0(W5,W6)        DISPLACEMENT FOR DEVICE              05430020
         LH    W3,K2(W5,W6)        TRKS/CYL                             05440020
         LR    W5,W0                DIVIDE REG.                         05450020
         AH    W5,K8(W1)           STARTING HH                          05460020
         LA    W4,K0               SET EVEN TO ZERO                     05470020
         DR    W4,W3                QUO=CYLS,REN=TRKS                   05480020
         STC   W4,K6(W2)           STORE H                              05490020
         AH    W5,K6(W1)           PLUS CC START                        05500020
         STC   W5,K4(W2)           STORE C                              05510020
         BR    LINKREG             RETURN                               05520020
         EJECT                                                          05530020
*********************************************************************** 05540020
*     CONSTANTS, BUFFERS, AND CHANNEL PROGRAMS                        * 05550020
*********************************************************************** 05560020
         SPACE 2                                                        05570020
* CHANNEL PROGRAM  BASE                                                 05580020
         DS    0D                                                       05590020
SRCHIDEQ CCW   49,SRCHADDR-START,X'40',5     CC                         05600020
SRCHTIC  CCW   8,SRCHIDEQ-START,X'40',1  CC                             05610020
TIC      CCW   8,TICADDR-START,X'00',1  TIC TO READ TXT OR RLD.         05620020
         SPACE                                                          05630020
* READ TEXT DATA AND NEXT COUNT (USUALLY RLD)                           05640020
READTXT  CCW   6,0,X'60',1024           CC + SILI                       05650020
         CCW   146,NEXTCNT-START,0,8         STOP                       05660020
         SPACE                                                          05670020
* READ RLD DATA AND NEXT COUNT (USUALLY TEXT)                           05680020
READRLD  CCW   6,RLDBUF-START,X'60',260      CC + SILI                  05690020
         CCW   146,NEXTCNT-START,0,8    STOP                            05700020
         SPACE                                                          05710020
* READ PDS BLOCK AND COUNT                                              05720020
READPDS  CCW   146,NEXTCNT-START,X'40',8     READ COUNT                 05730020
SRCHHIEQ CCW   105,0,X'40',8                 SEARCH KEY HIGH OR EQUAL   05740020
         CCW   8,READPDS-START,X'00',1                                  05750020
         CCW   6,RDAREA-START,X'00',256      READ BLOCK                 05760020
         SPACE 5                                                        05770020
SENSECCW CCW   4,SENSDATA-START,X'20',4      SILI                       05780020
         SPACE 2                                                        05790020
MEXTENT  DC    X'0'                    M   -CURRENT EXTENT NUMBER       05800020
SEEKADDR DC    XL2'0'               BB  -SEEK ON BBCCHHR                05810020
SRCHADDR DC    XL4'0'               CCHH-SEARCH ON CCHHR                05820020
RECORD   DC    X'0'                 R   -ID OF RECORD                   05830020
         SPACE                                                          05840020
SENSDATA DC    D'0'                 BUFFER FOR SENSE DATA               05850020
NEXTCNT  DC    D'0'                 NEXT CCHHR (SRCHADDR) FOR RLD TXT   05860020
R0BUFFER DC    D'0'                 BUFFER FOR RECORD 0                 05870020
TICADDR  DC    F'0'                 READTXT OF READRLD OR READ PDS.     05880020
         SPACE                                                          05890020
*                                                                       05900020
*  BUILD LIST -  CONSTRUCTED AS FOLLOWS                                 05910020
*    (1) WHEN NAME= NAME, BY SEARCH ROUTINE                             05920020
*    (2) WHEN NAME = ABS TRK OR TTR, AS A DUNMY BY INITIALIZATION       05930020
*                                                                       05940020
         DS    0F                                                       05950020
LISTADDR DC    H'1'                NUMBER OF ENTRIES IN LIST (FF)       05960020
LISTLL   DC    H'44'                NUMBER OF BYTES IN LIST ENTRY       05970020
LISTNAME DC    8X'0'                MEMBER NAME                         05980020
LISTTT   DC    H'0'                 RELATIVE TRACK                      05990020
LISTR    DC    X'0'                 RECORD                              06000020
LISTCN   DC    X'0'                 CONCATENATION NUMBER                06010020
LISTZ    DC    X'0'                   LIB                               06020020
LISTC    DC    X'0'                  BIT 3-7 = NUMBER OF HALF-WDS       06030020
LISTDATA DC    15H'0'               USER DATA FIELD                     06040020
* USER DATA FIELD                                                       06050020
LISTTTR  EQU   LISTDATA             TTR  FOR FIRST TEXT                 06060020
LISTATR1 EQU   LISTDATA+8            ATTRIBUTE FIELD (2 BBYTES)         06070020
LISTATR2 EQU   LISTDATA+9                                               06080020
LISTORIG EQU   LISTDATA+18           ORIGIN OF FIRST TEXT               06090020
LISTCNT  EQU   LISTDATA+13           COUNT (LENGTH) OF FIRST TEXT       06100020
         SPACE 2                                                        06110020
REFTAB   DC    4F'0'                   REFRESH TABLE                    06120020
XLIST    EQU   REFTAB+K8                                                06130020
PDARTAB  EQU   REFTAB                                                   06140020
SCAT     DC    F'0'                   SCATTER LIST ADDRESS              06150020
TRANS    DC    A(0)                  ADDR OF TRANSLATE LIST             06160020
RPTR     DC    F'0'                   RELOCATION FACTOR                 06170020
PPTR     DC    F'0'                   RELOCATION ADDR. OF LOAD CONST.   06180020
BDWD     DC    F'0'                   BOUNDARY WORD                     06190020
FLAGS    DC    F'0'                   BYTES FOR FLAGS                   06200020
RDAREA   DS    0D                      DIRECTORY READ BUFFER            06210020
RLDBUF   DC    33D'0'                 RELOCATION DICT FOR REFR TAB      06220020
UAMASK  DC    X'000007FF'           MASK TO ISOLATE CUA FROM UCB        06230020
MASK     DC    X'0000FFFF'         MASK                                 06240020
SAVE     DC    2D'0'               SAVE FOR GPRS AND W3 SCTR            06250020
MAXCT    DC    H'1024'              MAX COUNT WHEN TTR PASSED FOR MOD   06260020
         DS    0F                                                       06270020
* TRANSBUF MUST BE LOCATED AT LESS THAN 800 TO ALLOW 1K FOR SCATTER     06280020
TRANSBUF DC    64F'0'              TRANSLATE/SCATTER RECORD BUFFER      06290020
         SPACE 2                                                        06300020
C14      DC    H'14'               HALF WORD CONTAINING VALUE OF  14    06310020
H256     DC    H'256'              HALF WORD CONTAINING VALUE OF 256    06320020
         EJECT                                                          06330020
*********************************************************************** 06340020
         SPACE 2                                                        06350020
INIT     EQU   *                                                        06360020
*   DETERMINE IF MFT OR MVT SYSTEM                                      06370020
         TM    CVTDCB,X10            IS IT MVT SYS                      06380021
         BO    MVTSYS                YES-BRANCH                         06390021
         SPACE 1                                                        06400020
*  MFT SYSTEM  THE ERROR IS IN THE DYNAMIC AREA                         06410020
*     SEARCH THE ACTIVE RB QUEUE                                        06420020
         SPACE 2                                                        06430020
         L     W7,MCHTCB           CURRENT TCB                          06440020
         LM    W5,W6,REPDARF1      ERROR ADDR BEGINNING AND END         06450020
         L     W4,K24(W7)          GET PTR TO BOUNDARY BOX              06460020
         L     W3,K4(W4)           GET LOW PARTITION BOUNDARY           06470020
         CR    W5,W3               COULD ERROR BE IN THIS PARTITION     06480020
         BL    NOREFRSH            NO, ABEND TASK                       06490020
         L     W3,K8(W4)           GET HIGH PARTITION BOUNDARY          06500020
         CR    W5,W3               IS ERROR IN PARTITION                06510020
         BNL   NOREFRSH             NO, ABEND TASK                      06520020
         SPACE 1                                                        06530020
*  THE ERROR IS IN THIS PARTITION . SEARCH RB ENTRIES FOR A             06540020
*   REFRESHABLE MODULE OCCUPYING THE ADDR IN WHICH THE ERROR OCCURRED.  06550020
         SPACE 1                                                        06560020
         L     W9,K0(W7)           POINT TO FIRST RB ON QUEUE           06570020
RBQ1     EQU   *                                                        06580020
         CR    W9,W6               IS ERROR IN THIS RB                  06590020
         BNL   RBQ2                NO, LOOK AT NEXT ENTRY               06600020
         LA    W8,K32(W9)          INCREMENT TO END OF PRB OR LPRB      06610020
         CR    W8,W5               IS THE RB DAMAGED                    06620020
         BH    NOREFRSH            YES, MUST ABEND                      06630020
         LH    W8,K8(W9)           GET RB AND PROGRAM SIZE              06640020
         N     W8,MASK             CLEAN TOP TWO BYTES                  06650020
         SLL   W8,K3               MULTIPLY BY 8                        06660020
         AR    W8,W9               POINT TO END OF PROGRAM              06670020
         CR    W8,W5               IS ERROR IN THIS PROGRAM             06680020
         BH    RBQ3                YES, TAKE A CLOSER LOOK              06690020
RBQ2     EQU   *                                                        06700020
         L     W9,K28(W9)          GET POINTER TO NEXT RB               06710020
         CR    W9,W7               AT END OF ACTIVE RB QUEUE            06720020
         BNE   RBQ1                IF NOT, CHECK NEXT RB                06730020
         B     NOREFRSH            ABEND TASK                           06740020
RBQ3     EQU   *                                                        06750020
         TM    K10(K8),X01         IS MODULE REFRESHABLE                06760020
         BZ    NOREFRSH            NO, ABEND TASK                       06770020
         MVC   REFTAB(K8),K0(K9)   PUT MODULE NAME INTO REFREAH TABLE   06780020
         LA    W8,K32(W9)          GET ENTRY POINT OF MODULE            06790020
         ST    W8,REFTAB+K8        PUT INTO REFRESH TABLE               06800020
         B     REFRESH             ATTEMPT TO REFRESH MODULE            06810020
         SPACE 2                                                        06820020
*  MVTSYSTEM  THE ERROR IS IN THE DYNAMIC AREA                          06830020
MVTSYS   EQU   *                                                        06840020
         L     W3,MCHTCB               ADDR OF CURRENT TCB              06850020
         L     W3,K124(W3)         GET JOBSTEP TCB                      06860020
         L     W2,K44(W3)          GET PTR TO JOB PACK QUEUE            06870020
         LA    W2,K0(W2)           CLEAR HI BYTE                        06880020
         SPACE 2                                                        06890020
*          THE FOLLOWING ROUTINE SEARCHES CONTENTS DIRECTORY            06900020
*        ENTRIES FOR A REFRESHABLE MODULE OCCUPYING THE ADDRESS         06910020
*        IN WHICH THE ERROR OCCURRED. THIS ROUTINE IS USED FOR          06920020
*        SEARCH OF THE JOB PACK AREA QUEUE.                             06930020
         SPACE 1                                                        06940020
CDESRCH  EQU   *                                                        06950020
         LTR   W2,W2               ANY CDE ENTRIES                      06960020
         BZ    NOREFRSH             BRANCH NOT REFRESHABLE              06970020
         L     W6,REPDARF1            BEGINNING ADDR OF FAILING AREA    06980020
         CR    W2,W6               ERROR IN CDE                         06990020
         BL    CHKEXT              NO, CHECK EXTENTS                    07000020
         LA    W4,K24(W2)          END OF CDE                           07010020
         CR    W4,W6               ERROR IN CDE                         07020020
         BL    NOREFRSH             BRANCH NOT REFRESHABLE              07030020
CHKEXT   EQU   *                                                        07040020
         TM    K20(W2),X28         IS MODULE REFRESHABLE AND DOES IT    07050020
*                                   HAVE AN EXTENT LIST                 07060020
         BNO   NEXTCDE             NO, GO GET NEXT CDE                  07070020
         TM    K0(W2),X04          IS THIS THE MAJOR ENTRY FOR MODULE   07080020
         BO    NEXTCDE             NO, IT IS MINOR- GET NEXT            07090020
         L     W3,K20(W2)          GET ADDR OF EXTENT LIST              07100020
         LA    W3,K0(W3)           CLEAR HI BYTE                        07110020
         L     W4,K4(W3)           GET NO. OF ENTRIES IN EXTENT LIST    07120020
         SLL   W4,K2               MULTIPLY BY 4 TO GET BYTE DISP       07130020
*                                   BETWEEN LENGTH AND ADDR             07140020
CHKSEG   EQU   *                                                        07150020
         L     W5,K8(W3)           GET LENGTH OF SEGMENT                07160020
         LA    W5,K0(W5)           CLEAR HI BYTE                        07170020
         L     W7,K8(W4,W3)        GET ADDR OF SEGMENT                  07180020
         LA    W7,K0(W7)           CLEAR HI BYTE                        07190020
         AR    W5,W7               FIND UPPER BOUND OF SEGMENT          07200020
         CR    W6,W5               IS ERROR ABOVE SEGMENT               07210020
         BNL   NXTSEG              YES, GO CHECK NEXT SEGMENT           07220020
         CR    W6,W7               IS ERROR BELOW SEGMENT               07230020
         BL    NXTSEG              YES, GO CHECK NEXT SEGMENT           07240020
         LA    W5,K4               GET BYTE DISP FOR SINGLE ENTRY       07250020
         CR    W4,W5               IS MODULE SCATTER LOADED             07260020
         BE    NOSCAT              NO, BRANCH                           07270020
         MVC   REFTAB+K9(K3),K21(W2) EXTENT LIST ADDR                   07280020
         OI    REFTAB+K8,X80       SET SCATTER LOAD REFRESH FLAG        07290020
LDNAME   EQU   *                                                        07300020
         MVC   REFTAB(K8),K8(W2)   MODULE NAME INTO REFRESH TABLE       07310020
         B     REFRESH             ATTEMPT TO REFRESH MODULE            07320020
NOSCAT   EQU   *                                                        07330020
         MVC   REFTAB+K9(K3),K13(W3) ADDR OF STORAGE BLOCK              07340020
         NI    REFTAB+K8,X7F       ZERO SCATTER FLAG                    07350020
         B     LDNAME              FINISH LOADING REFRESH TABLE         07360020
NEXTCDE  EQU   *                                                        07370020
         L     W2,K0(W2)           GET ADDR OF NEXT CDE                 07380020
         LA    W2,K0(W2)           CLEAR HI BYTE                        07390020
         B     CDESRCH             RETURN                               07400020
NXTSEG   EQU   *                                                        07410020
         TM    K8(W3),X80          LAST ENTRY IN EXTENT LIST            07420020
         BO    NEXTCDE             YES, GO GET NEXT CDE                 07430020
         LA    W3,K4(W3)           BUMP EXTENT PTR                      07440020
         B     CHKSEG              GO CHECK THIS SEGMENT                07450020
         SPACE 1                                                        07460020
*********************************************************************** 07470020
*        CONTROL INITIALIZATION ROUTINE                               * 07480020
*  THIS ROUTINE RELOCATES THE CCWS, DETERMINES WHICH LIBRARY THE MODULE 07490020
*  TO BE REFRESHED IS ON, AND SETS UP A BUILD LIST FOR THE REFRESH RTN. 07500020
*********************************************************************** 07510020
         SPACE                                                          07520020
REFRESH  EQU   *                                                        07530020
* RELOCATE CCWS                                                         07540020
         LA    W1,K12              GET NO. OF CCWS TO BE RELOCATED      07550020
         LA    W2,SRCHIDEQ             GET ADDR OF CCWS                 07560020
LOOP     LR    W3,BASEREG          GET MODULE BASE                      07570020
         A     W3,K0(W2)                                                07580020
         ST    W3,K0(W2)                                                07590020
         LA    W2,K8(W2)                                                07600020
         BCT   W1,LOOP             LOOP UNTIL ALL CCWS ARE RELOCATED    07610020
         SPACE 2                                                        07620020
*  TEST  PDARTAB FLAG TO DETERMINE THE LIB OF MODULE. GET SVCLIB DCB OR 07630020
*  IF PRESENT, A JOBLIB DCB. OTHERWISE, LINKLIB DCB IS OBTAINED.        07640020
*  IN BUILD LIST    Z=0 PRIVATE LIBRARY                                 07650020
*                   Z=1 LINK LIBRARY                                    07660020
*                   Z=2 JOB LIBRARY                                     07670020
         SPACE                                                          07680020
         SR    DCBREG,DCBREG                                            07690020
         TM    PDARTAB+K8,X60      IS MODULE ON ASRLIB OR SVCLIB        07700020
         BZ    TSTLINK             BR NO, TEST FOR LINK                 07710020
         L     DCBREG,CVTSVDCB     GET  SVCLIB DCB ADDR                 07720020
         B     GETDEB              GET DEB ADDRESS                      07730020
TSTLINK  TM    PDARTAB+K8,X04      IS LINKLIB SPECIFIED                 07740020
         BO    SETLNK              GO LOAD LINKLIB DCB                  07750020
         L     DCBREG,MCHTCB       USE TCB TO GET                       07760020
         L     DCBREG,K40(DCBREG)  JOBLIB DCB ADDRESS                   07770020
         LTR   DCBREG,DCBREG        IS A JOBLIB ASSIGNED TO THIS TASK   07780020
         BZ    SETLNK              NO JOBLIB PRESENT  SET LINKLIB       07790020
         MVI   LISTZ,K2            NO DCB PTR, INDICATE JOBLIB BY Z=2   07800020
         B     GETDEB              GET DEB ADDRESS                      07810020
SETLNK   EQU   *                                                        07820020
         L     DCBREG,CVTLINK      GET  LINKLIB DCB ADDR                07830020
         MVI   LISTZ,K1            INDICATE LINKLIB BY Z=1              07840020
         MVI   LISTCN,K0           SET CONCATENATION NO. TO ZERO        07850020
GETDEB   L     DEBREG,DCBDEBAD          GET DEB ADDR                    07860020
         SPACE 2                                                        07870020
         SPACE                                                          07880020
* THE MODULES NAME HAS BEEN PASSED. THE PDS MUST BE READ AND SEARCHED.  07890020
         MVC   LISTNAME(K8),PDARTAB MOVE NAME TO BUILD LIST             07900020
         B     SRCHPDS                 READ BUILD LIST - REFRESH MOD    07910020
         SPACE                                                          07920020
*********************************************************************** 07930020
*        SEARCH ROUTINE                                               * 07940020
*        THE SEARCH ROUTINE READS THE DIRECTORY OF THE PARTITIONED DATA 07950020
*  SET UPON WHICH THE MODULE RESIDES. THE DIRECTORY STARTS ON THE FIRST 07960020
*  TRACK IN THE EXTENT ALLOCATED TO THE DATA SET. THIS ROUTINE THEN     07970020
*  SEARCHES FOR THE NAME OF THE MODULE AND WHEN FOUND, SAVES THE RECORD 07980020
*  ASSOCIATED WITH IT (THIS RECORD MAKES THE BUILD LIST).               07990020
*********************************************************************** 08000020
         SPACE                                                          08010020
SRCHPDS  EQU   *                                                        08020020
         SPACE                                                          08030020
* USE TTR CONVERT ROUTINE TO GET ABS TRK ADDR FOR PDS ON LIBRARY        08040020
         MVI   LISTR,K0            ZERO R FIELD                         08050020
INSERTCN EQU   *                                                        08060020
         SR    W0,W0                 ZERO TTRN REG FOR TTRCNVT          08070020
NEXTCN   EQU   *                                                        08080020
         IC    W0,LISTCN           INSERT C. N.                         08090020
         LA    W2,MEXTENT          ADDR OF MBBCCHHR (IN 1ST DEB EXTENT) 08100020
         BAL   LINKREG,TTRCNVT     TO TTR CONVERT ROUTINE TO GET ABS AD 08110020
         SPACE                                                          08120020
*  READ DIRECTORY BLOCK WITH LOGICAL RECORD CONTAINING NAME OF MOD      08130020
*  THE BLOCK KEY CONTAINS THE NAME OF THE LOGICAL RECORD WITH THE       08140020
*  HIGHEST BINARY VALUE. (THE LAST BLOCKS KEY IS FFFFFFFFFFFFFFFF.)     08150020
*  THE SEARCH WITH NAME IS HIGH OR EQUAL.                               08160020
         LA    W1,READPDS           GET READ BLK CCW ADDR               08170020
         ST    W1,TICADDR           PUT IN CP BASE TIC ADDR             08180020
         LA    W1,LISTNAME          GET ADDR OF NAME IN BLDL LIST       08190020
         ST    W1,SRCHHIEQ         STORE IN CCW FOR SEARCH KEY          08200020
         MVI   SRCHHIEQ,X69             RESTORE OP CODE                 08210020
         MVC   NEXTCNT(K5),SRCHADDR MOVE CCHH FOR I/O EXTENT CHECK      08220020
READBLCK EQU   *                                                        08230020
         BAL   LINK2,IOROUTNE      READ DIRECTORY             IE  45459 08240000
         SPACE                                                          08250020
* SCAN DIRECTORY BLOCK FOR CORRECT RECORD                               08260020
         LA    W3,RDAREA-K1        MINUS 1 FOR END OF READ              08270020
         AH    W3,RDAREA           SET END ADDRESS (RDAREA-1+C)         08280020
         LA    W1,RDAREA+K2        GET ADDR OF 1ST LOGICAL RECORD       08290020
         LA    W0,X1F              MASK FOR C BYTE IN RECORD            08300020
COMPARE  CLC   K0(K8,W1),LISTNAME       COMPARE NAMES                   08310020
         BE    NAMEFND             NAME IS FOUND                        08320020
         BH    NOTDIRCT                 NOT IN THIS DIRECTORY SECTION   08330020
* DIRECTORY NAME IS LOW, COMPARE NEXT                                   08340020
         IC    W2,K11(W1)               GET USERS FIELD LENGTH          08350020
         NR    W2,W0                MASK 3 H.O. BITS                    08360020
         LA    W2,K12(W2,W2)            ENTIRE ENTRY LENGTH IN 2        08370020
         BXLE  W1,W2,COMPARE            MORE RECORDS IN BLOCK           08380020
         B     TSTEND              CHECK LIBRARY                        08390020
MOVE     EQU   *                                                        08400020
         MVC   LISTC(K1),K11(W1)   MOVE C + USER DATA FROM RDAREA       08410020
*                                TO BLDL LIST.  LENGTH COMPUTED IN W4.  08420020
NAMEFND  EQU   *                                                        08430020
         MVC   LISTTT(K3),K8(W1)   MOVE TTR                             08440020
         IC    W4,K11(W1)          GET C FROM DIRECTORY                 08450020
         NR    W4,W0                MASK 3 HIGH ORDER BITS              08460020
         LH    W5,LISTLL                GET USERS LL                    08470020
         SH    W5,C14               SUBTRACT CONSTANT 14                08480020
         BM    NOREFRSH             BR IF LL LESS THAN MINIMUM          08490020
         BXLE  W4,W4,MOVEDATA           IS REG 5 MORE THAN 2(REG4)      08500020
         LR    W4,W5                USE SMALLER COUNT                   08510020
MOVEDATA EX    W4,MOVE                  MOVE INTO USERS LIST            08520020
         MVC   RPTR+K1(K3),PDARTAB+K9 GET RELOCATION FACTOR             08530020
         SPACE                                                          08540020
         TM    LISTATR1,X04            SCATTER FORMAT                   08550020
         BO    TSTSCTR             BR YES, CHK IF SCATTER SPECIFIED     08560020
         TM    PDARTAB+K8,X80          NO,WAS SCATTER SPECIFIED         08570020
         BO    SCTERR               YES, CAN'T DO IT                    08580020
         B     CNVTTR               BRANCH                              08590020
         SPACE                                                          08600020
TSTSCTR  EQU   *                                                        08610020
         TM    PDARTAB+K8,X80          WAS SCATTER SPECIFIED            08620020
         BO    SCATRLD             BR YES, SCATTER LOADED FOR SURE      08630020
* MUST BE BLOCK EXTENT LIST                                             08640020
         MVC   RPTR+K1(K3),XLIST+K13 GET ADDR. FOR RELOC. FACTOR        08650020
         B     REFRMOD             GO READ MODULE                       08660020
         SPACE 2                                                        08670020
CHKLIBCN EQU   *                                                        08680020
         CLC   DEBAMIND(K1),LISTCN CHECK C.N.                           08690020
         BH    ANOTHRDS                 MORE DATA SETS IN CNCTNTN       08700020
         B     TSTEND              TEST FOR LIBRARY                     08710020
ANOTHRDS EQU   *                                                        08720020
         IC    W4,LISTCN                                                08730020
         LA    W4,K1(W4)           INCREMENT C.N.                       08740020
         STC   W4,LISTCN                                                08750020
         B     INSERTCN            GO TO GET C.N.                       08760020
         SPACE 2                                                        08770020
*              NOT IN THIS DIRECTORY SECTION                            08780020
NOTDIRCT EQU   *                                                        08790020
         CLI   K0(W1),XFF          CHECK FOR CONTINUATION POINTER       08800020
         BL    CHKLIBCN             NOT HIGH NAME                       08810020
         CLC   K1(K7,W1),K0(W1)    MAKE SURE                            08820020
         BL    CHKLIBCN             REALLY NOT HIGH NAME                08830020
         SPACE                                                          08840020
*  STEP TO NEXT JOBLIB,ELSE SET TO SEARCH LINKLIB                       08850020
TSTEND   EQU   *                                                        08860020
         L     DEBREG,DEBAMIND     LOAD POINTER TO NEXT DEB             08870020
         LA    DEBREG,K0(DEBREG)        CLR EXTRA INFO                  08880020
         LTR   DEBREG,DEBREG       ANY MORE JOBLIBS                     08890020
         BNZ   SRCHPDS                 FIND PDS OF NEXT JOBLIB          08900020
         CLI   LISTZ,X01               IS IT LINKLIB                    08910020
         BE    NOREFRSH                GO SET ERROR FLAGS               08920020
         B     SETLNK                  BR NO TO SEARCH LINKLIB          08930020
         SPACE 3                                                        08932021
***  MAINTENANCE  AREA ***                                              08934021
MAINTID  DC    CL8'IGFMCHF4'           CORE IDENTIFIER                  08936021
MAINT    DC    S(*)                    MODULE DISPLACEMENT              08938021
         DC    10CL4'&REL&LEV'         ADDITIONAL SPACE                 08938421
         EJECT                                                          08940020
MCHMAC   DSECT                                                          08950020
         MCHMAC                                                         08960020
         EJECT                                                          08970020
*              DEB DEFINITION                                           08980020
IHADEB   DSECT                                                          08990020
         DC    F'0'                     DSECT                           09000020
DEBAMIND DS    X                         DEFINITION                     09010020
         DS    11X                        TO                            09020020
DEBNMEXT DS    X                           ALLOW                        09030020
         DS    15X                          FOR                         09040020
DEBDVMOD DC    F'0'                          ADR                        09050020
DEBBINUM DC    H'0'                           REF                       09060020
DEBSTRCC DC    H'0'                            TO                       09070020
DEBSTRHH DC    H'0'                             SYS                     09080020
DEBENDCC DC    H'0'                              DEB                    09090020
DEBENDHH DC    H'0'                               BLK                   09100020
DEBNMTRK DC    H'0'                                ADR                  09110020
         SPACE 2                                                        09120020
*              DCB  DUMMY-SECTION                                       09130020
         DCBD                                                           09140020
*                                                                       09150020
CVTMAC   CVT                                                            09160020
         END                                                            09170020
