         LCLA  &LEV,&REL                                                00510100
&LEV     SETA  40                                                       00511200
&REL     SETA  21                                                       00511300
&REL&LEV TITLE 'IGFMCHF6 LEVEL &LEV MCH SUBSYSTEM ANALYSIS'             00511400
*********************************************************************** 00516700
*                                                                     * 00517800
*TITLE:  'IGFMCHF6'                                                   * 00518900
*STATUS:  CHANGE LEVEL                                        *         00520000
*FUNCTION/OPERATION:  SUBSYSTEMS ANALYSIS RECEIVES CONTROL WHEN THERE * 00521100
* IS A DYNAMIC STORAGE FAILURE VIA IGFMCHF2 OR IGFMCHF3.  IF TSO IS   * 00522200
* ACTIVE AND THE RESUME PSW IS ENABLED OR THE ERROR IS NOT IN THE     * 00522600
*  LSQS, THIS MODULE SCHEDULES THE TSO SUBSYSTEM RECOVERY MODULE AS   * 00523300
* ITS SUCCESSOR.  ALSO IF TSO IS ACTIVE AND THE ERROR IS WITHIN       * 00523700
* A LSQS OR THE RESUME PSW IS DISABLED, THIS MODULE EXITS TO          * 00524100
* PDAR TERMINATOR(IGFMCHF5) WITH WAIT STATE INDICATED.                * 00524200
* IF TSO IS NOT ACTIVE , THE SUBSYSTEMS ANALYSIS MODULE EXITS TO THE  * 00524400
* PDAR TERMINATOR FOR NORMAL PROCESSING.                              * 00526600
*                                                                       00527000
*ENTRY POINTS:  IGFMCHF6                                              * 00527700
*                                                                       00528100
*INPUT: COMMON AREA                                                   * 00528800
*             REPDARF1  -   FAILING INSTRUCTION ADDRESS                 00538800
*             MCHRPSW   -   RESUME PSW                                  00540800
*             MCHTCB    -    CURRENT TCB                                00542800
*             REPDAR2   -   SOLID FAILURE INDICATED                     00542900
*             MCHSUBP  -  SS COMMON AREA MACRO                          00543000
*   REG 9 - SUBSYSTEM COMMON AREA ADDRESS                               00543700
*                                                                       00544100
*                                                                       00544500
*OUTPUT:  MCHSUB (SS COMMON AREA)                                       00545200
*MCHAST                                                                 00545900
*MCHSSYS1 DS     1 BYTE     AFFECTED FLAGS                              00546600
*MCHSSYF1 DS     3 BYTES    AFFECTED TCB ADDRESS                        00547300
*MCHSSYS3 DS     1 BYTE     CURRENT JOBSTEP FLAGS                       00548000
*MCHSSYF3 DS     3 BYTES    CURRENT JOBSTEP TCB ADDRESS                 00548700
*MCHIN1  DS    F                   STARTING ADDR OF STORAGE FAILURE   * 00549400
*                  80 IN THE  FIRST BYTE INDICATES A SOLID ERROR        00550100
*MCHIN2  DS    F                   ENDING ADDR OF STORAGE FAILURE     * 00550800
*MCHIN3  DS    F                   ADDR FAILING INSTRUCTION           * 00551500
*MCHIN4  DS    F                   CURRENT TCB POINTER                * 00552200
*MCHIN5  DS    F                   RESERVED                           * 00552900
*MCHIN6  DS    F                   RESERVED                           * 00553600
*MCHIN7  DS    F                   RESERVED                           * 00554300
*MCHIN8  DS    F                   RESERVED                           * 00555000
*MCHINPSW DS    2F                 MC OLD PSW                         * 00555700
*MCHRSPSW DS    2F                 RESUME PSW                         * 00556400
*MCHSSCDE DS    2F                 MESSAGE CODE FIELD                 * 00557100
*                                                                     * 00557800
*                                                                       00558200
*EXTERNAL ROUTINES:  NONE                                             * 00558500
*EXITS:  TSO SUBSYSTEM RECOVERY MODULE (IGFMCH91)                     * 00559600
*       PDAR TERMINATOR (IGFMCHF5)                                    * 00561800
*TABLES/WORK AREAS:  COMMON AREA,CVT,SCVT,RXL,RXLQE,MCHSUB            * 00562900
*                                                                       00563300
*ATTRIBUTES:  NON-RESIDENT                                            * 00564000
*             RE-ENTRANT                                              * 00565100
*             SUPERVISOR STATE                                        * 00566200
*                                                                     * 00567300
*NOTES    MAINTENANCE SPACE                                             00568400
*         A DC OF 50 BYTES WITH THE LABEL                               00569520
*         *****MAINT*****                                               00579520
*                                                                       00589520
*                                                                       00599500
*   THIS MODULE WAS MODIFIED FOR APAR 42247                             00609500
*********************************************************************** 00619520
         EJECT                                                          00629500
IGFMCHF6 CSECT                                                          00669520
         USING IGFMCHF6,BASE                                            01000020
         USING ASRCOMM,MCHCOMM                                          01500020
         USING MCHSUB,MCHSS                                             02000020
         USING CVTD,CVTBASE                                             02500020
         USING RXL,RXLB                                                 03000020
         USING RXLQE,RXLQEB                                             03500020
         STM   CVTBASE,MCHNUC,REGSAVE   SAVE REGS                       04000020
         MVI   MCHEXLEV,LEVEL      INDICATE MODULE LEVEL                12010000
         TM    CVTTSFLG,CVTTSRDY   IS TSO ACTIVE                        13000020
         BZ    GOTERM              NO, CONTINUE NORMAL PROCESSING       13500020
         SPACE 2                                                        14000020
* TSO IS ACTIVE        CHECK TO SEE IF ERROR LIES IN LSQS AREA          14500020
*  IF IT DOES THEN SYSTEM MUST BE PLACED IN DISABLED WAIT STATE         15000020
         SPACE 1                                                        15500020
* BRANCH TO INITIALIZE ROUTINE                                          16000020
         L     R2,REPDARF1         FAILING INSTRUCTION ADDR             16050000
         L     R3,CVTABEND         SECONDRY CVT ADDR                    16100000
         USING SCVTD,R3                                                 16150000
         L     RXLB,SCVTRXLQ       GET TSO RECOVERY EXTENT LIST         16200000
         DROP  R3                                                       16250000
         L     RXLQEB,RXLRXLQ      FIRST BOUNDARY Q  - TSC              17000020
         L     RXLQEB,RXLQRXLQ     NEXT BOUNDARY Q - TCAM SET UP DSECT  17500020
         L     RXLQEB,RXLQRXLQ     NEXT BOUNDARY Q - RCT    BASE REG    18000020
* DETERMINE IF ERROR LOCATION LIES IN ANY REGION'S LSQS AREA            18500020
CHKNXT   EQU   *                                                        19000020
         C     R2,RXLQRGLO         BEGINNING OF REGION LSQS             19500020
         BL    NXREGION            IS ERROR BELOW                       20000020
         C     R2,RXLQLSHI         END OF REGION LSQS                   20500020
         BH    NXREGION            IS ERROR HIGH                        21000020
* ERROR LIES IN THIS REGION'S LSQS AREA - MUST ENTER WAIT STATE         21500020
         SPACE 2                                                        22000020
WAIT     EQU   *                                                        22500020
         OI    REPDAR6,X40        SET CODE FOR WAIT MSG                 23000000
         B     GOTERM              GO TO PDAR TERM                      23500020
         SPACE 2                                                        24000020
NXREGION EQU   *                                                        24500020
         L     RXLQEB,RXLQRXLQ     LOAD NEXT REGION BOUNDARY QUEUE      25000020
         LTR   RXLQEB,RXLQEB       IS IT ZERO                           25500020
         BNZ   CHKNXT              NO, CHECK NEXT QUEUE                 26000020
* ERROR DOES NOT LIE IN LSQS - CONTINUE NORMAL PROCESSING               26500020
         SPACE 2                                                        27000020
         EJECT                                                          34000000
* INITIALIZE MCH SYBSYSTEM MACRO FOR SUBSYSTEM INTERFACE MODULE         34500020
         SPACE 2                                                        35000020
         TM    REMCOPSW,XFE        WAS I/O DISABLED AT TIME OF INT      35500000
         BZ    WAIT                YES, MUST ENTER WAIT STATE           36000020
         MVC   MCHRSPSW(8),MCHRPSW MOVE IN RESUME PSW             2980  38550020
         ST    R2,MCHIN1           ADDR OF STORAGE FAILURE              40000020
         L     R2,MCHTCB           CURRENT TCB                          41550000
         ST    R2,MCHIN4              IN THE SS COMMON MACRO            41600000
         L     R2,X7C(R2)          GET JOBSTEP                          41650000
         LA    R2,K0(R2)           CLEAR HI BYTE                        41700000
         ST    R2,MCHSSYS3         CURRENT JOBSTEP TCB                  41750000
         MVC   MCHINPSW(K8),REMCOPSW  MOVE IN MC OLD PSW                43000020
         TM    REPDAR2,XA0         IS ERROR SOLID                       43500020
         BZ    EXSUB               NO-INTERMITTENT ERROR                44000000
         MVI   MCHIN1,X40          YES-SET SOLID INDICATOR              44050000
EXSUB    EQU   *                                                        45000020
         MVI   MCHNXMOD,K2                 SCHEDULE TSO SUBSYSTEM MOD   45010020
         B     RETURN              RETURN TO NUC                        45060000
GOTERM   EQU   *                                                        48550000
         MVI   MCHNXMOD,K1          SCHEDULE PDAR TERM                  48600000
RETURN   EQU   *                                                        58000020
         LM    CVTBASE,MCHNUC,REGSAVE  RESTORE REGS                     58500020
         BR    MCHNUC              RETURN TO NUC                        59000020
         SPACE 2                                                        59500020
LEVEL    EQU   X'&LEV'             MODULE LEVEL                  2980   66010000
MCHSS    EQU   9                   REG                                  66500020
MCHCOMM  EQU   11                  REG                                  67000020
MCHNUC   EQU   14                  REG                                  68000020
X40      EQU   X'40'                                                    71000020
K8       EQU   8                                                        71500020
REGSAVE  DC    5F'0'               SAVE AREA                            72000000
XA0      EQU   X'A0'                                                    72510020
XFE      EQU   X'FE'                                                    72560000
*                                                                       72610000
K0       EQU   0                                                        73000000
K3       EQU   3                                                        73500020
K4       EQU   4                                                        74000020
X7C      EQU   X'7C'                                                    74050000
X80      EQU   X'80'                                                    74500020
X10      EQU   X'10'                                                    75000020
BASE     EQU   15                                                       75500020
CVTBASE  EQU   10                                                       76000020
RXLB     EQU   8                                                        76500020
RXLQEB   EQU   7                                                        77000020
R2       EQU   2                                                        78500020
K1       EQU   1                                                        81000020
K2       EQU   2                                                        81500020
R3       EQU   3                                                        82000020
*        MAINTENANCE AREA                                               83560000
MAINTID  DC    CL8'IGFMCHF6'       CORE IDENTIFIER                      83610000
MAINT    DC    S(*)                MODULE DISPLACEMENT                  83660000
         DC    10CL4'&REL&LEV'     ADDITIONAL SPACE                     83710000
CVTD     DSECT                                                          86000020
         CVT                                                            86500020
         EJECT                                                          86550000
SCVTD    DSECT                                                          86600000
         SCVT                                                           86650000
         EJECT                                                          86700000
ASRCOMM DSECT                                                           87000020
         MCHMAC                                                         87500020
         IKJRXL                                                         88000020
         IKJRXLQE                                                       88500020
MCHSUB   DSECT                                                          89000020
         MCHSUB                                                         89500020
      END                                                               90000020
