         LCLA  &LEV,&REL                                                00012000
&LEV     SETA  40                                                       00014000
&REL     SETA  21                                                       00016000
&REL&LEV TITLE 'IGFMVTF1 LEVEL &LEV PDAR 1 MVT '                        00018000
*********************************************************************** 00020020
*********************************************************************** 00030020
*              *                                      *                 00040020
*              *                                      *                 00050020
*TITLE   'IGFMVTF1(IGFMCHF1)'                                           00060020
*STATUS  CHANGE LEVEL=00                                             *  00070000
*FUNCTION/OPERATION  THE MVT SYSTEM ANALYSIS ROUTINE PERFORMS AN      * 00080020
*                   ANALYSIS OF DATA FROM THE MCH COMMON AREA AND     * 00090020
*                   DETERMINES THE IMPACT OF THE MACHINE CHECK ON THE * 00100020
*                   SYSTEM. IT READIES THE SYSTEM FOR ONE OF THE      * 00110020
*                   FOLLOWING RECOVERY PROCEDURES                       00120020
*                        A. REFRESHING A BLOCK OF CODE                * 00130020
*                        B. RETRYING AN INSTRUCTION                   * 00140020
*                        C. SETTING THE AFFECTED TASK NONDISPATCHABLE * 00150020
*                        D. TERMINATING THE ERROR-ASSOCIATED JOB STEP * 00160020
*                   IT MAY ALSO CORRECT DAMAGED SPF KEYS.             * 00170020
*ENTRY POINT   IGFMCHF1                                                 00180020
*INPUT   COMMON AREA                                                    00190020
*        (MCHPDAR)                                                      00200020
*OUTPUT  COMMON AREA                                                    00210020
*        (MCHPDAR,MCHTCB,MCHEXLEV,MCHNXMOD)                             00220020
*        MCHSUB                                                         00222000
*                                                                       00230020
*EXITS      (REFRESH/REPAIR VERIFICATION)                               00240020
*           (PDAR TERMINATION ANALYSIS)                                 00250020
*           (PDAR ANALYSIS 2)                                           00260020
*           (PDAR ANALYSIS 3)                                           00270020
*           (REFRESH LOADER)                                            00280020
*                                                                       00290020
*TABLES AND WORK AREAS   COMMUNICATION AREA                             00300020
*                              MCHTCB,MCHPDAR                           00310020
*EXTERNAL ROUTINES  NONE                                                00320020
*ATTRIBUTES    SERIALLY REUSEABLE,PRIVILEDGED                           00330020
*RESTRICTIONS  OPERATES ONLY IN A MVT SYSTEM                            00340020
*              *                                      *                 00350020
*              *                                      *                 00360020
*********************************************************************** 00370020
*********************************************************************** 00380020
*              *                                      *                 00390020
*              *                                      *                 00400020
*              ****************************************                 00410020
*  PDARSTAT    *  STAT  *          TCBAD              *                 00420020
*              ****************************************                 00430020
*  PDARTAB     *         NAME                         *                 00440020
*              *       8 BYTES                        *                 00450020
*              ****************************************                 00460020
*              *  FLAG  *        ADDRESS              *                 00470020
*              ****************************************                 00480020
*              *    LENGTH         *                  *                 00490020
*              *    2 BYTES        *                  *                 00500020
*              ****************************************                 00510020
*                                                                     * 00520020
*              ****************************************                 00530020
*  PDARCUA     *  CUA(2 BYTES)     *  CUA(2 BYTES)    *                 00540020
*              *  CUA              *  CUA             *                 00550020
*              *  CUA              *  CUA             *                 00560020
*              *  CUA              *  CUA             *                 00570020
*              *  CUA              *  CUA             *                 00580020
*              *  CUA              *  ZEROS           *                 00590020
*              ****************************************                 00600020
*                                                                     * 00610020
*  REPDAR                          (ASRMAC)                             00620020
*              ********************                                     00630020
*              *        *         *                                     00640020
*              ********************                                     00650020
*                                                                       00660020
*              ********************                                     00670020
*  COMSYSRS    *  CUA   *ATRB*    *                                     00680020
*              ********************                                     00690020
*              ****************************************                 00700020
*              ****************************************                 00710020
*                                                                       00720020
* FIELD NAME   BYTES     FIELD DISCRIPTION                              00730020
*   STAT       1         PDAR STATUS BYTE                               00740020
*       BIT    SETTING     MEANING                                      00750020
*   TCBAD      3         POINTER TO AFFECTED TASK CONTROL BLOCK         00760020
*   NAME       8         NAME OF PROGRAM TO BE SEARCHED IN THE LIBRARY, 00770020
*                        OR RELATIVE OR ABSOLUTE TRACK ADDRESS OF THE   00780020
*                        LOAD MODULE TO BE REFRESHED. SEE FLAG.         00790020
*                                                                       00800020
* FIELD NAME   BYTES     FIELD DESCRIPTION                              00810020
*   FLAG       1         REFRESH TABLE FLAGS                            00820020
*        BIT   SETTING     MEANING                                      00830020
*        0     0           ADDRESS IS ABSOLUTE STORAGE ADDRESS OF       00840020
*                          MODULE TO BE REFRESHED                       00850020
*        0     1           ADDRESS IS POINTER TO SCATTER LOAD EXTENT    00860020
*                          LIST                                         00870020
*        1     1           MODULE IS IN SVC  LIB                        00880020
*        2     1           MODULE IS IN ASR  LIB (IMPLIES ABS TRK ADR)  00890020
*        3     1           NAME FIELD IS RELATIVE TRACK ADDRESS         00900020
*        4     1           NAME FIELD IS ABSOLUTE TRACK ADDRESS         00910020
*                          LENGTH IN PDARTAB+12 CONTAINS TEXT LENGTH    00920020
*        5     1           MODULE IS IN LINKLIB                         00930020
*        6     1           PRIMARY FAILURE                              00940020
*        7     1           SET BY LOADER IF REFRESH OK                  00950020
*                                                                       00960020
* FIELD NAME   BYTES     FIELD DISCRIPTION                              00970020
*   CUA        2         CHAN AND UNIT ADDR OF JOBLIB AND LINKLIB       00980020
*                        (UP TO ELEVEN UNITS ARE CLEARED BY ASRNUC)     00990020
*                                                                       01000020
* FIELD NAME   BYTES     FIELD DISCRIPTION                              01010020
*   ADDRESS    3         SEE FLAG BIT 0                                 01020020
*                                                                       01030020
* FIELD NAME   BYTES     FIELD DISCRIPTION                              01040020
*   LENGTH     2         SEE FLAG BIT 4                                 01050020
*                                                                       01060020
* FIELD NAME   BYTES     FIELD DESCRIPTION                              01070020
*  REPDAR                PROGRAM DAMAGE ASSESSMENT AND REPAIR DATA      01080020
*                                                                       01090020
*  REPDAR1     1         PDAR ACTION                                    01100020
*        BIT   SETTING     MEANING                                      01110020
*        0     1           TERMINATION NECESSARY                        01120020
*        1     1           REPAIR/RETRY FAILED                          01130020
*        2     1           RETRY POSSIBLE                               01140020
*        3     1           INDETERMINATE INSTRUCTION COUNTER            01150020
*        4     1           INSTRUCTION INVOLVED                         01160020
*        5     1           OPERAND INVOLVED                             01170020
*        6     1           SYSTEM WAIT IF REFRESH/REPAIR/RETRY FAILS    01180020
*        7     1           INHIBIT TERMINATION                          01190020
*                                                                       01200020
* REPDAR2      1         PDAR ACTION                                    01210020
*        BIT   SETTING     MEANING                                      01220020
*        0     1           SOLID STORAGE DATA ERROR                     01230020
*        1     1           INTERMITTENT STORAGE DATA ERROR              01240020
*        2     1           SOLID SPF KEY ERROR                          01250020
*        3     1           INTERMITTENT SPF KEY ERROR                   01260020
*        4     1           REFRESH/REPAIR SUCCESSFUL                    01270020
*        5     1           STORAGE DATA ERROR LOCATION CLEARED          01280020
*        6     1           BLOCK STORAGE FAILURE                        01290020
*        7     1           UNIT STORAGE FAILURE                         01300020
*                                                                       01310020
* FIELD NAME   BYTES     FIELD DESCRIPTION                              01320020
*  REPDAR3     1         OPERATING SYSTEM STATUS                        01330020
*        BIT   SETTING     MEANING                                      01340020
*        0     1           WAIT PSEUDO TASK                             01350020
*        1     1           MASTER SCHEDULAR TASK                        01360020
*        2     1           SYSTEM TASK                                  01370020
*        3     1           PROBLEM PROGRAM TASK                         01380020
*        4     1           CURRENT PSW DISABLED FOR I/O AND EXTERNAL    01390020
*                          INTERRUPTIONS                                01400020
*        5-7               UNUSED                                       01410020
*                                                                       01420020
* FIELD NAME   BYTES     FIELD DESCRIPTION                              01430020
*  REPDAR4     1         LOCATION OF ERROR                              01440020
*        BIT   SETTING     MEANING                                      01450020
*        0     1           NUCLEUS                                      01460020
*        1     1           SVC TRANSIENT AREA                           01470020
*        2     1           ERROR TRANSIENT AREA                         01480020
*        3     1           REFRESHABLE NUCLEUS CSECT                    01490020
*        4     1           DYNAMIC AREA                                 01500020
*        5     1           LINK PACK AREA                               01510020
*        6     1           RESIDENT TYPE III SVC                        01520020
*        7     1           BLDL TABLE                                   01530020
*                                                                       01540020
*  REPDAR5     1         LOCATION OF INSTRUCTION WHEN FAILING ADDRESS   01550020
*                        INVOLVES OPERAND                               01560020
*        BIT   SETTING     MEANING                                      01570020
*        0     1           NUCLEUS                                      01580020
*        1     1           DYNAMIC AREA                                 01590020
*        2     1           LINK PACK AREA                               01600020
*        3-7               RESERVED FOR FUTURE USE                      01610020
*                                                                       01620020
*  REPDAR6     1         REQUESTED OPERATOR AWARENESS                   01630020
*        BIT   SETTING     MEANING                                      01640020
*        0     1           UNRECOVERABLE SUPERVISOR ERROR MSG.          01650020
*        1     1           UNRETRYABLE SUPERVISOR ERROR MSG.            01660020
*        2     1           DYNAMIC AREA UNRECOVERABLE MSG.              01670020
*        3     1           TASK ABEND MESSAGE                           01680020
*        4     1           BLDL REPAIRED ABEND MSG.                     01690020
*        5-7               UNUSED                                       01700020
*                                                                       01710020
* FIELD NAME   BYTES     FIELD DESCRIPTION                              01720020
*  REPDARF1    4         FAILING LOCATION BEGINNING ADDRESS             01730020
*  REPDARF2    4         FAILING LOCATION ENDING ADDRESS                01740020
*                                                                       01750020
*  REPDARI     4         INSTRUCTION ADDRESS AT FAILURE                 01760020
*                                                                       01770020
*  RERETRY     8         MCH RETRY REPORT AREA                          01780020
*                                                                       01790020
*   FAIL1                 ALIAS OF REPDARF1                             01800020
*   FAIL2                 ALIAS OF REPDARF2                             01810020
*                                                                       01820020
*  NOTES     MAINTENANCE SPACE                                          01822020
*            A DC OF 50 BYTES WITH THE LABEL                            01824020
*            *****MAINT*****                                            01826020
*                                                                       01828020
*********************************************************************** 01830020
*********************************************************************** 01840020
IGFMVTF1 CSECT                                                          01850020
WKR0     EQU   0                   GENERAL REGISTER                     01860020
WKR1     EQU   1                   GENERAL REGISTER                     01870020
WKR2     EQU   2                   GENERAL REGISTER                     01880020
WKR3     EQU   3                   GENERAL REGISTER                     01890020
WKR4     EQU   4                   GENERAL REGISTER                     01900020
WKR5     EQU   5                   GENERAL REGISTER                     01910020
WKR6     EQU   6                   GENERAL REGISTER                     01920020
WKR7     EQU   7                   GENERAL REGISTER                     01930020
WKR8     EQU   8                   GENERAL REGISTER                     01940020
WKR9     EQU   9                   GENERAL REGISTER                     01950020
WKR10    EQU   10                  GENERAL REGISTER                     01960020
LINK     EQU   10                  GENERAL LINKING REGISTER             01970020
COMREG   EQU   11                  BASE FOR  RMS COMMON AREA            01980020
BASEREG  EQU   12                  MODULE BASE REG                      01990020
RETURN   EQU   14                  EXIT REG TO RMS NUCLEUS              02000020
WKR15    EQU   15                  GENERAL REGISTER                     02010020
         EJECT                                                          02020020
K0       EQU   0                   DECIMAL VALUE                        02030020
K1       EQU   1                   DECIMAL VALUE                        02040020
K2       EQU   2                   DECIMAL VALUE                        02050020
K3       EQU   3                   DECIMAL VALUE                        02060020
K4       EQU   4                   DECIMAL VALUE                        02070020
K5       EQU   5                   DECIMAL VALUE                        02080020
K6       EQU   6                   DECIMAL VALUE                        02090020
K8       EQU   8                   DECIMAL VALUE                        02100020
K9       EQU   9                   DECIMAL VALUE                        02110020
K10      EQU   10                  DECIMAL VALUE                        02120020
K11      EQU   11                  DECIMAL VALUE                        02130020
K12      EQU   12                  DECIMAL VALUE                        02140020
K13      EQU   13                  DECIMAL VALUE                        02150020
K16      EQU   16                  DECIMAL VALUE                        02160020
K17      EQU   17                  DECIMAL VALUE                        02170020
K20      EQU   20                  DECIMAL VALUE                        02180020
K21      EQU   21                  DECIMAL VALUE                        02190020
K22      EQU   22                                                       02200020
K24      EQU   24                  DECIMAL VALUE                        02210020
K28      EQU   28                  DECIMAL VALUE                        02220020
K31      EQU   31                  DECIMAL VALUE                        02230020
K32      EQU   32                  DECIMAL VALUE                        02240020
K33      EQU   33                  DECIMAL VALUE                        02250020
K40      EQU   40                  DECIMAL VALUE                        02260020
K44      EQU   44                  DECIMAL VALUE                        02270020
K56      EQU   56                  DECIMAL VALUE                        02280020
K100     EQU   100                 COUNTER FOR TIO LOOP                 02290020
K116     EQU   116                 DECIMAL VALUE                        02300020
K124     EQU   124                 DECIMAL VALUE                        02310020
K128     EQU   128                 DECIMAL VALUE                        02320020
K132     EQU   132                 DECIMAL VALUE                        02330020
K136     EQU   136                 DECIMAL VALUE                        02340020
K152     EQU   152                 DECIMAL VALUE                        02350020
K173     EQU   173                                                      02360020
K200     EQU   200                 DECIMAL VALUE                        02370020
K252     EQU   252                 DECIMAL VALUE                        02380020
K400     EQU   400                 DECIMAL VALUE                        02390020
K1024    EQU   1024                DECIMAL VALUE                        02400020
K2048    EQU   2048                LENGTH OF 2K AREA                    02410020
         EJECT                                                          02420020
*    HEX EQUATES                                                        02430020
X01      EQU   X'01'               HEXADECIMAL VALUE                    02440020
X02      EQU   X'02'               HEXADECIMAL VALUE                    02450020
X04      EQU   X'04'               HEXADECIMAL VALUE                    02460020
X08      EQU   X'08'               HEXADECIMAL VALUE                    02470020
X10      EQU   X'10'                                                    02480020
X0D      EQU   X'0D'               HEXADECIMAL VALUE                    02490020
X0E      EQU   X'0E'               HEXADECIMAL VALUE                    02500020
X20      EQU   X'20'               HEXADECIMAL VALUE                    02510020
X24      EQU   X'24'               HEXADECIMAL VALUE                    02520020
X28      EQU   X'28'               HEXADECIMAL VALUE                    02530020
X40      EQU   X'40'               HEXADECIMAL VALUE                    02540020
X4A      EQU   X'4A'               HEXADECIMAL VALUE                    02550020
X52      EQU   X'52'               HEXADECIMAL VALUE                    02560020
X60      EQU   X'60'               HEXADECIMAL VALUE                    02570020
X7F      EQU   X'7F'               HEXADECIMAL VALUE                    02580020
X80      EQU   X'80'               HEXADECIMAL VALUE                    02590020
XBF      EQU   X'BF'               HEXADECIMAL VALUE                    02600020
XFF      EQU   X'FF'               HEXADECIMAL VALUE                    02610020
SEEK     EQU   X'07'               SEEK COMMAND                         02620020
RDR0     EQU   X'16'               READ RECORD ZERO COMMAND             02630020
SRCH     EQU   X'31'               SEARCH ID EQUAL COMMAND              02640020
TIC      EQU   X'08'               TRANSFER IN CHANNEL COMMAND          02650020
READDATA EQU   X'06'               READ DATA COMMAND                    02660020
SENSE    EQU   X'04'               SENSE COMMAND                        02670020
SCATLOAD EQU   X'80'               SCATTER LOAD FORMAT FLAG             02680020
TCBFRO   EQU   X'10'                                                    02690020
MVCSW    EQU   X'40'               ADDRESS OF CHANNEL STATUS WORD       02700020
MVCAW    EQU   X'48'               ADDRESS OF CHANNEL ADDRESS WORD      02710020
         EJECT                                                          02720020
*   DEFINITION OF REPDAR1                                             * 02730020
TERM     EQU   X'80'                                                    02740020
RF       EQU   X'40'               RETRY FAILED                         02750020
RP       EQU   X'20'               RETRY POSSIBLE                       02760020
II       EQU   X'10'               IC IND                               02770020
INSTR    EQU   X'08'               INSTR                                02780020
OPERAND  EQU   X'04'               OPERAND                              02790020
WAITFAIL EQU   X'02'               WAIT IF REPAIR FAILS                 02800020
INHIBTRM EQU   X'01'               INHIBIT TERM                         02810020
*   DEFINITION OF REPDAR2                                             * 02820020
SOLSTG   EQU   X'80'               SOLID STG                            02830020
INTSTG   EQU   X'40'               INT STG                              02840020
SOLSPF   EQU   X'20'               SOLID SPF                            02850020
INTSPF   EQU   X'10'               INT SPF                              02860020
REPAIR   EQU   X'08'               REP                                  02870020
STGCLR   EQU   X'04'               CLEARED                              02880020
BLOCK    EQU   X'02'               BLOCK STORAGE FAILURE                02890020
UNIT     EQU   X'01'               UNIT STORAGE FAILURE                 02900020
*   DEFINITION OF REPDAR3                                             * 02910020
TCBWAIT  EQU   X'80'               WAIT                                 02920020
TCBMS    EQU   X'40'               MAST SCHED                           02930020
TCBSYS   EQU   X'20'               SYS                                  02940020
TCBPP    EQU   X'10'               P/P                                  02950020
IODSBL   EQU   X'08'               IO DISABLED                          02960020
*   DEFINITION OF REPDAR4                                             * 02970020
NUC      EQU   X'80'                                                    02980020
SVCTRAN  EQU   X'40'                                                    02990020
ERRTRAN  EQU   X'20'                                                    03000020
NUCCSECT EQU   X'10'                                                    03010020
DYNAMIC  EQU   X'08'                                                    03020020
LINKPACK EQU   X'04'                                                    03030020
RESSVC3  EQU   X'02'                                                    03040020
BLDLTAB  EQU   X'01'                                                    03050020
*   DEFINITION OF REPDAR5                                             * 03060020
*   DEFINITION OF REPDAR6                                             * 03070020
MSGCODE0 EQU   X'80'                                                    03080020
MSGCODE1 EQU   X'40'                                                    03090020
MSGCODE2 EQU   X'20'                                                    03100020
MSGCODE3 EQU   X'10'                                                    03110020
MSGCODE4 EQU   X'08'                                                    03120020
LEVEL    EQU   X'&LEV'                                                  03130000
         EJECT                                                          03140020
MVIN000  EQU   *                                                        03150020
         USING *,BASEREG           MODULE ADDRESSABILITY                03160020
         USING DCOMAREA,COMREG                                          03170020
         USING DCVT,WKR15          SET UP BASE FOR CVT DSECT            03180020
         LR    WKR1,BASEREG        SAVE BASE REG TO AVOID DESTROYING    03190020
         LR    BASEREG,WKR15       SETUP MODULE BASE                    03200020
         STM   WKR2,WKR0,SAVE      SAVE ALL REGS EXCEPT GPR1            03210020
         ST    WKR1,SAVE+K40       SAVE REG 1  -  BASE REG              03220020
         L     WKR15,MCHCVT        SET UP BASE FOR CVT DSECT            03230020
         MVI   MCHEXLEV,LEVEL      MODULE LEVEL                         03240000
         L     WKR2,MCHSUBP       GET SUBSYSTEM MACRO ADDR    IE  42247 03242000
         LTR   WKR2,WKR2           IS THERE A SUBSYSTEM       IE  42247 03244000
         BZ    NOTZERO             NO-SKIP CLEARING           IE  42247 03246000
         XC    K0(X40,WKR2),K0(WKR2) CLEAR MCHSUB             IE  42247 03248000
NOTZERO  EQU   *                                              IE  42247 03248400
         TM    REPDAR1,RF          HAS RETRY FAILED                     03250020
         BO    MVRF000             YES  GO CHECK TERMINATION NEEDED     03260020
         EJECT                                                          03270020
MVTCB00  EQU   *                                                        03280020
         L     WKR2,CVTTCBP        GET PTR TO NEW AND CURRENT TCB PTRS  03290020
         L     WKR2,K4(WKR2)       GET PTR TO CURRENT TCB               03300020
         ST    WKR2,MCHTCB         SAVE ADDR OF CURRENT TCB             03320020
*   CHECK FOR WAIT STATE TCB IN CONTROL                               * 03350020
         L     WKR3,K0(WKR2)       GET RB POINTER                       03360020
         LTR   WKR3,WKR3           ANY RB                               03370020
         BZ    MVTCB10             NO  CONTINUE                         03380020
         TM    K17(WKR3),X02       IS WAIT TCB IN CONTROL               03390020
         BNO   MVTCB10             NO  CONTINUE                         03400020
         OI    REPDAR3,TCBWAIT     INDICATE TASK IS WAIT PSEUDO TASK    03410020
         B     MVENB00             CONTINUE, WITH NORMAL PROC.          03420020
MVTCB10  EQU   *                                                        03430020
         L     WKR3,K132(WKR2)     GET ADDRESS OF ORIGINATING TASK      03440020
         LTR   WKR3,WKR3           IS CURRENT TASK THE MASTER SCHEDULER 03450020
         BNZ   MVTCB20             NO,FIELD NOT ZERO  CONTINUE          03460020
         OI    REPDAR3,TCBMS       INDICATE TASK IS MASTER SCHEDULER    03470020
         B     MVENB00             CONTINUE WITH NORMAL PROC.           03480020
MVTCB20  EQU   *                                                        03490020
         L     WKR4,K132(WKR3)     GET ORIGINATORS ORIGINATOR ADDRESS   03500020
         LTR   WKR4,WKR4           IS HTAT THE MASTER SCHEDULER         03510020
         BNZ   MVTCB40             NO                                   03520020
MVTCB30  EQU   *                                                        03530020
         OI    REPDAR3,TCBSYS      INDICATE TASK IS A SYSTEM TASK       03540020
         B     MVENB00             CONTINUE WITH NORMAL PROC.           03550020
MVTCB40  EQU   *                                                        03560020
         L     WKR4,K132(WKR4)     GET NEXT LEVEL ORIGINATOR ADDRESS    03570020
         LTR   WKR4,WKR4           SYSTEM TASK                          03580020
         BZ    MVTCB30             YES                                  03590020
         OI    REPDAR3,TCBPP       INDICATE TASK IS PROBLEM PROGRAM     03600020
MVENB00  EQU   *                                                        03610020
         TM    REMCOPSW,XFF        WAS I/O DISABLED AT INTERRUPT        03620020
         BNZ   MVINT00             NO  GO TO INTERPRET INTERFACE FIELDS 03630020
         OI    REPDAR3,IODSBL      INDICATE I/O WAS DISABLED            03640020
         EJECT                                                          03650020
MVINT00  EQU   *                                                        03660020
         TM    REPDAR1,TERM+II     IS TERM AN IC INDETERMINATE ON       03670020
*   EITHER RP OR TERM MUST ALWAYS BE ON - THEREFORE, IT IS ASSUMED    * 03680020
*   THAT IF ONE IS TESTED (RP OR TERM) AND IT IS NOT ON, THEN THE     * 03690020
*   OTHER IS ON                                                       * 03700020
         BNO   MVINT20             NO                                   03710020
         TM    REPDAR3,TCBPP       IS THIS A PROBLEM PROGRAM            03720020
         BO    MVINT20             P/P, YES                             03730020
MVINT10  EQU   *                                                        03740020
         TM    REPDAR1,INHIBTRM    IS INHIBIT TERMINATION REQUESTED     03750020
         BO    MVINT15             YES, SKIP TERMINATION PROCEDURES     03760020
         OI    REPDAR6,MSGCODE1    UNRETRYABLE SUPERVISOR ERROR MSG.    03770020
MVINT15  EQU   *                                                        03780020
         MVI   MCHNXMOD,K2         SUCCESSOR IS PDAR TERM               03790020
MVEX000  EQU   *                                                        03800020
         LM    WKR2,WKR0,SAVE      RESTORE REGS                         03810020
         BR    RETURN              RETURN TO NUCLEUS                    03820020
MVINT20  EQU   *                                                        03830020
         TM    REPDAR2,SOLSTG+SOLSPF SOLID STORAGE DATA/SOLID SPF ERROR 03840020
         BNZ   MVSOL00             YES DETERMINE LOCATION               03850020
         TM    REPDAR3,IODSBL      CURRENT PSW DISABLED FOR I/O         03860020
         BNO   MVINT30             NO                                   03870020
         TM    REPDAR1,TERM        IS TERMINATION NECESSARY             03880020
         BO    MVINT10             YES                                  03890020
         OI    REPDAR1,WAITFAIL    SET WAIT IF REPAIR FAILS FLAG        03900020
MVINT30  EQU   *                                                        03910020
         TM    REPDAR2,INTSTG      INTERMITTENT STORAGE ERROR           03920020
         BO    MVSTG000            YES                                  03930020
         TM    REPDAR2,INTSPF      INTERMITTENT SPF ERROR               03940020
         BO    MVSOL00             YES                                  03950020
         TM    REPDAR1,RP          IS RETRY ON                          03960020
         BO    MVRETRY             IF ON - RETRY IS POSSIBLE            03970020
*   RETRY NOT POSSIBLE, TERMINATION NECESSARY                         * 03980020
MVINT31  EQU   *                                                        03990020
         TM    REPDAR1,INHIBTRM    IS INHIBIT TERMINATION REQUESTED     04000020
         BO    MVINT15             YES, SKIP TERMINATION PROCEDURES     04010020
         TM    REPDAR3,TCBWAIT     IS WAIT PSEUDO TCB CURRENT           04020020
         BO    MVINT10             YES  CANNOT ABEND                    04030020
         TM    REPDAR4,BLDLTAB     IS ERROR IN BLDL TABLE               04040020
         BNO   MVINT33             NO  REGULAR ABEND                    04050020
         OI    REPDAR6,MSGCODE4    REQUEST BLDL REPAIRED ABEND MESSAGE  04060020
         B     MVINT35             GO TO SET NON-DISP.                  04070020
MVINT33  EQU   *                                                        04080020
         OI    REPDAR6,MSGCODE3    TASK ABEND MESSAGE REQUIRED          04090020
MVINT35  EQU   *                                                        04100020
         MVI   MCHNXMOD,K2         SUCCESSOR IS PDAR TERM               04230020
         B     MVEX000             GO TO EXIT                           04240020
MVRETRY1 EQU   *                                                        04250020
         LR    RETURN,WKR3         RESTORE REG 14                       04260020
         OI    MCHDAMAG+K3,X10         SET REFRESH FLAG                 04270020
MVRETRY  EQU   *                                                        04280020
         TM    REPDAR1,RP          IS RETRY POSSIBLE                    04290020
         BNO   MVINT31             NO, GO TO ABEND TASK                 04300020
         MVI   MCHNXMOD,K1         SUCCESSOR IS RETRY                   04310020
         B     MVEX000             GO TO EXIT                           04320020
         EJECT                                                          04330020
*                                                                     * 04340020
*********************************************************************** 04350020
*              THIS ROUTINE DETERMINES WHETHER THE ADDRESS IN THE     * 04360020
*        INPUT GPR - WKR6 - LIES IN ANY OF THE TRANSIENT AREAS. IF    * 04370020
*        IT DOES THE APPROPRIATE FLAG IS SET AND RETURN IS TO THE     * 04380020
*        ADDRESS IN GPR LABELED LINK.  IF IT DOES NOT, RETURN IS      * 04390020
*        MADE TO THE ADDRESS IN LINK PLUS FOUR.                       * 04400020
*********************************************************************** 04410020
*                                                                     * 04420020
MVSTG000 EQU   *                                                        04430020
         L     WKR6,FAIL1          GET ADDRESS OF ERROR LOCATION        04440020
         C     WKR6,CVTNUCB        IS ERROR IN NUCLEUS                  04450020
         BNL   MVSTG100            N/, PASS CONTROL TO PDAR 2           04460020
         OI    REPDAR4,NUC         INDICATE ERROR IN NUVLEUS            04470020
MVNU000  EQU   *                                                        04480020
         L     WKR2,CVTABEND       GET ADDR. OF SECONDARY CVT           04490020
         L     WKR2,K12(WKR2)      GET ADDR. OF TACT                    04500020
         L     WKR3,K4(WKR2)       GET NUMBER OF ENTRIES IN TACT        04510020
         LA    WKR2,K8(WKR2)       BUMP ADDR. TO FIRST TACT ENTRY       04520020
MVNU010  EQU   *                                                        04530020
         L     WKR4,K0(WKR2)       GET ADDR. OF TRANSIENT AREA          04540020
         LA    WKR4,K0(WKR4)       CLEAR HI-ORDER BYTE                  04550020
         LA    WKR5,K1024          GET LENGTH OF TRANSIENT AREA         04560020
         AR    WKR5,WKR4           FIND UPPER BOUND OF TRANS. AREA      04570020
MVNU020  EQU   *                                                        04580020
         CR    WKR6,WKR5           IS ERROR ABOVE TRANSIENT AREA        04590020
         BNL   MVNU050             YES, GO GET NEXT TRANS. AREA         04600020
         CR    WKR6,WKR4           IS ERROR BELOW TRANSIENT AREA        04610020
         BL    MVNU050             YES, GO GET NEXT TRANS. AREA         04620020
* ERROR IS FOUND TO BE IN A TRANSIENT AREA                              04630020
* SET UP FOR BRANCH TO MODULE LOADER                                    04640020
         OI    REPDAR4,SVCTRAN     INDICATE ERROR IN SVC TRANSIENT AREA 04650020
         CLI   K0(WKR2),X40        IS TAB BEING LOADED                  04660020
         BE    MVSTG100            YES CANNOT REFRESH                   04670020
         L     WKR3,CVTSVDCB       ADDR OF SVCLIB                       04680020
         L     WKR1,K44(WKR3)      PLACE ADDR OF DEB INTO REG 1         04690020
         MVC   TRCCW3+K1(K3),K1(WKR2) PLACE STARTING ADDR OF TRANSIENT  04700020
*                                     AREA INTO CCW                     04710020
         LA    WKR3,TRCCW1         PLACE ADDR OF CHANNEL PROGRAM        04720020
         ST    WKR3,MCHIOB+K16       INTO RMS IOB                       04730020
         LA    WKR3,TRCCW1         ADDR OF CHANNEL PROGRAM              04740020
         STH   WKR3,TRCCW2+K2      PLACE SEEK ADDR IN CCW               04750020
         SRL   WKR3,K16            SHIFT                                04760020
         STC   WKR3,TRCCW2+K1                                           04770020
         LA    WKR3,MCHIOBSK+K3    SEEK ADDR                            04780020
         STH   WKR3,TRCCW1+K2      PLACE SEEK ADDR IN CCW               04790020
         SRL   WKR3,K16                                                 04800020
         STC   WKR3,TRCCW1+K1                                           04810020
         MVC   MCHTTRIN(K3),K9(WKR2) PLACE TTR OF TRANSIENT SVC AREA    04820020
         LR    WKR3,RETURN         SAVE REG 14                          04830020
         LA    RETURN,TRIORET      RETURN POINT                         04840020
         LR    WKR10,WKR15         SET REG 10 TO CVT BASE               04850020
         L     WKR15,MCHLDADR      ENTRY POINT OF MOD LOADER ROUTINE    04860020
         BR    WKR15               EXIT NUC.                            04870020
         EJECT                                                          04880020
TRIORET  EQU   *                                                        04890020
* RETURN HERE IF I/O SUCESSFUL                                          04900020
         B     MVRETRY1            TRANSIENT SVC I/O SUCCESSFUL         04910020
* RETURN HERE IF I/O UNSUCESSFUL                                        04920020
         LR    RETURN,WKR3         RESTORE REG 14                       04930020
         B     MVSTG100            EXIT                                 04940020
MVNU050  EQU   *                                                        04950020
         BCT   WKR3,MVNU060        BRANCH IF NOT LAST TRANS. AREA       04960020
         L     WKR2,MCHERIOB       GET ADDR. OF IOB FOR THE ERROR       04970020
*                                  TRANSIENT AREA                       04980020
         L     WKR3,K16(WKR2)      GET ADDR. OF CHANNEL PROGM           04990020
         LA    WKR3,K0(WKR3)       CLEAR HI-ORDER BYTE                  05000020
         L     WKR4,K16(WKR3)      GET ADDR. OF ERROR TRANSIENT AREA    05010020
         LA    WKR4,K0(WKR4)       CLEAR HI-ORDER BYTE                  05020020
         LA    WKR5,K400           GET LENGTH OF ERROR TRANS. AREA      05030020
         AR    WKR5,WKR4           GET UPPER BOUND OF TRANS. AREA       05040020
         CR    WKR6,WKR5           IS ERROR ABOVE TRANSIENT AREA        05050020
         BNL   MVNU065             YES, ERROR NOT IN ANY TRANS. AREAS   05060020
         CR    WKR6,WKR4           IS ERROR BELOW TRANSIENT AREA        05070020
         BL    MVNU065             YES, ERROR NOT IN ANY TRANS. AREAS   05080020
         OI    REPDAR4,SVCTRAN     INDICATE ERROR IN TRANSIENT AREA     05090020
         OI    REPDAR4,X20         INDICATE ERROR IN ERROR TRANS. AREA  05092020
         MVC   MCHICCWS(K4),K16(WKR2) ADDR OF CHANNEL PGM TO RMSIOB     05100020
         MVC   MCHIODCB(K4),K20(WKR2) ADDR OF DCB TO RMSIOB             05110020
         MVC   MCHIOBSK(K8),K32(WKR2) ABSOLUTE TRACK ADDR TO RMSIOB     05120020
         L     WKR15,MCHEXCP       IOS INTERFACE ENTRYPOINT             05130020
         LR    WKR3,RETURN         SAVE REG 14                          05140020
         LA    RETURN,TRIORET      RETURN POINT                         05150020
         BR    WKR15               RETURN                               05160020
MVNU060  EQU   *                                                        05170020
         LA    WKR2,K16(WKR2)      GET ADDR. OF NEXT ENTRY IN TACT      05180020
         B     MVNU010             GO TO CHECK THIS ENTRY               05190020
MVNU065  EQU   *                                                        05200020
         B     MVSTG100            ERROR NOT IN ANY TRANSIENT AREA      05210020
MVSTG100 EQU   *                                                        05220020
         MVI   MCHNXMOD,K3         SUCCESSOR IS PDAR 2 INTERMITTENT     05230020
         B     MVEX000             EXIT                                 05240020
         EJECT                                                          05250020
MVRF000  EQU   *                                                        05260020
         TM    REPDAR1,WAITFAIL    IS WAIT IF REPAIR FAILS BIT ON       05270020
         BO    MVINT10             YES SYSTEM CANNOT CONTINUE           05280020
         B     MVINT31             NO PREPARE FOR ABEND                 05290020
MVSOL00  EQU   *                                                        05300020
         MVI   MCHNXMOD,K4         SUCCESSOR IS PDAR 3 SOLID HANDLER    05310020
         B     MVEX000             RETURN TO NUCLEUS                    05320020
ZERO     DC    D'0'                     DB WD ZERO                      05330020
X31      EQU   X'31'                                                    05340020
TRCCW1   CCW   X31,K0,X60,K5       SEARCH RECORD ID EQUAL               05350020
TRCCW2   CCW   K8,K0,X60,K1        TIC                                  05360020
TRCCW3   CCW   K6,K0,X20,K1024     READ                                 05370020
SAVE     DS    15F                 REGISTER DAVE AREA                   05380020
MVLINKB  DC    F'0'                LOWER BOUND OF PACK AREA             05390020
MAINTID  DC    CL8'IGFMVTF1'       CORE IDENTIFIER                      05422000
MAINT    DC    S(*)                MODULE DISPLACEMENT                  05424000
         DC    10CL4'&REL&LEV'     ADDITIONAL SPACE                     05426000
         EJECT                                                          05430020
         DS    0D                                                       05440020
NCOMAREA DSECT                                                          05450020
         MCHMAC                                                         05460020
DCOMAREA EQU   NCOMAREA                                                 05470020
FAIL1    EQU   REPDARF1                                                 05480020
FAIL2    EQU   REPDARF2                                                 05490020
         EJECT                                                          05500020
DCVT     DSECT                                                          05510020
         CVT                                                            05520020
         END                                                            05530020
