         LCLA  &LEV,&REL                                                00010421
&LEV     SETA  20                                                       00010821
&REL     SETA  21                                                       00011221
&REL&LEV TITLE 'IGFMVTF2 LEVEL &LEV PDAR 2 MVT '                        00011621
*********************************************************************** 00012020
*********************************************************************** 00014020
*              *                                      *                 00016020
*              *                                      *                 00018020
*TITLE   'IGFMVTF2(IGFMCHF2)'                                           00018420
*STATUS  CHANGE LEVEL=00     11/13/70                                 * 00018820
*FUNCTION/OPERATION  THE MVT SYSTEM ANALYSIS ROUTINE PERFORMS AN      * 00019220
*                   ANALYSIS OF DATA FROM THE MCH COMMON AREA AND     * 00019620
*                   DETERMINES THE IMPACT OF THE MACHINE CHECK ON THE * 00019720
*                   SYSTEM. IT READIES THE SYSTEM FOR ONE OF THE      * 00019820
*                   FOLLOWING RECOVERY PROCEDURES                       00019920
*                        A. REFRESHING A BLOCK OF CODE                * 00029620
*                        C. SETTING THE AFFECTED TASK NONDISPATCHABLE * 00030020
*                        D. TERMINATING THE ERROR-ASSOCIATED JOB STEP * 00040020
*                   IT MAY ALSO CORRECT DAMAGED SPF KEYS.             * 00050020
*ENTRY POINT   IGFMCHF2                                                 00060020
*INPUT   COMMON AREA                                                    00070020
*        (MCHPDAR)                                                      00070420
*OUTPUT  COMMON AREA                                                    00070820
*        (MCHPDAR,MCHTCB,MCHEXLEV,MCHNXMOD)                             00070920
*                                                                       00073920
*EXITS      (REFRESH/REPAIR VERIFICATION)                               00075920
*           (PDAR TERMINATION ANALYSIS)                                 00077920
*           (REFRESH LOADER)                                            00079920
*           (PDAR ANALYSIS 3)                                           00082420
*                                                                       00084420
*TABLES AND WORK AREAS   COMMUNICATION AREA                             00086420
*                              MCHTCB,MCHPDAR                           00086820
*EXTERNAL ROUTINES  NONE                                                00087220
*ATTRIBUTES    SERIALLY REUSEABLE,PRIVILEDGED                           00087320
*RESTRICTIONS  OPERATES ONLY IN A MVT SYSTEM                            00087420
*                                                                       00089420
*NOTES   MAINTENANCE SPACE                                              00089820
*        A DC OF 50 BYTES WITH THE LABEL                                00139820
*        *****MAINT*****                                                00149820
*                                                                       00159820
*              *                                      *                 00189820
*              *                                      *                 00239820
*********************************************************************** 00289820
IGFMVTF2 CSECT                                                          00339820
WKR0     EQU   0                   GENERAL REGISTER                     00420220
WKR1     EQU   1                   GENERAL REGISTER                     00429920
WKR2     EQU   2                   GENERAL REGISTER                     00439620
WKR3     EQU   3                   GENERAL REGISTER                     00449320
WKR4     EQU   4                   GENERAL REGISTER                     00459020
WKR5     EQU   5                   GENERAL REGISTER                     00468720
WKR6     EQU   6                   GENERAL REGISTER                     00478420
WKR7     EQU   7                   GENERAL REGISTER                     00488120
WKR8     EQU   8                   GENERAL REGISTER                     00497820
WKR9     EQU   9                   GENERAL REGISTER                     00507520
WKR10    EQU   10                  GENERAL REGISTER                     00517220
LINK     EQU   10                  GENERAL LINKING REGISTER             00526920
COMREG   EQU   11                  BASE FOR  RMS COMMON AREA            00536620
BASEREG  EQU   12                  MODULE BASE REG                      00546320
RETURN   EQU   14                  EXIT REG TO RMS NUCLEUS              00556020
WKR15    EQU   15                  GENERAL REGISTER                     00565720
         EJECT                                                          00575420
K0       EQU   0                   DECIMAL VALUE                        00585120
K1       EQU   1                                                        00594820
K2       EQU   2                   DECIMAL VALUE                        00604520
K3       EQU   3                   DECIMAL VALUE                        00614220
K4       EQU   4                   DECIMAL VALUE                        00623920
K5       EQU   5                   DECIMAL VALUE                        00633620
K6       EQU   6                   DECIMAL VALUE                        00643320
K8       EQU   8                   DECIMAL VALUE                        00653020
K9       EQU   9                   DECIMAL VALUE                        00662720
K10      EQU   10                  DECIMAL VALUE                        00672420
K11      EQU   11                  DECIMAL VALUE                        00682120
K12      EQU   12                  DECIMAL VALUE                        00691820
K13      EQU   13                  DECIMAL VALUE                        00701520
K16      EQU   16                  DECIMAL VALUE                        00711220
K14      EQU   14                                                       00720920
K17      EQU   17                  DECIMAL VALUE                        00730620
K20      EQU   20                  DECIMAL VALUE                        00740320
K21      EQU   21                  DECIMAL VALUE                        00750020
K22      EQU   22                                                       00759720
K24      EQU   24                  DECIMAL VALUE                        00769420
K28      EQU   28                  DECIMAL VALUE                        00779120
K31      EQU   31                  DECIMAL VALUE                        00788820
K32      EQU   32                  DECIMAL VALUE                        00798520
K33      EQU   33                  DECIMAL VALUE                        00808220
K40      EQU   40                  DECIMAL VALUE                        00817920
K44      EQU   44                  DECIMAL VALUE                        00827620
X1       EQU   1                                                        00837320
X5       EQU   5                                                        00847020
X0       EQU   0                                                        00856720
X07      EQU   X'07'                                                    00866420
X0F      EQU   X'0F'                                                    00876120
K240     EQU   240                                                      00885820
K7       EQU   7                                                        00895520
K56      EQU   56                  DECIMAL VALUE                        00905220
K100     EQU   100                 COUNTER FOR TIO LOOP                 00914920
K116     EQU   116                 DECIMAL VALUE                        00924620
K124     EQU   124                 DECIMAL VALUE                        00934320
K128     EQU   128                 DECIMAL VALUE                        00944020
K132     EQU   132                 DECIMAL VALUE                        00953720
K136     EQU   136                 DECIMAL VALUE                        00963420
K152     EQU   152                 DECIMAL VALUE                        00973120
K200     EQU   200                 DECIMAL VALUE                        00982820
K252     EQU   252                 DECIMAL VALUE                        00992520
K400     EQU   400                 DECIMAL VALUE                        01002220
K1024    EQU   1024                DECIMAL VALUE                        01011920
         EJECT                                                          01021620
*    HEX EQUATES                                                        01031320
X01      EQU   X'01'               HEXADECIMAL VALUE                    01041020
X02      EQU   X'02'               HEXADECIMAL VALUE                    01050720
X04      EQU   X'04'               HEXADECIMAL VALUE                    01060420
X08      EQU   X'08'               HEXADECIMAL VALUE                    01070120
X10      EQU   X'10'                                                    01079820
X0D      EQU   X'0D'               HEXADECIMAL VALUE                    01089520
X0E      EQU   X'0E'               HEXADECIMAL VALUE                    01099220
X20      EQU   X'20'               HEXADECIMAL VALUE                    01108920
X24      EQU   X'24'               HEXADECIMAL VALUE                    01118620
X28      EQU   X'28'               HEXADECIMAL VALUE                    01128320
X31      EQU   X'31'                                                    01138020
X40      EQU   X'40'               HEXADECIMAL VALUE                    01147720
X4A      EQU   X'4A'               HEXADECIMAL VALUE                    01157420
X52      EQU   X'52'               HEXADECIMAL VALUE                    01167120
X60      EQU   X'60'               HEXADECIMAL VALUE                    01176820
X7F      EQU   X'7F'               HEXADECIMAL VALUE                    01186520
X80      EQU   X'80'               HEXADECIMAL VALUE                    01196220
XBF      EQU   X'BF'               HEXADECIMAL VALUE                    01205920
XFF      EQU   X'FF'               HEXADECIMAL VALUE                    01215620
SEEK     EQU   X'07'               SEEK COMMAND                         01225320
RDR0     EQU   X'16'               READ RECORD ZERO COMMAND             01235020
SRCH     EQU   X'31'               SEARCH ID EQUAL COMMAND              01244720
TIC      EQU   X'08'               TRANSFER IN CHANNEL COMMAND          01254420
READDATA EQU   X'06'               READ DATA COMMAND                    01264120
SENSE    EQU   X'04'               SENSE COMMAND                        01273820
SCATLOAD EQU   X'80'               SCATTER LOAD FORMAT FLAG             01283520
TCBFRO   EQU   X'10'                                                    01293220
MVCSW    EQU   X'40'               ADDRESS OF CHANNEL STATUS WORD       01302920
MVCAW    EQU   X'48'               ADDRESS OF CHANNEL ADDRESS WORD      01312620
QUADBRY  EQU    X'0F'              QUAD WORD BOUNDRY                    01322320
         EJECT                                                          01332020
*   DEFINITION OF REPDAR1                                             * 01341720
TERM     EQU   X'80'                                                    01351420
RF       EQU   X'40'               RETRY FAILED                         01361120
RP       EQU   X'20'               RETRY POSSIBLE                       01370820
II       EQU   X'10'               IC IND                               01380520
INSTR    EQU   X'08'               INSTR                                01390220
OPERAND  EQU   X'04'               OPERAND                              01399920
WAITFAIL EQU   X'02'               WAIT IF REPAIR FAILS                 01409620
INHIBTRM EQU   X'01'               INHIBIT TERM                         01419320
*   DEFINITION OF REPDAR2                                             * 01429020
SOLSTG   EQU   X'80'               SOLID STG                            01438720
INTSTG   EQU   X'40'               INT STG                              01448420
SOLSPF   EQU   X'20'               SOLID SPF                            01458120
INTSPF   EQU   X'10'               INT SPF                              01467820
REPAIR   EQU   X'08'               REP                                  01477520
STGCLR   EQU   X'04'               CLEARED                              01487220
BLOCK    EQU   X'02'               BLOCK STORAGE FAILURE                01496920
UNIT     EQU   X'01'               UNIT STORAGE FAILURE                 01506620
*   DEFINITION OF REPDAR3                                             * 01516320
TCBWAIT  EQU   X'80'               WAIT                                 01526020
TCBMS    EQU   X'40'               MAST SCHED                           01535720
TCBSYS   EQU   X'20'               SYS                                  01545420
TCBPP    EQU   X'10'               P/P                                  01555120
IODSBL   EQU   X'08'               IO DISABLED                          01564820
*   DEFINITION OF REPDAR4                                             * 01574520
NUC      EQU   X'80'                                                    01584220
SVCTRAN  EQU   X'40'                                                    01593920
ERRTRAN  EQU   X'20'                                                    01603620
NUCCSECT EQU   X'10'                                                    01613320
DYNAMIC  EQU   X'08'                                                    01623020
LINKPACK EQU   X'04'                                                    01632720
RESSVC3  EQU   X'02'                                                    01642420
BLDLTAB  EQU   X'01'                                                    01652120
*   DEFINITION OF REPDAR5                                             * 01661820
*   DEFINITION OF REPDAR6                                             * 01671520
MSGCODE0 EQU   X'80'                                                    01681220
MSGCODE1 EQU   X'40'                                                    01690920
MSGCODE2 EQU   X'20'                                                    01700620
MSGCODE3 EQU   X'10'                                                    01710320
MSGCODE4 EQU   X'08'                                                    01720020
LEVEL    EQU   X'&LEV'                                                  01729021
         EJECT                                                          01739420
MVIN000  EQU   *                                                        01749120
         USING *,WKR15             MODULE ADDRESSABILITY                01758820
*  THIS SECTION OF CODE WILL BE OVERLAID AND USED AS A BUFFER FOR       01768520
*        READING IN THE CHECKSUM BLOCKS OFF THE ASRLIB   240 BYTES      01778220
READBUF  EQU   *                                                        01787920
         USING DCOMAREA,COMREG                                          01797620
         STM   WKR10,WKR15,SAVE    SAVE REGS                            01807320
         DROP  WKR15                                                    01817020
         LR    BASEREG,WKR15       BASE REG                             01826720
         USING MVIN000,BASEREG     ADDRESSABILITY                       01836420
         USING DCVT,WKR15          SET UP BASE FOR CVT DSECT            01846120
         L     WKR15,MCHCVT        SET UP BASE FOR CVT DSECT            01855820
         MVI   MCHEXLEV,LEVEL      MODULE LEVEL                         01865521
         L     WKR2,CVTTCBP        GET PTR TO NEW AND CURRENT TCB PYRS  01875220
         L     WKR2,K4(WKR2)       GET PTR TO CURRENT TCB               01884920
         ST    WKR2,MVCURTCB       SAVE CURRENT TCB ADDRESS             01894620
         ST    WKR2,MCHTCB         SAVE ADDR OF CURRENT TCB             01904320
         L     WKR2,CVTHEAD        ADDR OF FIRST TRANSIENT TCB          01914020
         L     WKR5,K132(WKR2)     ADDR OF MOTHER TCB                   01923720
         L     WKR6,K132(WKR5)     MOTHER TCB-OTC FIELD                 01933420
         LTR   WKR6,WKR6           IF ZERO, YES MASTER SCHD             01943120
         BNE   MVINT10             IF NOT ERROR TERM                    01952820
         L     WKR6,K152(WKR5)     MASTER SCHED TO DUMMY PQE            01962520
         L     WKR6,K8(WKR6)       DUMMY PQE TO PQE                     01972220
         L     WKR6,K24(WKR6)      PQE TO START OF SUPVR                01981920
         ST    WKR6,MVLINKB        LOWER BOUND OF SUPVR CORE            01991620
         TM    REPDAR4,SVCTRAN     IS ERROR IN A TRANSIENT AREA         02001320
         BO    MVSTG125            YES, EXIT                            02011020
         B     MVSTG000            CONTINUE                             02020720
*                                                                     * 02030420
*********************************************************************** 02040120
*              THIS ROUTINE DETERMINES WHETHER THE ADDRESS IN THE     * 02050020
*        INPUT GPR - WKR6 - LIES IN THE BLDL TABLE.  IF IT DOES,      * 02060020
*        THE APPROPRIATE FLAG IS SET AND RETURN IS TO THE ADDRESS     * 02070020
*        IN GRP LABELED LINK PLUS FOUR.  IF IT DOES NOT, RETURN       * 02070121
*        IS MADE TO THE ADDRESS IN LINK                               * 02070221
*********************************************************************** 02070321
*                                                                     * 02070421
         SPACE  2                                                       02070521
MVNU100  EQU   *                                                        02070621
         MVI   SVCSW,X0            CLEAR SWITCH                SVCBLDL  02070721
         L     WKR2,MCHBLDL        GET LINKLIB BLDL ADDR       SVCBLDL  02070821
CLEAR     EQU  *                                                        02070921
         LA    WKR2,K0(WKR2)       CLEAR HI ORDER BYTE         SVCBLDL  02071021
         LTR   WKR2,WKR2           ANY BLDL TABLE               SVCBLDL 02071121
         BP    BUILD1              YES,SEE IF ERROR IS HERE     SVCBLDL 02071221
CKSVC    EQU   *                                                        02071321
         TM    SVCSW,XFF           HAS SVC BLDL TABLE BEEN CHECKED      02071421
         BO    K0(LINK)            ERROR IS NOT IN EITHER TABLE SVCBLDL 02071521
         L     WKR2,MCHSVCBL       GET ADDR OF SVC BLDL TAB     SVCBLDL 02071621
         OI    SVCSW,XFF           TURN ON SVC SWITCH           SVCBLDL 02071721
         B     CLEAR               CHECK IF TABLE EXISTS        SVCBLDL 02071821
BUILD1   EQU   *                                                        02071921
         CR    WKR6,WKR2           IS THE ERROR BELOW BLDL TAB  SVCBLDL 02072021
         BL    CKSVC               YES, GO SEE IF BOTH TABS CKECKED     02072121
         LA    WKR7,K4(WKR2)       GET ADDRESS OF FIRST ENTRY   SVCBLDL 02072221
         LR    WKR5,WKR7           SAVE THIS ADDRESS            SVCBLDL 02072321
         CR    WKR6,WKR7           IS ERROR IN FIRST 4 BYTES    SVCBLDL 02072421
         BL    BUILD2              YES,GO DELETE THE TABLE      SVCBLDL 02072521
         LH    WKR7,K0(WKR2)       GET NUMBER OF ENTRIES IN TAB SVCBLDL 02072621
         MH    WKR7,K2(WKR2)       MULTIPLY BY LENGHT OF EACH ENTRY     02072721
         LA    WKR7,K4(WKR7)       NOW HAVE TOTAL LENGTH OF TAB SVCBLDL 02072821
         AR    WKR7,WKR2           REG 7 HAS END OF TABLE       SVCBLDL 02072921
         CR    WKR6,WKR7           IS THE ERROR IN THE TABLE    SVCBLDL 02073021
         BNL   CKSVC               NO, SEE IF BOTH TABS CHECKED SVCBLDL 02073121
BUILD2   EQU   *                                                        02073221
         STM   WKR2,WKR3,K0(WKR6)  CLEAR THE BAD DATA           SVCBLDL 02073321
BUILD2A  EQU   *                                                        02073421
         TM    SVCSW,XFF           ERROR IN SVCTABLE            SVCBLDL 02073521
         BNO   BUILD3              NO,ERROR IS IN LINKTAB       SVCBLDL 02073621
         LA    WKR8,K32            SET LENGTH OF ENTRY TO 32    SVCBLDL 02073721
         B     BUILD4A             GO SET INTO TABLE            SVCBLDL 02073821
BUILD3   EQU   *                                                        02073921
         LA    WKR8,K56            SET LENGTH OF ENTRY TO 56    SVCBLDL 02074021
BUILD4A  EQU   *                                                        02074121
         ST    WKR8,K0(WKR2)       SET LENGTH IN TABLE          SVCBLDL 02074221
         LA    WKR8,K1             SET NUMBER OF ENTRIES        SVCBLDL 02074321
         STH   WKR8,K0(WKR2)       PUT THIS INTO THE TABLE      SVCBLDL 02074421
         XC    K4(K14,WKR2),K4(WKR2)  ZERO THIS ENTRY           SVCBLDL 02074521
         OI    REPDAR4,BLDLTAB     SET ERROR IN BLDL TAB BIT    SVCBLDL 02074621
         CR    WKR6,WKR5           SEE IF ERROR IN BEGIN OF TAB         02074721
         BL    K4(LINK)            IF YES ERROR IS NOT IN TWO TABS      02074821
         C     WKR7,FAIL2          GET ENDING FAILING ADDR      SVCBLDL 02074921
         BNL   K4(LINK)            ERROR DOES NOT CROSS TABS    SVCBLDL 02075021
         OI    REPDAR6,K12         INDICATE ERROR IN BOTH TABS  SVCBLDL 02075121
         XI    SVCSW,XFF           FLIP THE SWITCH              SVCBLDL 02075221
         LR    WKR2,WKR7           R2 POINTS TO NEXT TABLE      SVCBLDL 02075321
         L     WKR7,FAIL2          SET REG TO END LOOP          SVCBLDL 02075421
         B     BUILD2A             DELETE THIS TABLE            SVCBLDL 02075521
         EJECT                                                          02321420
MVSTG200 EQU   *                                                        02331120
         C     WKR6,MVLINKB        IS ERROR IN LINK PACK AREA           02340820
         BL    MVSTG300            NO  ONLY DYNAMIC AREA LEFT           02350520
         OI    REPDAR4,LINKPACK    ERROR IN LINK PACK AREA              02360220
*   CALL FOR SEARCH OF BLDL TABLE                                     * 02369920
         BAL   LINK,MVNU100        CHECK BLDL TABLE FOR ERROR           02379620
         B     MVSTG100            GO CHECK REFRESHABLE VIA CHECK SUM   02408720
MVSTG230 EQU   *                                                        02418420
         TM    REPDAR3,IODSBL      IS CURRENT PSW DISABLED              02428120
         BO    MVINT10             YES  CANNOT CONTINUE                 02437820
         B     MVINT31             NO  PREPARE FOR ABEND                02447520
         EJECT                                                          02457220
MVSTG300 EQU   *                                                        02466920
         OI    REPDAR4,DYNAMIC     INDICATE ERROR IN DYNAMIC AREA       02476620
         TM    REPDAR1,RP          IS RETRY POSSIBLE                    02486320
         BNO   MVSTG310            BRANCH TO RESTORE GOOD DATA          02496020
         TM    REPDAR7,X80         IS P/P REFRESH SUPPORTED             02505720
         BO    TRYREFR             YES, SCHEDULE P/P REFRESH LOADER     02515420
MVSTG310 EQU   *                                                        02525120
         TM    REPDAR3,X08         IS CURRENT PSW DISABLED              02534820
         BO    MVINT10             YES, CONTINUE TESTING                02544520
         L     WKR6,FAIL1          ADDR OF ERROR LOC                    02554220
         STM   WKR2,WKR5,K0(WKR6)  CORRECT BAD DATA                     02563920
         B     MVINT31             ABEND                                02573620
TRYREFR  EQU   *                                                        02583320
         MVI   MCHNXMOD,K3         SCHEDULE P P REFRESH LOADER          02593020
         B     MVEX000             EXIT                                 02602720
         EJECT                                                          02612420
CHKSUM   EQU   *                                                        02622120
         LH    WKR7,QUADMASK       GET MASK FOR AND                     02631820
         LM    WKR2,WKR3,REPDARF1  GET BOUND OF ERROR LOCATION          02641520
         SR    WKR3,WKR2           COMPUTE SIZE OF ERROR AREA           02651220
         LA    WKR9,K16            QUADWORD VALUE TO REG                02660920
         CR    WKR3,WKR9           COMPARE FOR GREATER THAN A QUADWORD  02670620
         BH    NOREFR              YES - CANNOT APPLY CHECKSUM          02680320
         NR    WKR2,WKR7           GET QUADWORD BOUNDARY                02690020
         LA    WKR2,K16(WKR2)      BUMP TO NEXT QUADWORD                02699720
         C     WKR2,REPDARF2       DOES END OF ERROR OVERLAP INTO THE   02709420
*                                  NEXT QUADWORD                        02719120
         BL    NOREFR              YES--CANNOT APPLY CHECKSUM           02728820
         SR    WKR9,WKR9           CLEAR REG                            02738520
         IC    WKR9,MCHASRNO       GET NO. OF CHECKSUM RECORDS          02748220
         LTR   WKR9,WKR9           ANY CHECKSUMS RECORDS                02757920
         BZ    NOREFR              NO  NOT REFRESHABLE                  02767620
         MVC   MCHIOBSK+K3(K4),MCHSTEXT MMOVE ABSOLUTE ADDR             02777320
         MVC   MCHIOBSK+K7(K1),MCHASRTR    RECORD                       02787020
READ     EQU   *                                                        02796720
         B     ASRREAD             READ ASR RECORD                      02806420
RDOK     EQU   *                                                        02816120
         LR    RETURN,WKR3         RESTORE REG                          02825820
         L     WKR15,MCHCVT        RESTORE CVT BASE                     02835520
         LA    WKR2,K10            INIT TO NO. OF ENTRIES PER ASR-RECRD 02845220
         LA    WKR4,READBUF        INIT TO FIRST ENTRY IN ASR-RECORD    02854920
         L     WKR5,REPDARF1       GET FAILING ADDRESS                  02864620
**  ASSUME 'REG5' CONTAINS ADDR OF FAILING LOCATION                  ** 02874320
COMPLOOP EQU   *                                                        02884020
         C     WKR5,K0(WKR4)       ABOVE LOWER BOUND OF REFRESH AREA    02893720
         BL    INCREMEN            NO                                   02903420
         C     WKR5,K4(WKR4)       BELOW UPPER BOUND OF REFRESH AREA    02913120
         BL    REFRESH             YES,  AREA IS REPAIRABLE             02922820
INCREMEN EQU   *                                                        02932520
         LA    WKR4,K24(WKR4)      BUMP TO NEXT SET OF ADDRESSES        02942220
         BCT   WKR2,COMPLOOP       CONTINUE                             02951920
         LA    WKR6,K10            NO. OF ENTRIES PRE ASR-RECORD        02961620
         SR    WKR9,WKR6           DECREMENT NO. OF ENTRIES             02971320
         LTR   WKR9,WKR9           TEST REG                             02981020
         BP    READ                BRANCH POSITIVE                      02990720
         BR    LINK                AREA IS NOT REPAIRABLE               03000420
         EJECT                                                          03010120
REFRESH  EQU   *                                                        03019820
         SR    WKR0,WKR0           CLEAR                                03029520
         SR    WKR1,WKR1                 REGS                           03039220
         SR    WKR2,WKR2                      FOR                       03048920
         SR    WKR3,WKR3                          STORE                 03058620
         N     WKR5,CLEAR8         GET DOUBLEWORD BOUNDARY              03068320
         TM    K3(WKR4),X08        IS REFR AREA ON DOUBLEWORD           03078020
         BNO   TESTEND             NO                                   03087720
         C     WKR5,K0(WKR4)       GET DOUBLEWORD BOUNDARY              03097420
         BNE   TESTEND             NO                                   03107120
         OI    REPDAR7,X40         SET BOUNDARY INDICATOR               03116820
         STM   WKR0,WKR1,K0(WKR5)  CLEAR DBLWD ONLY                     03126520
         B     COMPUTE             GO TO COMPUTE ERROR CHECKSUM         03136220
TESTEND  EQU   *                                                        03145920
         TM    K7(WKR4),X08        IS REFR AREA ENDING ON DBLWD         03155620
         BNO   CLEARALL            NO, CLEAR WHOLE QUADWORD             03165320
         L     WKR6,K4(WKR4)       GET ENDING ADDR OF REFR AREA         03175020
         NR    WKR6,WKR7           GET QUADWORD BOUNDARY                03184720
         CR    WKR5,WKR6           IS ERROR IN LAST DBLWD               03194420
         BNE   CLEARALL            NO                                   03204120
         OI    REPDAR7,X20         SET INDICATOR                        03213820
         STM   WKR0,WKR1,K0(WKR5)  CLEAR DBLWD ONLY                     03223520
         B     COMPUTE             GO COMPUTE CHECKSUM                  03233220
CLEARALL EQU   *                                                        03242920
         NR    WKR5,WKR7           GET QUADWORD BOUNDARY                03252620
         STM   WKR0,WKR3,K0(WKR5)  CLEAR QUADWORD                       03262320
COMPUTE  EQU   *                                                        03272020
         XC    CHEKSUM(K16),CHEKSUM INIT. TO ZERO                       03281720
         LM    WKR2,WKR3,K0(WKR4)  GET BOUNDS OF REFR AREA              03291420
         NR    WKR2,WKR7           GET QUADWORD BOUNDARY                03301120
         NR    WKR3,WKR7           GET QUADWORD BOUNDARY                03310820
         TM    K3(WKR4),X08        DBLWD BOUNDARY                       03320520
         BO    SKIP1               YES,BRANCH                           03330220
         XC    CHEKSUM(K8),K0(WKR2) CHECKSUM 1ST DBLWD                  03339920
SKIP1    EQU   *                                                        03349620
         XC    CHEKSUM+K8(K8),K8(WKR2) CHECKSUM 2ND DBLWD               03359320
         TM    K7(WKR4),X08        IS END OF AREA ON DBLWD              03369020
         BNO   SKIP2               NO, BRANCH                           03378720
         XC    CHEKSUM(K8),K0(WKR3) CHECKSUM LAST DBLWD                 03388420
SKIP2    EQU   *                                                        03398120
         LA    WKR2,K16(WKR2)      BUMP TO NEXT QUADWORD                03407820
         SR    WKR3,WKR2           COMPUTE SIZE                         03417520
         SRL   WKR3,K4             COMPUTE NUMBER OF QUADWORDS          03427220
         LTR   WKR3,WKR3           END OF QUADWORD                      03436920
         BZ    CHKLOOP2            IF YES, BRANCH AND MOVE IN LOCATION  03446620
CHEKLOOP EQU   *                                                        03456320
         XC    CHEKSUM(K16),K0(WKR2) CHECKSUM BITS IN THIS QUADWORD     03466020
         LA    WKR2,K16(WKR2)      BUMP ADDRESS                         03475720
         BCT   WKR3,CHEKLOOP       CONTINUE UNTIL ALL QUADWORDS DONE    03485420
CHKLOOP2 EQU   *                                                        03495120
         XC    CHEKSUM(K16),K8(WKR4)    SET CHECKSUM CVALUE             03504820
         TM    REPDAR7,X40         CORRECTION IN 1ST DBLWD ONLY         03514520
         BO    SKIP6               YES                                  03524220
         MVC   K0(K8,WKR5),CHEKSUM CORRECT LOCATION                     03533920
SKIP4    EQU   *                                                        03543620
         TM    REPDAR7,X20         CORRECTION IN LAST DBLWD ONLY        03553320
         BO    SKIP5               YES                                  03563020
         MVC   K8(K8,WKR5),CHEKSUM+K8 CORRECT LOCATION                  03572720
SKIP5    EQU   *                                                        03582420
         B     MVRETRY1            SCHEDULE REFRESH REPAIR VERIFY       03592120
SKIP6    MVC   K0(K8,WKR5),CHEKSUM+8    CORRECT LOCATION                03601820
         B     MVRETRY1            SCHEDULE REFRESH REPAIR VERIFY       03611520
NOREFR   EQU   *                                                        03621220
         BR    LINK                RETURN, NOT REFRESHABLE              03630920
*     SET UP FOR CHECKSUM READS                                         03640620
ASRREAD  EQU   *                                                        03650320
         CLI   UPDSW,X0            UPDATE  SWITCH ZERO                  03660020
         BE    SETUPDSW            YES, BRANCH                          03670020
         SR    WKR6,WKR6           ZERO REG                             03680020
         IC    WKR6,MCHIOBSK+K7    GET RECORD V VALUE                   03700020
         LA    WKR6,1(WKR6)           UPDATE TO NEXT RECORD             03710020
         STC   WKR6,MCHIOBSK+K7    RESTORE UPDATED VALUE                03720020
READRET  EQU   *                                                        03730020
         LA    WKR3,READBUF        ADDR OF READ IN BUFFER               03740020
         ST    WKR3,CHKSCCW2       PLACE ADDR INTO CHANNEL PGM          03750020
         MVI   CHKSCCW2,K6         COMMAND CODE                         03760020
         LA    WKR1,MCHIOB         ADDR OF RMS UOB                      03770020
         LA    WKR4,MCHDEB         ADDR OF RMS DEB                      03780020
         ST    WKR4,MCHDCB+K44     PLACE ADDR OF RMSDEB INTO DCB        03790020
         LA    WKR6,MCHDCB         ADDR OF RMS DCB                      03800020
         ST    WKR6,MCHDEDCB       PLACE INTO RMSDEDCB                  03810020
         MVI   MCHDEDCB,X0F                                             03820020
         ST    WKR6,MCHIODCB       STORE DCB ADDRESS IN IOB             03830020
         MVC   MCHUCB+K1(K3),MCHDEBXT+K1   GET UCB ADDRESS              03840020
         LA    WKR3,CHKSMCCW       ADDR OF CHANNEL PROGRAM              03850020
         ST    WKR3,MCHIOB+K16     STORE IN RMS IOB                     03860020
         MVC   CHKSCCW1+K1(K3),MCHIOB+K17   ADDR OF CHANNEL PGM         03870020
         LA    WKR3,MCHIOBSK+K3    SEEK ADDR                            03880020
         ST    WKR3,CHKSMCCW        INTO CHANNEL PGM                    03890020
         MVI   CHKSMCCW,X31        COMMAND CODE                         03900020
         LR    WKR3,RETURN         SAVE REG                             03910020
         L     WKR15,MCHEXCP       ENTRY POINT ADDRESS                  03920020
         BALR  RETURN,WKR15        EXIT TO MODULE LOADER                03930020
* RETURN HERE IF I/O WAS SUCCESSFUL                                     03940020
         B     RDOK                READ WAS SUCESSFUL                   03950020
* RETURN HERE IF I/O WAS NOT SUCESSFUL                                  03960020
         LR    RETURN,WKR3         RESTORE REG                          03970020
         L     WKR15,MCHCVT        RESTORE CVT BASE                     03980020
         B     MVSTG125            RETURN, NOT REFRESHABLE              03990020
SETUPDSW EQU   *                                                        04000020
         MVI   UPDSW,K1            SET UPDATE SWITCH                    04010020
         B     READRET             RETURN                               04020020
         EJECT                                                          04030020
MVINT10  EQU   *                                                        04040020
         TM    REPDAR1,INHIBTRM    IS INHIBIT TERMINATION REQUESTED     04050020
         BO    MVINT15             YES, SKIP TERMINATION PROCEDURES     04060020
         OI    REPDAR6,MSGCODE1    UNRETRYABLE SUPERVISOR ERROR MSG.    04070020
MVINT15  EQU   *                                                        04080020
         MVI   MCHNXMOD,K2         SUCCESSOR IS PDAR TERM               04090020
MVEX000  EQU   *                                                        04100020
         LM    WKR10,WKR15,SAVE     RESTORE REGS                        04110020
         BR    RETURN              RETURN TO NUCLEUS                    04120020
MVINT31  EQU   *                                                        04130020
         TM    REPDAR1,INHIBTRM    IS INHIBIT TERMINATION REQUESTED     04140020
         BO    MVINT15             YES, SKIP TERMINATION PROCEDURES     04150020
         TM    REPDAR3,TCBWAIT     IS WAIT PSEUDO TCB CURRENT           04160020
         BO    MVINT10             YES  CANNOT ABEND                    04170020
         TM    REPDAR4,BLDLTAB     IS ERROR IN BLDL TABLE               04180020
         BNO   MVINT33             NO  REGULAR ABEND                    04190020
         TM    SVCSW,XFF            IS ERROR IS SVC BLDL TABLE SVCBLDL  04191021
         BO    SETSVC               YES,SCHEDULE SVC BLDL MSG   SVCBLDL 04192021
         OI    REPDAR6,MSGCODE4     NO,SCHEDULE LINKLIB BLDL MSG        04193021
         B     MVINT15              SCHEDULE TERMINATION        SVCBLDL 04194021
SETSVC   EQU   *                                                        04195021
         OI    REPDAR6,X04          SCHEDULE  SVC DLTED MESSAGE SVCBLDL 04196021
         B     MVINT15              GO SCHEDULE TERMINTATION            04197021
MVINT33  EQU   *                                                        04220020
         OI    REPDAR6,MSGCODE3    TASK ABEND MESSAGE REQUIRED          04230020
         MVI   MCHNXMOD,K5         SUBSYSTEM ANALYSIS                   04233020
         B     MVEX000             EXIT                                 04236020
MVRETRY1 EQU   *                                                        04260020
         OI    MCHDAMAG+K3,X10         SET REFRESH FLAG                 04270020
         TM    REPDAR1,RP          IS RETRY POSSIBLE                    04280020
         BNO   MVINT31             NO, GO TO ABEND TASK                 04290020
         MVI   MCHNXMOD,K1         SET REFRESH REPAIR VERIFY SUCCESSOR  04300020
         B     MVEX000             RETURN TO NUC                        04310020
         EJECT                                                          04320020
MVSTG000 EQU   *                                                        04330020
         L     WKR6,FAIL1          GET ADDRESS OF ERROR LOCATION        04340020
         C     WKR6,CVTNUCB        IS ERROR IN NUCLEUS                  04350020
         BNL   MVSTG200            NO                                   04360020
         OI    REPDAR4,NUC         INDICATE ERROR IN NUCLEUS            04370020
MVSTG100 EQU   *                                                        04380020
         BAL   LINK,CHKSUM         GO CHECK REFRESHABLE VIA CHECK SUM   04390020
*  RETURN IS HERE IF NOT REFRESHABLE                                    04400020
MVSTG125 EQU   *                                                        04410020
         TM    REPDAR2,STGCLR      HAS ERROR LOCATION BEEN CLEARED      04420020
         BO    MVINT10             YES  CANNOT CONTINUE                 04430020
         TM    REPDAR3,IODSBL      CURRENT PSW DISABLED FOR I/O         04440020
         BO    MVINT10             YES CANNOT CONTINUE                  04450020
         TM    REPDAR1,INSTR       IS ADDRESS PERTAINING TO INSTRUCTION 04460020
         BO    MVINT10                 YES-PUT SYSTEM DOWN         VPTM 04470020
*   NO - IT PERTAINS TO THE OPERAND                                   * 04480020
         L     WKR6,REPDARI        GET INSTRUCTION COUNTER              04490020
         C     WKR6,CVTNUCB        IS IC IN NUCLEUS                     04500020
         BL    MVINT10                 YES-PUT SYSTEM DOWN         VPTM 04510020
         C     WKR6,MVLINKB        IS IC IN LINK PACK AREA              04520020
         BNL   MVINT10                 YES-PUT SYSTEM DOWN         VPTM 04530020
         B     MVINT31             GO TO ABEND OF TASK PREPARATION      04540020
         EJECT                                                          04620020
CHEKSUM  DC    4F'0'               CHECKSUM WORK AREA                   04630020
CHKSMCCW CCW   X31,K0,X60,K5       SEARCH RECORD ID EQUAL               04640020
CHKSCCW1 CCW   K8,K0,X60,K1        TIC                                  04650020
CHKSCCW2 CCW   K6,K0,X20,K240      READ                                 04660020
SAVE     DS    6F                  REGISTER SAVE AREA                   04670020
MVLINKB  DC    F'0'                LOWER BOUND OF PACK AREA             04680020
MVCURTCB DC    F'0'                ADDRESS OF CURRENT TCB               04690020
CLEAR8   DC    X'FFFFFFF8'         MASK                                 04700020
QUADMASK DC    X'FFF0'             MASK                                 04710020
UPDSW    DC    X'00'               FLAG                                 04720020
SVCSW    DC    X'00'                SVC BLDL SWITCH             SVCBLDL 04730021
NCOMAREA DSECT                                                          04740020
         MCHMAC                                                         04750020
DCOMAREA EQU   NCOMAREA                                                 04760020
FAIL1    EQU   REPDARF1                                                 04770020
FAIL2    EQU   REPDARF2                                                 04780020
DCVT     DSECT                                                          04790020
         CVT                                                            04800020
         END                                                            04810020
