LOADER   START                                                          01000019
         TITLE 'Q DUMP LOADER'                                          02000019
*********************************************************************** 02010019
*                                                                     * 02020019
*  MODULE:  IMCJQLDR                                                  * 02030019
*                                                                     * 02040019
*  STATUS:  OS/360 SERVICE AID PROGRAM                                * 02050019
*           R19 PID VERSION                                           * 02060019
*                                                                     * 02070019
* C 025400,028000-028280,510000,530000-540000,570000,            S21016 02070421
* C 620500-621500                                                S21016 02070821
*                                                                     * 02072021
*  FUNCTION:  IMCJQLDR IS THE LOADER PROGRAM FOR THE STAND-ALONE JOB  * 02080019
*        QUEUE DUMP IMCJQDMP.  THIS MODULE CONTAINS IPL TEXT, TWO     * 02090019
*        ADDITIONAL BOOTSTRAP CCW'S AND A LOADING PROCEDURE FOR THE   * 02100019
*        TWO MAIN MODULES OF IMCJQDMP.  THESE MODULES ARE LOADED IN   * 02110019
*        OBJECT MODULE FORM WITH ASSEMBLER CONTROL INFO. STRIPPED OFF * 02120019
*        AT LOAD TIME.  LOAD POINTS ARE TAKEN FROM LOCATION COUNTER   * 02130019
*        VALUE ON EACH OBJ CARD.                                      * 02140019
*             THE LOADER BUILDS A LIST OF ENTRY POINT ADDRESSES OF    * 02150019
*        THE LOADED MODULES TO PROVIDE A COMMUNICATION LINK BETWEEN   * 02160019
*        THE MODULES.  WHEN LOADING IS COMPLETE, CONTROL IS PASSED    * 02170019
*        VIA BRANCH AND LINK TO THE FIRST MODULE LOADED.         S21016 02180021
*                                   *****                        S21016 02190021
*        ON RETURN TO THE LOADER, THE CONTENT OF REG. 15 IS STORED IN * 02200019
*        THE INSTRUCTION ADDRESS FIELD OF A WAIT PSW AND THIS PSW     * 02210019
*        LOADED.  THE RETURN CODE VALUE MAY THEN BE DISPLAYED FROM    * 02220019
*        THE MAINTENANCE CONSOLE.                                     * 02230019
*                                                                     * 02240019
*  ENTRY POINTS:                                                      * 02250019
*                                                                     * 02260019
*        I/O - IPL CCW'S CONSIST OF A READ COMMAND CHAINED TO A TIC   * 02270019
*              TO CARD JUST READ, TWO SUBSEQUENT READ CCW'S BEGIN     * 02280019
*              THIS CARD.  THE LOADER WHICH SPANS THREE CARDS IS      * 02290019
*              BROUGHT INTO MAIN STORAGE BY THE OS/360 IPL I/O.       * 02300019
*              THE LOADER IS IN MACHINE EXECUTABLE CODE.              * 02310019
*                                                                     * 02320019
*        EXECUTABLE CODE:  THE IPL PSW CAUSES THE LOADER PROPER TO    * 02330019
*              GAIN CONTROL WHICH THEN PROCEDES TO LOAD THE QDUMP     * 02340019
*              MODULES.                                               * 02350019
*                                                                     * 02360019
*  INPUT:  INPUT TO THE LOADER ARE THE TWO MAIN MODULES OF IMCJQDMP   * 02370019
*        IN OBJECT MODULE FORM.                                       * 02380019
*                                                                     * 02390019
*  OUTPUT:  THE ASSEMBLER CONTROL INFO. IS STRIPPED FROM EACH OBJ     * 02400019
*        CARD AND THE TEXT PORTION IS LOADED INTO MAIN STORAGE AT THE * 02410019
*        ADDRESS GIVEN BY THE LOCATION COUNTER VALUE.                 * 02420019
*             ON EXIT TO THE LAST LOADED MODULE, REG 1 IS SET         * 02430019
*        POINTING TO THE ENTRY POINT LIST OF LOADED MODULES.  THIS    * 02440019
*        LIST PROVIDES A COMMUNICATION LINK BETWEEN THE MODULES.      * 02450019
*        THE FORMAT OF THE EP LIST IS DESCRIBED BELOW.                * 02460019
*                                                                     * 02470019
*  EXTERNAL REFERENCES:  NONE                                         * 02480019
*                                                                     * 02490019
         EJECT                                                          02500019
*  EXITS:                                                             * 02510019
*                                                                     * 02520019
*        NORMAL - TO QDUMP MAIN LINE:  WHEN LOADING IS COMPLETE       * 02530019
*                 CONTROL IS PASSED TO 1-ST MOD LOADED WHICH     S21016 02540021
*                 IS ASSUMED TO BE QDUMP MACHINE INTERFACE MODULE     * 02550019
*                 (IMCJQMCI).  REGISTER SET-UP ON ENTRY TO IMCJQMCI   * 02560019
*                 IS AS FOLLOWS:                                      * 02570019
*                                                                     * 02580019
*                     REG  1 - EP LIST ADDRESS                        * 02590019
*                         13 - 18 WORD REGISTER SAVE AREA             * 02600019
*                         14 - RETURN ADDRESS                         * 02610019
*                         15 - IMCJQMCI EP ADDRESS                    * 02620019
*                                                                     * 02630019
*               - FINAL COMPLETION:  ON RETURN FROM THE QDUMP MAIN    * 02640019
*                 LINE, REG 15 (RETURN CODE) IS STORED IN A WAIT PSW  * 02650019
*                 AND THIS PSW LOADED.  THE RETURN CODE CAN THEN BE   * 02660019
*                 DISPLAYED ON THE SYSTEM MAINTENANCE PANNEL.  FINAL  * 02670019
*                 COMPLETION IS A SYSTEM WAIT STATE.                  * 02680019
*                                                                     * 02690019
*        ERROR:  IF AN I/O ERROR OCCURS DURING THE LOADING PROCEDURE, * 02700019
*             A ONE INSTRUCTION LOOP IS ENTERED.  THE CSW SHOWS THE   * 02710019
*             ERROR CONDITIONS.  SENSE IS NOT READ FROM IPL DEVICE    * 02720019
*                                                                     * 02730019
*  TABLES / WORK AREAS:                                               * 02740019
*                                                                     * 02750019
*        BUFFER / SAVE AREA:  THE LOADER CLAIMS 72 BYTES IMMEDIATELY  * 02760019
*             FOLLOWING ITSELF IN MAIN STORAGE FOR AN INPUT BUFFER    * 02770019
*             AND REGISTER SAVE AREA.                                 * 02780019
*                                                                     * 02790019
*        EP TABLE:  A TWO WORD TABLE IS CONSTRUCTED WHICH        S21016 02800021
*             CONTAINS THE EP ADDRESSES OF THE LOADED MODULES.   S21016 02810021
*             THE QDUMP MACHINE INTERFACE MODULE (IMCJQMCI) IS   S21016 02824021
*             LOADED FIRST AND THE APPLICATION MODULE (IMCOSAPP) S21016 02826021
*             IS LOADED LAST.                                    S21016 02828021
*                                                                     * 02840019
*                  ****************                                   * 02850019
*                  *  @ IMCJQMCI  *                                   * 02860019
*                  ****************  EP TABLE FORMAT                  * 02870019
*                  *  @ IMCOSAPP  *                              S21014 02880021
*                  ****************                                   * 02890019
*                          F                                          * 02900019
*                                                                     * 02910019
*             REG 1 IS SET POINTING TO THIS TABLE                     * 02920019
*                                                                     * 02930019
*  ATTRIBUTES:  STAND-ALONE, MACHINE EXECUTABL CODE                   * 02940019
*                                                                     * 02950019
*********************************************************************** 02960019
         EJECT                                                          02970019
* REGISTER EQUATES                                                      03000019
         SPACE                                                          04000019
DEV      EQU   1                                                        05000019
PARM     EQU   1                                                        06000019
R2       EQU   2                                                        07000019
R5       EQU   5                                                        08000019
SAVE     EQU   13                                                       09000019
R14      EQU   14                                                       10000019
EP       EQU   15                                                       11000019
         SPACE                                                          12000019
* STORAGE EQUATES                                                       13000019
         SPACE                                                          14000019
IPLPSW   EQU   0                                                        15000019
CAW      EQU   X'48'                                                    16000019
CSW      EQU   X'40'                                                    17000019
         EJECT                                                          18000019
LOADPSW  DC    X'00000000'                                              19000019
         DC    A(LOADEP)                                                20000019
CCW1     CCW   X'02',CCW3,X'60',72  READ 1-ST CARD                      21000019
CCW2     CCW   X'08',CCW3,X'60',0   TIC TO CCW IN 1-ST CARD             22000019
         DC    CL48' '          PAD IPL RECORD TO SINGLE CARD           23000019
         SPACE                                                          24000019
         ORG   *+16                                                     25000019
         USING *,0                                                      26000019
         SPACE                                                          27000019
CCW3     CCW   X'02',CCW3+72,X'60',72  READ 2-ND CARD                   28000019
CCW4     CCW   X'02',CCW3+144,X'20',72 READ 3-RD CARD                   29000019
         SPACE                                                          30000019
LOADEP   LH    DEV,IPLPSW+2     FETCH ADDRESS OF IPL DEVICE             31000019
         LA    R2,LOADCCW       SET CAW TO ADDRESS OF                   32000019
         ST    R2,CAW           LOADCCW                                 33000019
TESTIO   TIO   0(DEV)                                                   34000019
         BC    7,TESTIO         WAIT FOR IPL DEVICE TO COMPLETE         35000019
READ     SIO   0(DEV)                                                   36000019
WAIT     TIO   0(DEV)                                                   37000019
         BC    7,WAIT           WAIT FOR READ TO COMPLETE               38000019
         TM    CSW+4,X'03'      UNIT CHECK OR UNIT EXCEPTION            39000019
         BC    5,*              IS ERROR CONDITION                      40000019
         TM    CSW+5,X'FF'      IF ANY BITS ARE ON IN 2-ND BYTE OF      41000019
         BC    5,*              STATUS - ERROR                          42000019
         CLI   LOADAREA+2,C'X'                                          43000019
         BE    TEXTREC                                                  44000019
         CLI   LOADAREA+2,C'N'  TEST FOR 'BEND' RECORD                  45000019
         BNE   READ             IF NOT BEND, THEN WE MUST HAVE ESD      46000019
*                               RECORD SO IGNORE AND READ NEXT RECORD   47000019
         SPACE                                                          48000019
         L     EP,LOADAREA+4    WHEN 'BEND' CARD IS FOUND,              49000019
*                               GET EP ADDRESS                          50000019
         TM    LOADLIST,X'40'   TEST FOR 1-ST MODULE LOADED      S21016 51000021
         BO    GO               IF SO, READY TO DISPATCH                52000019
         ST    EP,LOADLIST      IF NOT, STORE EP ADRESS          S21016 53000021
         OI    LOADLIST,X'40'   FLAG MODULE LOADED               S21016 54000021
         B     READ             BRANCH TO LOAD NEXT                     55000019
         SPACE                                                          56000019
GO       ST    EP,LOADLIST+4    STORE EP ADDRESS OF LAST MODULE  S21016 57000021
*                               LOADED, CONTROL WILL BE PASSED TO       58000019
*                               THIS MODULE                             59000019
         LA    PARM,LOADLIST    SET REG 1 POINTING TO LOAD LIST         60000019
         LA    SAVE,LOADAREA    SET SAVE AREA ADDRESS - READ-IN AREA    61000019
*                               BECOMES REG SAVE AREA FOR LOADED PGM    62000019
         L     EP,LOADLIST      PICK UP ADDR OF FIRST            S21016 62050021
*                               MODULE LOADED - THIS MOD TO GET  S21016 62100021
*                               CONTROL                          S21016 62150021
         BALR  R14,EP           TRANSFER CONTROL TO LOADED PROGRAM      63000019
         OI    LOADPSW+1,X'02'  ON COMPLETION, SET WAIT BIT ON IN       64000019
*                               FINISH PSW AND                          65000019
         ST    EP,LOADPSW+4     SET RETURN CODE IN IAR                  66000019
         LPSW  LOADPSW          STAND-ALONE OPERATION COMPLETE          67000019
         SPACE 2                                                        68000019
TEXTREC  L     R2,LOADAREA+4    GET LOCATION COUNTER VALUE              69000019
         LH    R5,LOADAREA+10   PICK UP TEXT RECORD LENGTH              70000019
         BCTR  R5,0                                                     71000019
         EX    R5,MOVEINST      MOVE TEXT CONTENT TO LOADED MODULE      72000019
         B     READ                                                     73000019
         SPACE                                                          74000019
MOVEINST MVC   0(0,R2),LOADAREA+16                                      75000019
         SPACE                                                          76000019
LOADLIST DC    2F'0'            LIST OF EP'S FOR LOADED MODULES         77000019
LOADCCW  CCW   X'02',LOADAREA,X'20',72                                  78000019
LOADAREA EQU   *                                                        79000019
         END                                                            80000019
