IMDPRFUB START                                                          00200020
         TITLE 'IMDPRFUB - REGION BOUNDARY ROUTINE'                     00400020
* C 646000                                                       A38027 00450020
* C 196000                                                       A40783 00500020
* A 536500-537500,538500,594500-595000,604100-605766,649000      A53323 00550001
* A 706500-707600,790500,794500-795940,914500-915500             A53323 00560001
* C 586000,698000,782000                                         A53323 00570001
*********************************************************************** 00600020
*                 *** IMDPRFUB - REGION BOUNDARY ROUTINE ***          * 00650021
*                                                                     * 00700021
* STATUS--OS/360 RELEASE 21.0                                         * 00750021
*                                                                     * 00760021
* FUNCTION--                                                          * 00770021
*   THIS ROUTINE DETERMINES THE UPPER AND LOWER BOUNDRIES OF THE      * 01600020
*   REGIONS FOR THE TASKS WHOSE TCB'S ARE ON THE TCB LIST. IT THEN    * 01800020
*   ENQUEUES THE REGION TO BE PRINTED.                                * 02000020
*   INTRODUCTORY COMMENTS FOR TIOTSV PRECEEDS THAT CSECT.             * 02050021
*                                                                     * 02100021
* ENTRY POINTS--                                                      * 02150021
*   IMDPRFUB IS THE ONLY ENTRY POINT.  CONTROL IS RECEIVED FROM       * 02160021
*   IMDPRPAL AFTER A 'PRINT ALL' CONTROL STATEMENT IS READ, FROM      * 02170021
*   IMDPRPDR AFTER A 'PRINT F03', FROM IMDPRPJB AFTER A 'PRINT        * 02180021
*   JOBNAME', AND FROM IMDPRPCR AFTER A 'PRINT CURRENT'.  STANDARD    * 02190021
*   LINKAGE IS USED                                                   * 02192021
*                                                                     * 02194021
* INPUT--                                                             * 02196021
*         REGISTER 12 - ADDRESS OF COMMON CSECT                       * 02198021
*         TCBLIST - LIST OF JOB STEP TCB'S WHOSE BOUNDARIES ARE TO    * 02198421
*                   BE DETERMINED.                                    * 02198821
*                                                                     * 02199221
* OUTPUT--                                                            * 02199621
*   OUTPUT CONSISTS OF USING PCBENQ TO BUILD AND ENQ PRINT CONTROL    * 02199721
*   BLOCKS.  THERE IS NO RETURN CODE.                                 * 02199821
*   MESSAGE 'ERROR FINDING REGION BOUNDARIES FOR TCB XXXXXX' IS       * 02199921
*   PRINTED FOR MVT.                                                  * 02249921
*                                                                     * 02259921
* EXTERNAL REFERENCES--                                               * 02269921
*         GETMAIN - TO OBTAIN STORAGE FOR PQE TABLES                  * 02279921
*         FREEMAIN - TO FREE PQE TABLES                               * 02289921
*         BRREAD - TO OBTAIN DATA FROM INPUT DUMP                     * 02291921
*         BRWRITE - TO WRITE ERROR MESSAGE TO 'PRINTER' DATA SET      * 02293921
*                                                                     * 02295921
* EXITS, NORMAL--                                                     * 02297921
*   RETURN TO CALLER THROUGH STANDARD LINKAGE.                        * 02298321
*                                                                     * 02298721
* EXITS, ERROR--                                                      * 02299121
*   NONE                                                              * 02299521
*                                                                     * 02299621
* TABLES/WORK AREAS--                                                 * 02299721
*   A TCBLIST IS PASSED TO THIS MODULE THROUGH AN ADDRESS IN          * 02299821
*   COMMON.  A SISTER TCBLIST IS BUILT BY THIS MODULE IN THE SAME     * 02333221
*   FORMAT AS THE TCBLIST.  THE FORMAT IS AS FOLLOWS:                 * 02343221
*                                                                     * 02353221
*         ************************************                        * 02363221
*         * PTR TO NEXT TCB ELEMENT OR ZEROS *                        * 02365221
*         ************************************                        * 02365621
*         * ADDRESS OF TCB                   *                        * 02366021
*         ************************************                        * 02366421
*                                                                     * 02366521
*   TABLE OF PQE POINTERS.  THIS TABLE CONTAINS POINTERS TO           * 02377621
*   UNIQUE DUMMY PQE'S FOR ALL FAMILIES OF TCB'S ON THE TCBLIST       * 02387621
*   'PQETBL' CONTAINS THE ADDRESS OF THE FIRST TABLE.                 * 02388021
*   TABLE FORMAT FOLLOWS:                                             * 02388421
*                                                                     * 02388821
*         ********************************                            * 02392521
*         * PTR TO NEXT TABLE OR ZEROS   *                            * 02394521
*         ********************************                            * 02394921
*         * FLAGS * ADDRESS OF DUMMY PQE *                            * 02395321
*         *       *(UP TO FIVE ADDRESSES)*                            * 02395721
*         ********************************                            * 02396121
*         FLAGS: X'08' IF ADDRESS IS IN SLOT                          * 02396221
*                X'00' IF NO ADDRESS IN SLOT                          * 02409621
*                X'80' OR X'88' FOR LAST (5TH) SLOT                   * 02419621
*                                                                     * 02421621
* ATTRIBUTES--NON-REUSABLE                                            * 02422021
*                                                                     * 02422421
* CHARACTER CODE DEPENDENCY--NONE                                     * 02422821
*                                                                     * 02422921
* NOTES--                                                             * 02423021
*   BRREAD ERROR HANDLERS:  IF A TCB OR PQE CANNOT BE READ FROM THE   * 02423121
*   INPUT DUMP, A MESSAGE IS PRINTED, THE PQE TABLE IS FREED, AND     * 02427621
*   PROCESSING CONTINUES WITH THE NEXT TCB ON THE TCBLIST.            * 02429621
*                                                                     * 02432121
*********************************************************************** 02436621
*/*IMDPRFUB: CHART (SEQ) */                                             02450021
*/*HEADER                                                               02500021
*/*IMDPRFUB - REGION BOUNDARY ROUTINE FLOWCHARTS                        02550021
*/*                                                    PAGE #     */    02560021
*/*IMDPRFUB: E START */                                                 02570021
*/* M SET UP ADDRESSABILITY */                                          02580021
*/* D (NO,BNDRY01,YES,) INIT PASS */                                    02590021
*/* M SET INIT PASS SWITCH ON */                                        02592021
*/* P (,BNDDONE) PUT FUB'S ADDRS IN COMMON */                           02594021
*/*BNDRY01: P ZERO TCB COUNTER */                                       02596021
*/* S (,BNDRY17B) BNDTPRG: PURGE MVT BNDRY TCB LIST */                  02598021
*/*BNDRY1: P ADD ONE TO TCB COUNT */                                    02598421
*/* M RESET SEQ1 SWITCH */                                              02598821
*/* S TCBRTRV: GET A TCB ADDR */                                        02599221
*/* D (NO,BNDDONE,YES,) IS THERE A TCB ADDR */                          02599621
*/* D (NO,BNDRY20,YES,) MVT DUMP */                                     02599721
*/*BNDRY15: P SAVE JOB STEP TCB ADDR */                                 02599821
*/* P SET UP MVT REGION BNDRY ERROR RTN */                              02599921
*/* P CLEAR PQE LOOP COUNTER */                                         02649921
*/* D (YES,BNDRY15B,NO,) IS SUBJECT TCB MAST. SCH. */                   02659921
*/*BNDRY15E: S BRREAD: GET PTR TO MOTHER TCB */                         02669921
*/* D (YES,BNDRY15D,NO,) IS IT = 0 */                                   02679921
*/* D (YES,BNDRY15D,NO,) IS IT MASTER */                                02689921
*/* P (,BNDRY15E) SAVE MOTHER TCB AS CURRENT SUBJECT */                 02691921
*/*BNDRY15D: P (,BNDRY15B) SAVE TOP TCB IN TREE */                      02693921
*/*BNDRY15A: D (YES,BNDRY17,NO,) WAS TCB MAST.SCH. */                   02695921
*/* D (YES,BNDRY15C,NO,) IS THIS TOP TCB IN TREE */                     02697921
*/* S BRREAD: GET PTR TO SISTER */                                      02698321
*/* S BNDTCBS: SAVE SISTER PTR */                                       02698721
*/*BNDRY15C: S BRREAD: GET DAUGHTER TCB PTR */                          02699121
*/* D (NO,BNDRY15B,YES,) IS DAUGHTER PTR = 0 */                         02699521
*/* S BNDRTCBG: GET LAST SISTER */                                      02699621
*/* D (NO,BNDRY17,YES,BNDRY15B) WAS THERE ONE */                        02699721
*/*BNDRY15B: P SAVE TCB ADDR */                                         02699821
*/* S BRREAD: GET PQE PTR FROM TCB */                                   02733221
*/* D (YES,BNDRY15A,NO,) IS DUMMY PQE PTR = 0 */                        02743221
*/* S PQESAVE: SAVE PQE ADDR (DUMMY) */                                 02753221
*/* N (DUP,BNDRY15A,NDUP,) CONDITIONAL RETURN ADDR */                   02763221
*/*BNDRY16: P POINT TO FORWARD PQE */                                   02765221
*/* P ADD ONE TO PQE LOOP CNT */                                        02765621
*/* D (NO,LOOPERR,YES,) IS CNT < 50 */                                  02766021
*/* S BRREAD: GET FORWARD PQE ADDR */                                   02766421
*/* D (YES,BNDRY15A,NO,) IS IT = 0 */                                   02766521
*/* S BRREAD: GET SIZE IN PQE */                                        02777621
*/* P SAVE SIZE */                                                      02787621
*/* S BRREAD: GET REGION BEGIN ADDR */                                  02788021
*/* P ADD BEGIN ADDR TO SIZE FOR END ADDR */                            02788421
*/* D (NO,BNDRY15,YES,) IS RESULT > 0 */                                02788821
*/* S BRREAD: GET PQE ROLLOUT FLAGS */                                  02792521
*/* P PUT FLAGS IN HIGH BYTE OF REG WITH TCB */                         02794521
*/* S TIOTSV: SAVE NAMES, BNDRS,TCB ADDR, & ROLLOUT FLGS */             02794921
*/* M SET SEQ1 SWITCH ON */                                             02795321
*/* P SET UP PARM-LIST FOR PCB ENQ */                                   02795721
*/* S (,BNDRY16) PCBENQ: SAVE ADDRS OF REGION TO BE PRINTED */          02796121
*/*LOOPERR: P (,MVTBERR) GET ADDR OF MVTBERR FOR BRANCH */              02796221
*/*BNDRY17: D (YES,BNDRY17A,NO,) SEQ1 SW. ON */                         02846221
*/* P LOAD JOB STEP TCB ADDR */                                         02856221
*/* P INDICATE NO REGION FOR THIS TCB */                                02866221
*/* S TIOTSV: SAVE NAMES FOR THIS TASK */                               02876221
*/*BNDRY17A: P RESTORE PREV. ERROR RTN ADDR */                          02886221
*/*BNDRY17B: D (YES,BNDRY1,NO,) IS TOP PQE TABLE PTR = 0 */             02888221
*/* P REMOVE TABLE FROM LIST */                                         02890221
*/* L (,BNDRY17B) FREE STORAGE FOR THIS TABLE ENTRY */                  02892221
*/*BNDTCBS: P LOAD ADDR OF TCB TO BE SAVED */                           02894221
*/* P BNDTSAV = TCBLIST; TCBLIST = BNDTLST */                           02894621
*/* S TCBSAVE: SAVE THE ADDR */                                         02895021
*/* P BNDTLST = TCBLIST; TCBLIST = BNDTSAV */                           02895421
*/* R RETURN VIA R9 */                                                  02895821
*/*BNDTCBG: P BNDTSAV = TCBLIST; TCBLIST = BNDTLST */                   02895921
*/* S TCBRTRV: GET 1ST TCB ON LIST */                                   02896021
*/* D (NO,BNDTCBG1,YES,) WAS THERE ONE */                               02896121
*/* S TCBREMV: REMOVE TCB FROM LIST */                                  02912821
*/*BNDTCBG1: P BNDTLST = TCBLIST; TCBLIST = BNDTSAV */                  02922821
*/* R RETURN VIA R9 */                                                  02923221
*/*BNDTPRG: P BNDTSAV = TCBLIST; TCBLIST = BNDTLST */                   02923621
*/* S TCBREMV: REMOVE ALL TCB'S FROM LIST */                            02924821
*/* P BNDTLST = TCBLIST; TCBLIST = BNDTSAV */                           02926821
*/* R RETURN VIA R9 */                                                  02928821
*/*PQESAVE: N RTN TO SAVE PQE POINTERS IN PQE TABLE */                  02929221
*/* P LOAD ADDR OF PQE TABLE */                                         02929321
*/*PQESVLP1: P GET PTR TO NEXT TABLE */                                 02929421
*/* D (YES,PQESAVE2,NO,) IS PTR = 0 */                                  02935021
*/* P UPDATE TABLE PTR */                                               02937021
*/*PQESVLP2: P POINT TO NEXT ENTRY IN TABLE */                          02939021
*/* D (NO,PQESAVE1,YES,) IS ENTRY USED */                               02939421
*/* P GET ADDR OF SAVED PQE ADDR */                                     02939821
*/* D (NO,%A,YES,) IS PQE A DUPL. */                                    02940221
*/* R RETURN VIA R9 */                                                  02940321
*/*%A: D (NO,PQESVLP2,YES,PQESVLP1) IS ENTRY LAST IN TABLE */           02940421
*/*PQESAVE1: P SAVE PQE ADDR AND FLAGS */                               02940521
*/* P INDICATE ENTRY IS USED */                                         02955321
*/* R RETURN TO R9 + 4 */                                               02965321
*/*PQESAVE2: L GET STORAGE FOR PQE TABLE */                             02967321
*/* P CLEAR THE STORAGE */                                              02969321
*/* P PUT NEW BLOCK ON LIST */                                          02969721
*/* P INDICATE IT AS LAST ON LIST */                                    02970121
*/* P (,PQESAVE1) POINT TO FIRST ENTRY IN TABLE */                      02970221
*/*MVTBERR: M SET UP ADDRESSABILITY */                                  02970321
*/* S BRWRITE: SPACE A LINE */                                          02975221
*/* S ADRCNVT: CONVERT JOB STEP TCB ADDR FOR MSG */                     02977221
*/* P MOVE ERROR MSG TO BUFFER */                                       02977621
*/* S (,BNDRY17A) BRWRITE: PRINT THE MSG */                             02978021
*/*BNDRY20: N RTN TO DETERMINE PARITITON BNDRY. IN PCP/MFT */           02978421
*/* P SAVE ERROR RTN ADDR THAT IS IN COMMON */                          02979701
*/* P MOVE FUB'S ERROR RTN ADDR INTO COMMON */                          02982501
*/* P SAVE TCB ADDR IN ANOTHER REG */                                   02983801
*/* P SAVE TCB ADDR IN CASE OF ERROR */                                 02984201
*/* S BRREAD: GET PTR TO BOUNDARY BOX */                                02985101
*/*BNDRY20A: S BRREAD: GET BEGINNING OF PART. PTR. */                   02986401
*/* S BRREAD: GET PTR TO END OF PARTITION */                            02987701
*/* D (YES,BNDRY20B,NO,) END ADDR = 0 */                                02989001
*/* S TIOTSV: SAVE NAMES, TCB ADDR AND BOUNDARIES */                    02990301
*/* P SET UP P-LIST FOR PCB ENQ */                                      02991601
*/* S PCBENQ: SAVE ADDRS. OF PART. TO BE PRINTED */                     02992901
*/*BNDRY20B: D (YES,BNDRY1,NO,) IS SEQ1 SW ON */                        02994201
*/* S BRREAD: GET BNDRY BOX FLAGS */                                    02995501
*/* D (NO,BNDRY2,YES,) IS THERE HIER. SUPPORT */                        02996801
*/* M SET SEQ1 SW. ON */                                                02998101
*/* P (,BNDRY20A) BUMP PTR TO HIERARCHY 1 BOX PTR */                    02999401
*/*BNDRY2: P (,BNDRY1) RESTORE PREVIOUS ERROR RTN ADDR IN COMMON */     02999801
*/*BNDDONE: M RESTORE REGS */                                           03000721
*/* R RETURN */                                                         03002021
*/*BNDERROR: N RTN TO HANDLE BRREAD ERRORS FOR PARTITION BNDRY BOX */   03004001
*/* M RESTORE FUB'S REGS USING R15 AS BASE REG */                       03006021
*/* M REESTABLISH ADDRESSABILITY */                                     03008021
*/* P GET ADDR OF OUTPUT BUFFER */                                      03010001
*/* S BRWRITE: SPACE A LINE */                                          03010401
*/* P GET ADDR OF TCB FOR ERROR MSG */                                  03010801
*/* L AADRCNVT: CONVERT ADDR OF TCB */                                  03011201
*/* P MOVE MSG TO BUFFER */                                             03011601
*/* S BRWRITE: PRINT MSG */                                             03011701
*/* P (,BNDRY2) RESTORE FUB'S ERROR RTN ADDR */                         03011801
*/*TIOTSV: E ENTRY */                                                   03012021
*/* M SET UP ADDRESSABILITY */                                          03014021
*/* P SAVE CALLER'S ERROR RTN ADDR */                                   03015501
*/* P PUT TIOT ERROR RTN ADDR IN COMMON */                              03017501
*/* L GET STORAGE FOR TIOT ELEMENT */                                   03020001
*/* P PUT BEGINNING AND ENDING ADDRS. IN ELE. */                        03021501
*/* P PUT TCB ADDR IN ELEMENT */                                        03023001
*/* P SAVE NEW ELEMENT ADDR */                                          03024501
*/* P LOAD INDEX & COUNT FOR MOVING 3 TIOT NAMES */                     03026001
*/* S BRREAD: GET TIOT PTR FROM TCB */                                  03027501
*/* P SAVE TIOT PTR */                                                  03029001
*/*TIOTSVLP: D (YES,TIOTSV,NO,) IS TIOT PTR = 0 */                      03030501
*/* D (YES,TIOTNSV,NO,) IS TIOT PTR > MACH. ADDR */                     03032001
*/* S BRREAD: GET A FIELD OF TIOT */                                    03033501
*/* P MOVE A NME TO THE ELEMENT */                                      03035001
*/* P INDEX TO NEXT NAME AND ELE. FIELD */                              03036501
*/* D (NO,TIOTSVLP,YES,TIOTSV4) 3 NAMES SAVED */                        03038001
*/*TIOTNSV: P BLANK OUT NAME FIELDS IN ELEMENT */                       03039501
*/*TIOTSV4: P LOAD ADDR OF FIRST ELEMENT */                             03041001
*/*TIOTSV3: D (YES,TIOTSV1,NO,) END OF CHAIN (=0) */                    03042501
*/* D (YES,TIOTSV2,NO,) DUP ELE. ON CHAIN */                            03044001
*/* P (,TIOTSV3) LOAD ADDR OF NEXT ELEMENT IN CHAIN */                  03045501
*/*TIOTSV1: P LINK NEW ELEMENT TO TOP OF CHAIN */                       03047001
*/* P (,TIOTRET1) SET RETURN CODE = 0 */                                03048501
*/*TIOTSV2: L FREE STORAGE OCCUPIED BY ELEMENT */                       03050001
*/* P RESTORE CALLER'S ERROR RTN ADDR */                                03050401
*/* P (,TIOTRET) SET RETURN CODE = 4 (DUP) */                           03051501
*/*TIOTERR: N RTN TO HANDLE BRREAD ERROR READING TIOT */                03051901
*/* M RESTORE TIOTSV'S REGS USING R15 AS BASE REG */                    03052321
*/* M REESTABLISH ADDRESSABILITY */                                     03052721
*/* P MOVE 'UNKNOWN' INTO JOBNAME FIELD OF ELEMENT */                   03052801
*/* P BLANK OUT REMAINDER OF ELEMENT */                                 03052901
*/* P (,TIOTSV4) CONTINUE BUILDING ELEMENTS */                          03054921
*/*TIOTTST: E ENTRY */                                                  03057001
*/* M SET UP ADDRESSABILITY */                                          03059021
*/* P GET ADDR OF TIOT ELEMENT PTR */                                   03061001
*/*TIOTTLP: P LOAD ADDR OF TIOT ELEMENT */                              03063001
*/* D (YES,TIOTTST2,NO,) END OF LIST */                                 03065021
*/* D (YES,TIOTTST1,NO,TIOTTLP) IS CURR. ADDR = START ADDR */           03067001
*/*TIOTTST1: P MOVE NAMES TO WORK AREA */                               03069001
*/* P DEQ THE ELEMENT */                                                03071001
*/* L FREE ITS STORAGE */                                               03073001
*/* P (,TIOTRET) SET RETURN CODE = 0 */                                 03075021
*/*TIOTTST2: P (,TIOTRET) SET RETURN CODE = 4 */                        03085021
*/*TIOTPRGE: E ENTRY */                                                 03087021
*/* M SET UP ADDRESSABILITY */                                          03089021
*/* P POINT TO TOP ELEMENT ADDR */                                      03091021
*/*TPRGELP: P LOAD ADDR OF TIOT ELEMENT */                              03091421
*/* D (YES,TIOTRET,NO,) END OF LIST */                                  03091821
*/* P REMOVE ELEMENT FROM LIST */                                       03091921
*/* L (,TPRGELP) FREE ELEMENT STORAGE */                                03100921
*/*TIOTRET: M RESTORE REGS */                                           03102921
*/* R RETURN */                                                         03104921
*/*IMDPRFUB: END */                                                     03106921
         SPACE                                                          03110021
         EQUATES                                                        03119021
         COMMON                                                         03146021
*                                                                 M3179 03173021
         OUTBUFM                                                        03200020
IMDPRFUB CSECT                                                          03400020
INIT     EQU   128                 INITIALIZATION DONE SWITCH           03600020
         STM   R14,R12,12(R13)     SAVE CALLER'S REGS                   03800020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             04000020
         USING RGNBNDRY,BASE1                                           04200020
RGNBNDRY LA    R2,BDYSAVE          SAVE AREA CHAINING                   04400020
         ST    R13,BDYSAVE+4                                            04600020
         ST    R2,8(R13)                                                04800020
         LR    R13,R2              ESTABLISH FUB'S SAVE AREA            05000020
         SPACE                                                          05200020
         USING COMMON,COMBASE      REG 12 IS COMMON CSECT POINTER       05400020
         SPACE                                                          05600020
         TM    BDYSW,INIT          TEST INITIALIZATION PASS             05800020
         BO    BNDRY01             INIT SW ON MEANS REAL THING          06000021
         OI    BDYSW,INIT          OFF - TURN ON AND INIT               06200020
         ST    R15,ARGNBND         STORE FUB'S ADDRESS IN COMMON        06400020
         LM    R2,R3,PTIOTTST      STORE TIOTTST AND TIOTPRGE ADDRS     06600020
         STM   R2,R3,ATIOTTST      IN COMMON                            06800020
         B     BNDDONE             GO RETURN TO LOADER                  07000020
         SPACE                                                          07200020
BNDRY01  XC    TCBCNTA,TCBCNTA     ZERO TCB COUNTER                     07600020
         BAL   R9,BNDTPRG          PURGE MVT BOUNDRY TCB LIST           07800020
         B     BNDRY17B            FREE ALL POSSIBLE PQE TABLES         08000020
*                                  IN THE EVENT THE OPERATOR HAD        08200020
*                                  STOPPED THE LAST DUMP WHILE WE HAD   08400020
*                                  SOME PQE ADDRS SAVED                 08600020
BNDRY1   LH    R2,TCBCNTA          LOAD TCB COUNT                       08800020
         AH    R2,ONEA             ADD ONE TO COUNT                     09000020
         STH   R2,TCBCNTA          STORE BACK UPDATED COUNT             09200020
         NI    SWB,255-SEQ1        RESET SEQ1 SW                        09400020
         L     R15,ATCBRTRV        LOAD ADDR OF TCB RETRIEVE ROUTINE    09600020
         BALR  RETREG,R15          LINK TO IT TO GET A TCB ADDR         09800020
         LTR   R2,R2               IS THERE A TCB ADDRESS               10000020
         BZ    BNDDONE             NO--GO TEST THE MORE SWITCH          10200020
         TM    SWE,MVTSW           IS THIS MVT                          10400020
         BZ    BNDRY20             NO--PCP OR MFT                       10600020
         SPACE 2                                                        10800020
*********************************************************************** 11000020
*                                                                     * 11200020
*   ROUTINE FOR DETERMINING BOUNDRIES OF REGIONS IN MVT               * 11400020
*                                                                     * 11600020
*********************************************************************** 11800020
         SPACE                                                          12000020
PQELIMIT EQU   51                  PQE LOOP LIMIT OF 50          A36406 12050020
PQELAST  EQU   128                                                      12200020
PQEACT   EQU   8                                                        12400020
BNDRY15  ST    R2,BNDJST           SAVE JOB STEP TCB ADDR               12600020
         MVC   BNDERASV,ERRADDR    SAVE ERROR ROUTINE ADDR              12800020
         LA    R15,MVTBERR         LOAD ADDR OF MVT REGION BND ERR ROUT 13000020
         ST    R15,ERRADDR         ENABLE IT                            13200020
         XC    PQECTN,PQECTN       CLEAR PQE LOOP COUNTER        A36406 13250020
         C     R2,MSTRTCB          IS SUBJECT TCB MASTER SCHEDULER TCB  13400020
         BE    BNDRY15B            YES--TAKE IT BY IT'SELF              13600020
BNDRY15E LA    PREG,MOTHER(R2)     ADDR OF PTR TO MOTHER                13800020
         BRREAD  (PREG),DATA,TJID=0                                     14000020
         L     PREG,0(PREG)        LOAD MOTHER PTR                      14200020
         LA    PREG,0(PREG)        CLEAR POS HI BYTE                    14400020
         LTR   PREG,PREG           TEST FOR ZERO                        14600020
         BZ    BNDRY15D            ZERO--TOP OF FAMILY TREE             14800020
         C     PREG,MSTRTCB        IS MOTHER MASTER SCHED               15000020
         BE    BNDRY15D            YES--SAVE TOP TCB OF FAMILY TREE     15200020
         LR    R2,PREG             MOTHER ADDR TO R2                    15400020
         B     BNDRY15E            LOOP TO TOP OF FAMILY TREE           15600020
BNDRY15D ST    R2,BNDTOPT          SAVE ADDR OF TOP TCB IN TREE         15800020
         B     BNDRY15B            FIND BOUNDRIES                       16000020
BNDRY15A C     R2,MSTRTCB          WAS IT THE MASTER SCHED TCB          16200020
         BE    BNDRY17             YES--ALL DONE WITH IT THEN           16400020
         C     R2,BNDTOPT          IS THIS THE TOP TCB IN TREE          16600020
         BE    BNDRY15C            YES--BR AROUND SAVE OF SISTER        16800020
         LA    PREG,SISTER(R2)     NO--SAVE SISTER TCB ADDR             17000020
         BRREAD  (PREG)                                                 17200020
         BAL   R9,BNDTCBS          SAVE SISTER TCB PTR                  17400020
BNDRY15C LA    PREG,DAUGHTER(R2)   ADDR OF DAUGHTER PTR                 17600020
         BRREAD  (PREG)                                                 17800020
         L     PREG,0(PREG)        LOAD DAUGHTER PTR                    18000020
         LTR   R2,PREG             IS THERE A DAUGHTER                  18200020
         BNZ   BNDRY15B            YES--GO FIND PQE FOR DAU             18400020
         BAL   R9,BNDTCBG          NO--GET LAST SISTER                  18600020
         LTR   R2,R2               WAS THERE ONE                        18800020
         BZ    BNDRY17             NO--GO AFTER NEXT JSTCB              19000020
BNDRY15B LR    R7,R2               SAVE TCB ADDR IN R7                  19200020
         LA    PREG,TCBPQE(R2)     PQE PTR ADDR                         19400020
         BRREAD  (PREG),,TJID=0                                  A40783 19600020
         L     R8,0(PREG)          DUMMY PQE PTR TO R8                  19800020
         LA    R8,0(R8)                 CLEAR POSSIBLE HIGH ORDER BYTE  20000020
         LTR   R8,R8               IS IT ZERO                           20200020
         BZ    BNDRY15A            YES--NO REGION                       20400020
         BAL   R9,PQESAVE          GO TEST FOR DUPLICATE DUMMY PQE ADDR 20600020
*                                  IF NOT SAVE THIS PQE FOR NEXT TIME   20800020
         B     BNDRY15A            RETURN POINT IF IT IS A DUPLICATE    21000020
BNDRY16  LA    PREG,PQEFPQE(R8)    ADDR OF PQE FORWARD POINTER          21200020
         IC    R5,PQECTN           GET PQE LOOP CTN              A36406 21250020
         LA    R5,1(R5)            ADD ONE TO LOOP CTN           A36406 21300020
         STC   R5,PQECTN           SAVE COUNTER                  A36406 21350020
         CLI   PQECTN,PQELIMIT     50 PQE'S ?                    A36406 21360020
         BNL   LOOPERR             YES AN ERROR                  A36406 21370001
*   FALL HERE FOR LESS THAN 50 PQE'S ON THE QUEUE                A36406 21380001
         BRREAD  (PREG)                                                 21400020
         L     R8,0(PREG)          PQE ADDR TO R8                       21600020
         LA    R8,0(R8)                 CLEAR POSSIBLE HIGH ORDER BYTE  21800020
         LTR   R8,R8               IS IT ZERO                           22000020
         BZ    BNDRY15A            YES--DONE WITH THIS TCB              22200020
         LA    PREG,PQESIZE(R8)    ADDR OF SIZE IN PQE                  22400020
         BRREAD  (PREG)                                                 22600020
         L     R4,0(PREG)          LOAD SIZE TO R4                      22800020
         LA    PREG,PQEREGN(R8)    ADDR OF BEGINNING OF REGION ADDR     23000020
         BRREAD  (PREG)                                                 23200020
         L     R3,0(PREG)          ADDR OF BEGINNING OF REGION          23400020
         AR    R4,R3               ADD BEGINNING ADDR TO LENGTH TO      23600020
*                                  OBTAIN ENDING ADDR                   23800020
         BNP   BNDRY16             ERROR--BYPASS THIS PQE               24000020
         LA    PREG,PQERFLGS(R8)   ADDR OF PQE ROLLOUT FLAGS            24200020
         BRREAD  (PREG)                                                 24400020
         IC    R6,0(PREG)          FLAGS TO R6                          24600020
         SLL   R6,24               SHIFT TO HIGH ORDER BYTE             24800020
         OR    R7,R6               OR PQE ROLLOUT FLAGS TO HIGH ORDER   25000020
*                                  BYTE OF TCB ADDR                     25200020
         L     R15,ATIOTSV         LOAD ADDR OF TIOT SAVE ROUTINE       25400020
         BALR  RETREG,R15          SAVE NAMES, BOUNDRIES, TCB ADDR, AND 25600020
*                                  ROLLOUT FLAGS OF JOBSTEP REGION      25800020
         OI    SWB,SEQ1            SET SEQ1 SW                          26000020
         STM   R3,R4,PCBLIST       SET UP P-LIST TO PCB ENQ             26200020
         LA    PREG,PCBLIST        POINT TO P-LIST                      26400020
         L     R15,APCBENQ         LOAD ADDR OF PCB ENQUEUE ROUTINE     26600020
         BALR  RETREG,R15          SAVE ADDRS OF REGION TO BE PRINTED   26800020
         LA    R7,0(R7)            REMOVE ROLLOUT FLAGS                 27000020
         B     BNDRY16             LOOP FOR ALL PQE'S OF THIS TCB       27200020
LOOPERR  LA    R15,MVTBERR         50 PQE'S ENCOUNTERED          A36406 27250001
         BR    R15                 GO PRINT ERROR MSG            A36406 27300001
BNDRY17  TM    SWB,SEQ1            IS SEQ1 SW SET  (TIOT SAVED)         27400020
         BO    BNDRY17A            YES--CONTINUE WITH NEXT TCB          27600020
         L     R2,BNDJST           LOAD JOB STEP TCB ADDR               27800020
         SR    R3,R3               NO--NO REGION FOR THIS TCB           28000020
         SR    R4,R4               MAKE START/END ADDRS ZERO            28200020
         L     R15,ATIOTSV         LOAD ADDR OF TIOT SAVE ROUTINE       28400020
         BALR  RETREG,R15          LINK TO IT                           28600020
*                                  CONTINUE WITH NEXT TCB               28800020
BNDRY17A MVC   ERRADDR,BNDERASV    RESTORE PREVIOUS ERR ROUT ADDR       29000020
BNDRY17B L     R1,PQETBL           LOAD ADDR OF TOP TABLE               29200020
         LTR   R1,R1               IS IT ZERO                           29400020
         BZ    BNDRY1              YES--ALL DONE FREEING                29600020
         MVC   PQETBL(4),0(R1)     NO--DELINK THIS TABLE FROM LIST      29800020
         FREEMAIN R,LV=24,A=(1)    FREE THIS TABLE ENTRY                30000020
         B     BNDRY17B            LOOP TO END OF LIST                  30200020
         SPACE 3                                                        30400020
*********************************************************************** 30600020
*                                                                     * 30800020
*   SAVE ADDRS OF ALL SISTERS ENCOUNTERED                             * 31000020
*                                                                     * 31200020
*********************************************************************** 31400020
         SPACE                                                          31600020
BNDTCBS  LR    R0,R2               SAVE R2 IN R0                        31800020
         L     R2,0(PREG)          LOAD ADDR OF TCB TO BE SAVED TO R2   32000020
         MVC   BNDTSAV,TCBLIST     SAVE TCBLIST PTR                     32200020
         MVC   TCBLIST,BNDTLST     MOVE IN BOUNDRY TCB LIST             32400020
         L     R15,ATCBSAVE        ADDR OF TCB SAVE ROUT                32600020
         BALR  RETREG,R15          GO SAVE THIS ADDR                    32800020
         MVC   BNDTLST,TCBLIST     UPDATE BOUNDRY TCB LIST              33000020
         MVC   TCBLIST,BNDTSAV     RESTORE TCBLIST                      33200020
         LR    R2,R0               RESTORE R2                           33400020
         BR    R9                  RETURN TO CALLER                     33600020
         SPACE 2                                                        33800020
*********************************************************************** 34000020
*                                                                     * 34200020
*   RETURN ADDRS OF PREVIOUSLY SAVED SISTER TCB'S                     * 34400020
*                                                                     * 34600020
*********************************************************************** 34800020
         SPACE                                                          35000020
BNDTCBG  MVC   BNDTSAV,TCBLIST     SAVE TCBLIST PTR                     35200020
         MVC   TCBLIST,BNDTLST     MOVE IN BOUNDRY TCB LIST PTR         35400020
         LA    R2,1                FOR FIRST TCB ON LIST                35600020
         L     R15,ATCBRTRV        ADDR OF TCB RETRIEVE ROUTINE         35800020
         BALR  RETREG,R15          LINK TO IT                           36000020
         LTR   R2,R2               WAS THERE ONE                        36200020
         BZ    BNDTCBG1            BR IF NOT TO AVOID REMOVAL           36400020
         L     R15,ATCBREMV        YES--REMOVE THIS TCB FROM LIST       36600020
         BALR  RETREG,R15          LINK TO REMOVE ROUTINE               36800020
BNDTCBG1 MVC   BNDTLST,TCBLIST     UPDATE BOUNDRY TCBLIST               37000020
         MVC   TCBLIST,BNDTSAV     RESTORE TCBLIST PTR                  37200020
         BR    R9                  RETURN TO CALLER                     37400020
         SPACE 2                                                        37600020
*********************************************************************** 37800020
*                                                                     * 38000020
*   REMOVE ALL TCB ADDRS THAT MAY BE ON THE BOUNDRY TCB LIST          * 38200020
*                                                                     * 38400020
*                                                                     * 38600021
*********************************************************************** 38800020
         SPACE                                                          39000020
BNDTPRG  MVC   BNDTSAV,TCBLIST     SAVE TCBLIST PTR                     39200020
         MVC   TCBLIST,BNDTLST     MOVE IN BOUNDRY TCB LIST PTR         39400020
         SR    R2,R2               ZERO R2 TO REMOVE ALL                39600020
         L     R15,ATCBREMV        ADDR OF TCB REMOVE ROUT              39800020
         BALR  RETREG,R15          LINK TO IT                           40000020
         MVC   BNDTLST,TCBLIST     MOVE BACK THE ZEROED PTR             40200020
         MVC   TCBLIST,BNDTSAV     RESTORE TCBLIST PTR                  40400020
         BR    R9                  RETURN TO CALLER                     40600020
         EJECT                                                          40800020
*********************************************************************** 41000020
*                                                                     * 41200020
*   SAVE PQE POINTERS IN PQE TABLE                                    * 41400020
*                                                                     * 41600020
*********************************************************************** 41800020
         SPACE                                                          42000020
PQESAVE  LA    R3,PQETBL           ADDR OF PQE TABLE PTR                42200020
PQESVLP1 L     R4,0(R3)            LOAD PTR TO NEXT TABLE ENTRY         42400020
         LTR   R4,R4               IS THIS END OF LIST                  42600020
         BZ    PQESAVE2            YES--BUILD NEW TABLE ENTRY           42800020
         LR    R3,R4               NO--UPDATE PTR                       43000020
PQESVLP2 LA    R4,4(R4)            INCR R4 TO NEXT ENTRY IN TABLE       43200020
         TM    0(R4),PQEACT        IS THIS ENTRY USED                   43400020
         BZ    PQESAVE1            NO--PQE ADDR DID NOT MATCH           43600020
         L     R1,0(R4)            YES--LOAD ADDR OF SAVED PQE ADDR     43800020
         LA    R1,0(R1)            CLEAR FLAGS                          44000020
         CR    R8,R1               COMPARE SAVED PQE TO SUBJECT PQE     44200020
         BCR   8,R9                RETURN +0 IF EQUAL                   44400020
         TM    0(R4),PQELAST       IS THIS THE LAST ENTRY IN THIS TABLE 44600020
         BNO   PQESVLP2            NO--LOOK AT NEXT ENTRY               44800020
         B     PQESVLP1            YES--LOOK AT NEXT TABLE              45000020
PQESAVE1 IC    R1,0(R4)            GET FLAGS                            45200020
         ST    R8,0(R4)            STORE PQE ADDR                       45400020
         STC   R1,0(R4)            STORE FLAGS BACK                     45600020
         OI    0(R4),PQEACT        SET THIS ENTRY ACITVE                45800020
         B     4(R9)               RETURN +4                            46000020
         SPACE                                                          46200020
PQESAVE2 GETMAIN R,LV=24           GET CORE FOR PQE TABLE               46400020
         XC    0(24,R1),0(R1)      CLEAR GOTTEN CORE                    46600020
         ST    R1,0(R3)            LINK NEW TABLE BLOCK ONTO LIST       46800020
         OI    20(R1),PQELAST      SET PQELAST FLAG ON                  47000020
         LA    R4,4(R1)            ADDR OF FIRST ENTRY IN TABLE         47200020
         B     PQESAVE1            GO SAVE SUBJECT PQE ADDR IN NEW TBL  47400020
         SPACE 3                                                        47600020
*********************************************************************** 47800020
*                                                                     * 48000020
*   ERROR IN MVT REGION BOUNDRY ROUTINE                               * 48200020
*                                                                     * 48400020
*********************************************************************** 48600020
         SPACE                                                          48800020
         DROP  BASE1                                                    49000020
         USING MVTBERR,R15         BASE ERROR HANDLER ON EP TO          49200020
*                                  GET STARTED                          49400020
MVTBERR  LA    R13,BDYSAVE         POINT TO FUB'S SAVE AREA             49600020
         LM    R14,R12,12(R13)     LOAD UP REGS                         49800020
         DROP  R15                                                      50000020
         USING RGNBNDRY,BASE1      SHIFT BACK TO REG 11 AS BASE         50200020
         L     BUFREG,CURBUF       LOAD ADDR OF OUTPUT BUFFER FOR BASE  50400020
         USING OUTBUF,BUFREG                                            50600020
         BRWRITE 1                 SPACE A LINE                         50800020
         LA    R4,BNDERRM+40       ADDR OF WHERE TCB ADDR GOES          51000021
         LA    PREG,BNDJST         ADDR OF JOB STEP TCB ADDR            51200020
         L     R15,AADRCNVT        ADDR OF 3 BYTE CONVERT ROUTINE       51400020
         BALR  RETREG,R15          LINK TO CONVERT ROUT                 51600020
         MVC   ADDR(L'BNDERRM),BNDERRM MOVE ERROR MSG TO BUFFER         51800020
         BRWRITE 1                 PRINT ERROR MSG                      52000020
         B     BNDRY17A            END FOR THIS JOB                     52200020
         SPACE 3                                                        52400020
*********************************************************************** 52600020
*                                                                     * 52800020
*   ROUTINE FOR DETERMINING BOUNDRIES OF PARTITIONS IN PCP AND MFT    * 53000020
*                                                                     * 53200020
*********************************************************************** 53400020
         SPACE                                                          53600020
BNDRY20  MVC   BNDERASV(4),ERRADDR SAVE CALLER'S ERROR RTN ADDR  A53323 53650001
         LA    R15,BNDERROR                                      A53323 53700001
         ST    R15,ERRADDR         ENABLE MY ERROR RTN ADDR      A53323 53750001
         LA    R7,0(R2)            SAVE TCB ADDR IN R7                  53800001
         ST    R2,BNDJST           SAVE TCB IN CASE OF ERROR     A53323 53850001
         LA    PREG,TCBMSS(R2)     ADDR OF PTR TO BOUNDRY BOX           54000020
         BRREAD  (PREG),DATA,TJID=0                                     54200020
         L     R8,0(PREG)          PTR TO BOUNDRY BOX                   54400020
BNDRY20A LA    PREG,4(R8)          ADDR OF BEGINNING OF PARTITION       54600020
         BRREAD  (PREG)                                                 54800020
         L     R3,0(PREG)          BEGINNING OF PARTITION TO R3         55000020
         LA    PREG,8(R8)          ADDR OF END OF PARTITION             55200020
         BRREAD  (PREG)                                                 55400020
         L     R4,0(PREG)          END OF PARTITION TO R4               55600020
         LA    R4,0(R4)            TO CLEAR POS HI BYTE                 55800020
         LTR   R4,R4               IS ENDING ADDR 0                     56000020
         BZ    BNDRY20B            YES--NO PARTITION                    56200020
         L     R15,ATIOTSV         LOAD ADDR OF TIOT SAVE ROUTINE       56400020
         BALR  RETREG,R15          SAVE NAMES, BOUNDRIES, AND TCB ADDR  56600020
         STM   R3,R4,PCBLIST       SET UP P-LIST TO PCB ENQ             56800020
         LA    PREG,PCBLIST        POINT TO P-LIST                      57000020
         L     R15,APCBENQ         LOAD ADDR OF PCB ENQUEUE ROUTINE     57200020
         BALR  RETREG,R15          SAVE ADDRS OF PARTITION TO BE        57400020
*                                  PRINTED                              57600020
BNDRY20B TM    SWB,SEQ1            IS SW SET                            57800020
         BO    BNDRY1              YES--ALL DONE WITH THIS TCB          58000020
         BRREAD  (R8)              NO--LETS TEST FOR HIERARCHY SUPPORT  58200020
         TM    0(PREG),X'01'       TEST FOR HIERARCHY SUPPORT           58400020
         BZ    BNDRY2              BR IF NOT                     A53323 58600001
         OI    SWB,SEQ1            YES--SET SEQ SW                      58800020
         LA    R8,12(R8)           INCR BNDRY BOX ADDR TO HIERARCHY 1   59000020
*                                  POINTERS                             59200020
         B     BNDRY20A            INCLUDE HIER 1 TO BE PRINTED         59400020
BNDRY2   MVC   ERRADDR(4),BNDERASV RESTORE PREVIOUS ERROR ADDR   A53323 59450001
         B     BNDRY1              GET NEXT TCB                  A53323 59500001
         SPACE 3                                                        59600020
BNDDONE  L     R13,4(R13)          POINT TO CALLER'S SAVE AREA          59800020
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGS                60000020
         BR    RETREG              RETURN                               60200020
         EJECT                                                          60250001
*********************************************************************** 60410001
*                                                                     * 60420001
*   ROUTINE FOR HANDLING BRREAD ERRORS WHILE READING PARTITION        * 60450001
*   BOUNDARY BOX.                                                     * 60500001
*                                                                     * 60510001
*********************************************************************** 60520001
         DROP  BASE1                                             A53323 60530001
         USING *,R15                                             A53323 60540001
BNDERROR LA    R13,BDYSAVE         GET MY SAVE AREA ADDR         A53323 60542001
         LM    R14,R12,12(R13)     RESTORE MY REGISTERS          A53323 60544001
         DROP  R15                                               A53323 60546001
         USING RGNBNDRY,BASE1                                    A53323 60548001
         L     BUFREG,CURBUF       LOAD ADDR OF OUTPUT BUFFER    A53323 60548401
         BRWRITE 1                 SPACE A LINE                  A53323 60548801
         LA    R4,PRTERMSG+43      GET ADDR FOR TCB IN MSG       A53323 60549201
         LA    PREG,BNDJST         PUT TCB ADDR IN PARAMETER REG A53323 60549601
         L     R15,AADRCNVT        GET ADDR OF 3 BYTE CONVERT RT A53323 60549701
         BALR  RETREG,R15          GO TO CONVERT RTN             A53323 60549801
         MVC   ADDR(L'PRTERMSG),PRTERMSG  MOVE MSG TO BUFFER     A53323 60549901
         BRWRITE 2                 PRINT THE MSG                 A53323 60566601
         B     BNDRY2              GO RESTORE ERROR RTN ADDR     A53323 60576601
         EJECT                                                          60583301
*********************************************************************** 60600020
*                                                                     * 60800020
*   CONSTANTS FOR RGNBNDRY ROUTINE                                    * 61000020
*                                                                     * 61200020
*********************************************************************** 61400020
BDYSAVE  DC    18F'0'              FUB'S SAVE AREA                      61600020
         SPACE                                                          61800020
PQETBL   DC    F'0'                ADDR OF PTR TO DUMMY PQE PTR TABLE   62000020
BNDERASV DC    F'0'                                                     62200020
BNDJST   DC    F'0'                                                     62400020
BNDTOPT  DC    F'0'                                                     62600020
BNDTLST  DC    F'0'                                                     62800020
BNDTSAV  DC    F'0'                                                     63000020
ATIOTSV  DC    A(TIOTSV)           ADDR OF TIOT SAVE ROUTINE            63200020
PTIOTTST DC    A(TIOTTST)          ADDR OF TIOT TEST ROUTINE            63400020
PTIOTPRG DC    A(TIOTPRGE)         ADDR OF TIOT PURGE ROUTINE           63600020
*                                  THESE TWO AD-CONS MUST BE IN ORDER   63800020
*                                  TST-PRGE BECAUSE INIT USES LM-STM    64000020
PCBLIST  DC    2F'0',H'0'                                               64200020
TCBCNTA  DC    H'0'                                                     64400020
*                                                                A38027 64450021
BNDERRM  DC    C'ERROR FINDING REGION BOUNDARIES FOR TCB XXXXXX '       64600021
BDYSW    DC    BL8'00000000'       BIT 1 - INIT SWITCH                  64800020
PQECTN   DC    X'00'               PQE LOOP COUNTER              A36406 64850020
PRTERMSG DC    C'ERROR FINDING PARTITION BOUNDARIES FOR TCB XXXXXX '    64900021
*                                                                A53323 64950021
         DROP  BASE1                                                    65000020
         EJECT                                                          65200020
TIOTSV   CSECT                                                          65400020
         SPACE                                                          65600020
*********************************************************************** 65800020
*                *** TIOT ELEMENT ROUTINES ***                        * 65850021
*                                                                     * 65900021
* STATUS--OS/360 - RELEASE 21.0                                       * 65950021
*                                                                     * 65960021
* FUNCTION--                                                          * 65970021
*   THIS IS A COLLECTION OF THREE ROUTINES THAT 1) SAVE THE           * 65980021
*   JOB/PROC/STEP NAMES WITH THEIR REGION BOUNDARIES, 2) RETURN       * 65990021
*   THE ABOVE, AND 3) PURGE ALL THAT HAD BEEN SAVED.                  * 65992021
*                                                                     * 65994021
* ENTRY POINTS--                                                      * 65996021
*   UPON ENTRY AT TIOTSV THIS ROUTINE WILL SAVE THE JOB NAME, STEP    * 66800020
*   NAME, THE PROCEEDURE STEP NAME, AND THE BOUNDRIES OF THE REGION   * 67000020
*   WHOSE TCB IS POINTED TO BY R7.                                    * 67200020
*   UPON ENTRY AT TIOTTST THE CURRENT PRINT ADDRESS WILL BE COMPARED  * 67400020
*   TO THE BEGINNING ADDRESSES IN THE TIOT ELEMENTS FOR AN EQUAL. IF  * 67600020
*   AN EQUAL IS FOUND THE ADDRESSES OF THE REGION BOUNDRIES AS WELL   * 67800020
*   AS THE THREE NAMES WILL BE MOVED TO THE ADDRESS IN R1 AND THE     * 68000020
*   ELEMENT WILL BE FREED.                                            * 68200020
*   IF ENTRY IS AT TIOTPRGE ALL ELEMENTS WILL BE FREED.               * 68400020
*   TIOTSV RECEIVES CONTROL FROM IMDPRFUB.  TIOTTST AND TIOTPRGE      * 68450021
*   RECEIVE CONTROL THROUGH AN ENTRY IN THE COMMON AREA.              * 68500021
*   ALL ENTRY POINTS USE STANDARD LINKAGE.                            * 68550021
*                                                                     * 68560021
* INPUT--                                                             * 68570021
*   FOR TIOTTST:  REGISTER 0 - LOW ADDRESS OF REGION                  * 68580021
*                 REGISTER 1 - ADDRESS OF LOCATION TO STORE OUTPUT    * 68590021
*   FOR TIOTSV:   REGISTER 3 - LOW ADDRESS OF REGION                  * 68592021
*                 REGISTER 4 - HIGH ADDRESS OF REGION                 * 68594021
*                 REGISTER 7 - ADDRESS OF REGION'S TCB                * 68596021
*   FOR ALL 3:    REGISTER 12 - ADDRESS OF COMMON CSECT               * 68598021
*                                                                     * 68598421
* OUTPUT--                                                            * 68598821
*   FOR TIOTSV:    RETURN CODE 0 - REGION WAS NOT ON QUEUE            * 68599221
*                  RETURN CODE 4 - REGION WAS ON QUEUE                * 68599621
*   FOR TIOTTST:   RETURN CODE 0 - REGION WAS ON QUEUE                * 68599721
*                  RETURN CODE 4 - REQION WAS NOT ON QUEUE            * 68599821
*                  TIOT ELEMENT (LESS LINK ADDRESS) IS MOVED TO       * 68599921
*                    LOCATION WHOSE ADDRESS IS IN REGISTER 1          * 68649921
*                                                                     * 68659921
* EXITS, NORMAL--                                                     * 68669921
*   RETURN TO CALLER THROUGH STANDARD LINKAGE.                        * 68679921
*                                                                     * 68689921
* EXITS, ERROR--                                                      * 68691921
*   NONE                                                              * 68693921
*                                                                     * 68695921
* TABLES/WORK AREAS--                                                 * 68697921
*   THE TIOT ELEMENT BUILT BY TIOTSV IS FORMATTED AS FOLLOWS:         * 68698321
*                                                                     * 68698721
*          0 *************************************                    * 68699121
*            * LINK TO NEXT TIOT ELEMENT OR ZERO *                    * 68699521
*          4 *************************************                    * 68699621
*            * LOW ADDRESS OF REGION             *                    * 68699721
*          8 *************************************                    * 68699821
*            * HIGH ADDRESS OF REGION            *                    * 68733221
*         12 *************************************                    * 68743221
*            * TCB ADDRESS FOR REGION            *                    * 68753221
*         16 *************************************                    * 68763221
*            * JOB NAME                          *                    * 68765221
*         24 *************************************                    * 68765621
*            * PROCEDURE NAME (ELSE STEP NAME)   *                    * 68766021
*         32 *************************************                    * 68766421
*            * STEP NAME (ELSE BLANKS)           *                    * 68766521
*         40 *************************************                    * 68777621
*                                                                     * 68787621
* ATTRIBUTES--NON-REUSEABLE                                           * 68788021
*                                                                     * 68788421
* CHARACTER CODE DEPENDENCY--NONE                                     * 68788821
*                                                                     * 68792521
* NOTES--                                                             * 68794501
*   IF THE TIOT FOR ANY TCB CAN NOT BE ACCESSED, 'UNKNOWN' IS         * 68794901
*   SUBSTITUTED FOR THE 'JOBNAME' IN THE TIOT ELEMENT.  THE PROCEDURE * 68795301
*   NAME AND STEP NAME FIELDS ARE BLANKED OUT.                        * 68795701
*                                                                     * 68796321
*********************************************************************** 68800020
         SPACE                                                          69000020
         STM   R14,R12,12(R13)     SAVE CALLER'S REGS                   69200020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             69400020
         USING *,BASE1                                                  69600020
TIOTBASE LA    R2,TIOTSAVE         SAVE AREA CHAINING            A53323 69800001
         ST    R13,TIOTSAVE+4                                           70000020
         ST    R2,8(R13)                                                70200020
         LR    R13,R2              TIOTSAVE USED BY ALL 3 TIOT QUEUE    70400020
*                                  ROUTINES                             70600020
         MVC TIOTERSV(4),ERRADDR   SAVE CALLER'S ERROR           A53323 70650001
*                                  ROUTINE ADDRESS               A53323 70700001
         LA    R2,TIOTERR          GET ADDR OF TIOT ERROR RTN    A53323 70750001
         ST    R2,ERRADDR          PUT IT IN COMMON              A53323 70760001
         LA    R0,TIOTLNGH         LENGTH OF TIOT ELEMENT               70800020
         GETMAIN R,LV=(0)          GET CORE FOR ELEMENT                 71000020
         LA    R3,0(R3)            CLEAR HIGH ORDER BYTE                71200020
         STM   R3,R4,4(R1)         STORE BEGINNING AND ENDING ADDRESSES 71400020
*                                  OF REGION                            71600020
         ST    R7,12(R1)           STORE TCB ADDR IN TIOT ELEMENT       71800020
         LR    R3,R1               SAVE NEW ELEMENT ADDR                72000020
         LA    R4,16(R1)           LOAD INDEX                           72200020
         LA    R6,3                LOAD COUNT                           72400020
         LA    PREG,TCBTIOT(R7)    ADDR OF PTR TO TIOT                  72600020
         BRREAD  (PREG),DATA,TJID=0                                     72800020
         L     R5,0(PREG)          LOAD TIOT ADDR TO R5                 73000020
         LA    R5,0(R5)            CLEAR POSSIBLE HI BYTE               73200020
TIOTSVLP LTR   PREG,R5             TIOT ADDRESS TO PARM REG             73400020
         BZ    TIOTNSV             NO TIOT--BLANK ELEMENT               73600020
         C     R5,ADDRMAX          COMPARE TIOT ADDR TO ADDRAMX         73800020
         BH    TIOTNSV             GT ADDRMAX--NO TIOT                  74000020
         BRREAD  (PREG)                                                 74200020
         MVC   0(8,R4),0(PREG)     MOVE NAME                            74400020
         LA    R4,8(R4)            INCR INDEX                           74600020
         LA    R5,8(R5)            INCR TO NEXT NAME                    74800020
         BCT   R6,TIOTSVLP         LOOP FOR ALL THREE NAMES             75000020
         B     TIOTSV4             LOOK FOR EQUAL ELEMENT               75200020
TIOTNSV  MVI   0(R4),X'40'         BLANK OUT JOB, STEP, AND PROC STEP   75400020
         MVC   1(23,R4),0(R4)      NAMES                                75600020
TIOTSV4  L     R6,TIOTADDR         ADDR OF FIRST ELEMENT                75800020
TIOTSV3  LTR   R6,R6               TEST FOR END OF CHAIN                76000020
         BZ    TIOTSV1             BR IF END--NO EQUAL ELEMENT          76200020
         CLC   4(TIOTLNGH-4,R6),4(R3) TEST FOR AN EQUAL ELEMENT         76400020
*                                  ALREADY ON THE CHAIN                 76600020
         BE    TIOTSV2             EQUAL--FREE ELEMENT JUST BUILT       76800020
         L     R6,0(R6)            LOAD ADDR OF NEXT ELEMENT IN CHAIN   77000020
         B     TIOTSV3             LOOP TO END OF CHAIN OR EQUAL ELE    77200020
         SPACE                                                          77400020
TIOTSV1  MVC   0(4,R3),TIOTADDR    LINK NEW ELEMENT TO TOP OF CHAIN     77600020
         ST    R3,TIOTADDR                                              77800020
         SR    R15,R15             RC = 0                               78000020
         B     TIOTRET1            RETURN TO CALLER              A53323 78200001
         SPACE                                                          78400020
TIOTSV2  LA    R0,TIOTLNGH         LOAD LENGTH OF AREA TO FREE          78600020
         FREEMAIN R,LV=(0),A=(R3)  FREE NEWLY CREATED DUPL ELEMENT      78800020
         LA    R15,4               RC = 4                               79000020
TIOTRET1 MVC   ERRADDR(4),TIOTERSV RESTORE CALLERS ERROR ADDR    A53323 79050001
         B     TIOTRET             RETURN TO CALLER                     79200020
         SPACE 3                                                        79400001
         DROP  BASE1                                             A53323 79450001
         USING *,R15                                             A53323 79500001
TIOTERR  LA    R13,TIOTSAVE        POINT TO TIOTSV SAVE AREA     A53323 79550001
         LM    R14,R12,12(R13)     RESTORE TIOTSV'S REGISTERS    A53323 79560001
         DROP  R15                                               A53323 79570001
         USING TIOTBASE,BASE1                                    A53323 79580001
         MVC   0(8,R4),UNKNOWN     MOVE UNKNOWN TO ELEMENT       A53323 79590001
         MVC   8(16,R4),7(R4)      BLANK OUT THE REST            A53323 79592001
         B     TIOTSV4             CONTINUE                      A53323 79594001
         DROP  BASE1                                                    79600020
         EJECT                                                          79800001
TIOTTST  STM   R14,R12,12(R13)     SAVE CALLER'S REGS                   80000020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             80200020
         USING *,BASE1                                                  80400020
         LA    R2,TIOTSAVE         SAVE AREA CHAINING                   80600020
         ST    R13,TIOTSAVE+4                                           80800020
         ST    R2,8(R13)                                                81000020
         LR    R13,R2              TIOTSAVE USED BY ALL 3 TOIT QUEUE    81200020
*                                  ROUTINES                             81400020
         LA    R4,TIOTADDR         INITIALIZE R4                        81600020
TIOTTLP  L     R3,0(R4)            LOAD ADDR OF TIOT ELEMENT            81800020
         LTR   R3,R3               END OF LIST                          82000020
         BZ    TIOTTST2            YES--RETURN CODE OF 4                82200020
         C     R0,4(R3)            DOES CURRENT ADDR EQ STARTING ADDR   82400020
*                                  OF JOB STEP REGION                   82600020
         BE    TIOTTST1            YES--MOVE ADDRESSES AND NAMES        82800020
         LR    R4,R3                                                    83000020
         B     TIOTTLP             LOOP THROUGH LIST                    83200020
         SPACE                                                          83400020
TIOTTST1 MVC   0(36,PREG),4(R3)    MOVE NAMES TO WORK AREA              83600020
         MVC   0(4,R4),0(R3)       DEQ ELEMENT                          83800020
         LA    R0,TIOTLNGH         LENGTH OF ELEMENT                    84000020
         LR    R1,R3               ADDR OF ELEMENT                      84200020
         FREEMAIN R,LV=(0),A=(1)   FREE CORE OCCUPIED BY ELEMENT        84400020
         SR    R15,R15             ZERO RETURN CODE                     84600020
         B     TIOTRET             RETURN                               84800020
         SPACE                                                          85000020
TIOTTST2 LA    R15,4               RETURN CODE OF 4                     85200020
         B     TIOTRET             RETURN                               85400020
         SPACE                                                          85600020
         DROP  BASE1                                                    85800020
         EJECT                                                          86000020
TIOTPRGE STM   R14,R12,12(R13)     SAVE CALLER'S REGS                   86200020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             86400020
         USING *,BASE1                                                  86600020
         LA    R2,TIOTSAVE         SAVE AREA CHAINING                   86800020
         ST    R13,TIOTSAVE+4                                           87000020
         ST    R2,8(R13)                                                87200020
         LR    R13,R2              TIOTSAVE USED BY ALL 3 TIOT QUEUE    87400020
*                                  ROUTINES                             87600020
         LA    R4,TIOTADDR         INITIALIZE R4                        87800020
TPRGELP  L     R3,0(R4)            LOAD ADDR OF TIOT ELEMENT            88000020
         LTR   R3,R3               END OF LIST                          88200020
         BZ    TIOTRET             YES--ALL DONE                        88400020
         MVC   0(4,R4),0(R3)       REMOVE ELE FROM LIST                 88600020
         LR    R1,R3               LOAD ADDR TO R1 FOR FREEMAIN         88800020
         LA    R0,TIOTLNGH         ELEMENT LENGTH                       89000020
         FREEMAIN R,LV=(0),A=(1) FREE CORE OCCUPIED BY ELEMENT          89200020
         B     TPRGELP             LOOP AND FREE ALL                    89400020
         SPACE 2                                                        89600020
*                                  ALL TIOT QUEUE ROUTINE EXIT THOUGH   89800020
TIOTRET  L     R13,4(R13)          HERE - POINT CALLER'S SAVE AREA      90000020
         L     R14,12(R13)                                              90200020
         LM    R0,R12,20(R13)     RESTORE CALLER'S REGS                 90400020
         BR    RETREG              RETURN                               90600020
         SPACE 3                                                        90800020
*****    SAVE AREA FOR TIOT ROUTINE     *****                           91000021
         SPACE                                                          91200020
TIOTSAVE DC    18F'0'              TIOT QUEUE ROUTINES' SAVE AREA       91400020
FUBPCH   DC    16F'0'              PATCH AREA                    A53323 91450001
TIOTERSV DC    F'0'                                              A53323 91500001
UNKNOWN  DC    C'UNKNOWN '                                       A53323 91550001
         SPACE                                                          91600020
         END                                                            91800020
