         TITLE 'IMDPRFUR - ALL REGIONS ROUTINE'                         00900020
IMDPRFUR START                                                          01800020
*********************************************************************** 02700020
*                                                                     * 02750021
* STATUS                                                              * 02760021
*    OS RELEASE 21                                                    * 02770021
*                                                                     * 02780021
* C 126500,288000,603000,846000                                   M6147 02800021
* A 324500-325000,351500-352500,504500-505000,612500-618500       M6147 02850021
* A 648500-650000,666500-674988,738500-739000,819500-820000       M6417 02900021
* A 837100-842500,873500-881920,900500-904500                     M6147 02950021
* D 540000-567000                                                 M6147 03000021
*                                                                     * 03600020
* FUNCTION                                                            * 03650021
*    THIS ROUTINE PLACES ON THE TCBLIST ALL JSTCBS IF MVT OR          * 03700021
*    MFT WITH ATTACH OPTION. IF PCP OR MFT W/O ATTACH OPTION ALL      * 03750021
*    TCBS WILL BE PLACED ON THE TCBLIST.                              * 03800021
*                                                                     * 03850021
* ENTRY POINTS                                                        * 03900021
*    IMDPRFUR IS THE ONLY ENTRY POINT.  IF THE INIT SWITCH IN FUR     * 03950021
*    IS NOT ON THE ENTRY POINT ADDRESS IS STORED IN COMMON (AALLRGN), * 04000021
*    THE SWITCH IS TURNED ON AND CONTROL IS RETURNED TO THE CALLER    * 04050021
*    (IMDPRSEG IN THIS CASE).  IF THE INIT SWITCH IS ON, THE LIST     * 04100021
*    OF TCB ADDRESSES IS BUILT AND CONTROL IS RETURNED TO THE CALLER  * 04150021
*    (FXT, PAL, OR PJB).                                              * 04200021
*                                                                     * 04250021
* INPUT                                                               * 04300021
*    REGISTER 12 - ADDRESS OF THE COMMON CSECT                        * 04350021
*                                                                     * 04400021
* OUTPUT                                                              * 04450021
*    THE LIST OF JOB STEP TCB ADDRESSES POINTED TO BY TCBLIST         * 04460021
*    IN COMMON                                                        * 04470021
*                                                                     * 04480021
* EXTERNAL REFERENCES                                                 * 04490021
*         IMDPRDMP REFERENCES                                         * 04492021
*         1. BRREAD - TO GET DATA FROM THE DUMP                       * 04494021
*         2. BRWRITE - TO WRITE OUTPUT COMMENTS TO PRINTER DD         * 04496021
*         3. TCBSAVE - TO PUT TCB ADDRESSES ON THE TCBLIST            * 04498021
*         4. TCBREMV - TO PURGE TCB LIST'S USED TO DETECT LOOPS       * 04498421
*         5. ADRCNVT - TO CONVERT A TCB ADDRESS FOR USE IN A COMMENT  * 04498821
*                                                                     * 04499221
* EXITS, NORMAL                                                       * 04499621
*         1. ARGEXIT - WHEN CALLED BY MODULES OTHER THAN IMDPRSEG     * 04499721
*         2. ARGEXIT1 - WHEN CALLED BY SEG TO INITIALIZE ONLY         * 04499821
*         NO RETURN CODES ARE SET IN EITHER CASE                      * 04499921
*                                                                     * 04549921
* EXITS, ERROR                                                        * 04559921
*         ARGEXIT - IF A LOOP IS DETECTED ONE OF THE FOLLOWING IS     * 04569921
*         WRITTEN TO PRINTER DATA SET FIRST:                          * 04579921
*           LOOP IN TCB READY QUEUE                                   * 04589921
*           LOOP IN DAUGHTER CHAIN FOR TCB XXXXXX                     * 04591921
*                                                                     * 04593921
* TABLES/WORK AREAS                                                   * 04595921
*    TCBLIST POINTS TO LIST OF TCB ADDRESSES BUILT BY FUR;  ITS FORMAT* 04597921
*    IS AS FOLLOWS:                                                   * 04598321
*         ***********************                                     * 04598721
*         * PTR TO NEXT ELEMENT *                                     * 04599121
*         ***********************                                     * 04599521
*         *   TCB  ADDRESS      *                                     * 04599621
*         ***********************                                     * 04599721
*                                                                     * 04599821
* ATTRIBUTES                                                          * 04649821
*    REUSEABLE                                                        * 04659821
*                                                                     * 04669821
* CHARACTER CODE DEPENDENCY                                           * 04679821
*    NONE                                                             * 04689821
*                                                                     * 04691821
* NOTES                                                               * 04693821
*    NONE                                                             * 04695821
*********************************************************************** 04697821
*********************************************************************** 09900020
*/*IMDPRFUR: CHART (SEQ) */                                             09950021
*/*HEADER                                                               10050021
*/*IMDPRFUR - ALL REGIONS ROUTINE FLOWCHARTS                            10100021
*/*                                                        PAGE #   */  10150021
*/*IMDPRFUR: E START */                                                 10160021
*/* P SET UP ADDRESSABILITY */                                          10170021
*/* D (NO,ALLRGNS,YES,) INIT PASS */                                    10180021
*/* P PUT ENTRY ADDR IN COMMON */                                       10190021
*/* M (,ARGEXIT1) SET INIT DONE SWITCH ON */                            10192021
*/*ALLRGNS: D (NO,ALLRGNS4,YES,) MVT OR MFT/ATTACH */                   10194021
*/* P LOAD ADDR OF HEAD TCB */                                          10196021
*/* S HDLOOPTS: TEST FOR LOOP IN TCB READY QUEUE */                     10198021
*/*ALLOOP: P SAVE TCB ADDR IN R7 */                                     10198421
*/* D (YES,ARGEXIT,NO,) IS TCB ADDR = 0 */                              10198821
*/* S DLOOPTST: TEST FOR LOOP IN DAUGHTER Q. FOR PRES. TCB */           10199221
*/*ALLOOP1: D (YES,CURSAVE,NO,) IS TCB MASTER SCHEDULER */              10199621
*/* P POINT TO TCB'S JOB STEP TCB PTR FOR MVT SYSTEM */                 10199721
*/* D (YES,ALLRGNS5,NO,) IS THIS MVT DUMP */                            10199821
*/* P POINT TO TCB'S JOB STEP TCB PTR FOR MFT */                        10199921
*/*ALLRGNS5: S BRREAD: GET JOB STEP TCB PTR FOR PRES. TCB */            10249921
*/* D (YES,ALLRGNS3,NO,) IS JOB STEP TCB = MASTER */                    10259921
*/* D (NO,PRESAVE,YES,) IS PRES. TCB = JOB STEP TCB */                  10269921
*/*ALLRGNS3: P POSITION TO DAUGHTER PTR OF PRES. TCB */                 10279921
*/* S BRREAD: GET DAUGHTER PTR */                                       10289921
*/* D (YES,CURSAVE,NO,) IS IT = 0 */                                    10291921
*/* P MAKE DAUGHTER PRESENT TCB */                                      10293921
*/* S (,ALLOOP1) DLOOPTST: TEST FOR LOOP IN DAUGHTER QUEUE */           10295921
*/*PRESAVE: P MAKE JOB STEP TCB PRESENT TCB */                          10297921
*/*CURSAVE: S TCBSAVE: SAVE PRES. TCB ON TCB LIST */                    10298321
*/* D (YES,ALLOOP2,NO,) IS DAUGHTER LIST = 0 */                         10298721
*/* P TLSTSAV = TCBLIST; TCBLIST = DLIST */                             10299121
*/* S TCBREMV: PURGE ALL TCB'S FROM DLIST */                            10299521
*/* P MAKE DLIST = 0; TCBLIST = TLSTSAV */                              10299621
*/*ALLOOP2: P POINT TO NEXT TCB ADDR IN READY QUEUE */                  10299721
*/* S BRREAD: GET NEXT TCB IN READY QUEUE */                            10299821
*/* S (,ALLOOP) HDLOOPTS: TEST FOR LOOP IN TCB READY QUEUE */           10349821
*/*DLOOPTST: N ROUTINE TO TEST FOR LOOP IN DAUGHTER QUEUE */            10359821
*/* P TLSTSAV = TCBLIST; TCBLIST = DLIST */                             10369821
*/* S TCBSAVE: SAVE DAUGHTER TCB ON DLIST */                            10379821
*/* P DLIST = TCBLIST; TCBLIST = TLSTSAV */                             10389821
*/* D (YES,%A,NO,) DUPLICATE ON DLIST */                                10391821
*/* R RETURN VIA R9 */                                                  10393821
*/*%A: S BRWRITE: SKIP TO TOP OF PAGE */                                10395821
*/* P MOVE DAUGHTER LOOP MSG TO BUFFER */                               10397821
*/* S ADRCNVT: CONVERT PRES. HEAD TCB ADDR FOR MSG */                   10398221
*/* S (,ALLOOP2) BRWRITE: PRINT THE MSG */                              10398621
*/*ALLRGNS4: N RTN TO SAVE ADDRS. OF ALL TCB'S FOR PCP AND MFT */       10399021
*/* P LOAD HEAD TCB ADDR */                                             10399421
*/* S HDLOOPTS: TEST FOR LOOP IN TCB READY QUEUE */                     10399521
*/*ALLOOP4: D (YES,ARGEXIT,NO,) IS TCB PTR = 0 */                       10399621
*/* S TCBSAVE: SAVE TCB ADDR ON TCB LIST */                             10399721
*/* P POINT TO NEXT TCB */                                              10449721
*/* S BRREAD: GET PTR TO NEXT TCB */                                    10459721
*/* S (,ALLOOP4) HDLOOPTS: TEST FOR LOOP IN TCB READY QUEUE */          10469721
*/*ARGEXIT: P TLSTSAV = TCBLIST; TCBLIST = HEADLIST */                  10479721
*/* S TCBREMV: REMOVE ALL TCB'S FROM HEADLIST */                        10489721
*/* P HEADLIST = 0; TCBLIST = TLSTSAV */                                10491721
*/*ARGEXIT1: P RESTORE REGS */                                          10493721
*/* R RETURN */                                                         10495721
*/*HDLOOPTS: P TLSTSAV.  = TCBLIST; TCBLIST = HEADLIST */               10497721
*/* S TCBSAVE: SAVE TCB ON HEADLIST */                                  10498121
*/* P HEADLIST = TCBLIST; TCBLIST = TLSTSAV */                          10498521
*/* D (YES,%B,NO,) WAS THERE A DUP TCB */                               10498921
*/* R RETURN VIA R9 */                                                  10499321
*/*%B: S BRWRITE: SKIP TO TOP OF PAGE */                                10499421
*/* P MOVE LOOP-IN- READY QUEUE MSG TO BUFFER */                        10499521
*/* S (,ARGEXIT) BRWRITE: PRINT THE MSG */                              10499621
*/*IMDPRFUR: END */                                                     10499721
         SPACE                                                          10800020
         EQUATES                                                        11700020
         COMMON                                                         12600020
         OUTBUFM                                                  M6147 12650021
IMDPRFUR CSECT                                                          13500020
INIT     EQU   128                                                      14400020
         STM   R14,R12,12(R13)     STORE CALLER'S REGISTERS             15300020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             16200020
         USING *,BASE1                                                  17100020
         LA    R2,ARGSAVE          SAVE AREA CHAIN                      18000020
         ST    R13,ARGSAVE+4                                            18900020
         ST    R2,8(R13)                                                19800020
         LR    R13,R2              ENTRY COMPLETE                       20700020
         SPACE                                                          21600020
         USING COMMON,COMBASE      COMMON CSECT BASED ON REG12          22500020
         SPACE                                                          23400020
         TM    ARGSW,INIT          TEST FOR INITIALIZATION PASS         24300020
         BO    ALLRGNS             GO TO NORMAL FUNCTION IF DONE INIT   25200020
         ST    R15,AALLRGN         STORE EP ADDR IN COMMON CSECT SO     26100020
*                                  OTHERS CAN USE ARG                   27000020
         OI    ARGSW,INIT          INDICATE INIT DONE                   27900020
         B     ARGEXIT1            INIT DONE - EXIT               M6147 28800021
         SPACE                                                          29700020
ALLRGNS  TM    SWE,MVTSW+MFTATCH   TEST FOR MVT OR MFT ATTACH           30600020
         BZ    ALLRGNS4            BR IF PCP OR MFT W/O ATTACH          31500020
         L     R3,CVTHEAD          LOAD ADDR OF HIGHEST PRTY TCB        32400020
         BAL   R9,HDLOOPTS         LINK TO TEST FOR LOOP IN       M6147 32450021
*                                  TCB READY QUEUE                M6147 32500021
ALLOOP   LR    R7,R3               SAVE TCB ADDR IN R7                  32550021
         LTR   R2,R3               LOAD NEXT TCB ADDR TO R2 AND TEST    33300021
         BE    ARGEXIT             IF ZERO, DONE FINDING TCBS           35100020
         BAL   R9,DLOOPTST         LINK TO TEST FOR LOOP IN       M6147 35150021
*                                  DAUGHTER QUEUE FOR TCB         M6147 35200021
*                                  ADDRESSED BY REG 2             M6147 35250021
ALLOOP1  C     R2,MSTRTCB          IS THIS THE MASTER SCHED             36000020
         BE    CURSAVE             YES--GO SAVE IT                      36900020
         TM    SWE,MVTSW           IS THIS MVT DUMP                     37800020
         LA    PREG,JSTCB(R2)      TCB'S JOB STEP TCB ADDR FOR MVT      38700020
         BO    ALLRGNS5            BR IF MVT                            39600020
         LA    PREG,MFTJST(R2)     TCB'S JOB STEP TCB ADDR FOR MFT      40500020
ALLRGNS5 BRREAD  (PREG),,TJID=0                                         41400020
         CLC   MSTRTCB+1(3),1(PREG) TEST FOR JSTCB EQ MASTER            42300020
         BE    ALLRGNS3            YES--CONSIDER IT SAME AS IT'SELF     43200020
         C     R2,0(PREG)          DOES TCB ADDR EQ JSTCBADDR           44100020
         BNE   PRESAVE             NO--SAVE JSTCB ADDR                  45000020
ALLRGNS3 LA    PREG,DAUGHTER(R2)   ADDR OF DAUGHTER PTR                 45900020
         BRREAD  (PREG)                                                 46800020
         L     PREG,0(PREG)        LOAD DAUGHTER ADDRESS                47700020
         LTR   PREG,PREG           IS TI ZERO                           48600020
         BZ    CURSAVE             YES--SAVE THIS TCB ADDR              49500020
         LR    R2,PREG             LOAD DAUGHTER ADDR TO R2             50400020
         BAL   R9,DLOOPTST         LINK TO TEST FOR LOOP IN       M6147 50450021
*                                  DAUGHTER QUEUE                 M6147 50500021
         B     ALLOOP1             LOOP                                 51300020
         SPACE                                                          52200020
PRESAVE  L     R2,0(PREG)          LOAD JSTCB ADDR INTO R2              53100020
         SPACE                                                          57600020
CURSAVE  L     R15,ATCBSAVE        LOAD ADDR OF TCB SAVE ROUTINE        58500020
         BALR  RETREG,R15          SAVE THE TCB ADDR ON TCB LIST        59400020
*                                  LOOP THROUGH ALL MASTER SCHEDULAR    60300021
*                                  DAUGHTERS                            61200020
***  PURGE ANY TCB-S ON DAUGHTER QUEUE  ***                       M6147 61250021
         OC    DLIST(4),DLIST      TEST FOR QUEUE EMPTY           M6147 61300021
         BZ    ALLOOP2             BRANCH AROUND PURGE IF SO      M6147 61350021
         MVC   TLSTSAV(4),TCBLIST  SAVE TCB LIST BASE SO AS TO    M6147 61400021
*                                  BE ABLE TO USE TCB LIST        M6147 61450021
*                                  DEQUEUE ROUTINE                M6147 61500021
         MVC   TCBLIST(4),DLIST    POINT TO DAUGHTER LIST         M6147 61550021
         SR    R2,R2               INDICATE PURGE ALL             M6147 61600021
         L     R15,ATCBREMV        POINT TO PURGE ROUTINE         M6147 61650021
         BALR  RETREG,R15          LINK TO IT                     M6147 61700021
         ST    R2,DLIST            R2 IS STILL ZERO - STORE AS    M6147 61750021
*                                  NEW BASE OF DAUGHTER QUEUE     M6147 61800021
         MVC   TCBLIST(4),TLSTSAV  RESTORE TCB LIST BASE          M6147 61850021
         SPACE                                                          62100020
ALLOOP2  LA    PREG,TCBNEXT(R7)    ADDR OF PTR TO NEXT TCB IN READY QUE 63000020
         BRREAD  (PREG)                                                 63900020
         L     R3,0(PREG)          LOAD ADDR OF NEXT TCB TO R3          64800020
         LR    R2,R3               PASS TCB ADDRESS TO HEAD LOOP  M6147 64850021
*                                  TEST ROUTINE IN REG 2          M6147 64900021
         BAL   R9,HDLOOPTS         LINK TO TEST FOR LOOP IN       M6147 64950021
*                                  TCB READY QUEUE                M6147 65000021
         B     ALLOOP              LOOP                                 65700020
         EJECT                                                          66600021
******************************************************************M6147 66650021
*                                                                 M6147 66660021
*        ROUTINE TO TEST FOR LOOP IN DAUGTHER QUEUE FOR A         M6147 66662021
*                          PARTICULAR TCB                         M6147 66664021
*                                                                 M6147 66670021
******************************************************************M6147 66700021
         SPACE                                                          66750021
DLOOPTST MVC   TLSTSAV(4),TCBLIST  SAVE BASE OF TCB LIST SO AS    M6147 66800021
*                                  TO BE ABLE TO USE TCB LIST     M6147 66850021
*                                  ENQUEUE ROUTINE                M6147 66900021
         MVC   TCBLIST(4),DLIST    POINT TO BASE OF DAUGHTER      M6147 66950021
*                                  QUEUE                          M6147 67000021
         L     R15,ATCBSAVE        POINT TO TCB ENQUEUE           M6147 67050021
         BALR  RETREG,R15          LINK TO IT                     M6147 67100021
         MVC   DLIST(4),TCBLIST    SAVE NEW BASE OF DAUGHTER      M6147 67110021
*                                  QUEUE                          M6147 67120021
         MVC   TCBLIST(4),TLSTSAV  RESTORE BASE OF TCB LIST       M6147 67130021
         LTR   R15,R15             TEST RETURN CODE FROM ENQUEUE  M6147 67150021
         BCR   8,R9                ZERO MEANS NEW TCB, SO RETURN  M6147 67200021
*                                  NON-ZERO MEANS TCB ALREADY ON  M6147 67250021
*                                  QUEUE, SO FALL TROUGHT INTO    M6147 67300021
*                                  ERROR HANDLER                  M6147 67350021
         USING OUTBUF,BUFREG       BASE MAP OF OUTPUT LINE        M6147 67400021
         SPACE                                                          67450021
         BRWRITE  SKIP                                            M6147 67452021
         L     BUFREG,CURBUF       POINT TO CURRENT OUTPUT BUF    M6147 67460021
*                                  MOVE DAUGHTER LOOP MSG TO      M6147 67462021
         MVC   ADDR(L'DMSG),DMSG   OUTPUT AREA                    M6147 67470021
         ST    R7,TLSTSAV          STORE TCB ADDRESS FOR CONVERT  M6147 67480021
         LA    PREG,TLSTSAV        POINT TO ADDRESS               M6147 67490021
         LA    R4,ADDR+31          POINT TO POSITION IN MSG OF    M6147 67492021
*                                  TCB ADDRESS                    M6147 67494021
         L     R15,AADRCNVT        GET ADDR OF 3-BYTE CONVERT RTN M6147 67496021
         BALR  RETREG,R15          LINK TO IT                     M6147 67498021
         BRWRITE  2                PRINT LOOP MESSAGE             M6147 67498421
         B     ALLOOP2             CONTINUE DOWN CVT HEAD         M6147 67498821
         EJECT                                                          67500020
*********************************************************************** 68400020
*                                                                     * 69300020
*   SAVE ADDRESSES OF ALL TCBS FOR PCP AND MFT                        * 70200020
*                                                                     * 71100020
*********************************************************************** 72000020
         SPACE                                                          72900020
ALLRGNS4 L     R2,CVTHEAD          ADDR OF FIRST TCB IN TCB CHAIN       73800020
         BAL   R9,HDLOOPTS         LINK TO TEST FOR LOOP IN       M6147 73850021
*                                  CVT READY QUEUE                M6147 73900021
ALLOOP4  LA    R2,0(R2)            CLEAR POSSIBLE HIGH ORDER BYTE       74700020
         LTR   R2,R2               TEST FOR END OF CHAIN                75600020
         BE    ARGEXIT             DONE FINDING TCBS WHEN END           76500020
*                                  OF CHAIN IS FOUND                    77400020
         L     R15,ATCBSAVE        ADDR OF TCB SAVE ROUTINE             78300020
         BALR  RETREG,R15          SAVE TCB ADDR OF TCBLIST             79200020
         LA    PREG,TCBNEXT(R2)    ADDR OF PTR TO NEXT TCB              80100020
         BRREAD  (PREG),,TJID=0                                         81000020
         L     R2,0(PREG)          LOAD NEXT TCB ADDR TO R2             81900020
         BAL   R9,HDLOOPTS         LINK TO TEST FOR LOOP IN       M6147 81950021
*                                  TCB READY QUEUE                M6147 82000021
         B     ALLOOP4             LOOP THROUGH ALL                     82800020
         SPACE                                                          83700020
***  PURGE CVT HEAD LIST ON EXIT  ***                             M6147 83710021
ARGEXIT  MVC   TLSTSAV(4),TCBLIST  SAVE BASE OF TCB LIST SO       M6147 83750021
*                                  TO BE ABLE TO USE TCB PURGE    M6147 83800021
*                                  ROUTINE                        M6147 83850021
         MVC   TCBLIST(4),HEADLIST  POINT TO CVT HEAD LIST        M6147 83900021
         SR    R2,R2               INDICATE REMOVAL OF ALL TCB-S  M6147 83950021
         L     R15,ATCBREMV        POINT TO DEQUEUE ROUTINE       M6147 84000021
         BALR  RETREG,R15          LINK TO IT                     M6147 84050021
         ST    R2,HEADLIST         REG 2 STILL ZERO - STORE AS    M6147 84100021
*                                  NEW BASE OF HEAD QUEUE         M6147 84150021
         MVC   TCBLIST(4),TLSTSAV  RESTORE BASE OF TCB LIST       M6147 84200021
         SPACE                                                          84250021
ARGEXIT1 L     R13,4(R13)          GET ADDR OF CALLER'S SAVE            84600021
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGISTERS           85500020
         BR    RETREG              RETURN                               86400020
         EJECT                                                          86450021
******************************************************************M6147 87350021
*                                                                 M6147 87360021
*            ROUTINE TO TEST FOR LOOP IN TCB READY QUEUE          M6147 87362021
*                                                                 M6147 87370021
******************************************************************M6147 87400021
         SPACE                                                          87450021
HDLOOPTS MVC   TLSTSAV(4),TCBLIST  SAVE BASE OF TCB LIST SO AS    M6147 87500021
*                                  TO BE ABLE TO USE TCB ENQUEUE  M6147 87550021
*                                  ROUTINE                        M6147 87600021
         MVC   TCBLIST(4),HEADLIST  POINT TO BASE OF CVT HEAD     M6147 87650021
*                                   QUEUE                         M6147 87700021
         L     R15,ATCBSAVE        POINT TO TCB ENQUUE            M6147 87750021
         BALR  RETREG,R15          LINK TO IT                     M6147 87800021
         MVC   HEADLIST(4),TCBLIST MOVE IN NEW BASE OF CVT HEAD   M6147 87850021
*                                  QUEUE                          M6147 87900021
         MVC   TCBLIST(4),TLSTSAV  RESTORE TCB LIST BASE          M6147 87950021
         LTR   R15,R15             TEST RETURN CODE FROM TCB      M6147 88000021
*                                  ENQUEUE ROUTINE                M6147 88050021
         BCR   8,R9                ZERO MEANS NEW ADDRESS, SO     M6147 88100021
*                                  RETURN TO CALLER               M6147 88150021
         BRWRITE  SKIP             NEW PAGE                       M6147 88152021
         L     BUFREG,CURBUF       LOAD CURRENT BUFFER ADDRESS    M6147 88160021
*                                  MOVE MSG TO OUTPUT LINE        M6147 88162021
         MVC   ADDR(L'HEADMSG),HEADMSG                            M6147 88170021
         BRWRITE  2                PRINT TCB HEAD LOOP MSG        M6147 88180021
         B     ARGEXIT             EXIT WITH ONLY THE TCB-S       M6147 88190021
*                                  PROCESSED THIS FAR             M6147 88192021
***  STATIC STORAGE FOR IMDPRFUR  ***                                   88200020
         SPACE                                                          89100020
ARGSAVE  DC    18F'0'              ARG'S SAVE AREA                      90000020
HEADLIST DC    F'0'                BASE OF CVT HEAD QUEUE -       M6147 90050021
*                                  ADDRESSES OF TCB PROCESSED -   M6147 90100021
*                                  USED TO DETECT LOOP IN CHAIN   M6147 90150021
DLIST    DC    F'0'                BASE OF DAUGHTER QUEUE -       M6147 90200021
*                                  USED TO DETECT LOOP IN         M6147 90250021
*                                  DAUGHTER QUEUE FOR A TCB       M6147 90300021
TLSTSAV  DC    F'0'                SAVE FOR BASE OF TCB LIST      M6147 90350021
HEADMSG  DC    C'LOOP IN TCB READY QUEUE'                         M6147 90400021
DMSG     DC    C'LOOP IN DAUGHTER CHAIN FOR TCB XXXXXX'           M6147 90450021
ARGSW    DC    B'00000000'         SWITCHES USED BY IMDPRARG            90900020
         END                                                            91800020
