IMDPRFXT START                                                          00700021
         TITLE 'IMDPRFXT - FORMAT VERB EXECUTOR'                        01800021
*********************************************************************** 01810021
*                                                                     * 01820021
*      ***  IMDPRFXT - FORMAT CONTROL STATEMENT EXECUTOR  ***         * 01850021
*                                                                     * 01900021
*  STATUS -- OS/360 RELEASE 21                                        * 02000021
*                                                                     * 02050021
*  FUNCTION --                                                        * 02090021
*                                                                     * 02144021
*         IMDPRFXT IS THE EXECUTOR MODULE FOR THE FORMAT CONTROL      * 02150021
*    STATEMENT.  THE FUNCTION OF THIS MODULE IS TO PRODUCE A FORMATTED* 02200021
*    LISTING OF THE SYSTEM CONTROL BLOCKS FOR EACH TASK IN THE DUMP   * 02250021
*    SYSTEM, AND A SUMMARY WHICH CONSISTS OF AN INDEX OF THE PAGE     * 02300021
*    NUMBERS ON WHICH FORMATTING OF EACH TASK BEGINS.  THIS FUNCTION  * 02350021
*    IS PERFORMED SOLELY BY USE OF THE SERVICE ROUTINES IN IMDPRDMP.  * 02400021
*         THE ALL REGIONS ROUTINE, IMDPRFUR, IS USED TO ENQUEUE THE   * 02450021
*    ADDRESSES OF ALL JOB STEP TCBS IN THE DUMP SYSTEM ON THE TCB LIST* 02500021
*    THEN THE FORMAT SERVICE ROUTINE, IMDPRFSR, IS CALLED TO FORMAT   * 02550021
*    THE SYSTEM CONTROL BLOCKS FOR EACH TCB FAMILY REPRESENTED ON THE * 02600021
*    TCB LIST.  THE TCB SYMMARY ROUTINE IN MODULE IMDPRFSR IS CALLED  * 02650021
*    TO PRINT THE SUMMARY TABLES OF FORMATTED TCBS.  FINALLY, THE     * 02660021
*    SUMMARY TABLE DEQUEUE ROUTINE AND TCB LIST DEQUEUE ROUTINE ARE   * 02670021
*    CALLED TO RELEASE THESE LISTS.                                   * 02680021
*                                                                     * 02690021
*  ENTRY POINTS --                                                    * 02692021
*                                                                     * 02692421
*         IMDPRFXT IS THE MAIN AND ONLY ENTRY POINT.  THIS MODULE IS  * 02694021
*    GIVEN CONTROL BY THE MAIN SCAN MODULE IN IMDPRDMP, IMDPRCTL,     * 02696021
*    WHENEVER THE 'FORMAT' CONTROL STATEMENT IS ENCOUNTERED.          * 02698021
*                                                                     * 02698121
*  INPUT --                                                           * 02698421
*                                                                     * 02698821
*         ON ENTRY, THE FLSHMODE SWITCH OF SWD IN COMMON IS TESTED.   * 02699221
*    IF THIS SWITCH IS ON, CONTROL RETURNS IMMEDIATELY TO IMDPRCTL; NO* 02699621
*    FORMATTING IS PERFORMED.                                         * 02699821
*         ALL OTHER INPUT REQUIRED FOR THE FORMAT OPERATION IS        * 02699921
*    OBTAINED BY THE SERVICE ROUTINES.                                * 02700021
*                                                                     * 02749921
*  OUTPUT --                                                          * 02759921
*                                                                     * 02769921
*         MODULE IMDPRFXT DIRECTS THE OUTPUT OF THE 'FORMAT' CONTROL  * 02779921
*    STATEMENT.  SYSTEM CONTROL BLOCKS FOR EACH TASK IN THE DUMP      * 02789921
*    SYSTEM ARE FORMATTED.  A SUMMARY IS PRINTED WHICH GIVES EACH TCB * 02791921
*    FOR WHICH CONTROL BLOCKS HAVE BEEN FORMATTED.  THE SUMMARY IS    * 02793921
*    ORGANIZED BY TCB FAMILY, AND THE NUMBER OF THE PAGE ON WHICH     * 02795921
*    FORMATTING BEGINS IS GIVEN FOR EACH TCB.                         * 02797921
*         DIRECT OUTPUT OF IMDPRFXT IS THE TITLE FOR THE FORMAT       * 02798321
*    OPERATION.                                                       * 02798721
*         IF THE ERROR CONDITION IS RAISED DURING IMDPRFXT OPERATION, * 02799121
*    ONE OF TWO MESSAGES IS ISSUED DEPENDING ON THE STAGE OF PROCESS- * 02799521
*    ING.  IN CASE THE ALL REGIONS ROUTINE IS PROCESSING WHEN AN ERROR* 02799621
*    OCCURS, THEN THE FOLLOWING MESSAGE IS ISSUED:                    * 02799721
*           'ERROR WHILE FORMATTING CONTROL BLOCKS - CONTINUING'      * 02799821
*         HOWEVER, IF AN ERROR OCCURS AFTER PROCESSING BY THE ALL     * 02849821
*    REGIONS ROUTINE IS COMPLETE, THEN THE FOLLOWING IS ISSUED:       * 02859821
*         'ERROR WHILE FORMATTING CONTROL BLOCKS - ROUTINE TERMINATED'* 02869821
*                                                                     * 02879821
*  EXTERNAL REFERENCES --                                             * 02889821
*                                                                     * 02891821
*         IMDPRWTR -                                                  * 02893821
*         THE IMDPRDMP SERVICE ROUTINE WHICH WRITES TO THE PRINTER    * 02895821
*         DATA SET.  THIS ROUTINE IS USED TO TITLE THE FIRST PAGE OF  * 02897821
*         THE 'FORMAT' CONTROL STATEMENT LISTING AND TO WRITE ERROR   * 02898221
*         MESSAGES TO THE OUTPUT LISTING.  THE CALLING SEQUENCE TO    * 02898621
*         IMDPRWTR IS GENERATED BY THE 'BRWRITE' PRIVATE MACRO        * 02899021
*         INSTRUCTION.                                                * 02899421
*                                                                     * 02899521
*         IMDPRFUR -                                                  * 02899621
*         THE ALL REGIONS ROUTINE OF IMDPRDMP.  THIS ROUTINE IS USED  * 02899721
*         TO ENQUEUE ON THE TCB LIST THE ADDRESSES OF ALL JOB STEP    * 02949721
*         TCBS IN THE DUMP SYSTEM.                                    * 02959721
*                                                                     * 02969721
*         IMDPRFSR -                                                  * 02979721
*         THE FORMAT SERVICE ROUTINE.  IMDPRFSR IS USED TO FORMAT     * 02989721
*         SYSTEM CONTROL BLOCKS FOR EACH TCB IN THE DUMP SYSTEM.      * 02991721
*         INPUT TO THIS ROUTINE IS THE TCB LIST.  SINCE THE TCB LIST  * 02993721
*         CONTAINS THE ADDRESSES OF ALL JOB STEP TCBS WHEN IMDPRFSR IS* 02995721
*         INVOKED, AND SINCE JSTCBS REPRESENT EVERY FAMILY OF TCBS IN * 02997721
*         THE DUMP SYSTEM, ALL TCBS ARE FORMATTED.                    * 02998121
*                                                                     * 02998521
*         IMDPRTSM -                                                  * 02998921
*         THIS ROUTINE IS USED BOTH TO PRINT THE TCB SYMMARY AT THE   * 02999321
*         END OF THE 'FORMAT' CONTROL STATEMENT LISTING AND TO FREE   * 02999421
*         TCB SUMMARY TABLES AFTER THE TCB SUMMARY IS COMPLETE.       * 02999521
*                                                                     * 02999621
*         IMDPRTSV -                                                  * 03049621
*         THE TCB LIST MANAGEMENT ROUTINE.  THE DEQUEUE ROUTINE IS    * 03059621
*         USED TO PURGE ALL ELEMENTS FROM THE TCB LIST WHEN IMDPRFXT  * 03069621
*         PROCESSING IS COMPLETE.                                     * 03079621
*                                                                     * 03089621
*  EXITS,NORMAL --                                                    * 03091621
*                                                                     * 03093621
*         ON COMPLETION OF PROCESSING FOR THE 'FORMAT' CONTROL        * 03095621
*    STATEMENT, IMDPRFXT RETURNS TO THE CONTROL/SCAN ROUTINE, CSECT   * 03097621
*    IMDPRMSC, IN MODULE IMDPRCTL.  ERROR CONDITIONS ARE HANDLED      * 03098021
*    INTERNALLY BY IMDPRFXT.                                          * 03098421
*                                                                     * 03098821
*  EXITS,ERROR --                                                     * 03099221
*                                                                     * 03099321
*         NONE                                                        * 03099421
*                                                                     * 03099521
*  TABLES/WORK AREAS --                                               * 03149521
*                                                                     * 03159521
*         NONE                                                        * 03169521
*                                                                     * 03179521
*  ATTRIBUTES --  REUSEABLE                                           * 03189521
*                                                                     * 03191521
*  CHARACTER CODE DEPENDENCY --  EBCDIC                               * 03193521
*                                                                     * 03195521
*  NOTES --                                                           * 03197521
*                                                                     * 03197921
*         MODULE IMDPRFXT CONTAINS AN ERROR HANDLING ROUTINE.  THE    * 03198321
*    ACTION OF THIS ROUTINE IS DEPENDENT ON WHAT STAGE OF IMDPRFXT    * 03198721
*    PROCESSING AN ERROR OCCURS.  IF THE ERROR CONDITION IS RAISED    * 03199121
*    WHILE THE ALL REGIONS ROUTINE IS PROCESSING, IMDPRFXT ATTEMPTS   * 03199221
*    TO FORMAT CONTROL BLOCKS FOR THOSE TCBS WHICH HAVE BEEN          * 03199321
*    PREVIOUSLY ENQUEUED ON THE TCB LIST.  IF THE ERROR OCCURS AFTER  * 03199421
*    THE ALL REGIONS PROCESSING IS COMPLETE, EXECUTION OF IMDPRFXT IS * 03249421
*    TERMINATED.                                                      * 03259421
*                                                                     * 03269421
*********************************************************************** 03279421
         EJECT                                                          03289421
         EQUATES                                                        03299421
         COMMON                                                         03400021
*                                                                 M3179 03500021
         OUTBUFM                                                        04200021
         EJECT                                                          18900121
*/*IMDPRFXT: CHART (AMODE,SEQ) */                                       18900521
*/*HEADER                                                               18901021
*/*IMDPRFXT  FORMAT VERB EXECUTOR                                       18901521
*/*                                                  PAGE # */          18902021
*/*IMDPRFXT: E START */                                                 18902521
*/*  M SET UP ADDRESSABILITY */                                         18903021
*/*  D (YES,FMTDONE,NO,) IS THIS FLUSH MODE? */                         18903521
*/*  M ZERO PRFMTSW SWITCH */                                           18904021
*/*  P SET UP ERROR ROUTINE ADDRESS */                                  18904521
*/*  M SET SQ1 SWITCH ON */                                             18905021
*/*  L BRWRITE SKIP TO TOP OF PAGE */                                   18905521
*/*  P MOVE FORMAT TITLE TO BUFFER */                                   18906021
*/*  L BRWRITE PRINT TITLE */                                           18906521
*/*  L IMDPRFUR GET JOB STEP TCBS FOR ALL REGIONS */                    18907021
*/*PRNTFMT1: M SET SQ2 SWITCH ON */                                     18907521
*/*  L IMDPRFSR GO FORMAT ALL REGIONS */                                18908021
*/*PRNTFMT2: L TCBSMRY  PRINT TCB SUMMARY */                            18908521
*/*  L TCBSMFR   FREE UP SUMMARY TABLES */                              18909021
*/*  L TCBREMV REMOVE ALL TCBS FROM TCB LIST */                         18909521
*/*  P RESTORE PREVIOUS ERROR ROUTINE ADDRESS */                        18910021
*/*FMTDONE: M EXIT LINKAGE */                                           18910521
*/*  R RETURN */                                                        18911021
*/*PRTFMTER: M SET UP ADDRESSABILITY */                                 18911521
*/*  L BRWRITE  SPACE A LINE */                                         18912021
*/*  D (YES,,NO,%L1) IS SQ1 OR SQ2 SWITCH ON? */                        18912521
*/*PRFMER2: P MOVE CONTINUING ERROR MESSAGE TO BUFFER */                18913021
*/*  P (,PRFMER1) SET RETURN ADDRESS TO PRNTFMT1 */                     18913521
*/*%L1: P MOVE CONTINUATION NOT POSSIBLE ERROR MESSAGE TO BUFFER */     18914021
*/*  M SET RETURN ADDRESS TO PRNTFMT2 */                                18914521
*/*PRFMER1: L BRWRITE  PRINT THE ERROR MESSAGE */                       18915021
*/*  M RESET THE ERROR SWITCHES */                                      18915521
*/*  R RETURN VIA REG 9 */                                              18916021
*/*IMDPRFXT:  END */                                                    18916521
         EJECT                                                          19600021
IMDPRFXT CSECT                                                          20300021
         STM   R14,R12,12(R13)     STORE CALLER'S REGS                  21000021
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             21700021
         USING *,BASE1                                                  22400021
FMTBASE  LA    R2,FMTSAVE          SAVE AREA CHAINNING                  23100021
         ST    R13,FMTSAVE+4                                            23800021
         ST    R2,8(R13)                                                24500021
         LR    R13,R2                                                   25200021
         SPACE                                                          25900021
         USING COMMON,COMBASE      BASE DSECT OF COMMON ON REG 12       26600021
         USING OUTBUF,BUFREG                                            27300021
         SPACE                                                          28000021
         TM    SWD,FLSHMODE        IS THIS FLUSH MODE                   28700021
         BO    FMTDONE             BRANCH TO EXIT IF SO                 29400021
         MVI   PRFMTSW,0           ZERO SWITCHES                        30100021
         MVC   ERADRSAV,ERRADDR    SAVE PREVIOUS ERROR ROUTINE ADDR     30800021
         LA    R15,PRTFMTER        ADDR OF PRNTFMT ERROR ROUTINE        31500021
         ST    R15,ERRADDR         STORE IN ERROR ROUTINE ADDR WORD     32200021
         OI    PRFMTSW,SQ1         SET FIRST SEQUENCE SWITCH            32900021
         BRWRITE  SKIP                                                  33600021
         L     BUFREG,CURBUF                                            34300021
         MVC   ADDR+43(L'FMTTITLE),FMTTITLE                             35000021
         BRWRITE  2                                                     35700021
         L     R15,AALLRGN         GET ADDR OF ALL REGIONS ROUTINE      36400021
         BALR  RETREG,R15          LINK TO FUR TO GET JOB STEP TCB      37100021
*                                  ADDRESSES FOR ALL REGIONS            37800021
PRNTFMT1 OI    PRFMTSW,SQ2         SET SECOND SEQUENCE SWITCH           38500021
         SR    R0,R0               TJID 0 FOR FORMAT                    39200021
         L     R15,AFORMAT         ADDR OF FORMAT ROUTINE               39900021
         BALR  RETREG,R15          GO DO FORMAT                         40600021
PRNTFMT2 L     R15,ATCBSMRY        GET ADDR OF PRINT SUMMARY ROUTINE    41300021
         BALR  RETREG,R15                                               42000021
         L     R15,ATCBSMFR        FREE SUMMARY TABLES                  42700021
         BALR  RETREG,R15                                               43400021
         L     R15,ATCBREMV        ADDR OF TCB REMOVE ROUTINE           44100021
         SR    R2,R2               TO INDICATE REMOVAL OF ALL TCB ADDRS 44800021
         BALR  RETREG,R15          LINK TO TCBREMV                      45500021
         MVC   ERRADDR,ERADRSAV    RESTORE ERROR ROUTINE TO PREVIOUS    46200021
*                                  VALUE                                46900021
FMTDONE  L     R13,4(R13)          POINT TO CALLER'S SAVE AREA          47600021
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGS                48300021
         BR    RETREG              RETURN                               49000021
         EJECT                                                          49700021
*********************************************************************** 50400021
*                                                                     * 51100021
*   ERROR DURING SOME PART OF PRNTFMT ROUTINE                         * 51800021
*                                                                     * 52500021
*********************************************************************** 53200021
         SPACE                                                          53900021
         DROP  BASE1                                                    54600021
         USING PRTFMTER,R15                                             55300021
PRTFMTER LA    R13,FMTSAVE         POINT TO SAVE AREA IN THIS ROUTINE   56000021
         LM    R0,R12,20(R13)      RESTORE REGS                         56700021
         DROP  R15                                                      57400021
         USING FMTBASE,BASE1       GO BACK TO ORIGINAL BASE - REG 11    58100021
         L     BUFREG,CURBUF       LOAD BUFFER ADDR                     58800021
         BRWRITE 1                 SPACE A LINE                         59500021
         TM    PRFMTSW,SQ1+SQ2     TEST SEQUENCE SWITCHES               60200021
         BM    PRFMER2             CONTINUATION POSSIBLE                60900021
         MVC   ADDR(L'PRFMSG1),PRFMSG1  CONTINUATION NOT POSSIBLE       61600021
*                                  MOVE ERROR MSG TO OUTPUT BUFFER      62300021
         LA    R9,PRNTFMT2         LOAD RETURN ADDR FOR QUIT            63000021
PRFMER1  BRWRITE 2                 PRINT ERROR MSG                      63700021
         NI    SWB,255-IOERR-FMTERR RESET ERROR SWITCHES                64400021
         BR    R9                  RETURN TO EITHER PRNTFMT1 TO CONT    65100021
*              ERROR DURING SOME PART OF PRNTFMT ROUTINE              * 65700021
*                                  OR PRNTFMT2 TO GIVE UP               65800021
         SPACE                                                          66500021
PRFMER2  MVC   ADDR(51),PRFMSG2    MOVE ERROR MSG TO BUFFER             67200021
         LA    R9,PRNTFMT1         LOAD CONTINUE RETURN ADDR            67900021
         B     PRFMER1             PRINT ERROR MSG AND CONTINUE         68600021
         SPACE                                                          69300021
***  STATIC STORAGE IN IMDPRFMT  ***                                    70000021
FMTSAVE  DC    18F'0'                                                   70700021
ERADRSAV DS    F                                                        71400021
FMTTITLE DC    C'* * * *    F O R M A T    * * * *'                     72100021
PRFMSG1  DC    C'ERROR WHILE FORMATTING CONTROL BLOCKS....ROUTINE TERMIX72800021
               NATED'                                                   73500021
PRFMSG2  DC    C'ERROR WHILE FORMATTING CONTROL BLOCKS....CONTINUING'   74200021
         SPACE                                                          74900021
         END                                                            98700021
