IMDPRLPA START                                                          00400020
         TITLE 'LPA MAP EXECUTOR'                                       00800020
*********************************************************************** 01200020
*                                                                     * 01600020
**                     ***  LPA MAP ROUTINE  ***                     ** 02000020
*                                                                     * 02400020
*                                                                     * 02800020
*  STATUS-  OS/360 RELEASE 21.00, JULY 15, 1971                       * 02801021
*                                                                     * 02802021
*  C 356000,380000-388000,716000-728000,872000                   A35932 02803021
*  A 684500                                                      A47532 02803421
*                                                                     * 02804021
*  FUNCTION-  THIS ROUTINE PRINTS A MAP OF THE LINK PACK AREA FOR MFT * 02805021
*      AND MVT SYSTEMS.  THIS MODULE IS LOADED AND INVOKED BY MODULE  * 02806021
*      IMDPRCTL WHEN THE LPAMAP CONTROL STATEMENT IS ENCOUNTERED.     * 02807021
*      IF A LINK PACK AREA IS PRESENT IN THE DUMP SYSTEM, A FORMATTED * 02808021
*      REPRESENTATION OF LINK PACK AREA QUEUE IS WRITTEN TO THE       * 02809021
*      PRINTER DATA SET.  WHEN THE OUTPUT IS FINISHED, CONTROL        * 02810021
*      RETURNS TO THE SCAN PORTION OF IMDPRCTL.  IF A PCP SYSTEM IS   * 02811021
*      BEING PRINTED, A DIAGNOSTIC MESSAGE IS PRINTED IN THE OUTPUT   * 02812021
*      LISTING (PRINTER) AND CONTROL IS RETURNED IMMEDIATELY TO       * 02813021
*      IMDPRCTL.                                                      * 02814021
*                                                                     * 02815021
*  ENTRY POINT-  IMDPRLPA IS THE MAIN AND ONLY ENTRY POINT.           * 02816021
*      THIS MODULE RECEIVES CONTROL FROM IMDPRCTL, THE CONTROL/SCAN   * 02817021
*      ROUTINE OF IMDPRDMP.                                           * 02818021
*                                                                     * 02819021
*  INPUT-                                                             * 02820021
*                                                                     * 02821021
*      1.  PARAMETERS:  ON ENTRY TO MODULE IMDPRLPA, GENERAL REGISTER * 02822021
*              12 CONTAINS THE ADDRESS OF THE IMDPRDMP COMMON CSECT,  * 02823021
*              IMDPRCOM.                                              * 02824021
*                                                                     * 02825021
*      2.  DUMP DATA SET:  INFORMATION FROM THE INPUT DUMP DATA SET   * 02826021
*              IS OBTAIN BY USE OF THE BRREAD PRIVATE MACRO           * 02827021
*              INSTRUCTION.                                           * 02828021
*                                                                     * 02829021
*  OUTPUT-  THE LINK PACK AREA MAP IS WRITTEN TO THE PRINTER DATA     * 02830021
*      SET.                                                           * 02831021
*                                                                     * 02832021
*  EXTERNAL REFERENCES-                                               * 02833021
*                                                                     * 02834021
*      1.  IMDPRWTR - THIS MODULE IS USED TO WRITE EACH LINE OF THE   * 02835021
*              OUTPUT LISTING.  LINKAGE TO IMDPRWTR IS THROUGH THE    * 02836021
*              BRWRITE PRIVATE MACRO INSTRUCTION.                     * 02837021
*                                                                     * 02838021
*      2.  IMDPRRDC - MODULE IMDPRRDC IS THE DUMP READ CONTROL        * 02839021
*              MODULE.  THE CALLING SEQUENCE TO THIS MODULE IS        * 02840021
*              GENERATED BY THE BRREAD MACRO INSTRUCTION.             * 02841021
*                                                                     * 02842021
*      3.  IMDPRMSG - THIS ROUTINE, INVOKED BY THE BRPRTMSG PRIVATE   * 02843021
*              MACRO, IS USED TO WRITE MESSAGES TO THE SYSPRINT DATA  * 02844021
*              SET.                                                   * 02845021
*                                                                     * 02846021
*      4.  IMDPRGFR - THIS IS THE GENERAL FORMATTING ROUTINE IN       * 02847021
*              IMDPRDMP.  INPUT TO THIS ROUTINE IS THE OUTPUT LINE    * 02848021
**             DESCRIPTION AS CODED IN THE FMTPTRN PRIVATE MACRO      * 02849021
**             INSTRUCTION.  IMDPRGFR FORMATS EACH OUTPUT LINE IN THE * 02850021
*              CURRENT OUTPUT BUFFER.                                 * 02851021
*                                                                     * 02852021
*  EXITS, NORMAL-  WHEN THE LINK PACK AREA MAP IS COMPLETE, CONTROL   * 02853021
*      RETURNS TO MODULE IMDPRCTL.                                    * 02854021
*                                                                     * 02855021
*  EXITS, ERROR-  FOUR ERROR CONDITIONS ARE DETECTED BY MODULE        * 02856021
*      IMDPRLPA.                                                      * 02857021
*                                                                     * 02858021
*      1.  NO LINK PACK MAP PRESENT IN DUMP SYSTEM OR DUMP BEING      * 02859021
*      PRINTED IS FROM A PCP SYSTEM.  IN THIS CASE, AN INFORMATIONAL  * 02860021
*      NOTATION IS MADE IN THE OUTPUT LISTING AND CONTROL RETURNS TO  * 02861021
*      IMDPRCTL.                                                      * 02862021
*                                                                     * 02863021
*      2.  I/O ERROR ON DUMP DATA SET OR ON SYSUT1 WORK FILE.         * 02864021
*      SHOULD THIS OCCUR, MESSAGE IMD158I IS WRITTEN TO THE SYSPRINT  * 02865021
*      DATA SET AND, IF COMMANDS ARE BEING ENTERED FROM THE CONSOLE   * 02866021
*      MESSAGE IMD158I IS ISSUED TO THE OPERATOR.  THE LPA MAP IS     * 02867021
*      TERMINATED AND CONTROL RETURNS TO IMDPRCTL.                    * 02868021
*                                                                     * 02869021
*      3.  PROGRAM CHECK RESULTING FROM INVALID BOUNDARY ALIGNMENT    * 02870021
*      OF LPA CONTROL BLOCK.  IN THIS CASE MESSAGE IMD159I IS ISSUED  * 02871021
*      IN THE SAME MANNER AS IMD158I DESCRIBED IN POINT (2).  THE LPA * 02872021
*      MAP IS TERMINATED AND CONTROL RETURNS TO IMDPRCTL.             * 02873021
*                                                                     * 02874021
*      4.  FORMAT ERROR IN DUMP SYSTEM.  THIS SITUATION OCCURS IF THE * 02875021
*      LINK FIELD OF A LPA CONTROL BLOCK CONTAINS AN ADDRESS WHICH IS * 02876021
*      GREATER THAN THE MAXIMUM MACHINE ADDRESS IN THE CVT OF THE     * 02877021
*      DUMP SYSTEM.  THE FORMAT ERROR CONDITION IS ALSO RAISED IF     * 02878021
*      A BLOCK IS MISSING FROM THE DUMP TAPE.  IF A FORMAT ERROR IS   * 02879021
*      DETECTED, MESSAGE IMD161I IS ISSUED IN THE SAME MANNER AS      * 02880021
*      IMD158I DESCRIBED IN POINT (2).  THE LPA MAP IS TERMINATED AND * 02881021
*      CONTROL RETURNS TO MODULE IMDPRLPA.                            * 02882021
*                                                                     * 02883021
*  TABLES/WORK AREAS-  NONE                                           * 02884021
*                                                                     * 02885021
*  ATTRIBUTES-  REUSABLE                                              * 02886021
*                                                                     * 02887021
*  CHARACTER CODE DEPENDENCY-  EBCDIC                                 * 02888021
*                                                                     * 02889021
*  NOTES-  NONE                                                       * 02890021
*                                                                     * 03600020
*********************************************************************** 04000020
         EJECT                                                          04050021
*/*IMDPRLPA: CHART (SEQ) */                                             04100021
*/* HEADER                                                              04150021
*/*IMDPRLPA - THE LINK PACK AREA MAPPING MODULE FLOWCHART               04200021
*/*                                                    PAGE #       */  04250021
*/*IMDPRLPA: E START */                                                 04300021
*/* P SAVE CALLER'S REG. & CHAIN SAVE AREAS */                          04350021
*/* D (YES,LPADONE1,NO,) IN FLUSH MODE */                               04360021
*/* P SAVE PREV. ERROR ROUTINE ADDRESS */                               04370021
*/* P SET ERROR ROUTINE ADDRESS FOR THIS ROUTINE */                     04380021
*/* L BRWRITE: SKIP TO NEW PAGE */                                      04390021
*/* D (NO,LPAMFT,YES,)  MVT DUMP */                                     04392021
*/* P LOAD ADDRESS OF OUTPUT BUFFER */                                  04394021
*/* P GET MASTER SCHEDULER TCB ADDRESS */                               04396021
*/* P POINT TO ADDRESS OF M/S LOAD LIST ELEMENT */                      04398021
*/* L BRREAD: READ IN @ OF M/S LOAD LIST ELEMENT */                     04398421
*/* P LOAD @ OF THIS FIRST LOAD LIST ELEMENT */                         04398821
*/*LPALOOP: P CLEAR HIGH ORDER BYTE OF REG CONTAINING LLE @ */          04399221
*/* D (YES,LPADONE,NO,) LLE ADDRESS ZERO */                             04399621
*/* S LPATITLE: PRINT TITLE IF AT TOP OF PAGE */                        04399721
*/* L BRREAD: READ LLE */                                               04399821
*/* P SAVE ADDR OF NEXT IN LLE IN CHAIN */                              04399921
*/* L BRREAD: READ CONTENTS DIRECTORY ENTRY */                          04400021
*/* P SAVE CDE ATTRIBUTES */                                            04410021
*/* L BRREAD: READ IN MODULE NAME */                                    04412021
*/* P MOVE MODULE NAME TO OUTPUT BUFFER */                              04414021
*/* L BRREAD: READ IN ENTRY POINT ADDRESS */                            04416021
*/* P POINT TO LOCATION FOR EPA IN BUFFER */                            04416421
*/* L ADRCNVT: CONVERT EP @ TO HEX AND MOVE TO BUFFER */                04416521
*/* P LOAD ADDRESS OF MAJOR CODE/ EXTENT LIST */                        04416621
*/* D (YES,LPAMAP3,NO,)  CDE ATTRIBUTES INDICATE MINOR CODE */          04426621
*/* P MOVE "MAJOR" TYPE TO OUTPUT BUFFER */                             04436621
*/*LPAMAP4: L BRREAD: READ IN MODULE LENGTH AND STARTING @ */           04446621
*/* P POINT TO LOCATION FOR MODULE LENGTH IN BUFFER */                  04448621
*/* L ADRCNVT: CONVERT LENGTH TO HEX AND MOVE TO BUFFER */              04449021
*/* P POINT TO LOCATION FOR STARTING ADDRESS IN BUFFER */               04449421
*/* L ADRCNVT: CONV. START @ TO HEX & MOVE TO BUFFER */                 04449821
*/* L BRWRITE: WRITE FROM BUFFER */                                     04449921
*/* P (,LPALOOP) GET @ OF NEXT LOAD LIST ELEMENT */                     04499921
*/*LPAMAP3: P POINT TO EXTENT LIST ADDRESS */                           04509921
*/* L BRREAD: READ IN EXTENT LIST ADDRESS */                            04519921
*/* P LOAD ADDRESS OF EXTENT LIST */                                    04529921
*/* P (,LPAMAP4) INDICATE MINOR IN OUTPUT BUFFER */                     04539921
*/*LPAMFT: D (NO,LPANONE,YES,) MFT DUMP */                              04541921
*/* P POINT TO LPA QUEUE ADDRESS */                                     04543921
*/* L BRREAD: READ IN LPA QUEUE ADDRESS */                              04545921
*/* P CLEAR HIGH ORDER BYTE OF LPA QUEUE ADDRESS */                     04547921
*/* D (YES,LPANONE,NO,) LPA QUEUE ADDRESS ZERO */                       04548321
*/*LPAMFTLP: P CLEAR HIGH ORDER BYTE OF RB ADDRESS */                   04548721
*/* D (YES,LPADONE,NO,) RB ADDRESS ZERO */                              04549121
*/* L BRREAD: READ IN RB */                                             04549521
*/* P SAVE ADDRESS OF NEXT RB */                                        04549621
*/* S LPATITLE: PRINT TITLE IF AT TOP OF PAGE */                        04549721
*/* P STORE @ OF MODULE NAME */                                         04549821
*/* P STORE @ OF EPA */                                                 04599821
*/* P STORE @ OF ROUTINE */                                             04609821
*/* P POINT TO SIZE AND FLAG BYTES */                                   04619821
*/* L BRREAD: READ IN SIZE AND FLAG */                                  04629821
*/* P CALCULATE SIZE IN BYTES */                                        04639821
*/* P STORE SIZE */                                                     04641821
*/* D (YES,%1,NO,) RB FLAG INDICATE LRB */                              04643821
*/* P LOAD @ OF "LPRB" IDENTIFIER */                                    04645821
*/*LPAMFT1: P STORE ADDRESS OF IDENTIFIER IN PATTERN */                 04647821
*/* P POINT TO PATTERN */                                               04648221
*/* L FMTLINE: FORMAT OUTPUT LINE */                                    04648621
*/* L BRWRITE: WRITE LINE */                                            04649021
*/* P (,LPAMFTLP) POINT TO NEXT LLE */                                  04649421
*/*%1: P (,LPAMFT1) LOAD @ OF "LRB" IDENTIFIER */                       04649521
*/*LPATITLE: D (YES,%2,NO,) SPACE TO PRINT LINE ON THIS PAGE */         04649621
*/* P LOAD BUFFER @ */                                                  04649721
*/* P MOVE FIRST TITLE TO OUTPUT BUFFER */                              04699721
*/* L BRWRITE: WRITE FIRST TITLE */                                     04709721
*/* P MOVE SECOND TITLE TO OUTPUT BUFFER */                             04719721
*/* L BRWRITE: WRITE SECOND TITLE */                                    04729721
*/*%2: R RETURN VIA R9 */                                               04739721
*/*LPAERROR: P RESTORE REGISTERS */                                     04741721
*/* P MOVE ABORTED MESSAGE TO WTO BUFFER */                             04743721
*/* P MOVE ERROR SWITCH TO WORK AREA */                                 04745721
*/* P RESET ERROR SWITCH TO INDICATE ONLY I/O OR FORMAT ERRORS */       04747721
*/* P POINT TO ERROR MESSAGE INDICATED BY ERROR SWITCH */               04748121
*/* P MOVE ERROR TO WTO BUFFER */                                       04748521
*/* L BRPRTMSG: WRITE ERROR MESSAGE ON SYSPRINT */                      04748921
*/* D (NO,LPADONE,YES,) COMMAND COMING FROM SYSIN */                    04749321
*/* L (,LPADONE) WTO: WRITE ERROR MESSAGE TO OPERATOR */                04749421
*/*LPANONE: S LPATITLE: PRINT TITLE IF TOP OF PAGE */                   04749521
*/* L BRWRITE: WRITE "NO LPA QUEUE" MESSAGE */                          04749621
*/*LPADONE: P RESTORE PREVIOUS ERROR ROUTINE @ */                       04759621
*/*LPADONE1: P RESTORE CALLER'S REG. */                                 04761621
*/* R RETURN */                                                         04763621
*/*IMDPRLPA: END */                                                     04765621
         EJECT                                                          04794421
         EQUATES                                                        04800020
         COMMON                                                         05200020
*                                                                 M3179 05250020
         OUTBUFM                                                        05600020
IMDPRLPA CSECT                                                          06000020
         SPACE                                                          06400020
MFTLPAQ  EQU   188                                                      06800020
LPALOAD  EQU   X'80'               MODULE IN LPA               @SA68379 07000021
         STM   R14,R12,12(R13)     SAVE CALLER'S REGISTERS              07200020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             07600020
         USING *,BASE1                                                  08000020
LPABASE  LA    R0,MAPSAVE          SAVE AREA CHAINNING                  08400020
         ST    R0,8(R13)                                                08800020
         ST    R13,MAPSAVE+4                                            09200020
         LR    R13,R0                                                   09600020
         SPACE                                                          10000020
         USING COMMON,COMBASE      COMMON CSECT BASED ON REG 12         10400020
         USING OUTBUF,BUFREG                                            10800020
         SPACE                                                          11200020
         TM    SWD,FLSHMODE        IS THIS FLUSH MODE                   11600020
         BO    LPADONE1            YES--RETURN AND DON'T DO ANYTHING    12000021
         MVC   LPAERSV,ERRADDR     SAVE CURRENT ERROR ROUTINE ADDR      12400020
         LA    R15,LPAERROR        LOAD ADDR OF LPAMAP ERROR ROUTINE    12800020
         ST    R15,ERRADDR         STORE AS ERROR ADDRESS               13200020
         BRWRITE SKIP              SKIP TO LINE ONE                     13600020
         TM    SWE,MVTSW           IS THIS AN MVT DUMP                  14000020
         BZ    LPAMFT              NO--GO TEST FOR MFT DUMP             14400020
         L     BUFREG,CURBUF       LOAD BUFFER ADDR                     14800020
LPAMAP6  L     R2,MSTRTCB          MASTER SCHED TCB ADDR                15200020
         LA    PREG,TCBLLEP(R2)    ADDR OF LOAD LIST PTR                15600020
         BRREAD  (PREG),DATA,TJID=0                                     16000020
         L     R2,0(PREG)          ADDR OF FIRST LOAD LIST ELEMENT      16400020
LPALOOP  LA    R2,0(R2)            CLEAR HIGH ORDER BYTE                16800020
         LTR   R2,R2               IS LLE PTR ZERO                      17200020
         BZ    LPADONE             IF YES ALL DONE MAPPING              17600020
         BAL   R9,LPATITLE         PRINT TITLE IF AT TOP OF PAGE        18000020
LPAMAP2  BRREAD  (R2)                                                   18400020
         MVC   LLENEXT,0(PREG)     SAVE ADDR OF NEXT LLE                18800020
         L     R2,4(PREG)          CDE PTR                              19200020
         BRREAD  (R2)                                                   19600020
         TM    0(PREG),LPALOAD     IS MODULE IN LINK PACK AREA @SA68379 19700021
         BZ    NEXTLLE             NO GET NEXT LLE             @SA68379 19800021
         MVC   CDEATTR(1),0(PREG)  SAVE CDE ATTRIBUTES                  20000020
         LA    PREG,8(R2)          ADDR OF NAME                         20400020
         BRREAD  (PREG)                                                 20800020
         MVC   FIELD1(8),0(PREG)   MOVE NAME TO BUFFER                  21200020
         LA    PREG,16(R2)         ENTRY POINT ADDR                     21600020
         BRREAD  (PREG)                                                 22000020
         LA    R4,FIELD1+20        LOC OF EPA IN BUFFER                 22400020
         L     R15,AADRCNVT        LOAD ADDR OF ADRCNVT ROUTINE         22800020
         BALR  RETREG,R15          LINK TO IT                           23200020
         L     R3,4(PREG)          EXTENT LIST OR MAJOR CDE ADDRESS     23600020
         TM    CDEATTR,MINCDE      IS THIS A MINOR CDE                  24000020
         BO    LPAMAP3             YES--GET MAJOR                       24400020
         MVC   FIELD1+44(5),MAJOR  NO--INDICATE MAJOR                   24800020
LPAMAP4  LA    PREG,8(R3)          EXT LIST ADDR + 8                    25200020
         BRREAD  (PREG)                                                 25600020
         LA    R4,FIELD1+36        LOC OF LENGTH IN BUFFER              26000020
         L     R15,AADRCNVT        LOAD ADDR OF ADRCNVT ROUTINE         26400020
         BALR  RETREG,R15          LINK TO IT                           26800020
         LA    PREG,4(PREG)        ADDR OF STARTING ADDR                27200020
         LA    R4,FIELD1+28        LOC OF STA IN BUFFER                 27600020
         L     R15,AADRCNVT        LOAD ADDR OF ADRCNVT ROUTINE         28000020
         BALR  RETREG,R15          LINK TO IT                           28400020
         TM    CDEATTR,MINCDE      IS CDE MINOR                @SA68379 28500021
         BNO   SKIPSAV             NO, DON'T SAVE DATA         @SA68379 28600021
         MVC   MAJLINE(22),FIELD1+20 SAVE FOR MAJOR CDE        @SA68379 28700021
SKIPSAV  BRWRITE 1                 GO PRINT                    @SA68379 28800021
         TM    CDEATTR,MINCDE      IS CDE MINOR                @SA68379 28860021
         BNO   NEXTLLE             NO, GET NEXT LLE            @SA68379 28920021
         MVC   FIELD1+44(5),MAJOR  INDICATE MAJOR CDE          @SA68379 28980021
         MVC   FIELD1(8),MNAME     MAJOR CDE NAME              @SA68379 29040021
         MVC   FIELD1+20(22),MAJLINE ADDR INFO FOR MAJOR CDE   @SA68379 29070021
         BRWRITE 1                                             @SA68379 29100021
NEXTLLE  L     R2,LLENEXT          ADDR OF NEXT LLE            @SA68379 29200021
         B     LPALOOP             LOOP THROUGH ALL LLES                29600020
         SPACE                                                          30000020
LPAMAP3  LA    PREG,8(R3)          ADDR OF CDE MAJOR NAME FIELD         30400021
         BRREAD  (PREG)                                        @SA68379 30500021
         MVC   MNAME(8),0(PREG)    SAVE MAJOR CDE NAME         @SA68379 30600021
         LA    PREG,20(R3)         EXTENT LIST PTR IN MAJOR CDE         30700021
         BRREAD  (PREG)                                                 30800020
         L     R3,0(PREG)          EXTENT LIST ADDR TO R3               31200020
         MVC   FIELD1+44(5),MINOR  INDICATE MINOR CDE                   31600020
         B     LPAMAP4             CONTINUE                             32000020
         SPACE 2                                                        32400020
*********************************************************************** 32800020
*                                                                     * 33200020
*   THIS ROUTINE WILL FORMAT THE LINK PACK AREA FOR MFT IF PRESENT    * 33600020
*                                                                     * 34000020
*********************************************************************** 34400020
         SPACE                                                          34800020
LPAMFT   TM    SWE,MFTSW           IS THIS AN MFT DUMP                  35200020
         BZ    LPANONE             NO--PCP...NO LINK PACK AREA   A35932 35600020
         L     R3,CVTADDR          LOAD ADDR OF CVT                     36400020
         LA    PREG,MFTLPAQ(R3)    LOAD ADDR OF LPAQ PTR                36800020
         BRREAD  (PREG),DATA,TJID=0                                     37200020
         L     R2,0(PREG)          LOAD LPAQ PTR                        37600020
         LA    R2,0(R2)            CLEAR HIGH BYTE               A35932 38000020
         LTR   R2,R2               TEST FOR LINK PACK AREA       A35932 38400020
         BZ    LPANONE             BRANCH IF NONE                A35932 38800020
LPAMFTLP LA    R2,0(R2)            CLEAR POSS HI BYTE                   39200020
         LTR   PREG,R2             LOAD ADDR OF RB TO PREG AND TEST     39600020
         BZ    LPADONE             ALL DONE IF ZERO                     40000020
         BRREAD  (PREG)                                                 40400020
         MVC   LLENEXT,0(PREG)     SAVE ADDR OF NEXT RB OF LIST         40800020
         BAL   R9,LPATITLE         PRINT TITLE IF TOP OF PAGE           41200020
         LA    PREG,8(R2)          ADDR OF NAME IN RB                   41600020
         ST    PREG,LPAMPTNA       STORE INTO PATTERN                   42000020
         LA    PREG,21(R2)         ADDR OF EPA IN RB                    42400020
         ST    PREG,LPAMPTNB       STORE INTO PATTERN                   42800020
         LA    PREG,24(R2)         STARTING ADDR OF ROUTINE             43200020
         ST    PREG,LPAWORK1       STORE INTO WORK AREA                 43600020
         LA    PREG,16(R2)         ADDR OF SIZE AND FLAG BYTES          44000020
         BRREAD  (PREG)                                                 44400020
         LH    R7,0(PREG)          LOAD SIZE IN DBL WRDS TO R7          44800020
         SLL   R7,3                MULTIPLY BY 8 FOR SIZE IN BYTES      45200020
         ST    R7,LPAWORK2         STORE SIZE INTO WORK AREA            45600020
         TM    2(PREG),X'F0'       TEST FOR LRB                         46000020
         LA    PREG,LPALRB         LOAD ADDR OF 'LRB' ID                46400020
         BO    LPAMFT1             BR IF LRB                            46800020
         LA    PREG,LPALPRB        LOAD ADDR OF 'LPRB' ID               47200020
LPAMFT1  ST    PREG,LPAMPTNC       STORE ADDR OF CORRECT ID INTO PATRN  47600020
         LA    PREG,LPAMPTN        LOAD ADDR OF PATTERN TO PREG         48000020
         SR    R0,R0               SET TJID TO ZERO                     48400020
         L     R15,AFMTLINE        LOAD ADDR OF FORMAT LINE ROUTINE     48800020
         BALR  RETREG,R15          GO FORMAT LINE                       49200020
         BRWRITE 1                 PRINT LINE                           49600020
         L     R2,LLENEXT          LOAD PTR TO NXT RB ON LIST           50000020
         B     LPAMFTLP            LOOP THROUGH LIST                    50400020
         SPACE 2                                                        50800020
*********************************************************************** 51200020
*                                                                     * 51600020
*   TEST FOR TOP OF PAGE AND PRINT TITLES IF IT IS                    * 52000020
*                                                                     * 52400020
*********************************************************************** 52800020
         SPACE                                                          53200020
LPATITLE LH    R0,LINENUM          LOAD NUMBER OF LINES PER PAGE-2      53600020
         C     R0,LINECNT          AM I AT TOP OF PAGE                  54000020
         BCR   7,R9                RETURN TO CALLER IF NOT              54400020
         L     BUFREG,CURBUF       TO ASSURE BUFREG IS LOADED           54800020
         MVC   ADDR+33(54),TITLE1  MOVE FIRST TITLE                     55200020
         BRWRITE 3                 GO PRINT FIRST TITLE                 55600020
         MVC   FIELD1+2(47),TITLE2 MOVE SECOND TITLE                    56000020
         BRWRITE 2                 GO PRINT SECOND TITLE                56400020
         BR    R9                  CONTINUE                             56800020
         EJECT                                                          57200020
*********************************************************************** 57600020
*                                                                     * 58000020
*   ERROR DURING LPA MAP....TERMINATE MAP                             * 58400020
*                                                                     * 58800020
*********************************************************************** 59200020
         SPACE                                                          59600020
         DROP  BASE1                                                    60000020
         USING *,R15               ERROR HANDLER BASED ON REG 15        60400020
LPAERROR LA    R13,MAPSAVE         SET UP LPA MAP SAVE AREA             60800020
         LM    R14,R12,12(R13)     RESTORE LPA'S REGS                   61200020
         DROP  R15                                                      61600020
         USING LPABASE,BASE1                                            62000020
         MVC   LPAERWTO+31(26),LPERMSG  MOVE ACTION TO WTO LIST         62400020
         MVC   LPAWORK1(1),SWB     MOVE SWB TO WORK AREA                62800020
         NI    LPAWORK1,IOERR+FMTERR  RESET ALL BUT POSSIBLE I/O AND    63200020
*                                  FORMAT ERROR SWITCHES                63600020
         SR    R3,R3               CLEAR R3                             64000020
         IC    R3,LPAWORK1         ERROR SWITCHES TO R3                 64400020
         SRL   R3,4                SHIFT RIGHT TO USE AS INDEX          64800020
         L     R5,AERRMSGA(R3)     LOAD CORRECT ERROR MESSAGE ADDR      65200020
         MVC   LPAERWTO+4(26),0(R5)  MOVE ERROR MSG TO WTO BUFFER       65600020
         BRPRTMSG LPAERWTO+4,53 PRINT ERROR MSG ON SYSPRINT             66000020
         TM    SWA,RDRSW           IF COMMANDS ARE BEING ENTERED FROM   66400020
*                                  SYSIN,                               66800020
         BZ    LPADONE             BRANCH OUT BEFORE ISSUING WTO        67200020
*                                  OTHERWISE, TELL OPERATOR ABOUT       67600020
*                                  ERROR                                68000020
         WTO   MF=(E,LPAERWTO)                                          68400020
         B     LPADONE                                           A47532 68450021
         SPACE 2                                                        68800020
*********************************************************************** 69200020
*                                                                     * 69600020
*   ALL DONE WITH MAP...RETURN TO CALLER                              * 70000020
*                                                                     * 70400020
*********************************************************************** 70800020
         SPACE                                                          71200020
LPANONE  BAL   R9,LPATITLE         TITLE PAGE BEFORE GIVING NONE A35932 71600020
*                                  MESSAGE                       A35932 72000020
         MVC   ADDR(L'NOLPAMSG),NOLPAMSG                         A35932 72400020
         BRWRITE  1                                              A35932 72800020
LPADONE  MVC   ERRADDR,LPAERSV     RESTORE PREVIOUS ERROR ADDR          73200020
LPADONE1 L     R13,4(R13)          RESTORE CALLER'S REGISTERS           73600021
         LM    R14,R12,12(R13)                                          74000020
         BR    RETREG              RETURN TO CALLER                     74400020
         EJECT                                                          74800020
*********************************************************************** 75200020
*                                                                     * 75600020
*   CONSTANTS AND SAVE AREA FOR LPAMAP ROUTINE                        * 76000020
*                                                                     * 76400020
*********************************************************************** 76800020
         SPACE                                                          77200020
MAPSAVE  DC    18F'0'              IMDPRLPA SAVE AREA                   77600020
LPAERSV  DC    F'0'                SAVE AREA FOR ERRADDR                78000020
LLENEXT  DC    F'0'                                                     78400020
LPAWORK1 DC    F'0'                                                     78800020
LPAWORK2 DC    F'0'                                                     79200020
MNAME    DC    8C' '               MAJOR CDE NAME SAVE FIELD   @SA68379 79400021
MAJLINE  DC    16C' '              EPA, STA, LNGH SAVE AREA    @SA68379 79500021
         SPACE                                                          79600020
LPAERWTO DC    AL2(57)              WTO LIST FORM                       80000020
         DC    X'8000'                                                  80400020
         DC    CL53' '                                                  80800020
         DC    X'0200'             DESC                                 81200020
         DC    X'4000'             ROUTCDE                              81600020
         SPACE                                                          82000020
*   PATTERN FOR MFT LINK PACK AREA MAP                                  82400020
LPAMPTN  FMTPTRN (DTA,DTAP,DTAE),,8,,FIELD1-ADDR,,(LPAMPTNA,0)          82800020
         FMTPTRN (DTA,DTAP),,3,,FIELD1+20-ADDR,,(LPAMPTNB,0)            83200020
         FMTPTRN (DTA,DTAP,DTAC),,3,,FIELD1+28-ADDR,,(LPAWORK1+1)       83600020
         FMTPTRN (DTA,DTAP,DTAC),,3,,FIELD1+36-ADDR,,(LPAWORK2+1)       84000020
         FMTPTRN (LBL,LBLP),4,,FIELD1+45-ADDR,,(LPAMPTNC,0),,LAST       84400020
LPALPRB  DC    CL4'LPRB'                                                84800020
LPALRB   DC    CL4'LRB'                                                 85200020
MAJOR    DC    C'MAJOR'                                                 85600020
MINOR    DC    C'MINOR'                                                 86000020
CDEATTR  DC    X'00'                                                    86400020
LPERMSG  DC    CL28'LINK PACK AREA MAP ABORTED'                         86800020
NOLPAMSG DC    C'NO LINK PACK AREA QUEUE'                        A35932 87200020
TITLE1   DC    C'* * * *    L I N K  P A C K  A R E A  M A P    * * * *X87600020
               '                                                        88000020
TITLE2   DC    C'NAME                EPA     STA    LNGH    TYPE'       88400020
         SPACE                                                          88800020
         END                                                            89200020
