IMDPRMST START                                                          00200020
         TITLE 'IMDPRMST - GET MASTER ROUTINE'                          00400020
*A 074500,0696500                                               SA58793 00402000
*C 108600                                                       SA58793 00404000
*A 108900                                                         M1741 00410021
*A 651520-651560                                                  M0863 00450021
*A 650085-650086                                                  M0862 00700021
*A 650020-650084,650087-652000,708600-709000                     S21016 00750021
*A 244500-245000                                                 A45382 00752021
*A 048100,096500-097000,108600-108800,111999,660585-660586       A46340 00754021
*A 708800                                                        A46340 00756021
*C 106500,109000                                                 A46340 00758021
*********************************************************************** 00760021
*                                                                     * 00800020
* STATUS -                                                            * 00850021
*                                                                     * 00860021
*    OS/360  RELEASE 21                                               * 00900021
*                                                                     * 00910021
* FUNCTION -                                                          * 00950021
*                                                                     * 00960021
*    IMDPRMST IS THE PRIMARY DUMP INITIALIZATION ROUTINE.  THIS       * 01000021
*    ROUTINE IS LOADED AND INVOKED BY THE READ-CONTROL ROUTINE        * 01050021
*    IMDPRRDC AS PART OF READ ROUTINE INITIALIZATION.  OFTEN          * 01100021
*    NEEDED INFORMATION IS EXTRACTED FROM THE DUMP DATA SET AND       * 01150021
*    STORED IN THE COMMON CSECT.  A LIST OF THIS INFORMATION          * 01200021
*    MAY BE FOUND UNDER THE OUTPUT SECTION.                           * 01250021
*                                                                     * 01252021
*    IMDPRMST CONTAINS DATE AND TIMER ROUTINES WHICH, IN THE CASE     * 01260021
*    OF A DUMP DATA SET PRODUCED BY IMDSADMP, COMPUTE DATE AND        * 01270021
*    TIME FOR THE IMDPRDMP PAGE TITLES.  THE DATE, IN JULIAN FORM,    * 01280021
*    IS OBTAINED FROM THE CVT AND CONVERTED TO THE REAL DATE, AND     * 01290021
*    THE TIME OF THE DUMP IS COMPUTED USING THE S/360 TIMER VALUE     * 01292021
*    AND THE OS/360 PSEUDO CLOCKS.                                    * 01294021
*                                                                     * 01294421
*    IF A DUMP TITLE IS CONTAINED IN THE HEADER RECORD, THIS          * 01296021
*    TITLE IS PRINTED ON THE FIRST PAGE OF THE DUMP LISTING.          * 01298021
*                                                                     * 01300021
* ENTRY POINTS -                                                      * 01350021
*                                                                     * 01360021
*    IMDPRMST IS THE MAIN AND ONLY ENTRY POINT.  IMDPRMST             * 01400021
*    RECEIVES CONTROL FROM MODULE IMDPRRDC DURING INITIALIZATION      * 01450021
*    (INIT FUNCTION).                                                 * 01500021
*                                                                     * 01550021
* INPUT -                                                             * 01600021
*                                                                     * 01610021
*    INFORMATION OBTAINED FOR COMMON BY IMDPRMST IS READ FROM         * 01650021
*    THE DUMP DATA SET USING THE BRREAD PRIVATE MACRO INSTRUCTION.    * 01700021
*    THIS MACRO GENERATES THE CALLING SEQUENCE TO MODULE              * 01750021
*    IMDPRRDC.  A COMPLETE LIST OF WHICH DATA IN THE DUMP DATA        * 01800021
*    SET IS REFERENCED BY IMDPRMST MAY BE FOUND UNDER OUTPUT.         * 01850021
*                                                                     * 01900021
*    CVTADDR - IF SETCVTSW IN SWA OF COMMON IS ON WHEN                * 01950021
*              IMDPRMST RECEIVES CONTROL, THE ADDRESS OF              * 02000021
*              THE CVT IN THE DUMP SYSTEM IS TAKEN FROM THE           * 02050021
*              COMMON CSECT FIELD CVTADDR.  THE SETCVTSW IS           * 02100021
*              SET BY THE CVT= CONTROL STATEMENT TO INDICATE          * 02150021
*              THAT THE CVT ADDRESS HAS BEEN SPECIFIED BY THE         * 02200021
*              USER AND SHOULD NOT BE TAKEN FROM LOCATION             * 02250021
*              X'4C' IN THE DUMP DATA SET.  IF THE CVT VALIDITY       * 02300021
*              CHECKING FAILS, A SCAN OF THE DUMP IS MADE IN          * 02350021
*              AN ATTEMPT TO LOCATE THE CVT.  THIS PROCESSING         * 02400021
*              IS DESCRIBED UNDER NOTE 1.                             * 02450021
*                                                                     * 02500021
*    OUTPUT -                                                         * 02550021
*                                                                     * 02560021
*    THE FOLLOWING FIELDS IN THE COMMON CSECT ARE INITIALIZED         * 02600021
*    BY IMDPRMST.                                                     * 02650021
*         1. CVTADDR - ADDRESS OF CVT IN DUMP SYSTEM (SEE CVTADDR     * 02700021
*            UNDER INPUT AND NOTE 1)                                  * 02750021
*         2. CURTCB - ADDRESS OF CURRENT TCB (CONTENT OF FULL WORD    * 02800021
*            ADDRESSED BY CVT+X'00')                                  * 02850021
*         3. SECCVTA - ADDRESS OF SECONDARY CVT (CVT+X'C8')           * 02900021
*         4. NUCTOP - UPPER BOUND OF NUCLEUS (CVT+X'80')              * 02950021
*         5. CVTHEAD - ADDRESS OF HIGHEST PRIORITY TCB ON TCB         * 03000021
*            READY QUEUE (CVT+X'A0')                                  * 03050021
*         6. ADDRMAX - HIGHEST MACHINE ADDRESS (CVT+X'A4')            * 03100021
*         7. SWE - SWITCHES SET ARE                                   * 03150021
*                  MVTSW - DUMP IS FROM MVT SYSTEM                    * 03200021
*                  MFTSW - DUMP IS FROM MFT SYSTEM                    * 03210021
*                  MFTATCH - DUMP IS FROM MFT SYSTEM WITH ATTACH      * 03220021
*         8. MSTRTCB - ADDRESS OF MASTER SCHEDULER TCB                * 03230021
*            (ORIGINATING TCB OF HIGHEST PRIORITY TCB ON              * 03240021
*            TCB READY QUEUE). THIS FIELD IS SET TO ZERO              * 03242021
*            FOR MFT AND PCP SYSTEMS.                                 * 03244021
*         9. MSTRDTR - ADDRESS OF MOST RECENTLY ATTACHED SUBTASK      * 03246021
*            OF MASTER SCHEDULER (MASTER SCHEDULER TCB+X'88')         * 03248021
*        10. TRNSVCTB - ADDRESS OF TRANSIENT AREA RB NAME TABLE.      * 03248421
*            THE HIGH ORDER BYTE OF THIS WORD IN COMMON CONTAINS      * 03248821
*            THE NUMBER OF ENTRIES IN THE RB NAME TABLE. (RB NAMES    * 03249221
*            ARE FOUND BY HIGHEST RB ON EACH TRANSIENT AREA FETCH     * 03249621
*            TCB WHICH IN TURN ARE ADDRESSED BY THE TRANSIENT         * 03249721
*            AREA CONTROL TABLE.)                                     * 03249821
*        11. PRFXA - ADDRESS OF HIGH PREFIX IN DUMP FROM AN           * 03249921
*            M65MP SYSTEM.  THIS FIELD IS SET TO ZERO FOR NON-        * 03266621
*            MP SYSTEMS, TO INDICATE THAT THE SYSTEM IS NOT M65MP.    * 03276621
*        12. TITLEMOD - MODULE NAME FROM DUMP HEADER RECORD,          * 03278621
*            EITHER IMDSADMP OR NAME OF MODULE USING SVC DUMP.        * 03280621
*        13. TITLEDTE - REAL DATA CONVERTED FROM JULIAN DATE IN       * 03282621
*            CVT (CVT+X'30')                                          * 03283021
*        14. TITLETME - TIME OF DUMP                                  * 03283121
*                  A) IF THE MODULE NAME IN THE DUMP HEADER RECORD    * 03283221
*                     IS IMDSADMP AND THE TIME OF DAY CLOCK IS NOT    * 03288821
*                     PRESENT ON THE SYSTEM, THEN THE TIME OF THE     * 03290821
*                     DUMP IS COMPUTED FROM THE DUMP CONTENT.  INPUT  * 03292821
*                     TO THIS TIME CALCULATION IS THE S/360 TIMER AT  * 03293221
*                     ADDRESS X'50' IN THE DUMP AND THE OS/360 TIMER  * 03293621
*                     ROUTINE PSEUDO CLOCKS AS ADDRESSED BY CVT+X'58'.* 03294021
*                     IF THE DUMP IS FROM AN M65MP SYSTEM, THE ACTIVE * 03294121
*                     TIMER IS DETERMINED BY THE TIME STATUS WORD IN  * 03294221
*                     THE LOW PREFIX (X'2CB').  WHEN THE TIMER STATUS * 03294321
*                     WORD IS ZERO, THE TIMER AT LOCATION X'50' IS    * 03308221
*                     ACTIVE, OTHERWISE THE TIMER AT RELATIVE LOCATION* 03318221
*                     X'50' IS THE HIGH PREFIX IS ACTIVE.             * 03320221
*                  B) IF THE MODULE NAME IN THE HEADER RECORD IS      * 03320621
*                     IMDSADMP AND THE TIME OF DAY CLOCK IS INDICATED * 03321021
*                     BY CVT OPTIONS AT CVT+X'B7', THEN THE TIME      * 03321421
*                     CANNOT BE COMPUTED BY IMDPRDMP.  THE TIME FIELD * 03321821
*                     IN THE TITLE IS FILLED IN WITH THE CHARACTER    * 03321921
*                     STRING 'TOD CLK'.                               * 03322021
*                  C) IF THE MODULE NAME IN THE HEADER RECORD IS NOT  * 03322121
*                     IMDSADMP, THE TIME OF THE DUMP IS EXTRACTED     * 03326721
*                     FROM THE HEADER RECORD (OFFSET X'08').          * 03328721
*                                                                     * 03329121
*         IF THE DUMP HEADER RECORD CONTAINS A TITLE, THE TITLE       * 03330721
*         IS PRINTED ON THE FIRST PAGE OF THE DUMP LISTING USING      * 03331121
*         THE BRWRITE PRIVATE MACRO INSTRUCTION.                      * 03331221
*                                                                     * 03331321
* EXTERNAL REFERENCES -                                               * 03331421
*                                                                     * 03333421
*    1. BRREAD - DUMP INFORMATION IS READ USING THE BRREAD PRIVATE    * 03336021
*       MACRO INSTRUCTION.  THIS MACRO EXPANDS TO THE CALLING         * 03338121
*       SEQUENCE TO MODULE IMDPRRDC, THE READ CONTROL ROUTINE.        * 03340121
*    2. BRWRITE - THE DUMP TITLE, IF PRESENT IN THE HEADER RECORD,    * 03340521
*       IS PRINTED ON THE FIRST PAGE OF THE DUMP LISTING USING        * 03340621
*       THE BRWRITE MACRO INSTRUCTION.  IF NO TITLE IS PRESENT,       * 03340721
*       THEN THE CHARACTER STRING 'TITLE FROM DUMP: NONE' IS          * 03344521
*       WRITTEN.  THE BRWRITE MACRO GENERATES LINKAGE TO THE          * 03346521
*       WRITE ROUTINE, IMDPRWTR.                                      * 03348521
*                                                                     * 03349021
* EXITS,NORMAL -                                                      * 03349421
*                                                                     * 03349521
*    SUCCESSFUL COMPLETION OF DUMP INITIALIZATION IS INDICATED        * 03349821
*    BY RETURNING TO IMDPRRDC WITH THE MSTRSW SWITCH IN SWC OF        * 03349921
*    COMMON SET.                                                      * 03351521
*                                                                     * 03353521
* EXITS,ERROR -                                                       * 03353921
*                                                                     * 03354021
*    IF AN ERROR IS ENCOUNTERED DURING DUMP INITIALIZATION,           * 03354421
*    IMDPRMST RETURNS TO IMDPRRDC WITH THE MSTRSW SWITCH IN SWC       * 03354521
*    OF COMMON OFF.  IMDPRRDC THE RAISES THEN ERROR CONDITION.        * 03354621
*                                                                     * 03354721
* TABLES/WORK AREAS -                                                 * 03355121
*                                                                     * 03355221
*    ALL OUTPUT OF IMDPRMST IS STORED IND THE IMDPRDMP COMMON CSECT   * 03355521
*                                                                     * 03355621
* ATTRIBUTES -                                                        * 03355721
*                                                                     * 03356021
*    REUSABLE                                                         * 03357321
*                                                                     * 03357621
* CHARACTER CODE DEPENDENCY - NONE                                    * 03358921
*                                                                     * 03359321
* NOTES -                                                             * 03359421
*                                                                     * 03359521
*    1. USING EITHER LOCATION X'4C' IN THE DUMP OR CVTADDR            * 03359621
*       IN COMMON (IF SETCVTSW IS ON), THE CVT IN THE DUMP            * 03359721
*       SYSTEM IS LOCATED.  A CHECK IS MADE AT CVT+X'50' FOR          * 03359821
*       THE INSTRUCTIONS SVC 3 AND BR 14 TO VERIFY THAT THE           * 03359921
*       CVT HAS BEEN FOUND.  IF THIS CHECK FAILS, THE DUMP            * 03360021
*       DATA SET IS SCANNED FOR THE ABOVE INSTRUCTION SEQUENCE        * 03360321
*       IN AN ATTEMPT TO LOCATE THE CVT.                              * 03360721
*    2. IMDPRMST ESTABLISHES AN ERROR HANDLER BY STORING THE          * 03361121
*       ADDRESS OF THE ERROR ROUTINE IN ERRADDR IN COMMON. SHOULD     * 03361221
*       AN ERROR OCCUR DURING IMDPRMST PROCESSING, THIS ERROR         * 03361621
*       HANDLER IS GIVEN CONTROL.  THE ACTION OF THIS ROUTINE         * 03362021
*       IS TO RETURN TO IMDPRRDC WITH THE MSTRSW OFF, THEREBY         * 03362421
*       CAUSING IMDPRRDC TO RAISE THE ERROR CONDITION.                * 03362521
*                                                                     * 03362621
*********************************************************************** 03362721
*/*IMDPRMST: CHART (SEQ) */                                             03362821
*/*HEADER                                                               03363221
*/*IMDPRMST - GET MASTER ROUTINE FLOWCHARTS                             03363621
*/*                                                      PAGE #   */    03364021
*/*IMDPRMST: E START */                                                 03364421
*/* P SET UP ADDRESSABILITY */                                          03365121
*/* P ESTABLISH GET MASTER-S ERROR HANDLER - MSTERR */                  03366221
*/* P BLANK OUT TITLE LINE */                                           03367321
*/* D (YES,GETMSTRC,NO,) WAS CVT ADDR SET BY CONTROL */                 03368421
*/* S (,GETMSTRA) BRREAD: GET CVT PTR FROM X'4C' OF DUMP */             03368721
*/*GETMSTRC: P GET ADDR OF CVT PTR FROM COMMON */                       03370321
*/*GETMSTRA: P LOAD CVT PTR */                                          03371921
*/*GETMSTRB: P SAVE CVT PTR IN COMMON */                                03373521
*/* M INDICATE ERROR TO BE IGNORED */                                   03373921
*/* M SET UP FOR CVT SEARCH */                                          03374321
*/* S BRREAD: GET WORD OF CVT WITH SVC 3 & BR 14 INSTRUCTIONS */        03375121
*/* D (YES,GETMSTMR,NO,) ARE THE INSTR. PRESENT */                      03376721
*/* P START CVT SEARCH AT LOCATION X'50' */                             03378321
*/*GETMSTRK: S BRREAD: GET A WORD OF STORAGE */                         03379921
*/* D (YES,GETMSTRI,NO,) SVC 3 & BR 14 INST. PRESENT */                 03389921
*/*GETMSTRL: P  ADD 4 TO SEARCH ADDR */                                 03393200
*/* D (YES,,NO,GETMSTRK) ADDR GREATER DEFAULT NUCTOP */                 03393600
*/* P (,GMSTERR) CANNOT FIND CVT - ERROR EXIT */                        03394000
*/*GETMSTRI: S BRREAD: GET ADDR OF TOP OF NUCLEUS */                    03395221
*/* D (NO,GETMSTRL,YES,) IS HIGH ORDER BYTE = 0 */                      03395621
*/* D (NO,GETMSTRL,YES,) LAST BYTE = 0 */                               03396021
*/* P SAVE NUCLEUS TOP ADDR */                                          03396421
*/* S BRREAD: GET MAXIMUM ADDR FROM CVT */                              03396521
*/* D (NO,GETMSTRL,YES,) HIGH BYTE = 0 */                               03396621
*/* D (NO,GETMSTRL,YES,) LAST BYTE = FF */                              03446621
*/* D (NO,GETMSTRL,YES,) IS IT >= NUCLEUS TOP */                        03456621
*/* P SAVE ADDR IN COMMON */                                            03466621
*/*GETMSTMR: M RESET CVT ERROR INDICATOR */                             03468621
*/* S BRREAD: GET TIMER WORD AT X'50' */                                03476621
*/* P SAVE TIMER VALUE */                                               03486621
*/* S BRREAD: GET FIRST WORD OF CVT */                                  03488621
*/* S BRREAD: GET CURRENT TCB POINTER */                                03490621
*/* P SAVE ADDR OF CURRENT TCB IN COMMON */                             03492621
*/*GETMSTR3: S BRREAD: GET PTR TO 2ND CVT */                            03494621
*/* P SAVE PTR TO 2ND CVT IN COMMON */                                  03495021
*/* S BRREAD: GET DATE FROM CVT */                                      03495421
*/* P SAVE DATE FOR LATER CONVERSION */                                 03495821
*/* S BRREAD: GET TOP OF NUC. VALUE */                                  03496221
*/* P SAVE IT IN COMMON */                                              03496321
*/* S BRREAD: GET TOP TCB ADDR FROM CVT */                              03496421
*/* P SAVE IT IN COMMON */                                              03496521
*/* S BRREAD: GET MACHINE SIZE FROM CVT */                              03513221
*/* P SAVE IT IN COMMON */                                              03523221
*/* S BRREAD: GET CVT OPTION B */                                       03525221
*/* D (NO,SHPC,YES,) TOD CLOCK IN SYSTEM */                             03527221
*/* M (,SYSOPT) INDICATE TOD CLOCK PRESENT */                           03529221
*/*SHPC: S BRREAD: GET PTR TO SHPC */                                   03529621
*/* P SAVE IT FOR LATER TIME RTN */                                     03529721
*/*SYSOPT: S BRREAD: GET SYSTEM OPTIONS */                              03529821
*/* M RESET SYSTEM TYPE SWITCHES */                                     03535421
*/* D (NO,GETMSTR4,YES,) IS THIS MVT SYSTEM */                          03537421
*/* M SET MVT SYSTEM SWITCH */                                          03539421
*/* P LOAD ADDR OF PREFIX ADDR FOR MP65 */                              03539821
*/* D (NO,GETMSTRE,YES,) IS THIS MP65 SYSTEM */                         03540221
*/* P CALCULATE AND SAVE HIGH PREFIX ADDR IN COMMON */                  03540621
*/* S BRREAD: GET TIMER STATUS INDICATOR */                             03540721
*/* D (YES,GETMSTRF,NO,) IS STATUS FIELD = 0 */                         03540821
*/* S BRREAD: GET TIMER FROM HIGH PREFIX */                             03540921
*/* P (,GETMSTRF) RE-SAVE TIMER VALUE */                                03555621
*/*GETMSTRE: P ZERO PREFIX ADDR WORD */                                 03565621
*/*GETMSTRF: S BRREAD: GET PTR TO MOTHER OF HEAD TCB */                 03567621
*/* P SAVE IT IN COMMON AS MASTER SCHED. TCB */                         03569621
*/* S BRREAD: GET PTR TO DAUGHTER TCB OF MASTER SCHED. */               03570021
*/* P SAVE IT IN COMMON */                                              03570421
*/* S BRREAD: GET TACT PTR FROM 2ND CVT */                              03570521
*/* S BRREAD: GET NUMBER OF ENTRIES IN TACT */                          03575421
*/* D (YES,GMSTERR,NO,) IS # OF ENTRIES > 50 */                         03577421
*/* D (YES,GMSTERR,NO,) IS # OF ENTRIES 0 OR LESS */                    03577821
*/* P LOAD TRANSIENT SVC TABLE ADDR FROM COMMON */                      03579421
*/* D (YES,GETMSTR8,NO,) IS IT = 0 */                                   03579821
*/* P CALCULATE LENGTH OF TABLE */                                      03580221
*/* L FREE STORAGE OCCUPIED BY OLD TABLE */                             03580321
*/* P ZERO OLD TABLE PTR */                                             03585221
*/*GETMSTR8: P CALCULATE # OF BYTES FOR NEW TABLE */                    03585321
*/* L GET STORAGE FOR NEW TABLE */                                      03587321
*/* P SAVE TABLE PTR AND LENGTH */                                      03589321
*/*GETMSTR7: S BRREAD: GET A TRANS. AREA FETCH TCB PTR */               03589721
*/* S BRREAD: GET THE RB ADDR FROM THE TCB */                           03590121
*/*GETMSTR6: S BRREAD: GET 4 BYTES OF NAME FROM RB */                   03632021
*/* P MOVE 4 BYTES OF NAME TO TABLE */                                  03642021
*/* D (NO,GETMSTR6,YES,) 8 BYTES GOTTEN */                              03652021
*/* P POINT TO NEXT TRAN. AREA FETCH TCB */                             03662021
*/* D (NO,GETMSTR7,YES,GETMSTR5) ALL ENTRIES GOTTEN */                  03672021
*/*GETMSTR4: N PCP/MFT SYSTEM */                                        03674021
*/* P ZERO OUT MASTER SCHED. TCB PTR IN COMMON */                       03674121
*/* P ZERO OUT MP65 PREFIX ADDR IN COMMON */                            03674221
*/* D (NO,GETMSTR5,YES,) MFT SYSTEM */                                  03688221
*/* M SET MFT SYSTEM SWITCH */                                          03698221
*/* S BRREAD: GET MFT ATTACH FLAG FROM CVT */                           03700221
*/* D (NO,GETMSTR5,YES,) IS IT ON */                                    03700621
*/* M (,GETMSTR5) SET MFT ATTACH SWITCH */                              03701021
*/*GETMSTR5: S BRREAD: READ THE HEADER RECORD */                        03701421
*/* P MOVE MODULE NAME TO TITLE */                                      03701821
*/* D (YES,DATER,NO,) IS IT IMDSADMP HEADER */                          03701921
*/* P GET DATE FROM HEADER */                                           03702021
*/*DATER: D (NO,GETMSTR1,YES,) IS DATE VALID */                         03702121
*/* P CONVERT 2-DIGIT YEAR TO DETERMINE TYPE OF YEAR */                 03706821
*/* P CONVERT 3-DIGIT DAY TO MONTH AND DAY */                           03708821
*/* P CONVERT THE DATE TO PRINTABLE CHARS. */                           03710821
*/* P MOVE YR., DAY AND MONTH TO DATE PATTERN FOR PRINTING */           03711221
*/* P MOVE PATTERN (DATE) TO TITLE */                                   03711321
*/*GETMSTR1: D (YES,GETMSTTM,NO,) IS THIS IMDSADMP DUMP */              03711421
*/* D (YES,GETMSTTM,NO,) IS TIMER IN HEADER = 0 */                      03723021
*/* P (,MASTDONE) FORMAT TIME FROM HEADER */                            03733021
*/*GETMSTTM: D (YES,NOTIME,NO,) IS SHPC = 0 */                          03733421
*/* D (YES,TODCLOCK,NO,) IS IT < 0 */                                   03733821
*/* S BRREAD: GET SHPC FROM DUMP */                                     03734221
*/* P SAVE SHPC */                                                      03734621
*/* S BRREAD: GET 24 HOUR PC */                                         03734721
*/* P SAVE 24 HR. PC */                                                 03734821
*/* S BRREAD: GET LOCAL TIME PC */                                      03738721
*/* P SAVE LOCAL TIME PC */                                             03740721
*/* P CALCULATE SHPC + T4PC - TIMER */                                  03741121
*/* D (NO,TIME1,YES,) IS RESULTS > 24 HOURS */                          03741521
*/* P ADD MODULO ADJUSTMENT */                                          03741921
*/*TIME1: P ADD LOCAL TIME PC */                                        03742321
*/* D (YES,TMEADJ,NO,) RESULTS OVERFLOW */                              03742421
*/* D (YES,TMEADJ,NO,TMECNVT) OVER 24 HOURS */                          03742521
*/*TMEADJ: P ADD MODULO ADJUSTMENT */                                   03746421
*/*TMECNVT: P CONVERT TIME VALUE TO HRS/MIN */                          03746521
*/*TMEDONE: P CONVERT TIME TO PRINTABLE CHARS. */                       03748521
*/* P MOVE TIME TO TITLE */                                             03748921
*/*MASTDONE: M SET MASTER SWITCH ON */                                  03749321
*/*GMSTERR: S BRREAD: READ HEADER RECORD */                             03749421
*/* D (YES,MVCTTL,NO,) IMDSADMP DUMP */                                 03749521
*/* D (YES,,NO,MVCTTL) LENGTH OF USER DATA POSITIVE */                  03749621
*/* P MOVE USER DATA FIELD TO OUTPUT BUFFER */                          03753021
*/* P MOVE MOVE HEADING TO OUTPUT BUFFER */                             03755021
*/*WRTTL: P SET DUMP TITLE SWITCH */                                    03755421
*/* S (,GMSTRET) BRWRITE: WRITE DUMP TITLE */                           03755821
*/*MVCTTL: P (,WRTTL) MOVE NO TITLE MESSAGE TO BUFFER */                03756221
*/*GMSTRET: P RESTORE REGS */                                           03756521
*/* R RETURN */                                                         03759921
*/*TODCLOCK: P (,MASTDONE) MOVE TOD INDICATOR TO TITLE */               03763321
*/*NOTIME: P (,MASTDONE) BLANK OUT TIME FIELD IN TITLE */               03766721
*/* E ERROR */                                                          03770121
*/* P POINT TO MST-S SAVE AREA */                                       03770221
*/* P RELOAD REGISTERS */                                               03808521
*/* D (YES,GETMSTRL,NO,) IGNORE CVT ERROR */                            03810521
*/* N (,GMSTRET) BRANCH TO EXIT WITHOUT SETTING MASTER SWITCH */        03818521
*/*IMDPRMST: END */                                                     03846821
         SPACE                                                          03885121
         EQUATES                                                        03923421
         COMMON                                                         03961721
IMDPRMST CSECT                                                          04000020
CVTTOD   EQU   32                  TOD CLOCK IN SYSTEM            M2019 04050020
CVTDATE  EQU   56                                                       04200020
CVTPTR   EQU   76                                                       04400020
CVTEXIT  EQU   80                                                       04450020
CVTTPC   EQU   88                                                       04600020
CVTNUCB  EQU   128                                                      04650020
CVTMZ00  EQU   164                                                      04660020
CVTOPTB  EQU   183                 OPTIONS B IN CVT               M2019 04700020
CVTABEND EQU   200                                                      04800020
BADCVT   EQU   64                                                A46340 04810021
PREFTMRA EQU   712                 OFFSET OF PREFIX TIMER        A38898 04850020
*                                  INDICATOR                     A38898 04900020
         STM   R14,R12,12(R13)     SAVE CALLER'S REGISTER               05000020
         BALR  BASE1,0             SET UP REG 11 AS BASE                05200020
         USING *,BASE1                                                  05400020
MSTBASE  LA    R1,MSTSAVE          SAVE AREA CHAINNING                  05600020
         ST    R13,MSTSAVE+4                                            05800020
         ST    R1,8(R13)                                                06000020
         LR    R13,R1                                                   06200020
         SPACE                                                          06400020
         USING COMMON,COMBASE                                           06600020
         SPACE                                                          06800020
         MVC   MSTERSAV(4),ERRADDR SAVE CALLER-S ERROR ROUTINE   A43168 06850021
*                                  ADDRESS                       A43168 06860021
         LA    R3,MSTERR           POINT TO ERROR HANDLER        A43168 06900021
*                                  FOR GET MASTER ROUTINE        A43168 06910021
         ST    R3,ERRADDR          ESTABLISH MST-S ERROR RTN     A43168 06950021
         MVC   TITLEMOD+7(8),BLANKS  BLANK OUT MODULE NAME IN TITLE     07000020
         MVC   TITLEDTE+5(8),BLANKS  BLANK OUT DATE                     07200020
         MVC   TITLETME+5(8),BLANKS  BLANK TIME                         07400020
         MVC   NUCTOP,MNUCTOP      INIT NUCTOP DEFAULT          SA58793 07450000
         TM    SWA,SETCVTSW        WAS CVT ADDRESS SET BY CONTROL       07600020
         BO    GETMSTRC            BRANCH IF YES                        07800020
         LA    PREG,CVTPTR         NO--GO FIND IT AT LOC X'4C'          08000020
         BRREAD  (PREG),DATA,TJID=0                                     08200020
         LTR   PREG,PREG           TEST PREG FOR ZERO OR NEG            08400020
         BNP   GMSTERR             BRACNH IF SO - ERROR                 08600020
         B     GETMSTRA            BRANCH AROUND                        08800020
         SPACE                                                          09000020
GETMSTRC LA    PREG,CVTADDR        POINT TO CVT ADDR                    09200020
GETMSTRA L     PREG,0(PREG)        CVT PTR                              09400020
GETMSTRB ST    PREG,CVTADDR        SAVE CVT ADDR                        09600020
         OI    PGCVTSW,BADCVT      CVT ERROR TO BE IGNORED       A46340 09650021
         LA    R3,CVTEXIT-4        SET UP FOR CVT SEARCH         A46340 09700021
         LR    R2,PREG             CVT ADDR TO R2                       09800020
         LA    PREG,80(R2)         PREPARE TO VALIDITY CHECK THE CVT    10000020
         BRREAD  (PREG),DATA,TJID=0                                     10200020
         CLC   0(4,PREG),CVTCHK    IS THERE AN SVC 3 AND BCR 15,14      10400020
         BE    GETMSTMR            IF SO, PROBABLY GOOD CVT             10600020
GETCVT   LA    R3,CVTEXIT          START CVT SEARCH AT LOC ZERO         10650021
GETMSTRK BRREAD  (R3)                                                   10700020
         CLC   0(4,PREG),CVTCHK    TEST FOR POSSIBLE CVT                10750020
         BE    GETMSTRI            A POSSIBLITY, GO TEST FURTHER        10800020
GETMSTRL AH    R3,FOUR             INCR. SEARCH ADDRESS                 10850020
         C     R3,NUCTOP           REACHED SEARCH LIMIT         SA58793 10860000
         BL    GETMSTRK            LOOP TO READ                  A46340 10870021
         NI    PGCVTSW,255-BADCVT  YES - RESET SWITCH            A46340 10880021
         OI    SWB,FMTERR          INDICATE FORMAT ERROR          M1741 10890021
         B     GMSTERR             PREPARE TO EXIT               A46340 10900021
GETMSTRI LA    PREG,CVTNUCB-CVTEXIT(R3)  ADDR OF NUC TOP                10950020
         BRREAD  (PREG)                                                 11000020
         CLI   0(PREG),0           TEST FOR ZERO IN HIGH BYTE           11050020
         BNE   GETMSTRL            BRANCH IF NOT, TO CONTINUE SEARCH    11100020
         CLI   3(PREG),0           TEST FOR LAST BYTE ZERO (2K BDY)     11150020
         BNE   GETMSTRL            BRANCH IF NOT, TO CONTINUE           11160020
         L     R2,0(PREG)          SAVE NUC TOP IN REG 2                11170020
         LA    PREG,CVTMZ00-CVTEXIT(R3)  ADDR OF MAX MACH. ADDR         11180020
         BRREAD  (PREG)                                                 11190020
         CLI   0(PREG),0           TEST FOR ZERO IN HIGH BYTE           11192020
         BNE   GETMSTRL            NOT, CONTINUE                        11194020
         CLI   3(PREG),255         TEST FOR FF IN LAST BYTE             11196020
         BNE   GETMSTRL            NOT, CONTINUE                        11198020
         C     R2,0(PREG)          COMPARE NUC TOP TO MAX MACH. AD      11198420
         BNL   GETMSTRL            CAN'T BE CVT                         11198820
         LA    R2,CVTEXIT          WE'VE GOT A  CVT                     11199220
         SR    R3,R2               BACK UP TO CVT BEGINNING             11199620
         LR    R2,R3               LOAD CVT ADDRESS TO REG 2            11199720
         ST    R2,CVTADDR          STORE CVT ADDR IN COMMON             11199821
GETMSTMR NI    PGCVTSW,255-BADCVT  RESET IGNORE INDICATOR        A46340 11199921
         LA    PREG,TIMER          ADDR OF TIMER                        11200021
         BRREAD  (PREG)                                                 11400020
         MVC   PTIMER(4),0(PREG)   SAVE THE TIMER VALUE                 11600020
*                                  ADDR OF CVT TCB POINTER IN REG 2     11800020
         BRREAD  (R2)                                                   12000020
         L     PREG,0(PREG)        CVTTCBP                              12200020
         LA    PREG,4(PREG)        ADDR OF CURRENT TCB PTR              12400020
         BRREAD  (PREG)                                                 12600020
         MVC   CURTCB(4),0(PREG)   SAVE ADDR OF CURRENT TCB             12800020
GETMSTR3 EQU   *                                                        13000020
         LA    PREG,CVTABEND(R2)   ADDR OF PTR TO SEC CVT               13200020
         BRREAD  (PREG)                                                 13400020
         L     PREG,0(PREG)        SAVE ADDR OF                         13600020
         ST    PREG,SECCVTA        SECONDARY CVT                        13800020
         LA    PREG,CVTDATE(R2)    ADDR OF DATE                         14000020
         BRREAD  (PREG)                                                 14200020
         MVC   DATE(4),0(PREG)     SAVE DATE FOR LATER                  14400020
         LA    PREG,128(R2)        NUC UPPERBOUND PTR ADDR              14600020
         BRREAD  (PREG)                                                 14800020
         L     R3,0(PREG)          SAVE UPPER BOUND                     15000020
         ST    R3,NUCTOP           OF NUCLEUS                           15200020
         LA    PREG,160(R2)        ADDR OF TCB CHAIN PTR                15400020
         BRREAD  (PREG)                                                 15600020
         L     R3,0(PREG)          SAVE TCB CHAIN                       15800020
         ST    R3,CVTHEAD          POINTER                              16000020
         LA    PREG,164(R2)        ADDR OF MACHINE SIZE                 16200020
         BRREAD  (PREG)                                                 16400020
         L     R3,0(PREG)          MACHINE SIZE                         16450020
         ST    R3,ADDRMAX          SAVE IT                              16500020
         LA    PREG,CVTOPTB(R2)    POINT TO CVT OPTIONS B         M2019 16910020
         BRREAD  (PREG)                                           M2019 16920020
         TM    0(PREG),CVTTOD      TEST FOR TOD CLOCK             M2019 16950020
         BZ    SHPC                IF NOT IN SYSTEM, GO STORE     M2019 16960020
*                                  PSEUDO CLOCK ADDRESS           M2019 16970020
         LA    PREG,1              INDICATE TOD TO TIME ROUTINE   M2019 16980020
         LCR   PREG,PREG                                          M2019 16990020
         ST    PREG,PSHPC                                         M2019 16992020
         B     SYSOPT              BRANCH TO TEST SYSTEM OPTION   M2019 16994020
SHPC     LA    PREG,CVTTPC(R2)     ADDR OF PTR TO SHPC            M2019 16996020
         BRREAD  (PREG)                                                 17200020
         MVC   PSHPC(4),0(PREG)    SAVE SHPC ADDR                       17400020
SYSOPT   LA    PREG,116(R2)        POINT TO SYSTEM OPTION         M2019 17600020
         BRREAD  (PREG)                                                 17800020
         NI    SWE,255-MVTSW-MFTSW-MFTATCH RESET SYS TYPE SWITCHES      18000020
         TM    0(PREG),X'10'       IS THIS MVT ENVIRONMENT              18200020
         BZ    GETMSTR4            BR IF PCP OR MFT                     18400020
         OI    SWE,MVTSW           SET MVT SWITCH                       18600020
         LA    R5,PRFXA            LOAD ADDR OF PREFIX ADDR FOR MP65    18800020
         CLI   0(PREG),X'14'       IS THIS MP65                         19000020
         BNE   GETMSTRE            BR AROUND IF NOT                     19200020
         L     R4,ADDRMAX          LOAD ADDR OF HIGH PRFX -1            19400020
         AH    R4,ONEA             ADD 1 TO IT FOR HIGH PREFIX ADDR     19600020
         ST    R4,0(R5)            STORE IT INTO PRFXA                  19800020
         OI    ADDRMAX+2,X'FF'     SET TO REAL MAX ADDR                 20000020
         LA    R5,PREFTMRA         POINT TO TIMER STATUS         A38898 20050020
*                                  INDICATOR IN PREFIX           A38898 20100020
         BRREAD  (R5)                                            A38898 20150020
         OC    0(4,PREG),0(PREG)   TEST STATUS FIELD FOR ZERO -  A38898 20160020
         BZ    GETMSTRF            MEANS TIMER ACTIVE            A38898 20170020
*                                  PREVIOUSLY SAVED TIMER OK     A38898 20180020
         LA    R5,TIMER(R4)        POINT TO TIMER IN HIGH PRF    A38898 20190020
         BRREAD  (R5)                                            A38898 20192020
         MVC   PTIMER(4),0(PREG)   RE-SAVE TIMER VALUE           A38898 20194020
         B     GETMSTRF            BR AROUND                            20200020
GETMSTRE XC    0(4,R5),0(R5)       ZERO PREFIX ADDR WORD                20400020
GETMSTRF L     R5,CVTHEAD          OBTAIN ADDR OF MASTER                20600020
         LA    R5,MOTHER(R5)       SCHEDULER TCB FROM                   20800020
*                                  MOTHER POINTER IN FIRST              21000020
         BRREAD  (R5)                                                   21200020
         L     R2,0(PREG)                                               21400020
         ST    R2,MSTRTCB          SAVE IT                              21600020
         LA    PREG,DAUGHTER(R2)   LOAD ADDR OF DAUGHTER PTR            21800020
         BRREAD  (PREG)                                                 22000020
         MVC   MSTRDTR(4),0(PREG)  SAVE MASTER SCHED DAUGHTER PTR       22200020
         L     PREG,SECCVTA        LOAD ADDR OF SEC CVT                 22400020
         LA    PREG,12(PREG)       ADDR OF TACT PTR                     22600020
         BRREAD  (PREG)                                                 22800020
         L     R2,0(PREG)          ADDR OF TACT                         23000020
         LA    PREG,6(R2)          ADDR OF NUMB OF ENTRIES       A35076 23200020
         BRREAD  (PREG)                                                 23400020
         LH    R4,0(PREG)          LOAD NUMB OF ENTRIES TO R4    A35076 23600020
         CH    R4,FIFTY            MORE THAN FIFTY TRANSIENT     A35076 23800020
*                                  AREAS IS SURELY AN ERROR      A35076 24000020
         BH    GMSTERR             BRANCH TO EXIT WITHOUT        A35076 24200020
*                                  SETTING GET MASTER SWITCH     A35076 24400020
         LTR   R4,R4               ERROR IN # OF T.A.'S?         A45382 24450021
         BNP   GMSTERR             YES, BRANCH TO EXIT           A45382 24500021
         L     R5,TRNSVCTB         LOAD TRANSIENT SVC TABLE ADDRESS     24600020
         LTR   R5,R5               IS THERE ALREADY ONE                 24800020
         BZ    GETMSTR8            BR IF NOT                            25000020
         LA    R1,0(R5)            LOAD ADDR TO R1 FOR FREEMAIN         25200020
         SR    R6,R6               ZERO IC REG                          25400020
         IC    R6,TRNSVCTB         GET LENGTH (IN DBL WORDS)            25600020
         SLL   R6,3                MULTIPLY BY 8 FOR BYTES              25800020
         LR    R0,R6               LENGTH TO R0 FOR FREEMAIN            26000020
         FREEMAIN R,LV=(0),A=(1)   FREE CORE OCCUPIED BY OLD TABLE      26200020
         XC    TRNSVCTB,TRNSVCTB   ZERO PTR                             26400020
GETMSTR8 LR    R0,R4               LOAD NUMB OF ENTRIES TO R0           26600020
         SLL   R0,3                MULTIPLY BY 8 FOR NUMBER OF BYTES    26800020
*                                  REQUIRED FOR TABLE                   27000020
         GETMAIN R,LV=(0)          GET CORE FOR TABLE                   27200020
         ST    R1,TRNSVCTB         STORE TABLE ADDRESS                  27400020
         STC   R4,TRNSVCTB         LENGTH IN DBL WORDS                  27600020
         LR    R5,R1               TABLE ADDR TO R5                     27800020
         LA    R2,20(R2)           ADDR OF FIRST TRANSIENT AREA         28000020
*                                  FETCH TCB                            28200020
GETMSTR7 BRREAD  (R2)                                                   28400020
         L     PREG,0(PREG)        LOAD TCB ADDR                        28600020
         BRREAD  (PREG)                                                 28800020
         L     PREG,0(PREG)        RB ADDR                              29000020
         LA    R6,96(PREG)         ADDR OF NAME                         29200020
         LA    R7,2                LOAD COUNT FOR NAME                  29400020
*                                  REG 6 CONTAINS ADDRESS OF NAME       29600020
GETMSTR6 BRREAD  (R6)                                                   29800020
         MVC   0(4,R5),0(PREG)     MOVE 4 BYTES OF NAME TO TABLE        30000020
         LA    R5,4(R5)            INCR                                 30200020
         LA    R6,4(R6)             REGS                                30400020
         BCT   R7,GETMSTR6         MOVE 8 BYTE NAME IN TWO PIECES       30600020
         LA    R2,16(R2)           ADDR OF NEXT TA FTCH TCB             30800020
         BCT   R4,GETMSTR7         LOOP FOR NUMB OF ENTRIES             31000020
         B     GETMSTR5            BR AROUND NEXT INST                  31200020
         SPACE                                                          31400020
GETMSTR4 EQU   *                                                        31600020
         XC    MSTRTCB,MSTRTCB     ZERO MASTER SCH TCB ADDR IF PCP/MFT  31800020
         LA    R5,PRFXA            LOAD ADDR OF MP65 PREFIX ADDR WORD   32000020
         XC    0(4,R5),0(R5)       ZERO THAT WORD TO INDICATE NONE      32200020
         TM    0(PREG),X'20'       TEST FOR MFT                         32400020
         BZ    GETMSTR5            BR IF PCP                            32600020
         OI    SWE,MFTSW           SET MFT SWITCH                       32800020
         LA    PREG,182(R2)        ADDR OF MFT ATTACH FLAG IN CVT       33000020
         BRREAD  (PREG)                                                 33200020
         TM    0(PREG),X'08'       IS ATTACH OPTION SUPPORTED           33400020
         BZ    GETMSTR5            NO--BR AROUND SETTING OF SW          33600020
         OI    SWE,MFTATCH         YES--SET MFT ATTACH SWITCH           33800020
         SPACE                                                          34000020
****  GET MODULE NAME AND MAYBE DATE & TIME FROM HEADER  ***            34200020
GETMSTR5 LA    PREG,X'800'         SET UP TO READ HEADER RECORD         34400021
         LNR   PREG,PREG           MINUS 2052 - ON BLOCK BACK FROM      34600020
*                                  ADDRESS ZERO BLOCK                   34800020
         BRREAD  (PREG)            READ HEADER                          35000020
         MVC   TITLEMOD+7(8),0(PREG)  STORE ISSUING MODULE NAME IN      35200021
*                                     TITLE                             35400020
         CLC   IMDSADMP(8),0(PREG)   IS THIS IMDSADMP HEADER            35600020
         BE    DATER               IF SO, DATE HAS BEEN STORED IN DATE  35800020
         MVC   DATE(4),12(PREG)    IF NOT, TAKE DATE FROM HEADER        36000020
         EJECT                                                          36200020
*********************************************************************** 36400020
*                                                                     * 36600020
*   THIS ROUTINE CONVERTS JULIAN DATE TO A REAL DATE AND PLACES IT IN * 36800020
*   THE TITLE                                                         * 37000020
*                                                                     * 37200020
*********************************************************************** 37400020
         SPACE                                                          37600020
DATER    EQU   *                                                        37800020
         TM    DATE+3,X'0F'        IS DATE VALID                        38000020
         BNO   GETMSTR1            BR IF NOT TO LEAVE DATE BLANK        38200020
         SR    R3,R3                CLEAR IC REG                        38400020
         IC    R3,DATE+1            GET YEAR                            38600020
         SLL   R3,4                 SHIFT LEFT 1 DIGIT,MAKE ROOM FOR    38800020
*                                   SIGN                                39000020
         LA    R2,15                LOAD SIGN TO R2                     39200020
         OR    R3,R2                OR SIGN INTO DECIMAL YEAR           39400020
         XC    WORK1(4),WORK1       ZERO FIRST WORD OF WORKAREA         39600020
         ST    R3,WORK1+4           STORE DEC YEAR INTO WORKAREA        39800020
         CVB   R3,WORK1             CONVERT YEAR TO BINARY              40000020
         LA    R2,3                  LOAD AND MASK  TO R2               40200020
         NR    R3,R2                 TEST FOR YEAR IN MULT OF FOUR      40400020
*                                    (IS IT A LEAP YEAR?)               40600020
         BZ    DATER1              BR IF IT IS                          40800020
         LA    R2,28               NUMBER OF DAYS IN FEB                41000020
         B     DATER2                                                   41200020
DATER1   LA    R2,29               NUMBER OF DAYS IN FEB IN LEAP YEAR   41400020
DATER2   STC   R2,MONTHMSK+10      STORE PROPER LENGTH FOR MONTH OF FEB 41600020
         XC    WORK1(8),WORK1      ZERO WORK AREA                       41800020
         MVC   WORK1+6(2),DATE+2   MOVE JULIAN DATE TO WORK1            42000020
         CVB   R4,WORK1            CONVERT TO BINARY                    42200020
         SR    R5,R5               CLEAR MONTH REG                      42400020
         LR    R6,R5               ZERO MONTH LENGTH REG                42600020
         LA    R3,12               LOAD LOOP COUNT                      42800020
         LA    R2,MONTHMSK-1       INITIALIZE BASE REG                  43000020
MONLOOP  AH    R5,ONEA             ADD ONE TO MONTH REG                 43200020
         IC    R6,0(R3,R2)         LOAD MONTH LENGTH                    43400020
         SR    R4,R6               SUBTRACT MONTH LENGTH FROM JULIAN    43600020
         BNP   MONADJ              BR IF EQ OR LT 0                     43800020
         BCT   R3,MONLOOP          LOOP                                 44000020
         SPACE                                                          44200020
MONADJ   AR    R4,R6               ADD MONTH LENGTH BACK                44400020
         CVD   R5,WORK1            CONVERT MONTH TO DECIMAL             44600020
         MVO   WORK1+1(4),WORK1+4(4) GET RID OF SIGN                    44800020
         IC    R6,WORK1+3          DECIMAL MONTH TO R6                  45000020
         SLL   R6,8                                                     45200020
         CVD   R4,WORK1            CONVERT DAY TO DECIMAL               45400020
         MVO   WORK1+1(4),WORK1+4(4) GET RID OF SIGN                    45600020
         IC    R6,WORK1+3          DECIMAL DAY TO R6                    45800020
         SLL   R6,8                                                     46000020
         IC    R6,DATE+1           YEAR TO R6                           46200020
         LA    R7,12               POSITIVE SIGN                        46400020
         SLL   R7,28               SHIFT TO HIGH ORDER DIGIT            46600020
         SLDL  R6,4                SIGN TO R6                           46800020
         ST    R6,WORK1            STORE PACKED DECIMAL DATE            47000020
         UNPK  EDWRK(6),WORK1(4)   MAKE DATE PRINTABLE                  47200020
         OI    EDWRK+5,X'F0'       SET ZONE IN SIGN SLOT                47400020
         MVC   DATEPTRN+6(2),EDWRK+4  MOVE YEAR TO PATTERN              47600020
         MVC   DATEPTRN+3(2),EDWRK+2  MOVE DAY TO PATTERN               47800020
         MVC   DATEPTRN(2),EDWRK   MOVE MONTH TO PATTERN                48000020
         MVC   TITLEDTE+5(8),DATEPTRN MOVE DATE TO TITLE                48200020
         EJECT                                                          48400020
*********************************************************************** 48600020
*                                                                     * 48800020
*   THIS ROUTINE DETERMINES TIME OF DAY FROM PSEUDO CLOCKS AND TIMER  * 49000020
*   CELL AND PLACES IT IN THE TITLE                                   * 49200020
*                                                                     * 49400020
*********************************************************************** 49600020
         SPACE                                                          49800020
GETMSTR1 CLC   IMDSADMP(8),0(PREG) TEST FOR STAND-ALONE DUMP            50000020
         BE    GETMSTTM            YES - BRANCH TO TIME ROUTINE         50200020
*                                  FOR SVC DUMP,                        50400020
         L     R3,8(PREG)          GET TIMER FIELD FROM HEADER          50600020
         LTR   R3,R3               TEST FOR TIME STORED                 50800020
         BZ    GETMSTTM            IF NOT, GO TRY TO GET TIME FROM      51000020
*                                  DUMP                                 51200020
***  FORMAT TIME FIELD FROM HEADER  ***                                 51400020
         OI    11(PREG),X'0F'      TURN ON FOR LAST ZONE                51600020
         UNPK  EDWRK(7),8(4,PREG)  MAKE TIME PRINTABLE            M1154 51800020
         MVC   TITLETME+5(2),EDWRK  MOVE HOURS TO TITLE                 52000020
         MVI   TITLETME+7,C'.'     TIME POINT                           52200020
         MVC   TITLETME+8(2),EDWRK+2  MOVE MINUTES TO TITLE             52400020
         MVI   TITLETME+10,C'.'    TIME POINT                           52600020
         MVC   TITLETME+11(2),EDWRK+4  MOVE SECONDS TO TITLE            52800020
         B     MASTDONE                                                 53000020
         SPACE                                                          53200020
GETMSTTM L     R3,PSHPC            GET SHPC ADDR FROM STORAGE           53400020
         LTR   R3,R3               TEST FOR TIMER PRESENT               53600020
         BZ    NOTIME                                                   53800020
         BM    TODCLOCK           BRANCH IF TOD CLOCK IS IND.     M2019 53850020
***  SHPC ADDRESS IN REG 3  ***                                         54000020
         BRREAD  (R3)                                                   54200020
         MVC   PSHPC(4),0(PREG)    SAVE SHPC                            54400020
         LA    PREG,4(R3)          ADDR OF 24 HR PC                     54600020
         BRREAD  (PREG)                                                 54800020
         MVC   PT4PC(4),0(PREG)    SAVE 24 HR PC                        55000020
         LA    PREG,8(R3)          ADDR OF LOCAL TIME PC                55200020
         BRREAD  (PREG)                                                 55400020
         MVC   PLTPC(4),0(PREG)    SAVE LOCAL TIME PC                   55600020
         L     R3,PSHPC            GET SHPC                             55800020
         AL    R3,PT4PC            ADD 24 HR PC                         56000020
         L     R4,PTIMER           LOAD TIMER VALUE                     56200020
         SRA   R4,1                DIVIDE BY 2                          56400020
         SLR   R3,R4               SHPC + T4PC -TIMER                   56600020
         CL    R3,TD24HRS          DOES RESULT EXCEED 24 HRS            56800020
         BL    TIME1               BR IF NOT                            57000020
         AL    R3,MODADJ           ADD MODULO ADJUSTMENT                57200020
TIME1    AL    R3,PLTPC            ADD LOCAL TIME PC                    57400020
         BC    3,TMEADJ            BR IF OVERFLOW                       57600020
         CL    R3,TD24HRS          CHECK FOR OVER 24 HRS                57800020
         BL    TMECNVT             BR IF NOT                            58000020
TMEADJ   AL    R3,MODADJ           ADD MODULO ADJUSTMENT                58200020
TMECNVT  LR    R7,R3                                                    58400020
         SRL   R7,1                CONVERT TO BINARY                    58600020
         M     R6,TD10E5                                                58800020
         D     R6,TDCNVR                                                59000020
         LR    R3,R7                                                    59200020
         LA    R1,32               INITIALIZE LOOP COUNT                59400020
         L     R5,TDIV             INITIALIZE REG                       59600020
TMELOOP  SR    R6,R6                                                    59800020
         DR    R6,R5               DEV DEC DIGITS AS REMAINDER          60000020
         LR    R8,R6                                                    60200020
         SRDL  R8,4                SHIFT DEC DIGITS INTO REG 9          60400020
         SH    R1,FOUR             DECR CNT BY 4                        60600020
          LTR  R7,R7               IS DIVIDEND REDUCED TO ZERO          60800020
         BZ    TMEDONE             BR IF IT IS                          61000020
         C     R1,TD24             IS COUNT EQ 24                       61200020
         BNL   TMELOOP             BR IF NOT                            61400020
         X     R5,TD12             ALTERNATE DIVISOR                    61600020
         B     TMELOOP                                                  61800020
         SPACE                                                          61810020
TODCLOCK MVC   TITLETME+5(8),TOD   MOVE TOD INDICATOR TO TITLE    M2019 61850020
         B     MASTDONE            GET MASTER COMPLETE            M2019 61900020
         SPACE                                                          62000020
NOTIME   MVC   TITLETME+5(8),TITLETME+4  BLANK TIME IN TITLE            62200020
         B     MASTDONE                                                 62400020
         SPACE                                                          62600020
TMEDONE  SRL   R9,0(R1)            SHIFT DEC DIGITS TO FINAL POS        62800020
         ST    R9,WORK1+4                                               63000020
         XC    WORK1(4),WORK1      ZERO WORK AREA                       63200020
         MVO   WORK1+1(3),WORK1+3(3) GET RID OF SIGN                    63400020
         OI    WORK1+3,X'0F'       MAKE SIGN PLUS                       63600020
         UNPK  EDWRK(6),WORK1+1(3) MAKE TIME VALUE PRINTABLE            63800020
         OI    EDWRK+5,X'F0'       MAKE LAST DIGIT PRINTABLE            64000020
         MVC   TITLETME+5(2),EDWRK+2  MOVE TIME TO TITLE                64200020
         MVI   TITLETME+7,C'.'     MOVE DOT TO TIME SPACE               64400020
         MVC   TITLETME+8(2),EDWRK+4                                    64600020
         SPACE                                                          64800020
MASTDONE OI    SWC,MSTRSW          SET MASTER SW                        65000020
****  BUILD TITLE (IF ANY) FROM HEADER RECORD  ***               S21016 65002021
GMSTERR  BRWRITE SKIP              SKIP TO TOP OF PAGE           S21016 65002421
         LA    PREG,X'800'         SET UP TO READ HEADER RECORD  S21016 65004021
         LNR   PREG,PREG           MINUS 2052 - ON BLOCK BACK    S21016 65006021
*                                  FROM ADDRESS ZERO BLOCK       S21016 65008021
         BRREAD  (PREG)            READ HEADER                   S21016 65008421
         CLC   0(8,PREG),IMDSADMP  TEST FOR IMDSADMP DUMP         M0862 65008521
         BE    MVCTTL              BYPASS TITLE SETUP BECAUSE     M0862 65008621
*                                  LENGTH REFLECTS REGS STORED   S21016 65008721
*                                  IN TITLE                      S21016 65018721
         LA    R2,100              SET UP MAXIMUM LL COUNT       S21016 65030021
         LH    R3,18(PREG)         OBTAIN LL FIELD FROM HEADER   S21016 65040021
         LTR   R3,R3               LL POSITIVE                   S21016 65050021
         BNP   MVCTTL              NO - WRITE NO TITLE MESSAGE   S21016 65060021
         CR    R2,R3               LL GREATER THAN MAXIMUM       S21016 65070021
         BH    MOVETTL             NO - USE LL FOR LENGTH        S21016 65080021
         LR    R3,R2               USE MAXIMUM LENGTH COUNT      S21016 65090021
MOVETTL  BCTR  R3,0                DECREMENT LENGTH BY 1         S21016 65100021
         L     R2,CURBUF           OBTAIN CURRENT BUFFER ADDRESS S21016 65110021
         EX    R3,MVCTL            MOVE USER DATA FROM HEADER    S21016 65120021
         MVC   1(17,R2),TTLFRDMP   MOVE HEADING TO BUFFER        S21016 65130021
WRTTTL   OI    PRSW,TTLSW          SET DUMP TITLE SWITCH         S21016 65140021
         BRWRITE 3                 WRITE DUMP TITLE              S21016 65150021
         B     GMSTRET             RETURN                        S21016 65160021
MVCTTL   L     R2,CURBUF           OBTAIN CURRENT BUFFER ADDRESS S21016 65170021
         MVC   1(21,R2),TTLFRDMP   MOVE NO TITLE MSG TO BUFFER   S21016 65180021
         B     WRTTTL              GO TO WRITE MESSAGE           S21016 65190021
GMSTRET  MVC   ERRADDR(4),MSTERSAV                                      65192021
         L     R13,MSTSAVE+4       POINT TO CALLER'S SAVE AREA   S21016 65200021
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGISTERS           65400020
         BR    RETREG              RETURN TO CALLER                     65600020
         EJECT                                                          65800020
**************************************************************** A43168 66000021
*                                                                A43168 66010021
*                  GET MASTER ERROR ROUTINE                      A43168 66012021
*                                                                A43168 66012421
*  RETURN TO IMDPRRDC WITHOUT SETTING MASTER SWITCH.  ERRORS     A43168 66014021
*  BE MUST CAUGHT BY IMDPRMST SO THAT THIS MODULE CAN BE DELETED A43168 66016021
*  BY IMDPRRDC.                                                  A43168 66018021
*                                                                A43168 66020021
**************************************************************** A43168 66050021
         SPACE                                                          66052021
         USING *,R15               TEMPORARILY BASE ON REG 15    A43168 66054021
MSTERR   LA    R13,MSTSAVE         POINT TO MST-S SAVE AREA      A43168 66056021
         LM    R14,R12,12(R13)     RELOAD MST-S REGISTERS        A43168 66058021
         DROP  R15                                               A43168 66058121
         USING MSTBASE,BASE1       SHIFT BACK TO REG 11 AS BASE  A43168 66058221
         SPACE                                                          66058421
         TM    PGCVTSW,BADCVT      CVT ERROR TO BE IGNORED       A46340 66058521
         BO    GETMSTRL            BEGIN SEARCH FOR CVT          A46340 66058621
         B     GMSTRET             BRANCH TO EXIT WITHOUT        A43168 66058821
*                                  SETTING MASTER SWITCH         A43168 66059221
         EJECT                                                          66060021
*********************************************************************** 66100021
*                                                                     * 66200020
*   SAVE AREA AND CONSTANTS FOR GETMSTR ROUTINE                       * 66400020
*                                                                     * 66600020
*********************************************************************** 66800020
         SPACE                                                          67000020
MSTSAVE  DC    18F'0'              IMDPRMST SAVE AREA                   67200020
MSTERSAV DC    F'0'                SAVE AREA FOR CALLER-S ERROR  A43168 67250021
*                                  ROUTINE ADDRESS               A43168 67300021
TD24HRS  DC    X'C5C43D7E'                                              67400020
MODADJ   DC    X'3A3BC282'                                              67600020
TD10E5   DC    F'200000'                                                67800020
TDCNVR   DC    X'0249F999'                                              68000020
TDIV     DC    F'10'                                                    68200020
TD12     DC    F'12'                                                    68400020
TD24     DC    F'24'                                                    68600020
PTIMER   DC    F'0'                                                     68800020
PSHPC    DC    F'0'                                                     69000020
PT4PC    DC    F'0'                                                     69200020
PLTPC    DC    F'0'                                                     69400020
DATE     DC    F'0'                                                     69600020
MNUCTOP  DC    F'250000'           DEFAULT NUCTOP               SA58793 69650000
IMDSADMP DC    CL8'IMDSADMP'                                            69800020
GETERSV  DC    F'0'                                                     70000020
EDWRK    DC    CL12' '                                                  70200020
MONTHMSK DC    X'1F1E1F1E1F1F1E1F1E1F1C1F'                              70400020
DATEPTRN DC    C'  /  /  '         DATE FORMAT                          70600020
CVTCHK   DC    X'0A0307FE'         SVC 3 AND BCR 15,14 IN CVT           70800020
TOD      DC    CL8'TOD CLK'                                       M2019 70850020
TTLFRDMP DC    C'TITLE FROM DUMP: '                              S21016 70860021
NOTTL    DC    C'NONE'                                           S21016 70870021
PGCVTSW  DC    X'00'               CVT ERROR SWITCH              A46340 70880021
MVCTL    MVC   18(0,R2),20(PREG)   MOVE USER DATA TO TITLE       S21016 70900021
         SPACE                                                          71000020
         END                                                            71200020
