IMDPRNUC START                                                          01000020
         TITLE 'IMDPRNUC - EXECUTOR WHICH PRINTS NUCLEUS AND SQA'       01000121
*********************************************************************** 01000221
*                                                                     * 01000421
*         ***     IMDPRNUC - PRINT NUCLEUS EXECUTOR      ***          * 01000621
*                                                                     * 01000821
* STATUS --  OS/360 RELEASE 21.0                                      * 01000921
*                                                                     * 01001221
* FUNCTION --                                                         * 01001421
*                                                                     * 01001621
*         THIS MODULE PRINTS THE NUCLEUSAND SQA,AND THE MP65 HIGH     * 01001721
*    PREFIX AREA OF THE DUMPED SYSTEM.  IF THE INITIALIZATION ROUTINE * 01001821
*    IMDPRMST HAS WORKED, THE ACTUAL TOP ADDRESS OF THE NUCLEUS AND   * 01002121
*    SQA IS OBTAINED.  IF THE ROUTINE FAILED, A DEFAULT ADDRESS IS    * 01002321
*    SUBSTITUTED FOR THE TOP OF THE NUCLEUS AND SQA AREA.  IF IT IS   * 01002421
*    AN MP65 SYSTEM, THE HIGH PREFIX ADDRESS IS OBTAINED AND THE      * 01002521
*    MAXIMUM ADDRESS OF THE SYSTEM IS ALSO OBTAINED.                  * 01002621
*         THE PRINT CONTROL BLOCK (PCB) CSECT, OF THE IMDPRDPS        * 01002721
*    SERVICE MODULE, IS USED TO ENQUEUE THE LOW AND HIGH ADDRESS OF   * 01003221
*    THE NUCLEUS AND SQA, AND THE LOW AND HIGH ADDRESS OF THE MP65    * 01003421
*    SYSTEM, IF PRESENT,ON THE PCB QUEUE FOR LATER PROCESSING BY THE  * 01003621
*    MODULE IMDPRDPS.                                                 * 01003721
*         IMDPRNUC ALSO SERVICES THE REQUEST OF IMDPRCTL TO PRINT THE * 01003821
*    NUCLEUS AND SQA, AND MP65 HIGH PREFIX AREA, IF PRESENT, WHEN     * 01004021
*    'ERRSW' IS ON IN IMDPRCOM.  IN THIS CASE PCBS ARE CREATED IN THE * 01004121
*    SAME MANNER DESCRIBED FOR NORMAL ENTRY TO IMDPRNUC.  IF THE      * 01004321
*    FLUSHMODE SWITCH IN IMDPRCOM IS ON THE INPUT STREAM IS CHECKED   * 01004421
*    FOR SYNTAX ERRORS ONLY.                                          * 01004621
*                                                                     * 01005021
* ENTRY POINTS --                                                     * 01005221
*                                                                     * 01005321
*         IMDPRNUC IS THE MAIN AND ONLY ENTRY POINT.  THIS MODULE     * 01005421
*    RECEIVES CONTROL WHEN THE 'NUCLEUS' PARAMETER OF THE PRINT       * 01005621
*    CONTROL STATEMENT IS ENCOUNTERED.  ALSO WHEN AN ERROR HAS OCCURR-* 01005721
*    ED IN THE DUMP INITIALIZATION AND THE ERROR CODE IS '0'.         * 01005921
*                                                                     * 01006021
* INPUT --                                                            * 01006221
*                                                                     * 01006321
*         THE COMMON CSECT, IMDPRCOM, WHICH CONTAINS VALUES OF        * 01006521
*    SWITCHES, CONSTANTS, AND ADDRESSES.  SPECIFICALLY, THE ADDRESS OF* 01006721
*    THE TOP OF THE NUCLEUS AND SQA AREA (NUCTOP), THE MP65 HIGH      * 01007121
*    PREFIX ADDRESS (PRFXA), AND THE MAXIMUM ADDRESS OF MAIN STORAGE  * 01007421
*    (ADDRMAX).                                                       * 01007621
*                                                                     * 01007721
* OUTPUT --                                                           * 01007921
*                                                                     * 01008121
*         THE NUCLEUS AND SQA, AND THE MP65 HIGH PREFIX AREA (IF ONE  * 01008421
*    EXISTS).                                                         * 01008721
*                                                                     * 01009321
* EXTERNAL REFERENCES --                                              * 01009521
*                                                                     * 01009721
*         1.  IMDPRPCB - TO ENQUEUE THE REQUESTED STORAGE LOCATIONS   * 01009921
*             ON THE PRINT CONTROL BLOCK QUEUE.                       * 01010121
*         2.  IMDPRDPS - TO FORMAT AND PRINT AREAS OF MAIN STORAGE    * 01010321
*             THAT ARE ENQUEUED ON THE PRINT CONTROL BLOCK QUEUE.     * 01010521
*         3.  BRWRITE - TO PRINT THE ABSOLUTE STORAGE TITLE ON THE    * 01010721
*             PRINTER DATA SET.                                       * 01010821
*                                                                     * 01010921
* EXITS, NORMAL --                                                    * 01011021
*                                                                     * 01011121
*         IMDPRNUC RETURNS TO IMDPRCTL.                               * 01011221
*                                                                     * 01011321
* EXITS, ERROR --                                                     * 01011421
*                                                                     * 01011521
*         NONE                                                        * 01011621
*                                                                     * 01011721
* TABLES/WORK AREAS --                                                * 01011821
*                                                                     * 01011921
*         THE COMMON CSECT, IMDPRCOM, WHICH CONTAINS THE ADDRESS OF   * 01012921
*    THE TOP OF THE NUCLEUS AND SQA, THE ADDRESS OF THE TOP OF MAIN   * 01013121
*    STORAGE, AND THE MP65 HIGH PREFIX AREA (IF ONE EXISTS).          * 01013321
*                                                                     * 01013521
* ATTRIBUTES --  REUSEABLE                                            * 01013621
*                                                                     * 01014921
* CHARACTER CODE DEPENDENCY --  EBCDIC                                * 01015021
*                                                                     * 01016021
* NOTES --  NONE                                                      * 01016121
*                                                                     * 01016221
*********************************************************************** 01016421
        EJECT                                                           01016621
*/*IMDPRNUC: CHART (AMODE,SEQ) */                                       01017121
*/*HEADER                                                               01017221
*/*IMDPRNUC  -  PRINTS RESIDENT AND PAGEABLE NUCLEUS AND SQA            01017321
*/*                                                    PAGE # */        01017421
*/*IMDPRNUC: E START */                                                 01017521
*/*  M ENTRY LINKAGE AND HOUSEKEEPING */                                01017621
*/*  D (YES,NUCLEUS,NO,) IS ERROR RTN SERVICE SW ON? */                 01017721
*/*  D (YES,NUCDONE,NO,) IS THIS FLUSH MODE? */                         01017821
*/*NUCLEUS: M TURN PRINT SWITCH ON */                                   01017921
*/*  P STORE ZERO AS STARTING ADDRESS IN PCB ENQUEUE P-LIST */          01018021
*/*  D (YES,NUCA,NO,) HAS THE MST ROUTINE WORKED? */                    01018121
*/*  P SET 'NO PREFEX AD' BYTE */                                       01018221
*/*  P (,NUCB) GET APPROXIMATE TOP OF NUCLEUS */                        01018321
*/*NUCA: P GET ADDRESS OF THE NUCLEUS */                                01018421
*/*NUCB: P STORE NUCLEUS ADDRESS FOR PCB ENQUEUE */                     01018521
*/*  P GET ADDRESS OF PCB ENQUEUE P-LIST */                             01018621
*/*  P GET ADDRESS OF PCB ENQUEUE ROUTINE */                            01018721
*/*  L IMDPRPCB     - ENQUEUE NUC AND INITIAL SQA ADDRESSES*/           01018821
*/*  P GET MP65 HIGH PREFIX ADDRESS */                                  01018921
*/*  D (YES,,NO,NUC1) IS THERE ONLY ONE MP65 SYSTEM? */                 01019021
*/*  P STORE HIGH PREFIX ADDRESS FOR PCB ENQUEUE ROUTINE */             01019121
*/*  P GET TOP-OF-BOX ADDRESS */                                        01019221
*/*  P STORE TOP-OF-BOX ADDRESS AS HIGH MARK FOR PRINTING */            01019321
*/*  P GET ADDRESS OF PCB ENQUEUE ROUTINE */                            01019421
*/*  L IMDPRPCB */                                                      01019521
*/*NUC1: L BRWRITE     -  SKIP TO TOP OF THE PAGE */                    01019621
*/*  P GET ADDRESS OF CURRENT OUTPUT BUFFER */                          01019721
*/*  P MOVE NUCLEUS TITLE TO BUFFER */                                  01019821
*/*  L BRWRITE  -  PRINT TITLE */                                       01019921
*/*  P GET ADDRESS OF PRINT STORAGE SERVICE ROUTINE */                  01020021
*/*  N PRINT THE NUC, SQA, AND MAYBE HIGH PREFIX */                     01020121
*/*  L IMDPRSTG */                                                      01020221
*/*NUCDONE: M RESET PRINT SWITCH */                                     01020321
*/*  M EXIT LINKAGE */                                                  01020421
*/*  R RETURN TO CALLER */                                              01020521
*/*IMDPRNUC:  END */                                                    01020621
      EJECT                                                             12000021
         EQUATES                                                        13000020
         COMMON                                                         14000020
*                                                                 M3179 14050020
         OUTBUFM                                                        15000020
IMDPRNUC CSECT                                                          16000020
         STM   R14,R12,12(R13)     SAVE CALLER'S REGISTERS              17000020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             18000020
         USING *,BASE1                                                  19000020
         LA    R2,NUCSAVE          SAVE AREA CHAINING                   20000020
         ST    R13,NUCSAVE+4                                            21000020
         ST    R2,8(R13)                                                22000020
         LR    R13,R2              ENTRY COMPLETE                       23000020
         SPACE                                                          24000020
         USING COMMON,COMBASE      BASE COMMON CSECT                    25000020
         USING OUTBUF,BUFREG                                            26000020
         SPACE                                                          27000020
         TM    PRSW,ERRSW          TEST FOR ERROR ROUTINE SERVICE       28000020
         BO    NUCLEUS             BRANCH AROUND FLUSH MODE             29000020
         TM    SWD,FLSHMODE        IS THIS FLUSH MODE                   30000020
         BO    NUCDONE             EXIT IF SO                           31000020
NUCLEUS  OI    SWA,PRNTSW          SET PRINT SWITCH                     32000020
         SR    R3,R3               STARTING AND ENDING                  33000020
         ST    R3,LOW              STORE IN PCB ENQUEUE P-LIST          34000020
         TM    SWC,MSTRSW          HAS GET MASTER ROUTINE WORKED        35000020
         BO    NUCA                BRANCH IF SO TO GET TOP NUC AD       36000020
*                                  FROM COMMON CSECT                    37000020
         XC    PRFXA(4),PRFXA      WARN OF NO PREFIX AD                 38000020
         L     R4,FAKETOP          APPROXIMATE TOP OF NUC               39000020
         B     NUCB                BRANCH TO ENQUE PCB                  40000020
NUCA     L     R4,NUCTOP           ADDRESS OF NUCLEUS                   41000020
NUCB     ST    R4,HIGH             STORE FOR PCB ENQUEUE                42000020
         LA    PREG,PCBLIST        POINT TO PCB ENQUEUE P-LIST          43000020
         L     R15,APCBENQ         LOAD ADDR OF PCB ENQ ROUTINE         44000020
         BALR  RETREG,R15          ENQUEUE TO BE PRINTED                45000020
         L     R3,PRFXA            LOAD MP65 HIGH PRFX ADDR             46000020
         LTR   R3,R3               IS THERE ONE (MP65 SYSTEM ONLY)      47000020
         BZ    NUC1                NO--CONTINUE                         48000020
         ST    R3,LOW              STORE FOR PCB ENQUEUE                49000020
         L     R4,ADDRMAX          LOAD TOP ADDR OF HIGH PRFX           50000020
         ST    R4,HIGH             STORE ADDRMAX FOR PCB ENQUEUE        51000020
         L     R15,APCBENQ         LOAD ADDR OF PCB ENQUEUE ROUT        52000020
         BALR  RETREG,R15          TO PRINT HIGH PRFX AS PART OF NUC    53000020
NUC1     BRWRITE  SKIP                                                  54000020
         L     BUFREG,CURBUF       GET CURRENT OUTPUT BUFFER ADDRESS    55000020
         MVC   ADDR+30(L'NUCTITLE),NUCTITLE                             56000020
*                                  MOVE NUC TITLE TO BUFFER             57000020
         BRWRITE  2                PRINT TITLE                          58000020
         L     R15,APRTSTG         GET ADDRESS OF PRINT STORAGE         59000020
*                                  SERVICE ROUTINE - DPS                60000020
         BALR  RETREG,R15          LINK TO DPS TO PRINT NUC, SQA AND    61000020
*                                  MAYBE HIGH PREFIX                    62000020
NUCDONE  NI    SWA,255-PRNTSW      RESET PRINT SWITCH                   63000020
         L     R13,4(R13)          POINT TO CALLER'S SAVE AREA          64000020
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGISTERS           65000020
         BR    RETREG              RETURN                               66000020
         EJECT                                                          67000020
*********************************************************************** 68000020
*                                                                     * 69000020
*  CONSTANTS USE BY IMDPRNUC                                          * 70000020
*                                                                     * 71000020
*********************************************************************** 72000020
         SPACE                                                          73000020
NUCSAVE  DC    18F'0'              NUC'S REGISTER SAVE AREA             74000020
PCBLIST  DS    0F                  P-LIST FOR PCB ENQUEUE               75000020
LOW      DS    F                   LOW ADDRESS TO BE PRINTED            76000020
HIGH     DS    F                   HIGH ADDRESS TO BE PRINTED           77000020
TJID     DC    H'0'                TJID OF STORAGE TO BE PRINTED  M2029 78000020
*                                  ALWAYS ZERO FOR NUC                  79000020
FAKETOP  DC    F'250000'           APPROX. NUC TOP                      80000020
NUCTITLE DC    C'* * * *  N U C L E U S  A N D  S Q A  P R I N T  * * *X81000020
                *'                                                      82000020
         SPACE                                                          83000020
         END                                                            84000020
