IMDPRPAL START                                                          01000020
         TITLE 'IMDPRPAL - PRINT ALL EXECUTOR'                          02000020
*********************************************************************** 03000020
*                                                                     * 04000020
**              ***  IMDPRPAL - ALL OPREAND ROUTINE   ***            ** 05000021
*                                                                     * 06000020
* STATUS --  OS/360 RELEASE 21.6                                      * 06050000
*                                                                     * 06100021
* C 230000                                                       A42707 06150021
* A 320500-330000,710500,74100-749500,820500                     A42707 06200021
* C 580000,743020,749500                                         A53323 06250000
* D 743040,747500,748000                                         A53323 06300000
* A 743004,749600,749700,749800,880500                           A53323 06350000
*                                                                     * 07000020
* FUNCTION --                                                         * 07050021
*         THIS MODULE PRINTS THE NUCLEUS AND SQA, THE MP65 HIGH PREFIX* 07100021
*    AREA, ALL ALLOCATED REGIONS, AND THE GENERAL PURPOSE REGISTERS OF* 07150021
*    THE DUMPED SYSTEM.  THE ADDRESS OF THE TOP OF THE NUCLEUS AND SQA* 07200021
*    IS OBTAINED, AS WELL AS THE MP65 HIGH PREFIX ADDRESS (IF ONE IS  * 07250021
*    PRESENT), AND THE MAXIMUM ADDRESS OF THE SYSTEM.                 * 07300021
*         THE PRINT CONTROL BLOCK (PCB) CSECT OF THE IMDPRDPS SERVICE * 07350021
*    MODULE IS USED TO ENQUEUE A LOW ADDRESS OF '0' AND THE HIGH      * 07400021
*    ADDRESS OF THE NUCLEUS AND SQA, AND THE LOW AND HIGH ADDRESS OF  * 07450021
*    THE MP65 HIGH PREFIX AREA, IF PRESENT, ON THE PCB QUEUE FOR LATER* 07500021
*    PROCESSING BY THE MODULE IMDPRDPS.                               * 07550021
*         THE ALL REGIONS ROUTINE, IMDPRFUR, IS USED TO ENQUEUE THE   * 07600021
*    TCB'S OF ALL ALLOCATED REGIONS ON THE 'TCBLIST' FOR LATER        * 07650021
*    PROCESSING BY THE MODULE IMDPRFUB.                               * 07700021
*         THE REGION BOUNDARY ROUTINE, IMDPRFUB, IS USED TO DETERMINE * 07750021
*    THE REGION BOUNDARIES OF THE TCBS ON THE 'TCBLIST'.  IMDPRFUB,   * 07800021
*    THEN USES THE PCB CSECT TO ENQUEUE THESE BOUNDARIES ON THE PCB   * 07850021
*    QUEUE FOR LATER PROCESSING BY IMDPRDPS.                          * 07900021
*                                                                     * 07950021
* ENTRY POINTS --                                                     * 08000021
*                                                                     * 08050021
*         IMDPRPAL IS THE MAIN AND ONLY ENTRY POINT.  THIS MODULE     * 08100021
*    RECEIVES CONTROL WHEN THE 'ALL' PARAMETER OF THE PRINT CONTROL   * 08150021
*    STATEMENT IS ENCOUNTERED.                                        * 08200021
*                                                                     * 08250021
* INPUT --                                                            * 08300021
*                                                                     * 08350021
*         THE COMMON CSECT, IMDPRCOM, WHICH CONTAINS VALUES OF        * 08400021
*    SWITCHES, CONSTANTS, AND ADDRESSES.  SPECIFICALLY, THE ADDRESS OF* 08450021
*    THE TOP OF THE NUCLEUS AND SQA (NUCTOP), THE MP65 HIGH PREFIX    * 08500021
*    ADDRESS (PRFXA), AND THE MAXIMUM ADDRESS OF MAIN STORAGE(ADDRMAX)* 08550021
*                                                                     * 08600021
*OUTPUT --                                                            * 08650021
*                                                                     * 08700021
*         THE NUCLEUS AND SQA, MP65 HIGH PREFIX AREA, IF PRESENT, THE * 08750021
*    STORAGE ASSOCIATED WITH EACH TCB ON THE PCB LIST, AND THE GENERAL* 08800021
*    PURPOSE REGISTERS.                                               * 08850021
*                                                                     * 08900021
* EXTERNAL REFERENCES --                                              * 08950021
*                                                                     * 09000021
*         1.  IMDPRPCB - TO ENQUEUE THE REQUESTED STORAGE LOCATIONS ON* 09050021
*             THE PCB QUEUE.                                          * 09100021
*         2.  IMDPRDPS - TO FORMAT AND PRINT AREAS OF MAIN STORAGE    * 09150021
*             THAT ARE ENQUEUED ON THE PCB QUEUE.                     * 09200021
*         3.  IMDPRFUR - TO ENQUEUE THE TCB'S OF ALL ALLOCATED REGIONS* 09250021
*             ON THE TCB LIST.                                        * 09300021
*         4.  IMDPRFUB - TO DETERMINE THE REGION BOUNDARIES ON THE    * 09350021
*             TCBS ON THE TCB LIST.                                   * 09400021
*         5.  BRWRITE - TO PRINT ALLOCATED STORAGE TITLE ON THE       * 09450021
*             PRINTER DATA SET.                                       * 09500021
*                                                                     * 09550021
* EXITS, NORMAL --                                                    * 09600021
*                                                                     * 09650021
*         IMDPRPAL RETURNS TO IMDPRCTL                                * 09700021
*                                                                     * 09750021
* EXITS, ERROR --                                                     * 09800021
*                                                                     * 09850021
*         NONE                                                        * 09900021
*                                                                     * 09950021
* TABLES/WORK AREAS --                                                * 10000021
*                                                                     * 10050021
*         THE COMMON CSECT, IMDPRCOM, WHICH CONTAINS THE ADDRESS OF   * 10100021
*    TOP OF THE NUCLEUS AND SQA, THE MP65 HIGH PREFIX AREA, IF ONE    * 10150021
*    EXISTS, AND THE MAXIMUM ADDRESS OF MAIN STORAGE.                 * 10200021
*                                                                     * 10250021
* ATTRIBUTES --  REUSEABLE                                            * 10300021
*                                                                     * 10350021
* CHARACTER CODE DEPENDENCY --  EBCDIC                                * 10400021
*                                                                     * 10450021
* NOTES --                                                            * 10500021
*                                                                     * 10550021
*         AN ERROR ROUTINE, RESIDENT IN IMDPRPAL, IS USED TO PURGE    * 10600021
*    TIOT LIST ELEMENTS SHOULD THE SEARCH FOR STORAGE ALLOCATED TO ALL* 10650021
*    PARTITIONS TERMINATE UNSUCCESSFULLY.                             * 10700021
*                                                                     * 10750021
*********************************************************************** 10800021
         EJECT                                                          14010021
*/*IMDPRPAL: CHART     (AMODE,SEQ) */                                   14050021
*/*HEADER                                                               14100021
*/*IMDPRPAL  -  PRINT ALL EXECUTOR                                      14150021
*/*                                                     PAGE #   */     14200021
*/*IMDPRPAL: E START */                                                 14250021
*/*  M ENTRY LINKAGE */                                                 14300021
*/*  D (YES,PALDONE,NO,) IS THIS FLUSH MODE? */                         14350021
*/*  P SAVE CALLER'S ERROR ROUTINE */                                   14400021
*/*  M RESET PRINT SWITCH */                                            14450021
*/*  P STORE ZERO AS STARTING ADDRESS TO BE ENQUEUED FOR PRINTING */    14500021
*/*  P GET TOP ADDRESS OF NUCLEUS */                                    14550021
*/*  P STORE TOP ADDRESS AS HIGH ADDRESS IN FIRST PCB */                14600021
*/*  P GET ADDRESS OF PCB ENQUEUE ROUTINE */                            14650021
*/*  S IMDPRPCB: ENQUE PCB */                                           14700000
*/*  P GET MP65 HIGH PREFIX ADDRESS */                                  14750021
*/*  N FOR MP65 ONLY */                                                 14800021
*/*  D (YES,,NO,ALLRGNS) IS THERE A HIGH PRFX ADDR? */                  14850021
*/*  P STORE HIGH PREFIX ADDRESS FOR PCB ENQUEUE ROUTINE */             14900021
*/*  P GET TOP-OF-BOX ADDRESS AND STORE IT */                           14950000
*/*  P STORE TOP ADDRESS AS HIGH MARK FOR PRINTING */                   14960021
*/*  GET ADDRESS OF PCB ENQUEUE ROUTINE */                              14970021
*/*  S IMDPRPCB: ENQUE PCB */                                           14982000
*/*ALLRGNS: L BRWRITE    -  SKIP A PAGE */                              14990021
*/*  P GET ADDRESS OF CURREN OUTPUT BUFFER */                           14992021
*/*  P MOVE PAL TITLE TO BUFFER */                                      14994021
*/*  L BRWRITE  - PRINT TITLE */                                        14996021
*/*  P GET ADDRESS OF ALL REGIONS ROUTINE */                            14998021
*/*  S IMDPRFUR: ENQ ALL TCB'S */                                       14998400
*/*BNDCONT: P GET ADDRESS OF REGION BOUNDARY ROUTINE */                 14998800
*/*  S IMDPRFUB: REGION BOUNDARY ROUTINE */                             14999200
*/*  L BRWRITE   - SKIP SPACES IN CASE OF ERROR MESSAGE */              14999621
*/*  P GET ADDRESS OF TCB DEQUEUE ROUTINE */                            14999700
*/*  P INDICATE PURGE */                                                14999821
*/*  S IMDPRTSV: DEQUE TCB'S */                                         14999900
*/*  M SET GENERAL PURPOSE REG SWITCH FOR IMDPRDPS */                   15049921
*/*  P GET ADDRESS OF PRINT STORAGE SERVICE ROUTINE */                  15059921
*/*  S IMDPRSTG: GO PRINT STORAGE DEFINED IN PCB'S */                   15069900
*/*PALDONE: P RESTORE ERROR ROUTINE ADDRESS */                          15079900
*/*  M EXIT LINKAGE */                                                  15089921
*/*  R RETURN TO CALLER */                                              15091921
*/*PALERR: P TEMPORARILY USE REG 15 AS BASE REGISTER */                 15097900
*/* COMMENT ERROR IN TCB CHAIN - PRINT MESSAGE - BRANCH TO BNDCONT */   15098000
*/*  P GET ADDRESS OF PAL'S SAVE AREA */                                15098321
*/*  P RELODE PAL'S REGISTERS */                                        15098700
*/*  P SHIFT BACK TO REG 11 AS BASE REGISTER */                         15099121
*/*  P GET CALLER'S ERROR ROUTINE ADDRESS */                            15099721
*/*  P RESTORE ERROR ROUTINE ADDRESS IN COMMON */                       15099821
*/*  L BRWRITE: SPACE 1 LINE  */                                        15109800
*/*  P MOVE ERROR MSG TO OUTPUT BUFFER */                               15119800
*/*  L BRWRITE: WRITE ERROR IN TCB CHAIN */                             15129800
*/*  P (,BNDCONT) BRANCH BACK TO BNDCONT */                             15139800
*/*IMDPRPAL:  END */                                                    15159821
         EJECT                                                          15199821
         EQUATES                                                        16000020
         COMMON                                                         17000020
*                                                                 M3179 17050020
         OUTBUFM                                                        18000020
IMDPRPAL CSECT                                                          19000020
         STM   R14,R12,12(R13)     SAVE CALLER'S REGISTERS              20000020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             21000020
         USING *,BASE1                                                  22000020
PALBASE  LA    R2,PALSAVE          SAVE AREA CHAINING            A42707 23000021
         ST    R13,PALSAVE+4                                            24000020
         ST    R2,8(R13)                                                25000020
         LR    R13,R2              ENTRY COMPLETE                       26000020
         SPACE                                                          27000020
         USING OUTBUF,BUFREG                                            28000020
         USING COMMON,COMBASE      BASE COMMON CSECT                    29000020
         SPACE                                                          30000020
         TM    SWD,FLSHMODE        IS THIS FLUSH MODE                   31000020
         BO    PALDONE             EXIT IF SO                           32000020
         MVC   PALERSAV(4),ERRADDR SAVE CALLER-S ERROR RTN. AD   A42707 32050021
         LA    R3,PALERR           POINT TO PAL-S ERROR          A42707 32100021
*                                  HANDLER                       A42707 32110021
         ST    R3,ERRADDR          STORE AS CURRENT ERROR RTN.   A42707 32150021
         NI    SWA,255-PRNTSW      RESET PRINT SWITCH            A42707 33000021
         SR    R3,R3               CLEAR R3 FOR ADDR 0                  34000020
         ST    R3,LOW              STORE AS LOW ADDRESS TO BE ENQUEUED  35000020
*                                  FOR PRINTING                         36000020
         L     R4,NUCTOP           LOAD TOP ADDR OF NUCLEUS             37000020
         ST    R4,HIGH             STORE AS HIGH ADDRESS IN FIRST PCB   38000020
         LA    PREG,PCBLIST        POINT TO PCB ENQUEUE P-LIST          39000020
         L     R15,APCBENQ         LOAD ADDR OF PCB ENQUEUE             40000021
         BALR  RETREG,R15          ENQUEUE NUCLEUS TO BE PRINTED        41000020
         L     R3,PRFXA            LOAD MP65'S HIGH PREFIX ADDR         42000020
         LTR   R3,R3               TEST FOR HIGH PRFX ADDR (MP65 ONLY)  43000020
         BZ    ALLRGNS             BR IF NONE TO FIND BOUNDRIES OF ALL  44000020
         ST    R3,LOW              ENQUEUE HIGH PREFIX FOR PRINTING     45000020
         L     R4,ADDRMAX          LOAD TOP OF BOX POINTER              46000020
         ST    R4,HIGH             STORE AS HIGH MARK FOR PRINTING      47000020
         L     R15,APCBENQ         PCB EQUEUE ROUTINE ADDR              48000020
         BALR  RETREG,R15          ADD HIGH PREFIX ADDR TO PRINT QUEUE  49000020
         SPACE                                                          50000020
ALLRGNS  BRWRITE  SKIP                                                  51000020
         L     BUFREG,CURBUF       POINT TO OUTPUT BUFFER               52000020
         MVC   ADDR+33(L'PALTITLE),PALTITLE  MOVE IN PAL TITLE    M5039 53000020
         BRWRITE  1                                                     54000020
         L     R15,AALLRGN         POINT TO ALL REGIONS ROUTINE         55000020
         BALR  RETREG,R15          LINK TO ALL RGN'S TO ENQUEUE TCB'S   56000020
*                                  OF ALL REGIONS                       57000020
BNDCONT  L     R15,ARGNBND         POINT TO REGION BOUNDARY ROUTINE     58000000
         BALR  RETREG,R15          LINK TO REGION BDY TO ENQUEUE ALL    59000020
*                                  ALLOCATED REGIONS FOR PRINTING       60000020
         BRWRITE  1                SPACE IN CASE OF ERROR MESSAGE       61000020
*                                  FROM SERVICE ROUTINES                62000020
         L     R15,ATCBREMV        POINT TO TCB DEQUEUE RTN.            62050021
         SR    R2,R2               INDICATE PURGE                       62100021
         BALR  RETREG,R15                                               62150021
         OI    SWD,GPRSFND         ASK DPS FOR REGS                     63000020
         L     R15,APRTSTG         POINT TO PRINT STORAGE SERVICE RTN.  64000020
         BALR  RETREG,R15          LINK TO IT                           65000020
         SPACE                                                          71000020
PALDONE  MVC   ERRADDR(4),PALERSAV RESTORE ERROR ROUTINE ADDR    A42707 71050021
         L     R13,4(R13)          GET ADDRESS OF CALLER'S SAVE AREA    72000021
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGISTER            73000020
         BR    RETREG              RETURN                               74000020
         SPACE                                                          74050021
         DROP  BASE1                                             A42707 74100021
         EJECT                                                          74150021
**************************************************************** A42707 74200021
*                                                                A42707 74250021
*                   IMDPRPAL ERROR HANDLER                       A42707 74260021
*                                                                A42707 74300021
* IF TCB CHAIN ERROR, PRINT COMMENT AND GO ON TO                 A53323 74300400
* BOUNDARY ROUTINE TO PRINT WHAT PARTITIONS WE HAVE              A53323 74302000
*                                                                A42707 74310021
**************************************************************** A42707 74350021
         SPACE                                                          74400021
         USING *,R15               TEMPORARILY USE R15 AS BASE   A42707 74450021
PALERR   LA    R13,PALSAVE         POINT TO PAL-S SAVE AREA      A42707 74500021
         LM    R14,R12,12(R13)     RELOAD PAL-S REGISTERS        A42707 74550021
         DROP  R15                                               A42707 74600021
         USING PALBASE,BASE1       SHIFT BACK TO REG 11 AS BASE  A42707 74650021
         SPACE                                                          74700021
         L     R15,PALERSAV        GET CALLER-S ERROR ROUTINE AD A42707 74850021
         ST    R15,ERRADDR         RESTORE AD IN COMMON          A42707 74900021
         BRWRITE  1                SPACE 1 LINE                  A53323 74950000
         MVC   ADDR(L'PARTERMG),PARTERMG  MOVE ERR MSG TO BUFFER A53323 74960000
         BRWRITE  2                WRITE ERROR MESSAGE           A53323 74970000
         B     BNDCONT             GO COMPLETE PROCESSING        A53323 74980000
         EJECT                                                          75000020
*********************************************************************** 76000020
*                                                                     * 77000020
*  CONSTANTS USED BY IMDPRPAL                                         * 78000020
*                                                                     * 79000020
*********************************************************************** 80000020
         SPACE                                                          81000020
PALSAVE  DC    18F'0'              PAL'S SAVE AREA                      82000020
PALERSAV DC    F'0'                SAVE AREA FOR CALLER-S ERR AD A42707 82050021
PCBLIST  DS    0F                  P-LIST FOR PCB ENQUEUE ROUTINE       83000020
LOW      DS    F                   LOW ADDRESS TO BE PRINTED            84000020
HIGH     DS    F                   HIGH ADDRESS TO BE PRINTED           85000020
TJID     DC    H'0'                TJID OF STORAGE TO BE PRINTED -      86000020
*                                  ALWAYS ZERO FOR PAL                  87000020
PALTITLE DC    C'* * * *    A L L O C A T E D  S T O R A G E   * * * *' 88000020
PARTERMG DC    C'ERROR IN TCB CHAIN DURING PRINT ALL FUNCTION'   A53323 88050000
         SPACE                                                          89000020
         END                                                            90000020
