IMDPRPCR START                                                          00500020
         TITLE 'IMDPRPCR - PRINT CURRENT EXECUTOR'                      01000020
*********************************************************************** 01500020
*                                                                     * 02000021
* STATUS -                                                            * 02050021
*                                                                     * 02060021
*    OS/360  RELEASE 21                                               * 02100021
*                                                                     * 02110000
*A685500-688000,770500-772500,825500-826000                  SA58202  * 02112000
*C690000                                                     SA58202  * 02114000
*C 545000,560000,635000,640000,700000                         A49133  * 02120000
*D 575000 - 630000                                            A49133  * 02130000
*                                                                     * 02150021
* FUNCTION -                                                          * 02200021
*                                                                     * 02210021
*    THIS IS THE CONTROL ROUTINE FOR THE PRINT CURRENT                * 02250021
*    FUNCTION OF IMDPRDMP.  THE ADDRESS OF THE CURRENT                * 02300021
*    TCB IN THE DUMP SYSTEM IS TAKEN FROM THE COMMON CSECT.           * 02350021
*    IF THE DUMP SYSTEM IS MVT, THE RB ADDRESS IN THIS TCB            * 02400021
*    IS COMPARED TO THE TCB ADDRESS ITSELF. IF EQUAL, THE             * 02450021
*    TCB IS THE WAIT TCB FOR WHICH NO STORAGE IS PRINTED.             * 02500021
*                                                                     * 02760021
*    IF THE CURRENT TCB DOES NOT REPRESENT A WAITING TASK,            * 02800021
*    OR IF THE DUMP SYSTEM IS MFT OR PCP, THE CURRENT TCB             * 02850021
*    ADDRESS IS ENQUEUED ON THE TCB LIST.  THE FOLLOWING              * 02900021
*    SERVICE ROUTINES ARE THEN USED TO COMPLETE THE FUNCTION.         * 02950021
*         1. IMDPRFUB, REGION BOUNDARY ROUTINE - TO ENQUEUE           * 03000021
*         THE REGION ASSOCIATED WITH THE CURRENT TCB ON               * 03050021
*         THE PCB LIST READY FOR PRINTING BY IMDPRDPS.                * 03100021
*         2. IMDPRFSR, FORMAT SERVICE ROUTINE - TO FORMAT             * 03150021
*         THE TCB FAMILY AND ASSOCIATED SYSTEM CONTROL                * 03200021
*         BLOCKS FOR THE CURRENT TCB.                                 * 03250021
*         3. IMDPRDPS, DUMP SERVICE ROUTINE - TO PRINT                * 03300021
*         THE REGION ASSOCIATED WITH THE CURRENT TASK.                * 03350021
*                                                                     * 03360021
*    WHEN THE CURRENT TASK REGION HAS BEEN PRINTED,                   * 03400021
*    PROCESSING BY IMDPRPCR IS COMPLETE AND CONTROL RETURNS           * 03450021
*    TO IMDPRCTL, THE CONTROL/SCAN ROUTINE IN THE IMDPRDMP            * 03500021
*    ROOT SEGMENT.                                                    * 03550021
*                                                                     * 03600021
* ENTRY POINTS -                                                      * 03650021
*                                                                     * 03652021
*    IMDPRPCR IS THE MAIN AND ONLY ENTRY POINT.  THIS                 * 03660021
*    MODULE IS INVOKED BY THE MAIN SCAN CSECT, IMDPRMSC,              * 03670021
*    IN MODULE IMDPRCTL, WHEN THE PRINT CURRENT CONTROL               * 03680021
*    STATEMENT IS ENCOUNTERED.                                        * 03690021
*                                                                     * 03700021
* INPUT -                                                             * 03710021
*                                                                     * 03712021
*    THE CURRENT TCB ADDRESS FROM THE DUMP SYSTEM IS TAKEN            * 03720021
*    FROM THE COMMON CSECT AT LABEL CURTCB.  THE BRREAD PRIVATE       * 03730021
*    MACRO INSTRUCTION IS USED TO READ THE RB ADDRESS FIELD           * 03740021
*    FROM THE CURRENT TCB AND THE RESUME PSW FIELD OF THE             * 03750021
*    CURRENT RB FOR THE TCB.                                          * 03760021
*                                                                     * 03770021
* OUTPUT -                                                            * 03780021
*                                                                     * 03782021
*    OUTPUT OF THE PRINT CURRENT FUNCTION OF IMDPRDMP IS              * 03790021
*    DIRECTED BY THIS ROUTINE.  THIS OUTPUT INCLUDES THE              * 03800021
*    FORMATTING OF SYSTEM CONTROL BLOCKS ASSOCIATED WITH              * 03810021
*    THE CURRENT TASK, THE GENERAL PURPOSE REGISTERS, IF              * 03820021
*    PRESENT IN THE DUMP, AND THE REGION ALLOCATED TO THE             * 03830021
*    CURRENT TASK.                                                    * 03840021
*                                                                     * 03842021
*    MODULE IMDPRPCR TITLES THE PRINT CURRENT OUTPUT LISTING.         * 03850021
*    IF THE CURRENT TASK IS THE WAIT TASK OF MVT SYSTEMS,             * 03860021
*    ONLY THE FOLLOWING MESSAGE IS PRINTED:                           * 03870021
*                                                                     * 03872021
*         CURRENT TASK IS DUMMY WAIT TASK                             * 03880021
*                                                                     * 03890021
*    IF THE JOB STEP TCB ADDRESS FOR MFT SYSTEM IS ZERO THEN ONLY     * 03892000
*    THE FOLLOWING OUTPUT COMMENT IS ISSUED:                          * 03894000
*                                                                     * 03894400
*         UNABLE TO OBTAIN JOB STEP TCB FOR CURRENT TASK              * 03896000
*                                                                     * 03896400
* EXTERNAL REFERENCES -                                               * 03900021
*                                                                     * 03902021
*    1. IMDPRRDC - THE READ CONTROL ROUTINE OF IMDPRDMP.              * 03910021
*    THE BRREAD MACRO INSTRUCTION IS USED TO OBTAIN                   * 03920021
*    INFORMATION FROM THE DUMP DATA SET.  THIS MACRO                  * 03930021
*    EXPANDS TO THE CALLING SEQUENCE TO MODULE IMDPRRDC.              * 03940021
*    2. IMDPRWTR - PRINTER DATA SET WRITE ROUTINE.                    * 03950021
*    THIS ROUTINE IS USED TO TITLE THE PRINT CURRENT OUTPUT           * 03960021
*    LISTING, AND, IF NECESSARY, TO WRITE THE WAIT TASK               * 03970021
*    MESSAGE.  LINKAGE TO IMDPRWTR IS GENERATED BY THE                * 03980021
*    BRWRITE PRIVATE MACRO INSTRUCTION.                               * 03990021
*    3. IMDPRTSV - TCB LIST MANAGEMENT ROUTINE.                       * 04000021
*    THE TCB LIST ENQUEUE ROUTINE IS USED TO ENQUEUE THE              * 04010021
*    CURRENT TCB ADDRESS ON THE TCB LIST.  THE TCB LIST               * 04020021
*    IS THEN USED AS INPUT TO THE REGION BOUNDARY ROUTINE             * 04030021
*    IMDPRFUB AND THE FORMAT SERVICE ROUTINE IMDPRFSR.                * 04040021
*    4. IMDPRFUB - THE REGION BOUNDARY ROUTINE.                       * 04050021
*    IMDPRFUB IS USED TO DETERMINE THE BOUNDS OF THE REGION           * 04060021
*    ASSOCIATED WITH THE CURRENT TASK AND THEN TO ENQUEUE             * 04070021
*    A PCB DESCRIBING THE REGION ON THE PCB LIST.  THIS               * 04080021
*    PCB LIST IS USED AS INPUT TO THE DUMP SERVICE ROUTINE            * 04090021
*    IMDPRDPS.                                                        * 04100021
*    5. IMDPRFSR - THE FORMAT SERVICE ROUTINE.                        * 04110021
*    THE FORMAT SERVICE ROUTINE IS CALLED TO FORMAT AND               * 04120021
*    PRINT THE SYSTEM CONTROL BLOCKS ASSOCIATED WITH THE              * 04130021
*    CURRENT TASK.  INPUT TO IMDPRFSR IS THE TCB LIST.                * 04140021
*    6. IMDPRDPS - THE DUMP PRINT SERVICE ROUTINE.                    * 04150021
*    THIS ROUTINE IS CALLED TO PRINT THE GENERAL PURPOSE              * 04160021
*    REGISTERS FROM THE DUMP HEADER RECORD AND THE REGION             * 04170021
*    ASSOCIATED WITH THE CURRENT TASK.  INPUT TO IMDPRDPS             * 04180021
*    IS THE PCB LIST.  THE GPRSFNS SWITCH IN SWD OF COMMON            * 04190021
*    IS SET BY IMDPRPCR TO INDICATE THAT THE GENERAL PURPOSE          * 04200021
*    REGISTERS ARE TO BE PRINTED.                                     * 04210021
*                                                                     * 04220021
* EXITS,NORMAL -                                                      * 04230021
*                                                                     * 04232021
*    WHEN PROCESSING BY IMDPRPCR IS COMPLETE, CONTROL                 * 04240021
*    RETURNS TO THE SCAN CSECT IMDPRMSC IN MODULE IMDPRCTL.           * 04250021
*                                                                     * 04260021
* EXITS,ERROR -                                                       * 04270021
*                                                                     * 04272021
*    NONE                                                             * 04280021
*                                                                     * 04290021
* TABLES/WORK AREAS -                                                 * 04300021
*                                                                     * 04302021
*    NONE                                                             * 04310021
*                                                                     * 04320021
* ATTRIBUTES -                                                        * 04330021
*                                                                     * 04332021
*    REUSABLE                                                         * 04340021
*                                                                     * 04350021
* CHARACTER CODE DEPENDENCY -                                         * 04360021
*                                                                     * 04362021
*    NONE                                                             * 04370021
*                                                                     * 04380021
* NOTES -                                                             * 04390021
*                                                                     * 04392021
*    N/A                                                              * 04400021
*                                                                     * 06000020
*********************************************************************** 06500020
         SPACE                                                          07000020
*/*IMDPRPCR: CHART IMDPRPCR */                                          07050000
*/*IMDPRPCR: E IOSTEST */                                               07100000
*/* P POINT TO I/O NEW PSW */                                           07150000
*/* S BRREAD: */                                                        07200000
*/* P PICK UP INSTR ADDR FROM I/O NEW */                                07250000
*/* D (YES,CURNT,NO,) ON BYTE BOUNDARY */                               07300000
*/* D (YES,CURNT,NO,) GREATER THAN NUC TOP IN COMMON */                 07350000
*/* P POINT TO INSTR ADDR FROM I/O NEW */                               07400000
*/* S BRREAD: */                                                        07450000
*/* D (NO,CURNT,YES,) STM 14,15 INSTRUCTION */                          07460000
*/* P ADD 7 TO INSTRUCTION FROM I/O NEW */                              07470000
*/* P SET IOS SWITCH */                                                 07480000
*/* S BRREAD: */                                                        07490000
*/* D (NO,CURNT,YES,) IOS SWITCH=X'F0' */                               07492000
*/* S BRREAD: */                                                        07494000
*/* P PICK UP REG 1 CONTENTS */                                         07496000
*/* D (YES,CURNT,NO,) REGISTER 1 = ZERO */                              07498000
*/* D (YES,CURNT,NO,) REG 1 GREATER THAN MAX RQE ADDR */                07498400
*/* D (NO,CURNT,YES,) ON WORD BOUNDARY */                               07498800
*/* D (NO,%MFTPCP,YES,) MVT DUMP */                                     07499200
*/* P ADD 12 TO INSTR ADDR IN I/O NEW PSW */                            07499600
*/* P POINT TO TCB ADDRESS */                                           07499700
*/* S BRREAD: */                                                        07499800
*/* D (YES,CURNT,NO,) TCB ADDR ZERO */                                  07499900
*/* D (NO,CURNT,YES,) DOUBLEWORD BOUNDARY */                            07549900
*/* D (YES,,NO,%WRITOUT) GREATER THAN NUC TOP */                        07559900
*/*CURNT: P GET CURRENT PCB ADDRESS FROM COMMON */                      07569900
*/* S BRREAD: */                                                        07579900
*/* P PICK UP RB ADDRESS */                                             07589900
*/* D (NO,%WRITOUT,YES,) MVT DUMP */                                    07591900
*/* D (NO,%WRITOUT,YES,) RB ADDR EQUAL TCB ADDR */                      07593900
*/* P MOVE CURRENT TASK = WAIT TASK MESSAGE TO OUTPUT */                07595900
*/* S BRWRITE: */                                                       07597900
*/* R */                                                                07598300
*/*%MFTPCP: P ADD 4 TO INSTR ADDR IN I/O NEW PSW */                     07598700
*/* P POINT TO TASK ID */                                               07599100
*/* S BRREAD: */                                                        07599500
*/* D (YES,CURNT,NO,) FREE RQE (X'FF') */                               07599600
*/* P DIVIDE TASK ID BY 4 */                                            07599700
*/* P GIVE CVTHEAD  CONTENT FROM COMMON */                              07599800
*/* D (YES,%WRITOUT,NO,) ID EQUAL ZERO */                               07649800
*/* P POINT TO NEXT READY QUEUE TCB */                                  07659800
*/*%TCBREAD: S BRREAD: */                                               07669800
*/* D (YES,CURNT,NO,) NEXT POINTER ZERO */                              07679800
*/* P SUBTRACT 1 FROM TASK ID */                                        07689800
*/* D (YES,,NO,%TCBREAD) ID EQUAL ZERO */                               07691800
*/*%WRITOUT: S BRWRITE: SKIP TO NEW PAGE */                             07693800
*/* P MOVE CURRENT TITLE TO OUTPUT BUFFER */                            07695800
*/* S BRWRITE: PRINT TITLE AND SPACE 2 LINES */                         07697800
*/* D (YES,,NO,TCBSAVE) MFT WITH ATTACH */                              07697900
*/* S BRREAD: GET JOB STEP TCB ADDR */                                  07698000
*/* D (YES,ERRMSG,NO,) IS ADDR ZERO */                                  07698100
*/*TCBSAVE: S IMDPRTSV: SAVE CURRENT TCB ADDRESS */                     07698200
*/*%REGION: S IMDPRFUB: FIND REGION BOUNDARY */                         07698600
*/* P CLEAR TJID REG FOR FORMAT SERVICE */                              07699000
*/* S IMDPRFSR: */                                                      07699400
*/* S BRWRITE: SKIP TO NEW PAGE BEFORE REGION */                        07699500
*/* P SET GPR SWITCH SO REGS ARE PRINTED */                             07699600
*/* S IMDPRDPS: PRINT REGION */                                         07699700
*/* R RETURN */                                                         07709700
*/*ERRMSG: S (,PCRDONE) BRWRITE: WRITE OUTPUT COMMENT */                07719700
*/*IMDPRPCR: END */                                                     07749700
         SPACE                                                          07799700
         EQUATES                                                        08000020
         COMMON                                                         08500020
*                                                                 M3179 08550020
         OUTBUFM                                                        09000020
IMDPRPCR CSECT                                                          09500020
         STM   R14,R12,12(R13)     SAVE CALLER'S REGISTERS              10000020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             10500020
         USING *,BASE1                                                  11000020
         LA    R2,PCRSAVE          SAVE AREA CHAINING                   11500020
         ST    R13,PCRSAVE+4                                            12000020
         ST    R2,8(R13)                                                12500020
         LR    R13,R2              ENTRY COMPLETE                       13000020
         SPACE                                                          13500020
         USING COMMON,COMBASE      BASE COMMON CSECT                    14000020
         USING OUTBUF,BUFREG                                            14500020
         EJECT                                                          15000020
*********************************************************************** 15500020
*                                                                     * 16000020
**                    ***  IOS TEST ROUTINE  ***                     ** 16500020
*                                                                     * 17000020
*   THIS ROUTINE TESTS THE IOS SWITCH AND IF SET WILL ATTEMPT TO GET  * 17500020
*   THE TCB ADDRESS OF THE TASK FOR WHOM THE I/O INTERRUPT IS BEING   * 18000020
*   SERVICED.                                                         * 18500020
*                                                                     * 19000020
*********************************************************************** 19500020
         SPACE                                                          20000020
IOSTEST  LA    PREG,120            ADDR OF I/O NEW PSW                  20500020
         BRREAD  (PREG),DATA,TJID=0                                     21000020
         L     R2,4(PREG)          ADDR OF I/O INTERRUPT ENTRY          21500020
         LA    R2,0(R2)            CLEAR POSSIBLE HIGH ORDER BYTE       22000020
         LA    R3,1                LOAD AND MASK                        22500020
         NR    R3,R2               TEST FOR EVEN BYTE ALIGNMENT         23000020
         BNZ   CURNT               INVALID IF NOT                       23500020
         C     R2,NUCTOP           COMPARE TO UPPER BOUND OF NUC        24000020
         BNL   CURNT               INVALID IF NOT LOW                   24500020
         BRREAD  (R2)                                                   25000020
         CLC   0(2,PREG),IOSENTR   TEST FOR X'90EF'                     25500020
         BNE   CURNT               NOT IOS ENTRY IF NOT                 26000020
         LA    PREG,7(R2)          ADDR OF IOS SW                       26500020
         BRREAD  (PREG)                                                 27000020
         TM    0(PREG),X'F0'       IS IOS SW SET                        27500020
         BNO   CURNT               NO - NOT IN BACK DOOR OF IOS         28000020
         L     PREG,GPRCD          LOAD CODE FOR GPRS                   28500020
         BRREAD  (PREG)                                                 29000020
         LTR   PREG,PREG           TEST FOR REGS                        29500020
         BZ    CURNT               REGS NOT FOUND                       30000020
         L     R2,4(PREG)          LOAD R1 VALUE AT TIME OF DUMP        30500020
         LA    R2,0(R2)            CLEAR HI BYTE                        31000020
         LTR   R2,R2               TEST FOR ZERO                        31500020
         BZ    CURNT               NOT RQE ADDR IF ZERO                 32000020
         C     R2,MAXRQE           COMPARE TO 32767                     32500020
         BNL   CURNT               NOT RQE ADDR IF GT                   33000020
         LA    R3,3                LOAD AND MASK                        33500020
         NR    R3,R2               TEST FOR WRD ALIGN                   34000020
         BNZ   CURNT               NOT RQE IF NOT                       34500020
         TM    SWE,MVTSW           TEST FOR MVT                         35000020
         BNO   IOSTEST1            BR IF PCP/MFT                        35500020
         LA    PREG,12(R2)         ADDR OF TCB PTR                      36000020
         BRREAD  (PREG)                                                 36500020
         L     R2,0(PREG)          LOAD TCB PTR                         37000020
         LA    R2,0(R2)            CLEAR HIGH BYTE                      37500020
         LTR   R2,R2               TEST FOR ZERO TCB ADDR               38000020
         BZ    CURNT               NOT TCB ADDR IF ZERO                 38500020
         LA    R3,7                LOAD AND MASK                        39000020
         NR    R3,R2               TEST FOR DBL WRD ALIGN               39500020
         BNZ   CURNT               NOT TCB IF NOT                       40000020
         C     R2,NUCTOP           COMP TO TOP OF NUCLEUS               40500020
         BNL   CURNT               BR IF NOT LOW                        41000020
         B     CURNT2              TCB ADDR IN REG 2                    41500020
         SPACE                                                          42000020
*   FIND TCB FROM RQE ON PCP/MFT                                        42500020
IOSTEST1 LA    PREG,4(R2)          ADDR OF TASK ID                      43000020
         BRREAD  (PREG)                                                 43500020
         TM    0(PREG),X'FF'       TEST FOR FREE RQE                    44000020
         BO    CURNT               NO TCB IF FREE                       44500020
         IC    R3,0(PREG)          GET TASK ID                          45000020
         SRL   R3,2                DIVIDE BY 4                          45500020
         L     R2,CVTHEAD          GET ADDR OF FIRST TCB                46000020
         LTR   R3,R3               TEST FOR ID OF 0                     46500020
         BE    CURNT2              TCB ADDR IN REG 2 IF SO              47000020
IOSTEST2 LA    PREG,TCBNEXT(R2)    ADDR OF PTR TO NEXT TCB              47500020
         BRREAD  (PREG)                                                 48000020
         L     R2,0(PREG)          LOAD ADDR                            48500020
         LA    R2,0(R2)            CLEAR POS HI BYTE                    49000020
         LTR   R2,R2               TEST FOR ZERO                        49500020
         BZ    CURNT               TASK ID TOO BIG                      50000020
         BCT   R3,IOSTEST2         LOOP FOR TASK ID CNT                 50500020
         B     CURNT2              TCB ADDR IN REG 2                    51000020
         EJECT                                                          51500020
CURNT    L     R2,CURTCB           LOAD ADDR OF CURRENT TCB FROM        52000020
*                                  COMMON CSECT                         52500020
         BRREAD  (R2),DATA,TJID=0                                       53000020
         L     PREG,0(PREG)        LOAD RB ADDR                         53500020
         TM    SWE,MVTSW           IS THIS AN MVT DUMP                  54000020
         BZ    CURNT2              BR IF NOT                     A49133 54500000
         CR    R2,PREG             MVT--IS THIS THE WAIT TCB...RB ADDR  55000020
*                                  EQ TCB ADDR                          55500020
         BE    CURNT3              YES--SOFT WAIT                A49133 56000000
         B     CURNT2              NO--CONTINUE                         56500020
         SPACE                                                          57000020
CURNT3   BRWRITE  2                SPACE TWO LINES               A49133 63500000
         L     BUFREG,CURBUF       PICK UP PNTR TO OUTPUT AREA   A49133 64000000
*                                  BUFFER                               64500020
         MVC   ADDR(L'WAITTASK),WAITTASK  STOW MESSAGE - DUMMY TASK     65000020
         BRWRITE  1                PUT MESSAGE ON OUTPUT LISTING        65500020
         B     PCRDONE             EXIT                                 66000020
         SPACE                                                          66500020
CURNT2   BRWRITE  SKIP                                                  67000020
         L     BUFREG,CURBUF                                            67500020
         MVC   ADDR+37(L'PCRTITLE),PCRTITLE                             68000020
         BRWRITE  2                                                     68500020
         TM    SWE,MFTSW+MFTATCH   MFT WITH ATTACH?             SA58202 68550000
         BNO   TCBSAVE             NO - GO SAVE CURRENT TCB     SA58202 68600000
         LA    PREG,MFTJST(R2)     YES - GET JOB STEP TCB       SA58202 68650000
         BRREAD (PREG)                                          SA58202 68700000
         L     R2,0(PREG)          IS ADDR ZERO                 SA58202 68750000
         LTR   R2,R2                                            SA58202 68760000
         BZ    ERRMSG              YES - PUT OUT MESSAGE        SA58202 68800000
TCBSAVE  L     R15,ATCBSAVE        ADDR OF TCB SAVE ROUTINE     SA58202 69000000
         BALR  RETREG,R15          GO SAVE TCB ADDR ON TCBLIST          69500020
         L     R15,ARGNBND         AD OF REGION BOUNDRY ROUTINE  A49133 70000000
         BALR  RETREG,R15          GO FIND TASK'S REGION BOUNDRIES      70500020
         SR    R0,R0               TJID IS ZERO                         71000020
         L     R15,AFORMAT         POINT TO FORMAT SERVICE ROUTINE      71500020
         BALR  RETREG,R15          GO FORMAT CURREN TCB                 72000020
         BRWRITE  SKIP                                                  72500020
         OI    SWD,GPRSFND         ASK DPS FOR REGS                     73000020
         L     R15,APRTSTG         GET ADDRESS OF PRINT STORAGE         73500020
*                                  ROUTINE                              74000020
         BALR  RETREG,R15          GO PRINT CURRENT TASK'S REGION       74500020
         L     R15,ATCBREMV        ADDR OF TCB REMOVE ROUTINE    A48075 74550021
         SR    R2,R2               TO INDICATE REMOVAL OF ALL    A48075 74600021
*                                  TCB ADDRESSES                 A48075 74650021
         BALR  RETREG,R15          LINK TO TCBREMV               A48075 74700021
         SPACE                                                          75000020
PCRDONE  L     R13,4(R13)          GET ADDRESS OF CALLER'S SAVE AREA    75500020
*                                  (CALLER IS IMDPRCTL)                 76000020
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGS                76500020
         BR    RETREG              RETURN                               77000020
         SPACE                                                          77050000
ERRMSG   L     BUFREG,CURBUF       ISSUE ERROR MESSAGE          SA58202 77100000
         MVC   ADDR(L'JSTCBERR),JSTCBERR                        SA58202 77150000
         BRWRITE 1                                              SA58202 77200000
         B     PCRDONE                                          SA58202 77250000
         EJECT                                                          77500020
*********************************************************************** 78000020
*                                                                     * 78500020
*   CONSTANTS FOR IMDPRPCR                                            * 79000020
*                                                                     * 79500020
*********************************************************************** 80000020
PCRSAVE  DC    18F'0'              PCR'S SAVE AREA                      80500020
MAXRQE   DC    F'32767'            MAXIMUM RQE ADDRESS                  81000020
IOSENTR  DC    X'90EF'                                                  81500020
PCRTITLE DC    C'* * * *    P R I N T  C U R R E N T    * * * *'        82000020
WAITTASK DC    C'CURRENT TASK IS DUMMY WAIT TASK'                       82500020
JSTCBERR DC    CL46'UNABLE TO OBTAIN JOB STEP TCB FOR CURRENT TASK'     82550000
*                                                               SA58202 82600000
         SPACE                                                          83000020
         END                                                            83500020
