IMDPRPDR START                                                          00400020
         TITLE 'IMDPRPDR - PRINT DAR OR F03 EXECUTOR'                   00800020
*/*IMDPRDPR: CHART */                                                   00850021
*/* E IMDPRPDR PRINT DAR RTN */                                         00900021
*/* M TURN OFF F03 SWITCHES */                                          00950021
*/* M SAVE ADDRESS OF PREVIOUS ERROR RTN */                             01000021
*/* M ENABLE IMDPRPDR ERROR RTN */                                      01050021
*/* P GET ADDR OF TOP TCB ON TCB CHAIN */                               01100021
*/*F03PRT1: D (NO,,YES,F03PRT2) END OF TCB CHAIN */                     01150021
*/* P GET TIOT PTR FOR THIS TCB */                                      01160021
*/* L BRREAD: READ TIOT ADDRESS */                                      01170021
*/* D (YES,,NO,F03PRT5) TIOT PRESENT */                                 01180021
*/* D (NO,,YES,F03PRT5) TIOT ADDR GREATER THAN MAXIMUM */               01190021
*/* D (YES,,NO,F03PRT5) TIOT ON FULL WORD BOUNDARY */                   01192021
*/* L BRREAD: READ STEPNAME FROM TIOT */                                01194021
*/* D (YES,,NO,F03PRT5) FAIL SOFT STEPNAME */                           01196021
*/*F03PRT6: L TCBSAVE: SAVE THIS TCB ADDRESS */                         01198021
*/*F03PRTLP: P GET ADDRESS OF NEXT TCB */                               01198421
*/* L (,F03PRT1) BRREAD: READ NEXT TCB ADDRESS */                       01198821
*/*F03PRT5: P GET TCB POINTER */                                        01199221
*/* L BRREAD: READ FIRST WORD OF TCB */                                 01199621
*/* D (NO,,YES,F03PRTLP) RB POINTER = 0 */                              01199721
*/* P INDICATE TWO RBS TO BE PROCESSED */                               01199821
*/*F03PRT51: L BRREAD: READ RB FLAG FIELD */                            01199921
*/* D (YES,,NO,F03PRT52) IS THIS AN SVRB */                             01249921
*/* L BRREAD: READ APSW FIELD (SECOND HALF OF SVC NAME) */              01259921
*/* D (NO,,YES,F03PRT6) IS THIS DAR SVC L01C */                         01269921
*/* D (NO,,YES,F03PRT6) IS THIS DAR SVC 221C */                         01279921
*/*F03PRT52: D (NO,,YES,F03PRTLP) FIRST RB PROCESSED */                 01289921
*/* P INDICATE FIRST RB PROCESSED */                                    01291921
*/* L BRREAD: READ RB LINK FIELD */                                     01293921
*/* D (YES,F03PRTLP,NO,F03PRT51) DOES LINK FIELD POINT TO TCB */        01295921
*/*F03PRT2: D (YES,,NO,F03PRTDN) MVT OR MFT ATTACH DUMP */              01297921
*/* P ZERO F03 TCB COUNT */                                             01298321
*/* P SET SEQUENCE SWITCH */                                            01298721
*/*F03PRT4: P INCREMENT TCB COUNT BY 1 */                               01299121
*/* L TCBRTRV: RETRIEVE TCB ADDRESS */                                  01299521
*/* D (YES,,NO,F03PRDNA) WERE THERE ANY MORE TCB ADDRESSES */           01299621
*/*F03PRT3: P GET PTR TO TCB'S JOB STEP TCB ADDRESS FOR MVT */          01299721
*/* D (NO,,YES,F03PRT8) IS THIS AN MVT DUMP */                          01299821
*/* P GET PTR TO TCB'S JOB STEP TCB ADDRESS FOR MFT */                  01349821
*/*F03PRT8: L BRREAD: READ POINTER TO JOB STEP TCB */                   01359821
*/* D (NO,,YES,F03PRT7) IS IT THE MASTER SCHEDULER TCB */               01369821
*/* D (YES,,NO,F03JSSV) IS THIS TCB THE JOB STEP TCB */                 01379821
*/*F03PRT7: L BRREAD: GET POINTER TO DAUGHTER TCB */                    01389821
*/* D (YES,F03PRT3,NO,F03CRSV) IS THERE ANY DAUGHTER */                 01391821
*/*F03JSSV: P LOAD JOB STEP TCB ADDRESS */                              01393821
*/*F03CRSV: P SAVE TCB LIST POINTER */                                  01395821
*/* P SET TCB LIST POINTER = F03 LIST POINTER */                        01397821
*/* L TCBSAVE: SAVE THIS TCB ADDR ON F03 LIST */                        01398221
*/* P RESTORE F03 LIST POINTER */                                       01398621
*/* P (,F03PRT4) RESTORE TCB LIST POINTER */                            01399021
*/*F03PRDNA: P INDICATE ALL TCBS TO BE REMOVED */                       01399421
*/* L TCBREMV: REMOVE ALL TCBS FROM LIST */                             01399521
*/* P SET TCB LIST POINTER = F03 LIST POINTER */                        01399621
*/* P ZERO F03 LIST POINTER */                                          01399721
*/*F03PRTDN: D (YES,,NO,PRINTRGN) IS THE TCB LIST POINTER = 0 */        01449721
*/* P MOVE 'NOTHING TO DO' MSG TO CURRENT BUFFER */                     01459721
*/* L (,F03DONE) BRWRITE: WRITE MESSAGE */                              01469721
*/*PRINTRGN: P MOVE F03 TITLE TO CURRENT BUFFER */                      01479721
*/* L BRWRITE: WRITE F03 TITLE */                                       01489721
*/* L IMDPRFUB: MAP F03 REGION AND ENQUEUE IT FOR PRINTING */           01491721
*/* P SET TJID = 0 */                                                   01493721
*/* L IMDPRFSR: FORMAT TCB AND CONTROL BLOCKS */                        01495721
*/* L IMDPRDPS: DUMP REGION */                                          01497721
*/*F03DONE: P RESTORE PREVIOUS ERROR RTN ADDRESS */                     01498121
*/* R RETURN TO CALLER */                                               01498521
*/*F03ERR: E F03 ERROR ROUTINE */                                       01498921
*/* P RESTORE REGISTERS FOR IMDPRPDR */                                 01499321
*/* L ADRCNVT: CONVERT TCB ADDRESS IN ERROR TO HEX */                   01499421
*/* D (YES,,NO,F03ERR1) SEQUENCE SWITCH SET */                          01499521
*/* P (,F03ERR2) MOVE TRUNCATED DAR ERROR MESSAGE TO CURRENT BUFFER */  01499621
*/*F03ERR1: P MOVE DAR ERROR MESSAGE TO CURRENT BUFFER */               01533021
*/*F03ERR2: L BRWRITE: WRITE DAR ERROR MESSAGE */                       01543021
*/* D (YES,F03PRT4,NO,F03PRT2) SEQUENCE SWITCH SET */                   01553021
*/*IMDPRPDR: END */                                                     01563021
*********************************************************************** 01566621
*                                                                     * 01600020
**                    ***  F03 PRINT ROUTINE  ***                    ** 02000020
*                                                                     * 02400020
*                                                                     * 02800020
* STATUS:   OS/360  RELEASE  21.0                                     * 02801021
*                                                                     * 02802021
* C 860000                                                       M4058* 02802421
* A 086000                                                            * 02802521
* C 176000                                                            * 02802621
* D 181000-364000                                                     * 02802721
*                                                                     * 02802821
*                                                                     * 02802921
* FUNCTION:  THIS ROUTINE IS THE CONTROL ROUTINE FOR THE PRINT F03    * 02803021
*      OPERATION.  STARTING WITH THE CVTHEAD VALUE IN THE COMMON      * 02804021
*      CSECT, AND PROCEEDING DOWN THE TCB READY QUEUE, THE STEP NAMES * 02805021
*      OF ALL TCB'S ARE CHECKED FOR THE NAME 'F03'.  EACH TCB WITH    * 02806021
*      THIS STEPNAME IS ENQUEUED ON THE TCBLIST.  ALSO, THE TWO MOST  * 02807021
*      RECENT RB'S FOR EACH TCB ARE CHECK TO DETERMINE WHETHER DAR IS * 02808021
*      IN CONTROL.  THIS TEST IS AS FOLLOWS:  EACH RB IS TESTED TO    * 02809021
*      INSURE THAT IT IS AN SVRB.  THEN THE RB NAME FIELD OR APSW     * 02810021
*      FIELD IS TESTED FOR THE NAMES '801C' AND '221C' BECAUSE THESE  * 02811021
*      ARE THE MODULE NAMES FOR DAR IN MVT AND PCP/MFT RESPECTIVELY.  * 02812021
*      TWO RB'S MUST BE CHECKED SINCE SVC DUMP (SVC 51) MAY BE THE    * 02813021
*      LATEST RB FOR A TASK IN DAR PROCESSING.  IF DAR IS PROCESSING  * 02814021
*      FOR A PARTICULAR TASK, THE TCB FOR THAT TASK IS ENQUEUED ON    * 02815021
*      THE TCBLIST.                                                   * 02816021
*          IF THE DUMP SYSTEM IS MVT, THE JSTCB FOR EACH ENQUEUED TCB * 02817021
*      IS DETERMINED AND THIS TCB IS ENQUEUED ON THE TCB LIST.  THIS  * 02817421
*      IS DONE TO INSURE THAT THE ENTIRE TCB FAMILY FOR A F03 OR DAR  * 02817821
*      TERMINATED TASK IS PRINTED.                                    * 02818221
*          AFTER ALL TCB'S IN THE DUMP SYSTEM HAVE BEEN PROCESSED,    * 02818621
*      THIS MODULE LINKS TO THE REGION BOUNDARY ROUTINE, IMDPRFUB,    * 02819321
*      TO ENQUEUE THE REGIONS OF F03 OR DAR TASKS ON THE PCBLIST FOR  * 02819421
*      PRINTING.  PRINTING OF THESE TASKS IS THEN ACCOMPLISHED USING  * 02819821
*      THE FORMAT (IMDPRFSR) AND PRINT STORAGE (IMDPRDPS) SERVICE     * 02820021
*      ROUTINES.                                                      * 02820421
*                                                                     * 02827021
* ENTRY POINT:  IMDPRPDR IS THE MAIN AND ONLY ENTRY POINT.  CONTROL   * 02828021
*      IS RECEIVED FROM THE CONTROL/SCAN ROUTINE, IMDPRCTL, WHENEVER  * 02829021
*      THE F03 OPERAND OF THE PRINT VERB IS SPECIFIED.                * 02830021
*                                                                     * 02831021
* INPUT:                                                              * 02832021
*                                                                     * 02833021
*      1.  THE VALUE OF CVTHEAD FIELD IN THE DUMP SYSTEM IS TAKEN     * 02834021
*      FROM THE COMMON CSECT (IMDPRCOM).  THIS VALUE IS EXTRACTED     * 02835021
*      FROM THE DUMP DATA SET BY MODULE IMDPRMST.                     * 02836021
*                                                                     * 02837021
*      2.  INFORMATION FROM THE DUMP DATA SET IS OBTAINED BY USE OF   * 02838021
*      BRREAD PRIVATE MACRO INSTRUCTION.                              * 02839021
*                                                                     * 02840021
* OUTPUT:  DIRECT OUTPUT OF THIS ROUTINE IS THE ADDRESSES OF ALL F03  * 02841021
*      OR DAR TERMINATED TASKS ON THE TCBLIST.  THROUGH THE USE OF    * 02842021
*      SERVICE ROUTINES, OUTPUT FOR THE PRINT F03 OPERATION IS        * 02843021
*      ACCOMPLISHED BY THIS ROUTINE.                                  * 02844021
*                                                                     * 02845021
* EXTERNAL REFERENCES:                                                * 02846021
*                                                                     * 02847021
*      1.  IMDPRRDC - READ CONTROL ROUTINE - TO OBTAIN INFORMATION    * 02848021
*      FROM THE DUMP DATA SET.  CALLING SEQUENCE FOR THIS ROUTINE IS  * 02849021
*      GENERATED BY THE BRREAD MACRO INSTRUCTION.                     * 02850021
*                                                                     * 02851021
*      2.  IMDPRWTR - PRINTER DATA SET WRITE ROUTINE - TO WRITE TITLE * 02852021
*      LINES AND IF NECESSARY AN ERROR MESSAGE TO THE PRINTER DATA    * 02853021
*      SET.  CALLING SEQUENCE FOR THIS ROUTINE IS GENERATED BY THE    * 02854021
*      BRWRITE PRIVATE MACRO INSTRUCTION.                             * 02855021
*                                                                     * 02856021
*      3.  IMDPRFUB - REGION BOUNDARY ROUTINE - TO ENQUEUE F03 AND    * 02857021
*      DAR REGIONS FOR PRINTING.                                      * 02858021
*                                                                     * 02859021
*      4.  IMDPRFSR - FORMAT SERVICE ROUTINE - TO FORMAT SYSTEM       * 02860021
*      CONTROL BLOCKS FOR F03 AND DAR TASKS.                          * 02861021
*                                                                     * 02862021
*      5.  IMDPRDPS - PRINT STORAGE SERVICE ROUTINE - TO PRINT F03    * 02863021
*      AND DAR REGIONS.                                               * 02864021
*                                                                     * 02865021
* EXITS - NORMAL:  WHEN ALL F03 AND DAR TASKS HAVE BEEN PRINTED,      * 02866021
*      CONTROL RETURNS TO MODULE IMDPRCTL.                            * 02867021
*                                                                     * 02868021
* EXITS - ERRORS:                                                     * 02869021
*                                                                     * 02870021
*      1.  IF AN OCCURS DURING THE SEARCH OF THE TCB READY QUEUE, THE * 02871021
*      FOLLOWING MESSAGE IS ISSUED TO THE PRINTER DATA SET.           * 02872021
*                                                                     * 02873021
*      TCB CHAIN ERROR IN DAR PRINT ROUTINE TCB XXXXXX CONTINUING     * 02874021
*                                                                     * 02875021
*      IN THIS CASE, THE SEARCH IS ABANDONED AND IMDPRPDR PROCESSING  * 02876021
*      CONTINUES WITH FINDING THE JSTCB'S FOR ALREADY ENQUEUED TCB'S, * 02877021
*      FOR MVT SYSTEMS, AND PRINTING OF ENQUEUED TASKS.  IF AN ERROR  * 02878021
*      OCCURS FINDING JSTCB'S, THE FOLLOWING MESSAGE IS ISSUED TO THE * 02879021
*      PRINTER DATA SET                                               * 02880021
*                                                                     * 02881021
*      TCB CHAIN ERROR IN DAR PRINT ROUTINE TCB XXXXXX CONTINUING     * 02882021
*      WITH NEXT TCB                                                  * 02883021
*                                                                     * 02884021
*      THE TYPES OF ERRORS WHICH CAN BE ENCOUNTERED ARE 1) ADDRESS OF * 02885021
*      DATA REQUESTED FROM DUMP IS GREATER THAN MAXIMUM MACHINE       * 02886021
*      ADDRESS IN CVT OF DUMP SYSTEM, 2) INVALID BOUNDARY ALLIGNMENT  * 02887021
*      OF SYSTEM CONTROL BLOCK, 3) DATA REQUESTED IS NOT IN DUMP DATA * 02888021
*      SET BECAUSE OF A MISSING DUMP BLOCK, AND 4) I/O ERROR          * 02889021
*      OBTAINING DUMP DATA.                                           * 02890021
*                                                                     * 02891021
*      2.  IF NO F03 OR DAR TASKS CAN BE FOUND, THE FOLLOWING MESSAGE * 02892021
*      IS ISSUED AND CONTROL RETURNS TO IMDPRCTL.                     * 02893021
*                                                                     * 02894021
*      NO TASKS IN DAR OR F03 WAIT                                    * 02895021
*                                                                     * 02896021
* TABLES/WORK AREAS:  NONE                                            * 02897021
*                                                                     * 02898021
* ATTRIBUTES:  REUSABLE                                               * 02899021
*                                                                     * 02900021
* CHARACTER CODE DEPENDENCY:  NONE                                    * 02901021
*                                                                     * 02902021
* NOTES:  NONE                                                        * 02903021
*                                                                     * 05600020
*********************************************************************** 06000020
         SPACE                                                          06400020
         EQUATES                                                        06800020
         COMMON                                                         07200020
*                                                                 M3179 07250020
         OUTBUFM                                                        07600020
IMDPRPDR CSECT                                                          08000020
F03SQ1   EQU   128                                                      08400020
TCBDAR   EQU   172                                             @SA68390 08600021
F03RB2   EQU   64                                                       08800020
RBLINK   EQU   28                                                       09200020
         STM   R14,R12,12(R13)     SAVE CALLER'S REGISTERS              09600020
         BALR  BASE1,0             ESTABLISH REG 11 AS BASE             10000020
         USING F03PRT,BASE1                                             10400020
F03PRT   LA    R2,F03SAVE          SAVE AREA CHAINING                   10800020
         ST    R13,F03SAVE+4                                            11200020
         ST    R2,8(R13)                                                11600020
         LR    R13,R2              ESTABLISH PDR'S SAVE AREA            12000020
         SPACE                                                          12400020
         USING COMMON,COMBASE      REG 12 IS COMMON CSECT POINTER       12800020
         USING OUTBUF,BUFREG       REG 6 IS BASE FOR OUTBUF DSECT       13200020
         SPACE                                                          13600020
         MVI   F03PRSW,0           ZERO F03PRT SW                       14000020
         MVC   F03ERSV,ERRADDR     SAVE PREVIOUS ERROR ROUT ADDR        14400020
         LA    R15,F03ERR          ADDR OF THIS ROUTINES ERROR ROUT     14800020
         ST    R15,ERRADDR         ENABLE ERROR ROUTINE                 15200020
         XC    F03LIST,F03LIST     ZERO F03 LIST BASE                   15600020
         L     R2,CVTHEAD          LOAD ADDR OF TOP TCB ON CHAIN        16000020
F03PRT1  LA    R2,0(R2)            CLEAR POSSIBLE HI BYTE               16400020
         LTR   R2,R2               TEST FOR END OF CHAIN                16800020
         BZ    F03PRT2             BR IF END                            17200020
         LA    PREG,TCBDAR(R2)     ADDR OF TCB DAR FIELD       @SA68390 17600021
         BRREAD  (PREG),DATA,TJID=0                                     18000020
         CLI   0(PREG),X'00'       DAR TERMINATED TASK         @SA68390 18100021
         BE    F03PRTLP            NO, GET NEXT TCB            @SA68390 18200021
F03PRT6  L     R15,ATCBSAVE        ADDR OF TCB SAVE ROUTINE             23600020
         BALR  RETREG,R15          SAVE THIS TCB ADDR                   24000020
F03PRTLP LA    PREG,TCBNEXT(R2)    ADDR OF NEXT TCB PTR                 24400020
         BRREAD  (PREG)                                                 24800020
         L     R2,0(PREG)          LOAD ADDR OF NEXT TCB IN CHAIN       25200020
         B     F03PRT1             LOOP THROUGH TCB CHAIN               25600020
         SPACE                                                          26000020
         EJECT                                                          36450021
*********************************************************************** 36500021
*                                                                     * 36510021
*  FOR MVT SYSTEMS, FIND JSTCB FOR EACH TCB NOW ON TCB LIST.          * 36520021
*  THIS INSURES THAT ENTIRE FAMILY WILL BE PRINTED.                   * 36530021
*                                                                     * 36540021
*********************************************************************** 36542021
         SPACE                                                          36800020
F03PRT2  TM    SWE,MVTSW+MFTATCH   IS THIS AN MVT OR MFT ATTACH DUMP    37200020
         BZ    F03PRTDN            NO--ALL DONE WITH FIND OPERATION     37600020
         XC    F03CNT,F03CNT       YES--MUST GET JOBSTEP TCB ADDR       38000020
*                                  FOR EACH TCB ON LIST                 38400020
         OI    F03PRSW,F03SQ1      SET SEQ SW                           38800020
F03PRT4  LH    R2,F03CNT           LOAD TCB COUNT                       39200020
         AH    R2,ONEA             ADD ONE TO IT                        39600020
         STH   R2,F03CNT           UPDATE COUNT                         40000020
         L     R15,ATCBRTRV        LOAD ADDR OF TCB RETREIVE ROUT       40400020
         BALR  RETREG,R15          GO GET A TCB ADDR                    40800020
         LTR   R2,R2               WERE THERE ANY MORE                  41200020
         BZ    F03PRDNA            NO--ALMOST DONE                      41600020
F03PRT3  TM    SWE,MVTSW           IS IT MVT                            42000020
         LA    PREG,JSTCB(R2)      ADDR OF TCB'S JOB STEP TCB ADDR FOR  42400020
*                                  MVT                                  42800020
         BO    F03PRT8             YES--IT'S MVT SO BR AROUND NEXT INST 43200020
         LA    PREG,MFTJST(R2)     NO--LOAD ADDR OF JSTCB FOR MFT       43600020
F03PRT8  BRREAD  (PREG)                                                 44000020
         CLC   MSTRTCB+1(3),1(PREG) DOES JSTCB EQ MASTER                44400020
         BE    F03PRT7             YES--CONSIDER SAME AS IT'SELF        44800020
         C     R2,0(PREG)          DOES JOBSTEP TCB ADDR EQ IT'SELF     45200020
         BNE   F03JSSV             NO--SAVE JOBSTEP TCB ADDR            45600020
F03PRT7  LA    PREG,DAUGHTER(R2)   ADDR OF PTR TO DAUGHTER              46000020
         BRREAD  (PREG)                                                 46400020
         L     PREG,0(PREG)        LOAD DAU PTR                         46800020
         LTR   PREG,PREG           IS THERE A DAUGHTER                  47200020
         BZ    F03CRSV             NO--SAVE ADDR OF TCB IN R2           47600020
         LR    R2,PREG             LOAD DAU TO R2                       48000020
         B     F03PRT3             LOOP                                 48400020
         SPACE                                                          48800020
F03JSSV  L     R2,0(PREG)          LOAD JOBSTEP TCB ADDR                49200020
F03CRSV  MVC   F03TSV,TCBLIST      SAVE TCB LIST PTR                    49600020
         MVC   TCBLIST,F03LIST     MOVE IN F03 LIST PTR                 50000020
         L     R15,ATCBSAVE        ADDR OF SAVE ROUTINE                 50400020
         BALR  RETREG,R15          GO SAVE THIS TCB ADDR ON F03LIST     50800020
         MVC   F03LIST,TCBLIST     RESTORE F03LIST PTR                  51200020
         MVC   TCBLIST,F03TSV      RESTORE TCBLIST PTR                  51600020
         B     F03PRT4             LOOP THORUGH LIST                    52000020
         EJECT                                                          52050021
*********************************************************************** 52100021
*                                                                     * 52110021
*  LINK TO SERVICE ROUTINES TO ACCOMPLISH FORMATING OF DAR AND        * 52120021
*  F03 TASKS.                                                         * 52130021
*                                                                     * 52140021
*********************************************************************** 52150021
         SPACE                                                          52400021
F03PRDNA SR    R2,R2               CLEAR R2 TO INDICATE REMOVE ALL      52800020
         L     R15,ATCBREMV                                             53200020
         BALR  RETREG,R15          REMOVE ALL TCBS                      53600020
         MVC   TCBLIST,F03LIST     MAKE TCBLIST POINT TO LIST OF JOB    54000020
*                                  STEP TCB ADDRESSES FOR ALL JOBS IN   54400020
*                                  F03 FAIL SOFT                        54800020
         XC    F03LIST,F03LIST     ZERO F03 LIST PTR                    55200020
F03PRTDN OC    TCBLIST,TCBLIST     IS THERE ANYTHING TO PRINT           55600020
         BNZ   PRINTRGN            YES - GO DO IT                       56000020
*                                  NO - ISSUE NOTHING TO DO MESSAGE     56400020
         BRWRITE  1                SPACE A LINE                         56800020
         L     BUFREG,CURBUF       POINT TO CURRENT OUTPUT BUFFER       57200020
         MVC   ADDR(27),NODARF03   MOVE NOTHIN' MESSAGE TO OUTPUT BUF   57600020
         BRWRITE  2                PRINT IT ON PRINTER DATA SET         58000020
         B     F03DONE             GO EXIT                              58400020
         SPACE 2                                                        58800020
PRINTRGN BRWRITE  SKIP                                                  59200020
         L     BUFREG,CURBUF       GET AN OUTPUT BUFFER                 59600020
         MVC   ADDR+34(L'F03TITLE),F03TITLE                             60000020
         BRWRITE  2                                                     60400020
         L     R15,ARGNBND         POINT TO REGION BOUNDARY ROUTINE     60800020
         BALR  RETREG,R15          LINK TO FUB TO MAP F03 REGION AND    61200020
*                                  ENQUEUE IT FOR PRINTING              61600020
         SR    R0,R0               ZERO OUT TJID PARM             M2013 62000020
         L     R15,AFORMAT         GET ADDR OF FORMAT SERVICE ROUTINE   62400020
         BALR  RETREG,R15          GO OFF TO FORMAT TCB AND CONTROL     62800020
*                                  BLOCKS FOR WAITING TASK              63200020
         L     R15,APRTSTG         POINT TO DPS                         63600020
         BALR  RETREG,R15          LINK TO IT TO DUMP REGION            64000020
         L     R15,ATCBREMV        ADDR OF TCB REMOVE ROUTINE    A48075 64050021
         SR    R2,R2               TO INDICATE REMOVAL OF ALL    A48075 64100021
*                                  TCB ADDRESSES                 A48075 64150021
         BALR  RETREG,R15          LINK TO TCBREMV               A48075 64200021
         SPACE                                                          64400020
F03DONE  MVC   ERRADDR,F03ERSV     RESTORE PREVIOUS ERROR ROUTINE ADDR  64800020
         L     R13,4(R13)          GET ADDR OF CALLER'S SAVE AREA       65200020
         LM    R14,R12,12(R13)     RESTORE CALLER'S REGISTER'S          65600020
         BR    RETREG              RETURN                               66000020
         EJECT                                                          66400020
*********************************************************************** 66800020
*                                                                     * 67200020
*   ERROR ROUTINE FOR F03 PRINT                                       * 67600020
*                                                                     * 68000020
*********************************************************************** 68400020
         SPACE                                                          68800020
         DROP  BASE1                                                    69200020
         USING F03ERR,R15          TEMPORARILY BASE ERROR HANDLER       69600020
*                                  ON EP ADDR IN REG 15                 70000020
F03ERR   LA    R13,F03SAVE         POINT TO PDR'S SAVE AREA             70400020
         LM    R14,R12,12(R13)     RESTORE PDR'S REGS                   70800020
         DROP  R15                                                      71200020
         USING F03PRT,BASE1        SHIFT BACK TO REG 11 AS BASE         71600020
         BRWRITE 1                 SPACE A LINE                         72000020
         ST    R2,WORK1            STORE R2 FOR CONVERSION              72400020
         LA    PREG,WORK1          ADDR OF VAL TO BE CONVERTED          72800020
         LA    R4,F03ERMSG+43      ADDR OF WHERE IT GOES                73200020
         L     R15,AADRCNVT        ADDR OF 3 BYTE CONVERT ROUTINE       73600020
         BALR  RETREG,R15          CONVERT TCB ADDR                     74000020
         MVI   F03ERMSG+49,C'.'    RESTORE THE PERIOD IN MSG            74400020
         L     BUFREG,CURBUF       LOAD OUTPUT BUFFER ADDR              74800020
         TM    F03PRSW,F03SQ1      TEST SQ1 SW                          75200020
         BZ    F03ERR1             BR IF NOT ON                         75600020
         MVC   ADDR(64),F03ERMSG   MOVE TRUNC ERROR MSG TO BUF          76000020
         B     F03ERR2             BR AROUND                            76400020
F03ERR1  MVC   ADDR(78),F03ERMSG   MOVE ERROR MESSAGE TO BUFFER         76800020
F03ERR2  BRWRITE 2                 PRINT MESSAGE AND SPACE 2 LINES      77200020
         TM    F03PRSW,F03SQ1      TEST SEQ SW                          77600020
         BZ    F03PRT2             BR IF IT ISN'T ON                    78000020
         B     F03PRT4             RESUME WITH NEXT TCB ON LIST         78400020
         EJECT                                                          78800020
*********************************************************************** 79200020
*                                                                     * 79600020
*   CONSTANTS FOR F03PRT ROUTINE                                      * 80000020
*                                                                     * 80400020
*********************************************************************** 80800020
         SPACE                                                          81200020
F03SAVE  DC    18F'0'                                                   81600020
F03TSV   DC    F'0'                SAVE AREA FOR TCBLIST PTR            82000020
F03LIST  DC    F'0'                JOBSTEP F03 TCB LIST PTR             82400020
F03ERSV  DC    F'0'                SAVE AREA FOR PREV ERR ROUT ADDR     82800020
F03PRTA  DC    A(F03PRT)                                                83200020
F03CNT   DC    H'0'                F03 TCB COUNT                        83600020
F03NM    DC    F'0'                STEPNAME FOR TASK WHICH IS IN F03    84000020
         DC    CL4'F03'            WAIT STATE                           84400020
F03PRSW  DC    X'00'               BIT 0 - SEQUENCE SWITCH              84800020
*                                      1 - PROCESSING SECOND RB ON      85200020
*                                          A PARTICULAR TCB             85600020
DARSVCNM DC    C'L01C'             NAME OF DAR SVC - MVT R21.0    M4058 86000021
DARMFT19 DC    C'221C'             NAME OF DAR - MFT R19                86400020
NODARF03 DC    C'NO TASKS IN DAR OR F03 WAIT'                           86800020
F03ERMSG DC    C'TCB CHAIN ERROR IN DAR PRINT ROUTINE   TCB XXXXXX....CX87200020
               ONTINUING WITH NEXT TCB'                                 87600020
F03TITLE DC    C'* * * *    D A R  A N D  F 0 3  T A S K S    * * * *'  88000020
         SPACE                                                          88400020
         END                                                            88800020
